         TITLE 'CLOSE DIRECT ACCESS MESSAGE QUEUES'                     00002021
*********************************************************************** 00004021
*                                                                     * 00006021
* STATUS- CHANGE LEVEL 20  JANUARY 1971                               * 00008021
*                                                                     * 00010021
* FUNCTION-  A TEST IS MADE TO DETERMINE IF CLOSE WAS ISSUED FOR      * 00012021
*    MESSAGE QUEUES DATA SET OR CHECKPOINT.  THE DD ENTRY IN THE TIOT * 00014021
*    (GOTTEN FROM DCB) IS COMPARED WITH 'TPCHKPNT', THE NAME THAT MUST* 00016021
*    BE USED FOR CHECKPOINT.  THE ADDRESS OF THE FIRST AVAILABLE BRB  * 00018021
*    IS PLACED IN DCBEODAD OF THE DISK TO SET BACK AS ASSEMBLED.  THE * 00020021
*    FIRST AVAILABLE BUFFER IS PLACED IN THE FIRST AVAILABLE BRB AS   * 00022021
*    ASSEMBLED SO THAT THE MCP CAN BE REOPENED WITHOUT RELOADING.     * 00024021
*         THE PROCESSING PROGRAM DEB CHAIN IS CHECKED FOR ANY REMAIN- * 00026021
*    ING OPEN PROCESSING PROGRAMS.  ALL OPEN PROCESSING PROGRAMS ARE  * 00028021
*    ABENDED WITH AN 0A6 COMPLETION CODE.  THE ADDRESS OF THE TERMINAL* 00030021
*    TABLE AT X'9C' INTO THE CVT IS ZEROED.                           * 00032021
*         IF CLOSE WAS ENTERED FOR A CANCEL OR ABEND,  THE READY QUEUE* 00034021
*    SEARCH IS BYPASSED AND EXIT IS MADE FROM THE ROUTINE.  IF THE    * 00036021
*    CLOSE WAS ENTERED FOR A CLOSEDOWN, THE READY QUEUE IS SEARCHED   * 00038021
*    FOR ANY ELEMENTS OTHER THAN THE DUMMY END ELEMENT.  IF A QCB IS  * 00040021
*    FOUND AND ITEMS ARE PRESENT IN THE CHAIN OF STCB'S, A TEST IS    * 00042021
*    MADE FOR A FULL STCB.  IF THE ITEM ON THE READY QUEUE OR IN THE  * 00044021
*    QCB'S CHAIN OF STCBS IS A FULL STCB (FROM QPOST OR QWAIT), THE   * 00046021
*    STCB IS REMOVED.  THE ECB AND TCB ADDRESSES ARE OBTAINED FOR THE * 00048021
*    OS POST ROUTINE.  THE ROUTINE LINKS TO THE POST ROUTINE TO POST  * 00050021
*    THE ECB COMPLETE.  WHEN THE DUMMY END ELEMENT IS REACHED ON THE  * 00052021
*    READY QUEUE, EXIT IS MADE TO THE NEXT NON ZERO ENTRY IN THE WTG  * 00054021
*    TABLE.                                                           * 00056021
*         IF THE CLOSE IS FOR CHECKPOINT, A TEST IS MADE OF THE CHECK-* 00058021
*    POINT FLAGS FOR CHECKPOINT ELEMENT ON THE DISK I/O QUEUE (X'F4').* 00060021
*    IF THE FLAGS INDICATE THE ELEMENT IS ON THE DISK I/O QUEUE, THE  * 00062021
*    QUEUE IS SEARCHED AND THE ELEMENT IS REMOVED.  IF THE CHECKPOINT * 00064021
*    FLAGS INDICATE THE ELEMENT IS ON THE TIME QUEUE (X'F1'), THE     * 00066021
*    ELEMENT IS REMOVED FROM THE QUEUE.                               * 00068021
*         IF A CONSTANT (WKAREA) IN IGG019NH INDICATES THAT THE CORE  * 00070021
*    OBTAINED FOR THE CHECKPOINT HAS NOT BEEN FREED, A FREEMAIN IS    * 00072021
*    ISSUED.  IF CHECK REQUEST IS BEING USED, ANY ELEMENT ON THE CHECK* 00074021
*    REQUEST QUEUE IS REMOVED.  THE TCB AND ECB ARE OBTAINED.  THE OS * 00076021
*    POST ROUTINE IS USED TO POST THE ECB COMPLETE.                   * 00078021
*         TO PREVENT FURTHER CHECKPOINTS THE CHECK POINT FLAGS ARE    * 00080021
*    ZEROED AND THE BRANCH TO DISPATCH INSTRUCTION IS MOVED INTO THE  * 00082021
*    CHECKPOINT SUBTASK.  THE APPENDAGE ADDRESS IN THE DEB IS CHANGED * 00084021
*    TO POINT TO IOS APPENDAGE.  THE ROUTINE LOOPS WAITING FOR ALL    * 00086021
*    CHECKPOINT DISK I/O TO COMPLETE.  IF THE CLOSE WAS ENTERED FOR   * 00088021
*    ABEND OR CANCEL, EXIT IS MADE TO THE NEXT NON-ZERO ENTRY IN THE  * 00090021
*    WTG TABLE.                                                       * 00092021
*         IF CLOSE WAS ENTERED FOR A CLOSEDOWN, A BRANCH IS TAKEN TO  * 00094021
*    THE CONVERT ROUTINE TO OBTAIN THE DISK ADDRESS FOR A TTR OF 1.   * 00096021
*    A CCW IS SET UP IN IGG019NH TO WRITE THE CONTROL RECORD TO       * 00098021
*    INDICATE THAT THERE WAS NORMAL COMPLETION..  AN EXCP IS ISSUED   * 00100021
*    TO WRITE THE RECORD.  IF, UPON COMPLETION, THERE WAS A PERMANENT * 00102021
*    I/O ERROR, THE ROUTINE IS ENDED ABNORMALLY WITH AN ERROR CODE OF * 00104021
*    0A4.  OTHERWISE, EXIT IS MADE TO THE NEXT NON-ZERO ENTRY IN THE  * 00106021
*    WTG TABLE.                                                       * 00108021
*                                                                     * 00110021
* ENTRY POINTS- ENTRY IS MADE TO THE FIRST BYTE OF THE MODULE BY AN   * 00112021
*         XCTL TO IGG0203O BY THE SYSTEM OPEN.                        * 00114021
*                                                                     * 00116021
* INPUT-                                                              * 00118021
*    5- ADDRESS OF THE FIRST ENTRY IN THE DCB PARAMETER LIST          * 00120021
*    6- ADDRESS OF THE BEGINNING OF THE WHERE-TO-GO TABLE             * 00122021
*    7- ADDRESS OF THE CURRENT ENTRY IN THE DCB PARAMETER LIST        * 00124021
*    8- ADDRESS OF THE CURRENT EXECUTOR'S ENTRY IN THE WHERE-TO-GO    * 00126021
*       TABLE.                                                        * 00128021
*                                                                     * 00130021
* OUTPUT-  REGISTERS 7 AND 8 WILL BE POSITIONED AT THE NEXT ENTRIES IN* 00132021
*    THE DCB PARAMETER LIST AND THE WHERE-TO-GO TABLE.                * 00134021
*                                                                     * 00136021
* EXTERNAL REFERENCES- THE CONVERT ROUTINE IS USED VIA THE ADDRESS    * 00138021
*    IN THE CVT.  THE OS POST ROUTINE IS USED.                        * 00140021
*                                                                     * 00142021
* EXITS, NORMAL- THIS ROUTINE EXITS VIA AN XCTL TO THE NEXT NON-ZERO  * 00144021
*    ENTRY IN THE WHERE-TO-GO TABLE.                                  * 00146021
*                                                                     * 00148021
* EXIT ERROR-  THIS ROUTINE EXITS VIA AN 0A4 ABEND IF THERE WAS A     * 00150021
*    PERMANENT I/O ERROR WHEN WRITING THE CHECKPOINT CONTROL RECORD.  * 00152021
*                                                                     * 00154021
* TABLES/WORK AREAS-                                                  * 00156021
*    1. DCB PARAMETER LIST CONTAINS THE ADDRESS OF EACH DCB SPECIFIED * 00158021
*    IN THE OPEN MACRO INSTRUCTION. 2. THE WHERE-TO-GO TABLE CONTAINS * 00160021
*    THE ID AND TTR OF THE ROUTINE NEEDED TO PROCESS THE DCB. 3. THE  * 00162021
*    WHERE-TO-GO TABLE POINTS TO A WORK AREA IN WHICH REGISTERS 9-15  * 00164021
*    ARE PASSED TO AND FROM THIS ROUTINE.                             * 00166021
*                                                                     * 00168021
* ATTRIBUTES-  RE-ENTRANT AND PRIVILEGED.                             * 00170021
*                                                                     * 00172021
* CHARACTER CODE DEPENDENCY- NONE                                     * 00174021
*                                                                     * 00176021
* NOTES- NONE                                                         * 00178021
*                                                                     * 00180021
*********************************************************************** 00182021
IGG0203O START                                                          00200013
*1202119000,192600-193200,438000-450000                           22753 00300018
*1990438000-450000                                                24951 00350018
* 193300,450000,614000                                           A26775 00370019
* 165000-167000,184500-185500                                    A28775 00380019
*A000020-001820                                                  S21016 00385021
* 0710008158600-162800,165100-166800,386200-387200               A36509 00390020
*D176000                                                         A46052 00395021
*A152200-153800                                                  A46057 00397021
*A152060-152120                                                  A57919 00398021
*                                                                       00400013
* REGISTER USAGE                                                        00600013
*                                                                       00800013
R0       EQU   0        WORK/PARAMETER REG                              01000013
R1       EQU   1        WORK/PARAMETER REG                              01200013
RDCB     EQU   2         CURRENT DCB                                    01400013
RBASE    EQU   3         BASE OF THIS ROUTINE                           01600013
RCORE    EQU   4         WORK AREA ADDR                                 01800013
RPAR     EQU   5         PARAMETER LIST ADDR                            02000013
RWTG     EQU   6        FRONT OF WHERE-TO-GO (WTG) TABLE                02200013
RPARC    EQU   7         CURRENT ENTRY IN PARAMETER LIST                02400013
RWTGC    EQU   8         CURRENT ENTRY IN WTG                           02600013
R9       EQU   9                                                        02800013
RDEB     EQU   11        DEB ADDR                                       03000013
RB       EQU   12        WORK REG                                       03200013
RC       EQU   13        WORK REG                                       03400013
RL     EQU     14                                                       03600013
RJ       EQU   15        WORK/PARAMETER REG                             03800013
*                                                                       04000013
CVTTCBAD EQU   0                                                        04200013
EXCP     EQU   0                                                        04400013
LPS      EQU   0                                                        04600013
WAIT     EQU   1                                                        04800013
TTQUES   EQU   4                                                        05000013
TIOTAD   EQU   4                                                        05200013
TCBTIO   EQU   12                                                       05400013
CVTABLE  EQU   16                                                       05600013
IOSAPPAD EQU   20                                                       05800013
DEBAPPAD EQU   28                                                       06000013
CKQUE    EQU   28                                                       06200013
CONVERT  EQU   28                                                       06400013
DISK     EQU   36                                                       06600019
RSAVE    EQU   40                                                       06800013
POSTAD   EQU   152                                                      07000013
CVTMZ00  EQU   164                                               A36509 07100020
TIMEPT   EQU   332                                                      07200013
READY    EQU   X'50'                                                    07400013
DUMMY    EQU   X'55'                                                    07600013
CKPTAD   EQU   304                                                      07800013
         USING FORECORE,RCORE                                           08000013
         USING IHADCB,RDCB                                              08200013
         USING IGG019NH,RDEB                                            08400013
         BALR  RBASE,0                                                  08600013
         USING *,RBASE                                                  08800013
         L     RDCB,0(0,RPARC)         ACCESS DCB FOR DASD              09000013
         LA    RJ,1                                                     09200013
         ST    RJ,DCBIOBAD    RESET IOB FIELD                           09400013
         L     RDEB,DCBDEBAD       ADDRESS OF THE DEB                   09600013
         XC    8(4,RDEB),8(RDEB)   ZERO THE IRB POINTER                 09800013
         L     RC,CVTABLE(0,0)         ACCESS ADDRESS OF CVT            10000013
         L     RB,CVTTRMTB(0,RC)       ACCESS QTAM TERMINAL TABLE       10200013
         L     RB,TTQUES(0,RB)         ACCESS IMPLEMENTATION MODULE     10400013
*                                                                       10600013
* DETERMINE IF CLOSE IS FOR DASD MESSAGE QUEQE OR CHECKPOINT DATASET    10800013
*                                                                       11000013
         LR    RJ,RC               SAVE ADDRESS OF CVT                  11200013
         L     RJ,CVTTCBAD(RJ)    LOAD POINTER TO LIST OF TCBS          11400013
         L     RJ,4(RJ)            LOAD CURRENT TCB                     11600013
         LA    RJ,0(RJ)            CLEAR HIGH ORDER BYTE                11800013
         LR    R9,RJ               SAVE TCB ADDRESS               22753 11900018
         L     RJ,TCBTIO(RJ)      USE TIOT ADDRESS PLUS                 12000013
         AH    RJ,DCBTIOT          DCB TIOT OFFSET                      12200013
         CLC   TIOTAD(8,RJ),CKPTDDNM   LOAD TTR OF CONTROL RECORD       12400013
         BE    CLCKPT                   BRANCH IF CLOSE CHECKPOINT      12600013
*********************************************************************** 12800013
*                                                                       13000013
* THIS CODE IS FOR DASD MESSAGE QUEQU ONLY                              13200013
*                                                                       13400013
*********************************************************************** 13600013
         LR    RC,RB                   SAVE ADDRESS OG IGG019NG         14000013
         L     RB,0(0,RB)              ACCESS FIXED AREA                14200013
         MVC   DCBEODAD+1(3),49(RB)    SET ADDR OF 1ST AVAILABLE RE-   X14400013
               QUEST INTO DCB                                           14600013
         L     RJ,48(0,RB)             ACCESS FIRST REQUEST             14800013
         MVC   1(3,RJ),25(RB)          MOVE ADDR OF FIRST AVAILABLE    X15000013
               BUFFER INTO LINK FIELD IN FIRST AVAILABLE REQUEST        15200013
         TM    TCBFLAGS(R9),X'80'      IS MCP ABENDING?          A57919 15206021
         BO    NOEXITOK          YES, BYPASS STIMER              A57919 15212021
*                                                                A46057 15220021
*        PREVENT TIMER INTERRUPTS AFTER THIS POINT SINCE TERM   A46057  15240021
*        TABLE PTR IN CVT WILL BE GONE SHORTLY.  STIMER WITH    A46057  15260021
*        NO EXIT WILL DO THIS NICELY                            A46057  15280021
*                                                                A46057 15300021
         STIMER REAL,,BINTVL=BINTVL                             A46057  15320021
         B     NOEXITOK                                         A46057  15340021
BINTVL   DC    F'1'          SET INTERVAL FOR 0.01 SECS         A46057  15360021
NOEXITOK DS    0H            MOVE RIGHT ALONG                   A46057  15380021
*                                                                       15400013
* TERMINATE ANY PROCESSING TASKS WITH QTAM DCB'C OPENED                 15600013
         SSM   *+1                     DISABLE INTERRUPTS               15800013
         LA    RDCB,272(0,RB)      INITIALIZE FOR LOOP           A36509 15860020
ABNDLOOP TM    23(RDCB),3          ADDRESS ON FULL WORD BOUNDARY A36509 15920020
         BNZ   ENDABND             NO, DON'T ISSUE ABEND         A36509 15980020
         L     RDCB,20(RDCB)       GET NEXT DEB ADDRESS          A36509 16040020
         L     15,CVTABLE          GET CVT ADDRESS               A36509 16100020
         CL    RDCB,CVTMZ00(15)    IS ADDRESS IN CORE            A36509 16160020
         BNL   ENDABND             NO, DON'T ISSUE ABEND         A36509 16220020
         LTR   RDCB,RDCB           TEST FOR END                  A36509 16280020
         BZ    ENDABND             BRANCH IF NONE                       16400013
         L     1,0(0,RDCB)        PROCESSING TCB ADDR FROM DEB   A27848 16500019
         LA    0,0(1)              CLEAR HIGH ORDER BYTE         A36509 16510020
         TM    3(RDCB),3           ADDRESS ON FULL WORD BOUNDARY A36509 16520020
         BNZ   ABNDLOOP            NO, SKIP ABEND                A36509 16530020
         CL    0,CVTMZ00(15)       IS ADDRESS IN CORE            A36509 16540020
         BNL   ABNDLOOP            NO, DON'T ISSUE ABEND         A36509 16550020
         LA    1,4(1)              INITIALIZE FOR FIRST TIME     A36509 16560020
DEBLOOP  TM    7(1),3              ADDRESS ON FULL WORD BOUNDARY A36509 16570020
         BNZ   ABNDLOOP            NO, SKIP ABEND                A36509 16580020
         L     1,4(1)              GET NEXT DEB ADDRESS          A36509 16590020
         LA    1,0(1)              CLEAR HIGH ORDER BYTE         A36509 16600020
         CL    1,CVTMZ00(15)       IS ADDRESS IN CORE            A36509 16610020
         BNL   ABNDLOOP            NO, SKIP ABEND                A36509 16620020
         TM    24(1),X'0F'         IS THIS A DEB                 A36509 16630020
         BNO   ABNDLOOP            NO, SKIP ABEND                A36509 16640020
         LTR   1,1                 IS THIS END OF CHAIN          A36509 16650020
         BZ    ABNDLOOP            YES, DEB NOT FOUND, SKIP ABENDA36509 16660020
         CLR   1,RDCB              IS THIS THE DEB               A36509 16670020
         BNE   DEBLOOP             NO, LOOK AT NEXT DEB          A36509 16680020
         L     1,A6CODE                                                 16800013
         L     15,52(0,15)         ABTERM ROUTINE                       17200013
         BALR  14,15                                                    17400013
         B     ABNDLOOP                                                 17800013
         DS    0A                                                       18000013
A6CODE   DC    X'800A6000'         A6 ABEND CODE                        18200013
ENDABND  EQU   *                                                        18400013
         L     RDCB,CVTABLE(0,0)  GET ADDR OF CVT                A28775 18450019
         XC    CVTTRMTB(4,RDCB),CVTTRMTB(RDCB)  CLEAR QTAM ENTRY A28775 18500019
*                                               IN CVT           A28775 18550019
*                                                                       18600013
*      POST ALL WAITING STCB'S COMPLETE                                 18800013
         LR    RDCB,RC                 SAVE ADDRESS OF IGG019NG         19000013
         STM   5,15,20(RC)             SAVE REGISTERS USED BY THIS CODE 19200013
         TM    TCBFLAGS(R9),ABNORM ABNORMAL COMPLETION            22753 19260018
         BNZ   SETUPWTG           YES, BYPASS READY QUEUE SCAN   A22753 19330019
         LA    RPAR,READY-4(RC)        INITIALIZE FOR READY QUEUE SCAN  19400013
RDYLOOP  CLC   5(3,RPAR),DUMMY(RDCB)   END OF READY QUEUE               19600013
         BE    SETUPWTG                BRANCH IF YES                    19800013
         LR    RWTGC,RPAR              SAVE ADDRESS OF THIS ITEM        20000013
         L     RPAR,4(RPAR)            ADDRESS OF NEXT READY ITEM       20200013
         TM    0(RPAR),X'FF'           ITEM ELEMENT OR FULL STCB        20400013
         BC    8,ELEMSTCB              BRANCH IF YES                    20600013
*                                                                       20800013
*      ITEM IS A QCB SEARCH THE QTRAN CHAIN FOR FULL STCB'S             21000013
*                                                                       21200013
         LA    RPARC,4(RPAR)           INITIALIZE FOR QTRAN SEARCH      21400013
QTRNLOOP LR    RWTGC,RPARC             SAVE ADDRESS OF THIS ITEM        21600013
         L     RPARC,4(RPARC)          ADDRESS OF NEXT STCB IN CHAIN    21800013
         TM    4(RPARC),X'FF'          DUMMY END ITEM                   22000013
         BO    RDYLOOP                 BRANCH IF YES                    22200013
         TM    0(RPARC),X'FF'          IS THIS A FULL STCB              22400013
         BC    7,QTRNLOOP              BRANCH IF NOT FULL STCB          22600013
         LR    RB,RPARC                SET PARAMETER FOR POST SUBRT.    22800013
         BAL   RWTG,POST                                                23000013
*                                                                       23200013
         B     QTRNLOOP                TO LOOK AT THE NEXT STCB         23400013
*      ITEM IS AN ELEMENT OF FULL STCB DETERMINE WHICH                  23600013
*                                                                       23800013
ELEMSTCB CLC   1(3,RPAR),DUMMY(RDCB)   TEST FOR FULL STCB               24000013
         BNE   RDYLOOP                 BRANCH NOT FULL STCB             24200013
         LR    RB,RPAR                 PARAMETER FOR POST SUBRT.        24400013
         LA    RWTG,RDYLOOP            SET RETURN ADDRESS FOR POST SUB  24600013
*                                                                       24800013
*      POST COMPLECTION ON THE FULL STCB                                25000013
*                                                                       25200013
POST    LA    RDEB,24(RB)             LOAD ECB ADDRESS                  25400013
         MVC   5(3,RWTGC),5(RB)        REMOVE STCB FROM CHAIN           25600013
         TM    11(RB),X'80'            THIS STCB LINK TO THE TCB        25800013
         L     RB,28(RB)               NEXT SVRB OR TCB ADDRESS         26000013
         BC    8,POST+10               BRANCH NOT TCB ADDRESS LOADED    26200013
         L     15,CVTABLE              CVT ADDRESS                      26400013
         L     15,152(15)              ENTRY POINT TO O/S POST ROUTINE  26600013
         BALR  14,15                   TO THE O/S POST ROUTINE          26800013
         BR    RWTG                                                     27000013
*********************************************************************** 27200013
*                                                                       27400013
* THIS CODE IS FOR CHECKPOINT DATA SET ONLY                             27600013
*                                                                       27800013
*********************************************************************** 28000013
CLCKPT   L     RCORE,4(RWTGC)     LOAD ADDRESS OF THE WORK AREA         28200013
         L     RB,LPS(RB)          GET ADDRESS OF LPS QUEUE             28400013
         L     RDEB,CKPTAD(RB)     LOAD ADDRESS OF CHECKPOINT ROUTINE   28600013
*                                                                       28800013
*      REMOVE CHECK POINT ELEMENT FROM THE DISK QUEUE                   29000013
*                                                                       29200013
         SSM   *+1                DISABLE INTERRUPTS                    29400013
         TM    CKPTAD(RB),4       IS CHECK POINT ELEMENT IN THE DISK Q  29600013
         BZ    ENDDISK            BRANCH NOT IN THE DISK QUEUE          29800013
         LA    RL,DISK-4(RB)      ADDRESS OF THE DISK QUEUE MINUS FOUR  30000013
         LR    RC,RL                                                    30200013
NEXTDSK  L     RC,4(RC)           LOAD POINTER TO NEXT DISK ELEMENT     30400013
         CLI   4(RC),255          END OF DISK ELEMENT CHAIN             30600013
         BE    ENDDISK            BRANCH IF YES                         30800013
         CLC   5(3,RL),CKPTAD+1(RB) THIS ELEMENT CHECK POINT            31000013
         BE    REMDSK             BRANCH IF YES                         31200013
         LR    RL,RC              SAVE ADDRESS OF THIS ELEMENT          31400013
         B     NEXTDSK                                                  31600013
REMDSK   MVC   5(3,RL),5(RC)      REMOVE CHECK POINT ELEMENT            31800013
*                                                                       32000013
*      REMOVE THE CHECK POINT ELEMENT FROM THE TIME QUEUE               32200013
*                                                                       32400013
ENDDISK  TM    CKPTAD(RB),X'1F'   CHECK POINT ELEMENT IN THE TIME QUEUE 32600013
         BC    7,NOTTME           BRANCH NOT IN TIME QUEUE              32800013
         L     RL,TIMEPT(RB)      ADDRESS OF THE TIME QUEUE             33000013
         LR    RC,RL              INITIALIZE RC FOR FIRST PASS          33200013
NEXTTME  L     RC,12(RC)          ADDRESS OF NEXT ELEMENT IN THE TIME Q 33400013
         CLC   TIMEPT+1(3,RB),13(RL) END OF THE ELEMENT CHAIN           33600013
         BE    NOTTME             BRANCH IF YES                         33800013
         CLC   CKPTAD+1(3,RB),13(RL) THIS CHECK POINT ELEMENT           34000013
         BE    REMTIME            BRANCH IF YES                         34200013
         LR    RL,RC              SAVE ADDRESS OF THIS ELEMENT          34400013
         B     NEXTTME                                                  34600013
REMTIME  MVC   13(3,RL),13(RC)    REMOVE CHECK POINT ELEMENT FROM Q     34800013
*                                                                       35000013
*      FREE CORE GOTTEN FOR THE CHECK POINT RECORD                      35200013
*                                                                       35400013
NOTTME   L     R1,WKAREA          ADDRESS OF THE LAST GOTTEN CORE       35600013
         LTR   R1,R1              HAS THIS CORE BEEN FREED              35800013
         BC    12,NOCORE           BRANCH IF CORE HAS BEEN FREED        36000013
*                                       OR CHECKPOINT HAS NEVER BEEN    36200013
*                                       TAKEN                           36400013
         LA    R1,0(R1)           CLEAR THE HIGH ORDER BYTE             36600013
         L     R0,SUBPOOL         SIZE OF THE GOTTEN CORE               36800013
         FREEMAIN R,LV=(0),A=(1)                                        37000013
*                                                                       37200013
*      POST COMPLECTION ON WAITING PROCESSING PARTITIONS                37400013
*                                                                       37600013
NOCORE   TM    CKPTAD(RB),X'10'   ARE CKREQ MACRO BEING USED            37800013
         BZ    NOPART             BRANCH IF NOT USED                    38000013
         STM   9,2,RSAVE(RCORE)   SAVE REGISTERS                        38200013
         L     R9,CKQUE(RDEB)     LOAD ADDRESS OF QUEUE                 38400013
NEXTPART L     RDEB,4(R9)         ADDRESS OF NEXT PARTITION ELEMENT     38600013
         TM    4(R9),3             ADDRESS ON FULL WORD BOUNDARY A36509 38620020
         BNZ   ALLGONE             NO, DON'T ISSUE POST          A36509 38640020
         L     RJ,CVTABLE          GET CVT ADDRESS               A36509 38660020
         LA    RDEB,0(RDEB)        CLEAR HIGH ORDER BYTE         A36509 38680020
         CL    RDEB,CVTMZ00(RJ)    IS ADDRESS IN CORE            A36509 38700020
         BNL   ALLGONE             NO, SKIP POST                 A36509 38720020
         CLI   4(RDEB),255        DUMMY END ELEMENT                     38800013
         BE    ALLGONE            BRANCH IF YES                         39000013
         MVC   5(3,R9),5(RDEB)    REMOVE ELEMENT FROM WAITING QUEUE     39200013
         L     RJ,POSTAD(RJ)      ADDRESS OF THE SYSTEM POST ROUTINE    39600013
         L     RB,8(RDEB)         ADDRESS OF THE TCB FOR THE PARTITION  39800013
         BALR  RL,RJ              LINK TO THE POST ROUTINE              40000013
         LM    10,2,RSAVE+4(RCORE) RESTORE REGISTERS                    40200013
         B     NEXTPART                                                 40400013
ALLGONE  L     RDEB,RSAVE+8(RCORE) RESTORE REGISTERS                    40600013
*                                                                       40800013
*      PREVENT ANY FURTHER CHECK POINT ACTION                           41000013
*                                                                       41200013
NOPART   MVI   CKPTAD(RB),0       ZERO THE CHECK POINT FLAGS            41400013
         L     RC,8(RDEB)         ADDRESS OF THE CHECK POINT SUBTASK    41600013
         MVC   6(4,RC),DUMTASK    MOVE IN THE DUMMY BRANCH TO DISPATCH  41800013
         L     R1,DCBDEBAD        LOAD THE DEB ADDRESS                  42000013
         L     RC,CVTABLE         ADDRESS OF THE CVT                    42200013
         MVC   DEBAPPAD+1(3,R1),IOSAPPAD+1(RC) SET TO USE IOS APPENDAGE 42400013
         SSM   CONFF              ENABLE INTERRUPTS                     42600013
*                                                                       42800013
*      WAIT FOR ALL CHECK POINT DISK I/O TO COMPLETE                    43000013
*                                                                       43200013
         CLI   DISKIOB+4,0        HAS ALL CHECK POINT DISK I/O COMP.    43400013
         BE    *-4                BRANCH IF NOT COMPLETE                43600013
*                                                                 24951 43800018
*             TEST FOR NORMAL SYSTEM CLOSE DOWN                   24951 44000018
*                                                                 24951 44200018
         L     RC,CVTTCBAD(RC)    TCB LIST ADDRESS                24951 44400018
         L     RC,CUR(RC)         CURRENT TCB ADDRESS             24951 44600018
         TM    TCBFLAGS(RC),ABNORM  TEST FOR ABNORMAL COMPLETION  24951 44800018
         BNZ   CPEXIT             BRANCH IF ABNORMAL COMPLETION  A24951 45000019
*                                                                       45200013
*      CONVERT TTR TO ACTUAL DISK ADDRESS                               45400013
*                                                                       45600013
         STM   9,2,RSAVE(RCORE)    SAVE REGISTERS                       45800013
         LA    R0,256              LOAD ATTR OF 1 FOR CONVERT ROUTINE   46000013
         LA    RDCB,SEEKAD        RETURN MBBCCHHR ADDRESS               46200013
         L     RC,CVTABLE          GET ADDRESS OF CVT                   46400013
         L     RJ,CONVERT(RC)      LOAD ADDRESS OF THE CONVERT ROUTINE  46600013
         BALR  RL,RJ               BRANCH TO CONVERT                    46800013
         LM    9,2,RSAVE(RCORE)   RESTORE SAVED REGISTERS               47000013
*                                                                       47200013
* SET UP THE THIRD CCW IN CHECKPOINT IOB                                47400013
*                                                                       47600013
         MVI   CONTROL,0          FLAG AS SUCCESSFUL COMPLETION         47800013
         LA    RB,CONTROL          GET ADDRESS AREA TO BE WRITTEN FROM  48000013
         ST    RB,DISKRW           STORE ABOVE ADDRESS IN CCW           48200013
         MVI   DISKRW,5            STORE WRITE CODE IN CCW              48400013
         LA    RB,4               LOAD LENGTH OF THE WRITE              48600013
         ST    RB,DISKRW+4         STORE IN CCW                         48800013
*                                                                       49000013
*      ROUTINE TO ISSUE EXCP FOR READ OR WRITE ON THE DISK              49200013
*                                                                       49400013
EXCPRT   LA    1,DISKIOB          LOAD IOB PARAMETER FOR IOS            49600013
         SVC   EXCP                                                     49800013
*                                                                       50000013
*      NOW WAIT FOR COMPLECTION AND TEST FOR PERMANENT ERROR            50200013
*                                                                       50400013
         LA    0,1                 LOAD NUMBER OF EVENTS WAITED UPON    50600013
         LA    R1,DECB            LOAD WAIT PARAMETER                   50800013
         SVC   WAIT                                                     51000013
         CLI   DECB,X'7F'         TEST FOR PERMANENT I/O ERROR          51200013
         BE    CPEXIT             BRANCH TO EXIT ON NO ERROR            51400013
*                                                                       51600013
*      PERMANENT I/O ERROR SYSTEM ABEND                                 51800013
*                                                                       52000013
         L     R1,DISKERR         LOAD DISK ERROR ABEND CODE            52200013
         ABEND (1)                                                      52400013
*                                                                       52600013
*                                                                       52800013
*********************************************************************** 53000013
*                                                                       53200013
* THIS CODE IS COMMON                                                   53400013
*                                                                       53600013
*********************************************************************** 53800013
SETUPWTG EQU   *                                                        54000013
         LM    5,15,20(RDCB)           RELOAD SAVED REGISTERS           54200013
         SSM   READY-4(RDCB)           ENABLE INTERRUPTS                54400013
CPEXIT   XC    0(4,RWTGC),0(RWTGC) CLEAR ID TO INDICATE COMPLECTION     54600013
         L     RCORE,4(RWTGC)                                           54800013
RELOOP   LA    RWTGC,WGOFF(0,RWTGC)                                     55000013
         LA    RPARC,PLOFF(0,RPARC)                                     55200013
         CLC   0(2,RWTGC),AMIDCNST                                      55400013
         BCR   8,RBASE                                                  55600013
         CLC   0(2,RWTGC),CLOSEIDL                                      55800013
         BL    RELOOP                                                   56000013
         CLC   0(2,RWTGC),CLOSEIDH                                      56200013
         BH    RELOOP                                                   56400013
         LR    RPARC,RPAR          RE-INIT CURRENT WTG REG.             56600013
         LA    RWTGC,WAOFF(RWTG)   AND CURRENT PARAM LIST REG           56800013
ZCHECK   CLI   0(RWTGC),X'00'                                           57000013
         BNE   XCTLRTNE                                                 57200013
         LA    RWTGC,WGOFF(0,RWTGC)                                     57400013
         LA    RPARC,PLOFF(0,RPARC)                                     57600013
         B     ZCHECK                                                   57800013
*                                                                       58000013
XCTLRTNE EQU   *                                                        58200013
         LA    RJ,DXCCW12                                               58400013
         MVC   6(2,RWTG),0(RWTGC)                                       58600013
         MVC   14(3,RWTG),2(RWTGC)                                      58800013
         XCTL  DE=(RWTG),SF=(E,(15))                                    59000013
*                                                                       59200013
*                                                                       59400013
DUMTASK  BC    15,X'F6'(12)       BRANCH TO DISPATCH                    59600013
CONFF    DC    X'FF'                                                    59800013
HALFZERO DC    H'0'                                                     60000013
CKPTDDNM DC    C'TPCHKPNT'                                              60200013
         DS    0F                                                       60400013
DISKERR  DC    X'800A4000'                                              60600013
WAOFF    EQU   32                                                       60800013
PLOFF    EQU   4                                                        61000013
WGOFF    EQU   8                                                        61200013
ABNORM   EQU   X'B7'                                                    61400019
CUR      EQU   4                                                        61600013
TCBFLAGS EQU   29                                                       61800013
CVTTRMTB EQU   156                                                      62000013
CLOSEIDL DC    C'0B'                                                    62200013
CLOSEIDH DC    C'0G'                                                    62400013
AMIDCNST DC    C'3O'                                                    62600013
         DS    0F                                                       62800013
         ORG   IGG0203O+1008                                            63000013
XCTLEND  DC    X'0000'                                                  63200013
         DC    XL4'0'                                                   63400013
         ORG   IGG0203O+1020                                            63600013
         DC    C'020'                                                   63800013
         DC    X'7E'                                                    64000013
         EJECT                                                          64200013
         DCBD  DSORG=(CQ,DA)                                            64400013
         EJECT                                                          64600013
FORECORE DSECT                                                          64800013
         IECDSECT                                                       65000013
         EJECT                                                          65200013
IGG019NH DSECT                                                          65400013
CPBASE   EQU   9                                                        65600013
RCDFIX   EQU   8                                                        65800013
ADDRESS  EQU   196                                                      66000013
ERRORQ   EQU   200                                                      66200013
         USING *,CPBASE                                                 66400013
LCBSTATE DC    X'1D'              WRITE COUNT/KEY/DATA COMMAND          66600013
         DC    AL3(LCBSTATE)      WRITE ADDRESS                         66800013
         DC    X'80'              DATA CHAINING FLAG                    67000013
         DC    AL3(8)             LENGTH                                67200013
         DC    A(TERMTBL)         STCB ADDRESS                          67400013
         DC    A(0)               LINK FIELD WHEN IN THE TIME QUEUE     67600013
TERMSZ   DC    H'0'               STORAGE FOR THE TERMINAL TABLE SIZE   67800013
POLLOFF  DC    H'0'               POLLING LIST OFFSET IN THE CP RECORD  68000013
QOFF     DC    H'0'               QUEUE DATA OFFSET IN THE C/P RECORDS  68200013
LCBOFF   DC    H'0'               LCB DATA OFFSET IN THE C/P RECORDS    68400013
WKAREA   DC    A(0)               ADDRESS OF THE C/P RECORD IN CORE     68600013
TTRZ     DC    A(0)               START TTR FOR SECOND CHECKPOINT AREA  68800013
SUBPOOL  DC    X'FE000000'                                              69000013
OVERHEAD DC    H'0'               OVERHEAD VALVE FOR THE CK. PT. DEVICE 69200013
TRKLN    DC    H'0'               TRACK LENGTH OF THE CHECK PT. DEVICE  69400013
TIMEQ    DC    H'0'               USED BY TIME DELAY ROUTINE            69600013
CPINT    DC    H'0'               CHECK/POINT INTERVAL IN SECONDS       69800013
DECB     DC    A(0)               DECB TO BE USED FOR READ AND WRITE    70000013
DISKIOB  DC    X'42'              START OF THE DISK IOB                 70200013
         DC    AL3(0)                                                   70400013
         DC    A(DECB)            IOBDECB ADDRESS                       70600013
         DC    A(0)                                                     70800013
         DC    X'0F000000'                                              71000013
IOBCCWAD DC    A(DISKCCWS)        IOBCCW ADDRESS                        71200013
DISKDCB  DC    A(0)               ADDRESS OF THE DISK DCB               71400013
         DC    2A(0)                                                    71600013
SEEKAD   DC    2A(0)              DISK SEEK ADDRESS                     71800013
DISKCCWS DC    X'31'              SEARCH COMMAND                        72000013
         DC    AL3(SEEKAD+3)      SEARCH ADDRESS                        72200013
         DC    X'40000005'        FLAGS AND LENGTH                      72400013
DISKTIC  DC    X'08'              TIC COMMAND                           72600013
         DC    AL3(DISKCCWS)      TIC ADDRESS                           72800013
CONTROL  DC    H'0'               INPUT AREA FOR THE CONTROL RECORD     73000013
CPSIZE   DC    H'0'               SIZE OF THE CHECK POINT OUTPUT        73200013
DISKRW   DC    X'06'              READ DATA COMMAND                     73400013
         DC    AL3(CONTROL)       INPUT ADDRESS                         73600013
         DC    A(2)               LENGTH                                73800013
COUNTSW  DC    X'80'                                                    74000013
QUEUEST  DC    AL3(0)             START QUEUE AREA ADDRESS              74200013
TERMTBL  DC    A(0)               ADDRESS OF THE TERMINAL TABLE         74400013
CON3     DC    H'3'                                                     74600013
         END                                                            74800013
