         TITLE 'IEDAYD - TSO DESTINATION SCHEDULER'                     01000020
IEDAYD   CSECT                                                          02000020
*A450000                                                         S22029 02001022
*C420000,430000                                                  S22029 02002022
*D493000-496000                                                  S22029 02003022
*A490000,510000,530000                                           A42371 02005020
*********************************************************************** 02010020
*TITLE  'IEDAYD'  TIME SHARING DESTINATION SCHEDULER                  * 02020020
*                                                                     * 02030020
*STATUS -- CHANGE LEVEL 20.0                                          * 02040020
*                                                                     * 02050020
*FUNCTION -- THE TIME SHARING DESTINATION SCHEDULER GETS CONTROL IN   * 02060020
*   PLACE OF THE TCAM DESTINATION SCHEDULER WHEN TSO IS IN THE SYSTEM.* 02070020
*   IF THIS ROUTINE WAS ACTIVATED BECAUSE A TCAM BUFFER WAS POSTED TO * 02080020
*   IT, IT LOADS THE ADDRESS OF THE TCAM DESTINATION SCHEDULER'S STCB * 02090020
*   (IEDQHM) INTO REGISTER 3, AND BRANCHES TO THE DISPATCHER BYPASS   * 02100020
*   FUNCTION TO IMMEDIATELY ACTIVATE THE STCB.                        * 02110020
*      IF THIS ROUTINE WAS ACTIVATED BY THE POSTING OF A TIME SHARING * 02120020
*   DESTINATION QCB TO ITSELF, IT SETS THE POSTED BIT OFF IN THE QCB  * 02130020
*   AND CHECKS TO SEE IF A SIMULATED ATTENTION READ WAS REQUESTED.    * 02140020
*   IF IT WAS, CONTROL IMMEDIATELY PASSES TO THE DISPATCHER DISPATCH  * 02150020
*   FUNCTION.  IF NOT, THIS ROUTINE CHECKS TO SEE IF TPUT REQUESTED   * 02160020
*   A WRITE BREAK.  IF NOT, CONTROL ALSO PASSES TO THE DISPATCH       * 02170020
*   FUNCTION.  IF A WRITE BREAK WAS REQUESTED, THIS ROUTINE LOADS THE * 02180020
*   LCB ADDRESS INTO REGISTER 4 AND BRANCHES TO THE TIME SHARING      * 02190020
*   SCHEDULER (IEDAYZ) TO DETERMINE WHETHER A WRITE BREAK CHANNEL     * 02200020
*   COMMAND CAN BE ISSUED.  IF IT CAN, IEDAYZ ISSUES AN IOHALT.  IN   * 02210020
*   EITHER CASE, CONTROL RETURNS TO THIS ROUTINE, WHICH THEN PASSES   * 02220020
*   CONTROL TO THE DISPATCHER DISPATCH FUNCTION.                      * 02230020
*                                                                     * 02240020
*ENTRY POINT -- IEDAYD - TO INITIATE A WRITE BREAK OPERATION, IF      * 02250020
*   NECESSARY, AND TO ASSIGN A BUFFER OR QCB TO ITS DESTINATION.      * 02260020
*   CALLING SEQUENCE          L    R15,STCBLINK-1                     * 02270020
*                             BR   R15                                * 02280020
*                                                                     * 02290020
*INPUT -- IEDAYD IS CALLED BY THE DISPATCHER WHEN A TCAM BUFFER IS    * 02300020
*   POSTED TO IT, OR WHEN A TIME SHARING DESTINATION QCB IS POSTED    * 02310020
*   TO ITSELF.  AT ENTRY THE FOLLOWING REGISTERS ARE SET.             * 02320020
*   R1 HAS THE ADDRESS OF THE TCAM BUFFER OR TIME SHARING QCB.        * 02330020
*   R3 HAS THE STCB ADDRESS.                                          * 02340020
*   R7 HAS THE DESTINATION QCB ADDRESS.                               * 02350020
*   R11 HAS THE DISPATCHER ADDRESS.                                   * 02360020
*   R13 HAS THE ADDRESS OF AVTSAVE2.                                  * 02370020
*   R15 HAS THE ENTRY POINT ADDRESS.                                  * 02380020
*                                                                     * 02390020
*OUTPUT -- ON EXIT TO THE DISPATCHER BYPASS FUNCTION, REGISTER 3 CON- * 02400020
*   TAINS THE ADDRESS OF THE TCAM DESTINATION SCHEDULER'S STCB.       * 02410020
*      ON EXIT TO THE TIME SHARING SCHEDULER, THE FOLLOWING REGISTERS * 02420020
*   ARE SET.                                                          * 02430020
*   R2 HAS THE RETURN ADDRESS IN IEDAYD.                              * 02440020
*   R3 HAS THE RETURN ADDRESS IN IEDAYD.                              * 02450020
*   R4 HAS THE LCB ADDRESS.                                           * 02460020
*   R7 HAS THE DESTINATION QCB ADDRESS.                               * 02470020
*   R10 HAS THE DCB ADDRESS.                                          * 02480020
*   R11 HAS THE DISPATCHER ADDRESS.                                   * 02490020
*   R13 HAS THE ADDRESS OF AVTSAVE2.                                  * 02500020
*      ON EXIT TO THE DISPATCHER DISPATCH FUNCTION, THE POSTED BIT IN * 02510020
*   THE TIME SHARING QCB IS OFF.                                      * 02520020
*                                                                     * 02530020
*EXTERNAL ROUTINE -- IEDAYZ - TO DETERMINE WHETHER THE WRITE BREAK    * 02540020
*   CHANNEL COMMAND REQUESTED BY TPUT CAN BE ISSUED, AND TO ISSUE AN  * 02550020
*   IOHALT ON THE LINE IF IT CAN.                                     * 02560020
*                                                                     * 02570020
*EXITS-NORMAL -- TO THE DISPATCHER BYPASS FUNCTION.                   * 02580020
*   TO THE DISPATCHER DISPATCH FUNCTION.                              * 02590020
*                                                                     * 02600020
*EXITS-ERROR -- NONE                                                  * 02610020
*                                                                     * 02620020
*TABLES/WORKAREAS -- AVT, LCB, QCB, DCB, STCB, TSID.                  * 02630020
*                                                                     * 02640020
*ATTRIBUTES -- SERIALLY REUSABLE, REFRESHABLE, ENABLED, RESIDENT,     * 02650020
*   PROBLEM PROGRAM MODE                                              * 02660020
*                                                                     * 02670020
*NOTES -- THE OPERATION OF THIS MODULE DOES NOT DEPEND UPON A         * 02680020
*   PARTICULAR INTERNAL REPRESENTATION OF THE EXTERNAL CHARACTER      * 02690020
*   SET.                                                              * 02700020
*                                                                     * 02710020
*********************************************************************** 02720020
         SPACE 2                                                        19000020
*        REGISTER EQUATES                                               20000020
         SPACE                                                          21000020
RTRM     EQU   1                        ADDRESS OF TERM ENTRY, WORK REG 22000020
R2       EQU   2                        WORK REGISTER                   23000020
RSTCB    EQU   3                        ADDRESS OF STCB                 24000020
RLCB     EQU   4                        ADDRESS OF LCB                  25000020
R6       EQU   6                        ADDRESS OF TS SCHEDULER         26000020
RQCB     EQU   7                        ADDRESS OF DESTINATION QCB      27000020
RDCB     EQU   10                       ADDRESS OF DCB                  28000020
RDISP    EQU   11                       ADDRESS OF DISPATCHER           29000020
RBASE    EQU   12                       BASE REGISTER                   30000020
R13      EQU   13                       ADDRESS OF AVTSAVE2             31000020
R15      EQU   15                       HAS BASE ADDRESS AT ENTRY       32000020
         SPACE 2                                                        33000020
*        ADDRESSABILITY                                                 34000020
         SPACE                                                          35000020
         USING AVTSAVE2,R13                                             36000020
         USING IEDQDISP,RDISP                                           37000020
         USING IEDQLCB,RLCB                                             38000020
         USING IEDQQCB,RQCB                                             39000020
         USING IEDQSTCB,RSTCB                                           40000020
         USING IHADCB,RDCB                                              41000020
         DC    AL1(DSPMCPL8),AL3(0),A(0)  STCB FIELDS            S22029 42000022
         USING *,RBASE                                                  44000020
         LR    RBASE,R15                ESTABLISH ADDRESSABILITY        45000020
IEDAYD  IEDHJN  AYD000                                                  45500022
         CLI   QCBSTVTO-IEDQQCB(RTRM),DSPSNDSC PASSED ELEMENT A QCB?    46000020
         BE    AYD100                   BRANCH ON YES                   47000020
         L     RSTCB,AVTTSOPT          GET THE ADDRESS OF        S22029 48000022
         L     RSTCB,TSIDEST-IEDQTSI(,RSTCB) TCAM DEST SCHED STCBS22029 48500022
         B     DSPBYPAS                 GIVE HM CONTROL                 49000020
         DC    C'IEDAYD'                ID FOR DUMPS             A42371 49300020
         DC    X'1154'                  AND JULIAN DATE          A42371 49600020
AYD100   EQU   *                                                        50000020
         NI    QCBTSOF2,X'FF'-QCBPOSTO  TURN OFF QCB POSTED BIT         51000020
         TM    QCBTSOF1,QCBDISC         LOGGING OFF              A42371 51300020
         BO    AYD105                   BRANCH YES TO ALLOW BREAKA42371 51600020
         TM    QCBTSOF1,QCBSATRD        SIMULATED ATTENTION READ?       52000020
         BO    DSPDISP                  BRANCH ON YES TO RETURN         53000020
AYD105   EQU   *                                                 A42371 53500020
         TM    QCBTSOF1,QCBWRBRK        WRITE BREAK REQUESTED?          54000020
         BZ    DSPDISP                  BRANCH ON NO TO RETURN          55000020
         SR    RTRM,RTRM                                                56000020
         IC    RTRM,QCBRELLN            QCB'S STARTING RLN              57000020
         SR    R2,R2                                                    58000020
         L     RDCB,QCBDCBAD-1          GET ADDRESS OF DCB              59000020
         IC    R2,DCBEIOBX              GET LCB SIZE                    60000020
         MR    RTRM-1,R2                GET STARTING LCB OFFSET         61000020
         AL    RTRM,DCBIOBAD            POINT TO IOB OF LCB             62000020
         SH    RTRM,LCBSIZE             ADJUST TO START OF LCB          63000020
         LR    RLCB,RTRM                LCB BASE                        64000020
         LA    R2,AYD200                SET UP WITH RETURN ADDRESS      65000020
         L     R6,AVTTSOPT              ADDRESS OF TIME SHARING QCB     66000020
         L     R6,TSISCHED-IEDQTSI(,R6) GET ADDRESS OF TS SCHEDULER     67000020
         BAL   RSTCB,28(,R6)            BRANCH TO ROUTINE               68000020
AYD200   EQU   *                                                        69000020
         B     DSPDISP                  RETURN                          70000020
         SPACE 2                                                        71000020
*        CONSTANTS                                                      72000020
         SPACE                                                          73000020
LCBSIZE  DC    AL2(LCBFLAG1-IEDQLCB)    SIZE OF LCB FROM RCB TO IOB     74000020
         EJECT                                                          75000020
         TLCBD                                                          76000020
         EJECT                                                          77000020
         TQCBD                                                          78000020
         PRINT NOGEN                                                    79000020
         TTSID                                                          80000020
         TAVTD                                                          81000020
         TDISPD                                                         82000020
         DCBD  DSORG=TX                                                 83000020
         TSTCBD                                                         84000020
         END                                                            85000020
