         TITLE 'IGG019QB - WTTA TELETYPE LINE APPENDAGE'                00100017
IGG019QB START                                                          00200017
*90357106300-106600,274000-275000,414000,527500                    00PS 00250017
*D105000-106000,213000,295000                                    A25044 00260021
*A104200-105800,212100-213300,294500-295500                      A25044 00270021
* STATUS       CHANGE LEVEL 000    MAY,10 1968                          00300017
*                                                                       00400017
*                                                                       00500017
* FUNCTION     THIS ROUTINE IS AN I/O APPENDAGE                         00600017
*                                                                       00700017
         SPACE 4                                                        00800017
         USING IGG019QB,WTBASE                                          00900017
         USING IHADCB,Y                                                 01000017
         USING IECKLCB0,LCBREG                                          01100017
         USING IECKPREF,FREG                                            01200017
         SPACE 4                                                        01300017
*********      REGISTERS DEFINITIONS    **********                      01400017
*                                                                       01500017
FREG     EQU   1                       BASE FOR BUFFER PREFIX           01600017
TREG     EQU   2                       PTR TO LAST CCW EXECUTED         01700017
*                                      ALSO BASE FOR IOB                01800017
Y        EQU   3                       BASE FOR DCB                     01900017
LCBREG   EQU   4                       BASE FOR LCB                     02000017
SPREG    EQU   5                       LINK REGISTER FROM QTAM LINE-END 02100017
LGREG    EQU   7                       WORK REGISTER                    02200017
TCREG    EQU   8                       WORK REGISTER                    02300017
QREG     EQU   9                       INTERNAL LINK REGISTER           02400017
WTBASE   EQU   10                      BASE FOR MODULE IGG019NI         02500017
EOSREG   EQU   11                      WORK REGISTER                    02600017
REGC     EQU   12                      WORK REGISTER                    02700017
Z        EQU   13                      BASE FOR MODULE IGG019NG         02800017
REGD     EQU   13                      WORK REGISTER FOR PCI APPENDAGE  02900017
SUPREG   EQU   14                      LINK REGISTER FROM I/O SUP.      03000017
LEBASE   EQU   15                      BASE FOR LINE-END QTAM           03100017
         EJECT                                                          03200017
*********      INTERNAL EQUIVALENCES  ********                          03300017
*                                                                       03400017
TIMOUT   EQU   X'01'                   TIME-OUT SENSE BIT               03500017
LSTDATA  EQU   X'02'                   LOST DATA BIT ON SENSE BYTE      03600017
DTCHK    EQU   X'08'                   DATA CHECK BIT ON SENSE BYTE     03700017
         SPACE 1                                                        03800017
CSW      EQU   64                                                       03900017
UEXC     EQU   X'01'                   UNIT EXECPTION BIT IN CSW        04000017
UCHK     EQU   X'02'                   UNIT CHECK BIT IN CSW            04100017
DE       EQU   X'04'                   DE BIT IN CSW                    04200017
CE       EQU   X'08'                   CE BIT IN CSW                    04300017
PCI      EQU   X'80'                   PCI FLAG IN CSW                  04400017
         SPACE 1                                                        04500017
HIO      EQU   X'08'                   HIO/WTTA FLAG IN LCBINCAM        04600017
EOTFLG   EQU   X'10'                   EOT/WTTA FLAG IN LCBINCAM        04700017
WRUFLG   EQU   X'40'                   WRU/WTTA FLAG IN LCBINCAM        04800017
DATAFLG  EQU   X'20'                   DATA FLAG                        04900017
RCVE     EQU   X'08'                   RECEIVE BIT IN LCBSTATUS         05000017
MSGNST   EQU   X'08'                   MESSAGE NOT SENT FLAG            05100017
TRANS    EQU   X'80'                   TRANSMISSION ERROR FLAG          05200017
         SPACE 1                                                        05300017
CCWTP    EQU   5                       DISPLACEMENT FOR CCW TP CODE     05400017
WRITE    EQU   X'01'                   WRITE COMMAND CODE               05500017
READ     EQU   X'02'                   READ COMMAND CODE                05600017
PRE      EQU   X'06'                   PREPARE COMMAND CODE             05700017
TIC      EQU   X'08'                   TIC COMMAND CODE                 05800017
BREAK    EQU   13                      BREAK CCW COMMAND CODE           05900017
RDI      EQU   1                       READ INITIAL OP CODE             06000017
TPPAD    EQU   4                       TP CODE FOR WRITE PAD            06100017
IDRESP   EQU   7                       IDENT EXCHANGE TP CODE           06200017
TPBREAK  EQU   10                      TP CODE FOR BREAK                06300017
TPTEXT   EQU   17                      TP CODE FOT TEXT TRANSFERT       06400017
         SPACE 1                                                        06500017
IAMYES   EQU   X'20'                   IAM=YES CODED IN DCB             06600017
*                                       (TERMINAL TO CPU WRU VALID)     06700017
WRUYES   EQU   X'40'                   WRU=YES CODED IN DCB             06800017
*                                       (CPU TO TERMINAL WRU VALID)     06900017
WRUEND   EQU   X'08'                   IDENT EXCHANGE REQUESTED AT THE  07000017
*                                      END OF OUTGOING MESSAGE          07100017
WRU      EQU   X'32'                   WRU CHARACTER                    07200017
CLEANUP  EQU   X'80'                   CLEANUP CODE  FOR LPS            07300017
LERTHDC  EQU   179                     DISPLACEMENT FOR THRESHOLD CTR   07400017
*                                      FOR DATA CHK(CONTENTION)         07500017
         EJECT                                                          07600017
*              *******************************************              07700017
*              *                                         *              07800017
*              *              INTERFACE                  *              07900017
*              *                WITH                     *              08000017
*              *     QTAM/PCI AND QTAM/CE APPENDAGES     *              08100017
*              *                                         *              08200017
*              *******************************************              08300017
         SPACE  4                                                       08400017
*              WHEN IGG019QB IS ENTERED ON CHANNEL END, CONTROL IS      08500017
*              IMMEDIATLY GIVEM TO THE QTAM/CE APPENDAGE TO PROCESS     08600017
*              A PROGRAM CHECK IF ANY, IF NO CONTROL IS RETURNED HERE   08700017
         SPACE  2                                                       08800017
*                                                                       08900017
*              TO HERE WHEN IGG019QB IS ENTERED FROM THE SUPERVISOR     09000017
*              THE ADDRESS OF THIS MODULE IS IN REGISTER 15             09100017
         B     16(15)                  ENTRY  FROM SUPERVISOR           09200017
         SPACE 1                                                        09300017
*              TO HERE WHEN IGG019QB IS REENTERED FROM QTAM/CE APPEND.  09400017
         B     ENTRYNG                 ENTRY  FROM IGG019NG             09500017
*                                                                       09600017
NGPCIAPP DC    A(0)                    ADDRESS OF QTAM/PCI APPEND. SET  09700017
*                                      AT OPEN TIME                     09800017
NGENDAPP DC    A(0)                    ADDRESS OF QTAM/CE APPENDAGE SET 09900017
*                                      AT OPEN TIME                     10000017
*                                                                       10100017
*                                                                       10200017
         LR    WTBASE,15               LOAD MODULE BASE                 10300017
         L     LEBASE,NGENDAPP          LOAD BASE FOR QTAM LINE-END     10400017
         BR    LEBASE             GO TO QTAM LINE END            A25045 10420021
         DROP  WTBASE                                            A25045 10440021
         SPACE  2                                                       10460021
         USING *,LEBASE                                          A25045 10480021
*        ENTER HERE FOR PCI ON WTTA LINES                        A25045 10500021
         SPACE 2                                                        10520021
         L     WTBASE,QBMOD       ESTABLISH ADDRESSABILITY       A25045 10540021
         DROP  LEBASE                                                   10560021
         USING IGG019QB,WTBASE                                   A25045 10580021
         CLC   68(2,0),STATUS        IS PCI ALONE                  00PS 10630017
         BE    NEWBUF                YES,GO TO QTAM-PCI            00PS 10660017
         EJECT                                                          10700017
*              *********************************************            10800017
*              *                                           *            10900017
*              *             PCI APPENDAGE                 *            11000017
*              *                                           *            11100017
*              *********************************************            11200017
         SPACE 3                                                        11300017
*     1- IF THE INTERRUPTED CCW IS A WRITE CCW,OR A READ CCW WITH A     11400017
*        RESIDUAL COUNT DIFFERENT FROM THE INITIAL COUNT, CONTROL IS    11500017
*        GIVEN TO THE NORMAL QTAM/PCI APPENDAGE                         11600017
         SPACE 2                                                        11700017
*     2- IF THE INTERRUPTED CCW IS A BTAM READ CCW WITH A RESIDUAL      11800017
*        COUNT EQUAL TO THE INITIAL COUNT, CONTROL IS RETURNED TO THE   11900017
*        SUPERVISOR                                                     12000017
         SPACE 2                                                        12100017
*     3- IF THE INTERRUPTED CCW IS A QTAM READ CCW WITH A RESIDUAL      12200017
*        COUNT EQUAL TO THE INITIAL COUNT,THE LAST RECEIVED CHARACTER   12300017
*        IS ANALYZED:                                                   12400017
         SPACE 1                                                        12500017
*             - IF EOM,EOT OR WRU CHARACTER,THE CSW IS UPDATED WITH     12600017
*               THE CCW CORRESPONDING TO THE LAST FILLED BUFFER,AND     12700017
*               CONTROL IS RETURNED TO THE SUPERVISOR                   12800017
         SPACE 1                                                        12900017
*             - IF NOT EOM,EOT OR WRU CHARACTER, CONTROL IS GIVEN TO    13000017
*               THE NORMAL QTAM/PCI APPENDAGE.                          13100017
         SPACE 3                                                        13200017
         NI    CSW+5,255-PCI           SUPPRESS PCI FLAF                13300017
         LA    REGC,0(TREG)            GET IOB ADDRESS                  13400017
         SH    REGC,IOBADDR            BACK UP TO LCB                   13500017
         TM    LCBSTATE-LCB(REGC),X'08'   IS LINE SENDING               13600017
         BZ    NEWBUF                  YES,TAKE NORMAL PCI              13700017
         L     EOSREG,CSW              GET CCW ADDRESS                  13800017
         LA    EOSREG,0(EOSREG)        CLEAR FIRST BYTE                 13900017
         S     EOSREG,F8               RETRIEVE LAST EXECUTED CCW       14000017
         CLC   70(2,0),6(EOSREG)       CCW CNT EQU RESID CNT            14100017
         BNE   NEWBUF                  NO, TAKE NORMAL PCI              14200017
         LA    REGD,LCBCPA+24-LCBFLAG1(TREG) ASSUME READ CONTINUE       14300017
         CLI   LCBCPA+24-LCBFLAG1(TREG),READ IS IT A READ CONTINUE      14400017
         BE    *+8                     YES                              14500017
         LA    REGD,16(REGD)           NO,POINT ON ACCURATE CCW         14600017
         CR    REGD,EOSREG             IS IT THE INTERRUPTED CCW        14700017
         BCR   8,SUPREG                LEAVE PCI APPENDAGE              14800017
         L     REGD,LCBCLPCI-LCB-1(REGC) GET LAST USED BRB              14900017
         L     EOSREG,0(REGD)          GET ITS BUFFER                   15000017
         AH    EOSREG,6(REGD)          POINT AFTER BUFFER               15100017
         BCTR  EOSREG,0                BACKSPACE TO LAST CHARACTER      15200017
         L     REGD,LCBDCBPT-LCB(REGC) GET DCB ADDRESS                  15300017
         CLC   0(1,EOSREG),DCBWTEOM-IHADCB(REGD) IS IT EOM              15400017
         BE    HOLDBUF                 BRANCH IF YES                    15500017
         CLC   0(1,EOSREG),DCBWTEOT-IHADCB(REGD) IS IT EOT              15600017
         BE    HOLDBUF                 BRANCH IF YES                    15700017
         CLI   0(EOSREG),WRU           IS IT WRU                        15800017
         BNE   NEWBUF                  BRANCH IF NO                     15900017
HOLDBUF  XC    70(2),70                CLEAR RESIDUAL COUNT IN CSW      16000017
         L     REGD,LCBCLPCI-LCB-1(REGC) GET LAST USED BRB              16100017
         L     EOSREG,0(REGD)          POINT AT FIRST BYTE              16200017
         SH    EOSREG,TXTOFSET         POINT ON HEADER                  16300017
         CLI   MSTATUS-FBLOCK(EOSREG),2   IS IT THE FIRST BUFFER        16400017
         BNE   NOFIRST                                                  16500017
         LA    REGD,LCBCPA+24-LCB(REGC)  ASSUME READ CONTINUE           16600017
         CLI   LCBCPA+24-LCB(REGC),READ  IS IT A READ CONTINUE          16700017
         BE    *+8                     YES                              16800017
         LA    REGD,16(REGD)           NO,POINT ON ACCURATE CCW         16900017
NOFIRST  AL    REGD,F8                 UPDATE FOR CSW                   17000017
         ST    REGD,CSW                AND UPDATE IT                    17100017
         BR    SUPREG                  LEAVE PCI APPENDAGE              17200017
NEWBUF   L     LEBASE,NGPCIAPP         GET PCI APPENDAGE ADDRESS        17300017
         BR    LEBASE                  GO TO PCI APPEND.                17400017
         EJECT                                                          17500017
*              *********************************************            17600017
*              *                                           *            17700017
*              *          NORMAL CHANNEL END APPENDAGE     *            17800017
*              *                                           *            17900017
*              *       ABNORMAL CHANNEL END APPENDAGE      *            18000017
*              *                                           *            18100017
*              *********************************************            18200017
         SPACE 3                                                        18300017
************** TO HERE WHEN IGG019QB IS ENTERED FROM IGG019NG   ******* 18400017
*                                                                       18500017
*                                                                       18600017
*              IF AN ABNORMAL CONDITION FOR WTTA, EXIT TO CALL ERP      18700017
*              MUST BE TAKEN                                            18800017
         SPACE 3                                                        18900017
ENTRYNG  EQU   *                                                        19000017
         LA    TREG,0(TREG)            CLEAR THE FIRST BYTE             19100017
         L     Y,LCBDCBPT              SET UP BASE FOR DCB              19200017
         TM    LCBCSW+5,X'20'          PROGRAMCHECK                     19300017
         BZ    WTTANPCK                NO                               19400017
         XC    LCBCSW+6(2),LCBCSW+6    ZERO COUNT IN CSW                19500017
         CLI   0(TREG),TIC             CAUSED BY TIC                    19600017
         BE    16(SPREG)               YES,RETURN TO QTAM LINE-END/     19700017
         TM    4(TREG),128             NO,IS THE CHAIN DATA FLAG ON     19800017
*                                      - IF NO TIS INDICATES THE LAST   19900017
*                                        SEGMENT OF AN OUTGOING MESSAGE 20000017
*                                        AND IGNORE THE PROGRAM CHECK   20100017
*                                      - IF YES RETURN TO QTAM LINE-END 20200017
         BZ    WTTANE                  IGNORE THE PROGRAM CHECK         20300017
         B     16(SPREG)               RETURN TO QTAM LINE-END          20400017
WTTANPCK EQU   *                                                        20500017
         CLI   LCBECBPT,X'48'          IS IT INTERRUPT FROM HIO         20600017
         BE    HIORTN                  BRANCH IF YES                    20700017
*                                      (STOPLINE OR CLOSEMC)            20800017
         CLI   LCBECBPT,X'7F'          CHECK FOR NORMAL COMPLETION      20900017
         BE    GOODCD                  YES,NORMAL                       21000017
         TM    LCBSTATE,X'08'          IS LINE RECEIVING                21100017
         BZ    POSTS                   NO,POST TO LPS                   21200017
         OI    MSTATUS,X'02'      SET BFR AS LAST                A25044 21210021
         OI    LCBINCAM,EOTFLG    SET EOT FLAG ON IN LCB         A25044 21220021
         OI    LCBERRST+1,TRANS   SET TRANSMISSION ERROR IN LCB  A25044 21230021
         CLI   0(TREG),PRE        IS ERROR ON PREPARE            A25044 21240021
         BE    POSTERR            IF YES, GO TO POST ERROR       A25044 21250021
         L     EOSREG,0(TREG)     GET DATA AREA ADDR             A25044 21260021
         LA    EOSREG,0(0,EOSREG) CLEAR HIGH ORDER BYTE          A25044 21270021
         AH    EOSREG,6(TREG)     POINT AFTER                    A25044 21280021
         SH    EOSREG,LCBCSW+6    LAST RECEIVED CHARACTER        A25044 21290021
         CLC   6(2,TREG),LCBCSW+6 INITIAL COUNT E0 RESIDUAL COUNTA25044 21300021
         BE    SUPCHAR            BRANCH IF YES                  A25044 21310021
         BCT   EOSREG,SUPCHAR     NO, BACK TO LAST RECEIVED CHAR A25044 21320021
*                                 TO OVERRIDE IT                 A25044 21330021
GOODCD   TM    LCBFLAG1,X'FB'          IS IT ABNORMAL APPENDAGE ENTRY   21400017
         BZ    WTTAP                   NO,NORMAL APPENDAGE              21500017
         TM    LCBCSW+5,X'1F'          ABNORMAL STATUS                  21600017
         BNZ   12(SPREG)               YES,CALL ERP                     21700017
         TM    LCBCSW+4,UCHK           UNIT CHECK                       21800017
         BZ    WTTAP                   NO,CONTINUE CHECKING             21900017
         TM    LCBSENSE,TIMOUT         TIME-OUT                         22000017
         BNO   WTTANT                  NO,CONTINUE CHECKING             22100017
         CLI   0(TREG),READ            TM-OUT ON READ                   22200017
         BE    WTTAP                   YES,THIS IS A NORMAL END         22300017
         B     12(SPREG)               NO,ABNORMAL END,CALL ERP         22400017
WTTANT   TM    LCBSENSE,DTCHK          DATA CHECK                       22500017
         BNO   WTTAND                  NO,CONTINUE CHECKING             22600017
         CLI   CCWTP(TREG),TPBREAK     IS IT A BREAK SEQUENCE           22700017
         BE    WRBRK0                  YES,CONTENTION                   22800017
         CLI   0(TREG),WRITE           DATA-CHK ON WRITE                22900017
         BE    CONT                    YES,CONTENTION                   23000017
         CLI   0(TREG),X'00'           IS IT AN INSERT CCW              23100017
         BE    CONT                    YES                              23200017
         B     12(SPREG)               NO,ABNORMAL CONDITION,CALL ERP   23300017
WTTAND   TM    LCBSENSE,LSTDATA        LOST DATA                        23400017
         BNO   12(SPREG)               NO,ABNORMAL END,CALL ERP         23500017
         CLI   0(TREG),READ             LOST DATA ON READ               23600017
         BNE   12(SPREG)               NO,ABNORMAL CONDITION,CALL ERP   23700017
WTTAP    TM    LCBCSW+4,UEXC           UNIT EXECPTION                   23800017
         BNO   WTTANE                  NO,CONTINUE CHECKING             23900017
         CLI   CCWTP(TREG),TPBREAK     IS IT A SEQUENCE BREAK           24000017
         BE    WRBRK0                  YES,CONTENTION                   24100017
         CLI   0(TREG),WRITE           UEXC ON WRITE                    24200017
         BE    CONT1                   YES,CONTENTION                   24300017
         CLI   0(TREG),X'00'           IS IT AN INSERT CCW              24400017
         BE    CONT1                   YES                              24500017
WTTANE   TM    LCBINCAM,HIO            WAS AN HIO STARTTED              24600017
         BO    HIORTN                  BRANCH IF YES                    24700017
         CLI   CCWTP(TREG),TPBREAK     IS IT A BREAK SEQUENCE           24800017
         BE    BREAKRTN                YES, RESTART CHANNEL PROGAM      24900017
         CLI   CCWTP(TREG),IDRESP      IS IT AN END OF ID EXCHANGE      25000017
         BE    IDRTN                   BRANCH IF YES                    25100017
         TM    LCBSTATE,X'08'          IS LINE SENDING                  25200017
         BZ    SENDRTN                 BRANCH IF YES                    25300017
         EJECT                                                          25400017
*                                                                       25500017
************   TO HERE WHEN THE LINE IS RECEIVING   *************       25600017
*                                                                       25700017
         SPACE  1                                                       25800017
*     1- IF THE LAST RECEIVED CHARACTER IS WRU AND IF IAM=YES IS WANTED 25900017
*             - IF BTAM READ CCW INTERRUPTED AN ID-EXCHANGE CHANNEL     26000017
*               PROGRAM IS STARTED                                      26100017
*             - IF QTAM READ CCW INTERRUPTED, THE BUFFER IS POSTED TO   26200017
*               THE INTERIM LPS QUEUE WITH THE WRUFLAG IN THE LCB       26300017
         SPACE  1                                                       26400017
*     2- IF THE LAST CHARACTER IS EOM OR EOT, IT IS OVERLAID BY X'1F',  26500017
*        IF NOT X'1F' IS ADDED IN THE BUFFER                            26600017
*         THE PURPOSE OF THIS IS TO ALLOW IN CASE OF MESSAGE SWITCHING  26700017
*        TO SEND THE STANDART EOT CHARACTER(X'37) WHICH IS THEN         26800017
*        PRODUCED THROUGH THE TRANSLATE TABLE                           26900017
         SPACE  1                                                       27000017
*     3- IF THE LINE IS INTERRUPTED BY AN HIO OPERATION:                27100017
*             - IF DATA WAS BEING RECEIVED, THE INTERRUPTED READ        27200017
*               INITIAL CHANNEL PROGRAM IS RESTARTED                    27300017
*             - IF NO DATA WAS BEING RECEIVED EOT/CLEANUP FLAGS    00PS 27400017
*               ARE SET IN LCB AND THE BUFFER IS POSTED TO LPS     00PS 27500017
         SPACE  2                                                       27600017
*                                                                       27700017
         L     EOSREG,0(TREG)          *                                27800017
         LA    EOSREG,0(EOSREG)         *                               27900017
         AH    EOSREG,6(TREG)            *POINT ON LAST REC. CHAR       28000017
         SH    EOSREG,LCBCSW+6          *                               28100017
         BCTR  EOSREG,0                *                                28200017
         CLC   6(2,TREG),LCBCSW+6      YES, IS THERE AT LEAST ONE CHAR  28300017
         BE    ADDONE                  NO,POINT ON FIRST CHARACTER      28400017
TESTCHAR CLI   0(EOSREG),WRU           IS IT A WRU CHARACTER            28500017
         BNE   TESTEOM                 BRANCH IF NO                     28600017
         TM    DCBBQFLG,IAMYES         IAM=YES IN DCB                   28700017
         BO    WRURTN                  YES                              28800017
TESTEOM  CLC   0(1,EOSREG),DCBWTEOM    IS IT AN EOM CHARACTER           28900017
         BE    SUPCHAR                 YES,SUPPRESS IT                  29000017
         CLC   0(1,EOSREG),DCBWTEOT    IS IT AN EOT CHARACTER           29100017
         BE    SUPCHAR-4               YES,SUPPRESS IT                  29200017
         CLI   0(EOSREG),WRU           IS IT WRU                        29300017
         BE    SUPCHAR                 YES,SUPPRESS IT                  29400017
ADDONE   OC    LCBCSW+6(2),LCBCSW+6  RESIDUAL COUNT EQ TO ZERO   A25044 29450021
         BZ    SUPCHAR            BRANCH IF YES                  A25044 29500021
         LA    EOSREG,1(0,EOSREG)  SKIP TO NEXT CHARACTER        A25044 29550021
         LH    TCREG,LCBCSW+6          PICK UP REDIDUAL COUNT           29600017
         BCTR  TCREG,0                 REDUCE BY ONE                    29700017
         STH   TCREG,LCBCSW+6          AND RESRORE IT                   29800017
         TM    LCBCSW+4,UCHK           HAS UNIT CHECK OCCURED           29900017
         BNO   SUPCHAR                 BRANCH IF NO                     30000017
         TM    LCBSENSE,TIMOUT         IS THERE TIMOUT                  30100017
         BNO   SUPCHAR                 BRANCH IF NO                     30200017
         OI    LCBINCAM,EOTFLG         YES,SET EOT FLAG                 30300017
SUPCHAR  MVI   0(EOSREG),X'1F'         SET EOT IN BUFFER                30400017
         TM    LCBERCCW+1,DATAFLG      ARE DATA ALREADY RECEIVED        30500017
         BO    POST                    BRANCH IF YES                    30600017
         LA    TCREG,LCBCPA+24         GET ADDRESS OF CCW (READ CONT)   30700017
         CLI   LCBCECB,RDI             IS IT A READ INITIAL             30800017
         BNE   *+8                     NO                               30900017
         LA    TCREG,LCBCPA+40         GET ADDRESS OF CCW (READ INIT)   31000017
         CR    TCREG,TREG              IS QTAM CCW INTERRUPTED          31100017
         BNE   POST                    YES, POST BUFFER                 31200017
         L     LGREG,0(TREG)               COMPUTE                      31300017
         LA    LGREG,0(LGREG)          IF VALID DATA                    31400017
         CR    LGREG,EOSREG            IN THIS FIRST BUFFER             31500017
         BNE   POST                    .... YES ....                    31600017
POSTERR  OI    LCBSTATE,CLEANUP        SET CLEANUP CODE IN LCB          31700017
         OI    LCBINCAM,EOTFLG         SET EOT FLAG ON                  31800017
         OI    MSTATUS,X'30'           SET STATUS TO BYPASS HDR         31900017
         B     POST1                   BRANCH TO POST WITH CLEANUP CODE 32000017
*                                                                       32100017
*        TO HERE WHEN WRU SIGNAL IS RECEIVED                            32200017
*                                                                       32300017
WRURTN   LH    LGREG,LCBCSW+6          PICK UP RESIDUAL COUNT           32400017
         MVI   0(EOSREG),X'1F'         SET EOT IN BUFFER                32500017
         LA    TCREG,LCBCPA+24         GET ADDRESS OF CCW (READ CONT)   32600017
         CLI   LCBCECB,RDI             IS IT A READ INITIAL             32700017
         BNE   *+8                     NO                               32800017
         LA    TCREG,LCBCPA+40         GET ADDRESS OF CCW (READ INIT)   32900017
         CR    TCREG,TREG              IS QTAM CCW INTERRUPTED          33000017
         BE    WRU1                    NO                               33100017
         OI    LCBINCAM,WRUFLG         SET WRU FLAG                     33200017
         OI    LCBERCCW+1,DATAFLG      SET DATA FLAG                    33300017
         LA    LGREG,1(LGREG)          NO,ADD OME TO RESIDUAL COUNT     33400017
         STH   LGREG,LCBCSW+6          TO CONTINUE READING AT CORRECT   33500017
         B     POST                    POINT AND POST                   33600017
WRU1     LA    LGREG,1(LGREG)                                           33700017
         CH    LGREG,6(TREG)           AT LEAST ONE VALID DATA          33800017
         BE    WRU3                    NO                               33900017
         OI    LCBERCCW+1,DATAFLG      SET DATA FLAG                    34000017
         ST    EOSREG,0(TCREG)         UPDATE CCW DATA ADDRESS          34100017
         MVI   0(TCREG),READ           RESTORE OP CODE                  34200017
         STH   LGREG,6(TCREG)          UPDATE CCW COUNT                 34300017
WRU3     LA    TREG,LCBCPA             GET ID-EXCHANGE START ADDRESS    34400017
         NI    4(TCREG),X'F7'          SUPPRESS PCI FLAG                34500017
         B     8(SPREG)                RETURN TO SUPVR TO RESTART I/O   34600017
         EJECT                                                          34700017
*                                                                       34800017
************** TO HERE WHEN THE LINE WAS INTERRUPTED BY A HIO  *****    34900017
*                                                                       35000017
HIORTN   EQU   *                                                        35100017
         NI    LCBINCAM,X'F6'          CLEAR FLAGS FOR CORRECT RESTART  35200017
         CLI   0(TREG),PRE             IS PREPARE CCW INTERRUPTED       35300017
         BNE   HIO1                    BRANCH IF NO                     35400017
         CLI   LCBCSW+4,CE+DE+UEXC     TEST ENDING STATUS               35500017
         BNE   HIO4                    BRANCH IF NOT EQUAL              35600017
         B     POSTERR                                                  35700017
HIO1     CLI   0(TREG),READ            IS IT A READ CCW INTERRUPTED     35800017
         BNE   HIO4                    BRANCH IF NO                     35900017
         L     LGREG,0(TREG)           IF YES, SOME CHARS               36000017
         AH    LGREG,6(TREG)           ARE ALREADY SENT BY TERMINAL     36100017
         SH    LGREG,LCBCSW+6          UPDATE THE READ CCW              36200017
         ST    LGREG,0(TREG)           AND                              36300017
         MVC   6(2,TREG),LCBCSW+6      ITS DATA LENGTH                  36400017
HIO4     LA    TREG,LCBCPA+40          LOAD RESTART CHAN PROG ADDR      36500017
         B     8(SPREG)                RETURN TO SUPVR TO RESTART I/O   36600017
         EJECT                                                          36700017
**************   TO HERE WHEN END OF SEND OPERATION   **********        36800017
*                                                                       36900017
*        THE EOT FLAG IS TURNED ON IN THE LCB AND THE ACTION DEPENDS    37000017
*        ON WHETHER THE ID-EXCHANGE IS REQUESTED AT THE END OF          37100017
*        OUTGOING MESSAGES(WRU MACRO IN ENDSEND SUBGROUP)               37200017
         SPACE  1                                                       37300017
*             - IF REQUESTED, THE ID-EXCHANGE CHANNEL PROGRAM IS        37400017
*               STARTED AND THE LAST EMPTY BUFFER WILL BE POSTED TO     37500017
*               THE LPS QUEUE ON COMPLETION OF THIS ID-EXCHANGE         37600017
         SPACE  1                                                       37700017
*             - IF NOT REQUESTED, THE LAST EMPTY BUFFER IS POSTED TO    37800017
*               THE LPS QUEUE.                                          37900017
*                                                                       38000017
SENDRTN  LH    LGREG,MSEGSZE           GET SEGMENT SIZE                 38100017
         SH    LGREG,LCBCSW+6          AND                              38200017
         STH   LGREG,MSEGSZE           UPDATE IT                        38300017
         OI    LCBINCAM,EOTFLG         SET EOTFLAG ON                   38400017
         TM    DCBBQFLG,IAMYES+WRUEND  IDENT EXCHANGE REQUESTED         38500017
         BNO   POSTS                   IF NO BRANCH TO POST             38600017
         OI    LCBCPA+37,X'80'         TP CODE TO INDICATE ENDSEND      38700017
         LA    TREG,LCBCPA+24          LOAD ID EXCHNG START ADDR        38800017
         B     8(SPREG)                RETURN TO SUPVR TO RESTART I/O   38900017
         SPACE 3                                                        39000017
*                                                                       39100017
**************  TO HERE WHEN CONTENTION APPEARS. ***********            39200017
*                                                                       39300017
*                                                                       39400017
*     1- IF CONTENTION OCCURS ON WRITE CCW , THE THRESHOLD DATA CHECK   39500017
*        COUNTER IS CHECKED.                                            39600017
         SPACE 1                                                        39700017
*             - IF THE THRESHOLD IS REACHED EXIT TO THE ERP             39800017
         SPACE 1                                                        39900017
*             - IF THE THRESHOLD IS NOT REACHED, IT IS INCREMENTED BY   40000017
*               ONE AND A CHANNEL PROGRAM (WRITE BREAK + WRITE CRLF )   40100017
*               IS EXECUTED.ON COMPLETION OF THIS CHANNEL PROGRAM THE   40200017
*               INTERRUPTED WRITE CCW IS REINITIATED.                   40300017
         SPACE  2                                                       40400017
*     2- IF CONTENTION OCCURS ON THE WRITE BREAK CCW, THIS CHANNEL      40500017
*        PROGRAM IS REINITIATED AT LEAST FIFTEEN. AFTER  EXIT TO THE    40600017
*        ERP IS TAKEN                                                   40700017
         SPACE 2                                                        40800017
CONT     IC    LGREG,LERTHDC(LCBREG)   THRESHOLD CONTENTION COUNTER     40900017
         LA    LGREG,1(LGREG)          ADD ONE                          41000017
         STC   LGREG,LCBCPA+60                                          41100017
         CLC   LCBCPA+60,DCBKSTAT+1     HAS CONTENTION                  41200017
*                                      COUNTER REACHED THRESHOLD        41300017
         BH    12(SPREG)             YES,CALL ERP                  00PS 41400017
         CLI   CCWTP(TREG),TPTEXT      IS IT TEXT TRANSFERT             41500017
         BE    12(SPREG)               YES                              41600017
         STC   LGREG,LERTHDC(LCBREG)    STORE UPDATED CTR               41700017
CONT1    ST    TREG,LCBCPA+60          SAVE RESTART ADDRESS             41800017
*                                      THE SAVE QREQ IS THE SECOND      41900017
*                                      PART OF THE TIC CCW              42000017
         B     WRBRK                                                    42100017
WRBRK0   IC    LGREG,LCBCPA+60         PICK-UP BREAK COUNTER            42200017
         LA    LGREG,1(LGREG)          ADD ONE                          42300017
         STC   LGREG,LCBCPA+60         AND STORE                        42400017
         CLI   LCBCPA+60,X'0F'         IS THE LINE BROKEN               42500017
         BE    12(SPREG)               PROBABLY,CALL ERP                42600017
WRBRK    LA    TREG,BREAKCCW           LOAD ADDRESS OF BREAK CCW        42700017
         B     8(SPREG)                RETURN TO SUPVR TO RESTART I/O   42800017
BREAKRTN L     TREG,LCBCPA+60          GET SAVED RESTART ADDRESS        42900017
         LA    TREG,0(TREG)            SUPPREXS FIRST BYTE              43000017
         NI    4(TREG),255-X'08'       SUPPRESS PCI                     43100017
         MVI   0(TREG),WRITE           SET WRITE OP CODE                43200017
         B     8(SPREG)                RETURN TO SUPVR TO RESTART I/O   43300017
         EJECT                                                          43400017
************* TO HERE AT THE END OF IDENT EXCHANGE CHANNEL PROGRAM  *** 43500017
*                                                                       43600017
IDRTN    TM    LCBSTATE,X'08'          IS LINE RECEIVING                43700017
         BO    RCVID                   BRANCH IF YES                    43800017
         TM    LCBCPA+37,X'80'         IS IT THE MESSAGE END            43900017
         BO    SENDEND                 BRANCH IF YES                    44000017
         BAL   QREG,CHECKID            GO TO CHECK IDENT                44100017
         B     IDERR1                  ERROR RETURN                     44200017
         LA    TREG,LCBCPA+48          LOAD START ADDR OF WRITE         44300017
         B     8(SPREG)                RETURN TO SUPVR TO RESTART I/O   44400017
IDERR1   OI    LCBERRST+1,MSGNST+TRANS SET FLAGS IN LINE ERROR HW       44500017
         B     POSTS                                                    44600017
SENDEND  BAL   QREG,CHECKID            GO TO CHECK IDENT                44700017
         OI    LCBERRST+1,TRANS        INDICATE TRANSMISSION ERROR      44800017
         B     POSTS                   ID OK. POSTS BUFFER              44900017
RCVID    BAL   QREG,CHECKID            GO TO CHECK IDENT                45000017
         B     IDERR2                  ERROR RETURN                     45100017
         CLI   DCBWTEOM,WRU            WRU EQUAL TO EOM                 45200017
         BNE   RCVID1                  BRANCH IF NO                     45300017
         TM    LCBERCCW+1,DATAFLG      ARE DATA RECEIVED                45400017
         BO    POSTWRU                 IF YES, BRANCH TO POST           45500017
RCVID1   LA    TREG,LCBCPA+24          GET READ CCW (READ CONT)         45600017
         CLI   LCBCECB,RDI             IS IT READ INITIAL               45700017
         BNE   8(SPREG)                RETURN TO SUPVR TO RESTART I/O   45800017
         LA    TREG,LCBCPA+40          GET READ CCW (READ INIT)         45900017
         B     8(SPREG)                RETURN TO SUPVR TO RESTART I/O   46000017
IDERR2   OI    LCBINCAM,EOTFLG         SET EOT FLAG                     46100017
         OI    LCBERRST+1,TRANS        INDICATE TRANSMISSION ERROR      46200017
         TM    LCBDCBPT,DATAFLG        ARE DATA RECEIVED                46300017
         BO    POSTWRU                 BRANCH IF YES                    46400017
         OI    LCBSTATE,CLEANUP        SET CLEANUP CODE                 46500017
         OI    MSTATUS,X'30'           BFR STATUS TO BYPASS HDR RTN     46600017
POSTWRU  LH    TREG,LCBCPA+30          PIC-UP RESIDUAL COUT             46700017
         CLI   LCBCECB,RDI             IS IT A READ INITIAL             46800017
         BNE   *+8                     NO                               46900017
         LH    TREG,LCBCPA+46          PICK-UP C RRECT RE IDUAL COUNT   47000017
         BCTR  TREG,0                  SUBSTRACT ONE                    47100017
         STH   TREG,LCBCSW+6           AND UPDATE CSW                   47200017
         B     POST                    AND POST                         47300017
*                                                                       47400017
*        ROUTINE TO CHECK THE IDENTIFICATION SENT BY THE TERMINAL       47500017
*                                                                       47600017
CHECKID  TM    DCBBQFLG,WRUYES         IS TERMINAL INTERROGATED         47700017
         BNO   4(QREG)                 NO,IT IS OK                      47800017
         CLI   0(TREG),BREAK           IS IT A BREAK AFTER READ-ID      47900017
         BE    CHECKID1                YES                              48000017
         ST    TREG,LCBCPA+60          SAVE READ-ID CCW ADDRESS         48100017
         LA    TREG,BREAKID            LOAD BREAK CCW ADDRESS           48200017
         B     8(SPREG)                RETURN TO SUPVR TO RESTART I/O   48300017
CHECKID1 L     TREG,LCBCPA+60          RESTORE READ-ID CCW ADDRESS      48400017
         L     LGREG,0(TREG)           GET READ IDENT AREA ADDR         48500017
         LR    EOSREG,LGREG            *GET THE                         48600017
         LH    TCREG,6(TREG)           *TERMINAL ID ADDRESS             48700017
         SR    EOSREG,TCREG            *AND ITS LENGTH                  48800017
         BCTR  EOSREG,0                POINT TO BEGINNING OF ID-AREA    48900017
         BCTR  TCREG,0                 ASSEMBLE LENGTH                  49000017
         EX    TCREG,COMPID            EXECUTE COMPARE                  49100017
         BCR   7,QREG                  ERROR RETURN                     49200017
         EX    TCREG,ZEROID            CLEAR READ-ID AREA               49300017
         B     4(QREG)                 COMPARAISON OK                   49400017
COMPID   CLC   0(1,LGREG),0(EOSREG)    COMPARE READ ID WITH EXPECTED    49500017
ZEROID   XC    0(1,LGREG),0(LGREG)                                      49600017
         EJECT                                                          49700017
*                                                                       49800017
*************  RETURNS TO QTAM LINE-END  *************                  49900017
*                                                                       50000017
*        POST BUFFER TO..                                               50100017
*              - LPS QUEUE IF IT IS SENDING                             50200017
*              - INTERIM LPS QUEUE IF IT IS RECEIVING                   50300017
*                                                                       50400017
POST     LH    LGREG,MSEGSZE           UPDATE BUFFER                    50500017
         SH    LGREG,LCBCSW+6          SIZE WITH                        50600017
         STH   LGREG,MSEGSZE           RESIDUAL COUNT                   50700017
POST1    BR    SPREG                   POST TO INTERIM LPS QUEUE        50800017
POSTS    OI    LCBINCAM,EOTFLG         SET EOT FLAG FOR READ INITIAL    50900017
         B     4(SPREG)                POST TO LPS QUEUE                51000017
         SPACE 3                                                        51100017
*                                                                       51200017
*************  INTERNAL LITTERALS  ****************                     51300017
*                                                                       51400017
TXTOFSET DC    AL2(TXSTRT-FBLOCK)      DISPLACEMENT FOF BUFFER HEADER   51500017
IOBADDR  DC    AL2(LCBFLAG1-LCB)                                        51600017
CRLF     DC    X'02081F'               CR LF LTRS                       51700017
K8       DC    H'8'                                                     51800017
F8       DC    F'8'                                                     51900017
         CNOP  0,8                                                      52000017
BREAKCCW DC    X'0D000000600A0005'     **                               52100017
         DC    AL1(1)                   * CHAN PROG FOR CONTENTOIN      52200017
         DC    AL3(CRLF)                * WRITE BREAK +                 52300017
         DC    X'200A'                  *  WRITE CR LF                  52400017
         DC    H'3'                    **                               52500017
         SPACE  1                                                       52600017
BREAKID  DC    X'0D0000002007000A'     BREAK CCW FOR READ-ID            52700017
STATUS   DC    XL2'0080'             PCI ALONE                     00PS 52750017
         LTORG                                                          52800017
         ORG   IGG019QB+X'4DC'                                          52900017
QBMOD    DC    A(IGG019QB)                                              53000021
         EJECT                                                          53100017
         DCBD  DSORG=(QX),DEVD=WT                                       53200017
         EJECT                                                          53300017
         LCBD  QTAM=3                                                   53400017
         EJECT                                                          53500017
         PREFIXD                                                        53600017
         END                                                            53700017
