         TITLE 'IEDAYF - IOHALT ROUTINE.'                               02000022
IEDAYF   CSECT                                                          02001022
*A669100,670200                                                  S22029 02005022
*C300000-310000,413000                                           S22029 02010022
*D670500,670800,675000                                           S22029 02015022
*A020000                                                         S21903 02016022
*C050000-200000,280000-286000,422200,630000,665460,668400,677400,S21903 02017022
*C677490,677530,677610,678000,678300,678900,677530               S21903 02018022
*********************************************************************** 02020020
*TITLE  'IEDAYF'  IOHALT ROUTINE                                      * 02040020
*                                                                     * 02060020
*STATUS -- CHANGE LEVEL 20.0                                          * 02080020
*                                                                     * 02100020
*FUNCTION -- THE IOHALT ROUTINE GETS CONTROL WHEN EITHER AN LCB OR AN * 02120020
*   ERB IS POSTED FROM LINE END APPENDAGE.  FOR AN LCB, THIS ROUTINE  * 02140020
*   MONITORS FOR AN ATTENTION IF THE LCB OPEN CHECK OP CODE HAS BEEN  * 02160020
*   SET AND IF A PREPARE HAS BEEN ISSUED FOR THE LINE.  WHEN AN ATTEN-* 02180020
*   TION OCCURS, THIS ROUTINE ISSUES AN IOHALT SVC (SVC 33) ON THE    * 02200020
*   PREPARE.  IT THEN EXITS TO THE DISPATCHER DISPATCH FUNCTION TO    * 02220020
*   DISPATCH THE NEXT SUBTASK.                                        * 02240020
*      AN ERB IS POSTED WHEN A HARDWARE ATTENTION OCCURS OR WHEN A    * 02260020
*   2741 HANGS UP.  THIS ROUTINE ACCESSES THE LCB FROM THE ERB AND    * 02280020
*   SETS OFF THE PREPARE BIT.  THEN, IF THE LCB IS IN THE TIME DELAY  * 02300020
*   QUEUE, THIS ROUTINE LINKS FIRST TO THE TIME DELAY SUBTASK (IEDQHG)* 02320020
*   TO REMOVE IT, AND THEN TO THE DISPATCHER PRIORITY FUNCTION TO     * 02340020
*   INSERT THE RECEIVE SCHEDULER'S STCB INTO THE LCB'S STCB CHAIN BY  * 02360020
*   PRIORITY.  IF THE LCB COMPLETION CODE INDICATES THAT I/O ENDED ON * 02380020
*   THE LINE BECAUSE OF AN IOHALT, LINE FREE PRIORITY IS SET, AND THE * 02400020
*   LCB IS SET TO BE POSTED TO ITSELF.  IF THE LINE IS CONNECTED TO   * 02420020
*   A 2741, AND A PREPARE CCW WAS INTERRUPTED, THIS ROUTINE INDICATES * 02440020
*   IN THE LCB THAT A CIRCLE D WAS SENT AND CHECKS TO SEE IF THE 2741 * 02460020
*   HAS HUNG UP.  IF IT HAS, THE LCB IS SET TO BE POSTED TO THE       * 02480020
*   HANGUP ROUTINE.  IF A PREPARE CCW WAS NOT INTERRUPTED, BUT A      * 02500020
*   CIRCLE D WAS SENT, THE LCB IS SET TO INDICATE CIRCLE D SENT.  FOR * 02520020
*   2741'S THAT HAVE NOT HUNG UP, AND FOR ALL OTHER DEVICES, THE SCB  * 02540020
*   HARDWARE ATTENTION BIT IS SET ON, AND THE LCB IS SET TO BE POSTED * 02560020
*   TO THE ATTENTION ROUTINE.  IN ALL CASES EXCEPT WHEN I/O WAS ENDED * 02580020
*   BY IOHALT, PCI PRIORITY IS SET.  FINALLY, THIS ROUTINE LINKS ALL  * 02600020
*   PREVIOUS ELEMENTS IN THE CHAIN, SETS THE QCB ADDRESS IN THE LCB,  * 02620020
*   INDICATES THAT THE LCB IS THE NEW FIRST ELEMENT IN THE CHAIN, AND * 02640020
*   EXITS TO THE DISPATCHER CHAIN FUNCTION TO POST ALL THE ELEMENTS   * 02660020
*   IN THE CHAIN TO THE APPROPRIATE QCBS.                             * 02680020
*                                                                     * 02700020
*ENTRY POINT -- IEDAYF - TO MONITOR FOR AN ATTENTION, OR TO HANDLE A  * 02720020
*   HARDWARE ATTENTION OR HANGUP SITUATION                            * 02740020
*   CALLING SEQUENCE          L    R15,STCBLINK-1                     * 02760020
*                             BR   R15                                * 02780020
*                                                                     * 02800020
*INPUT -- IEDAYF IS CALLED BY THE DISPATCHER WHEN AN LCB OR AN ERB IS * 02820020
*   POSTED TO IT FROM LINE END APPENDAGE.  AT ENTRY, THE FOLLOWING    * 02840020
*   REGISTERS ARE SET.                                                * 02860020
*   R1 HAS THE ADDRESS OF THE LCB OR ERB                              * 02880020
*   R11 HAS THE DISPATCHER ADDRESS.                                   * 02900020
*   R13 HAS THE ADDRESS OF AVTSAVE2                                   * 02920020
*   R15 HAS THE ENTRY POINT ADDRESS.                                  * 02940020
*                                                                     * 02960020
*OUTPUT -- ON LINKING TO THE IOHALT SVC ROUTINE, THE FOLLOWING REGIS- * 02980020
*   TERS ARE SET.                                                     * 03000020
*   R2 HAS THE UCB ADDRESS                                            * 03020020
*   R8 HAS THE DEB ADDRESS                                            * 03040020
*   R10 HAS THE DCB ADDRESS                                           * 03060020
*      ON LINKING TO THE TIME DELAY SUBTASK, THE FOLLOWING REGISTERS  * 03080020
*   ARE SET.                                                          * 03100020
*   R1 HAS THE LCB ADDRESS                                            * 03120020
*   R14 HAS THE RETURN ADDRESS IN IEDAYF                              * 03140020
*   R15 HAS THE ENTRY POINT ADDRESS OF THE TIME DELAY REMOVAL ROUTINE * 03160020
*   IN THE TIME DELAY SUBTASK                                         * 03180020
*      ON LINKING TO THE DISPATCHER PRIORITY FUNCTION, THE FOLLOWING  * 03200020
*   REGISTERS ARE SET.                                                * 03220020
*   R1 HAS THE ADDRESS OF THE RECEIVE SCHEDULER KEY                   * 03240020
*   R7 HAS THE ADDRESS OF THE FIRST STCB IN THE LCB'S STCB CHAIN      * 03260020
*   R14 HAS THE RETURN ADDRESS IN IEDAYF                              * 03280020
*      ON EXIT TO THE DISPATCHER DISPATCH FUNCTION, REGISTER 4 CON-   * 03300020
*   TAINS THE LCB ADDRESS.                                            * 03320020
*      ON EXIT TO THE DISPATCHER CHAIN FUNCTION, THE LCB IS SET TO BE * 03340020
*   POSTED TO THE ATTENTION QCB, THE HANGUP QCB, OR ITSELF.  THE LCB  * 03360020
*   PRIORITY IS SET, AND THE FOLLOWING REGISTERS ARE SET.             * 03380020
*   R1 HAS THE ADDRESS OF THE LCB TO BE POSTED, AS FIRST ELEMENT IN   * 03400020
*   THE CHAIN                                                         * 03420020
*   R3 HAS THE SCB ADDRESS                                            * 03440020
*   R4 HAS THE LCB ADDRESS                                            * 03460020
*   R5 HAS THE ADDRESS OF THE QCB TO WHICH THE LCB IS TO BE POSTED    * 03480020
*   R10 HAS THE DCB ADDRESS                                           * 03500020
*   R14 HAS THE ENTRY POINT ADDRESS IN THE DISPATCHER                 * 03520020
*                                                                     * 03540020
*EXTERNAL ROUTINES -- IOHALT SVC ROUTINE - TO HALT I/O ON A LINE      * 03560020
*   IEDQHG - TO REMOVE AN LCB FROM THE TIME DELAY QUEUE               * 03580020
*   DISPATCHER PRIORITY FUNCTION - TO INSERT THE RECEIVE SCHEDULER'S  * 03600020
*   STCB INTO THE LCB'S STCB CHAIN                                    * 03620020
*                                                                     * 03640020
*EXITS-NORMAL -- TO THE DISPATCHER DISPATCH FUNCTION                  * 03660020
*   TO THE DISPATCHER CHAIN FUNCTION                                  * 03680020
*                                                                     * 03700020
*EXITS-ERROR -- NONE                                                  * 03720020
*                                                                     * 03740020
*TABLES/WORKAREAS -- AVT, DCB, LCB, SCB, DEB, TSID, TPRIOR ERB.       * 03760020
*                                                                     * 03780020
*ATTRIBUTES -- REENTRANT, ENABLED, RESIDENT, PROBLEM PROGRAM MODE     * 03800020
*                                                                     * 03820020
*NOTES -- THE OPERATION OF THIS MODULE DOES NOT DEPEND UPON A         * 03840020
*   PARTICULAR INTERNAL REPRESENTATION OF THE EXTERNAL CHARACTER      * 03860020
*   SET.                                                              * 03880020
*                                                                     * 03900020
*********************************************************************** 03920020
         SPACE 2                                                        04000020
R1       EQU   1                        REGISTER EQUATE          S21903 05000022
R2       EQU   2                        REGISTER EQUATE          S21903 06000022
RSCB     EQU   3                        REGISTER EQUATE          S21903 07000022
RLCB     EQU   4                        REGISTER EQUATE          S21903 08000022
R5       EQU   5                        REGISTER EQUATE          S21903 09000022
R6       EQU   6                        REGISTER EQUATE          S21903 10000022
RWORK    EQU   7                        REGISTER EQUATE          S21903 11000022
RDEB     EQU   8                        REGISTER EQUATE          S21903 12000022
R9       EQU   9                        REGISTER EQUATE          S21903 13000022
RDCB     EQU   10                       REGISTER EQUATE          S21903 14000022
RDSP     EQU   11                       REGISTER EQUATE          S21903 15000022
RBAS     EQU   12                       REGISTER EQUATE          S21903 16000022
R13      EQU   13                       REGISTER EQUATE          S21903 17000022
R14      EQU   14                       REGISTER EQUATE          S21903 18000022
R15      EQU   15                       REGISTER EQUATE          S21903 19000022
         SPACE 2                                                        22000020
OPNCHK   EQU   X'AC'                    OPEN CHECK               S21903 24000022
         SPACE 2                                                        26000020
         USING IEDQDISP,RDSP            DISPATCHER BASE          S21903 28000022
         USING AVTSAVE2,R13             SAVE AREA BASE           S21903 28100022
         USING IEDQLCB,RLCB             LCB BASE                 S21903 28200022
         USING IEDQSCB,RSCB             SCB BASE                 S21903 28300022
         USING IHADCB,RDCB              DCB BASE                 S21903 28400022
         USING IEDQTSI,RWORK            WORK BASE                S21903 28500022
X48      EQU   X'48'                    EQUATE                   S21903 28600022
IR       EQU   X'40'                    INTERVENTION REQUIRED           28700020
DELAYBIT EQU   X'02'                    DELAY BIT                S21903 28800022
TO       EQU   X'01'                   TIME OUT                         28900020
PREPARE  EQU   6                        PREPARE                  S21903 29000022
IEDAYF   IEDHJN                                                         30000022
         DC    AL1(DSPMCPL4),AL3(*-1)   STCB                            32000020
IEDAYF0  BALR  RBAS,0                   LOAD BASE REGISTER              34000020
         USING *,RBAS                                                   36000020
         LA    RLCB,0(R1)               LCB ADDRESS                     36500020
         CLI   LCBPRI-IEDQLCB(R1),PRIDSPLB IS IT THE ERB?               37000020
         BE    ITSERB                   BRANCH ON YES                   37500020
         SH    RLCB,ERBOF               ASSUME ERB                      38200020
         TM    PRFTIC-IEDQPRF(R1),X08   IS ELEMENT A BUFFER             38900020
         BZ    OKERB                    BRANCH NO - MUST BE ERB         39600020
*                                                                       40300020
         LR    R6,R1                    SAVE BUFFER ADDRESS             40600020
         L     RLCB,PRFLCB-IEDQPRF-1(R1)  LCB ADDRESS FROM BUFFER       41000020
         MVC   PRFOPCDE-IEDQPRF(8,R1),PRFSHDR-IEDQPRF(R1) RESTORES22029 41300022
*                                                         CCW    S22029 41310022
         TM    LCBSTAT1,LCBSENDN        SEND STATE                      41320020
         BZ    OKERB                    BRANCH NO                       41340020
*                                                                       41360020
         LA    R15,LCBERB               ERB ADDRESS                     41380020
         LA    R2,AVTBFRTB-4              INITIALIZE FOR LOOP           41400020
*        REMOVE ERB FROM BUFFER RETURN QUEUE IF THERE                   41420020
SCNERB   EQU   *                                                        41440020
         LR    R1,R2                    NEW LAST ELEMENT                41460020
         USING IEDQQCB,R1                                               41480020
         L     R2,QCBLINK-1            FIRST/NEXT ELEMENT ON Q          41500020
         LA    R2,0(,R2)                CLEAR HIGH ORDER BYTE           41520020
         CL    R2,AVTDELAD              DUMMY LAST ELEMENT              41540020
         BE    OKERB                    BRANCH YES - NOT THERE          41560020
*                                                                       41580020
         CLR   R2,R15                   IS THIS THE ERB                 41600020
         BNE   SCNERB                   BRANCH NO - CONTINUE SCAN       41620020
*                                                                       41640020
         MVC   QCBLINK,QCBLINK-IEDQQCB(R2)  REMOVE ERB                  41670020
         OI    LCBERBST,LCBDLNKN        MAKE LCB POSTABLE               41680020
OKERB    EQU   *                                                        41700020
         LH    R1,LCBTTCIN              OFFSET TO LINE ENTRY            41740020
         N     R1,AVTCLRHI              CLEAR HIGH ORDER HALF           41780020
         L     R15,AVTRNMPT             ADDRESS OF TNT                  41820020
         BALR  R14,R15                  LINK TO TNT                     41860020
*                                                                       41900020
         USING IEDQTRM,R1                                               41940020
         SR    R2,R2                                                    41980020
         IC    R2,TRMCHCIN              CHARACTERISTICS INDEX           42020020
         BCTR  R2,0                     MINUS 1                         42060020
         SLL   R2,2                     TIMES FOUR                      42100020
         AL    R2,AVTCSTCS                                              42140020
         TM    1(R2),X'20'              ATTENTION FEATURE               42180020
         BZ    NOATTN                   BRANCH ON NO ATTENTION   S21903 42220022
         TM    LCBTSOB,LCBSATRD         SENDING TRANSLATE ERR MSG       42230020
         BO    NOATTN1                  BRANCH ON YES                   42240020
*                                                                       42260020
         MVC   LCBCSWSV(7),LCBCSW       SAVE CSW                        42400020
         MVC   LCBCPA(8),PREPCCW        SET UP PREPARE CCW              43100020
         MVI   LCBTPCD,X'10'            SET TP OP CODE                  43800020
         MVI   LCBTPCD+11,OPNCHK        SET OPEN LINE CHECK FLAG        44500020
         LA    R1,LCBCPA               CHANNEL PROGRAM ADDRESS          45200020
         ST    R1,LCBSTART-1            SET START ADDRESS               45900020
         LA    R1,LCBFLAG1              IOB ADDRESS                     46600020
         EXCP  (1)                                                      47300020
*                                                                       48000020
         L     RDCB,LCBDCBPT            DCB ADDRESS                     50000020
         USING IHADCB,RDCB                                              52000020
         SR    RWORK,RWORK              CLEAR REGISTER                  54000020
         IC    RWORK,LCBUCBX            PICK UP UCB INDEX               56000020
         SLL   RWORK,2                  MULTIPLY BY FOUR                58000020
         L     RDEB,DCBDEBAD            DEB ADDRESS                     60000020
         L     R1,DEBUCBAD-DEBNMSUB(RWORK,RDEB)  UCB ADDRESS            62000020
         MVC   LCBFLAG1(5),NORMHIO      PREVENT LOST LINE IF ERP S21903 63000022
         IOHALT (1)                                                     64000020
EXIT     B     DSPDISP                  RETURN TO DISPATCHER            66000020
ITSERB   EQU   *                                                        66030020
         SH    RLCB,ERBOF               BACK UP TO LCB                  66090020
         NI    LCBTSOB,X'FF'-LCBPREP    TURN OFF PREPARE BIT            66180020
         TM    LCBINSRC+2,DELAYBIT      IS LCB IN THE DELAY QUEUE?      66210020
         BZ    NOTINQ                   BRANCH ON NO                    66240020
         LR    R1,RLCB                  INDICATE WANT LCB REMOVED       66270020
         L     R15,AVTHG02              TIME DELAY REMOVAL ROUTINE      66300020
         BALR  R14,R15                  REMOVE LCB FROM QUEUE           66330020
         LA    RWORK,LCBRSKEY           LINK RECEIVE SCHED INTO STCB CH 66360020
         LR    R1,RWORK                                                 66390020
         BAL   R14,DSPPRIOR             DISPATCHER WILL DO LINK         66420020
NOTINQ   EQU   *                                                        66450020
         L     RSCB,LCBSCBA-1           ADDRESS OF SCB                  66460020
         L     RDCB,LCBDCBPT            ADDRESS OF DCB                  66470020
         CLI   LCBECBCC,X48             WAS IT ENDED BY IOHALT?         66480020
         BE    LCBTOLCB                 BRANCH ON YES                   66510020
         TM    LCBTSOB,LCB2741N         IS IT A 2741?                   66540020
         BO    IS2741                   BRANCH IF 2741           S21903 66546022
*                                                                       66552020
         CLC   LCBTPCD(3),LCBTPCD+1     1050 MONITOR SEQUENCE           66558020
         BE    POSTATTN                 BRANCH YES                      66564020
*                                                                       66570020
         B     OKERB                    CHECK FOR ATTN                  66576020
*                                                                       66582020
IS2741   EQU   *                                                        66588020
         L     R5,LCBCSW-1              INTERRUPTED CCW+8               66600020
         LA    R5,0(,R5)                                                66630020
         SH    R5,EIGHT                 BACK UP TO INTERRUPTED CCW      66660020
         CLI   0(R5),PREPARE            DID WE INTERRUPT ON A PREPARE?  66690020
         BE    SETD                     BRANCH ON YES                   66720020
         CLC   6(2,R5),AVTFZERO         WAS CIRCLE D SENT?              66750020
         BNE   POSTATTN                 BRANCH ON NO                    66780020
         OI    LCBTSOB,LCBCIRCD         INDICATE CIRCLE D SENT          66810020
         B     POSTATTN                 BRANCH TO POST ATTENTION S21903 66840022
SETD     EQU   *                                                        66870020
         OI    LCBTSOB,LCBCIRCD         INDICATE CIRCLE D SENT          66900020
POSTATTN EQU   *                                                        66910020
         L     RWORK,AVTTSOPT          GET ADDR OF TSINPUT       S22029 66920022
         TM    LCBSENS0,IR+TO           HAS TERMINAL HUNG UP?           66930020
         BNZ   HANGUP                   BRANCH ON YES                   66960020
         OI    SCBERR3,SCBATTN                                      TSO 67020020
         L     R5,TSIATTEN             GET ADDR OF ATTEN RTN     S22029 67050022
POSTLCB  EQU   *                                                        67110020
         LA    R9,PRIFSPCI-1            SET PRIORITY                    67140020
POST    EQU   *                                                         67150020
         LR    R1,RLCB                  LCB TO BE POSTED                67170020
         ST    R5,0(R1)                 SET QCB ADDRESS                 67320020
         STC   R9,4(R1)                 SET ELEMENT PRIORITY            67350020
         B     DSPPOST                  EXIT TO DISPATCHER              67390020
*                                                                       67440020
HANGUP   EQU   *                                                        67470020
         L     R5,TSIHANG               ADDRESS OF HANG UP ROUTINE      67530020
         B     POSTLCB                   POST LCB TO HANGUP             67560020
*                                                                       67590020
LCBTOLCB EQU   *                                                        67620020
         LR    R5,RLCB                  ADDRESS OF QCB                  67650020
         LA    R9,PRILNFRE              PRIORITY                        67680020
         B     POST                     BRANCH TO POST           S21903 67740022
NOATTN1  EQU   *                                                        67740120
         L     RSCB,LCBSCBA-1           SCB ADDRESS                     67740220
         NI    SCBERR2,X'FF'-SCBCODER   RESET TRANSLATE ERROR           67740320
         MVI   SCBMRFSD,AVTEZERO        RESET TABLE COUNT               67740420
         NI    LCBTSOB,X'FF'-LCBSATRD-LCBTSBUF RESET POST FLAG          67740520
NOATTN   EQU   *                                                        67741020
         TM    LCBSTAT2,LCBMSGNN        MESSAGE GEN                     67742020
         BZ    NOTMGN                   BRANCH NO                       67743020
*                                                                       67744020
         LA    R9,PRIRCQCB              GET PRIORITY                    67745020
         L     R5,AVTMSGS-1                                             67746020
         L     R5,0(,R5)                MH ADDRESS                      67747020
         LA    RLCB,LCBERB              ERB TO BE POSTED                67748020
         B     POST                     BRANCH TO POST           S21903 67749022
*                                                                       67750020
NOTMGN   EQU   *                                                        67751020
         TM    LCBSTAT1,LCBRECVN        RECEIVE STATE                   67752020
         BO    NOCLEAR                  BRANCH IF NOT RECEIVE    S21903 67753022
         USING IEDQPRF,R6                                               67754020
         XC    PRFSIZE,PRFSIZE          SIZE = 0                        67755020
NOCLEAR  EQU   *                                                        67756020
         OI    SCBERR4,SCBTXTTN         SET TEXT ERROR                  67756520
         LA    R9,PRIMHBFR-1            SET PRIORITY                    67757020
         L     R5,LCBDCBPT              DCB ADDRESS                     67758020
         L     R5,DCBMH-IHADCB-1(R5)    MH ADDRESS                      67759020
         LR    RLCB,R6                  POST BUFFER                     67760020
         B     POST                     BRANCH TO POST           S21903 67761022
*                                                                       67762020
         EJECT                                                          67770020
EIGHT    DC    H'8'                     CONSTANT                 S21903 67800022
ERBOF    DC    AL2(LCBERBFS)            CONSTANT                 S21903 67830022
PREPCCW  DC    X'06',AL3(*),X'200000BC'   PREPARE CCW                   67870020
NORMHIO  DC    X'C210000048'            CONSTANT                 S21903 67890022
X08      EQU   8                                                        67910020
         TTRMD                                                          67930020
         TPRFD                                                          67950020
         EJECT                                                          68000020
         TQCBD                                                          70000020
         TDISPD                                                         72000020
         TLCBD                                                          74000020
         TDEBD                                                          76000020
         DCBD  DSORG=TX                                                 78000020
         TPRIOR                                                         78400020
         TTSID                                                          78800020
         TSCBD                                                          79200020
         TAVTD                                                          79600020
         END                                                            80000020
