         TITLE 'IEDAYI  - TSINPUT'                                      00100020
IEDAYI   CSECT                                                          00200020
         SPACE 1                                                        00500020
         DC    AL1(DSPMCPL2),X'00'      ACTIVATION KEY                  00510020
         SPACE 1                                                        00520020
*********************************************************************** 00530020
*                                                                     * 00540020
*                                                                M2688  00541020
*                                                                M3278  00542020
*                                                                TS1628 00545020
*                                                                M0030  00546020
*                                                                 M3462 00547020
*                                                                 M0045 00548020
*                                                                 M5303 00549020
*                                                                 M5469 00549520
*          RELEASE 23 DELETIONS                                       * 00550020
*          RELEASE 22 DELETIONS                                       * 00560020
*          RELEASE 21 DELETIONS                                       * 00570020
*0884006200,013800,175000-179000,184000,185000-187000,190000,    S22029 00571001
*0884200000,230000-233000,235000-235300,337000,341000-342000,    S22029 00572001
*0884347000,350000,485000,490600-491500,516400-517600,525700-    S22029 00573001
*0884526600,962000-970000                                        S22029 00574001
*0884                                                            A44839 00575021
*                                                                     * 00580020
*0884005860,083300,129000,142000,183000,227000,235600,236400,    S22028 00581001
*0884240500,246000,335200,338000,339200,358940,368700,463000,    S22028 00582001
*0884486200                                                      S22028 00583001
* STATUS CHANGE LEVEL 002                                               00593021
*                                                                     * 00600020
* FUNCTION -                                                          * 00610020
*    THIS ROUTINE IS RESPONSIBLE FOR MOVING THE INCOMING TEXT FROM A  * 00620001
*    TCAM BUFFER INTO A TIME SHARING BUFFER OR BUFFERS AND PLACING    * 00630020
*    THE BUFFER(S) ON THE INPUT QUEUE.                                * 00640020
*                                                                     * 00650020
* ENTRY POINTS -                                                      * 00660020
*    ENTRY IS ALWAYS THROUGH THE FIRST EXECUTABLE INSTRUCTION.        * 00670020
*    CONTROL IS ALWAYS RECEIVED FROM THE TCAM DISPATCHER UNDER ONE OF * 00680020
*    THE FOLLOWING CONDITIONS.                                        * 00690020
*                                                                     * 00700020
*    1 - EITHER THE PCI APPENDAGE, WHICH INDICATES A FULL TCAM BUFFER,* 00710020
*        OR THE LINE END APPENDAGE, WHICH INDICATES THE END OF THE    * 00720020
*        MESSAGE (EOT, EOB, BREAK-IN, OR TIME OUT), QPOSTS A TCAM     * 00730020
*        BUFFER TO THE MHR.  THE FORWARD AND LOGON MACROS IN THE      * 00740020
*        INHDR SECTION OF THE MHR PERFORM THE INITIALIZATION NECES-   * 00750020
*        SARY TO DIRECT THE BUFFER TO TSINPUT.  SUBSEQUENTLY, AT THE  * 00760020
*        END OF THE INPUT MESSAGE HANDLING ROUTINES, THE BUFFER IS    * 00770020
*        QPOSTED TO THE TSINPUT DESTINATION QCB.                      * 00780020
*                                                                     * 00790020
*    2 - WHEN ONE OF THE TIOC ROUTINES (TGET, TCLEARQ, TSOUTPUT, OR   * 00800020
*        ATTENTION) QPOSTS TSINPUT'S DESTINATION QCB TO ITSELF FOR    * 00810020
*        THE PURPOSE OF REMOVING THE SYSTEM LWAIT CONDITION.          * 00820020
*                                                                     * 00830020
* INPUT -                                                             * 00840020
*    THE FOLLOWING PARAMETERS ARE PASSED WHEN CONTROL IS RECEIVED AS  * 00850020
*    THE RESULT OF ENTRY (1) DESCRIBED ABOVE.                         * 00860020
*        REGISTER 1  CONTAINS THE TCAM BUFFER ADDRESS.                * 00870020
*        REGISTER 7  CONTAINS TSINPUT'S DESTINATION QCB ADDRESS.      * 00880020
*        REGISTER 11 CONTAINS THE ADDRESS OF THE TCAM DISPATCHER.     * 00890020
*        REGISTER 13 CONTAINS THE ADDRESS OF AVTSAVE2.                * 00900020
*        REGISTER 15 CONTAINS THE ENTRY POINT ADDRESS OF TSINPUT.     * 00910020
*                                                                     * 00920020
*    THE FOLLOWING PARAMETERS ARE PASSED WHEN CONTROL IS RECEIVED AS  * 00930020
*    THE RESULT OF ENTRY (2) DESCRIBED ABOVE.                         * 00940020
*        REGISTER 1  CONTAINS TSINPUT'S DESTINATION QCB ADDRESS.      * 00950020
*        REGISTER 7  CONTAINS TSINPUT'S DESTINATION QCB ADDRESS.      * 00960020
*        REGISTER 11 CONTAINS THE ADDRESS OF THE TCAM DISPATCHER.     * 00970020
*        REGISTER 13 CONTAINS THE ADDRESS OF AVTSAVE2.                * 00980020
*        REGISTER 15 CONTAINS THE ENTRY POINT ADDRESS OF TSINPUT.     * 00990020
*                                                                     * 01000020
* OUTPUT -                                                            * 01010020
*    REGISTER 1 - CONTAINS THE ADDRESS OF THE FIRST AND ONLY OR FIRST * 01020020
*    IN A CHAIN OF ELEMENTS TO BE POSTED BY THE TCAM DISPATCHER.  IF  * 01030020
*    NO ELEMENTS ARE TO BE POSTED, REGISTER 1 MUST CONTAIN ZEROS. THE * 01040020
*    ELEMENTS BEING POSTED MAY BE QCB'S, LCB'S, OR TCAM BASIC UNITS   * 01050020
*    (ALWAYS RETURNED AS ONE TCAM BUFFER).  THIS CHAIN OF ELEMENTS    * 01060020
*    MAY CONTAIN ANY NUMBER OF QCB'S AND/OR LCB'S, HOWEVER, IF A TCAM * 01070020
*    BUFFER IS BEING POSTED, IT WILL ALWAYS APPEAR AS THE LAST        * 01080020
*    ELEMENT IN THE CHAIN.                                            * 01090020
*                                                                     * 01100020
*    REGISTER 11 - CONTAINS THE ADDRESS OF THE TCAM DISPATCHER.       * 01110020
*                                                                     * 01120020
* EXTERNAL REFERENCES -                                               * 01130020
*    THE QTIP SVC (SVC 101) WITH THE APPROPRIATE ENTRY CODES, IS      * 01140020
*    USED BY THIS ROUTINE TO PASS CONTROL TO A ROUTINE WITHIN QTIP    * 01150020
*    NAMED 'IEDAYII'.  IEDAYII IS A LOGICAL EXTENSION OF TSINPUT USED * 01160020
*    TO INTERFACE WITH THE CONTROL BLOCKS AND BUFFERS WITHIN THE TSO  * 01170020
*    REGION.                                                          * 01180020
*                                                                     * 01190020
* EXITS, NORMAL -                                                     * 01200020
*    CONTROL IS ALWAYS RETURNED BY BRANCHING TO 'DSPCHAIN' WITHIN THE * 01210020
*    TCAM DISPATCHER.                                                 * 01220020
*                                                                     * 01230020
* EXITS, ERROR -                                                      * 01240020
*    NONE                                                             * 01250020
*                                                                     * 01260020
* TABLES/WORK AREAS -                                                 * 01270020
*    THE FIRST BYTE OF THE TCAM BUFFER 'PRFSRCE' FIELD IS CLEARED IN  * 01280020
*    ORDER TO SAVE INFORMATION CONTAINED IN LCB AND THE STATUS OF THE * 01290020
*    TCAM BUFFER IF INSUFFICIENT TS BUFFERS ARE AVAILABLE TO PROCESS  * 01300020
*    ALL THE DATA IN THE TCAM BUFFER.                                 * 01310020
*                                                                     * 01320020
*    A DOUBLE WORD AREA IN THE AVT LABELED 'AVTDOUBL' IS USED TO      * 01330020
*    BUILD THE CHAIN OF ELEMENTS TO BE POSTED BY THE TCAM DISPATCHER  * 01340020
*    AFTER EXITING FROM TSINPUT.                                      * 01350020
*                                                                     * 01360020
* ATTRIBUTES -                                                        * 01370020
*    SERIALLY-REUSABLE, REFRESHABLE, ENABLED                          * 01380001
*                                                                     * 01390020
* CHARACTER CODE DEPENDENCY -                                         * 01400020
*    THIS ROUTINE IS DEPENDENT ON THE FOLLOWING EBCDIC CHARACTERS.    * 01410020
*        X'0D' - EBCDIC CARRIAGE RETURN CHARACTER.  EQUATED TO        * 01420020
*        'CARRRTRN' WITHIN THIS ROUTINE.                              * 01430020
*                                                                     * 01440020
*        X'15' - EBCDIC NEW LINE CHARACTER.  EQUATED TO 'NEWLINE'     * 01450020
*        WITHIN THIS ROUTINE.                                         * 01460020
*                                                                     * 01470020
*        X'25' - EBCDIC LINE FEED CHARACTER.  EQUATED TO 'LINEFEED'   * 01480020
*        WITHIN THIS ROUTINE.                                         * 01490020
*                                                                     * 01500020
* NOTES -                                                             * 01510020
*                                                                     * 01520020
*********************************************************************** 01530020
         EJECT                                                          01540020
*********************************************************************** 01550020
********                                                       ******** 01600020
******** REGISTER EQUATES                                      ******** 01700020
********                                                       ******** 01800020
*********************************************************************** 01900020
         SPACE 1                                                        02000020
R0       EQU   0                        INDEX REGISTER                  02100020
RWRKZ    EQU   R0                       WORK/PARAMETER REGISTER         02200020
RPARM    EQU   1                        WORK/PARAMETER REGISTER         02300020
RSCANF   EQU   2                        POINTER TO BEGIN OF DATA SCANED 02500020
RWRK2    EQU   RSCANF                   WORK/PARAMETER REGISTER         02600020
RSCANL   EQU   3                        POINTER TO END OF DATA SCANNED  02660020
RSCB     EQU   RSCANL                   SCB ADDRESS                     02720020
RWRK3    EQU   RSCB                     WORK/PARAMETER REGISTER         02800020
RBUEND   EQU   4                        END OF BASIC UNIT BEING SCANNED 02900020
RLCB     EQU   RBUEND                   LCB ADDRESS                     03000020
RBUADR   EQU   5                        ADDR OF BASIC UNIT BEING SCANED 03200020
RTRMNTRE EQU   RBUADR                   ADDR OF TERMINAL ENTRY TABLE    03300020
RPREFIX  EQU   6                        TCAM BUFFER ADDRESS             03500020
RQCB     EQU   7                        QCB ADDRESS                     03700020
RWRK7    EQU   RQCB                     WORK/PARAMETER REGISTER         03800020
RDSZE    EQU   8                        SIZE OF DATA IN TCAM BUFFER     03900020
RWRK8    EQU   RDSZE                    WORK/PARAMETER REGISTER         04000020
RTSB     EQU   9                        TSB ADDRESS                     04100020
RTIOC    EQU   10                       TIOCRPT ADDRESS                 04200020
RDISP    EQU   11                       DISPATCHER ADDRESS (IEDQEA)     04300020
RWK11    EQU   RDISP                    WORK/PARAMETER REGISTER         04400020
RBASE    EQU   12                       BASE REGISTER                   04500020
RAVT     EQU   13                       ADDRESS OF AVTSAVE2             04600020
RETRN    EQU   14                       RETURN ADDRESS                  04700020
RDEL     EQU   RETRN                    OFFSET TO DATA IN TCAM BFR      04800020
RWK14    EQU   RDEL                     WORK/PARAMETER REGISTER         04900020
RNTRE    EQU   15                       ENTRY POINT                     05000020
RTRNCD   EQU   RNTRE                    RETURN CODE                     05100020
RWK15    EQU   RTRNCD                   WORK/PARAMETER REGISTER         05200020
         EJECT                                                          05300020
*********************************************************************** 05400020
********                                                       ******** 05500020
******** MASKS AND DISPLACEMENTS                               ******** 05600020
********                                                       ******** 05700020
*********************************************************************** 05800020
         SPACE 1                                                        05900020
K0       EQU   0                        NULL DISPLACEMENT               06000020
K1       EQU   1                        BYTE DISPLACEMENT               06100020
CC3270ND EQU   1                        AID CHAR LENGTH FOR 3270 S22028 06150001
K2       EQU   2                        LENGTH FIELD                    06200020
K3       EQU   3                        LENGTH FIELD                    06300020
CC3270D3 EQU   3                        CONTROL CHAR LNG FOR     S22028 06330001
*                                       3270                     S22028 06360001
K4       EQU   4                        WORD DISPLACEMENT               06400020
CC3270D6 EQU   6                        TOTAL CONTROL CHAR       S22028 06420001
*                                       LENGTH                   S22028 06440001
*                                       FOR 3270                        06460001
NOTEQUAL EQU   7                        MASK FOR A CONDITION CODE OF 7  06500020
EQUAL    EQU   8                        MASK FOR CONDIT'N CODE 8        06550020
K11      EQU   11                       BYTE DISPLACEMENT        S22029 06570001
K12      EQU   12                       SAVE AREA OFFSET                06600020
K24      EQU   24                       LENGTH FIELD                    06800020
K68      EQU   68                       LENGTH FIELD                    06900020
ONE      EQU   X'01'                    CONSTANT                        07000020
CARRRTRN EQU   X'0D'                    CARRIAGE RETURN CHARACTER       07150020
NEWLINE  EQU   X'15'                    NEW LINE CHARACTER              07200020
WAITQBFR EQU   X'10'                    USED TO INDICATE TCAM BFR HAS   07270020
*                                       BEEN ON TCAM BFR WAIT QUEUE     07340020
NOTMOVED EQU   X'20'                    IND NOT ALL OF SCANNED DATA IN  07370020
*                                       TCAM BFR WAS MOVED TO TS BFR(S) 07400020
LINEFEED EQU   X'25'                    LINE FEED CHARACTER             07440020
SBA      EQU   X'11'                    SBA CHARACTER            S22028 07450001
TIMEOUT  EQU   X'40'                    TIME OUT OCCURED IN THIS BFR    07460020
WRITEBRK EQU   X'80'                    WRITE BREAK IN PROGRESS         07500020
CC32706  EQU   X'08'                    TCAM BUFFER HAS MORE     S22028 07520001
*                                       THAN                     S22028 07540001
*                                       ONE CONTROL CHARACTER           07560001
OFF      EQU   X'FF'                    USED TO RESET BITS              07600020
         EJECT                                                          07700020
********                                                                07800020
******** ESTABLISH ADDRESSABILITY                                       07900020
********                                                                08000020
         USING *,RBASE                  ESTABLISH ADDRESSABILITY        08080020
         LR    RBASE,RNTRE              PUT ENTRY PT ADDR INTO BASE REG 08160020
         B     TSIN0010                 BRANCH AROUND IDENTIFIER        08240020
         DC    CL6'IEDAYI'              IDENTIFIER                      08320020
         DC    X'2104'                  DATE - 4/13/72           S22028 08330001
         DS    0H                       ENSURE HALFWORD ALLIGNMENT      08350020
         USING AVTSAVE2,RAVT            USE RAVT AS AVT BASE REGISTER   08380020
         USING TIOCRPT,RTIOC            USE RTIOC AS TIOCRPT BASE REG   08500020
         USING TSB,RTSB                 USE RTSB AS TSB BASE REGISTER   08600020
         SPACE 2                                                        08700020
********                                                                08800020
******** INITIALIZATION-GET POINTERS TO THE TIOCRPT AND THE AVT.  ALSO  08900020
******** CLEAR A WORK AREA FOR A TCAM BUFFER RETURN QUEUE.              09000020
********                                                                09100020
TSIN0010 EQU   *                                                        09150020
         ST    RDISP,AVTSAVE2+K68       SAVE TCAM DISPATCHER ADDRESS    09170020
         L     RWRK2,CVTPTR             GET CVT ADDRESS                 09200020
         USING CVT,RWRK2                USE RWRK2 AS CVT BASE REG       09300020
         L     RTIOC,CVTTSCVT                  GET ADDR OF TSCVT        09400020
         L     RTIOC,TSCVTRPT-TSCVT(R0,RTIOC)  GET ADDR OF TIOCRPT      09500020
         DROP  RWRK2                    DROP RWRK2 AS CVT BASE REG      09800020
         XC    AVTDOUBL,AVTDOUBL        CLEAR A WORK AREA IN THE AVT    09900020
         SPACE 2                                                        10000020
********                                                                10100020
******** ENTRY CHECK                                                    10200020
********                                                                10300020
         LA    RQCB,K0(R0,RQCB)         CLEAR HI ORDER BYTE OF REGISTER 10350020
         LA    RPARM,K0(R0,RPARM)       CLEAR HI ORDER BYTE OF REGISTER 10400020
         CLR   RPARM,RQCB               WAS A TCAM BUFFER PASSED        10500020
         BE    TSIN2000                 BRANCH IF NO                    10600020
         LR    RPREFIX,RPARM            GET TCAM BUFFER ADDRESS         10700020
         USING IEDQPRF,RPREFIX          USE RPREFIX AS PREFIX BASE REG  10800020
         SPACE 2                                                        10900020
********                                                                11000020
******** FIND ASSOCIATED LCB AND SCB FOR THIS TERMINAL                  11100020
********                                                                11200020
         USING IEDQLCB,RLCB             USE RLCB AS LCB BASE REGISTER   11300020
         USING IEDQSCB,RSCB             USE RSCB AS SCB BASE REGISTER   11400020
         L     RLCB,PRFLCB-K1           GET LCB ADDRESS                 11500020
         L     RSCB,LCBSCBA-K1          ADDRESS OF THE CURRENT SCB      11600020
         SPACE 2                                                        11700020
********                                                                11800020
******** FIND ASSOCIATED TERMINAL ENTRY TABLE AND QCB FOR THIS TERMINAL 11900020
********                                                                12000020
         USING IEDQTRM,RTRMNTRE         USE RPARM AS TERM ENTRY BASE    12100020
         USING IEDQQCB,RQCB             USE RQCB AS QCB BASE REGISTER   12200020
         LH    RPARM,PRFSRCE            GET INDEX TO TNT                12300020
         L     RWK15,AVTRNMPT           GET ADDRESS OF TNT              13000020
         BALR  RETRN,RNTRE              BR TO CODE AT BEGINNING OF TNT  13100020
         LR    RTRMNTRE,RPARM           GET ADDR OF TERM ENTRY TABLE    13200020
         L     RQCB,TRMDESTQ-K1         GET DEST QCB ADDR FOR THIS TERM 13300020
         TM    QCBFLAG,QCBTSSES         IS TSO SESSION IN PROGRESS      13330020
         BZ    TSIN0174                 RETURN TCAM BFR IF NOT          13360020
         TM    AVTBIT3,AVTTSAB          DID TSO ABEND            A44839 13370021
         BO    TSIN0174                 RETURN TCAM BUFFERS IF   A44839 13380021
*                                       YES                      A44839 13390021
         DROP  RTRMNTRE                 DROP TERM ENTRY TBL BASE REG    13400020
         SPACE 2                                                        13500020
********                                                                13600020
******** FIND ASSOCIATED TSB FOR THIS TERMINAL                          13700020
********                                                                13800020
         SR    RTSB,RTSB                CLEAR TSB REGISTER              13900020
         IC    RTSB,TIOCTSBS            GET TSB SIZE                    14000020
         LH    RWRK8,QCBTJID            POS IN TSB CHAIN OF CURRENT TSB 14100020
         BCTR  RWRK8,R0                 DECR TJID FOR PROPER TSB        14300020
         MR    RWRK8,RWRK8              CALC OFFSET TO CURRENT TSB      14400020
         A     RTSB,TIOCTSB-K1          ADDR OF CURRENT TSB             14500020
         SPACE 2                                                        14600020
********                                                                14700020
******** IF THIS IS THE LAST TCAM BUFFER OF THE MESSAGE, PERFORM END OF 14780020
******** MESSAGE PROCESSING AND SAVE RELATED INFORMATION IN THE FIRST   14860020
******** BYTE OF THE TIC FIELD IN THE FIRST BASIC UNIT OF THE TCAM      14940020
******** BUFFER ACCORDING TO THE FOLLOWING FORMAT.                      15020020
********                                                                15100020
********       BIT 0 - WILL REFLECT THE LCBWRBRK BIT.                   15200020
********                                                                15250020
********       BIT 1 - WILL REFLECT THE OCCURANCE OF TIME OUT (X'01' IN 15310020
********               LCBSENS0).                                       15370020
********                                                                15450020
********       BIT 2 - WILL INDICATE THAT PART OF THE LAST LINE SCANNED 15470020
********               IN THIS TCAM BFR WAS NOT MOVED TO TS BFR(S).     15490020
********                                                                15510020
********       BIT 3 - WILL INDICATE THAT THIS BUFFER HAS BEEN ON THE   15540020
********               TCAM BUFFER WAIT QUEUE.                          15570020
********                                                                15600020
         CLC   PRFSIZE,AVTFZERO         IS SIZE FIELD ZEROS             15601020
         BE    TSIN0174                 RETURN TCAM BFR IS YES          15602020
         USING IEDQTSI,RWRK8            EST TSINPUT'S QCB BASE          15603020
         L     RWRK8,AVTTSOPT           ADDR OF TSINPUT'S QCB           15604020
         LA    RWRK8,TSIBUFQ            ADDR OF BFR WAIT QUEUE          15605020
         DROP  RWRK8                    DROP TSINPUT'S QCB BASE         15606020
         TM    TSBFLG1,TSBIFLSH         IS TCLEARQ INPUT IN PROGRESS    15609420
         BO    TSIN0012                 YES, CHECK TCAM BFR WAIT QUEUE  15611420
         NI    PRFTIC,AVTEZERO          CLEAR FIRST BYTE OF TIC FIELD   15614720
         TM    PRFSTAT1,PRFNLSTN        IS THIS LAST TCAM BFR OF MSG    15620020
         BO    TSIN0019                 BRANCH IF NO                    15630020
         NI    QCBFLAG,OFF-QCBREAD      IND READ NO LONGER HAS PRIORITY 15650020
         TM    LCBTSOB,LCBWRBRK         DID A WRITE BREAK OCCUR         15660020
         BZ    TSIN0011                 BRANCH IF NO                    15670020
         OI    PRFTIC,WRITEBRK          IND WRITE BREAK IN PROGRESS     15680020
         SPACE 1                                                        15690020
TSIN0011 EQU   *                                                        15700020
         NI    LCBTSOB,OFF-LCBWRBRK     RESET WRITE BREAK INDICATOR     15740020
         TM    PRFSTAT1,PRFCNCLN        IS THIS TCAM MSG TO BE CANCELED 15780020
         BO    TSIN0012                 BRANCH IF YES                   15860020
         TM    SCBERR3,SCBATTN+SCBSATTN+SCBXPI+SCBXPD  DID ATTEN OCCUR  15920020
         BZ    TSIN0018                 BRANCH IF NO                    15980020
         OI    PRFSTAT1,PRFCNCLN        IND THAT MSG IS TO BE CANCELED  16040020
         SPACE 1                                                        16100020
TSIN0012 EQU   *                                                        16200020
         TM    QCBTSOF2,QCBBUFQ         ANY TCAM BFRS ON WAIT QUEUE FOR 16202020
*                                       THIS QCB                        16204020
         BZ    TSIN0016                 BRANCH IF NONE FOR THIS QCB     16206020
         LR    RWK11,RPREFIX            SAVE PASSED TCAM BFR ADDRESS    16208020
         LA    RTSB,K0(R0,RTSB)         CLEAR HI-ORDER BYTE OF REG      16210020
         SPACE 1                                                        16220020
TSIN0013 EQU   *                                                        16222020
         L     RPREFIX,K0(R0,RWRK8)     GET NEXT TCAM BFR ON WAIT QUEUE 16224020
         LA    RPREFIX,K0(R0,RPREFIX)   CLEAR HI-ORDER BYTE OF REG      16226020
         LTR   RPREFIX,RPREFIX          ANY MORE TCAM BFRS ON QUEUE     16228020
         BZ    TSIN0015                 BRANCH IF NO MORE               16230020
         L     RWRK2,PRFQCBA-K1         GET ADDR OF ASSOCIATED TSB      16232020
         LA    RWRK2,K0(R0,RWRK2)       CLEAR HI-ORDER BYTE OF REG      16234020
         CR    RTSB,RWRK2               IS BFR PART OF THIS TCAM MSG    16236020
         BE    TSIN0014                 BRANCH IF YES                   16238020
         LA    RWRK8,PRFLINK-K1         ADDR OF NEXT BFR POINTER        16240020
         B     TSIN0013                 BRANCH TO CONTINUE SEARCH       16242020
         SPACE 1                                                        16244020
TSIN0014 EQU   *                                                        16246020
         MVC   K1(K3,RWRK8),PRFLINK     RE-CHAIN TCAM BFR WAIT QUEUE    16248020
         LA    RETRN,TSIN0013           SET RETURN ADDR TO CONT SCAN    16250020
         B     TSIN4000                 BRANCH TO BFR RETURN ROUTINE    16252020
         SPACE 1                                                        16254020
TSIN0015 EQU   *                                                        16256020
         NI    QCBTSOF2,OFF-QCBBUFQ     IND NO MORE TCAM BFRS ARE IN    16258020
*                                       THE WAIT QUEUE FOR THIS QCB     16260020
         LR    RPREFIX,RWK11            RESTORE LAST TCAM BFR ADDRESS   16262020
         USING IEDQTSI,RWRK8            EST TSINPUT'S QCB BASE REGISTER 16262420
         L     RWRK8,AVTTSOPT           GET ADDR OF TSINPUT'S QCB       16262820
         LA    RWRK8,TSIBUFQ            GET ADDR OF TCAM BFR WAIT QUEUE 16263220
         DROP  RWRK8                    DROP TSINPUT'S QCB BASE REG     16263620
         SPACE 1                                                        16264020
TSIN0016 EQU   *                                                        16266020
         TM    TSBFLG1,TSBIFLSH         IS TCLEARQ INPUT IN PROGRESS    16266620
         BO    TSIN2028                 YES, RETURN TCAM BUFFER         16267220
         CLC   TSBIBFP,AVTFZERO         ANY TS BFRS ON INPUT HDR QUEUE  16268020
         BE    TSIN0017                 BRANCH IF NONE FOR THIS TSB     16270020
         SPACE 2                                                        16276020
********                                                                16278020
******** CALL QTIP TO DELETE ANY FRAGMENT MESSAGE WHICH MAY BE ON THE   16280020
******** INPUT QUEUE.                                                   16282020
********                                                                16284020
         QTIP  8,(RAVT)                                                 16286020
         SPACE 2                                                        16286620
********                                                                16287220
******** IF AUTOMATIC CHARACTER PROMPTING IS IN PROGRESS, REPROMPT THE  16287820
******** USER WITH THE PROMPT CHARACTER OR THE LAST LINE NUMBER.        16288420
********                                                                16289020
TSIN0017 EQU   *                                                        16289620
         TM    TSBFLG2,TSBAUTON         IS AUTO PROMPTING IN PROGRESS   16290220
         BZ    TSIN0174                 BRANCH IF NO                    16290820
         OI    SCBERR2,SCBALN           TELL TCAM TO PROMPT THE USER    16291420
         B     TSIN0174                 BRANCH TO RETURN TCAM BUFFER    16292020
         DROP  RSCB                     DROP RSCB AS SCB BASE REGISTER  16294020
         SPACE 1                                                        16296020
TSIN0018 EQU   *                                                        16298020
         TM    LCBSENS0,ONE             DID TIME OUT OCCUR IN THIS BFR  16498020
         BZ    TSIN0019                 BRANCH IF NO                    16698020
         OI    PRFTIC,TIMEOUT           IND TIME OUT OCCURED IN BFR     16898020
         DROP  RLCB                     DROP RLCB AS LCB BASE REG       17200020
         SPACE 2                                                        17300020
********                                                                17400020
******** DETERMINE WHETHER THIS IS A TCAM HEADER OR A TCAM TEXT BUFFER  17500001
******** AND SET THE DATA OFFSET EQUAL TO THE APPROPRIATE TCAM PREFIX   17600001
******** SIZE.                                                          17700001
********                                                                18000020
TSIN0019 EQU   *                                                        18100020
         LH    RDSZE,PRFSIZE            SIZE OF DATA IN TCAM BFR        18200020
         LA    RDEL,AVTHDRSZ            DATA OFFSET FOR TCAM HDR S22029 18500001
         TM    PRFSTAT1,PRFNHDRN        IS THIS FIRST BFR OF MESSAGE    18800020
         BZ    TSIN0028                 BRANCH IF YES                   18900020
         LA    RDEL,AVTTXTSZ            DATA OFFSET FOR TCAM TXT S22029 19000001
         SPACE 2                                                        19200020
********                                                                19300020
******** DETERMINE IF THERE ARE ANY TCAM BUFFERS ON THE TCAM BUFFER     19400020
******** WAIT QUEUE FOR THIS TSB.  IF THERE ARE, PLACE THIS TCAM BUFFER 19500020
******** ON THE QUEUE.                                                  19600020
********                                                                19700020
TSIN0020 EQU   *                                                        19800020
         STH   RDEL,PRFSRCE             PUT DATA OFFSET INTO HDR BFR    19900020
         SR    RDSZE,RDEL               ACTUAL SIZE OF DATA IN TCAM BFR 20100020
         STH   RDSZE,PRFSIZE            STORE UPDATED DATA SIZE         20200020
         TM    QCBTSOF2,QCBBUFQ         ANY TCAM BFRS ON BFR WAIT QUEUE 20300020
*                                       FOR THIS TSB                    20400020
         BO    TSIN0240                 YES, PUT BFR ON WAIT Q          20900020
         B     TSIN0052                 BRANCH TO PROCESS TCAM BUFFER   21500020
         SPACE 2                                                        22400020
********                                                                22500020
******** SINCE THIS IS THE FIRST TCAM BUFFER OF THE MESSAGE, THE FIRST  22600020
******** TWO OR THREE BYTES OF DATA MAY BE ALL ZEROS. IF SO, ADJUST     22700001
******** DATA OFFSET AND DATA SIZE VALUES TO EXCLUDE THESE BYTES.       22800020
********                                                                22900020
TSIN0028 EQU   *                                                        23400020
         LA    RSCANF,K12(RDEL,RPREFIX) POINT TO 1ST DATA CHAR   S22029 23500001
         SR    RDSZE,RDEL               DATA SIZE IN BUFFER      S22029 23530001
         SPACE 1                                                        23580020
TSIN0029 EQU   *                                                        23600020
         LTR   RDSZE,RDSZE              ANY DATA LEFT IN TCAM BFR       23620020
         BZ    TSIN0040                 BRANCH IF NO MORE        S22028 23640001
         CLI   K0(RSCANF),AVTEZERO      IS THIS BYTE OF DATA ALL ZEROS  23660020
         BNE   TSIN0030                 BRANCH IF NO                    23700020
         LA    RSCANF,K1(R0,RSCANF)     POINT TO NEXT CHAR IN TCAM BFR  23800020
         LA    RDEL,K1(R0,RDEL)         INCREMENT DATA OFFSET           23900020
         BCTR  RDSZE,R0                 DECR SIZE OF DATA IN TCAM BFR   24000020
         B     TSIN0029                 BR TO CHECK ZEROES AGAIN S22028 24050001
         SPACE 2                                                 S22028 24052001
********                                                                24053001
******** CHECK FOR 3270 TERMINAL, IF IT IS, BYPASS THE CONTROL          24054001
******** CHARACTERS IN SCANNING.  THE CONTROL CHARACTERS WILL BE MOVED  24055001
******** INTO TS BUFFERS BY IEDAYII.  THERE WILL BE ONE CONTROL (AID)   24056001
******** CHARACTER WHEN ONLY PROGRAM FUNCTION KEYS ARE ENTERED, BUT     24057001
******** THERE WILL BE EITHER THREE OR SIX CONTROL CHARACTERS IF ANY    24058001
******** TEXT DATA IS ENTERED. IF THE FOURTH CHARACTER IS X'11',        24059001
******** THE NUMBER OF CONTROL CHARACTERS WILL BE SIX. OTHERWISE        24060001
******** THERE WILL BE THREE CONTROL CHARACTERS. BIT 4 (X'08') IN THE   24061001
******** FIRST BYTE OF THE TIC FIELD IN THE TCAM BUFFER (PRFTIC)        24062001
******** WILL BE TURNED ON INDICATING TO IEDAYII THAT THERE ARE MORE    24063001
******** THAN ONE CONTROL CHARACTERS TO MOVE.                           24064001
********                                                                24065001
TSIN0030 EQU   *                                                 S22028 24066001
         TM    TSBSTAT,TSB3270          TEST FOR 3270            S22028 24067001
         BZ    TSIN0040                 BRANCH IF NO             S22028 24068001
         CH    RDSZE,CC3270L            IS DATA SIZE LESS THAN 3 S22028 24069001
         BNL   TSIN0032                 BRANCH IF NO             S22028 24070001
         LA    RDEL,CC3270ND(R0,RDEL)   ADD 1 TO DATA OFFSET     S22028 24071001
         BCTR  RDSZE,R0                 MINUS 1 FROM DATA SIZE   S22028 24072001
         B     TSIN0040                 GO TO STORE DATA SIZE    S22028 24073001
         SPACE 1                                                 S22028 24074001
TSIN0032 EQU   *                                                 S22028 24075001
         LA    RDEL,CC3270D3(R0,RDEL)   ADD 3 TO DATA OFFSET     S22028 24076001
         SH    RDSZE,CC3270L            SUBTRACT 3 FROM DATA     S22028 24077001
*                                       SIZE                     S22028 24078001
         OI    PRFTIC,CC32706           BUFFER HAS MORE THAN 1   S22028 24079001
*                                       CONTROL CHARACTERS              24080001
         CLI   CC3270D3(RSCANF),SBA     CHECK FOR SBA CHAR       S22028 24081001
         BNE   TSIN0040                 BRANCH IF NOT            S22028 24082001
         SPACE 1                                                 S22028 24083001
         LA    RDEL,CC3270D3(R0,RDEL)   ADD 3 MORE TO DATA       S22028 24084001
*                                       OFFSET                   S22028 24085001
         SH    RDSZE,CC3270L            SUBTRACT 3 MORE FROM     S22028 24086001
*                                       DATA SIZE                S22028 24087001
         SPACE 2                                                        24100020
********                                                                24200020
******** STORE THE UPDATED DATA SIZE AND THE DATA OFFSET IN THE HEADER  24300020
******** BUFFER.                                                        24400020
********                                                                24500020
TSIN0040 EQU   *                                                 S22028 24600001
         STH   RDEL,PRFSRCE             PUT DATA OFFSET INTO HDR BFR    24800020
         STH   RDSZE,PRFSIZE            STORE UPDATED DATA SIZE         25000020
         SPACE 2                                                        29700020
********                                                                29800020
******** IF THERE ARE ANY TIME SHARING BUFFERS ON THE INPUT QUEUE FOR   29900020
******** THIS TSB, GET A POINTER TO THE LAST HEADER BUFFER ON THIS      30000020
******** QUEUE.                                                         30100020
********                                                                30200020
TSIN0052 EQU   *                                                        30300020
         USING TIOCBUF,RWK11            USE RWK11 AS TS BFR BASE REG    30600020
         L     RWK11,TSBIBFP-K1         GET FIRST BFR ON INPUT QUEUE    30700020
         LA    RWK11,K0(R0,RWK11)       CLEAR HI ORDER BYTE OF REG      30720020
         LTR   RWK11,RWK11              ANY TS BFRS ON INPUT HDR QUEUE  30740020
         BZ    TSIN0062                 BRANCH IF NONE                  30760020
         SPACE 1                                                        30800020
TSIN0056 EQU   *                                                        30900020
         CLC   BUFFHEAD,AVTFZERO        MORE HDR BFRS ON INPUT QUEUE    31000020
         BE    TSIN0060                 BRANCH IF NO MORE               31100020
         L     RWK11,BUFFHEAD-K1        GET ADDR OF NEXT HDR BFR ON Q   31200020
         B     TSIN0056                 CONT SEARCH FOR LAST HDR BFR    31300020
         SPACE 2                                                        31400020
********                                                                31407020
******** IF THIS TCAM BUFFER IS NOT A HEADER BUFFER, AND IF THERE ARE   31414020
******** NO INCOMPLETE TIME SHARING BUFFERS AND NO TCAM BUFFERS BEING   31421020
******** HELD FOR THIS TERMINAL, THE DATA SHOULD BE IGNORED.            31428020
********                                                                31435020
TSIN0060 EQU   *                                                        31442020
         TM    BUFFFL2,BUFFFRAG         IS LAST TCAM MSG ON Q COMPLETE  31449020
         BO    TSIN0070                 BRANCH IF NOT                   31456020
         SPACE 1                                                        31463020
TSIN0062 EQU   *                                                        31470020
         TM    PRFSTAT1,PRFNHDRN        IS THIS FIRST TCAM BFR OF MSG   31477020
         BO    TSIN0174                 BRANCH IF NO                    31484020
         SPACE 2                                                        31491020
********                                                                31500020
******** DETERMINE IF ANY TS BUFFERS ARE AVAILABLE TO PROCESS THE TCAM  31600020
******** BUFFER.  IF SO, CALCULATE THE BEGINNING ADDRESS OF THE DATA    31700020
******** WITHIN THE TCAM BUFFER.  OTHERWISE, PLACE THE TCAM BUFFER ON   31800020
******** THE TCAM BUFFER WAIT QUEUE.                                    31900020
********                                                                32100020
         TM    TSBFLG2,TSBBIPI          IS THIS PARTIAL LINE COMPLETION 32230020
         BO    TSIN0070                 BRANCH IF YES                   32260020
         CLC   TIOCNFBF,AVTFZERO        ARE THERE ANY FREE TS BUFFERS   32300020
         BE    TSIN0240                 NO, PUT BFR ON WAIT Q           32500020
         SPACE 2                                                        32700020
********                                                                32800020
******** DETERMINE IF THE DATA IN THE TCAM BUFFER BEGINS IN THE FIRST   32900020
******** BASIC UNIT.  IF NOT, PART OF THE DATA HAS ALREADY BEEN MOVED   33000020
******** PRIOR TO THE BUFFER HAVING BEEN PLACED ON THE TCAM WAIT QUEUE. 33100020
******** IN THIS EVENT, THE DATA MUST START IN THE SECOND BASIC UNIT OF 33200020
******** THE BUFFER.                                                    33300020
********                                                                33400020
TSIN0070 EQU   *                                                        33500020
         LH    RDSZE,PRFSIZE            GET SIZE OF DATA IN TCAM BFR    33510020
         LR    RBUADR,RPREFIX           SET B.U. SCAN PTR TO BFR ADDR   33600020
         LH    RDEL,PRFSRCE             GET OFFSET TO DATA IN TCAM BFR  33860020
         LH    RWK15,AVTKEYLE           GET BASIC UNIT SIZE             34000020
         CLR   RDEL,RWK15               DOES DATA BEGIN IN FIRST B.U.   34300020
         BL    TSIN0090                 BRANCH IF YES                   34400020
         L     RBUADR,PRFTIC            GET ADDR OF SECOND BASIC UNIT   34500020
         SR    RDEL,RWK15               DECR DATA OFFSET BY FIRST B.U.  34600020
         SPACE 1                                                        34800020
TSIN0090 EQU   *                                                        34900020
         LA    RSCANL,K12(RDEL,RBUADR)  CALCULATE BEGIN OF DATA ADDRESS 35100020
         LH    RBUEND,AVTKEYLE          GET BASIC UNIT SIZE             35200020
         LA    RBUEND,K12(RBUADR,RBUEND)  PT TO END OF THIS BASIC UNIT  35300020
         DROP  RQCB                     DROP RQCB AS QCB BASE REGISTER  35770020
         SPACE 2                                                        35776020
********                                                                35782020
******** REMOVE ALL LINE FEED CHARACTERS FROM THE BEGINNING OF EACH TS  35788020
******** MESSAGE PRIOR TO SCANNING IT FOR VALID DATA.                   35794020
********                                                                35800020
TSIN0092 EQU   *                                                        35806020
         LR    RPARM,RDSZE              SAVE ORIGINAL DATA SIZE         35807020
         SPACE 1                                                        35808020
TSIN0093 EQU   *                                                        35809020
         LTR   RDSZE,RDSZE              ANY DATA IN TCAM BFR TO SCAN    35812020
         BNZ   TSIN0094                 BRANCH IF YES                   35818020
         STH   RDSZE,PRFSIZE            UPDATE SIZE OF DATA IN TCAM BFR 35824020
         B     TSIN0170                 BRANCH TO PROCESS TCAM BUFFER   35830020
         SPACE 1                                                        35836020
TSIN0094 EQU   *                                                        35842020
         CLI   K0(RSCANL),LINEFEED      IS NEXT CHAR A LINE FEED CHAR   35848020
         BNE   TSIN0095                 BRANCH IF NOT TO SCAN DATA      35854020
         LA    RSCANL,K1(R0,RSCANL)     INCR END SCAN PTR TO NEXT CHAR  35860020
         BCTR  RDSZE,R0                 DECR DATA SIZE BY ONE           35866020
         CLR   RBUEND,RSCANL            IS SCAN TO END OF BASIC UNIT    35872020
         LA    RETRN,TSIN0093           SET UP RETURN ADDRESS           35878020
         BCR   NOTEQUAL,RETRN           CONT IF NOT END OF BASIC UNIT   35884020
         B     TSIN0150                 BR TO GET ANOTHER BASIC UNIT    35890020
         SPACE 1                                                        35891020
TSIN0095 EQU   *                                                        35892020
         LH    RDEL,PRFSRCE             GET OFFSET TO DATA IN TCAM BFR  35893020
         SR    RPARM,RDSZE              CALCULATE NEW DATA OFFSET       35895020
         AR    RDEL,RPARM               ADD TO OLD DATA OFFSET          35896020
         STH   RDEL,PRFSRCE             STORE UPDATED DATA OFFSET       35897020
         STH   RDSZE,PRFSIZE            STORE UPDATED DATA SIZE         35898020
         SPACE 2                                                        35900020
********                                                                36000020
******** SCAN THE BASIC UNIT CURRENTLY POINTING TO FOR A CARRIAGE       36100020
******** RETURN, NEW LINE, LINE FEED, LINE DELETE, OR CHARACTER DELETE  36200020
******** CHARACTER.  IF ONE OF THESE CHARACTERS IS ENCOUNTERED, TAKE    36300020
******** THE APPROPRIATE ACTION DESCRIBED BELOW.  OTHERWISE, CONTINUE   36400020
******** SCANNING WITH THE NEXT BASIC UNIT OF THE TCAM BUFFER.  WHEN NO 36500020
******** MORE BASIC UNITS REMAIN TO BE SCANNED, CONTINUE PROCESSING.    36600020
********                                                                36700020
TSIN0096 EQU   *                                                        36730020
         LR    RSCANF,RSCANL            INITIALIZE BEGIN SCAN POINTER   36760020
         SR    RWRK7,RWRK7              INIT CHARACTER COUNT TO ZERO    36810020
         CLC   TSBIBFP,AVTFZERO         ANY TS BFRS ON INPUT HDR QUEUE  36820020
         BE    TSIN0102                 BRANCH IF NONE                  36830020
         TM    BUFFFL1,BUFFNLCR         IS LAST MSG ON QUEUE COMPLETE   36840020
         BO    TSIN0102                 BRANCH IF YES                   36850020
         LH    RWRK7,BUFFWORK           GET PREVIOUS CHARACTER COUNT    36860020
         SPACE 1                                                        36880020
TSIN0102 EQU   *                                                        36890020
         CLR   RBUEND,RSCANL            IS SCAN TO END OF BASIC UNIT    37300020
         BNE   TSIN0106                 BRANCH IF NOT                   37330020
         BAL   RETRN,TSIN0150           BR TO GET ANOTHER BASIC UNIT    37370020
         SPACE 1                                                        37420020
TSIN0106 EQU   *                                                        37460020
         CLI   TSBLNDCC,K0              0 MEANS NO DELETE CHAR  OS58447 37470001
         BE    TSIN0107                 NO CHAR, DON'T COMPARE  OS58447 37480001
         CLC   K0(K1,RSCANL),TSBLNDCC   IS THE NEXT CHAR LINE DELETE    37500020
         BE    TSIN0130                 BRANCH IF YES                   37600020
TSIN0107 EQU   *                                                OS58447 37650001
         CLI   K0(RSCANL),NEWLINE       IS THE NEXT CHAR NEW LINE CHAR  37800020
         BE    TSIN0120                 BRANCH IF YES                   38000020
         CLI   K0(RSCANL),CARRRTRN      IS THE NEXT CHAR CARRIAGE RETRN 38300020
         BE    TSIN0120                 BRANCH IF YES                   38400020
         CLI   TSBCHDCC,K0              0 MEANS NO DELETE CHAR  OS58447 38450001
         BE    TSIN0108                 NO CHAR, DON'T COMPARE  OS58447 38452001
         CLC   K0(K1,RSCANL),TSBCHDCC   IS THE NEXT CHAR CHAR DELETE    38460020
         BNE   TSIN0108                 BRANCH IF NO                    38520020
         LTR   RWRK7,RWRK7              DOES CHARACTER COUNT EQUAL ZERO 38530020
         BZ    TSIN0110                 BRANCH IF YES                   38540020
         BCTR  RWRK7,R0                 DECR CHARACTER COUNT BY ONE     38550020
         B     TSIN0110                 CONTINUE SCANNING               38560020
         SPACE 1                                                        38570020
TSIN0108 EQU   *                                                        38580020
         CLI   K0(RSCANL),LINEFEED      IS THE NEXT CHAR LINE FEED CHAR 38590020
         BE    TSIN0110                 BRANCH IF YES                   38600020
         LA    RWRK7,K1(R0,RWRK7)       INCR CHARACTER COUNT BY ONE     38610020
         SPACE 1                                                        38620020
TSIN0110 EQU   *                                                        38630020
         LA    RSCANL,K1(R0,RSCANL)     INCR END SCAN PTR TO NEXT CHAR  38635020
         BCT   RDSZE,TSIN0102           CONT SCAN IF MORE DATA LEFT     38642020
         TM    PRFSTAT1,PRFNLSTN        IS THIS LAST TCAM BFR OF MSG    38650020
         BO    TSIN0170                 BRANCH IF NO                    38660020
         SPACE 1                                                        38670020
TSIN0120 EQU   *                                                        38680020
         TM    PRFTIC,NOTMOVED          ANY UNMOVED DATA IN TCAM BFR    38690020
*                                       FROM A PREVIOUS SCAN            38700020
         BO    TSIN0122                 BRANCH IF YES                   38710020
         LTR   RWRK7,RWRK7              DOES CHARACTER COUNT EQUAL ZERO 38720020
         BNZ   TSIN0122                 BRANCH IF NO                    38730020
         LR    RSCANF,RSCANL            INDICATE A NULL LINE            38740020
         LTR   RDSZE,RDSZE              WAS LAST CHAR SCANNED CR OR NL  38750020
         BZ    TSIN0136                 BRANCH IF NO                    38760020
         LA    RSCANL,K1(R0,RSCANL)     INCR END SCAN PTR PAST CR OR NL 38770020
         B     TSIN0136                 BRANCH TO CHAR/LINE DELETE RTN  38780020
         SPACE 1                                                        38790020
TSIN0122 EQU   *                                                        38800020
         LTR   RDSZE,RDSZE              WAS LAST CHAR SCANNED CR OR NL  38810020
         BZ    TSIN0170                 BRANCH IF NO TO MOVE DATA       38820020
         LA    RSCANL,K1(R0,RSCANL)     INCR END SCAN PTR PAST CR OR NL 38830020
         B     TSIN0170                 BRANCH TO MOVE DATA             38840020
         SPACE 2                                                        38900020
********                                                                39000020
******** DELETE THE INPUT LINE WHICH IS CURRENTLY BEING SCANNED AND     39100020
******** INCREMENT THE BEGIN AND END SCAN POINTER TO THE NEXT           39200020
******** CHARACTER IN THE TCAM BUFFER.  IF THE TCAM BUFFER IS NOT THE   39300020
******** FIRST BUFFER OF THE MESSAGE AND THE LAST CHARACTER MOVED INTO  39400020
******** TIME SHARING BUFFERS FOR THIS MESSAGE WAS NOT A CARRAGE RETURN 39500020
******** CHARACTER, A FRAGMENT MESSAGE WHICH IS PART OF THE LINE TO BE  39600020
******** DELETED EXISTS ON THE TS BUFFER INPUT QUEUE.  IN THIS CASE,    39700020
******** THE FRAGMENT MESSAGE WILL BE REMOVED FROM THE INPUT QUEUE.     39800020
********                                                                40000020
TSIN0130 EQU   *                                                        40050020
         BCTR  RDSZE,R0                 DECREMENT DATA SIZE BY ONE      40100020
         LA    RSCANL,K1(R0,RSCANL)     INCR END PTR PAST LINE DEL CHAR 40102020
         LR    RSCANF,RSCANL            RESET BEGINNING OF SCAN PTR     40104020
         LTR   RDSZE,RDSZE              ANY DATA LEFT TO SCAN           40106020
         BZ    TSIN0136                 BRANCH IF NO MORE               40108020
         CLR   RBUEND,RSCANL            IS SCAN TO END OF BASIC UNIT    40110020
         BNE   TSIN0132                 BRANCH IF NO                    40112020
         BAL   RETRN,TSIN0150           BR TO GET ANOTHER BASIC UNIT    40114020
         SPACE 1                                                        40116020
TSIN0132 EQU   *                                                        40118020
         CLI   K0(RSCANL),NEWLINE       IS THE NEXT CHAR NEW LINE CHAR  40120020
         BE    TSIN0134                 BRANCH IF YES                   40122020
         CLI   K0(RSCANL),CARRRTRN      IS THE NEXT CHAR CARRIAGE RETRN 40124020
         BNE   TSIN0136                 BRANCH IF NO                    40126020
         SPACE 1                                                        40128020
TSIN0134 EQU   *                                                        40130020
         LA    RSCANL,K1(R0,RSCANL)     INCR END SCAN PTR PAST CR OR NL 40132020
         SPACE 2                                                        40134020
********                                                                40136020
******** THE FOLLOWING SECTION OF CODE IS COMMON TO BOTH LINE DELETE    40138020
******** AND CHARACTER DELETE FUNCTIONS.  IF PART OF THIS TS MESSAGE    40140020
******** HAS ALREADY BEEN MOVED INTO TS BUFFERS, RETURN ALL BUT THE     40142020
******** HEADER BUFFER ASSOCIATED WITH THIS TS MESSAGE.                 40144020
********                                                                40146020
TSIN0136 EQU   *                                                        40148020
         STH   RDSZE,PRFSIZE            UPDATE AMOUNT OF DATA IN BUFFER 40160020
         CLC   TSBIBFP,AVTFZERO         ANY TS BFRS ON INPUT HDR QUEUE  40260020
         BE    TSIN0138                 BRANCH IF NONE                  40360020
         TM    BUFFFL1,BUFFNLCR         IS LAST MSG ON QUEUE COMPLETE   40460020
         BO    TSIN0138                 BRANCH IF YES                   40660020
         SPACE 2                                                        40940020
********                                                                40970020
******** CALL QTIP SVC TO DELETE THE INPUT LINE CURRENTLY BEING SCANNED 41000020
********                                                                41030020
         QTIP  8,(RAVT)                                                 41060020
         B     TSIN0172                 BR TO INIT FOR NEXT SCAN        41100020
         SPACE 1                                                        41140020
TSIN0138 EQU   *                                                        41180020
         CLR   RSCANF,RSCANL            IS NEXT CHARACTER CR OR NL      41220020
         BNE   TSIN0170                 BRANCH IF YES                   41260020
         LTR   RDSZE,RDSZE              ANY MORE DATA LEFT TO SCAN      41300020
         BZ    TSIN0170                 BR IF NO TO CREATE A NULL LINE  41320020
         SR    RWRK7,RWRK7              RESET CHARACTER COUNT TO ZERO   41340020
         B     TSIN0102                 BR TO CONTINUE SCANNING DATA    41360020
         SPACE 2                                                        41400020
********                                                                41500020
******** DETERMINE IF ANY MORE BASIC UNITS REMAIN TO BE SCANED.  IF SO, 41600020
******** POINT TO THE NEXT BASIC UNIT AND CALCULATE THE BEGINNING OF    41700020
******** DATA WITHIN THIS BASIC UNIT.                                   41800020
********                                                                41900020
TSIN0150 EQU   *                                                        42000020
         DROP  RPREFIX                  DROP RPREFIX AS TCAM BFR BASE   42100020
         USING IEDQPRF,RBUADR           USE RBUADR AS TCAM BFR BASE REG 42200020
         L     RBUADR,PRFTIC            GET ADR OF NEXT BASIC UNIT      42300020
         DROP  RBUADR                   DROP RBUADR AS TCAM BFR BASE    42400020
         USING IEDQPRF,RPREFIX          USE RPREFIX AS TCAM BFR BASE    42500020
         LA    RSCANL,K12(R0,RBUADR)    POINT TO DATA IN THE NEXT B.U.  42600020
         CLR   RSCANF,RBUEND            IS BEGIN SCAN AT END LAST B.U.  42700020
         BNE   TSIN0160                 BRANCH IF NOT                   42800020
         LR    RSCANF,RSCANL            SET BEGIN SCAN EQUAL END SCAN   42900020
         SPACE 1                                                        42920020
TSIN0160 EQU   *                                                        42940020
         LH    RBUEND,AVTKEYLE          GET BASIC UNIT SIZE             42960020
         LA    RBUEND,K12(RBUADR,RBUEND)  PT TO END OF THIS BASIC UNIT  42980020
         BR    RETRN                    RETURN TO CALLER                43000020
         SPACE 2                                                        44100020
********                                                                44200020
******** CALL QTIP SVC TO MOVE THE SCANED DATA IN THE TCAM BUFFER       44300020
******** INTO TIME SHARING BUFFER(S).                                   44400020
********                                                                44500020
TSIN0170 EQU   *                                                        44600020
         QTIP  9,(RAVT)                                                 44700020
         SPACE 2                                                        44800020
********                                                                44900020
******** DETERMINE IF THE MOVE ROUTINE WAS SUCCESSFUL IN OBTAINING      45000020
******** ENOUGH TS BUFFERS TO MOVE THE SCANED DATA IN THE TCAM BUFFER   45100020
******** INTO TS BUFFER(S).  IF NOT, RETURN ANY TCAM BASIC UNITS WHICH  45200020
******** MAY BE EMPTY AND PLACE THE REMAINDER OF THE TCAM BUFFER ON THE 45300020
******** TIOCRPT BUFFER WAIT QUEUE.  OTHERWISE, DETERMINE IF ANY MORE   45400020
******** DATA REMAINS TO BE SCANNED.  IF NOT, RETURN THE EMPTY TCAM     45500020
******** BUFFER.                                                        45600020
********                                                                45700020
         LR    RWK11,RTRNCD             GET PTR TO LAST TS HDR ON QUEUE 45800020
         SRL   RTRNCD,K24               RIGHT ADJUST RETURN CODE        45900020
         LTR   RTRNCD,RTRNCD            RTRN CODE IND NO TS BFRS AVAIL  46000020
         BNZ   TSIN0180                 BRANCH IF YES                   46100020
         SPACE 1                                                        46130020
TSIN0172 EQU   *                                                        46160020
         LH    RDSZE,PRFSIZE            GET UNMOVED DATA SIZE           46200020
         LTR   RDSZE,RDSZE              ANY MORE DATA LEFT TO SCAN      46400020
         BNZ   TSIN0176                 BRANCH IF YES                   46500020
         SPACE 1                                                        46600020
TSIN0174 EQU   *                                                        46700020
         LA    RETRN,TSIN2020           RETURN TO CHK BFR WAIT QUEUE    46800020
         B     TSIN4000                 PUT TCAM BFR ON RETURN QUEUE    46900020
         SPACE 1                                                        47000020
TSIN0176 EQU   *                                                        47100020
         TM    BUFFFL1,BUFFNLCR         IS LAST TS MSG COMPLETE         47230020
         BZ    TSIN0096                 CONT SCANNING IF NOT            47260020
         CLC   TIOCNFBF,AVTFZERO        ARE THERE ANY FREE TS BUFFERS   47300020
         BNE   TSIN0092                 BRANCH IF YES TO CONTINUE SCAN  47400020
         DROP  RWK11                    DROP RWK11 AS TS BFR BASE REG   47500020
         SPACE 2                                                        47600020
********                                                                47700020
******** DETERMINE IF ANY EMPTY TCAM BASIC UNITS CAN BE RETURNED PRIOR  47800020
******** TO PLACING THE TCAM BUFFER ON THE TCAM BUFFER WAIT QUEUE.      47900020
********                                                                48000020
TSIN0180 EQU   *                                                        48100020
         CLI   PRFNBUNT,ONE             MORE THAN ONE BASIC UNIT IN BFR 48200020
         BE    TSIN0240                 BRANCH IF NO                    48300020
         LR    RBUADR,RPREFIX           GET ADDR OF FIRST BASIC UNIT    48400020
         LH    RDEL,PRFSRCE             GET OFFSET TO DATA IN TCAM BFR  48560020
         LH    RWK15,AVTKEYLE           GET BASIC UNIT SIZE             48700020
         SR    RWRK3,RWRK3              CLEAR REGISTER                  48790020
         IC    RWRK3,PRFNBUNT           GET NO. BASIC UNITS IN TCAM BFR 48880020
         BCTR  RWRK3,R0                 DECR NO. BASIC UNITS BY ONE     48970020
         SPACE 2                                                        49240020
********                                                                49330020
******** CALCULATE THE NUMBER OF TCAM BASIC UNITS WHICH ARE EMPTY AND   49420020
******** CAN BE RETURNED.                                               49510020
********                                                                49600020
TSIN0200 EQU   *                                                        49690020
         DROP  RPREFIX                  DROP RPREFIX AS TCAM BFR BASE   49780020
         USING IEDQPRF,RBUADR            USE RBUADR AS TCAM BFR BASE    49870020
         CR    RDEL,RWK15               DOES DATA BEGIN IN THIS B.U.    49970020
         BL    TSIN0210                 BRANCH IF YES                   50230020
         SR    RDEL,RWK15               DECR DATA OFFSET BY DATA AREA   50320020
         L     RBUADR,PRFTIC            GET ADDR OF NEXT BASIC UNIT     50410020
         BCT   RWRK3,TSIN0200                  CONT IF NOT LAST B.U.    50590020
         SPACE 2                                                        50680020
********                                                                50770020
******** IF THE UNMOVED DATA DOES NOT BEGIN IN THE FIRST BASIC UNIT,    50860020
******** DETERMINE IF THE DATA OFFSET IN THE BEGINING BASIC UNIT IS     50950020
******** LARGE ENOUGH TO ALLOW THE PREFIX OF THAT BASIC UNIT TO BE      51040020
******** OVERLAYED WITH THE HEADER AND THE FIRST BASIC UNIT TO BE RE-   51130020
******** TURNED.                                                        51220020
********                                                                51310020
TSIN0210 EQU   *                                                        51400020
         CLR   RBUADR,RPREFIX           DOES DATA BEGIN IN THE FIRST BU 51490020
         BE    TSIN0240                 BRANCH IF YES                   51580020
         TM    PRFSTAT1,PRFNHDRN        HEADER PREFIX            S22029 51640001
         BO    TSIN0215                 NO, USE TEXT PREFIX      S22029 51660001
         LA    RDSZE,AVTHDRSZ           COMPARAND FOR HDR PRF SZ S22029 51680001
         B     TSIN0220                 CHECK FOR EMPTY BASIC    S22029 51700001
*                                       UNITS TO RETURN                 51720001
TSIN0215 EQU   *                                                 S22029 51740001
         LA    RDSZE,AVTTXTSZ           COMPARAND FOR TXT PRF SZ S22029 51760001
TSIN0220 EQU   *                                                 S22029 51780001
         CR    RDEL,RDSZE               ENOUGH ROOM FOR PREFIX   S22029 51800001
         BL    TSIN0230                 BRANCH IF NO                    51850020
         SPACE 2                                                        51940020
********                                                                52030020
******** MOVE HEADER PREFIX TO OVERLAY PREFIX OF FIRST BASIC UNIT       52120020
******** CONTAINING UNMOVED DATA AND RETURN EMPTY BASIC UNITS.          52210020
********                                                                52300020
         MVC   PRFTIC(K1),PRFTIC-IEDQPRF(RPREFIX) MOVE FLAGS TO TIC FLD 52390020
         L     RWK15,PRFTIC             SAVE FLAGS AND TIC ADDRESS      52480020
         LA    RDSZE,K11(RDSZE)         UPDATE FOR MOVE COUNT    S22029 52570001
         EX    RDSZE,MOVEPRFX           MOVE BUFFER PREFIX INTO  S22029 52620001
*                                       NEW FIRST BASIC UNIT            52670001
         ST    RWK15,PRFTIC             RESTORE FLAGS AND TIC ADDRESS   52720020
         STH   RDEL,PRFSRCE             STORE UPDATED DATA OFFSET       52780020
         LA    RWRK3,K1(R0,RWRK3)        INCR NO. OF BASIC UNITS BY 1   52840020
         STC   RWRK3,PRFNBUNT           NO. BASIC UNITS GOING ON QUEUE  52930020
         DROP  RBUADR                   DROP RBUADR AS TCAM BFR BASE    53020020
         USING IEDQPRF,RPREFIX          USE RPREFIX AS TCAM BFR BASE    53110020
         IC    RWK14,PRFNBUNT           GET TOTAL NO. OF BASIC UNITS    53200020
         SR    RWK14,RWRK3              CALC NO. BASIC UNITS TO RETURN  53290020
         STC   RWK14,PRFNBUNT           NO. BASIC UNITS BEING RETURNED  53380020
         BAL   RETRN,TSIN4000           RETURN BASIC UNITS              53470020
         LR    RPREFIX,RBUADR           PT TO BFR TO BE PLACED ON QUEUE 53560020
         B     TSIN0240                 BR TO PLACE TCAM BFR ON QUEUE   53650020
         SPACE 2                                                        53740020
********                                                                53830020
******** RETURN THE EMPTY BASIC UNITS WHICH FOLLOW THE FIRST BASIC UNIT 53920020
******** AND CHAIN TO THE FIRST BASIC UNIT THE BASIC UNITS WHICH        54010020
******** CONTAIN UNMOVED DATA.                                          54100020
********                                                                54190020
TSIN0230 EQU   *                                                        54280020
         LA    RWRK3,K2(R0,RWRK3)       INCR NO. OF BASIC UNITS BY 2    54460020
         AR    RDEL,RWK15               INCR DATA OFFSET FOR HEADER     54470020
         SR    RWK15,RWK15              CLEAR REGISTER                  54480020
         IC    RWK15,PRFNBUNT           GET TOTAL NO. OF BASIC UNITS    54490020
         CLR   RWRK3,RWK15              CAN ANY BASIC UNITS BE RETURNED 54500020
         BE    TSIN0240                 BR IF NO TO PUT BFR ON WAIT Q   54510020
         STC   RWRK3,PRFNBUNT           NO. BASIC UNITS GOING ON QUEUE  54550020
         LR    RPARM,RPREFIX            SAVE ADDR OF FIRST BASIC UNIT   54560020
         L     RPREFIX,PRFTIC           GET ADDR OF SECOND BASIC UNIT   54570020
         SR    RWK15,RWRK3              CALC NO. BASIC UNITS TO RETURN  54580020
         STC   RWK15,PRFNBUNT           NO. BASIC UNITS BEING RETURNED  54590020
         DROP  RPREFIX                  DROP RPREFIX AS TCAM BFR BASE   54600020
         USING IEDQPRF,RPARM            USE RPARM AS TCAM BFR BASE REG  54610020
         XC    PRFTIC+K1(K3),PRFTIC+K1  CLEAR TIC FIELD                 54617020
         LA    RBUADR,K0(R0,RBUADR)     CLEAR HI-ORDER BYTE OF REG      54624020
         O     RBUADR,PRFTIC            MOVE FLAGS TO HI-ORDER BYTE     54631020
         ST    RBUADR,PRFTIC            CHAIN BASIC UNITS TOGETHER      54640020
         STH   RDEL,PRFSRCE             STORE UPDATED DATA OFFSET       54840020
         DROP  RPARM                    DROP RPARM AS TCAM BFR BASE REG 55210020
         USING IEDQPRF,RPREFIX          USE RPREFIX AS TCAM BFR BASE    55510020
         BAL   RETRN,TSIN4000           RETURN BASIC UNITS              55900020
         LR    RPREFIX,RPARM            PT TO BFR TO BE PLACED ON QUEUE 56000020
         SPACE 2                                                        56100020
********                                                                56200020
******** THE FOLLOWING ROUTINE IS USED TO PLACE A TCAM BUFFER ON THE    56300020
******** BUFFER WAIT QUEUE, LOCATED IN TSINPUT'S DESTINATION QCB,       56400020
******** UNTIL TIME SHARING BUFFERS BECOME AVAILABLE TO PROCESS IT.     56500020
******** IF ANY TCAM BUFFERS ASSOCIATED WITH THIS QCB ARE IN THE WAIT   56600020
******** QUEUE, CHAIN THIS TCAM BUFFER TO THE LAST SUCH BUFFER FOR THIS 56700020
******** QCB.  OTHERWISE, PUT THE BUFFER AT THE END OF THE QUEUE.       56800020
********                                                                56900020
         USING IEDQTSI,RWRK8            USE RWRK8 AS TSINPUT QCB BASE   57200020
TSIN0240 EQU   *                                                        57300020
         ST    RTSB,PRFQCBA-K1          SAVE TSB ADDR IN TCAM BFR       57605020
         USING IEDQQCB,RQCB             USE RQCB AS QCB BASE REGISTER   57610020
         L     RQCB,TSBQCB-K1           GET QCB ADDRESS                 57620020
         L     RWRK8,AVTTSOPT           GET ADDR OF TSINPUT'S QCB       57700020
         LA    RPREFIX,K0(R0,RPREFIX)   CLEAR HI-ORDER BYTE OF REGISTER 57710020
         CLC   TSIBUFQ,AVTFZERO         ANY TCAM BFRS ON WAIT QUEUE     57730020
         BNE   TSIN0270                 BRANCH IF YES                   57760020
         ST    RPREFIX,TSIBUFQ          PUT TCAM BUFFER ON WAIT QUEUE   57790020
         XC    PRFLINK,PRFLINK          CLEAR LINK FIELD OF LAST BFR    57820020
         B     TSIN0400                 BRANCH TO END                   57850020
         SPACE 1                                                        57880020
TSIN0270 EQU   *                                                        57910020
         DROP  RPREFIX                  DROP RPREFIX AS TCAM BFR BASE   57940020
         USING IEDQPRF,RWRK3            USE RWRK3 AS TCAM BFR BASE REG  57970020
         L     RWRK3,TSIBUFQ            GET ADDR OF FIRST BFR ON QUEUE  58000020
         TM    QCBTSOF2,QCBBUFQ         ANY BFRS ON QUEUE FOR THIS QCB  58030020
         BZ    TSIN0340                 BRANCH IF NONE                  58060020
         LA    RTSB,K0(R0,RTSB)         CLEAR HI ORDER BYTE OF TSB REG  58100020
         LA    RWRK8,TSIBUFQ            ADDR OF BFR WAIT QUEUE          58130020
         DROP  RWRK8                    DROP TSINPUT'S BASE REG         58160020
         SPACE 1                                                        58200020
TSIN0280 EQU   *                                                        58300020
         L     RWRK2,PRFQCBA-K1         GET ADDR OF TSB FOR THIS BUFFER 58400020
         LA    RWRK2,K0(R0,RWRK2)       CLEAR HI ORDER BYTE OF REGISTER 58500020
         CLR   RTSB,RWRK2               IS TSB FOR THIS QUEUE BFR EQUAL 58600020
*                                       TO CURRENT TSB SEARCHING FOR    58700020
         BE    TSIN0300                 BRANCH IF YES                   58800020
         LA    RWRK8,PRFLINK-K1         SAVE ADDR OF LINK FIELD         58850020
         L     RWRK3,PRFLINK-K1         GET ADDR OF NEXT BFR IN QUEUE   58900020
         B     TSIN0280                 CONT SEARCH FOR ASSOCIATED TSB  59000020
         SPACE 1                                                        59100020
TSIN0300 EQU   *                                                        59200020
         DROP  RWRK3                    DROP TCAM BFR BASE REG          59208020
         USING IEDQPRF,RPREFIX          EST TCAM BFR BASE REG           59216020
         TM    PRFTIC,WAITQBFR          WAS THIS BFR ON THE WAIT QUEUE  59224020
         BZ    TSIN0320                 BRANCH IF NOT                   59232020
         MVC   PRFLINK,K1(RWRK8)        CHAIN TO NEXT BFR ON Q          59240020
         ST    RPREFIX,K0(RWRK8)        CHAIN TO PREVIOUS BFR           59248020
         B     TSIN0400                 BRANCH TO END                   59256020
         DROP  RPREFIX                  DROP TCAM BFR BASE REG          59264020
         USING IEDQPRF,RWRK3            EST TCAM BFR BASE REG           59272020
         SPACE 1                                                        59280020
TSIN0320 EQU   *                                                        59288020
         CLC   PRFLINK,AVTFZERO         IS THIS THE LAST BFR IN QUEUE   59300020
         BE    TSIN0380                 BRANCH IF YES                   59400020
         L     RWK15,PRFLINK-K1         GET ADDR OF NEXT BFR IN QUEUE   59500020
         DROP  RWRK3                    DROP RWRK3 AS TCAM BFR BASE REG 59600020
         USING IEDQPRF,RWK15            USE RWK15 AS TCAM BFR BASE REG  59700020
         L     RWRK2,PRFQCBA-K1         GET ADDR OF TSB FOR THIS BUFFER 59800020
         LA    RWRK2,K0(R0,RWRK2)       CLEAR HI ORDER BYTE OF REGISTER 59900020
         CLR   RTSB,RWRK2               IS THE NEXT BFR ALSO ASSOCIATED 60000020
*                                       WITH THE CURRENT TSB            60100020
         BNE   TSIN0380                 BRANCH IF NO                    60200020
         LR    RWRK3,RWK15              POINT TO NEXT BFR IN QUEUE      60300020
         B     TSIN0320                 CONTINUE SCAN                   60400020
         DROP  RWK15                    DROP RWK15 AS TCAM BFR BASE REG 60500020
         USING IEDQPRF,RWRK3            USE RWRK3 AS TCAM BFR BASE REG  60600020
         SPACE 1                                                        61200020
TSIN0340 EQU   *                                                        61300020
         CLC   PRFLINK,AVTFZERO         IS THIS LAST TCAM BFR IN QUEUE  61400020
         BE    TSIN0380                 BRANCH IF YES                   61500020
         L     RWRK3,PRFLINK-K1         GET NEXT BFR IN QUEUE           61600020
         B     TSIN0340                 CONT SEARCH FOR LAST BFR IN Q   61700020
         SPACE 1                                                        62300020
TSIN0380 EQU   *                                                        62400020
         MVC   PRFLINK-IEDQPRF(K3,RPREFIX),PRFLINK  CHAIN NEW BFR TO    62460020
*                                       THE NEXT BFR ON THE WAIT QUEUE  62520020
         ST    RPREFIX,PRFLINK-K1       CHAIN NEW BFR TO THE PREVIOUS   62580020
*                                       BFR ON THE WAIT QUEUE           62640020
         SPACE 1                                                        62700020
TSIN0400 EQU   *                                                        62800020
         OI    QCBTSOF2,QCBBUFQ         IND BFRS IN QUEUE FOR THIS QCB  62900020
         DROP  RWRK3                    DROP RWRK3 AS TCAM BFR BASE REG 63000020
         USING IEDQPRF,RPREFIX          EST TCAM BFR BASE REG           63100020
         OI    PRFTIC,WAITQBFR          IND BFR WAS ON THE WAIT QUEUE   63200020
         TM    TIOCFLG,TIOCSYLW         IS THE SYSTEM IN LWAIT          63300020
         BO    TSIN0440                 BRANCH IF YES                   63800020
         SPACE 2                                                        64400020
********                                                                64500020
******** CALL QTIP SVC TO PUT THE SYSTEM IN AN LWAIT CONDITION.         64600020
********                                                                64700020
         QTIP  7,(RAVT)                                                 64800020
         SPACE 1                                                        65000020
TSIN0440 EQU   *                                                        65100020
         OI    QCBTSOF1,QCBNOBUF        LOCK USER'S KEYBOARD TO INPUT   65150020
         B     TSIN2020                 BRANCH TO CHK BFR WAIT Q        65220020
         DROP  RPREFIX,RQCB             DROP BASE REGISTERS             65310020
         SPACE 2                                                        65400020
********                                                                65500020
******** TURN OFF TSINPUT'S POST BIT                                    65600020
********                                                                65700020
TSIN2000 EQU   *                                                        65800020
         USING IEDQTSI,RQCB             USE RQCB AS TSINPUT'S QCB BASE  65900020
         NI    TSIFLAG,OFF-TSIPOST      TURN OFF TSINPUT'S POST BIT     66000020
         DROP  RQCB                     DROP RQCB AS TSINPUT'S QCB BASE 66100020
         SPACE 2                                                        66200020
********                                                                66300020
******** DETERMINE IF ANY TCAM BUFFERS ARE CHAINED TO THE TCAM BUFFER   66400020
******** WAIT QUEUE.  IF SO, AND IF TS BUFFERS ARE NOW AVAILABLE,       66500020
******** REMOVE THE TCAM BUFFERS ONE AT A TIME IN FIFO ORDER FROM THE   66600020
******** WAIT QUEUE IN ORDER TO PROCESS THEM.                           66700020
********                                                                66800020
TSIN2020 EQU   *                                                        66900020
         USING IEDQTSI,RWRK8            USE RWRK8 AS TSINPUT'S QCB BASE 67000020
         L     RWRK8,AVTTSOPT           GET ADDR OF TSINPUT'S QCB       67100020
         LA    RWRK8,TSIBUFQ            ADDR OF BFR WAIT QUEUE          67200020
         DROP  RWRK8                    DROP TSINPUT'S BASE REG         67300020
         SPACE 1                                                        67400020
TSIN2022 EQU   *                                                        67500020
         USING IEDQPRF,RPREFIX          USE PREFIX AS TCAM BFR BASE     67600020
         L     RPREFIX,K0(R0,RWRK8)     GET NEXT BFR ON QUEUE           67640020
         LA    RPREFIX,K0(R0,RPREFIX)   CLR HI-ORDER BYTE OF REG        67680020
         LTR   RPREFIX,RPREFIX          ANY MORE BFRS ON QUEUE          67720020
         BZ    TSIN2040                 BRANCH IF NO MORE               67760020
         TM    AVTBIT3,AVTTSAB          DID TSO ABEND            A44839 67764021
         BNO   TSIN2023                 GET TSO ADDR IF NO       A44839 67768021
         L     RWRK2,PRFLINK-K1         GET NEXT BFR ON QUEUE    A44839 67772021
         LA    RWRK2,K0(R0,RWRK2)       CLR HI-ORDER BYTE OF REG A44839 67776021
         ST    RWRK2,K0(R0,RWRK8)       RE-CHAIN BFR WAIT QUEUE  A44839 67780021
         BAL   RETRN,TSIN4000           GO TO RETURN BUFFER      A44839 67784021
         B     TSIN2022                 CONTINUE SCAN            A44839 67788021
TSIN2023 EQU   *                                                 A44839 67792021
         L     RTSB,PRFQCBA-K1          GET TSB ADDRESS                 67800020
         TM    TSBFLG1,TSBIFLSH         IS TCLEARQ IN PROGRESS          67900020
         BO    TSIN2026                 BRANCH IF YES                   68000020
         CLC   TIOCNFBF,AVTFZERO        ARE THERE ANY FREE TS BUFFERS   68100020
         LA    RETRN,TSIN0052           SET RETURN TO PROC BFR          68400020
         BNE   TSIN2032                 BRANCH IF ANY FREE BFRS         68700020
         SPACE 2                                                        69000020
********                                                                69100020
******** FIND THE NEXT BUFFER ON THE WAIT QUEUE WHICH IS NOT ASSOCIATED 69200020
******** WITH THE CURRENT BUFFER.                                       69300020
********                                                                69400020
TSIN2024 EQU   *                                                        69450020
         L     RWRK2,PRFLINK-K1         GET ADDR OF NEXT BFR IN QUEUE   69500020
         CLC   PRFQCBA,K1(RWRK2)        IS NEXT BFR ASSOCIATED WITH THE 70000020
*                                       SAME TSB AS BFR JUST REMOVED    70100020
         LA    RWRK8,PRFLINK-K1         SAVE PTR TO LINK FIELD          70200020
         BNE   TSIN2022                 BRANCH IF NOT                   70300020
         LR    RPREFIX,RWRK2            UPDATE CURRENT BFR PTR          70400020
         B     TSIN2024                 BRANCH TO CONTINUE SCAN         70500020
         SPACE 2                                                        70610020
********                                                                70620020
******** IF INPUT QUEUE FLUSHING HAS OCCURRED, RETURN THIS TCAM BUFFER. 70630020
******** IF THE TCAM BUFFER IS THE LAST OF THE MESSAGE, TERMINATE INPUT 70640020
******** QUEUE FLUSHING AND RETURN THE BUFFER.                          70650020
********                                                                70660020
TSIN2026 EQU   *                                                        70668020
         BAL   RETRN,TSIN2032           BR TO REMOVE THIS BUFFER        70676020
         SPACE 1                                                        70684020
TSIN2028 EQU   *                                                        70692020
         TM    PRFSTAT1,PRFNLSTN        IS THIS LAST BFR OF MESSAGE     70700020
         BO    TSIN2030                 NO, RETURN TCAM BFR             70710020
         SPACE 2                                                        70720020
********                                                                70730020
******** CALL QTIP SVC TO TERMINATE TCLEARQ INPUT PROCESSING.           70740020
********                                                                70750020
         QTIP  5,(RAVT)                                                 70760020
         SPACE 1                                                        70765020
TSIN2030 EQU   *                                                        70770020
         BAL   RETRN,TSIN4000           RETURN TCAM BUFFER              70775020
         B     TSIN2022                 BRANCH TO CONTINUE SCAN         70780020
         SPACE 2                                                        70785020
********                                                                70790020
******** THE FOLLOWING SUBROUTINE IS USED TO REMOVE A TCAM BUFFER FROM  70795020
******** THE TCAM BUFFER WAIT QUEUE.                                    70800020
********                                                                70805020
TSIN2032 EQU   *                                                        70810020
         USING IEDQQCB,RQCB             EST TERM DEST QCB BASE          70815020
         L     RQCB,TSBQCB-K1           GET QCB ADDRESS                 70820020
         L     RWRK2,PRFLINK-K1         GET NEXT BFR ON QUEUE           70825020
         LA    RWRK2,K0(R0,RWRK2)       CLR HI-ORDER BYTE OF REG        70830020
         ST    RWRK2,K0(R0,RWRK8)       RE-CHAIN BFR WAIT QUEUE         70835020
         LTR   RWRK2,RWRK2              ANY MORE BFRS ON QUEUE          70840020
         BZ    TSIN2034                 BRANCH IF NO MORE               70845020
         CLC   PRFQCBA,PRFQCBA-IEDQPRF(RWRK2) IS THE NEXT BFR ON        70850020
*                                       THE QUEUE PART OF THIS TCAM MSG 70855020
         BCR   EQUAL,RETRN              RETURN TO CALLER IF YES         70860020
         SPACE 1                                                        70865020
TSIN2034 EQU   *                                                        70870020
         NI    QCBTSOF2,OFF-QCBBUFQ     INDICATE NO MORE BUFFERS        70875020
*                                       ON WAIT QUEUE FOR THIS QCB      70880020
         BR    RETRN                    RETURN TO CALLER                70885020
         DROP  RPREFIX,RQCB             DROP BASE REGISTERS             70890020
         SPACE 2                                                        70900020
********                                                                71000020
******** DETERMINE IF ENOUGH TS BUFFERS ARE AVAILABLE TO REMOVE THE     71100020
******** SYSTEM FROM LWAIT.  IS SO, REMOVE ANY TSB'S WHICH MAY BE ON    71200020
******** THE TSB WAIT QUEUE AND UNLOCK THE ASSOCIATED TERMINAL KEYBOARD 71300020
******** TO ALLOW ANOTHER READ TO BE ISSUED.                            71400020
********                                                                71500020
TSIN2040 EQU   *                                                        71600020
         TM    AVTBIT3,AVTTSAB          DID TSO ABEND            A44839 71620021
         BO    TSIN2050                 RETURN CONTROL TO TCAM   A44839 71640021
*                                       DISPATCHER IF YES               71660021
         TM    TIOCFLG,TIOCSYLW         IS THE SYSTEM IN LWAIT          71700020
         BZ    TSIN2050                 BRANCH IF NO                    71800020
         SR    RWRK2,RWRK2              CLEAR REGISTER          YA00161 71850001
         CH    RWRK2,TIOCNFBF           ANY FREE BUFFERS AT ALL YA00161 71870001
         BE    TSIN2050                 NO, DON'T REMOVE LWAIT  YA00161 71880001
         CLC   TIOCNFBF,TIOCUSLW        ENOUGH FREE TS BFRS TO REMOVE   71900020
*                                       SYSTEM LWAIT CONDITION          72000020
         BL    TSIN2050                 BRANCH IF NO                    72100020
         SPACE 2                                                        72200020
********                                                                72300020
******** CALL QTIP TO REMOVE THE SYSTEM FROM LWAIT                      72400020
********                                                                72500020
         QTIP  6,(RAVT)                                                 72600020
         SPACE 2                                                        77700020
********                                                                77800020
******** RETURN CONTROL TO DSPCHAIN WITHIN THE TCAM DISPATCHER.  ALSO   77900020
******** RETURN ANY FREE TCAM BUFFERS AND/OR ANY QCBS WAITING TO BE     78000020
******** POSTED.                                                        78100020
********                                                                78200020
TSIN2050 EQU   *                                                        78300020
         USING IEDQDISP,RDISP           TCAM DISPATCHER BASE REGISTER   78400020
         L     RDISP,AVTSAVE2+K68       RESTORE TCAM DISPATCHER ADDRESS 78500020
         L     RPARM,AVTDOUBL           GET QCB AND/OR TCAM BFR ADDR    78700020
         B     DSPCHAIN                 RETURN TO THE TCAM DISPATCHER   78800020
         DROP  RDISP                    DROP TCAM DISPATCHER BASE REG   78900020
         SPACE 2                                                        79000020
********                                                                79100020
******** PLACE TCAM BUFFER ON RETURN QUEUE.  THIS QUEUE IS A DOUBLE     79200020
******** WORD WORK AREA LOCATED AT AVTDOUBL.  ALL BASIC UNITS PLACED ON 79300020
******** THIS QUEUE ARE CHAINED TOGETHER AS ONE BUFFER VIA THE TIC      79400020
******** FIELD.  THE FIRST BASIC UNIT PLACED ON THIS QUEUE WILL BE THE  79500020
******** BUFFER HEADER FOR ALL BASIC UNITS BEING RETURNED.  IF ADDING   79550020
******** A BUFFER TO THE LAST BUFFER ALREADY ON THIS QUEUE WOULD CAUSE  79600020
******** THE ONE BYTE BASIC UNIT COUNT FIELD TO OVERFLOW, ANOTHER       79650020
******** BUFFER HEADER WILL BE ADDED TO THE END OF THE QUEUE AND        79700020
******** CHAINNING WILL CONTINUE WITH THIS BUFFER.  THIS QUEUE MAY ALSO 79750020
******** CONTAIN ONE OR MORE LCB'S OR QCB'S WHICH ARE TO BE TPOSTED TO  79800020
******** THEMSELVES.  THE LCB'S, QCB'S, AND THE TCAM HEADERS ARE        79850020
******** CHAINED TOGETHER VIA THEIR LINK FIELDS.  THE TCAM HEADERS, IF  79900020
******** PRESENT, WILL ALWAYS BE THE LAST ELEMENTS IN THIS QUEUE.       79950020
******** THE FIRST WORD OF AVTDOUBL WILL POINT TO THIS CHAIN.  THE      80000020
******** SECOND WORD OF AVTDOUBL WILL POINT TO THE LAST BASIC UNIT ON   80080020
******** THE QUEUE.                                                     80160020
********                                                                80300020
TSIN4000 EQU   *                                                        80400020
         USING IEDQPRF,RPREFIX          USE RPREFIX AS TCAM BFR BASE    80500020
         XC    PRFLINK,PRFLINK          CLEAR BUFFER LINK FIELD         80600020
         SR    RWRK2,RWRK2              CLEAR REGISTER                  80700020
         IC    RWRK2,PRFNBUNT           NO. OF BASIC UNITS TO RETURN    80800020
         L     RWK15,AVTDOUBL           GET FIRST ELEMENT ON RETURN Q   80900020
         LTR   RWK15,RWK15              ANY ELEMENTS ON RETURN QUEUE    81000020
         BZ    TSIN4010                 BRANCH IF NONE                  81100020
         SPACE 1                                                        81200020
TSIN4002 EQU   *                                                        81300020
         CLC   PRFLINK-IEDQPRF(K3,RWK15),AVTFZERO  IS THIS ELEMENT THE  81360020
*                                       LAST ELEMENT IN THE LINK CHAIN  81420020
         BE    TSIN4004                 BRANCH IF YES                   81500020
         L     RWK15,K4(R0,RWK15)       GET ADDR OF NEXT ELEMENT        81600020
         B     TSIN4002                 BRANCH TO CONTINUE SEARCH       81700020
         SPACE 1                                                        81800020
TSIN4004 EQU   *                                                        81900020
         CLC   AVTDOUBL+K4(K4),AVTFZERO  ANY BASIC UNITS ON RETRN QUEUE 82000020
         BE    TSIN4006                 BRANCH IF NONE                  82100020
         DROP  RPREFIX                  DROP RPREFIX AS PREFIX BASE REG 82200020
         USING IEDQPRF,RWK15            USE RWK15 AS PREFIX BASE REG    82300020
         SR    RWRKZ,RWRKZ              CLEAR REGISTER                  82350020
         IC    RWRKZ,PRFNBUNT           GET NO. OF BASIC UNITS ON QUEUE 82400020
         ALR   RWRKZ,RWRK2              UP COUNT BY NO. BEING RETURNED  82500020
         CH    RWRKZ,C255               CAN THESE BASIC UNITS BE ADDED  82520020
*                                       TO HDR BFR ON THE RETURN QUEUE  82540020
         BH    TSIN4005                 BR IF NO TO ADD ANOTHER HDR BFR 82560020
         STC   RWRKZ,PRFNBUNT           STORE UPDATED COUNT IN HDR      82600020
         L     RWK15,AVTDOUBL+K4        ADDR OF LAST BASIC UNIT ON Q    82700020
         ST    RPREFIX,PRFTIC           PUT RETURNED BASIC UNITS ON Q   82800020
         B     TSIN4020                 BR TO COMPLETE CHAIN            82900020
         SPACE 1                                                        83000020
TSIN4005 EQU   *                                                        83010020
         ST    RPREFIX,PRFLINK-K1       CHAIN THIS HDR TO LAST ON QUEUE 83020020
         MVI   PRFPRI,PRISBPCI          RESTORE BUFFER PRIORITY         83030020
         B     TSIN4008                 BRANCH TO COMPLETE CHAIN        83040020
         SPACE 1                                                        83050020
TSIN4006 EQU   *                                                        83100020
         DROP  RWK15                    DROP RWK15 AS TCAM BFR BASE REG 83200020
         USING IEDQQCB,RWK15            USE RWK15 AS QCB BASE REG       83300020
         IC    RWRKZ,QCBPRI             PICK UP ELEMENT PRIORITY        83350020
         SLL   RWRKZ,K24                LEFT ADJUST PRIORITY            83400020
         LA    RPREFIX,K0(R0,RPREFIX)   CLEAR HI-ORDER BYTE OF REGISTER 83450020
         OR    RPREFIX,RWRKZ            RESTORE PRIORITY                83500020
         ST    RPREFIX,QCBLINK-K1       CHAIN HDR TO LAST QCB OR LCB    83550020
         SPACE 1                                                        83600020
TSIN4008 EQU   *                                                        83700020
         DROP  RWK15                    DROP RWK15 AS PREFIX BASE REG   83800020
         USING IEDQPRF,RPREFIX          USE RPREFIX AS PREFIX BASE REG  83900020
         LA    RWK15,AVTBFRTB           GET BFR RETURN QCB ADDRESS      84000020
         ST    RWK15,PRFQCBA-K1         PUT BFR RETURN QCB ADDR IN HDR  84100020
         MVI   PRFPRI,PRISBPCI          PUT BFR PRIORITY IN HDR BFR     84200020
         B     TSIN4020                 BR TO COMPLETE CHAIN            84400020
         SPACE 1                                                        84500020
TSIN4010 EQU   *                                                        84600020
         ST    RPREFIX,AVTDOUBL         PUT BFR ON RETURN QUEUE         84700020
         B     TSIN4008                 BR TO PUT TCAM HEADER ON QUEUE  84800020
         SPACE 1                                                        84900020
TSIN4030 EQU   *                                                        85000020
         L     RPREFIX,PRFTIC           NEXT BASIC UNIT BEING RETURNED  85100020
         SPACE 1                                                        85200020
TSIN4020 EQU   *                                                        85300020
         BCT   RWRK2,TSIN4030           SEARCH FOR LAST BASIC UNIT ON Q 85400020
         ST    RPREFIX,AVTDOUBL+K4      UPDATE LAST IN QUEUE POINTER    85500020
         XC    PRFTIC,PRFTIC            ZERO TIC FLD OF LAST BASIC UNIT 85600020
         BR    RETRN                    RETURN TO CALLER                85700020
         DROP  RPREFIX,RTSB,RTIOC,RAVT  DROP CONTROL BLOCK BASE REGS    85800020
         EJECT                                                          85900020
*********************************************************************** 86000020
********                                                       ******** 86100020
******** CONSTANTS                                             ******** 86200020
********                                                       ******** 86300020
*********************************************************************** 86400020
         SPACE 1                                                        86500020
MOVEPRFX MVC   K0(K0,RBUADR),K0(RPREFIX)  MOVE OLD BFR PREFIX    S22029 86600001
*                                       INTO NEW 1ST BASIC UNIT         86700001
C255     DC    H'255'                   CONSTANT 255 USED TO CHECK FOR  86960020
*                                       BASIC UNIT COUNT OVERFLOW       87020020
CC3270L  DC    H'3'                     CONSTANT USED TO CHECK   S22028 87040001
*                                       3270 CONTROL CHAR LENGTH        87060001
         SPACE 3                                                        87100020
*********************************************************************** 87200020
********                                                       ******** 87300020
******** DSECTS                                                ******** 87400020
********                                                       ******** 87500020
*********************************************************************** 87600020
         SPACE 1                                                        87700020
********                                                                87800020
******** AVT - ADDRESS VECTOR TABLE                                     87900020
********                                                                88000020
         SPACE 1                                                        88100020
         TAVTD                                                          88200020
         EJECT                                                          88300020
********                                                                88400020
******** TIOCBUF - TIOC BUFFER FORMAT                                   88500020
********                                                                88600020
         SPACE 1                                                        88700020
         IKJTIOCB                                                       88800020
         EJECT                                                          88900020
********                                                                89000020
******** CVT - COMMUNICATIONS VECTOR TABLE                              89100020
********                                                                89200020
         SPACE 1                                                        89300020
CVT      DSECT                                                          89400020
         CVT                                                            89500020
         EJECT                                                          89630020
********                                                                89700020
******** TCAM DISPATCHER                                                89800020
********                                                                89900020
         SPACE 1                                                        90000020
         TDISPD                                                         90100020
         EJECT                                                          90200020
********                                                                90300020
******** LCB - LINE CONTROL BLOCK                                       90400020
********                                                                90500020
         SPACE 1                                                        90600020
         TLCBD                                                          90700020
         EJECT                                                          90800020
********                                                                90900020
******** TCAM BUFFER PREFIX                                             91000020
********                                                                91100020
         SPACE 1                                                        91200020
         TPRFD                                                          91300020
         EJECT                                                          91400020
********                                                                91500020
******** TCAM BUFFER PRIORITIES                                         91600020
********                                                                91700020
         SPACE 1                                                        91800020
         TPRIOR                                                         91900020
         EJECT                                                          92000020
********                                                                92100020
******** QCB - DESTINATION QUEUE ELEMENT CONTROL BLOCK                  92200020
********                                                                92300020
         SPACE 1                                                        92400020
         TQCBD                                                          92500020
         EJECT                                                          92600020
********                                                                92700020
******** SCB - STATION CONTROL BLOCK                                    92800020
********                                                                92900020
         SPACE 1                                                        93000020
         TSCBD                                                          93100020
         EJECT                                                          93200020
********                                                                93300020
******** TIOCRPT - TIOC REFERENCE POINTER TABLE                         93400020
********                                                                93500020
         SPACE 1                                                        93600020
         IKJTIOCP                                                       93700020
         EJECT                                                          93800020
********                                                                93900020
******** TERMINAL ENTRY TABLE                                           94000020
********                                                                94100020
         SPACE 1                                                        94200020
         TTRMD                                                          94300020
         EJECT                                                          94400020
********                                                                94500020
******** TSB - TERMINAL STATUS BLOCK                                    94600020
********                                                                94700020
         SPACE 1                                                        94800020
         IKJTSB                                                         94900020
         EJECT                                                          95000020
********                                                                95100020
******** TSCVT - TIME SHARING COMMUNICATIONS VECTOR TABLE               95200020
********                                                                95300020
         SPACE 1                                                        95400020
         IKJTSCVT                                                       95500020
         EJECT                                                          95600020
********                                                                95700020
******** DESTINATION QCB FOR TSINPUT                                    95800020
********                                                                95900020
         SPACE 1                                                        96000020
         TTSID                                                          96100020
         END                                                            97100020
