         TITLE ' IGG0203N  QTAM CLOSE LINE GROUP'                       00400013
*********************************************************************** 00800013
*                                                                     * 01200013
*NAME-  IGG0203N     CLOSE COMMUNICATIONS LINE GROUP                  * 01600013
*                                                                     * 02000013
*STATUS-  CHANGE LEVEL 000                                 OS QTAM I  * 02400013
*                                                                     * 02800013
*FUNCTION-  IGG0203N IS ENTERED FROM THE SYSTEM CLOSE ROUTINE.  THE   * 03200013
*   ADDRESS OF THE CURRENT DCB BEING CLOSED IS IN REGISTER 8 ON ENTRY.* 03600013
*   FROM THIS DCB AND ITS ASSOCIATED DEB, THE STARTING ADDRESS AND    * 04000013
*   LENGTH OF THE LCB IS CALCULATED AND A FREEMAIN RELEASES THAT      * 04400013
*   AREA IN CORE.  THE LCB AND IOB POINTERS AND STATUS BYTES ARE      * 04800013
*   CLEARED IN THE DCB.  COMPLETION OF THIS ROUTINE IS INDICATED IN   * 05200013
*   THE WHERE-TO-GO TABLE BY PLACING ZEROES OVER THE ADDRESS OF       * 05600013
*   THIS ROUTINE.  IF THE ROUTINE IS TO BE USED AGAIN FOR ANOTHER     * 06000013
*   DCB, RETURN IS TO THE BEGINNING OF THE ROUTINE.  THE NORMAL EXIT  * 06400013
*   IS TO THE NEXT ROUTINE IN THE WHERE-TO-GO TABLE VIA AN XCTL.      * 06800013
*                                                                     * 07200013
*ENTRY POINTS-  IGG0203N - ENTRY IS MADE HERE FROM THE SYSTEM CLOSE   * 07600013
*   ROUTINE.                                                          * 08000013
*                                                                     * 08400013
*INPUT-                                                               * 08800013
*   REGISTER  7- CURRENT ENTRY IN THE PARAMETER LIST (POINTS TO       * 09200013
*        CURRENT DCB).                                                * 09600013
*   REGISTER  8- CURRENT ENTRY IN THE WHERE-TO-GO TABLE.              * 10000013
*                                                                     * 10400013
*OUTPUT-  REGISTERS 7 AND 8 WILL BE POSITIONED TO THE NEXT UNFINIS85D @ 10800013
*   ENTRY AND THE DCB WILL BE CLOSED.                                 * 11200013
*                                                                     * 11600013
*EXTERNAL ROUTINES-  N/A.                                             * 12000013
*                                                                     * 12400013
*EXITS-  NORMAL- THIS ROUTINE TERMINATES BY LOCATING THE NEXT NON-ZERO* 12800013
*   ENTRY IN THE WHERE-TO-GO TABLE AND EXECUTING AN XCTL TO THAT      * 13200013
*   ROUTINE.                                                          * 13600013
*        ERRORS- NONE.                                                * 14000013
*                                                                     * 14400013
*TABLES/WORK AREAS- THE WHERE-TO-GO TABLE CONTAINS THE ID AND TTR     * 14800013
*   OF THE MODULES NEEDED BY THE SYSTEM CLOSE ROUTINE.  THE DCB       * 15200013
*   PARAMETER LIST CONTAINS THE ADDRESS OF EACH DCB SPECIFIED IN THE  * 15600013
*   CLOSE MACRO.                                                      * 16000013
*                                                                     * 16400013
*ATTRIBUTES-  THIS ROUTINE IS EXECUTED IN THE TRANSIENT AREA AS       * 16800013
*   ENABLED, PRIVILEGED, AND REENTRANT.                               * 17200013
*                                                                     * 17600013
*********************************************************************** 18000013
***                                                                     18050021
***                                                                     18100021
*C428000,432000,488000                                        A62119    18150021
*A476500,480500,481000,496500,497000,648500,651992            A64648    18200021
IGG0203N CSECT                                                          18400013
RE       EQU    0             WORK/PARAMETER REG                        18800013
RF       EQU    1             WORK/PARAMETER REG                        19200013
RLCB     EQU    2             LCB ADDRESS                               19600013
RBASE    EQU    3             BASE REGISTER                             20000013
RDCB     EQU    4             DCB ADDRESS                               20400013
RPAR     EQU    5             START OF PARAMETER LIST                   20800013
RWTG     EQU    6             START FO WTG                              21200013
RPARC    EQU    7             CURRENT ENTRY IN PARAMETER LIST           21600013
RWTGC    EQU    8             CURRENT ENTRY IN WTG TABLE                22000013
RC       EQU     9            WORK REG                                  22400013
RUCB     EQU   10             CURRENT UCB ADDRESS                       22800013
RDEB     EQU   11             DEB ADDRESS                               23200013
RB       EQU   12             WORK REG                                  23600013
RTIOT    EQU     13           TIOT ADDRESS                              24000013
RD       EQU   14             WORK/PARAMETER REG                        24400013
RJ       EQU   15             WORK/PARAMETER REG                        24800013
RCORE    EQU   4                                                        25200013
CVT      EQU   16                                                       25600013
PURGE    EQU   16                                                       26000013
IOSAPP   EQU   20                                                       26400013
PROPTION EQU   160                                                      26800013
WAIT     EQU   1                                                        27200013
EXCP     EQU   0                                                        27600013
         USING IECKLCB0,RLCB                                            28000013
         USING IHADCB,RDCB                                              28400013
         USING IECTDEB+36,RDEB                                          28800013
         BALR  RBASE,0                                                  29200013
         USING *,RBASE                                                  29600013
*                             REGISTER INITIALIZATION FOR               30000013
*                             DEB AND DCB.                              30400013
*                                                                       30800013
         L     RDCB,0(0,RPARC)         ACCESS DCB BEING CLOSED          31200013
         L     RDEB,DCBDEBAD           ACCESS RELATED DEB               31600013
*                                                                       32000013
*  PURGE I/O ON ALL LINES                                               32400013
*                                                                       32800013
         L     RF,CVT             ADDRESS OF THE CVT                    33200013
         MVC   DEBAPPAD(3),IOSAPP+1(RF) CHANGE TO IOS APPENDAGES        33600013
         L     RF,4(RWTGC)                                              34000013
         ST    RDEB,0(RF)          DEB ADDRESS TO PARAMETER LIST        34400013
         MVI   0(RF),PROPTION      MOVE IN THE OPTION BYTE              34800013
         XC    4(8,RF),4(RF)         CLEAR FOR PURGE                    35200013
         SVC   PURGE               PURGE ALL I/O                        35600013
         LA    RE,1                LOAD THE WAIT COUNT                  36000013
         L     RF,4(RWTGC)         GET OPEN WORKAREA ADDRESS            36400013
         LA    RF,4(RF)            GET ECB ADDRESS                      36800013
         SVC   WAIT                WAIT FOR COMPLETION OF PURGE         37200013
*                                                                       37600013
*  DISABLE ALL LINES UNLESS TYPE 3 ADAPTER                              38000013
*                                                                       38400013
         SR    RC,RC               CLEAR FOR COUNT OF LINES             38800013
         L     RLCB,DEBUCBAD       ACCESS THE UCB ADDRESS               39200013
         TM    19(RLCB),X'70'      IS THIS A TYPE 3 ADAPTER             39600013
         BZ    TYPE3               BRANCH IF YES                        40000013
         L     RLCB,DCBLCBAD       ACCESS THE START OF THE LCB'S        40400013
         IC    RC,DEBNMEXT         GET THE NUMBER OF LINES              40800013
         SR    RTIOT,RTIOT         CLEAR FOR LCB SIZE                   41200013
         IC    RTIOT,DCBEIOBX      GET THE SIZE OF AN LCB               41600013
AGAIN    AR    RLCB,RTIOT          ACCESS 1ST (OR NEXT) LCB             42000013
         MVC   LCBCPA(8),DISABLE   SET UP DISABLE COMMAND               42400013
         XC    LCBCLCCW(4),LCBCLCCW  CLEAR FOR ECB                      42800021
         LA    RF,LCBCLCCW        GET ADDRESS OF ECB FOR IOS            43200021
         ST    RF,LCBECBPT         AND STORE IT IN THE LCB              43600013
         LA    RF,LCBCPA           GET ADDRESS OF CHANNEL PROGRAM AREA  44000013
         ST    RF,LCBSTART-1       GET STARTING ADDRESS                 44400013
         LA    RF,LCBFLAG1         ACCESS EXCP PARAMETER                44800013
         SVC   EXCP                DISABLE THE LINE                     45200013
         BCT   RC,AGAIN            LOOP IF MORE LINES                   45600013
*                                                                       46000013
*  WAIT FOR DISABLE COMMANDS TO COMPLETE                                46400013
*                                                                       46800013
         L     RLCB,DCBLCBAD       GET THE START OF THE LCB'S           47200013
         IC    RC,DEBNMEXT         GET NUMBER OF LINES                  47600013
         SR    RJ,RJ               CLEAR WORK REGISTER        A64648    47650021
NEXTWT   AR    RLCB,RTIOT          ACCESS 1ST (OR NEXT) LCB             48000013
         TM    LCBSIOCC,X'20'      SIO COND. CODE 2?          A64648    48050021
         BO    FLAGCC2              YES, GO SET INDICATOR     A64648    48100021
         LA    RE,1                SET UP THE WAIT COUNT                48400013
         LA    RF,LCBCLCCW        ACCESS THE ECB ADDRESS                48800021
         SVC   WAIT                WAIT FOR DISABLE                     49200013
         BCT   RC,NEXTWT           LOOP FOR NEXT WAIT                   49600013
         LTR   RJ,RJ        ANY WAITS SKIPPED FOR SIO CC 2?   A64648    49650021
         BNZ   SIOCC2       YES, GO TO PURGE AGAIN            A64648    49700021
TYPE3    SR    RF,RF                   CLEAR FOR NUMBER OF LCB'S        50000013
         IC    RF,DEBNMEXT             ACCESS COUNT OF LCB'S            50400013
         IC    RC,DCBEIOBX             ACCESS SIZE OF LCB               50800013
         L     RJ,16                   CVT ADDRESS                      51200013
         L     RJ,156(RJ)              ADDRESS OF TERMTBL               51600013
         L     RJ,4(RJ)                ADDRESS OF NG                    52000013
         L     RJ,0(RJ)                ADDRESS OF LPS QUEUE             52400013
         L     RJ,332(RJ)              ADD RESS OF TIME QUEUR           52800013
         LR    RUCB,RC                 CANNOT DESTROY LCB SIZE          53200013
         LR    RDEB,RF                 CANNOT DESTROY # OF LCB'S        53600013
         SSM   *+1                     GET DISABLED                     54000013
LOOP     LR    RB,RJ                   INITIALIZE TO START OF TIME Q    54400013
         L     RLCB,DCBLCBAD      ADDRESS OF THE LCB/IOB AREA           54800013
         LA    RLCB,0(RLCB,RUCB)  ADDRESS OF THIS LCB AND CLEAR THE     55200013
*                                 HIGH ORDER BYTE OF RLCB               55600013
LOOP2    LR    RTIOT,RB                SAVE LAST TIME ENTRY             56000013
         L     RB,12(RB)               NEXT ENTRY IN TIME Q             56400013
         LA    RB,0(RB)                CLEAR HIGH ORDER                 56800013
         CR    RB,RJ                   END OF TIME QUEUE                57200013
         BE    NOTIN                   YES                              57600013
         CR    RB,RLCB                 IS ENTRY THIS LCB                58000013
         BNE   LOOP2                   NO, CHECK REST OF Q              58400013
         MVC   13(3,RTIOT),13(RLCB)    REMOVE FROM TIME QUEUE           58800013
NOTIN    AR    RUCB,RC                 STEP TO NEXT LCB                 59200013
         BCT   RDEB,LOOP               CONTINUE FOR ALL LCB'S           59600013
         SSM   CONFF              ENABLE                                60000013
         L     RLCB,DCBLCBAD           ACCESS START OF LCB'S MINUS SIZE 60400013
         MR    RE,RC                   CALCULATE SIZE OF TOTAL LCB AREA 60800013
         LR    RE,RF                   BYTE COUNT TO REGISTER 0         61200013
         LA    RF,0(RC,RLCB)           CALCULATE START OF LCB'S         61600013
         O     RE,IOBPOOL              INSERT SUBPOOL CODE              62000013
         FREEMAIN   R,LV=(0),A=(1)                                      62400013
         XC    DCBLCBAD+1(2),DCBLCBAD+1  RESET LCB POINTER TO INDICATE  62800013
         MVI   DCBLCBAD+3,1               NO LCB AREA                   63200013
         XC    DCBIOBAD(3),DCBIOBAD     RESET IOB POINTER TO INDICATE   63600013
         MVI   DCBIOBAD+3,1               NO IOB AREA                   64000013
         XC    DCBIFLGS(1),DCBIFLGS    CLEAR STATUS BYTE                64400013
         XC    DCBEIOBX(1),DCBEIOBX    CLEAR SIZE OF LCB                64800013
         B     SETUPWTG                                       A64648    64850021
*****                                                                   64900021
*****                                                                   64950021
FLAGCC2  LA    RJ,1            SET ON SIO CC 2 FLAG           A64648    65000021
         BCT   RC,NEXTWT       RETURN, BYPASSING WAIT         A64648    65050021
SIOCC2   EQU   *               NOW PURGE AGAIN TO STOP RETRIES A64648   65100021
         L     RF,4(RWTGC)                                    A64648    65150021
         ST    RDEB,0(RF)      DEB ADDR TO PARAM. LIST        A64648    65160021
         MVI   0(RF),PROPTION   SET OPTION BYTE               A64648    65170021
         XC    4(8,RF),4(RF)   CLEAR FOR PURGE                A64648    65180021
         SVC   PURGE           PURGE REMAINING IO             A64648    65190021
         LA    RE,1            LOAD WAIT COUNT                 A64648   65192021
         L     RF,4(RWTGC)     OPEN WORKAREA ADDR             A64648    65194021
          LA   RF,4(RF)        GET ECB ADDR                   A64648    65196021
         SVC   WAIT                                           A64648    65198021
         B     TYPE3                                          A64648    65198421
*****                                                                   65198821
*****                                                                   65199221
SETUPWTG EQU   *                                                        65200013
         XC    0(4,RWTGC),0(RWTGC)      CLEAR ID TO INDICATE COMPLETION 65600013
*                                  OF EXECUTOR.                         66000013
         L     RCORE,4(RWTGC)                                           66400013
RELOOP   LA    RWTGC,WGOFF(0,RWTGC)     INCREMENT CURRENT WTG REGISTER. 66800013
         LA    RPARC,PLOFF(0,RPARC)     INCREMENT CURRENT PARAMETER     67200013
*                                  LIST REGISTER TO NEXT ENTRY.         67600013
         CLC   0(2,RWTGC),AMIDCNST      IF THE NEXT WTG ENTRY CALLS FOR 68000013
         BCR   8,RBASE             BTAM CLOSE, REEXECUTE THIS EXECUTOR. 68400013
         CLC   0(2,RWTGC),CLOSEIDL                                      68800013
         BL    RELOOP                                                   69200013
         CLC   0(2,RWTGC),CLOSEIDH                                      69600013
         BH    RELOOP                                                   70000013
         LR    RPARC,RPAR               REINITIALIZE CURRENT WTG REG    70400013
         LA    RWTGC,WAOFF(0,RWTG) AND CURRENT PARAMETER LIST REG.      70800013
ZCHECK   CLI   0(RWTGC),X'00'  TEST FOR 0 ENTRY                         71200013
         BNE   XCTLRTNE            IF NOT ZERO, GO TO TRANSFER CONTROL. 71600013
         LA    RWTGC,WGOFF(0,RWTGC) IF ZERO, GET NEXT ENTRY AND RETURN  72000013
         LA    RPARC,PLOFF(0,RPARC) TO ZCHECK.                          72400013
         B     ZCHECK                                                   72800013
*    *    *    *    *    *    *    *    *    *    *    *    *    *    * 73200013
XCTLRTNE EQU   *                                                        73600013
         USING FORECORE,RCORE                                           74000013
         LA    RJ,DXCCW12                                               74400013
         MVC   6(2,RWTG),0(RWTGC)  MOVE ID TO NAME FIELD                74800013
         MVC   14(3,RWTG),2(RWTGC)  MOVE TTR TO WTG TABLE               75200013
         XCTL  DE=(RWTG),SF=(E,(15))                                    75600013
WAOFF    EQU   32                       OFFSET OF FIRST WTG ENTRY FROM  76000013
*                                  START OF WTG.                        76400013
PLOFF    EQU   4                        OFFSET OF DCB ENTRIES.          76800013
WGOFF    EQU   8                        OFFSET OF WTG ENTRIES.          77200013
DISABLE  DC    X'2F000000'                                              77600013
         DC    X'20000001'                                              78000013
CLOSEIDL DC    C'0B'                                                    78400013
CLOSEIDH DC    C'0G'                                                    78800013
AMIDCNST DC    C'3N'          ID OF THIS MODULE                         79200013
CONFF    DC    X'FF'                                                    79600013
         DS    0F                                                       80000013
IOBPOOL  DC    X'FA000000'              SUBPOOL NUMBER OF 250 FOR IOB'S 80400013
         ORG   IGG0203N+1008                                            80800013
XCTLEND  DC    X'0000'                                                  81200013
         ORG   IGG0203N+1020                                            81600013
         DC    C'020'                                                   82000013
         DC    X'7E'                                                    82400013
         EJECT                                                          82800013
         DCBD  DSORG=CX                                                 83200013
         EJECT                                                          83600013
        IECTDEBX                                                        84000013
         EJECT                                                          84400013
         LCBD  QTAM=3                                                   84800013
         EJECT                                                          85200013
FORECORE DSECT                                                          85600013
         IECDSECT                                                       86000013
         END                                                            86400013
