         TITLE 'IEDAYB - TSO TIOC 3270 OUTPUT EDIT ROUTINE'             00030053
IEDAYB   CSECT                                                          00060053
         SPACE 3                                                        00100053
*  CHANGE ACTIVITY AS FOLLOWS:                                          00148653
******************** MICROFICHE FLAGS *********************** SUPT CODE 00180053
*A510600,694800,699600,715800                                   SA59194 00180153
*C004200-004800,655800-656400,658800-659400                     SA59194 00180253
*D493200-510000,513600-518400,700200,702000-703800,705600-714000SA59194 00180353
*C468000-468600,470400                                          SA60311 00180453
*A114900,150800-151000,151500,236000-236200,277400-277600,      SA60002 00180553
*A278500-278700,297300,308700                                   SA60002 00180653
*A312100-312300,324200-324400,334300-334700,352210-352250,      SA60002 00180753
*A401600-401800,409270-409690,464000-464200,465300,476600-476800SA60002 00180853
*A478500,512500-512850,519200-519400,557000-557200,622280-622600SA60002 00180953
*A659000,676660-676720,677450,688400-688600,693668-693700,      SA60002 00181053
*A794000-794200,798900,799400-799600,803700,883500              SA60002 00181153
*C259800,284400,294000-295200,296400,298800,300000-301200,427200SA60002 00181253
*C483600-486600,491400-510900,695000,697200-698400,826200-828000SA60002 00181353
*C837600,838800-839400                                          SA60002 00181453
*D216600,342600,695400-696000                                   SA60002 00181553
*A696500                                                        SA59517 00181653
*A047100,106500,135800-136000,212500-212700,221550,222800-223000SA61765 00181753
*A223900-224200,233100,244000,249200-249400,249670-250090,259500SA61765 00181853
*A266600-266800,312050,324460-324520,334350,348610-348670,      SA61765 00181953
*A352202-352206,371500-371700,381680-382080,390200-390400,      SA61765 00182053
*A456200-456500,512660-512680,                                  SA61765 00182153
*A653500-653900,794600-794800,865500,879900,888300              SA61765 00182253
*C009600-014400,022200-023400,048000-048600,129600,151000,221800SA61765 00182353
*C229800,277600,278400-279600,285600,286800,292200,             SA61765 00182453
*C316200,318000-319800,325200,327600-331200,333600-334200,      SA61765 00182553
*C334600,341400-343200,348800,                                  SA61765 00182653
*C352220,352240-352500,382800,807000,808800-809400,811200-811800SA61765 00182753
*D199800,236000-236200,260400,300600-301200,315000,             SA61765 00182853
*D322800-323400,324000,338400-339000                            SA61765 00182953
*C172500                                                        OY00522 00183053
*D877000                                                        OY00522 00183153
*A237500                                                        OX03936 00183253
*C493500                                                        SA67086 00183353
*C277500                                                        SA64364 00183453
*C304500                                                        SA68030 00183553
*A304500                                                        SA68024 00183653
*A689500                                                        SA68050 00183753
*A749400                                                        OY00488 00883756
*D139800-142200                                                 OY00488 01183756
         SPACE 2                                                        01620053
*********************************************************************** 01680053
*                                                                     * 01740053
*                                                                     * 01800053
*  TITLE:  IEDAYB                                                     * 01830053
*                                                                     * 01860053
*  MODULE NAME = IEDAYB                                               * 01920053
*                                                                     * 01980053
*  DESCRIPTIVE NAME = TSO TIOC 3270 OUTPUT EDIT ROUTINE               * 02040053
*                                                                     * 02100053
*  COPYRIGHT = 'NONE'                                                 * 02130053
*                                                                     * 02160053
*  STATUS:  CHANGE LEVEL 5                                            * 02220053
*                                                                     * 02280053
*                                                                     * 02340053
* FUNCTION --                                                         * 02400053
*    THE TIOC 3270 OUTPUT EDIT ROUTINE INSPECTS AND EDITS OUTPUT      * 02430053
*    MESSAGES CONTAINED IN TSO BUFFERS AND MSGGEN MESSAGES IN THE SCB.* 02460053
*    TSO MESSAGES ARE MOVED TO TCAM BUFFERS FOR OUTPUT.  MSGGEN       * 02520053
*    MESSAGES ARE MOVED TO THE SCBMBSSA AREA IN THE SCB.  THE EDIT    * 02580053
*    SCAN IS BASED ON THE RECEIVING AREA/BUFFER SIZE REMAINING, AND   * 02640053
*    THE SCREEN LINES REMAINING.  THE DISPLAY SCREEN SIZE IS SPECIFIED* 02700053
*    BY THE USER IN THE TERMINAL STATUS BLOCK (TSB) AND MAY BE        * 02730053
*    CHANGED BY THE TERMINAL COMMAND.  THE TCAM BUFFER SIZE MAY NOT   * 02760053
*    BE EXCEEDED.  IF THE ENTIRE TCAM BUFFER IS FILLED BEFORE FILLING * 02820053
*    THE SCREEN, AN INCOMPLETE MOVE RETURN IS EXECUTED.  AT THE END OF* 02880053
*    A LINE OR MESSAGE, THIS ROUTINE CHECKS FOR SIMULATED ATTENTION   * 02940053
*    REQUEST.  IF SPECIFIED, THIS ROUTINE LINKS TO THE SIMULATED      * 03000053
*    ATTENTION ROUTINE (IEDAYS) TO UPDATE THE QCB SIMULATED ATTENTION * 03030053
*    LINE COUNT (QCBSATCT), AND TO REQUEST A SIMULATED ATTENTION READ * 03060053
*    IF THE THRESHOLD IS REACHED.  FOR CONTROL OR ASIS MESSAGES, THIS * 03120053
*    ROUTINE REPLACES INVALID LINE CONTROL CHARACTERS/SEQUENCES WITH  * 03180053
*    A COLON TO AVOID PROGRAM-CAUSED I/O ERRORS.  IN ADDITION TO      * 03240053
*    INSERTING NEW LINE SEQUENCES, AND REPLACING INVALID CHARACTERS,  * 03300053
*    THIS ROUTINE INSERTS LINE CONTROL CHARACTERS REQUIRED TO OUTPUT  * 03330053
*    THE MESSAGE TO THE 3270.  WHEN THE TCAM BUFFER IS READY FOR      * 03360053
*    OUTPUT, THIS ROUTINE ISSUES THE QTIP SVC (101) TO UPDATE THE     * 03420053
*    OFFSET AND LENGTH FIELDS IN THE TSO BUFFER PREFIX.  ON RETURN TO * 03480053
*    THE CALLING ROUTINE, THIS ROUTINE SETS A RETURN CODE.            * 03540053
*                                                                     * 03600053
*                                                                     * 03630053
* ENTRY POINTS --                                                     * 03660053
*    IEDAYB - TO EDIT A 3270 OUTPUT MESSAGE                           * 03720053
*                                                                     * 03780053
*    CALLING SEQUENCE                                                 * 03840053
*         L    R15,AVTTSOPT                                           * 03900053
*         L    R15,TSI3270-IEDQTSI(,R15)                              * 03930053
*         BR   R15                                                    * 03960053
*                                                                     * 04020053
*                                                                     * 04080053
* INPUT --                                                            * 04140053
*    IEDAYB IS CALLED BY THE TIOC EDIT ROUTINE (IEDAYE) TO EDIT       * 04200053
*    3270 OUTPUT BUFFERS, WITH THE FOLLOWING REGISTERS SET:           * 04230053
*                                                                     * 04260053
*    R4 HAS THE LCB ADDRESS                                           * 04320053
*    R6 HAS THE TIMESHARING BUFFER ADDRESS (IN TIMESHARING REGION) OR * 04380053
*         THE MESSAGE ADDRESS FROM THE MESSAGE GENERATION             * 04440053
*         ROUTINE (IEDAYM)                                            * 04500053
*    R7 HAS THE TCAM BUFFER ADDRESS                                   * 04530053
*         OR THE ADDRESS OF THE RECEIVING AREA IN THE SCB             * 04560053
*    R11 HAS THE ADDRESS OF AVTSAVE4                                  * 04620053
*    R13 HAS THE ADDRESS OF AVTSAVE2                                  * 04680053
*    R15 HAS THE ENTRY POINT ADDRESS                                  * 04740053
*                                                                     * 04800053
*                                                                     * 04830053
* OUTPUT --                                                           * 04860053
*    ON RETURN TO THE CALLING ROUTINE, THE MESSAGE IS IN              * 04920053
*    EDITED FORM, THE QCB CARRIAGE POSITION COUNT IS UPDATED, AND THE * 04980053
*    FOLLOWING REGISTERS ARE SET:                                     * 05040053
*                                                                     * 05100053
*    R0 HAS THE LENGTH OF DATA IN TCAM BUFFER/SCB                     * 05130053
*    R1 HAS THE LENGTH OF DATA MOVED FROM TS BUFFER/MSGGEN AREA       * 05160053
*    R2 HAS THE CURRENT TSO BUFFER                                    * 05220053
*    R5 HAS THE DESTINATION QCB ADDRESS                               * 05280053
*    R14 HAS THE RETURN ADDRESS IN THE TSOUTPUT ROUTINE (IEDAYO)      * 05340053
*         OR THE RETURN ADDRESS IN THE TSO MESSAGE GENERATION         * 05400053
*         ROUTINE (IEDAYM)                                            * 05430053
*    R15 HAS ONE OF THE FOLLOWING RETURN CODES:                       * 05460053
*       IEDAYM                                                        * 05520053
*         X'00' = SUCCESSFUL COMPLETION                               * 05580053
*       IEDAYO                                                        * 05640053
*         X'00' = TS MESSAGE COMPLETELY MOVED AND SCREEN IS FULL      * 05700053
*         X'08' = TS MESSAGE COMPLETELY MOVED AND SCREEN NOT FULL     * 05730053
*         X'0C' = TS MESSAGE NOT COMPLETELY MOVED AND SCREEN NOT FULL * 05760053
*         X'10' = TS MESSAGE NOT COMPLETELY MOVED BUT SCREEN IS FULL  * 05820053
*                                                                     * 05880053
*                                                                     * 05940053
* EXTERNAL REFERENCES --                                              * 06000053
*    IEDAYS - TO HANDLE REQUESTS FOR SIMULATED ATTENTION BY           * 06030053
*         LINE COUNT                                                  * 06060053
*    QTIP SVC ROUTINE - TO UPDATE THE TIMESHARING BUFFER PREFIX       * 06120053
*                                                                     * 06180053
*                                                                     * 06240053
* EXITS,NORMAL --                                                     * 06300053
*    TO THE TSOUTPUT ROUTINE (IEDAYO)                                 * 06330053
*    TO THE TSO MESSAGE GENERATION ROUTINE (IEDAYM)                   * 06360053
*                                                                     * 06420053
*                                                                     * 06480053
* EXITS,ERROR --                                                      * 06540053
*    NONE                                                             * 06600053
*                                                                     * 06630053
*                                                                     * 06660053
* TABLES/WORK AREAS --                                                * 06720053
*    AVT,LCB,QCB,TSID,TCAM BUFFER PREFIX,TSO BUFFER PREFIX            * 06780053
*                                                                     * 06840053
*                                                                     * 06900053
* ATTRIBUTES --                                                       * 06930053
*    SERIALLY REUSABLE,REFRESHABLE,ENABLED,RESIDENT,PROBLEM PROGRAM   * 06960053
*    MODE                                                             * 07020053
*                                                                     * 07080053
*                                                                     * 07140053
* CHARACTER CODE DEPENDENCY --                                        * 07200053
*    THIS ROUTINE IS DEPENDENT ON DATA CHARACTERS TRANSLATED TO       * 07230053
*    EBCDIC CODE.                                                     * 07260053
*                                                                     * 07320053
*                                                                     * 07380053
* NOTES --                                                            * 07440053
*    AVTSAVE4 (GMAIN DSECT) IS THE OUTPUT EDIT                        * 07500053
*    WORKAREA, WITH THE FOLLOWING INPUT FIELDS SET:                   * 07530053
*                                                                     * 07560053
*    TSBUFR HAS THE TIMESHARING BUFFER ADDRESS                        * 07620053
*    TCBUFR HAS THE TCAM BUFFER ADDRESS                               * 07680053
*    MSGLEN HAS THE LENGTH OF DATA                                    * 07740053
*    WBUFSZ HAS THE TCAM BUFFER SIZE                                  * 07800053
*    CARCT HAS THE QCB CARRIAGE COUNT                                 * 07830053
*    LINENUM HAS THE DISPLAY NUMBER OF LINES                          * 07860053
*    LINESIZE HAS THE DISPLAY LINE SIZE                               * 07920053
*    WFLGS HAS THE TSO PARAMETER FLAGS                                * 07980053
*    FLAG1 HAS FLASHBACK REQUESTED FLAG                               * 08040053
*    TSCURR IS EQUIVALENT TO TSBUFR                                   * 08100053
*                                                                     * 08130053
*                                                                     * 08160053
*                                                                     * 08220053
*********************************************************************** 08280053
         EJECT                                                          08340053
*********************************************************************** 08400053
*********                                                     ********* 08430053
*********                 REGISTER EQUATES                    ********* 08460053
*********                                                     ********* 08520053
*********************************************************************** 08580053
         SPACE 2                                                        08640053
RZERO    EQU   0                        INDEX REGISTER                  08700053
RPARM    EQU   1                        WORK/PARAMETER REGISTER         08730053
RPARM2   EQU   2                        WORK/PARAMETER REGISTER         08760053
RTIOC    EQU   2                        TSO BUFFER                      08820053
RBASE2   EQU   3                        2ND BASE REGISTER IF NEEDED     08880053
RLCB     EQU   4                        LCB ADDRESS                     08940053
RQCB     EQU   5                        QCB ADDRESS                     09000053
RTSBUF   EQU   6                        TS BUFFER/MSGGEN ADDRESS        09030053
RTCBUF   EQU   7                        TCAM BUFFER/MSGGEN SCB ADDRESS  09060053
RTEMP    EQU   8                        RTEMP/RTEMPA MUST BE EVEN/ODD   09120053
RTEMPA   EQU   9                        RTEMP/RTEMPA MUST BE EVEN/ODD   09180053
RDCB     EQU   10                       DCB ADDRESS                     09240053
RWRK11   EQU   11                       TSO 3270 PARAMETER/WORKAREA     09300053
RBASE    EQU   12                       TSO 3270 EDIT BASE REGISTER     09330053
RAVT     EQU   13                       ADDRESS OF AVTSAVE2             09360053
RLINK    EQU   14                       RETURN/ENTRY ADDRESS REGISTER   09420053
RRTN     EQU   15                       ENTRY/RETURN ADDRESS REGISTER   09480053
         SPACE 2                                                        09540053
*********************************************************************** 09600053
         EJECT                                                          09630053
*********************************************************************** 09660053
*********                                                     ********* 09720053
*********             MASKS AND DISPLACEMENTS                 ********* 09780053
*********                                                     ********* 09840053
*********************************************************************** 09900053
         SPACE 2                                                        09930053
ZERO     EQU   0                        ZERO                            09960053
ONE      EQU   1                        ONE                             10020053
TWO      EQU   2                        TWO                             10080053
THREE    EQU   3                        THREE                           10140053
FOUR     EQU   4                        FOUR                            10200053
SIX      EQU   6                        SIX                             10230053
SEVEN    EQU   7                        SEVEN                           10260053
EIGHT    EQU   8                        EIGHT                           10320053
TWELVE   EQU   12                       TWELVE                          10380053
THIRTEEN EQU   13                       THIRTEEN                 Y00522 10440053
SIXTEEN  EQU   16                       SIXTEEN                         10500053
EIGHTEEN EQU   18                       EIGHTEEN                        10530053
TWENTY   EQU   20                       TWENTY                          10590053
TWENTYSX EQU   26                       TWENTYSIX                       10620053
FORTY    EQU   40                       FORTY                           10680053
EIGHTY   EQU   80                       EIGHTY                          10740053
RC0      EQU   0                        RETURN CODE 0                   10800053
RC8      EQU   8                        RETURN CODE 8           SA61765 10830053
RC12     EQU   12                       RETURN CODE C                   10860053
RC16     EQU   16                       RETURN CODE 10                  10920053
QCBIEND  EQU   4                        QCB FLAG FOR SPECIAL OUTPUT     10980053
QCBDEND  EQU   8                        QCB FLAG FOR SPECIAL OUTPUT     11040053
QCBLF    EQU   X'10'                    QCB LINE FEED BIT               11100053
QCBCR    EQU   X'20'                    QCB CARRAIGE RETURN BIT         11130053
QCBNL    EQU   QCBCR+QCBLF              QCB NEW LINE BIT                11160053
NOT      EQU   X'FF'                    NEGATIVE MASK                   11220053
NOTHIGH  EQU   X'F0'                    MASK HIGH                       11280053
SBA      EQU   X'11'                    SET BUFFER ADDRESS              11340053
INC      EQU   X'13'                    INSERT CURSOR                   11400053
SF       EQU   X'1D'                    START FIELD                     11430053
WCC      EQU   X'C1'                    WRITE CONTROL CHARACTER         11490053
WCCRESTR EQU   X'C3'                    WCC KEYBOARD RESTORE            11520053
WCCDEF   EQU   X'40'                    DEFAULT WRITE CONTROL   SA60002 11580053
BYPATTR  EQU   X'4C'                    BYPASS ATTRIBUTE BYTE           11640053
READATT  EQU   X'40'                    READ ATTRIBUTE BYTE             11700053
WRITEATT EQU   X'C8'                    WRITE ATTRIBUTE BYTE            11730053
CMD      EQU   X'F1'                    COMMAND OPERATOR WRITE CHAR     11760053
STX      EQU   X'02'                    REMOTE CONTROL CHARACTER        11820053
ETX      EQU   X'03'                    REMOTE CONTROL CHARACTER        11880053
CR       EQU   X'0D'                    CARRIAGE RETURN CHARACTER       11940053
RESTORE  EQU   X'14'                    RESTORE CHARACTER               12000053
NLCHAR   EQU   X'15'                    NEWLINE CHARACTER               12030053
BYPASS   EQU   X'24'                    BYPASS CHARACTER                12060053
ESC      EQU   X'27'                    REMOTE ESCAPE CONTROL CHARACTER 12120053
EOT      EQU   X'37'                    EOT CHARACTER                   12180053
COLON    EQU   X'7A'                    COLON                           12240053
R3270    EQU   X'90'                    3270 REMOTE                     12300053
L3270    EQU   X'02'                    3270 LOCAL                      12330053
ICMASK   EQU   12                       INSERT CHARACTER MASK    Y00522 12360053
         SPACE 2                                                        12420053
*********************************************************************** 12480053
         EJECT                                                          12540053
*********************************************************************** 12600053
*********                                                     ********* 12630053
*********              ESTABLISH ADDRESSABILITY               ********* 12660053
*********                                                     ********* 12720053
*********************************************************************** 12780053
         SPACE 2                                                        12840053
         USING IEDAYB,RBASE,RBASE2      SET BASE ADDRESSABILITY SA61765 12900053
         USING AVTSAVE2,RAVT            SET SAVEAREA ADDRESSABILITY     12930053
         USING IEDQQCB,RQCB             SET QCB ADDRESSABILITY          12960053
         USING IEDQLCB,RLCB             SET LCB ADDRESSABILITY          13020053
         USING GMAIN,RWRK11             SET WORKAREA ADDRESSABILITY     13080053
         USING TIOCBUF,RTIOC            SET TSO BUFFER ADDRESSABILITY   13140053
         SPACE 2                                                        13200053
*********************************************************************** 13230053
         EJECT                                                          13260053
*********************************************************************** 13320053
         LR    RBASE,RRTN               SET BASE REGISTER               13380053
         LA    RBASE2,4095(RBASE)       SET SECOND              SA61765 13440053
         LA    RBASE2,1(RBASE2)         BASE REGISTER           SA61765 13500053
IEDAYB   IEDHJN AYB010                                                  13530053
*********************************************************************** 13560053
         LTR   RTSBUF,RTSBUF            ENTRY FOR NEW LINE              13620053
         BZ    CHKTYP                   YES, BRANCH TO CHECK TYPE ENTRY 13680053
         TM    WFLGS,TSOMSG             TSO OR MSGGEN ENTRY             13740053
         BO    SENDTSO                  TSO ENTRY                       13800053
CHKTYP   EQU   *                                                        13830053
         TM    WFLGS,TSOMSG             TSO OR MSGGEN ENTRY             13860053
         BO    HDRS1                    TSO ENTRY                       13920053
         NI    QCBRETCT,NOT-QCBDEND     SPECIAL OUTPUT FLAG OFF         14280053
         CLC   ONE(THREE,RTSBUF),PROMPT IS THIS A SIMATTN PROMPT Y00522 14340053
         BNE   SAVSCB2                  NO DONT SET THE FLAG     Y00522 14400053
         OI    FLAG2,PROMPTFG           SET THE PROMPT FLAG      Y00522 14430053
SAVSCB2  EQU   *                                                 Y00522 14460053
         TM    WFLGS,FRSTMGEN           IS THIS FIRST MSGGEN PASSY00522 14580053
         BZ    NOTFIRST                 NO, BRANCH               Y00522 14640053
         XC    MSGNLNTH,MSGNLNTH        CLEAR TOTAL MOVED COUNT  Y00522 14700053
         XC    FROMR,FROMR              CLEAR OUT FROM COUNT     Y00522 14760053
NOTFIRST EQU   *                                                 Y00522 14820053
         TM    FLAG2,X3705              IS THE 3270 ON A 3705    Y00522 14880053
         BO    HDRS0                    YES, DONT CHANGE MSG SIZEY00522 14940053
         IC    RLINK,MSGLEN+ONE         MESSAGE SIZE IN SCB             15000053
HDRS0    EQU   *                                                 Y00522 15030053
         STC   RLINK,WBUFSZ+ONE         STORE IN TCAM BUFFER SIZE FIELD 15100053
HDRS1    EQU   *                                                        15150053
         TM    WFLGS,FRSTMGEN           IS THIS THE FIRST PASS   Y00522 15180053
         BZ    HDRS2                    YES, DONT NEED THE HEADERY00522 15240053
         BAL   RLINK,CNTLHDRS           INSERT HEADER CONTROL           15300053
HDRS2    EQU   *                                                 Y00522 15330053
         TM    WFLGS,TSOMSG             TSO ENTRY                       15360053
         BZ    DATA                     NO, CHECK NEW LINE ENTRY        15420053
INSCUR   EQU   *                                                        15480053
         NC    TOR,TOR                  IS 'TO' COUNT ZERO              15540053
         BZ    NEWLDONE                 YES, BRANCH                     15600053
         CLI   QCBSATCT,ZERO            IS THIS LINE ZERO       SA60002 15630053
         BNE   INSCUR2                  NO, INSERT CURSOR       SA61765 15660053
         LTR   RTSBUF,RTSBUF            ENTRY FOR NEW LINE      SA61765 15720053
         BZ    INSCUR1                  YES, DO NOT INSERT CURSOSA61765 15780053
INSCUR2  EQU   *                                                SA61765 15840053
         BAL   RLINK,INSTCURS           INSERT CURSOR ORDER             15900053
INSCUR1  EQU   *                                                SA60002 15930053
         TM    AVTPARM3+TWO,L3270       IS THIS 3270 LOCAL              15960053
         BO    NEWLDONE                 YES, BRANCH FOR NORMAL RETURN   16020053
         TM    FLAG2,X3705              IS THE 3270 ON A 3705    Y00522 16080053
         BO    SENDTSO                  YES, BRANCH              Y00522 16140053
         BAL   RLINK,ETXEND             GO INSERT ETX            Y00522 16200053
NEWLDONE EQU   *                                                        16230053
         NI    QCBRETCT,NOT-QCBNL       TURN OFF FLAGS                  16260053
         L     RLINK,TOR                GET NUMBER OF CHARACTERS MOVED  16320053
         ST    RLINK,FROMR              STORE IN MOVED FROM SAVEAREA    16380053
         B     SUCCESS                  BRANCH FOR NORMAL RETURN        16440053
         SPACE 2                                                        16500053
DATA     EQU   *                                                        16530053
         LTR   RTSBUF,RTSBUF            ENTRY FOR LEFT ADJUSTMENT       16560053
         BZ    INSCUR                   YES, INSERT CURSOR              16620053
         MVC   LINE+ONE(ONE),LINESV+ONE SET LINE SIZE                   16680053
         TM    AVTPARM3+TWO,L3270       IS THIS 3270 LOCAL              16740053
         BZ    DATA1                    NO, BRANCH                      16800053
         TM    QCBTSOF2,QCBDSSMI        IS RESTORE KEYBOARD FLG SET     16830053
         BZ    DATA1                    NO, BRANCH                      16860053
         CLI   0(RTSBUF),ONE            IS MESSAGE COUNT ONE            16920053
         BE    NEWLDONE                 YES, THIS IS RESTORE KEYBOARD   16980053
*                                       ENTRY                           17040053
DATA1    EQU   *                                                        17100053
         IC    RLINK,ZERO(RTSBUF)       FIRST BYTE IS MESSAGE COUNT     17130053
         TM    FLAG2,X3705              IS THE 3270 ON A 3705    Y00522 17160053
         BZ    DATA3                    BRANCH NO                Y00522 17180053
         SH    RRTN,SIXCHAR             NONTSO PREFIX           OY00522 17200053
         TM    QCBFLAG,QCBTSSES         TSO IN SESSION          OY00522 17204053
         BZ    DATA4                    BRANCH NO               OY00522 17208053
         SH    RRTN,AVTHA2              TSO PREFIX              OY00522 17212053
DATA4    EQU   *                                                OY00522 17216053
         SH    RRTN,CHAR8               DEDUCT LEADING CONTROL   Y00522 17220053
         TM    WFLGS,FMTFLAG            IS FORMAT INFO IN BUFFER Y00522 17280053
         BZ    DATA2                    NO, BRANCH               Y00522 17340053
         SH    RRTN,FIVECHAR            SUBTARCT ITS COUNT       Y00522 17400053
DATA2    EQU   *                                                 Y00522 17430053
         SR    RLINK,RRTN               SUBTRACT FROM TOTAL      Y00522 17460053
         AR    RTSBUF,RRTN              SKIP DATA ALREADY MOVED  Y00522 17520053
DATA3    EQU   *                                                 Y00522 17550053
         STC   RLINK,BLNTH+ONE          TS BUFFER DATA SIZE             17580053
         STC   RLINK,MSGLEN+ONE         MESSAGE LENGTH                  17640053
         LA    RTSBUF,ONE(RTSBUF)       INCREMENT TO MESSAGE FIELD      17700053
         TM    WFLGS,NOLEFT             REQUEST LEFT JUSTIFICATION      17750053
         BO    PUTDATA                  NO, BRANCH TO MOVE MSGGEN DATA  17760053
         L     RLINK,LCBSCBA-ONE        GET SCB ADDRESS                 17820053
         USING IEDQSCB,RLINK            ESTABLISH ADDRESSABILITY        17880053
         TM    SCBERR2,SCBALN           ENTRY FOR AUTO LINE NUMBERING   17940053
         DROP  RLINK                    DROP ADDRESSABILITY             18000053
         BZ    NOALN                    NO, BRANCH                      18030053
         CLI   MSGLEN+ONE,EIGHT         IS THIS AUTO DATA OR MSG        18060053
         BH    NOALN                    BRANCH ON MSG                   18120053
         MVC   DEND+EIGHT(EIGHT),ZERO(RTSBUF) SAVE LINE NUMBER          18200053
         LA    RTSBUF,DEND+EIGHT        CHANGE INPUT POINTER            18240053
NOALN    EQU   *                                                        18300053
         CLI   CARCT+ONE,ZERO           NEED LEFT JUSTIFICATION         18330053
         BE    PUTDATA                  NO, BRANCH TO CHECK SCBSIZE     18360053
         CLI   CARCT+ONE,NOT            LEFT JUSTIFICATION WITH NO CNT  18420053
         BE    NOCNTNL                  YES, BRANCH FOR NEW LINE        18480053
         TM    CARCT+ONE,NOTHIGH        CARRIAGE COUNT FOR IDLES        18540053
         BO    NOCNTNL                  YES, BRANCH FOR NEW LINE        18600053
         CLI   CARCT+ONE,ONE            CARRIAGE COUNT ONE              18630053
         BNE   CNTNL                    NO, COUNT ONE LINE              18660053
         TM    SWT1,WRATTSW             CARRIAGE COUNT FOR ATTRIBUTE    18720053
         BO    PUTDATA                  YES, BRANCH FOR NEW LINE        18780053
CNTNL    EQU   *                                                        18840053
         OI    FLAG2,NOMOVECT+NWLNCNT   SET NO MOVECOUNT+LINECOUNT FLAG 18900053
         BAL   RLINK,NWLNCHRS           DETERMINE NEWLINE ADDRESS       18930053
         SH    RTCBUF,FOURCHAR          BACK UP TO CURSOR ADDRESS       18960053
         BAL   RLINK,CURSADDR           INSERT CURSOR ADDRESS           19020053
         AH    RTCBUF,TWOCHAR           SKIP OVER SF/ATTRIBUTE BYTES    19080053
         NI    FLAG2,NOT-NOMOVECT-NWLNCNT TURN OFF FLAGS                19140053
NOCNTNL  EQU   *                                                        19200053
         MVI   CARCT+ONE,ZERO           ZERO LINE POSITION COUNT        19230053
         TM    SWT1,WRATTSW             ATTRIBUTE BYTE PRESENT          19260053
         BZ    PUTDATA                  NO, BRANCH                      19320053
         MVI   CARCT+ONE,ONE            SET LINE POSITION COUNT TO ONE  19380053
         SPACE 2                                                        19440053
*********************************************************************** 19500053
*   MOVE MSGGEN MESSAGE TO SCB                                        * 19530053
*********************************************************************** 19560053
PUTDATA  EQU   *                                                        19620053
         LH    RLINK,LINESV             SET TO MAX LINE SIZE     Y00522 19680053
         TM    FLAG2,X3705              IS THE 3270 ON A 3705    Y00522 19740053
         BO    PASTNEWL                 YES, TREAT MSGGEN AS DATAY00522 19800053
         SR    RPARM,RPARM              CLEAR WORK REGISTER             19830053
         LH    RPARM,WBUFSZ             GET SCB SIZE                    19860053
         SH    RPARM,SIXCHAR            SUBTRACT COUNT OF END CONTROL   19920053
         TM    AVTPARM3+TWO,L3270       IS THIS 3270 LOCAL              19980053
         BO    PUTDAT00                 YES, BRANCH TO CHECK SIZE       20040053
         BCTR  RPARM,ZERO               SUBTRACT ONE MORE FOR REMOTE    20100053
PUTDAT00 EQU   *                                                        20130053
         CH    RPARM,MSGLEN             IS THERE ROOM IN SCB            20160053
         BL    PUTDATA0                 NO, TRUNCATE TO SIZE IN SCB     20220053
         LH    RPARM,MSGLEN             GET MESSAGE LENGTH              20280053
PUTDATA0 EQU   *                                                        20340053
         CH    RPARM,LINE               WILL MSG WRAP TO NEXT LINE      20400053
         BNH   PUTDATA1                 NO, BRANCH TO UPDATE AND MOVE   20430053
         BAL   RLINK,SIMATCAL           UPDATE LINE COUNT               20460053
PUTDATA1 EQU   *                                                        20520053
         BAL   RLINK,UPDTE              UPDATE TO, TCAM BUF, AND CARCT  20580053
         BCTR  RPARM,ZERO               REDUCE COUNT FOR MOVE           20640053
         EX    RPARM,MOVDATA            MOVE MESSAGE TO SCB             20700053
         AR    RTCBUF,RPARM             UPDATE POINTER TO LAST CHAR     20730053
         LA    RPARM,ONE(RPARM)         ADD BACK DATA COUNT             20760053
         CLI   ZERO(RTCBUF),NLCHAR      WAS LAST CHARACTER NEW LINE     20820053
         BNE   NOTNLCHR                 NO, CORRECT COUNT               20880053
         OI    FLAG2,NWLNCNT            SET LINE COUNT FLAG             20940053
         BAL   RLINK,NWLNCHRS           DETERMINE NEWLINE ADDRESS       21000053
         B     PUTDATA2                 BRANCH TO END CONTROL           21030053
NOTNLCHR EQU   *                                                        21060053
         LA    RTCBUF,ONE(RTCBUF)       ADD BACK BUFFER POSITION        21120053
PUTDATA2 EQU   *                                                        21180053
         TM    QCBFLAG,QCBTSSES         TS SESSION STARTED              21240053
         BZ    PUTDATA3                 NO, BRANCH                      21300053
         BAL   RLINK,STARTFLD           INSERT START FIELD ORDER        21330053
         BAL   RLINK,RDATTRIB           INSERT READ ATTRIBUTE BYTE      21360053
PUTDATA3 EQU   *                                                        21420053
         TM    FLAG2,NWLNCNT            IS LINE COUNT FLAG SET          21480053
         BZ    INSCUR                   NO, BRANCH TO INSERT CURSOR     21540053
         NI    FLAG2,NOT-NWLNCNT        TURN OFF LINE COUNT FLAG        21600053
         MVI   ZERO(RTCBUF),SBA         INSERT SBA ORDER                21640053
         LA    RTCBUF,ONE(RTCBUF)       ADD BACK BUFFER POSITION        21680053
         BAL   RLINK,CURSADDR           INSERT CURSOR ADDRESS           21720053
         B     INSCUR                   BRANCH TO INSERT CURSOR         21780053
         EJECT                                                          21840053
*********************************************************************** 21900053
*   MOVE TIOC BUFFER DATA TO TCAM BUFFER                              * 21930053
*********************************************************************** 21960053
SENDTSO  EQU   *                        TSO SEND DATA ENTRY             22020053
         TM    WFLGS,TSOMSG             IS THIS A MSGGEN         Y00522 22080053
         BO    SENDTSO9                 NO, BRANCH               Y00522 22150053
         TM    QCBRETCT,QCBDEND         SPECIAL ENTRY FLAG ON    Y00522 22440053
         BO    CHKSPEN2                 YES GO SEE WHY           Y00522 22500053
         B     SENDTSO2                 CONTINUE PROCESSING      Y00522 22530053
SENDTSO9 EQU   *                                                 Y00522 22560053
         LA    RTEMP,ONE                SET REGISTER TO ONE     SA61765 22620053
         CR    RTIOC,RTEMP              IS THIS ENDING ENTRY    SA61765 22680053
         BE    CHKSPENT                 YES, DO NOT INITIALIZE  SA61765 22740053
         SR    RTEMP,RTEMP              CLEAR WORK REGISTER             22800053
         IC    RTEMP,BUFFOFST           OFFSET TO DATA IN TS BUFFER     22830053
         AR    RTSBUF,RTEMP             ADD OFFSET TO POINT TO DATA     22860053
         MVC   BLNTH+ONE(ONE),BUFFLNTH  AMOUNT OF DATA IN TS BUFFER     22920053
         L     RLINK,BUFFTRLR-ONE       POINTER TO NEXT TRAILER BUFFER  22980053
         LA    RLINK,ZERO(RLINK)        CLEAR FLAG BYTE                 23040053
         LTR   RLINK,RLINK              TEST FOR TRAILER BUFFER         23100053
         BZ    CHKSPENT                 BRANCH IF NO TRAILER            23130053
         OI    FLAG1,TRAILER            SET TRAILER BUFFER FLAG         23160053
CHKSPENT EQU   *                                                        23220053
         TM    QCBRETCT,QCBDEND         IS THIS SPECIAL ENTRY FOR       23280053
*                                          END CONTROL INSERTION        23340053
         BZ    SENDTSO1                 NO, BRANCH TO INSERT HEADER     23400053
         TM    QCBRETCT,QCBIEND         IS LINE ROOM FLAG ALSO SET      23430053
         BZ    CHKSPEN2                 NO, BRANCH TO CALCULATE CURSOR  23460053
         NI    QCBRETCT,NOT-QCBIEND     TURN OFF LINE ROOM FLAG SA61765 23520053
         MVC   LINE+ONE(ONE),LINESV+ONE GET TERMINAL LINE SIZE          23600053
CHKSPEN2 EQU   *                                                        23640053
         CLI   CARCT+ONE,NOTHIGH        SPECL ENTY OFFSET SET   SA61765 23700053
         BL    CHKSPEN3                 NO, DO NOT SET QTIP     SA61765 23730053
         CR    RTIOC,RTEMP              ENDING SEQUENCE ENTRY   OX03936 23737053
         BE    CHKSPEN3                 YES, BR - DO NOT INIT FOR       23744053
*                                       QTIP                    OX03936 23751053
         MVI   MOVED+ONE,ONE            SET FOR QTIP ENTRY              23760053
         OI    FLAG2,NWLNCNT            SET LINECOUNT FLAG              23820053
         NI    QCBRETCT,NOT-QCBDEND     TURN OFF SPECIAL ENTRY  SA61765 23880053
CHKSPEN3 EQU   *                                                SA61765 23940053
         BAL   RLINK,CALCURSR           CALCULATE CURSOR ADDRESS        24000053
         NI    FLAG2,NOT-NWLNCNT        TURN OFF LINECOUNT FLAG         24050053
         CLI   CARCT+ONE,NOTHIGH        SPECL ENTY OFFSET SET   SA61765 24100053
         BNL   CHKSPEN4                 YES, CALCULATE BRANCH   SA61765 24150053
         MVI   CARCT+ONE,SBASCND        SET OFFSET TO INSERT SBASA61765 24200053
CHKSPEN4 EQU   *                                                SA61765 24250053
         NI    CARCT+ONE,NOT-NOTHIGH    TURN OFF UNUSED BITS            24300053
         SR    RLINK,RLINK              CLEAR BRANCH REGISTER           24350053
         IC    RLINK,CARCT+ONE          GET BRANCH OFFSET               24400053
         MVI   CARCT+ONE,ZERO           CLEAR LINE COUNT                24450053
         SLL   RLINK,TWO                MULTIPLY BY 4                   24500053
         B     SPSECENT(RLINK)          BRANCH ON OFFSET                24550053
         SPACE 2                                                        24600053
SPSECENT B     NORMALSF                 F0  STARTFIELD INSERT           24650053
         B     SFATTON                  F1  READ ATTRIBUTE INSERT       24700053
         B     CURSINST                 F2  SBA INSERT          SA61765 24750053
         B     CURSR1IN                 F3  FIRST CURSOR INSERT         24800053
         B     CURSR2IN                 F4  SECOND CURSOR INSERT        24850053
         B     SBACURON                 F5  INC INSERT                  24900053
         B     ADDETX1                  F6  ETX INSERT                  24930053
         B     ETXON                    F7  EOT INSERT                  24960053
         B     PARTLETX                 F8  ETX/EOT INSERT      SA61765 25020053
         SPACE 2                                                        25080053
SENDTSO1 EQU   *                                                        25140053
* IF THIS IS THE FIRST BASIC UNIT OF A 3270 MESSAGE, CONTROL HEADER   * 25200053
* INFORMATION MUST BE INSERTED IN THE TCAM BUFFER                     * 25230053
         SPACE 2                                                        25260053
         L     RTEMPA,LCBERBCH-ONE      ADDRESS OF FIRST BASIC UNIT     25320053
         LA    RTEMPA,0(RTEMPA)         CLEAR HI-ORDER BYTE             25380053
         LA    RLINK,0(RTCBUF)          BUFFER ADDRESS PASSED           25440053
         SH    RLINK,HDRPRFX            SUBTRACT PREFIX SIZE            25500053
         CR    RLINK,RTEMPA             IS THIS FIRST BASIC UNIT        25530053
         BNE   SENDTSO2                 NO, DO NOT ADD CONTROL HEADER   25560053
         OI    FLAG2,HEADERFG           SET HEADER FLAG                 25620053
SENDTSO5 EQU   *                                                SA61765 25680053
         BAL   RLINK,CNTLHDRS           INSERT HEADER INFORMATION       25740053
         OI    FLAG2,HEADERFG           SET HEADER FLAG         SA61765 25800053
         B     SENDTSO4                 GET LINESIZE            SA61765 25830053
SENDTSO2 EQU   *                                                        25860053
         TM    BUFFFL1,BUFFHDR          TSO HEADER BUFFER?      SA61765 25920053
         BZ    SENDTSO4                 NO, DO NOT ADD HEADER   SA61765 25980053
         TM    WFLGS,ASISCNTL           IS THIS ASIS CONTROL    SA61765 26040053
         BO    SENDTSO4                 YES, DO NOT ADD HEADER  SA61765 26100053
         CLI   BUFFOFST,BUFFHDLN        OFFSET EQUAL PREFIX     SA61765 26130053
         BE    SENDTSO5                 YES, ADD SUBSEQUENT HDR SA61765 26160053
SENDTSO4 EQU   *                                                SA61765 26220053
         SR    RLINK,RLINK              CLEAR WORK REGISTER             26280053
         IC    RLINK,LINESV+ONE         GET TERMINAL LINE SIZE          26340053
         SH    RLINK,CARCT              SUBTRACT FOR LINE COUNT LEFT    26400053
         BP    PASTNEWL                 BRANCH IF ROOM LEFT THIS LINE   26430053
         TM    WFLGS,CONTROLM           IS THIS CONTROL MODE            26460053
         BO    CONTRMOD                 YES, BRANCH TO USE LINE SIZE    26520053
         BAL   RLINK,NWLNCHRS           DETERMINE NEW LINE ADDRESS      26580053
         TM    FLAG2,HEADERFG           IS THIS FIRST BASIC UNIT        26640053
         BO    SENDTSO3                 YES, BRANCH                     26700053
         BAL   RLINK,SBAINSRT           INSERT SBA ORDER AND CURSOR     26730053
         B     CONTRMOD                 BRANCH TO GET LINE SIZE         26760053
         SPACE 2                                                        26820053
SENDTSO3 EQU   *                                                        26880053
         SH    RTCBUF,FOURCHAR          BACK UP TO CURSOR ADDRESS       26940053
         OI    FLAG2,NOMOVECT           SET NO MOVECOUNT FLAG           27000053
         BAL   RLINK,CURSADDR           INSERT CURSOR ADDRESS           27030053
         AH    RTCBUF,TWOCHAR           ADD BACK                SA61765 27060053
         NI    FLAG2,NOT-NOMOVECT       TURN OFF FLAG           SA60002 27120053
CONTRMOD EQU   *                                                        27180053
         IC    RLINK,LINESV+ONE         GET TERMINAL LINE SIZE          27240053
         SPACE 2                                                        27300053
PASTNEWL EQU   *                                                        27330053
         STC   RLINK,LINE+ONE           SET LINE SIZE REMAINING         27360053
         SPACE 2                                                        27420053
         BAL   RLINK,CALCSIZE           DETERMINE AMT DATA TO BE MOVED  27480053
         SPACE 2                                                        27540053
         CLI   SWT2,RETCOD40            ANY ROOM LEFT IN TCAM BUFFER    27600053
         BE    NOTALL                   NO, RETURN FOR NEW BUFFER       27630053
         CLI   SWT2,RETCOD44            DATA ALREADY MOVED      SA61765 27660053
         BE    ADDETX1                  ADD ETX IF NECESSARY    SA64364 27740053
         SPACE 2                                                        27780053
         BAL   RLINK,EDIT               MOVE AND EDIT DATA              27850053
         SPACE 2                                                        27900053
         SR    RTEMP,RTEMP              CLEAR WORK REGISTER             27930053
         IC    RTEMP,SWT2               GET OFFSET INDICATION           27960053
DATAMVTB EQU   *                        DATA MOVED RETN CDE BRANCHTABLE 28020053
         B     DATAMVTB(RTEMP)          USE CALCSIZE RETURN CODE OFFSET 28080053
         B     NEWLINE                  4  SEND ALL DATA THIS LINE      28140053
         B     EBUF                     8  FILL TCAM BUFFER             28200053
         B     PARTML                   12 SEND LINE SIZE REMAINING     28230053
         B     NORMALND                 16 ADD NORMAL ENDING            28260053
         EJECT                                                          28320053
*  RETURN CODE 4  -  ALL DATA IN TS BUFFER MOVED                        28380053
NEWLINE  EQU   *                                                        28440053
         TM    WFLGS,TSOMSG             IS THIS A MSGGEN         Y00522 28500053
         BZ    NORMALSF                 YES, BRANCH              Y00522 28530053
         NI    SWT1,CRNL+BYPFLAG        TURN OFF ALL EXCEPT             28560053
*                                       CR/NL AND BYPFLAG               28620053
         NC    WBUFSZ,WBUFSZ            ANY ROOM LEFT TCAM BUFFER       28680053
         BNZ   NEWLINE2                 YES, BRANCH TO CHECK MESSAGE    28740053
         TM    WFLGS,TSOASIS+CONTROLM   IS THIS ASIS OR CONTROL MODE    28800053
         BNZ   NEWLINE2                 YES, CHECK END OF MSG.  SA61765 28830053
         TM    BUFFFL1,BUFFNLCR         IS THIS END OF MESSAGE          28860053
         BO    NORMALND                 YES, BRANCH             SA61765 28920053
         BAL   RLINK,QTIPR              UPDATE TS BUFFER                28980053
         B     NOTALL                   WAIT FOR NEW BUFFER             29040053
         SPACE 2                                                        29100053
NEWLINE2 EQU   *                                                        29130053
         NC    MSGLEN,MSGLEN            ANY MORE DATA TO MOVE           29160053
         BNZ   MOREDATA                 YES, BRANCH                     29220053
         TM    WFLGS,TSOASIS+CONTROLM   IS THIS ASIS OR CONTROL MODE    29280053
         BNZ   ASISCHK                  YES, BRANCH             SA60002 29340053
         TM    BUFFFL1,BUFFNLCR         IS THIS END OF MESSAGE          29400053
         BO    NORMALND                 YES, BRNCH TO COUNT LINESA61765 29440053
         NC    LINE,LINE                ANY ROOM LEFT THIS LINE         29480053
         BNZ   NORMALL2                 YES, BRANCH             SA61765 29520053
         B     NORMALND                 BRANCH TO COUNT LINE    SA61765 29580053
         SPACE 2                                                        29640053
ASISCHK  EQU   *                                                        29700053
         TM    WFLGS,ASISCNTL           IS THIS ASIS CONTROL    SA60002 29730053
         BO    ASISCHK2                 YES, ZERO CARCT         SA60002 29760053
         TM    WFLGS,CONTROLM           IS THIS CONTROL MODE    SA60002 29820053
         BO    CONTLINE                 YES, CHECK FOR END      SA60002 29900053
         NC    LINE,LINE                ANY ROOM LEFT THIS LINE         29940053
         BNZ   ASISCHK3                 YES, CHECK FOR INC      SA60002 30000053
         BAL   RLINK,SIMATCAL           COUNT ONE LINE                  30030053
ASISCHK2 EQU   *                                                SA60002 30060053
         MVI   CARCT+ONE,ZERO           CLEAR LINE COUNT                30120053
         NI    QCBRETCT,NOT-QCBNL       TURN OFF NEWLINE FLAGS          30180053
ASISCHK3 EQU   *                                                SA60002 30240053
         TM    FLAG1,INCSW              IS INC FLAG SET         SA60002 30300053
         BO    ADDETX1                  YES, BRANCH TO CHK REMOTEA60002 30340053
         TM    WFLGS,ASISCNTL           IS THIS ASIS CONTROL    SA60002 30380053
         BO    ADDETX1                                          SA68030 30420053
         TM    SWT1,BYPFLAG             BYPASS/RESTORE FLAG SET SA68024 30440053
         BO    RDATTON                  YES, CHK FULL SCREEN    SA68024 30460053
         B     NORMALSF                 ADD START FIELD/ATT     SA60002 30480053
         SPACE 2                                                        30540053
CONTLINE EQU   *                                                SA60002 30600053
         TM    SWT1,BYPFLAG             IS BYPASS/RESTORE FLAG SET      30630053
         BZ    ADDETX1                  NO, BRANCH TO CHECK FOR REMOTE  30660053
         B     SBACURON                 INSERT INC ORDER        SA60002 30720053
         SPACE 2                                                        30780053
MOREDATA EQU   *                                                        30840053
         NC    LINE,LINE                ANY ROOM LEFT THIS LINE         30900053
         BZ    PARTML                   NO, BRANCH TO UPDATE LINECOUNT, 30930053
*                                       TSO BUFFER, ADD REMOTE ETX/EOT  30960053
*                                       IF NEEDED, AND SET END OF LINE  31020053
*                                       RETURN                          31080053
         BAL   RLINK,QTIPR              UPDATE TS BUFFER                31140053
ASISDATA EQU   *                                                SA60002 31200053
         TM    FLAG1,TRAILER            IS TRAILER BUFFER FLAG ON       31230053
         BZ    NOTALL                   NO, SET INCOMPLETE MOVE RETURN  31260053
         L     RTSBUF,BUFFTRLR-ONE      GET TRAILER BUFFER ADDRESS      31320053
         LA    RTSBUF,ZERO(RTSBUF)      CLEAR HI-ORDER BYTE             31380053
         ST    RTSBUF,TSCURR            STORE AS CURRENT BUFFER         31440053
         LR    RTIOC,RTSBUF             SAVE START ADDRESS OF BUFFER    31500053
ASISDAT1 EQU   *                                                SA61765 31530053
         MVI   SWT1,ZERO                TURN OFF FLAGS          SA60002 31560053
         MVI   FLAG1,ZERO               TURN OFF FLAGS          SA60002 31620053
         NI    FLAG2,X3705              LEAVE 3705 BIT ON        Y00522 31680053
         B     SENDTSO                  CONTINUE EDIT                   31740053
         SPACE 2                                                        31800053
*  RETURN CODE 8 - FILL TCAM BUFFER                                     31830053
EBUF     EQU   *                                                        31860053
         NC    LINE,LINE                ANY ROOM LEFT THIS LINE         31920053
         BNZ   EBUF1                    YES, JUST NO ROOM TCAM  SA61765 31980053
         BAL   RLINK,NWLNCHRS           COUNT ONE LINE                  32040053
         TM    AVTPARM3+TWO,L3270       IS THIS 3270 LOCAL              32100053
         BO    EBUF1                    YES, SET INCOMPLETE MOVESA61765 32130053
         TM    FLAG2,X3705              IS THE 3270 ON A 3705    Y00522 32160053
         BO    EBUF1                    YES, BRANCH              Y00522 32220053
         TM    QCBTSOF1,QCBSATRD        IS SCREEN FULL          SA61765 32280053
         BO    PARTML1                  YES, SET INCOMPLETE MOVESA61765 32340053
         BCTR RTCBUF,ZERO               BACK UP ONE BYTE         Y00522 32400053
         MVI   ZERO(RTCBUF),ETX                                  Y00522 32440053
EBUF1    EQU   *                                                SA61765 32460053
         BAL   RLINK,QTIPR              UPDATE TS BUFFER        SA61765 32520053
         TM    QCBTSOF1,QCBSATRD        IS SCREEN FULL          SA61765 32580053
         BZ    NOTALL                   NO, SET INCOMPLETE MOVE SA61765 32640053
         B     ENDSCR                   MVE NOT COMP/SCRN FULL  SA61765 32700053
         SPACE 2                                                        32730053
*  RETURN CODE 12 - FILLED LINE.  MORE TO DO.                           32760053
PARTML   EQU   *                                                        32820053
         BAL   RLINK,SIMATCAL           UPDATE LINE COUNT               32880053
         TM    WFLGS,ASISCNTL           IS THIS ASIS CONTROL    SA60002 32940053
         BO    PARTML3                  YES, MORE DATA TO MOVE  SA60002 33000053
         TM    QCBTSOF1,QCBSATRD        IS SCREEN FULL          SA61765 33030053
         BZ    PARTML3                  NO, GET MORE DATA       SA61765 33060053
         TM    AVTPARM3+TWO,L3270       IS THIS 3270 LOCAL              33120053
         BO    ENDLINE                  YES, UPDATE TS BUFFER   SA61765 33180053
         TM    FLAG2,X3705              IS THE 3270 ON A 3705    Y00522 33240053
         BO    NORMALSF                 YES, BRANCH              Y00522 33300053
         BAL   RLINK,ETXEND             INSERT ETX ENDING FOR REMOTE    33330053
         TM    FLAG1,ETXSW              IS ETX FLAG SET                 33360053
         BO    PARTML2                  YES, BRANCH                     33450053
PARTML1  EQU   *                                                SA61765 33480053
         MVI   CARCT+ONE,ETXEOTPL       SET SECOND ENTRY OFFSET SA61765 33540053
         B     REQSECEN                 BR TO UPDATE TS BUFFER  SA61765 33600053
PARTML2  EQU   *                                                        33630053
         BAL   RLINK,EOTEND             INSERT EOT ENDING FOR REMOTE    33660053
         TM    FLAG1,EOTSW              IS EOT FLAG SET                 33720053
         BZ    PARTML1                  NO, BRANCH              SA61765 33780053
ENDLINE  EQU   *                                                SA61765 33840053
         BAL   RLINK,QTIPR              UPDATE TS BUFFER        SA61765 33900053
         B     ENDSCR                   SET SCREEN FULL         SA61765 33930053
PARTML3  EQU   *                                                SA60002 33960053
         BAL   RLINK,QTIPR              UPDATE TS BUFFER        SA61765 34020053
         L     RTSBUF,TSCURR            GET CURRENT TS BUFFER   SA60002 34080053
         NC    BLNTH,BLNTH              ANY DATA LEFT THIS BUFFERA60002 34140053
         BNZ   ASISDAT1                 YES, CONTINUE EDIT      SA61765 34200053
         B     ASISDATA                 GET NEXT BUFFER         SA60002 34240053
         SPACE 2                                                        34280053
*  RETURN CODE 16 - ADD NORMAL ENDING CONTROL                           34320053
NORMALND EQU   *                                                        34390053
         NI    SWT1,CRNL                TURN OFF ALL EXCEPT CR/NL       34440053
         OI    FLAG2,NWLNCNT            SET LINECOUNT FLAG              34500053
         BAL   RLINK,NWLNCHRS           COUNT ONE LINE                  34530053
         TM    SWT1,CRNL                IS CR/NL SWITCH SET             34560053
         BZ    NORMALSF                 NO, BRANCH                      34620053
         BCTR  RTCBUF,ZERO              WILL OVERLAY NL/CR CHARACTER    34680053
         LH    RLINK,WBUFSZ             SIZE OF TCAM BUFFER     SA61765 34740053
         LA    RLINK,ONE(RLINK)         ADD ONE TO IT           SA61765 34800053
         STH   RLINK,WBUFSZ             STORE IT BACK           SA61765 34830053
         OI    FLAG2,NOMOVECT           SET NO MOVECOUNT FLAG   SA61765 34900053
         OI    QCBRETCT,QCBNL           TURN ON NEWLINE FLAG    SA61765 34920053
         SPACE 2                                                        34980053
* START HERE IF CR/NL SWITCH NOT SET                                    35040053
NORMALSF EQU   *                                                        35100053
         BAL   RLINK,STARTFLD           INSERT START FIELD ORDER        35130053
         TM    SWT1,SFATTSW             IS START FIELD FLAG SET         35160053
         BO    SFATTON                  YES, BRANCH                     35250053
         MVI   CARCT+ONE,STFDSCND       SET SECOND ENTRY OFFSET         35280053
         B     REQSECEN                 BRANCH TO UPDATE TS BUFFER      35340053
SFATTON  EQU   *                                                        35400053
         OI    FLAG2,NWLNCNT            SET LINECOUNT FLAG              35430053
         TM    FLAG2,NOMOVECT           NO MOVECOUNT FLAG SET   SA61765 35460053
         BZ    SFATTON3                 NO, BRANCH              SA61765 35520053
         NI    FLAG2,NOT-NOMOVECT       TURN OFF FLAG           SA61765 35580053
         LH    RLINK,WBUFSZ             SIZE OF TCAM BUFFER     SA61765 35640053
         BCTR  RLINK,ZERO               DECREMENT BY ONE        SA61765 35700053
         STH   RLINK,WBUFSZ             STORE IT BACK           SA61765 35730053
SFATTON3 EQU   *                                                SA61765 35760053
         NC    LINE,LINE                ANY ROOM LEFT THIS LINE         35820053
         BZ    SFATTON2                 NO, BRANCH              SA61765 35880053
         TM    WFLGS,TSOASIS            IS THIS ASIS MODE       SA61765 35940053
         BZ    SFATTON1                 NO, BRANCH              SA61765 36000053
         TM    SWT1,CRNL                IS CR/NL SWITCH SET     SA61765 36030053
         BO    SFATTON1                 YES, BRANCH             SA61765 36060053
SFATTON2 EQU   *                                                SA61765 36120053
         NI    FLAG2,NOT-NWLNCNT        TURN OFF LINECOUNT FLAG         36180053
SFATTON1 EQU   *                                                        36240053
         BAL   RLINK,RDATTRIB           INSERT READ ATTRIBUTE BYTE      36300053
         TM    SWT1,RDATTNLF            IS READ ATTRIBUTE FLAG SET      36330053
         BO    RDATTON                  YES, BRANCH                     36360053
         MVI   CARCT+ONE,RDATSCND       SET SECOND ENTRY OFFSET         36420053
         B     REQSECEN                 BRANCH TO UPDATE TS BUFFER      36480053
RDATTON  EQU   *                                                        36540053
         TM    WFLGS,TSOMSG             IS THIS A MSGGEN         Y00522 36600053
         BZ    RDATTON3                 YES, BRANCH              Y00522 36630053
         TM    QCBTSOF1,QCBSATRD        IS SCREEN FULL          SA61765 36660053
         BZ    NORMALL2                 NO, BRANCH TO UPDATE TSOSA61765 36720053
CURSINST EQU   *                                                SA61765 36780053
         TM    WFLGS,TSOASIS            IS THIS ASIS MODE       SA60002 36840053
         BZ    RDATTON1                 NO, CHECK LINE          SA61765 36900053
         TM    SWT1,CRNL                IS CR/NL SWITCH SET     SA60002 36930053
         BO    RDATTON1                 YES, CHECK LINE         SA61765 36960053
         TM    QCBRETCT,QCBNL           IS NEWLINE FLAG SET     SA61765 37020053
         BZ    SBACURON                 NO, ADD INSERT CURSOR   SA61765 37100053
         NI    QCBRETCT,NOT-QCBNL       TURN OFF NEWLINE FLAG   SA61765 37140053
RDATTON1 EQU   *                                                        37200053
         BAL   RLINK,SBAINSRT           INSERT SBA ORDER AND CURSOR     37230053
         TM    SWT1,SBAENDSW+CUR1FLAG+CUR2FLAG ARE INSERT FLAGS SET     37260053
         BO    SBACURON                 YES, BRANCH                     37320053
         TM    SWT1,SBAENDSW            IS SBA FLAG SET                 37380053
         BO    SBAON                    YES, BRANCH                     37440053
         MVI   CARCT+ONE,SBASCND        SET SECOND ENTRY OFFSET         37500053
         B     REQSECEN                 BRANCH TO UPDATE TS BUFFER      37530053
SBAON    EQU   *                                                        37560053
         TM    SWT1,CUR1FLAG            IS 1ST CURSOR FLAG SET          37620053
         BO    CUR1ON                   YES, BRANCH                     37680053
         MVI   CARCT+ONE,CUR1SCND       SET SECOND ENTRY OFFSET         37740053
         B     REQSECEN                 BRANCH TO UPDATE TS BUFFER      37800053
CUR1ON   EQU   *                                                        37830053
         MVI   CARCT+ONE,CUR2SCND       SET SECOND ENTRY OFFSET         37860053
         B     REQSECEN                 BRANCH TO UPDATE TS BUFFER      37920053
RDATTON3 EQU   *                                                 Y00522 37980053
         LH    RLINK,CARCT              GET THE CARRIAGE COUNT   Y00522 38040053
         LA    RLINK,ONE(,RLINK)        ADD ONE FOR THE READ ATT Y00522 38100053
         STH   RLINK,CARCT              STORE BACK THE COUNT     Y00522 38130053
         LA    RLINK,RDATTON1           SET UP RETURN ADDRESS    Y00522 38160053
         B     CALCURSR                 GO UPDATE CURSOR ADDRESS Y00522 38220053
CURSR1IN EQU   *                                                        38280053
         BAL   RLINK,CURSADDR           INSERT CURSOR ADDRESS           38340053
         TM    SWT1,CUR1FLAG+CUR2FLAG   ARE CURSOR FLAGS SET            38400053
         BO    SBACURON                 YES, BRANCH                     38430053
         B     CUR1ON                   BRANCH TO SET SECOND ENTRY      38460053
CURSR2IN EQU   *                                                        38520053
         BAL   RLINK,CURSADR2           INSERT 2ND CURSOR ADDRESS       38580053
SBACURON EQU   *                                                        38640053
         BAL   RLINK,INSTCURS           INSERT INC ORDER                38700053
         TM    FLAG1,INCSW              IS INC FLAG SET                 38730053
         BO    ADDETX1                  YES, BRANCH                     38760053
         MVI   CARCT+ONE,INCSCND        SET SECOND ENTRY FLAG           38820053
         SPACE 2                                                        38880053
REQSECEN EQU   *                                                        38940053
         OI    QCBRETCT,QCBDEND         SET SECOND ENTRY REQUEST        39000053
         BAL   RLINK,QTIPR              UPDATE TSO BUFFER               39030053
         NC    LINE,LINE                ANY ROOM LEFT THIS LINE         39060053
         BZ    NOTALL                   NO, SET INCOMPLETE MOVE RETURN  39120053
         OI    QCBRETCT,QCBIEND         SET LINE ROOM FLAG              39180053
         B     NOTALL                   SET INCOMPLETE MOVE RETURN      39240053
         SPACE 2                                                SA61765 39300053
PARTLETX EQU   *                                                SA61765 39330053
         OI    FLAG1,PARTEND            SET PARTIAL MOVE FLAG   SA61765 39360053
         SPACE 2                                                        39420053
ADDETX1  EQU   *                                                        39480053
         TM    AVTPARM3+TWO,L3270       IS THIS 3270 LOCAL              39540053
         BO    NORMALL                  YES, SET NORMAL MOVE RETURN     39600053
         TM    FLAG2,X3705              IS THE 3270 ON A 3705    Y00522 39630053
         BO    NORMALL                  YES, BRANCH              Y00522 39660053
         BAL   RLINK,ETXEND             GO INSERT ETX            Y00522 39720053
         TM    FLAG1,ETXSW              IS ETX FLAG SET                 39780053
         BO    ETXON                    YES, BRANCH                     39840053
         MVI   CARCT+ONE,ETXSCND        SET SECOND ENTRY FLAG           39880053
         B     REQSECEN                 BRANCH TO UPDATE TS BUFFER      39920053
ETXON    EQU   *                                                        39960053
         TM    FLAG2,X3705              IS THE 3270 ON A 3705    Y00522 40020053
         BO    NORMALL                  YES, BRANCH              Y00522 40080053
         BAL   RLINK,EOTEND             GO INSERT EOT            Y00522 40140053
         TM    FLAG1,EOTSW              IS EOT FLAG SET                 40200053
         BO    NORMALL                  YES, BRANCH                     40230053
         MVI   CARCT+ONE,EOTSCND        SET SECOND ENTRY FLAG           40260053
         B     REQSECEN                 BRANCH TO UPDATE TS BUFFER      40320053
         SPACE 2                                                        40380053
NORMALL  EQU   *                                                        40440053
         TM    QCBRETCT,QCBDEND         IS THIS SPECIAL ENTRY   SA61765 40500053
         BZ    NORMALL1                 NO, BRANCH TO UPDATE    SA61765 40530053
         MVC   CARCT+ONE(ONE),QCBCARCT  RESTORE LINE POSITION   SA61765 40560053
         CLI   CARCT+ONE,STFDSCND      CHK CARRIAGE COUNT       OY03933 40570056
         BL    NORMALL3                                         OY03933 40580056
         MVI   CARCT+ONE,ZERO           ZERO CARRIAGE COUNT     OY03933 40590056
NORMALL3 EQU   *                                                OY03933 40600056
         NI    QCBRETCT,NOT-QCBDEND     TURN OFF SPECIAL ENTRY  SA61765 40620053
         B     SUCCESS                  SET SUCCESSFUL RETURN   SA61765 40680053
NORMALL1 EQU   *                                                SA61765 40740053
         BAL   RLINK,QTIPR              UPDATE TSO BUFFER               40800053
         TM    FLAG1,PARTEND            IS PARTIAL MOVE FLAG SETSA61765 40830053
         BO    ENDSCR                   YES, SET SCREEN FULL    SA61765 40860053
         B     SCRFULL                  MVE COMP/SCREEN FULL    SA61765 40948053
NORMALL2 EQU   *                                                SA61765 40980053
         BAL   RLINK,QTIPR              UPDATE TS BUFFER        SA61765 41040053
         B     MSGCOMP                  SET MESSAGE COMPLETE    SA61765 41100053
         EJECT                                                          41130053
CALCSIZE EQU   *                                                        41160053
         SPACE 2                                                        41220053
*********************************************************************** 41280053
* THIS ROUTINE CALCULATES THE SPACE AVAILABLE IN TCAM BUFFER AND/OR   * 41340053
* ON THE CURRENT LINE.  THE SIZE OF AVAILABLE SPACE IS RETURNED IN    * 41400053
* RPARM.  THE INPUT SIZE IS IN BLNTH IN THE WORKAREA.  RETURN CODES   * 41430053
* OF 4,8,12,16, AND 40 ARE SET AT SWT2 IN THE WORKAREA.               * 41460053
*********************************************************************** 41520053
         SPACE 2                                                        41580053
         NC    WBUFSZ,WBUFSZ            IS TCAM BUFFER FULL             41640053
         BZ    NOBUFLEF                 YES, INDICATE NO ROOM LEFT      41700053
         NC    BLNTH,BLNTH              DATA ALREADY MOVED      SA61765 41730053
         BZ    NODATA                   YES, INDICATE MOVED     SA61765 41760053
         LH    RTEMPA,WBUFSZ            GET TCAM BUFFER SIZE            41820053
         LH    RPARM,BLNTH              GET TS BUFFER SIZE              41880053
         IC    RDCB,ZERO(RTSBUF)        GET FIRST CHARACTER             41940053
         STC   RDCB,SAVX2               SAVE IT                         42000053
         BCTR  RPARM,ZERO               SUBTRACT ONE TO POINT TO LAST   42030053
         IC    RDCB,ZERO(RPARM,RTSBUF)  GET LAST CHARACTER              42060053
         STC   RDCB,SAVX2+ONE           SAVE IT                         42120053
         LA    RPARM,ONE(RPARM)         RESET LENGTH                    42180053
         CLI   SAVX2,RESTORE            IS FIRST CHARACTER RESTORE      42240053
         BNE   NOTREST                  NO, DO NOT REDUCE COUNT         42300053
         BCTR  RTEMPA,ZERO              REDUCE BY ONE FOR RESTORE/ATTR  42330053
NOTREST  EQU   *                                                        42360053
         CLC   BLNTH,MSGLEN             EQUAL IF END OF MSG OR BFR      42420053
         BE    FAKER                    IF END, BRANCH                  42480053
CALC1    EQU   *                                                        42540053
         CH    RTEMPA,BLNTH             TOO MUCH DATA FOR TCAM BUFFER   42600053
         BL    SPART                    YES, CHECK LINESIZE REMAINING   42630053
         TM    WFLGS,ASISCNTL           IS THIS ASIS CONTROL    SA60002 42660053
         BO    CALC2                    YES, IS SPACE AVAILABLE SA60002 42720053
         TM    WFLGS,CONTROLM           IS THIS CONTROL MODE            42780053
         BO    SETRET4                  YES, NO NEED TO CHECK LINE SIZE 42840053
CALC2    EQU   *                                                        42900053
         CH    RPARM,LINE               SPACE AVAILABLE THIS LINE       42930053
         BH    SETRET12                 NO, SEND REST OF LINE           42960053
         SPACE 2                                                        43020053
*  CAN SEND ENTIRE MSG THIS LINE                                        43080053
SETRET4  EQU   *                                                        43140053
         LH    RPARM,BLNTH              GET TS BUFFER SIZE              43200053
         MVI   SWT2,RETCOD4             SET RETURN CODE 4               43230053
         BR    RLINK                    TO SEND ALL DATA THIS LINE      43260053
         SPACE 2                                                        43320053
FAKER    EQU   *                                                        43380053
         CLI   SAVX2+ONE,INC            IS LAST CHARACTER INC   SA60002 43440053
         BNE   NLCRBUF1                 NO, CHECK FOR NEWLINE   SA60002 43500053
         OI    FLAG1,INCSW              SET INC FLAG SWITCH     SA60002 43530053
         B     TCBUFCH1                 BRANCH TO SET LENGTH    SA60002 43560053
NLCRBUF1 EQU   *                                                SA60002 43620053
         TM    WFLGS,ASISCNTL           IS THIS ASIS CONTROL    SA60002 43680053
         BO    TCBUFCH1                 YES, SET LENGTH         SA60002 43740053
         CLI   SAVX2+ONE,NLCHAR         IS LAST CHARACTER NEW LINE      43800053
         BNE   CARRRTCK                 NO, CHECK FOR CARRIAGE RETURN   43830053
NLCRBUF2 EQU   *                                                        43860053
         OI    SWT1,CRNL                SET CR/NL FLAG SWITCH           43920053
         SH    RPARM,TWOCHAR            SUBTRACT TWO FROM LENGTH        43980053
         BNM   NLCRBUF4                 BRANCH NOT MINUS TO CHK BYP     44040053
         SR    RPARM,RPARM              SET LENGTH TO ZERO              44100053
NLCRBUF4 EQU   *                                                        44130053
         IC    RDCB,ZERO(RPARM,RTSBUF)  GET NEXT TO LAST CHARACTER      44160053
         STC   RDCB,SAVX2+ONE           SAVE IT                         44220053
         B     BYPASSCK                 BRANCH TO CHECK FOR BYPASS      44280053
         SPACE 2                                                        44340053
CARRRTCK EQU   *                                                        44400053
         CLI   SAVX2+ONE,CR             IS LAST CHARACTER CARRIAGE RETN 44430053
         BE    NLCRBUF2                 YES, BRANCH TO REDUCE TCAM BUF  44460053
BYPASSCK EQU   *                                                        44520053
         CLI   SAVX2+ONE,BYPASS         IS LAST CHARACTER BYPASS        44580053
         BNE   TCBUFCH1                 NO, GET TS BUFFER SIZE          44640053
         OI    SWT1,BYPFLAG             SET BYPASS FLAG SWITCH          44700053
         SH    RTEMPA,ONECHAR           SUBTRACT ONE FROM LENGTH        44730053
         BNM   TCBUFCH1                 BRANCH NOT MINUS                44760053
         SR    RTEMPA,RTEMPA            SET LENGTH TO ZERO              44820053
TCBUFCH1 EQU   *                                                        44880053
         LH    RPARM,BLNTH              SET LENGTH FOR ALL              44940053
         CR    RPARM,RTEMPA             TOO MUCH DATA FOR TCAM BUFFER   45000053
         BH    REMENDNG                 YES, REMOVE END CHARACTERS      45030053
         TM    SWT1,CRNL                IS CR/NL SWITCH SET             45060053
         BO    SETRET16                 YES, BRANCH                     45120053
         TM    WFLGS,TSOASIS+CONTROLM   IS THIS ASIS OR CONTROL MODE    45180053
         BNZ   CALC2                    YES, BRANCH             SA60002 45240053
         CLC   MSGLEN,LINE              IS MESSAGE LONGER THAN LINE     45300053
         BH    CALC2                    YES, WILL TAKE END OF LINE RTN  45330053
         TM    BUFFFL1,BUFFNLCR         IS THIS LAST BUFFER             45360053
         BZ    CALC2                    NO, BRANCH TO SEND ALL          45420053
         SPACE 2                                                        45480053
*  MOVE MSG AND ADD NORMAL END CONTROL                                  45540053
SETRET16 EQU   *                                                        45600053
         MVI   SWT2,RETCOD16            SET RETURN CODE 16              45630053
         BR    RLINK                    TO ADD END CONTROL              45660053
         SPACE 2                                                        45720053
REMENDNG EQU   *                                                        45780053
         TM    SWT1,CRNL+BYPFLAG        IS CR/NL AND/OR BYPASS SW SET   45840053
         BZ    SPART                    NO, BRANCH                      45900053
         TM    SWT1,CRNL                IS CR/NL SWITCH SET             45930053
         BZ    REMOVEN1                 NO, CHECK BYPASS SWITCH         45960053
         NI    SWT1,NOT-CRNL            TURN OFF CR/NL FLAG SWITCH      46020053
         BCTR  RPARM,ZERO               DO NOT INCLUDE IN MOVE COUNT    46080053
         SPACE 2                                                        46140053
TCBUFCHK EQU   *                                                        46200053
         CR    RPARM,RTEMPA             TOO MUCH DATA FOR TCAM BUFFER   46230053
         BNH   SPART1                   NO, BRANCH                      46260053
REMOVEN1 EQU   *                                                        46320053
         TM    SWT1,BYPFLAG             IS BYPASS SWITCH SET            46400053
         BZ    SPART                    NO, CHECK LINESIZE REMAINING    46440053
         NI    SWT1,NOT-BYPFLAG         TURN OFF BYPASS FLAG SWITCH     46500053
         LA    RTEMPA,ONE(RTEMPA)       ADD BACK BUFFER SIZE            46530053
         BCTR  RPARM,ZERO               DO NOT INCLUDE IN MOVE COUNT    46560053
         B     TCBUFCHK                 BRANCH TO CHECK TCAM BUFFERSIZE 46620053
         SPACE 2                                                        46680053
*  CAN SEND ONLY PART OF MSG AS NOT ENOUGH ROOM ON LINE                 46740053
SETRET12 EQU   *                                                        46800053
         LH    RPARM,LINE               SET COUNT TO LINESIZE AVAILABLE 46830053
         MVI   SWT2,RETCOD12            SET RETURN CODE 12              46860053
         BR    RLINK                    TO SEND LINESIZE AVAILABLE      46920053
         SPACE 2                                                        46980053
*  CAN SEND ONLY PART OF MSG AS NOT ENOUGH TCAM BUFFER ROOM             47040053
SPART    EQU   *                                                        47100053
         LR    RPARM,RTEMPA             SET LENGTH EQUAL TO TCAM BUFFER 47130053
SPART1   EQU   *                                                        47160053
         CH    RPARM,LINE               IS TCAM BUFFER LARGER THAN LINE 47220053
         BNL   SETRET12                 YES, SET FOR PARTIAL LINE       47280053
         MVI   SWT2,RETCOD8             SET RETURN CODE 8               47340053
         BR    RLINK                    TO FILL TCAM BUFFER             47400053
         SPACE 2                                                        47430053
*  NO ROOM LEFT IN TCAM BUFFER                                          47460053
NOBUFLEF EQU   *                                                        47520053
         MVI   SWT2,RETCOD40            INDICATE NO ROOM LEFT TCAM BUF  47580053
         BR    RLINK                    RETURN                          47640053
         SPACE 2                                                SA61765 47700053
*   NO DATA TO MOVE                                             SA61765 47730053
NODATA   EQU   *                                                SA61765 47760053
         MVI   SWT2,RETCOD44            INDICATE ALREADY MOVED  SA61765 47850053
         BR    RLINK                    RETURN                  SA61765 47880053
         EJECT                                                          47940053
EDIT     EQU   *                        EDIT ROUTINE                    48000053
         SPACE 2                                                        48030053
*********************************************************************** 48060053
**  RPARM HAS THE AMOUNT OF DATA TO BE MOVED. RTSBUF/BTCBUF ARE THE  ** 48120053
**  MOVE ADDRESSES                                                   ** 48180053
*********************************************************************** 48240053
         SPACE 2                                                        48300053
         ST    RLINK,AVTDOUBL+FOUR      SAVE RETURN ADDRESS REGISTER    48330053
         XC    DEND(FOUR),DEND          ZERO NON-PRINT COUNT            48360053
         LR    RZERO,RPARM              SAVE COUNT OF DATA TO BE MOVED  48410053
         TM    WFLGS,TSOMSG             IS IT A MSGGEN           Y00522 48460053
         BZ    EDIT01                   YES, BRANCH              Y00522 48510053
         XC    MSGNLNTH,MSGNLNTH        CLEAR OUT SCREEN CONT FLGY00522 48560053
EDIT01   EQU   *                                                 Y00522 48610053
         CLI   0(RTSBUF),RESTORE        IS FIRST CHARACTER RESTORE      48660053
         BNE   NOTRESTR                 NO, MOVE DATA TO TCAM BUFFER    48720053
         TM    WFLGS,ASISCNTL           IS THIS ASIS CONTROL    SA60002 48780053
         BO    RESTASIS                 YES, CHANGE ATTRIBUTE   SA60002 48840053
         TM    WFLGS,CONTROLM           IS THIS CONTROL MODE            48900053
         BO    NOTRESTR                 YES, BRANCH TO MOVE DATA        48930053
RESTASIS EQU   *                                                SA60002 48960053
         BAL   RLINK,STARTFLD           INSERT START FIELD              49020053
         MVI   ZERO(RTCBUF),WRITEATT    INSERT WRITE ATTRIBUTE BYTE     49080053
         LA    RTCBUF,ONE(RTCBUF)       ADD ONE TO TCAM BUFFER          49140053
         LA    RTSBUF,ONE(RTSBUF)       ADD ONE TO TSO BUFFER           49180053
         BCTR  RPARM,ZERO               MINUS 1 FOR RESTORE     SA60311 49220053
         LTR   RPARM,RPARM              IS DATA COUNT ZERO      SA60311 49260053
         BNP   RESCOUNT                 YES, EDIT IS COMPLETE   SA67086 49300053
NOTRESTR EQU   *                                                        49340053
         LR    RTEMPA,RPARM             GET COUNT OF DATA MOVE  SA60311 49380053
         BCTR  RTEMPA,ZERO              REDUCE COUNT BY 1 FOR EXECUTE   49420053
         EX    RTEMPA,MOVDATA           MOVE DATA TO TCAM BUFFER        49460053
         SPACE 2                                                        49500053
         LR    RPARM,RTCBUF             ADDRESS OF DATA TO BE EDITED    49540053
         LR    RRTN,RPARM               FIND ADDRESS OF LAST CHARACTER  49580053
         AR    RRTN,RTEMPA                   TO BE EDITED               49620053
EDITEXEC EQU   *                                                        49660053
         SR    RPARM2,RPARM2            CLEAR ARGUMENT REGISTER         49700053
**  AFTER EXECUTING TRANSLATE AND TEST -- RPARM WILL HAVE ADDRESS OF    49740053
**  THE ARGUMENT BYTE.  RPARM2 WILL HAVE TRANSLATE TABLE ARGUMENT.      49780053
         TM    WFLGS,ASISCNTL           IS THIS ASIS CONTROL    SA60002 49820053
         BO    EDITTEST                 YES, TEST DATA          SA60002 49860053
         TM    WFLGS,CONTROLM           IS THIS CONTROL MODE            49900053
         BO    CNTRLCK                  YES, CHECK FOR CONTROL CHARS    49940053
         SPACE 2                                                        49980053
EDITTEST EQU   *                                                SA60002 50020053
         EX    RTEMPA,TRNSEDIT          TRANSLATE/TEST DATA             50060053
         BZ    RESCOUNT                 EDIT IS COMPLETE                50100053
         SPACE 2                                                        50140053
         SLL   RPARM2,TWO               MULTIPLY OFFSET BY FOUR         50180053
EDITBRCH EQU   *                        EDIT BRANCH TABLE               50220053
         B     EDITBRCH(RPARM2)         BRANCH TO EDIT BRANCH OFFSET    50260053
         B     REPLCHAR                 01 REPLACE INVALID CHARACTER    50300053
         B     CARRETRN                 02 CARRIAGE RETURN ADDRESS      50340053
         B     BUFFADDR                 03 SBA/EUA/SF/RTA CHAR  SA60002 50380053
         B     INSERTCU                 04 INSERT CURSOR CHARACTER60002 50420053
         B     BYPASSCH                 05 BYPASS CHARACTER     SA60002 50460053
         EJECT                                                          50500053
*   THE FOLLOWING CODE REPLACES AN INVALID CHARACTER WITH A COLON     * 50540053
REPLCHAR EQU   *                                                        50580053
CARRETRN EQU   *                        CR/NL CHARACTER                 50620053
         MVI   0(RPARM),COLON           REPLACE INVALID CHARACTER       50660053
         B     NEXTCHRT                 BRANCH TO INCREMENT POINTER     50700053
         SPACE 2                                                        51120053
BUFFADDR EQU   *                        SBA/EUA/SF/RTA CHARACTERSA60002 51180053
         TM    WFLGS,TSOASIS            IS THIS ASIS MODE               51246053
         BZ    REPLCHAR                 NO, REPLACE INVALID CHARACTER   51300053
         B     NONPRINT                 BRANCH TO NON-PRINT             51350053
         SPACE 2                                                        51400053
INSERTCU EQU   *                        INSERT CURSOR CHARACTER SA60002 51450053
         TM    WFLGS,TSOASIS            IS THIS ASIS MODE       SA60002 51500053
         BZ    REPLCHAR                 NO, REPLACE INVALID CHARSA60002 51550053
         TM    WFLGS,ASISCNTL           IS THIS ASIS CONTROL    SA61765 51600053
         BO    NONPRINT                 YES, BRANCH TO NON-PRINTSA61765 51650053
         CR    RRTN,RPARM               IS THIS LAST CHARACTER  SA60002 51700053
         BNE   REPLCHAR                 NO, REPLACE INVALID CHARSA60002 51750053
         TM    FLAG1,INCSW              IS INC FLAG SET         SA60002 51800053
         BZ    REPLCHAR                 NO, REPLACE INVALID CHARSA60002 51850053
         B     NONPRINT                 BRANCH TO NON-PRINT     SA60002 51900053
         SPACE 2                                                        51940053
BYPASSCH EQU   *                        BYPASS CHARACTER                51960053
         TM    WFLGS,ASISCNTL           IS THIS ASIS CONTROL    SA60002 52020053
         BO    REPLCHAR                 YES, REPLACE INVALID CHARA60002 52080053
         CR    RRTN,RPARM               IS THIS LAST CHARACTER TO EDIT  52140053
         BE    SFATTRIB                 YES,INSERT START FIELD/ATTRIB   52200053
         LR    RLINK,RPARM              GET BUFFER POINTER              52230053
         LA    RLINK,ONE(RLINK)         ADD ONE TO IT                   52260053
         CR    RRTN,RLINK               IS THIS LAST CHARACTER          52320053
         BNE   REPLCHAR                 NO, REPLACE BYPASS CHARACTER    52380053
         TM    SWT1,CRNL                IS CR/NL CHARACTER LAST         52440053
         BZ    REPLCHAR                 NO, REPLACE BYPASS CHARACTER    52500053
SFATTRIB EQU   *                                                        52530053
         TM    SWT1,BYPFLAG             IS BYPASS SWITCH SET            52560053
         BZ    REPLCHAR                 NO, REPLACE INVALID CHARACTER   52620053
CNTBYPAS EQU   *                                                        52680053
         MVI   ZERO(RPARM),SF           INSERT START FIELD              52740053
         LA    RPARM,ONE(RPARM)         ADD ONE TO BUFFER ADDRESS       52800053
         LA    RRTN,ONE(RRTN)           ADD ONE FOR NEW LAST CHARACTER  52830053
         MVI   ZERO(RPARM),BYPATTR      INSERT BYPASS ATTRIBUTE BYTE    52860053
         B     BUFBYRES                 BRANCH TO UPDATE COUNT          52920053
         SPACE 2                                                        52980053
CNTRESTR EQU   *                                                        53040053
         MVI   ZERO(RPARM),SF           INSERT START FIELD              53100053
         LA    RPARM,ONE(RPARM)         ADD ONE TO BUFFER ADDRESS       53130053
         LA    RRTN,ONE(RRTN)           ADD ONE FOR NEW LAST CHARACTER  53160053
         MVI   ZERO(RPARM),WRITEATT     INSERT WRITE ATTRIBUTE BYTE     53220053
BUFBYRES EQU   *                                                        53280053
         BAL   RLINK,MOVEDONE           UPDATE TCAM BUFFER POINTER      53340053
         OI    SWT1,BYPFLAG             SET BYPASS/RESTORE FLAG         53400053
         B     NEXTCHRT                 INCREMENT POINTER       SA68024 53430053
         EJECT                                                          53460053
CNTRLCK  EQU   *                        CONTROL CHARACTERS CHK ROUTINE  53520053
         EX    RTEMPA,TRNSCONT          TRANSLATE/TEST CONTROL CHARS    53580053
         BZ    RESCOUNT                 CONTROL CHARS CHECK DONE        53640053
         SPACE 2                                                        53700053
         SLL   RPARM2,TWO               MULTIPLY OFFSET BY FOUR         53730053
CNTLBRCH EQU   *                        CONTROL BRANCH TABLE            53760053
         B     CNTLBRCH(RPARM2)         BRANCH TO CONTROL BRANCH OFFSET 53820053
         B     CNTCOLON                 01  REPLACE INVALID CHARACTER   53880053
         B     CNTREMOT                 02  REMOTE CONTROL VALID        53940053
         B     CNTRESTR                 03  RESTORE CHARACTER           54000053
         B     CNTBYPAS                 04  BYPASS CHARACTER            54030053
         SPACE 2                                                        54060053
CNTREMOT EQU   *                                                        54120053
         TM    AVTPARM3+TWO,R3270       IS THIS 3270 REMOTE             54180053
         BO    NEXTCHRT                 YES, INCREMENT TO NEXT          54240053
CNTCOLON EQU   *                                                        54300053
*  THE FOLLOWING CODE REPLACES NON-CONTROL CHARACTERS WITH A COLON    * 54330053
         MVI   0(RPARM),COLON           REPLACE INVALID CHARACTER       54360053
         SPACE 2                                                        54420053
NONPRINT EQU   *                                                        54480053
         LH    RLINK,DEND+TWO           GET PRINT/NON-PRINT COUNT       54540053
         LA    RLINK,ONE(RLINK)         ADD ONE TO COUNT                54600053
         STH   RLINK,DEND+TWO           STORE PRINT/NON-PRINT COUNT     54630053
         SPACE 2                                                        54660053
NEXTCHRT EQU   *                                                        54720053
         LA    RPARM,ONE(RPARM)         INCREMENT TO NEXT CHARACTER     54780053
         LR    RTEMPA,RRTN              GET ADDRESS OF LAST CHARACTER   54840053
         SR    RTEMPA,RPARM             DETERMINE NEW COUNT FOR         54900053
*                                       TRANSLATE AND TEST EXECUTION    54930053
*                                       AND IF DIFFERENCE IS NOT MINUS  54960053
         BNM   EDITEXEC                 BRANCH TO EXECUTE               55020053
         SPACE 2                                                        55080053
RESCOUNT EQU   *                                                        55140053
         LR    RPARM,RZERO              RESTORE COUNT OF DATA MOVED     55200053
         SPACE 2                                                        55230053
         TM    WFLGS,ASISCNTL           IS THIS ASIS CONTROL    SA60002 55260053
         BO    EDITDONE                 YES, UPDATE ADDRESSES   SA60002 55320053
         TM    WFLGS,CONTROLM           IS THIS CONTROL MODE            55380053
         BZ    EDITDONE                 NO, BRANCH TO UPDATE ADDRESSES  55440053
CONTDONE EQU   *                                                        55500053
         SH    RPARM,DEND+TWO           SUBTRACT PRINT COUNT            55530053
         STH   RPARM,DEND+TWO           STORE NON-PRINT COUNT           55560053
         LR    RPARM,RZERO              RESTORE COUNT OF DATA MOVED     55620053
         SPACE 2                                                        55700053
EDITDONE EQU   *                        UPDATE POINTERS AND COUNTS      55740053
         BAL   RLINK,UPDATE             UPDATE COUNTS, POINTERS, ETC    55800053
         L     RTIOC,TSCURR             GET CURRENT TS BUFFER           55830053
         L     RLINK,AVTDOUBL+FOUR      RESTORE RETURN REGISTER         55860053
         BR    RLINK                    RETURN                          55920053
         EJECT                                                          55980053
*********************************************************************** 56040053
*   THIS ROUTINE UPDATES TIOC/TCAM POINTERS AND LINE COUNTERS         * 56100053
*********************************************************************** 56130053
UPDATE   EQU   *                                                        56160053
         AR    RTSBUF,RPARM             UPDATE TS BUFR POINTER          56220053
         AR    RTCBUF,RPARM             UPDATE TCAM BUFR POINTER        56280053
UPDATE1  EQU   *                                                        56340053
         LH    RDCB,MSGLEN              MSG LENGTH PASSED               56400053
         SR    RDCB,RPARM               LESS NUMBER CHARS MOVED         56430053
         STH   RDCB,MSGLEN              STORE IT BACK                   56460053
         L     RDCB,FROMR               NUMBER REMOVED FROM TS BUFFER   56520053
         AR    RDCB,RPARM               PLUS THOSE REMOVED NOW          56580053
         ST    RDCB,FROMR               STORE IT BACK                   56640053
         LH    RDCB,LINE                AVAILABLE LINE SIZE             56700053
         SR    RDCB,RPARM               LESS MESSAGE LENGTH             56730053
         AH    RDCB,DEND+TWO            LESS NON-PRINT COUNT            56760053
         STH   RDCB,LINE                STORE IT BACK                   56820053
         LH    RDCB,BLNTH               NO OF CHAR IN TS BUFFER         56880053
         SR    RDCB,RPARM               REDUCE BY NUMBER MOVED          56940053
         STH   RDCB,BLNTH               STORE IT BACK                   57000053
         LH    RDCB,MOVED               AMOUNT REMOVED FROM 1 TS BUFR   57030053
         AR    RDCB,RPARM               PLUS NO MOVED THIS TIME         57060053
         STH   RDCB,MOVED               STORE IT BACK                   57120053
         SPACE 2                                                        57180053
UPDTE    EQU   *                                                        57240053
         LH    RDCB,WBUFSZ              CURRENT TCAM BUFFER SIZE        57300053
         SR    RDCB,RPARM               SUBTRACT NUMBER CHARS MOVED     57330053
         STH   RDCB,WBUFSZ              STORE REMAINDER                 57360053
         L     RDCB,TOR                 'TO' COUNT TO BE RETURNED       57420053
         AR    RDCB,RPARM               ADD NUMBER CHARS MOVED          57480053
         ST    RDCB,TOR                 STORE IT BACK                   57540053
         LH    RDCB,CARCT               CURRENT LINE POSITION COUNT     57600053
         CLC   LINESV+ONE(ONE),CARCT+ONE LINESIZE>LINECOUNT             57630053
         BH    UPDTCART                 YES, BRANCH AROUND RESET        57660053
         SR    RDCB,RDCB                SET COUNT TO ZERO               57720053
UPDTCART EQU   *                                                        57780053
         AR    RDCB,RPARM               ADD NUMBER MOVED                57840053
         SH    RDCB,DEND+TWO            SUBTRACT NON-PRINT COUNT        57900053
         BP    UPDTE1                   DO NOT ALLOW NEGATIVE COUNT     57930053
         SR    RDCB,RDCB                SET COUNT TO ZERO               57960053
UPDTE1   EQU   *                                                        58020053
         STH   RDCB,CARCT               STORE IT BACK                   58080053
         BR    RLINK                    RETURN                          58140053
         EJECT                                                          58200053
MOVEDON1 EQU   *                                                        58230053
         CLI   LINE+ONE,ZERO            IS AVAILABLE LINE SIZE ZERO     58260053
         BE    MOVEDON2                 YES, DO NOT COUNT MOVE          58320053
         LH    RTEMP,LINE               AVAILABLE LINE SIZE             58380053
         BCTR  RTEMP,ZERO               SUBTRACT ONE FROM IT            58440053
         STH   RTEMP,LINE               STORE IT BACK                   58500053
MOVEDON2 EQU   *                                                        58530053
         LH    RTEMP,CARCT              CURRENT LINE POSITION COUNT     58560053
         CLC   LINESV+ONE(ONE),CARCT+ONE LINESIZE>LINECOUNT             58620053
         BNH   MOVEDONE                 NO, DO NOT COUNT                58680053
         LA    RTEMP,ONE(RTEMP)         ADD ONE TO IT                   58740053
         STH   RTEMP,CARCT              STORE IT BACK                   58800053
         SPACE 2                                                        58830053
*********************************************************************** 58860053
*   THIS ROUTINE UPDATES TCAM POINTERS AND DATA COUNTERS              * 58920053
*********************************************************************** 58980053
MOVEDONE EQU   *                        UPDATE POINTERS ROUTINE         59040053
         LA    RTCBUF,ONE(RTCBUF)       BUMP TCAM BUFFER ADDRESS PTR    59100053
         TM    FLAG2,NOMOVECT           IS NO MOVECOUNT FLAG SET        59130053
         BCR   ONE,RLINK                YES, DO NOT COUNT MOVE          59160053
         L     RTEMP,TOR                GET 'TO' COUNT                  59220053
         LA    RTEMP,ONE(RTEMP)         ADD ONE TO IT                   59280053
         ST    RTEMP,TOR                AND SAVE IT                     59340053
         LH    RTEMP,MSGNLNTH           GET TOTAL MOVED COUNT    Y00522 59400053
         LA    RTEMP,ONE(RTEMP)         ADD ONE                  Y00522 59430053
         STH   RTEMP,MSGNLNTH           STORE BACK NEW COUNT     Y00522 59460053
         LH    RTEMP,WBUFSZ             SIZE OF TCAM BUFFER             59520053
         BCTR  RTEMP,ZERO               DECREMENT BY ONE                59580053
         STH   RTEMP,WBUFSZ             UPDATE TCAM BUFFER SIZE         59640053
         BR    RLINK                    RETURN                          59700053
         EJECT                                                          59730053
STXFIRST EQU   *                        STX INSERT ROUTINE              59760053
         NC    WBUFSZ,WBUFSZ            ANY MORE ROOM IN TCAM BUFFER    59820053
         BCR   EIGHT,RLINK              NO, RETURN                      59880053
         MVI   ZERO(RTCBUF),STX         INSERT STX CHARACTER            59940053
         B     MOVEDONE                 UPDATE COUNT, PTR AND RETURN    60000053
         SPACE 2                                                        60030053
ESCINST  EQU   *                        ESCAPE CONTROL INSERT ROUTINE   60060053
         NC    WBUFSZ,WBUFSZ            ANY MORE ROOM IN TCAM BUFFER    60120053
         BCR   EIGHT,RLINK              NO, RETURN                      60180053
         MVI   ZERO(RTCBUF),ESC         INSERT ESC CHARACTER            60240053
         B     MOVEDONE                 UPDATE COUNT, PTR AND RETURN    60300053
         SPACE 2                                                        60330053
CMDOPINS EQU   *                        INSERT COMMAND OPERATOR ROUTINE 60360053
         NC    WBUFSZ,WBUFSZ            ANY MORE ROOM IN TCAM BUFFER    60420053
         BCR   EIGHT,RLINK              NO, RETURN                      60480053
         MVI   ZERO(RTCBUF),CMD         INSERT COMMAND OPERATOR CHAR    60540053
         B     MOVEDONE                 UPDATE COUNT, PTR AND RETURN    60600053
         SPACE 2                                                        60630053
WCCINST  EQU   *                        WRITE CONTROL CHAR ROUTINE      60660053
         NC    WBUFSZ,WBUFSZ            ANY MORE ROOM IN TCAM BUFFER    60720053
         BCR   EIGHT,RLINK              NO, RETURN                      60780053
         MVI   ZERO(RTCBUF),WCC         INSERT WRITE CONTROL CHARACTER  60840053
         B     MOVEDONE                 UPDATE COUNT, PTR AND RETURN    60900053
         SPACE 2                                                        60930053
WCCDEFLT EQU   *                        DEFAULT WCC ROUTINE     SA60002 60960053
         NC    WBUFSZ,WBUFSZ            ANY MORE ROOM IN TCAM BUFA60002 61020053
         BCR   EIGHT,RLINK              NO, RETURN              SA60002 61080053
         MVI   ZERO(RTCBUF),WCCDEF      INSERT DEFAULT WCC      SA60002 61140053
         B     MOVEDONE                 UPDATE COUNT, PTR AND RETURN    61200053
         SPACE 2                                                        61230053
STARTFLD EQU   *                        START FIELD ORDER ROUTINE       61260053
         NC    WBUFSZ,WBUFSZ            ANY MORE ROOM IN TCAM BUFFER    61320053
         BCR   EIGHT,RLINK              NO, RETURN                      61380053
         MVI   ZERO(RTCBUF),SF          INSERT START FIELD ORDER        61440053
         OI    SWT1,SFATTSW             SET START FIELD FLAG            61500053
         B     MOVEDONE                 UPDATE COUNT,PTR AND RETURN     61530053
         SPACE 2                                                        61560053
WRATTRIB EQU   *                        WRITE ATTRIBUTE INSERTION       61620053
         NC    WBUFSZ,WBUFSZ            ANY MORE ROOM IN TCAM BUFFER    61680053
         BCR   EIGHT,RLINK              NO, RETURN                      61740053
         MVI   ZERO(RTCBUF),WRITEATT    INSERT WRITE ATTRIBUTE BYTE     61800053
         OI    SWT1,WRATTSW             SET WRITE ATTRIBUTE BYTE FLAG   61830053
         B     MOVEDON1                 UPDATE COUNT, PTR AND RETURN    61860053
         SPACE 2                                                        61920053
RDATTRIB EQU   *                        READ ATTRIBUTE INSERTION        61980053
         NC    WBUFSZ,WBUFSZ            ANY MORE ROOM IN TCAM BUFFER    62040053
         BCR   EIGHT,RLINK              NO, RETURN                      62100053
         MVI   ZERO(RTCBUF),READATT     INSERT READ ATTRIBUTE BYTE      62130053
         OI    SWT1,RDATTNLF            SET READ ATTRIBUTE BYTE FLAG    62160053
         TM    FLAG2,NWLNCNT            IS LINE COUNT FLAG SET          62244053
         BO    MOVEDONE                 YES, BRANCH AROUND CARCT        62280053
         TM    QCBRETCT,QCBIEND         IS SCREEN FORMAT FLAG SET       62340053
         BO    MOVEDONE                 YES, BRANCH AROUND CARCT        62400053
         B     MOVEDON1                 UPDATE COUNT, PTR AND RETURN    62430053
         SPACE 2                                                        62460053
INSTCURS EQU   *                                                        62520053
         NC    WBUFSZ,WBUFSZ            ANY MORE ROOM IN TCAM BUFFER    62580053
         BCR   EIGHT,RLINK              NO, RETURN                      62640053
         MVI   ZERO(RTCBUF),INC         INSERT CURSOR ORDER             62700053
         OI    FLAG1,INCSW              SET INSERT CURSOR FLAG          62730053
         B     MOVEDONE                 UPDATE COUNT, PTR AND RETURN    62760053
         SPACE 2                                                        62820053
ETXEND   EQU   *                        ETX INSERT  ROUTINE             62880053
         NC    WBUFSZ,WBUFSZ            ANY MORE ROOM IN TCAM BUFFER    62940053
         BCR   EIGHT,RLINK              NO, RETURN                      63000053
         MVI   ZERO(RTCBUF),ETX         INSERT ETX CHARACTER            63030053
         OI    FLAG1,ETXSW              SET ETX FLAG                    63060053
         B     MOVEDONE                 UPDATE COUNT, PTR AND RETURN    63120053
         SPACE 2                                                        63180053
EOTEND   EQU   *                                                        63240053
         NC    WBUFSZ,WBUFSZ            ANY MORE ROOM IN TCAM BUFFER    63300053
         BCR   EIGHT,RLINK              NO, RETURN                      63330053
         MVI   ZERO(RTCBUF),EOT         INSERT EOT CHARACTER            63360053
         OI    FLAG1,EOTSW              SET EOT FLAG                    63440053
         B     MOVEDONE                 UPDATE COUNT, PTR AND RETURN    63480053
         EJECT                                                          63540053
CNTLHDRS EQU   *                        INSERT CONTROL HEADER ROUTINE   63600053
         SPACE 2                                                        63630053
*********************************************************************** 63660053
*   THIS ROUTINE INSERTS THE PROPER LINE CONTROL CHARACTERS IN THE    * 63720053
*   TCAM/SCB HEADER AREA.                                             * 63780053
*********************************************************************** 63840053
         SPACE 2                                                        63900053
         STM   RLINK,RRTN,AVTDOUBL      SAVE LINKING REGISTERS          63930053
         XC    DEND(FOUR),DEND          ZERO NON-PRINT COUNT            63960053
         TM    WFLGS,TSOMSG             TSO OR MSGGEN ENTRY     SA61765 64020053
         BZ    CNTLMSG                  MSGGEN ENTRY            SA61765 64080053
         TM    FLAG2,HEADERFG           IS THIS FIRST BASIC UNITSA61765 64140053
         BZ    CNTLHDR1                 NO, ADD SUBSEQUENT HDR  SA61765 64200053
CNTLMSG  EQU   *                                                SA61765 64230053
         TM    AVTPARM3+TWO,L3270       IS THIS 3270 LOCAL              64260053
         BO    LOCALWCC                 YES, BRANCH TO CHECK FOR WCC    64320053
         TM    FLAG2,X3705              IS THE 3270 ON A 3705    Y00522 64380053
         BO    YES3705A                 YES, BRANCH              Y00522 64440053
         BAL   RLINK,STXFIRST           GO INSERT STX            Y00522 64500053
YES3705A EQU   *                                                 Y00522 64530053
         TM    WFLGS,TSOASIS+CONTROLM   IS THIS ASIS OR CONTROL SA59194 64560053
         BNZ   ASISESC                  YES, CHECK FOR ESCAPE   SA59194 64620053
CNTLESC  EQU   *                                                SA59194 64680053
         BAL   RLINK,ESCINST            INSERT ESCAPE CONTROL CHAR      64740053
         BAL   RLINK,CMDOPINS           INSERT COMMAND OPERATOR         64800053
CNTLASCK EQU   *                                                        64830053
         TM    WFLGS,TSOASIS+CONTROLM   IS THIS ASIS OR CONTROL SA59194 64860053
         BO    ASISCNT                  ASIS CONTROL MODE       SA60002 64920053
         BNZ   SBACHECK                 YES, CHECK SBA ORDER    SA59194 64980053
NOTSBA   EQU   *                                                        65040053
         BAL   RLINK,WCCINST            INSERT WCC ORDER                65100053
         TM    QCBFLAG,QCBTSSES         TS SESSION STARTED              65130053
         BO    CNTWCCTS                 YES, BRANCH                     65160053
         BCTR  RTCBUF,ZERO              BACK UP ONE CHARACTER           65220053
         MVI   ZERO(RTCBUF),WCCRESTR    INSERT KEYBOARD RESTORE WCC     65280053
         LA    RTCBUF,ONE(RTCBUF)       RESTORE TCAM BUFFER             65340053
CNTWCCTS EQU   *                                                        65400053
         TM    QCBRETCT,QCBIEND         IS SCREEN FORMAT FLAG SET       65430053
         BZ    NOSCRFRM                 NO, BRANCH AROUND FORMAT        65460053
         OI    WFLGS,FMTFLAG            SET FORMAT FLAG          Y00522 65520053
         MVC   SAVX1(TWO),ATT480        SAVE 480 CURSOR POSITION        65580053
         CLI   LINESV+ONE,FORTY         IS THIS 480 SCREEN              65620053
         BE    SCREEN48                 YES, BRANCH TO FORMAT 480 SCRN  65700053
         CLI   LINESV+ONE,EIGHTY        IS THIS 1920 SCREEN             65730053
         BNE   NOSCRFRM                 NO, FORGET FORMAT               65760053
         MVC   SAVX1(TWO),ATT1920       SAVE 1920 CURSOR POSITION       65820053
SCREEN48 EQU   *                                                        65900053
         BAL   RLINK,SBAINSRT           INSERT SBA ORDER AND CURSOR     65920053
         BAL   RLINK,STARTFLD           INSERT FIELD ORDER              66000053
         BAL   RLINK,RDATTRIB           INSERT READ ATTRIBUTE BYTE      66030053
NOSCRFRM EQU   *                                                        66060053
         LTR   RTSBUF,RTSBUF            ENTRY FOR NEW LINE              66120053
         BZ    CHKCARCT                 YES, CHECK LINE COUNT           66180053
CNTLHDR1 EQU   *                                                        66240053
         BAL   RLINK,CALCURSR           CALCULATE CURSOR ADDRESS        66300053
         BAL   RLINK,SBAINSRT           INSERT SBA ORDER AND CURSOR     66330053
         TM    QCBFLAG,QCBTSSES         TS SESSION STARTED              66360053
         BZ    CNTLRETN                 NO, BRANCH TO RETURN            66420053
         LTR   RTSBUF,RTSBUF            ENTRY FOR NEW LINE              66480053
         BZ    NLRDATT                  YES, BRANCH TO INSERT SF        66540053
         TM    WFLGS,ASISCNTL           IS THIS ASIS CONTROL    SA60002 66600053
         BO    CNTLHDR3                 YES, CHECK UNITS        SA60002 66630053
         TM    WFLGS,CONTROLM           IS THIS CONTROL MODE            66700053
         BO    CNTLRETN                 YES, BRANCH FOR RETURN          66720053
CNTLHDR3 EQU   *                                                SA60002 66780053
         TM    FLAG2,HEADERFG           IS THIS FIRST BASIC UNIT        66840053
         BZ    CNTLHDR2                 NO, BRANCH                      66900053
         TM    BUFFFL1,BUFFHDR          IS THIS TSO HEADER BUFFER       66930053
         BO    CNTLHDR2                 YES, BRANCH TO INSERT           66960053
         CLI   QCBSATCT,ZERO            IS THIS LINE ZERO               67020053
         BNE   CNTLRETN                 NO, BRANCH TO RETURN            67080053
         CLI   QCBCARCT,ZERO            IS LINE POSITION COUNT ZERO     67140053
         BNE   CNTLRETN                 NO, BRANCH TO RETURN            67200053
CNTLHDR2 EQU   *                                                        67230053
         TM    WFLGS,TSOMSG             IS THIS A MSGGEN         Y00522 67260053
         BO    CNTLHDR5                 NO, BRANCH               Y00522 67320053
         LA    RLINK,CNTLHDR6           SET UP RETURN ADDRESS    Y00522 67380053
         B     STARTFLD                 GO PUT IN START FIELD    Y00522 67420053
CNTLHDR5 EQU   *                                                 Y00522 67460053
         CLI   MSGNLNTH,STFLDFLG        IS THE START FIELD THERE Y00522 67500053
         BNH   CNTLHDR6                 YES, DONT PUT IN ANOTHER Y00522 67560053
         BAL   RLINK,STARTFLD           GO PUT IN START FIELD    Y00522 67640053
         TM    SWT1,SFATTSW             ROOM FOR START FIELD     Y00522 67680053
         BZ    CNTLHDR6                 NO, BRANCH               Y00522 67750053
         MVI   MSGNLNTH,STFLDFLG        INDICATE START FILED     Y00522 67800053
CNTLHDR6 EQU   *                                                 Y00522 67830053
         TM    WFLGS,TSOMSG             IS THIS A MSGGEN         Y00522 67860053
         BO    CNTLHDR4                 NO, BRANCH               Y00522 67920053
         LA    RLINK,CNTLRETN           SET RETURN ADDRESS       Y00522 67980053
         B     WRATTRIB                 GO PUT IN WRITE ATTR.    Y00522 68040053
CNTLHDR4 EQU   *                                                 Y00522 68100053
         CLI   MSGNLNTH,WRATTFLG        IS WRITE ATTR. ALREADY INY00522 68130053
         BE    CNTLRETN                 YES, DONT NEED ANOTHER   Y00522 68160053
         BAL   RLINK,WRATTRIB           GO PUT IN WRITE ATTR.    Y00522 68220053
         TM    SWT1,WRATTSW             WAS THERE ROOM FOR ONE   Y00522 68280053
         BZ    CNTLRETN                 NO, GET IT IN NEXT UNIT  Y00522 68340053
         MVI   MSGNLNTH,WRATTFLG        INDICATE ONE IN BUFFER   Y00522 68400053
*                                                                     * 68430053
CNTLRETN EQU   *                                                        68460053
         NI    QCBRETCT,NOT-QCBIEND     TURN OFF SCREEN FORMAT FLAG     68520053
         LM    RLINK,RRTN,AVTDOUBL      RESTORE LINKING REGISTERS       68580053
         BR    RLINK                    RETURN                          68640053
*                                                                     * 68700053
         SPACE 2                                                        68730053
LOCALWCC EQU   *                                                        68760053
         TM    QCBTSOF2,QCBDSSMI        IS RESTORE KEYBOARD FLG SET     68840053
         BZ    CNTLASCK                 NO, BRANCH TO CHECK ASIS        68880053
         MVI   ZERO(RTCBUF),WCCRESTR    INSERT KEYBOARD RESTORE WCC     68940053
         CLI   QCBSATCT,ZERO            IS LINE ZERO ?          SA68050 68950053
         BNE   MDTON                    NO, BRANCH              SA68050 68960053
         NI    ZERO(RTCBUF),X'C2'       TURN OFF MDT BIT        SA68050 68970053
MDTON    EQU   *                                                SA68050 68980053
         BAL   RLINK,MOVEDONE           UPDATE COUNT, PTR AND RETURN    69000053
         CLI   0(RTSBUF),ONE            IS MESSAGE COUNT ONE            69030053
         BE    CNTLRETN                 YES, BRANCH TO RETURN           69100053
         TM    WFLGS,TSOMSG             TSO OR MSGGEN MESSAGE   SA59517 69106053
         BO    CHKCARC1                 TSO ENTRY               SA59517 69112053
         B     CNTWCCTS                 NO, SIM ATTN ENTRY              69120053
         SPACE 2                                                        69196053
CHKCARCT EQU   *                                                        69240053
         CLI   QCBSATCT,ZERO            IS THIS LINE ZERO       SA60002 69300053
         BE    CNTLRETN                 YES, BRANCH FOR RETURN  SA60002 69330053
         CLI   CARCT+ONE,NOT            REQUEST LINE RETURN             69396053
         BE    CHKCARC1                 YES, BRANCH TO NEW LINE INSERT  69420053
         CLI   CARCT+ONE,ZERO           DOES IT NEED LEFT ADJUSTMENT    69500053
         BNE   CHKCARC2                 YES, BRANCH TO COUNT LINE       69520053
         TM    QCBRETCT,QCBIEND         IS SCREEN FORMAT FLAG SET       69560053
         BO    CHKCARC1                 YES, BRANCH TO MOVE CURSOR      69600053
         TM    WFLGS,TSOMSG             TSO OR MSGGEN MESSAGE   SA59517 69660053
         BO    CHKCARC1                 TSO ENTRY               SA59517 69680053
         MVI   TOR+THREE,ZERO           RETURN COUNT OF ZERO            69700053
         B     CNTLRETN                 BRANCH FOR RETURN               69750053
CHKCARC2 EQU   *                                                        69780053
         LM    RLINK,RRTN,AVTDOUBL      RESTORE REGISTERS               69840053
         STM   RLINK,RRTN,AVTSAVE2      SAVE REGISTERS                  69900053
         BAL   RLINK,SIMATCAL           UPDATE LINE COUNT               69930053
         LM    RLINK,RRTN,AVTSAVE2      RESTORE REGISTERS               70000053
         STM   RLINK,RRTN,AVTDOUBL      SAVE REGISTERS                  70040053
CHKCARC1 EQU   *                                                        70080053
         MVI   CARCT+ONE,ZERO           CLEAR LINE POSITION COUNT       70140053
         OI    FLAG2,NWLNCNT            SET LINE COUNT FLAG             70190053
         B     CNTLHDR1                 FINISH CONTROL HEADER           70240053
         SPACE 2                                                        70290053
ASISCNT  EQU   *                                                SA60002 70340053
         TM    BUFFFL1,BUFFHDR          IS THIS TSO HEADER      SA60002 70390053
         BO    CNTLRETN                 YES, BRANCH TO RETURN   SA60002 70440053
         BAL   RLINK,WCCDEFLT           INSERT WCC ORDER        SA60002 70500053
         B     CNTLRETN                 BRANCH TO RETURN        SA60002 70540053
         SPACE 2                                                        70580053
NLRDATT  EQU   *                                                        70620053
         CLI   QCBSATCT,ZERO            IS THIS LINE ZERO               70660053
         BE    CNTLRETN                 YES, BRANCH TO RETURN           70700053
         BAL   RLINK,STARTFLD           INSERT START FIELD ORDER        70740053
         BAL   RLINK,RDATTRIB           INSERT READ ATTRIBUTE BYTE      70780053
         NI    FLAG2,NOT-NWLNCNT        TURN OFF LINE COUNT FLAG        70820053
         B     CNTLRETN                 BRANCH TO RETURN                70860053
         SPACE 2                                                        70900053
ASISESC  EQU   *                                                        70940053
         CLI   BLNTH+ONE,TWO            IS TSO BUF COUNT>2      SA60002 70980053
         BL    CNTLESC                  NO- DO NOT CHECK        SA59194 71020053
         CLI   ZERO(RTSBUF),ESC         IS TSO BUFFER CHARACTER ESCAPE  71060053
         BNE   CNTLESC                  NO, INSERT ESC/CMD      SA60002 71100053
         LA    RTEMPA,TWO               SET MOVE CHARACTER COUNTSA60002 71140053
         BAL   RLINK,MOVECHAR           MOVE ESC AND COMMAND    SA60002 71180053
         TM    WFLGS,ASISCNTL           IS THIS ASIS CONTROL    SA60002 71220053
         BO    CNTLUPDT                 BRANCH TO UPDATE        SA60002 71260053
         SPACE 2                                                        71460053
SBACHECK EQU   *                                                        71520053
         CLI   BLNTH+ONE,FOUR           IS TSO BUF COUNT>4      SA59194 71600053
         BL    NOTSBA                   NO- DO NOT CHECK        SA59194 71640053
         CLI   ONE(RTSBUF),SBA          IS TSO BUFFER COMMAND SBA       71700053
         BNE   NOTSBA                   NO, INSERT SBA AND CURSOR       71730053
         LA    RTEMPA,FOUR              SET MOVE CHARACTER COUNT        71760053
         BAL   RLINK,MOVECHAR           MOVE SBA AND CURSOR ADDRESS     71820053
         SPACE 2                                                        71880053
STFLDCHK EQU   *                                                        71940053
         LA    RTEMPA,TWO               SET MOVE CHARACTER COUNT        72000053
         LH    RTEMP,DEND+TWO           GET NON-PRINT COUNT     SA59194 72030053
         AR    RTEMP,RTEMPA             ADD MOVE COUNT          SA59194 72060053
         CH    RTEMP,BLNTH              TSO BUF COUNT GREATER   SA59194 72120053
         BH    CNTLUPDT                 NO- DO NOT CHECK        SA59194 72180053
         LA    RLINK,CNTLUPDT           LINK REGISTER RETURN POINT      72230053
         CLI   ZERO(RTSBUF),SF          IS TSO BUFFER COMMAND STARTFLD  72280053
         BE    MOVECHAR                 YES, MOVE STARTFIELD/ATTRIBUTE  72330053
CNTLUPDT EQU   *                                                        72380053
         LH    RPARM,DEND+TWO           GET NON-PRINT COUNT             72430053
         BAL   RLINK,UPDATE1            UPDATE PTRS, COUNT AND RETURN   72480053
         B     CNTLRETN                 BRANCH TO RETURN                72540053
         SPACE 2                                                        72600053
*                                                                     * 72630053
*   MOVE ASIS CONTROL CHARACTERS                                      * 72660053
*                                                                     * 72720053
MOVECHAR EQU   *                        MOVE ASIS CONTROL CHARACTERS    72780053
         LH    RTEMP,WBUFSZ             GET TCAM BUFFER SIZE REMAINING  72840053
         SR    RTEMP,RTEMPA             SUBTRACT COUNT OF MOVE          72900053
         BCR   TWELVE,RLINK             RETURN IF NOT ENOUGH ROOM       72930053
         LH    RTEMP,DEND+TWO           GET NON-PRINT COUNT             72960053
         AR    RTEMP,RTEMPA             ACCUMULATE MOVED COUNT          73020053
         STH   RTEMP,DEND+TWO           STORE NON-PRINT COUNT           73080053
         BCTR  RTEMPA,ZERO              REDUCE COUNT FOR EXECUTE MOVE   73140053
         EX    RTEMPA,MOVDATA           EXECUTE MOVE INSTRUCTION        73200053
         LA    RTEMPA,ONE(RTEMPA)       ADD BACK COUNT                  73230053
         AR    RTCBUF,RTEMPA            UPDATE TCAM BUFR POINTER        73260053
         AR    RTSBUF,RTEMPA            UPDATE TS BUFR POINTER          73320053
         BR    RLINK                    RETURN                          73380053
         SPACE 2                                                        73440053
         EJECT                                                          73500053
*                                                                     * 73530053
*   THIS ROUTINE VALIDATES CURSOR ADDRESS                             * 73560053
*                                                                     * 73620053
CURSORCK EQU   *                        TO VALIDATE CURSOR ADDRESS      73680053
         LR    RTEMP,RPARM              MOVE CURSOR ADDRESS TO WORKAREA 73740053
         SLL   RTEMP,EIGHTEEN           CONVERT 3270                    73800053
         SRDL  RTEMP,TWENTYSX                CURSOR ADDRESS             73830053
         SLL   RTEMPA,TWO                         TO BINARY             73860053
         SLDL  RTEMP,SIX                               SCREEN POSITION  73920053
         LR    RPARM,RTEMP              SAVE SCREEN POSITION FOR COMPAR 73980053
         SPACE 2                                                        74040053
         SR    RTEMP,RTEMP              CLEAR WORK REGISTER             74100053
         SR    RTEMPA,RTEMPA            CLEAR WORK REGISTER             74130053
         IC    RTEMP,LINESV             GET DISPLAY NUMBER OF LINES     74160053
         IC    RTEMPA,LINESV+ONE        GET DISPLAY LINE SIZE           74220053
         MR    RTEMP,RTEMP              MULTIPLY TO GET SCREEN SIZE     74280053
*                                       IN RTEMPA                       74340053
         LR    RTEMP,RPARM              MOVE SCREEN POSITION TO COMPARE 74400053
         BR    RLINK                    RETURN TO COMPARE               74430053
         EJECT                                                          74460053
CALCURSR EQU   *                        CALCULATE NEW LINE ADDRESS      74520053
         SR    RRTN,RRTN                CLEAR WORK REGISTER             74580053
         CLC   LINESV+ONE(ONE),CARCT+ONE LINESIZE>LINECOUNT             74640053
         BL    CURSLINE                 NO, DON'T INCLUDE COUNT         74700053
         LH    RRTN,CARCT               GET PRESENT CARRIAGE POSITION   74730053
CURSLINE EQU   *                        CALCULATE LINE POSITION ADDRESS 74760053
         SR    RTEMP,RTEMP              CLEAR WORK REGISTER             74820053
         SR    RTEMPA,RTEMPA            CLEAR WORK REGISTER             74880053
         IC    RTEMP,LINESV+ONE         GET DISPLAY LINE SIZE           74940053
         TM    QCBFLAG,QCBTSSES         TS SESSION STACKED ?    OY00488 74960056
         BZ    SATCTOK                  NO, BRANCH              OY00488 74980056
         IC    RTEMPA,QCBSATCT          GET NUMBER OF LINES ENTERED     75000053
         CLI   QCBSATCT,NOT             IS COUNT FOR ERASE              75030053
         BNE   SATCTOK                  NO, BRANCH                      75060053
         IC    RTEMPA,LINESV            GET DISPLAY NO OF LINES         75120053
         BCTR  RTEMPA,ZERO              SUBTRACT ONE FOR CALCULATION    75180053
         TM   FLAG2,PROMPTFG            IS THIS THE SIM ATTN PROMPT     75240053
         BO    SATCTOK                  YES, BRANCH                     75300053
         BCTR  RTEMPA,ZERO              SUBTRACT ONE MORE               75330053
         TM    QCBTSOF2,QCBDSSMI        IS RESTORE KEYBOARD FLG SET     75360053
         BZ    SATCTOK                  NO, BRANCH                      75420053
         MVI   CARCT+ONE,ZERO           CLEAR LINE POSITION COUNT       75480053
         LH    RRTN,CARCT               GET NEW CARRIAGE POSITION       75540053
         LA    RTEMPA,ONE(RTEMPA)       ADD ONE FOR CALCULATION         75600053
SATCTOK  EQU   *                                                        75630053
         MR    RTEMP,RTEMP              MULTIPLY TO GET LINE POSITION   75700053
         LR    RTEMP,RTEMPA             MOVE SCREEN POSITION TO EVENREG 75720053
         LTR   RTSBUF,RTSBUF            ENTRY FOR NEW LINE              75780053
         BNZ   CURSLIN0                 NO, BRANCH AROUND DECREMENT     75848053
         CLI   QCBSATCT,ZERO            IS THIS LINE ZERO               75900053
         BE    CURSLIN0                 YES, BRANCH AROUND DECREMENT    75930053
         BCTR  RTEMP,ZERO               SUBTRACT ONE FROM POSITION      75960053
CURSLIN0 EQU   *                                                        76020053
         TM   FLAG2,PROMPTFG            IS THIS THE SIM ATTN PROMY00522 76080053
         BO    CURSLIN3                 YES, BRANCH              Y00522 76140053
         L     RTEMPA,LCBSCBA-ONE       POINT TO THE SCB         Y00522 76200053
         USING IEDQSCB,RTEMPA           SET UP ADDRESSABILITY    Y00522 76230053
         TM    SCBERR2,SCBALN           IS THIS AUTO LINE NUMBER Y00522 76260053
         BZ    CURSLIN2                 NO, CONTINUE CALCULATING Y00522 76320053
         CLI   MSGLEN+ONE,EIGHT         IS THIS THE LINE NUMBER  Y00522 76380053
         BNH   CURSLIN3                 YES CONTINUE CALCULATION Y00522 76440053
CURSLIN2 EQU   *                                                 Y00522 76500053
         TM    FLAG2,NWLNCNT            IS LINE COUNT FLAG ON           76530053
         BO    CURSLIN1                 YES, BRANCH AROUND DATA COUNT   76560053
CURSLIN3 EQU   *                                                 Y00522 76620053
         AR    RTEMP,RRTN               ADD PRESENT CARRIAGE POSITION   76680053
CURSLIN1 EQU   *                                                        76740053
         SLL   RTEMP,TWENTY             CONVERT BINARY                  76800053
         SRDL  RTEMP,TWENTYSX                SCREEN POSITION            76830053
         SRL   RTEMPA,TWENTYSX                    TO REQUIRED           76860053
         STC   RTEMP,SAVX1                             HARDWARE         76920053
         STC   RTEMPA,SAVX1+ONE                             FORMAT      76980053
         TR    SAVX1(TWO),CONVERTB                                      77040053
         BR    RLINK                    RETURN                          77100053
         EJECT                                                          77130053
NWLNCHRS EQU   *                        CALCULATE NEWLINE ROUTINE       77160053
         STM   RLINK,RRTN,AVTSAVE2      SAVE LINKING REGISTERS          77220053
         BAL   RLINK,SIMATCAL           UPDATE LINE COUNT               77280053
         SPACE 2                                                        77340053
*  LINE COUNT HAS NOW BEEN UPDATED BY 1                               * 77400053
         BAL   RLINK,CALCURSR           CALCULATE CURSOR ADDRESS        77430053
         LM    RLINK,RRTN,AVTSAVE2      RESTORE LINKING REGISTERS       77460053
         BR    RLINK                    RETURN                          77520053
         SPACE 2                                                        77580053
SBAINSRT EQU   *                                                        77640053
         STM   RRTN,RPARM,AVTSAVE2      SAVE PARAMETER REGISTERS        77700053
         NC    WBUFSZ,WBUFSZ            ANY MORE ROOM IN TCAM BUFFER    77730053
         BCR   EIGHT,RLINK              NO, RETURN                      77760053
         LR    RRTN,RLINK              SAVE RETURN REG          OY03457 77790056
        TM    WFLGS,TSOMSG             IS THIS A MSGGEN         Y00522  77820053
         BZ    SBAINST1                 YES, BRANCH              Y00522 77880053
         CLI   MSGNLNTH,AVTEZERO        IS SBA ALREADY THERE     Y00522 77940053
         BNE   SBAINST2                YES DONT PUT IN ANOTHER  OY03457 78000056
         MVI   MSGNLNTH,SBAFLAG         INDICATE SBA THERE       Y00522 78030053
SBAINST1 EQU   *                                                 Y00522 78060053
         MVI   ZERO(RTCBUF),SBA         INSERT SET BUFFER ADDR ORDER    78120053
         BAL   RLINK,MOVEDONE           UPDATE COUNT, PTR AND RETURN    78300053
SBAINST2 EQU   *                                                OY03457 78310056
         OI    SWT1,SBAENDSW           SET SBA FLAG             OY03457 78320056
         BAL   RLINK,CURSADDR           INSERT CURSOR ADDRESS           78330053
         LR    RLINK,RRTN               RESTORE RETURN REGISTER         78360053
         LM    RRTN,RPARM,AVTSAVE2      RESTORE PARAMETER REGISTERS     78420053
         BR    RLINK                    RETURN                          78480053
         SPACE 2                                                        78540053
CURSADDR EQU   *                        INSERT CURSOR ROUTINE           78600053
         NC    WBUFSZ,WBUFSZ            ANY MORE ROOM IN TCAM BUFFER    78630053
         BCR   EIGHT,RLINK              NO, RETURN                      78660053
        TM    WFLGS,TSOMSG             IS THIS A MSGGEN         Y00522  78720053
         BZ    CURSADR1                 YES, BRANCH              Y00522 78780053
         CLI   MSGNLNTH,CUR1FG          IS FIRST CURSOR THERE    Y00522 78840053
         BNH   CURSADR                 YES DONT PUT IT IN AGAIN OY03457 78900056
         MVI   MSGNLNTH,CUR1FG          IND CURSOR 1 THERE       Y00522 78930053
CURSADR1 EQU   *                                                 Y00522 78960053
         MVC   ZERO(ONE,RTCBUF),SAVX1   INSERT FIRST CURSOR ADDRESS     79020053
         LR    RPARM,RLINK              SAVE RETURN REGISTER            79140053
         BAL   RLINK,MOVEDONE           UPDATE COUNT, PTR AND RETURN    79200053
         LR    RLINK,RPARM              RESTORE RETURN REGISTER         79230053
CURSADR  EQU   *                                                OY03457 79240056
         OI    SWT1,CUR1FLAG           SET 1ST CURSOR FLAG      OY03457 79250056
CURSADR2 EQU   *                                                        79260053
         NC    WBUFSZ,WBUFSZ            ANY MORE ROOM IN TCAM BUFFER    79320053
         BCR   EIGHT,RLINK              NO, RETURN                      79400053
        TM    WFLGS,TSOMSG             IS THIS A MSGGEN         Y00522  79440053
         BZ    CURSADR3                 YES, BRANCH              Y00522 79500053
         CLI   MSGNLNTH,CUR2FG          IS CURSOR 2 ALREADY THEREY00522 79530053
         BCR   THIRTEEN,RLINK           YES DONT PUT IT IN AGAIN Y00522 79560053
         MVI   MSGNLNTH,CUR2FG          IND CURSOR 2 ALREADY     Y00522 79620053
CURSADR3 EQU   *                                                 Y00522 79680053
         MVC   ZERO(ONE,RTCBUF),SAVX1+ONE INSERT 2ND CURSOR ADDRESS     79740053
         OI    SWT1,CUR2FLAG            SET 2ND CURSOR FLAG             79800053
         B     MOVEDONE                 UPDATE COUNT, PTR AND RETURN    79830053
         EJECT                                                          79890053
SIMATCAL EQU   *                                                        79940053
         STM   RLINK,RRTN,AVTDOUBL      SAVE LINKING REGISTERS          79980053
         L     RRTN,AVTTSOPT            POINT TO TSO INPUT QCB          80040053
         USING IEDQTSI,RRTN             ESTABLISH ADDRESSABILITY        80100053
         L     RRTN,TSISIMAT            ADDRESS OF SIM ATTN ROUTINE     80130053
         DROP  RRTN                     DROP ADDRESSABILITY             80160053
         LA    RRTN,0(RRTN)             CLEAR HI-ORDER BYTE             80220053
         LTR   RRTN,RRTN                IS SIM ATTN USED                80280053
         BZ    NOSIMAT                  NO, BRANCH TO RETURN            80340053
         TM    WFLGS,ASISCNTL           IS THIS ASIS CONTROL    SA60002 80400053
         BO    NOSIMAT                  YES, DO NOT COUNT LINE  SA60002 80430053
         BAL   RLINK,SIXTEEN(RRTN)      CALL IEDAYS                     80460053
         MVI   CARCT+ONE,ZERO           CLEAR LINE COUNT        SA61765 80520053
         NI    QCBRETCT,NOT-QCBNL       TURN OFF NEWLINE FLAG   SA61765 80580053
NOSIMAT  EQU   *                                                        80640053
         LM    RLINK,RRTN,AVTDOUBL      RESTORE LINKING REGISTERS       80700053
         BR    RLINK                    RETURN                          80730053
         SPACE 2                                                        80760053
QTIPR    EQU   *                        UPDATE TSO BUFFER               80820053
         STM   RLINK,RRTN,AVTSAVE2      SAVE LINKING REGISTERS          80880053
         STM   RZERO,RPARM,AVTDOUBL     SAVE PARAMETER REGISTERS        80940053
         SR    RRTN,RRTN                CLEAR PARAMETER REGISTERSA60002 81000053
         LH    RRTN,MOVED               GET COUNT OF DATA MOVED         81030053
         TM    WFLGS,TSOMSG             IS THIS A MSGGEN         Y00522 81060053
         BO    QTIP00                   NO,GO ISSUE THE REAL QTIPY00522 81120053
         TM    WFLGS,FRSTMGEN           IS THIS FIRST MSGGEN PASSY00522 81180053
         BZ    QTIP0                    NO, BRANCH               Y00522 81240053
         XC    MSGNLNTH(TWO),MSGNLNTH   CLEAR OUT MSGGEN COUNTER Y00522 81300053
QTIP0    EQU   *                                                 Y00522 81330053
         L     RZERO,TOR                GET CURRENT MOVED COUNT  Y00522 81360053
         LH    RRTN,MSGNLNTH            GET PREVIOUS MOVED COUNT Y00522 81420053
         AR    RRTN,RZERO               ACCUMULATE MOVED COUNT   Y00522 81480053
         STH   RRTN,MSGNLNTH            UPDATE TOTAL MOVED COUNT Y00522 81540053
         B     QTIP02                   RETURN                   Y00522 81600053
QTIP00   EQU   *                                                 Y00522 81630053
         LTR   RRTN,RRTN                IS MOVED COUNT ZERO     SA60002 81660053
         BZ    QTIP02                   YES, DO NOT ISSUE QTIP  SA60002 81720053
         L     RPARM2,TSCURR            GET TSO BUFFER ADDRESS          81780053
         TM    QCBRETCT,QCBDEND         IS THIS SECOND ENTRY REQUEST    81840053
         BZ    QTIP01                   NO, BRANCH                      81900053
         BCTR  RRTN,ZERO                LEAVE ONE IN BUFFER TO GET BACK 81930053
QTIP01   EQU   *                                                        81960053
         QTIP  17,AVTSAVE3              UPDATE BUFFER                   82020053
QTIP02   EQU   *                                                SA60002 82080053
         XC    MOVED,MOVED              CLEAR FIELD FOR NEXT PASSY00522 82140053
         LM    RLINK,RRTN,AVTSAVE2      RESTORE LINKING REGISTERS       82200053
         LM    RZERO,RPARM,AVTDOUBL     RESTORE PARAMETER REGISTERS     82230053
         BR    RLINK                    RETURN                          82260053
TRUNCATE EQU   *                                                 Y00522 82320053
         NI    FLAG1,AVTEFF-PARTEND     TURN OFF PART MOVE FLAG  Y00522 82380053
         LA    RLINK,SIX                SET UP CONSTANT          Y00522 82440053
         CH    RLINK,WBUFSZ             ROOM IN TCAM FOR ENDING  Y00522 82500053
         BNH   NORMALSF                 YES, GO PUT IT IN        Y00522 82530053
         LH    RRTN,WBUFSZ              GET REMAINING ROOM LEFT  Y00522 82560053
         AR    RRTN,RLINK               ADD BACK SIX             Y00522 82620053
         STH   RRTN,WBUFSZ              STORE IT BACK            Y00522 82680053
         L     RRTN,TOR                 GET TOTAL MOVED COUNT    Y00522 82740053
         SR    RRTN,RLINK               SUBTRACT SIX             Y00522 82800053
         ST    RRTN,TOR                 STORE IT BACK            Y00522 82830053
         SR    RTCBUF,RTEMP             BACK BUFFER POINTER UP   Y00522 82860053
         B     NORMALSF                 GO PUT IN ENDING SEQUENCEY00522 82920053
         EJECT                                                          82980053
SUCCESS  EQU   *                        RETURN CODE ZERO                83040053
         L     RLINK,LCBSCBA-ONE        GET SCB ADDRESS          Y00522 83050053
         USING IEDQSCB,RLINK            SET ADDRESSABILITY       Y00522 83060053
         TM    SCBERR2,SCBALN           IS THIS AUTO LINE NUMBER Y00522 83070053
         DROP  RLINK                    DROP ADDRESSABILITY      Y00522 83080053
         BNZ   SCRFULL                  YES, BRANCH              Y00522 83090053
         TM    WFLGS,TSOMSG             IS THIS A MSGGEN         Y00522 83100053
         BZ    SUCCESS1                 YES, BRANCH              Y00522 83130053
         XC    MSGNLNTH,MSGNLNTH        CLEAR OUT FLAG BYTES     Y00522 83160053
         B     SCRFULL                  CONTINUE EXIT            Y00522 83190053
SUCCESS1 EQU   *                                                 Y00522 83220053
         XC    CARCT,CARCT              CLEAR CARRIAGE COUNT     Y00522 83250053
SCRFULL  EQU   *                        TS MSG MOVE COMPLETE    SA61765 83280053
         LA    RRTN,RC0                 AND SCREEN IS FULL      SA61765 83340053
         TM    FLAG2,X3705              IS THE 3270 ON A 3705    Y00522 83400053
         BZ    EXIT                     NO, EXIT                 Y00522 83430053
         TM    WFLGS,TSOMSG             IS THIS A MSGGEN         Y00522 83460053
         BO    EXIT                     NO, EXIT                 Y00522 83520053
         ICM   RRTN,ICMASK,MSGNLNTH     SET UP LENGTH MOVED      Y00522 83580053
         XC    MSGNLNTH,MSGNLNTH        CLEAR OUT MOVED COUNT    Y00522 83640053
         B     EXIT                     BRANCH TO EXIT                  83700053
         SPACE 2                                                        83730053
MSGCOMP  EQU   *                        TS MSG MOVE COMPLETE    SA61765 83760053
         LA    RRTN,RC8                 AND SCREEN NOT FULL     SA61765 83820053
         XC    MSGNLNTH,MSGNLNTH        CLEAR WORK AREA          Y00522 83880053
         B     EXIT                     BRANCH TO EXIT          SA61765 83940053
         SPACE 2                                                SA61765 84000053
ENDSCR   EQU   *                        TS MESSAGE NOT COMPLETE SA61765 84030053
         TM    WFLGS,TSOMSG             IS THIS A MSGGEN         Y00522 84060053
         BZ    TRUNCATE                 YES, GO SHORTEN IT       Y00522 84120053
         LA    RRTN,RC16                BUT SCREEN IS FULL      SA61765 84180053
         B     EXIT                     BRANCH TO EXIT                  84240053
         SPACE 2                                                        84300053
NOTALL   EQU   *                        TS MESSAGE NOT COMPLETE SA61765 84330053
         LA    RRTN,RC12                AND SCREEN NOT FULL     SA61765 84360053
         B     EXIT                     BRANCH TO EXIT                  84420053
         SPACE 2                                                        84480053
EXIT     EQU   *                        EXIT ROUTINE                    84540053
         MVC   QCBCARCT,CARCT+ONE       UPDATE LINE POSITION COUNT      84600053
         MVC   TWENTY(TWELVE,RAVT),TOR  SAVE CONTENTS OF RETURN REGS    84630053
         ST    RRTN,SIXTEEN(RAVT)       SAVE RETURN CODE FOR 15         84660053
         RETURN (14,12)                                                 84720053
         EJECT                                                          84780053
TRNSEDIT TRT   ZERO(ZERO,RPARM),EDITABLE TEST FOR CONTROL CHARACTERS    84840053
TRNSCONT TRT   ZERO(ZERO,RPARM),CONTRLTB TEST FOR NON-CONTROL CHRS      84900053
MOVDATA  MVC   ZERO(ZERO,RTCBUF),ZERO(RTSBUF) MOVE DATA TO TCAM BUF     84930053
         SPACE 2                                                        84960053
CONVERTB DC    X'40C1C2C3C4C5C6C7'      TRANSLATE TABLE TO              85020053
         DC    X'C8C94A4B4C4D4E4F'        *                             85080053
         DC    X'50D1D2D3D4D5D6D7'           CONVERT BINARY VALUE       85140053
         DC    X'D8D95A5B5C5D5E5F'             *                        85200053
         DC    X'6061E2E3E4E5E6E7'                TO REQUIRED           85230053
         DC    X'E8E96A6B6C6D6E6F'                  *                   85260053
         DC    X'F0F1F2F3F4F5F6F7'                     HARDWARE FORMAT  85320053
         DC    X'F8F97A7B7C7D7E7F'                       *              85380053
         SPACE 2                                                        85440053
EDITABLE EQU   *                                                        85500053
*                 0 1 2 3 4 5 6 7 8 9 A B C D E F                       85530053
         DC    X'00010101010001000000000000020000'     0        SA60002 85560053
         DC    X'00030304010201010000000000030000'     1        SA60002 85620053
         DC    X'00000000050001000000000000010000'     2        SA60002 85680053
         DC    X'00000000000000010000000003010000'     3        SA60002 85740053
         DC    X'00000000000000000000000000000000'     4                85800053
         DC    X'00000000000000000000000000000000'     5                85830053
         DC    X'00000000000000000000000000000000'     6                85860053
         DC    X'00000000000000000000000000000000'     7                85920053
         DC    X'00000000000000000000000000000000'     8                85980053
         DC    X'00000000000000000000000000000000'     9                86040053
         DC    X'00000000000000000000000000000000'     A                86100053
         DC    X'00000000000000000000000000000000'     B                86130053
         DC    X'00000000000000000000000000000000'     C                86160053
         DC    X'00000000000000000000000000000000'     D                86220053
         DC    X'00000000000000000000000000000000'     E                86280053
         DC    X'00000000000000000000000000000000'     F                86340053
         SPACE 2                                                        86400053
CONTRLTB EQU   *                                                        86430053
*                 0 1 2 3 4 5 6 7 8 9 A B C D E F                       86460053
         DC    X'01020101010001010101010101010101'     0        SA60002 86520053
         DC    X'01010100030101010101010101010102'     1                86580053
         DC    X'01010101040102020101010101010101'     2        SA60002 86640053
         DC    X'01010201010101010101010101010100'     3        SA60002 86700053
         DC    X'01010101010101010101010101010101'     4                86730053
         DC    X'01010101010101010101010101010101'     5                86760053
         DC    X'01010101010101010101010101010101'     6                86820053
         DC    X'01010101010101010101010101010101'     7                86880053
         DC    X'01010101010101010101010101010101'     8                86940053
         DC    X'01010101010101010101010101010101'     9                87000053
         DC    X'01010101010101010101010101010101'     A                87030053
         DC    X'01010101010101010101010101010101'     B                87060053
         DC    X'01010101010101010101010101010101'     C                87120053
         DC    X'01010101010101010101010101010101'     D                87180053
         DC    X'01010101010101010101010101010101'     E                87240053
         DC    X'01010101010101010101010101010101'     F                87300053
         SPACE 2                                                        87330053
ONECHAR  DC    H'1'                     HALFWORD OF ONE                 87360053
TWOCHAR  DC    H'2'                     HALFWORD OF TWO                 87420053
THREECHR DC    H'3'                     HALFWORD OF THREE               87480053
FOURCHAR DC    H'4'                     HALFWORD OF FOUR                87540053
FIVECHAR DC    H'5'                     HALFWORD FIVE            Y00522 87600053
SIXCHAR  DC    H'6'                     HALFWORD OF SIX                 87630053
CHAR8    DC    H'8'                     HALFWORD EIGHT           Y00522 87660053
HDRPRFX  DC    H'42'                    TCAM HEADER PREFIX SIZE         87720053
COLON3   DC    X'7A7A7A'                3 COLONS                        87780053
ATT480   DC    X'C75F'                  480 SCREEN FORMAT COMMAND       87840053
ATT1920  DC    X'5D7F'                  1920 SCREEN FORMAT COMMAND      87900053
PROMPT   DC   X'5C5C5C'                 PROMPT CHARACTER STRING  Y00522 87930053
BTULNGTH DC    H'0019'                  BTU LENGTH IN BUFFER     Y00522 87960053
         DC    10F'0'                   TEMPORARY PATCH AREA            88020053
         EJECT                                                          88080053
GMAIN    DSECT                                                          88140053
TSBUFR   DS    F                        TSO BUF OR MSGGEN ADDRESS       88200053
TCBUFR   DS    F                        TCAM/SCB ADDRESS                88230053
MOVED    DS    H                        DATA MOVED                      88260053
LINE     DS    H                        LINE SIZE REMAINING             88350053
BLNTH    DS    H                        TSO BUFFER DATA SIZE            88380053
MSGLEN   DS    H                        MESSAGE SIZE                    88440053
WBUFSZ   DS    H                        TCAM BUFFER SIZE                88500053
*                                                                     * 88530053
CARCT    DS    H                        QCBCARCT                        88560053
*                             BIT DEFINITIONS                         * 88620053
STFDSCND EQU   X'F0'                    SECOND ENTRY OFFSET             88680053
RDATSCND EQU   X'F1'                    SECOND ENTRY OFFSET             88740053
SBASCND  EQU   X'F2'                    SECOND ENTRY OFFSET             88800053
CUR1SCND EQU   X'F3'                    SECOND ENTRY OFFSET             88830053
CUR2SCND EQU   X'F4'                    SECOND ENTRY OFFSET             88860053
INCSCND  EQU   X'F5'                    SECOND ENTRY OFFSET             88920053
ETXSCND  EQU   X'F6'                    SECOND ENTRY OFFSET             88980053
EOTSCND  EQU   X'F7'                    SECOND ENTRY OFFSET             89040053
ETXEOTPL EQU   X'F8'                    SECOND ENTRY OFFSET     SA61765 89100053
*                                                                     * 89130053
LINESV   DS    H                        FROM TSB OR DEFAULT             89160053
*                                                                     * 89220053
LINENUM  EQU   LINESV                   DISPLAY NUMBER OF LINES         89280053
LINESIZE EQU   LINESV+1                 DISPLAY LINE SIZE               89340053
*                                                                     * 89400053
SWT1     DS    X                        SWITCH 1                        89430053
*                             BIT DEFINITIONS                         * 89460053
CUR2FLAG EQU   X'80'                    SECOND CURSOR FLAG              89520053
CUR1FLAG EQU   X'40'                    FIRST CURSOR FLAG               89580053
RDATTNLF EQU   X'20'                    READ ATTRIBUTE BYTE FLAG        89640053
SFATTSW  EQU   X'10'                    START FIELD FLAG                89700053
BYPFLAG  EQU   X'08'                    BYPASS FLAG                     89730053
CRNL     EQU   X'04'                    CARRIAGE RETURN/NEWLINE FLAG    89760053
SBAENDSW EQU   X'02'                    SET BUFFER ADDRESS FLAG         89820053
WRATTSW  EQU   X'01'                    WRITE ATTRIBUTE BYTE FLAG       89880053
*                                                                     * 89940053
SWT2     DS    X                        SWITCH 2                        90000053
*                             BIT DEFINITIONS                         * 90030053
RETCOD4  EQU   4                        CALCSIZE RETURN CODE 4          90060053
RETCOD8  EQU   8                        CALCSIZE RETURN CODE OF 8       90120053
RETCOD12 EQU   12                       CALCSIZE RETURN CODE OF 12      90180053
RETCOD16 EQU   16                       CALCSIZE RETURN CODE OF 16      90240053
RETCOD40 EQU   40                       CALCSIZE RETURN CODE NO ROOM    90300053
RETCOD44 EQU   44                       CALCSIZE RETURN CODE 44 SA61765 90330053
*                                                                     * 90360053
WFLGS    DS    H                        TSO FLAGS                       90460053
*                             BIT DEFINITIONS                         * 90560053
TSOMSG   EQU   X'80'                    TSO ENTRY                       90660053
CONTROLM EQU   X'40'                    CONTROL MODE                    90760053
TSOASIS  EQU   X'20'                    TSO TPUT ASIS                   90860053
FRSTMGEN EQU   X'10'                    FIRST MSGGEN PASS SWT    Y00522 90960053
ASISCNTL EQU   X'60'                    ASIS SCREEN CONTROL     SA60002 91060053
FMTFLAG  EQU   X'08'                    SCR FORMAT INFO IN BUFFERY00522 91160053
NOLEFT   EQU   X'06'                    NO LEFT JUSTIFICATION REQUEST   91260053
LEFT     EQU   X'05'                    LEFT JUSTIFICATION REQUEST      91360053
*                                                                     * 91460053
SAVX1    DS    H                        SCREEN CURSOR ADDRESS           91560053
*                                                                     * 91660053
FLAG1    DS    X                        FLAG BYTE 1                     91760053
*                             BIT DEFINITIONS                         * 91860053
TRAILER  EQU   X'80'                    TRAILER BUFFER FLAG             91960053
PARTEND  EQU   X'40'                    PARTIAL MOVE FLAG       SA61765 92060053
INCSW    EQU   X'04'                    INSERT CURSOR FLAG              92160053
EOTSW    EQU   X'02'                    EOT FLAG                        92260053
ETXSW    EQU   X'01'                    ETX FLAG                        92360053
*                                                                     * 92460053
FLAG2    DS    X                        FLAG BYTE 2                     92560053
*                             BIT DEFINITIONS                         * 92660053
X3705    EQU   X'80'                    TERMINAL ON A 3705       Y00522 92760053
X1050    EQU   X'40'                    DEVICE IS A 1050         Y00522 92860053
PROMPTFG EQU   X'20'                    PROMPT STRING FLAG       Y00522 92960053
NLCRFLAG EQU   X'10'                    NL/CR COUNT FLAG                93060053
NWLNCNT  EQU   X'08'                    LINE COUNT FLAG                 93160053
CARRDATT EQU   X'04'                    READ ATTRIBUTE LINE POS FLAG    93260053
HEADERFG EQU   X'02'                    FIRST BASIC UNIT FLAG           93360053
NOMOVECT EQU   X'01'                    NO MOVECOUNT FLAG               93460053
*                                                                     * 93560053
SAVX2    DS    H                        FIRST/LAST CHARACTER            93660053
TOR      DS    F                        DATA COUNT                      93760053
FROMR    DS    F                        DATA COUNT MOVED                93860053
TSCURR   DS    F                        CURRENT TSO BUFFER              93960053
MSGNLNTH DS    H                        LENGTH OF MSGGEN DATA    Y00522 94060053
SBAFLAG  EQU   X'EF'                    SBA FLAG                 Y00522 94160053
CUR1FG   EQU   X'EE'                    CURSOR ONE FLAG          Y00522 94260053
CUR2FG   EQU   X'ED'                    CURSOR TWO FLAG          Y00522 94360053
STFLDFLG EQU   X'EC'                    START FIELD FLAG         Y00522 94460053
WRATTFLG EQU   X'EB'                    WRITE ATTRIBUTE FLAG     Y00522 94560053
DEND     DS    D                        DOUBLE SAVE                     94660053
SIZE     EQU   *-GMAIN                                                  94760053
         EJECT                                                          94860053
         IKJTIOCB                                                       94960053
         TAVTD                                                          95060053
         TLCBD                                                          95160053
         TQCBD                                                          95260053
         TSCBD                                                          95360053
         TTSID                                                          95460053
         END                                                            95560053
