         TITLE 'IGG0203P  QTAM CLOSE PROCESS QUEUE'                     00200013
*********************************************************************** 00400013
*                                                                     * 00600013
*NAME-  IGG0203P     QTAM CLOSE PROCESS QUEUE                         * 00800013
*                                                                     * 01000013
* STATUS - CHANGE LEVEL=20        JANUARY 1971                        * 01070021
*                                                                     * 01140021
* FUNCTION - IGG0203P IS ENTERED FROM THE SYSTEM CLOSE.  THE NAME OF  * 01210021
*    THE GET OR PUT MODULE (USING ID AT 124) IS MOVED TO A WORKAREA   * 01280021
*    IN THE DEB.  A DELETE IS ISSUED TO REMOVE THE MODULE LOADED BY   * 01350021
*    OPEN.                                                            * 01420021
*         IF THE MESSAGE CONTROL PROGRAM HAS ENDED, EXIT IS MADE FROM * 01490021
*    THE ROUTINE.  THE CHAIN OF QTAM DEBS IN IGG019NG IS SEARCHED FOR * 01560021
*    THE DEB OF THE DCB BEING CLOSED.  IF THE END OF THE CHAIN IS     * 01630021
*    REACHED, EXIT IS MADE FROM THE ROUTINE.  IF THE DCB IS OPENED    * 01700021
*    FOR INPUT, THE DEB IS REMOVED FROM THE CHAIN.                    * 01770021
*         IF MCP HAS BEEN CANCELLED OR ABENDED, EXIT IS MADE FROM THE * 01840021
*    ROUTINE.  IF CLOSE WAS ENTERED FOR CLOSE OF DCB OR CLOSEDOWN,    * 01910021
*    THE SEARCH OF THE QUEUES IS BYPASSED.  IF CLOSE WAS ENTERED FOR  * 01980021
*    ABEND OR CANCEL OF MPP, THE RB CHAIN OF THE TCB IS SEARCHED.     * 02050021
*    IF A SVRB FOR A QWAIT IS FOUND, THE QCB BEING WAITED FOR IS      * 02120021
*    OBTAINED FROM REGISTER 2 IN THE SAVE AREA OF THE SVRB. IF THE QCB* 02190021
*    IS ON THE READY QUEUE,QSAVE IS SET TO POINT TO ITSELF AND THE QCB* 02260021
*    IS REMOVED FROM THE READY QUEUE.  IF NOT ON THE READY QUEUE, THE * 02330021
*    SVRB IS REMOVED FROM THE STCB CHAIN.                             * 02400021
*         IF CHECK POINT IS IN THE SYSTEM, INDICATED BY THE ADDRESS   * 02470021
*    OF IGG019NH IN CPFLAG IN THE FIXED AREA OF IGG019NG, THE ADDRESS * 02540021
*    OF THE CHECK REQUEST QUEUE IS OBTAINED.  IF THE ELEMENT ON THE   * 02610021
*    CHECK REQUEST QUEUE IS FOR THE TASK BEING CLOSED, THE ELEMENT IS * 02680021
*    REMOVED FROM THE QUEUE.                                          * 02750021
*         IF THE DCB IS OPENED FOR INPUT, THE DEBOFLGS ARE ZEROED.    * 02820021
*    THE FLAG IN THE HIGH ORDER POSITION OF DCBEODAD IS RESET TO ZERO.* 02890021
*    IF THE BRB IN THE DEB IS ON THE ACTIVE BRB OR DISK I/O QUEUE, THE* 02960021
*    BRB IS REMOVED FROM THE QUEUE.                                   * 03030021
*         THE ADDRESS OF THE DASD PROCESS QUEUE IN THE BRB IS MADE    * 03100021
*    ADDRESSIBLE.  THE QCB ADDRESS IN THE FIRST WORD OF A BUFFER ON   * 03170021
*    THE MAIN STORAGE PROCESS QUEUE IS ZEROED.  THE LAST SEGMENT      * 03240021
*    GOTTEN IS OBTAINED FROM DCBSEGAD.  IF THE BUFFER HAS NOT BEEN    * 03310021
*    RETURNED, END OF MESSAGE IS SET IN THE BUFFER AND POSTED TO THE  * 03380021
*    RETURN BUFFER QUEUE.  QFAC OF THE DASD PROCESS QCB IS SET TO THE * 03450021
*    NEXT AVAILABLE DISK RECORD.  THE SUBTASK POINTER IN THE DASD     * 03520021
*    PROCESS QCB IS RESTORED TO THE DASD DESTINATION STCB.            * 03590021
*         THE BUFFERS ON THE M-S PROCESS QUEUE ARE POSTED TO THE      * 03660021
*    AVAILABLE BUFFER QUEUE.  THE MSDLINK FIELD OF THE LAST HEADER    * 03730021
*    MESSAGE IS SAVED IN QLINK OF THE DASD PROCESS QUEUE FOR USE WHEN * 03800021
*    THE DCB IS REOPENED.                                             * 03870021
*         THE TERMINAL TABLE IS SEARCHED FOR TERM ENTRIES WHOSE DCB   * 03940021
*    HAS BEEN OPENED.  THE LCB IS OBTAINED AND A QWAIT IS ISSUED ON   * 04010021
*    QATTACH TO INSURE THE LCB IS NOT ON THE READY QUEUE.  IF THE QCB * 04080021
*    IN THE LCBDESTQ FIELD IS THE SAME AS THE QCB FOR THE DCB BEING   * 04150021
*    CLOSED, CONVERSATIONAL MODE FOR THE LCB IS CONSIDERED.  A QWAIT  * 04220021
*    IS ISSUED TO OBTAIN A BUFFER FROM THE AVAILABLE BUFFER QUEUE.    * 04290021
*         INTERRUPTS ARE DISABLED, AND LCBSTATE IS TESTED.  IF        * 04360021
*    CLEANUP, CONVERSE, AND RECEIVE ARE NOT ON, THE BUFFER IS POSTED  * 04430021
*    BACK TO THE AVAILABLE BUFFER QUEUE.                              * 04500021
*         IF THE LINE IS IN CONVERSATIONAL MODE, THE BUFFER IS POSTED * 04570021
*    TO THE LPS QUEUE WITH HEADER, END OF MESSAGE SET IN MSTATUS; LCB * 04640021
*    ADDRESS IN MSLCB OF THE HEADER; AND RECALL, CLEANUP, INITIATE,   * 04710021
*    AND SEND SET IN LCBSTATE.  INTERRUPTS ARE ENABLED BEFORE THE     * 04780021
*    QPOST.                                                           * 04850021
*         WHEN THE END OF THE TERMINAL TABLE IS REACHED, THE OPEN FLAG* 04920021
*    IN THE DASD PROCESS QCB + 4 IS SET TO ZERO.  THE DCBSEGAD FIELD  * 04990021
*    OF THE DCB IS RE-INITIALIZED TO ONE.  IF THERE ARE MORE DEBS IN  * 05060021
*    THE CHAIN OF QTAM DEBS OR IF CLOSE WAS INITIATED BY ABEND, THE   * 05130021
*    NEXT DCB IS CLOSED.                                              * 05200021
*         IF THE DCB IS OPENED FOR OUTPUT OR THE CLOSE IS FOR A       * 05270021
*    GENERAL CLOSEDOWN, THE ID FOR IGG0203R IS SET IN THE WHERE-TO-GO * 05340021
*    TABLE FOR AN XCTL TO THE SECOND LOAD OF CLOSE.  EXIT IS MADE     * 05410021
*    TO THE NEXT NONZERO ENTRY IN THE WTG TABLE.                      * 05480021
*                                                                     * 05550021
* ENTRY POINTS - IGG0203P - ENTRY IS MADE HERE BY AN XCTL FROM THE    * 05620021
*   PREVIOUS ENTRY IN THE WHERE-TO-GO TABLE.                          * 06200013
*                                                                     * 06400013
*INPUT-                                                               * 06600013
*   REGISTER  7- CURRENT ENTRY IN THE DCB PARAMETER LIST (POINTS TO   * 06800013
*        CURRENT DCB).                                                * 07000013
*   REGISTER  8- CURRENT ENTRY IN THE WHERE-TO-GO TABLE.              * 07200013
*                                                                     * 07400013
*OUTPUT-  REGISTERS 7 AND 8 WILL BE POSITIONED TO THE NEXT UNFINISHED * 07600013
*   ENTRIES AND THE DEB'S FOR THE DCB'S IN THE PARAMETER LIST WILL BE * 07800013
*   REMOVED FROM THE CHAIN OF PROCESSING PROGRAM DEB'S.               * 08000013
*                                                                     * 08200013
*EXTERNAL ROUTINES-                                                   * 08400013
*        IGG065 - QWAIT MODULE IN IECKQQ01.                           * 08600013
*        IGG067 - QPOST MODULE IN IECKQQ01.                           * 08800013
*                                                                     * 09000013
*EXITS-                                                               * 09200013
*   NORMAL- THIS ROUTINE TERMINATES BY LOCATING THE NEXT NON-ZERO     * 09400013
*        ENTRY IN THE WHERE-TO-GO TABLE AND EXECUTING AN XCTL TO      * 09600013
*    THAT ROUTINE.  IF THE DCB IS OPENED FOR OUTPUT OR CLOSE WAS      * 09700021
*    ENTERED FOR A GENERAL CLOSEDOWN, EXIT IS MADE TO THE NEXT LOAD   * 09800021
*    OF CLOSE, IGG0203R.                                              * 09900021
*   ERROR- NONE.                                                      * 10000013
*                                                                     * 10200013
*TABLES/WORK AREAS-  THE WHERE-TO-GO TABLE CONTAINS THE ID AND TTR    * 10400013
*   OF THE MODULES NEEDED BY THE SYSTEM CLOSE ROUTINE.  THE DCB       * 10600013
*   PARAMETER LIST CONTAINS THE ADDRESS OF EACH DCB SPECIFIED IN THE  * 10800013
*   CLOSE MACRO OR AN INDICATION THAT A GENERAL CLOSE DOWN IS         * 11000013
*   REQUIRED.                                                         * 11200013
*                                                                     * 11400013
*ATTRIBUTES-  THIS ROUTINE IS EXECUTED IN THE TRANSIENT AREA AS       * 11600013
*   ENABLED, PRIVILEGED, AND REENTRANT.                               * 11800013
*                                                                     * 12000013
*********************************************************************** 12200013
IGG0203P START                                                          12400013
*1210188100-189000,746400-747600                                   5610 12500016
*81990188100-188200                                                00PS 12550016
*2330524000,548050-549650,555000,568000-698000,750500-751500,      8551 12560016
*2330780000-787000                                                 8551 12570016
*341248200,507000-509000,810600-811200                            18972 12580017
*3412449000                                                       19509 12590017
*83660190100-191200                                               20510 12595017
* 487000                                                          23172 12597018
* 202400-203600                                                  AIL/32 12598018
* 233000                                                         A26024 12599018
* 548020-548080                                                   M3131 12599518
* 167000,188400-188700,378000,471000-472000,492050-493900,       A29201 12599619
* 548360-548660,549250,709000,712000,746100-747920               A29201 12599719
* 198000,656000                                                  A29195 12599819
* 219000-223000                                                  A28775 12599919
* 218300-219500,370000,492050,492141,492500,601000               A31036 12649920
* 568000-572000                                                  A33027 12699920
*C228000                                                         A33039 12719920
*A004000-056200,097000-099000                                    S21016 12729921
*C220500-222500                                                  A43637 12735921
*A636000-656000                                                  A43637 12741921
RE       EQU   0                                                        12749920
RF       EQU   1                                                        12800013
FREG     EQU   1                                                        13000013
TREG     EQU   2                                                        13200013
RDCB     EQU   2                                                        13400013
RBASE    EQU   3                                                        13600013
RCORE    EQU   4                                                        13800013
RPAR     EQU   5                                                        14000013
RWTG     EQU   6                                                        14200013
RPARC    EQU   7                                                        14400013
RWTGC    EQU   8                                                        14600013
SAVE     EQU   9                                                        14800013
EREG     EQU   10                                                       15000013
RDEB     EQU   11                                                       15200013
RB       EQU   12                                                       15400013
RC       EQU   13                                                       15600013
RD       EQU   14                                                       15800013
RJ       EQU   15                                                       16000013
*                                                                       16200013
QWAIT    EQU   65                                                       16400013
QPOST    EQU   67                                                       16600013
QATTACH  EQU   72                                                A29201 16700019
*                                                                       16800013
         USING FORECORE,RCORE                                           17000013
         USING IHADCB,RDCB                                              17200013
         USING IECTDEB+36,RDEB                                          17400013
         USING IECKPREF,FREG                                            17600013
         BALR  RBASE,0                                                  17800013
         USING *,RBASE                                                  18000013
*                                                                       18200013
         L     RDCB,0(0,RPARC)         ACCESS DCB TO BE CLOSED          18400013
         L     RDEB,DCBDEBAD           ACCESS DEB                       18600013
         LA    RDEB,0(RDEB)            CLEAR THE HIGH ORDER BYTE        18800013
         LA    RB,112(RDEB)        POINT TO WORKAREA IN DEB        00PS 18810016
         MVC   0(6,RB),NAME        MOVE IN NAME OF MODULE        A29201 18840019
         MVC   6(2,RB),12(RB)      MOVE IN REMAINDER OF NAME     A29201 18870019
         DELETE EPLOC=(RB)    DELETE MODULE                        5610 18900016
         SSM   *+1                DISABLE INTERRUPTS                    19000013
         L     RB,CVTABLE              ACCESS CVT                       19200013
         L     RC,CVTTRMTB(0,RB)       ACCESS QTAM TERMINAL TABLE       19400013
         LTR   RC,RC               TEST FOR MESSAGE CONTROL YET ACTIVE  19600013
         BZ    SETUPWTG            BYPASS CLEANUP FUNCTION IF NOT       19800013
         L   EREG,TTQUES(0,RC)         ACCESS IMPLEMENTATION MODULE     20000013
         L     RC,0(0,EREG)            ACCESS FIXED AREA IN IMPLEM.MOD. 20200013
         LA    RD,272(0,RC)            ADDRESS OF MQ-DEB CHAIN-20       20400013
LOOP1    LR    RB,RD                   SAVE PREVIOUS DEB IN CHAIN       20600013
         L     RD,20(0,RB)             ACCESS NEXT DEB IN CHAIN         20800013
         CR    RDEB,RD                 IS IT FOR DCB BEING CLOSED       21000013
         BE    REMOVE                     YES                           21200013
         LTR   RD,RD                      NO. END OF CHAIN REACHED      21400013
         BNZ   LOOP1                      NO                            21600013
         B     SETUPWTG                EXIT DCB NOT OPENED              21800013
REMOVE   EQU   *                                                 A31036 21830020
         TM    DCBMACRF+1,X'40'    IS THIS AN OUTPUT DCB         A31036 21860020
         BO    SKIP                YES, DO NOT REMOVE IT         A31036 21890020
         MVC   20(4,RB),20(RD)     REMOVE DEB FROM MQ-DEB CHAIN  A31036 21920020
SKIP     EQU   *                                                 A31036 21950020
         L    RJ,288(0,RC)         GET MESSAGE CONTROL TCB ADDR  A43637 22050021
         TM    TCBFLGS(RJ),X'F7'  IS MCP CLOSING OR ABENDING     A43637 22150021
         BNZ   GETOUT             YES,BYPASS CLEANUP FUNCTION    A43637 22250021
*                                                                       22400013
* IF CLOSE IS INITIATED BY ABEND,REMOVE SVRB FROM QTAM CHAINS           22600013
         SSM   *+1                 DISABLE INTERRUPTIONS         A33039 22800020
         L     FREG,DEBNMSUB           LOAD TCB ADDRESS FROM THE DEB    23000013
         TM    TCBFLGS(FREG),X'B7' TEST CLOSE INITIATED BY ABEND A26024 23300018
         BZ    NOCHKPT             BRANCH IF NOT                        23400013
         L     TREG,TCBRBP(0,FREG) LOAD ADDR OF LAST RB                 23600013
RBLOOP   TM    XSTAB+1(TREG),X'80' TEST FOR LAST RB                     23800013
         BNZ   NORMCLOS            BRANCH IF NO QTAM SVRB FOUND         24000013
         LR    RJ,TREG             SAVE PREVIOUS RB ADDR                24200013
         L     TREG,XRBLNK-1(0,RJ) GET NEXT RB                          24400013
         CLI   XSTAB(RJ),X'C0'     TYPE II SVC                          24600013
         BNE   RBLOOP              NO                                   24800013
         CLI   XRBPSW+3(TREG),QWAIT                                     25000013
         BNE   RBLOOP              NOT QWAIT                            25200013
         MVI   XRBPSW+3(TREG),X'FF'  PREVENT REUSE ON NEXT ENTRY   00PS 25300015
         L     TREG,XRBREG+8(0,RJ) QCB ADDRESS FROM SAVE AREA           25400013
         LA    RB,12(0,RC)         ON ACTIVE BRB QUEUE                  25600013
         CL    RB,0(0,TREG)                                             25800013
         BE    RMVBRB              YES-REMOVE BRB                       26000013
         LA    RB,36(0,RC)         ON DISK QUEUE                        26200013
         CL    RB,0(0,TREG)                                             26400013
         BE    RMVBRB              YES-REMOVE BRB                       26600013
         CLI   0(TREG),3          IS QCB ON READY QUEUE                 26800013
         BE    RMVSTCB              YES-REMOVE IT                       27000013
         LA    RB,8(0,TREG)        OTHERWISE                            27200013
         CL    TREG,0(0,TREG)      HAS POST BEEM COMPLETED              27400013
         LA    TREG,0(0,RJ)        REMOVE SVRB FROM STCB CHAIN          27600013
         BNE   RMVBRB                                                   27800013
RMVSTCB  LA    RB,80(0,EREG)      OR READY QUEUE                        28000013
         MVC   73(3,EREG),77(EREG) RESET QSAVE FOR SUBSEQUENT QPOST     28200013
RMVBRB   L     RJ,0(0,RB)          GET ADDR OF FIRST ELEMENT OR STCB    28400013
         CLI   4(RJ),X'FF'         TEST FOR END                         28600013
         BE    NORMCLOS            ELEMENT NOT IN CHAIN                 28800013
         LA    RJ,0(0,RJ)          CLEAR HIGH ORDER BYTE                29000013
         CLR   RJ,TREG             IS THIS ELEMENT TO BE REMOVE         29200013
         BE    RELINK              BRANCH IF YES                        29400013
         LA    RB,4(0,RJ)          SET UP FOR NEXT ELEMENT              29600013
         B     RMVBRB              AND BRANCH TO TEST                   29800013
RELINK   MVC   1(3,RB),5(TREG)     REMOVE ELEMENT                       30000013
TCBRBP   EQU   0                                                        30200013
TCBFLGS  EQU   29                                                       30400013
XSTAB    EQU   10                                                       30600013
XRBPSW   EQU   16                                                       30800013
XRBLNK   EQU   29                                                       31000013
XRBREG   EQU   32                                                       31200013
NORMCLOS EQU   *                                                        31400013
* REMOVE CHECKPOINT REQUEST                                             31600013
         L     TREG,304(0,RC)      TEST FOR CHECKPOINT IN SYSTEM        31800013
         LTR   TREG,TREG                                                32000013
         BZ    NOCHKPT             BRANCH IF NO CHECKPOINT              32200013
         L     TREG,28(0,TREG)     GET ADDRESS OF CHECKPOINT QUEUE      32400013
CPLOOP   LR    RJ,TREG             SAVE PREVIOUS ELEMENT ADDR           32600013
         L     TREG,4(0,TREG)      GET NEXT ELEMENT                     32800013
         CLI   4(TREG),X'FF'                                            33000013
         BNE   NOCHKPT             BRANCH IF ELEMENT NOT FOUND          33200013
         CL    FREG,8(0,TREG)      IF NOT THIS TASK                     33400013
         BNE   CPLOOP              LOOK AT ENXT ELEMENT                 33600013
         MVC   5(3,RJ),5(TREG)     REMOVE ELEMENT FOR THIS TASK         33800013
NOCHKPT  EQU   *                                                        34000013
         L     RDCB,0(RPARC)           RELOAD DCB ADDRESS               36600013
         TM    DCBMACRF+1,X'40'        IS THIS OUTPUT DCB               36800013
         BO    NEXTLOAD            YES,NEXT LOAD HANDLES OUTPUT  A31036 37000020
*  THIS SECTION IS FOR AN INPUT DCB ONLY                                37200013
MQIN     EQU   *                                                        37400013
         MVI   8(RDEB),0           ZERO FIRST BYTE OF QCB ADDR.  A29201 37800019
         MVI   DCBEODAD,0         RESET FIRST TIME FLAGS FOR GET        38200013
* REMOVE BRB FROM ACTIVE BRB OR DISK QUEUE IF IT IS ON                  38400013
         LA    FREG,DEBNMSUB+48    ADDR OF BRB WITHIN DEB               38600013
         LA    RB,12(0,RC)         ON ACTIVE BRB QUEUE                  38800013
         CL    RB,0(0,FREG)                                             39000013
         BE    RMVBRB2             YES-REMOVE BRB                       39200013
         LA    RB,36(0,RC)         ON DISK QUEUE                        39400013
         CL    RB,0(0,FREG)                                             39600013
         BNE   NOREMOVE                                                 39800013
RMVBRB2  L     RJ,0(0,RB)          GET ADDR OF FIRST ELEMENT OR STCB    40000013
         CLI   4(RJ),X'FF'         TEST FOR END                         40200013
         BE    NOREMOVE            ELEMENT NOT IN CHAIN                 40400013
         LA    RJ,0(0,RJ)          CLEAR HIGH ORDER BYTE                40600013
         CLR   RJ,FREG             IS THIS ELEMENT TO BE REMOVE         40800013
         BE    RELINK2             BRANCH IF YES                        41000013
         LA    RB,4(0,RJ)          SET UP FOR NEXT ELEMENT              41200013
         B     RMVBRB2             AND BRANCH TO TEST                   41400013
RELINK2  MVC   1(3,RB),5(FREG)     REMOVE ELEMENT                       41600013
NOREMOVE EQU   *                                                        41800013
         NI    59(RDEB),X'FC'          SET ADDR TO START OF PROCESS Q   42000013
         L     RD,56(RDEB)             ADDRESS OF PROCESS Q ON DASD     42200013
* CLEAR QCB ADDRSSES FROM BUFFERS IN CORE PROCESS QUEUE                 42400013
         LA    FREG,DEBNMSUB+32    SET TO DUMMY FIRST ELEMENT           42600013
CLRQCB   XC    1(3,FREG),1(FREG)   CLEAR QCB ADDRESS                    42800013
         LR    RB,FREG             SAVE ADDR OF PREVIOUS BUFFRE         43000013
         L     FREG,4(0,RB)        GET ADDR OF NEXT BUFFER              43200013
         CLC   5(3,FREG),5(RB)     TEST FOR DUMMY LAST BUFFER           43400013
         BNE   CLRQCB              IF NOT RETURN TO CLEAR NEXT BUFFER   43600013
*  CONTENTS OF DCB REGISTER IS DESTROYED AFTER THIS POINT               43800013
         L     FREG,DCBSEGAD           ACCESS BUFFER TO POST            44000013
         LA    RB,DEBNMSUB+36          ADDR. OF CORE PROCESS QUEUE      44200013
         CL    RB,0(0,FREG)        TEST FOR BUFFER PREVIOUSLY RETURNED  44400013
         BNE   XPOST                                                    44600013
         L     TREG,280(RC)            GET RETURN QUEUE ADDRESS         44800013
         OI    MSTATUS,2          INDICATE MESSAGE COMPLETE       19509 44900017
         SVC   QPOST                   POST REMAINING BUFFER            45000013
XPOST    EQU   *                                                        45200013
         MVC  1(3,RD),17(RDEB)        SET ELEMENT CHAIN IN QCB TO      X45400013
               FIRST UNPROCESSED BUFFER                                 45600013
         MVC   9(3,RD),209(RC)     RESTORE SUBTASK POINTER IN PROC. QCB 45800013
*  THIS CODE PLACES UNPROCESSED HEADER SEGMENTS INTO DISK QUEUE AND UN- 46000013
*  PROCESSED TEXT SEGMENTS INTO AVAILABLE BUFFER QUEUE                  46200013
NEXTBFR  EQU   *                                                        46400013
         L     RF,36(RDEB)             FIRST UNPROC.BUFFER IN PROCESS Q 46600013
         MVC   37(3,RDEB),5(RF)        SET NEXT BUFFER AS FIRST         46800013
         C     RF,36(RDEB)             IS BFR REALLY DUMMY LAST ELEMENT 47000013
         BE    CONVERSE            YES, CHECK FOR LCB IN         A29201 47100019
*                                    CONVERSE MODE               A29201 47200019
         LA    TREG,24(0,RC)           NO,ACCESS AVAILABLE BUFFER Q     47400013
         TM    MSTATUS,X'01'           IS SEGMENT HEADER                47600013
         BO    TEXT                       NO,TEXT                       47800013
         MVC   17(3,RDEB),MSDLINK      SAVE NEXT DISK RECORD ADD.IN DEB 48600013
         MVC   5(3,RD),17(RDEB)   SET QLINK TO RETRANSMIT         23172 48700018
TEXT     EQU   *                                                        48800013
         SVC   QPOST                   POST UNPROCESSED BUFFER          49000013
         B     NEXTBFR                 REPEAT LOOP                      49200013
CONVERSE L     RB,CVTABLE          LOAD CVT ADDRESS              A31036 49205020
         L     RB,CVTTRMTB(0,RB)   LOAD TERMTBL ADDRESS            8551 49205720
         LR    RC,RB               INITIALIZE FOR FIRST TIME       8551 49206420
         SR    RD,RD              CLEAR WORK REGISTER              8551 49207120
TERMLOOP L     RF,8(RC)           LOAD QCB ADDRESS                 8551 49207820
         CLI   QRET(RF),X'68'     IS THIS A DESTINATION QUEUE      8551 49208520
         BNE   ENDTEST            NO SKIP THIS ENTRY               8551 49209220
         L     RDCB,QDCB-1(RF)     LOAD DCB ADDRESS                8551 49209920
         TM    DCBOFLGS,X'10'     IS DCB OPEN                      8551 49210620
         BNO   ENDTEST            NO,SKIP THIS ENTRY               8551 49211320
         IC    RD,QRLN(RF)         LOAD RELATIVE LINE NUM2ER     A29194 49212020
         L    RF,DCBDEBAD          LOAD DEB ADDRESS FROM DCB       8551 49212720
         SR    RJ,RJ               CLEAR WORK REGISTER             8551 49213420
         IC    RJ,DEBNMEXT-DEBNMSUB(RF) LOAD NUMBER OF EXTENTS   A31036 49214120
         CR    RD,RJ              IS RELATIVE LINE NO. GREATER THAN8551 49214820
*                                 NO. OF EXTENTS                   8551 49215520
         BH    ENDTEST            YES,SKIP THIS ENTRY              8551 49216220
         IC    RJ,DCBEIOBX        LOAD LCB SIZE                    8551 49216920
         MR    RD,RD              MULTIPLY RLN BY LCB SIZE         8551 49217620
         A     RJ,DCBLCBAD         GET ADDRESS OF CORRECT LCB      8551 49218320
         LA    TREG,QATTACH(0,EREG) GET ADDRESS OF QATTACH FOR   A29201 49219020
*                                    QWAIT                       A29201 49220019
         SVC   QWAIT               WAIT FOR PREVIOUS QPOSTS      A29201 49225019
         L     SAVE,LCBDESTQ-1-LCB(RJ) LOAD DESTINATION QUEUE    A29201 49230019
*                                    ADDRESS FROM SOURCE LCB     A29201 49235019
         LA    SAVE,0(SAVE)        CLEAR HIGH ORDER BYTE         A29201 49240019
         C     SAVE,8(RDEB)        IS DESTINATION THIS QUEUE     A29201 49245019
         BNE   ENDTEST             NO, CHECK NEXT LCB            A31036 49250020
         L     TREG,0(0,EREG)      GET FIXED AREA ADDRESS        A29201 49255019
         LA    TREG,24(0,TREG)     GET AVAILABLE BUFFER QUEUE    A29201 49260019
*                                    ADDRESS FOR QWAIT           A29201 49265019
         SVC   QWAIT               WAIT FOR BUFFER               A29201 49270019
         SSM   *+1                 DISABLE INTERRUPTS            A29201 49275019
         TM    LCBSTATE-LCB(RJ),X'A8' ARE CLEANUP, CONVERSE, AND A29201 49280019
*                                    RECEIVE SET IN SOURCE LCB   A29201 49285019
         BNO   POSTBFR             NO, RETURN BUFFER TO          A29201 49290019
*                                    AVAILABLE BUFFER QUEUE      A29201 49295019
         NI    LCBSTATE-LCB(RJ),X'EF' TURN OFF INITIATE TO       A29201 49300019
*                                    INDICATE MESSAGE PROCESSED  A29201 49305019
         CLI   LCBCPA-LCB(RJ),0    IS SOURCE READY TO SEND REPLY A29201 49310019
         BNE   POSTBFR             NO, RECALL IS NOT SET         A29201 49315019
         MVI   LCBSTATE-LCB(RJ),X'F6' SET RECALL, CLEANUP,       A29201 49320019
*                                    INITIATE, AND SEND TO       A29201 49325019
*                                    RE-ENTER CONVERSE ROUTINE   A29201 49330019
         L     TREG,0(0,EREG)      GET LPS QUEUE ADDRESS         A29201 49335019
         ST    RJ,MSLCB-1          PUT LCB ADDRESS IN BUFFER     A29201 49340019
         MVI   MSTATUS,2           SET HEADER EOM IN PREFIX      A29201 49345019
         MVI   FPRI,X'E0'          SET LOW PRIORITY IN BUFFER    A29201 49350019
POSTBFR  SSM   SSMCON              ENABLE INTERRUPTS             A29201 49355019
         SVC   QPOST               AND POST BUFFER TO AVAILABLE  A29201 49360019
*                                    BUFFER QUEUE OR LPS QUEUE   A29201 49365019
ENDTEST  IC    RD,8(RC)            LENGTH OF THIS ENTRY            8551 49367020
         AR    RC,RD              INCREMENT TO NEXT ENTRY          8551 49369020
         C     RC,0(RB)            COMPARE TO LAST ENTRY ADDRESS   8551 49371020
         BNH   TERMLOOP          BRANCH IF MORE ENTRIES TO INSPECT 8551 49373020
ZEROQCB  L     RB,8(RDEB)          GET QCB ADDRESS               A29201 49375019
         MVI   4(RB),0             FLAG QCB AS CLOSED            A29201 49380019
         L     RC,0(0,EREG)         ACCESS FIXED AREA IN NG        8551 55500016
         L     RDCB,0(RPARC)           RE-ESTABLISH DCB BASE REGISTER   55600013
ALSOCH1  LA    RJ,1                    RE-INITIALIZE TO INDICATE NO     55800013
         ST    RJ,DCBSEGAD                BUFFER LEFT OVER              56000013
         L     RD,292(0,RC)            ACCESS DEB FOR NEXT MQ-DCB       56200013
         LTR   RD,RD                   IS THERE ANY MQ-DCB LEFT         56400013
         BNZ   SETUPWTG                   YES,BRANCH                    56600013
         L     FREG,DEBTCBAD-1     LOAD TCB ADDRESS              A33027 56800020
         TM    TCBFLGS(FREG),X'B7' TEST CLOSE INITIATED BY ABEND A33027 57000020
         BNZ   SETUPWTG            BRANCH IF ABEND               A33027 57200020
         TM    288(RC),X'0F'      TEST IF THIS IS A GENERAL        8551 57600016
*                                  CLOSE DOWN PROCEDURE FOR QTAM   8551 58600016
         BO    SETUPWTG           NO SKIP STOP LINES IN NEXT LOAD  8551 59600016
NEXTLOAD EQU   *                                                 A31036 60100020
         MVC   0(5,RWTGC),LOAD2     MOVE IN LOAD 2 MODULE          8551 60600016
         L    RJ,4(RWTGC)                                          8551 61600016
         B     RELOOP             XCTL TO LOAD 2                   8551 62600016
GETOUT   TM    DCBMACRF,X'40'     IS THIS  AN INPUT DCB          A43637 63600021
         BO    SETUPWTG           BRANCH IF YES                  A43637 64600021
         MVC   20(4,RB),20(RD)    REMOVE DEB FROM MQ-DEB CHAIN   A43637 65600021
SETUPWTG EQU   *                                                        70000013
         XC    0(4,RWTGC),0(RWTGC) CLEAR ID TO INDICATE COMPLETION.     70200013
         L     RCORE,4(RWTGC)                                           70400013
RELOOP   LA    RWTGC,WGOFF(0,RWTGC)                                     70600013
         LA    RPARC,PLOFF(0,RPARC)                                     70800013
         XC    8(4,RDEB),8(RDEB)  ZERO FOR SYSTEM CLOSE          A29195 70860019
         SSM   SSMCON             ENABLE INTERRUPTS                     70920019
         CLC   0(2,RWTGC),AMIDCNST                                      71000013
         BCR   8,RBASE             BRANCH IF MORE DCB'S TO CLOSE A29201 71200019
         CLC   0(2,RWTGC),CLOSEIDL                                      71400013
         BL    RELOOP                                                   71600013
         CLC   0(2,RWTGC),CLOSEIDH                                      71800013
         BH    RELOOP                                                   72000013
         LR    RPARC,RPAR         REINITIAL CURRENT WTG REG             72200013
         LA    RWTGC,WAOFF(RWTG)   AND CURRENT PARAM LIST REG           72400013
ZCHECK   CLI   0(RWTGC),X'00'                                           72600013
         BNE   XCTLRTNE                                                 72800013
         LA    RWTGC,WGOFF(0,RWTGC)                                     73000013
         LA    RPARC,PLOFF(0,RPARC)                                     73200013
         B     ZCHECK                                                   73400013
XCTLRTNE EQU   *                                                        73600013
         LA    RJ,DXCCW12                                               73800013
         MVC   6(2,RWTG),0(RWTGC)                                       74000013
         MVC   14(3,RWTG),2(RWTGC)                                      74200013
         XCTL  DE=(RWTG),SF=(E,(15))                                    74600013
NAME     DC    C'IGG019'           FIRST 6 CHARACTERS OF NAME    A29201 74792019
SSMCON   DC    X'FF'                                                    74800013
*                                                                       75000013
QRLN     EQU   16                                                  8551 75050016
QDCB     EQU   17                                                  8551 75100016
QRET     EQU   8                                                   8551 75150016
WAOFF    EQU   32                                                       75200013
PLOFF    EQU   4                                                        75400013
WGOFF    EQU   8                                                        75600013
HDR      EQU   X'00'                                                    75800013
CVTABLE  EQU   16                                                       76000013
CVTTRMTB EQU   156                                                      76200013
CLOSEIDL DC    C'0B'                                                    76400013
CLOSEIDH DC    C'0G'                                                    76600013
AMIDCNST DC    C'3P'                                                    76800013
TTQUES   EQU   4                                                        77200013
AA       EQU   16                                                       77400013
DISK     EQU   36                                                       77600013
*                                                                       77800013
NENT     EQU   1                  ONE LOAD MODULE                  8551 77900016
LENGTH   EQU   NENT*6+6                                            8551 78000016
NODBWDS  EQU   (LENGTH+7)/8                                        8551 78100016
ORGIDTTR  EQU   1024-NODBWDS*8                                     8551 78200016
         ORG    IGG0203P+ORGIDTTR                                  8551 78300016
LOAD2    DC    C'3R'                                               8551 78400016
         DC    X'00000000'                                         8551 78500016
EDEND    DC    XL2'0'                                              8551 78600016
         CNOP  4,8                                                 8551 78700016
         ORG   IGG0203P+1020                                            78800013
         DC    C'020'                                                   79000013
         DC    X'7E'                                                    79200013
*                                                                       79400013
         EJECT                                                          79600013
         PREFIXD                                                        79800013
         EJECT                                                          80000013
         DCBD  DSORG=(MQ,CX)                                            80200013
         EJECT                                                          80400013
FORECORE DSECT                                                          80600013
         IECDSECT                                                       80800013
         IECTDEBX                                                       81000013
DEBDESTQ  EQU  68                                                 18972 81060017
         EJECT                                                          81120017
         LCBD  QTAM=3                                                   81200013
         END                                                            81400013
