         TITLE 'IEDAYO  -  TSO TIOC TSOUTPUT ROUTINE'                   00050020
IEDAYO   CSECT                                                          00100020
         COPY  LCGASMS2                                         YM2814  00120000
*                                                                       00150020
         ENTRY IEDAYO02                                                 00170020
*                                                                       00200020
*********************************************************************** 00250020
*                                                                       00300020
         AIF   ('&LIB' NE 'LIB4').LIB4BAA                       YM2814  00306000
*D596030-596110,596590-596630,596710-596990                     YM2814  00312000
*D669000                                                        YM2865  00314000
*                                                                     * 00318000
.LIB4BAA ANOP                                                   YM2814  00324000
*          RELEASE 20 DELETIONS                                         00330020
*                                                                M3659  00340020
*                                                                M0271  00360020
*                                                                M1202  00390020
*0000                                                            TS1638 00420020
*                                                                TS1628 00430020
*                                                                M2655  00440020
*                                                                 M2701 00442020
*                                                                M3381  00445020
*                                                                M3546  00447020
*                                                                M4041  00447520
*                                                                 M4033 00448020
*                                                                M4694  00448520
*                                                                M4681  00449020
*                                                                 M4665 00449320
*                                                                 M1599 00449620
*                                                                 M5316 00449720
*                                                                 M5301 00449820
*                                                                 M6361 00449920
*          RELEASE 21 DELETIONS                                         00450020
*A084500-085000,126100-126487,437080-437400,443200,404200-      SA70323 00450121
*A444600,50367-504090,504200,504800-505100,512800-513100        SA70323 00450221
*A529400-530200                                                         00450321
*C093100,377800-380920,516400,516800,517000-518000,530700       SA70323 00452021
*C584200-584220,593070,889700-902300                            SA70323 00454021
*D210700-213500,245500-265200,402600-402800,584240-593055       SA70323 00454421
*D689700-696200                                                 SA70323 00454521
*A780100-780200                                                 SA64036 00454721
*1332026000-026200,048000-049000,093100,101500-103700,104000-    S22029 00456421
*1332104600,200500-201500,203500-206000,207500,211000-265000,    S22029 00458121
*1332401500-402000,403000,405500-406000,407000,409500,412000-    S22029 00459821
*1332412500,441500,664300,690000-696000,740500-741500,756000,    S22029 00461521
*1332756200-756500,757500-758000,759000-760500,762000-764500,    S22029 00463221
*1332767000-768500,782000,902500                                 S22029 00464921
*1332210570-210920                                               M1193  00466621
*1332093100,594520-597000,610650-610670                          M0141  00468321
*1332093100,169400-169950,342000-342200,486200,669000            A44839 00470021
*1332                                                            A52381 00480021
*                        RELEASE 01 OF VS2 CHANGES              YA00526 00500021
*A513200-513420,516400-518060,529800-530280                     YA00526 00550021
*D516400-517600                                                 YA00526 00600021
*C530700                                                        YA00526 00650021
*                                                                       00900020
*                                                                       00920020
* STATUS CHANGE LEVEL 002                                               00940000
*                                                                       00960020
*                                                                       00980020
* FUNCTION -- THIS ROUTINE IS RESPONSIBLE FOR SUPERVISING THE           01000020
*    MOVEMENT OF DATA FROM TSO BUFFERS TO TCAM BUFFERS.  IT MUST        01020020
*    OBTAIN AND FILL TCAM BUFFERS AS REQUIRED BY THE DATA.  AFTER       01040020
*    THE DATA IS SUCCESSFULLY SENT, THIS ROUTINE IS RESPONSIBLE         01060020
*    FOR RETURNING THE TSO BUFFERS TO THE AVAILABLE BUFFER QUEUE.       01080020
*                                                                       01100020
* ENTRY POINTS --                                                       01120020
*         IEDAYO - ENTERED FOR ONE OF THE FOLLOWING PURPOSES            01140020
*    (1) AN INITIAL REQUEST FOR TCAM BUFFER(S).                         01160020
*    (2) THE FIRST REQUEST ON THIS MESSAGE FROM THE PCI ROUTINE         01180020
*    FOR TCAM BUFFER(S).                                                01200020
*    (3) A SUBSEQUENT REQUEST FROM THE PCI ROUTINE FOR A TCAM BUFFER.   01220020
*    (4) A REQUEST TO REBUILD AND RESEND THE LAST OUTPUT MESSAGE        01260020
*    BECAUSE AN ERROR HAS OCCURRED.                                     01300020
*    (5) A REQUEST TO FREE TSO AND TCAM BUFFERS BECAUSE THE             01320020
*    ASSOCIATED MESSAGE HAS BEEN SUCCESSFULLY SENT.                     01340020
*                                                                       01420020
*         IEDAYO02 - ENTERED WHEN A REQUEST FOR A TCAM BASIC UNIT       01440020
*    BY THIS MODULE HAS BEEN SATISFIED.                                 01460020
*                                                                       01480020
* INPUT --                                                              01500020
*         IEDAYO -                                                      01520020
*    REG. 1 - ADDR OF ERB (PURPOSES 1 THRU 4 ABOVE) OR TCAM             01540020
*             BUFFER (PURPOSE 5 ABOVE).                                 01560020
*    REG. 3  - ADDR OF STCB                                             01580020
*    REG. 7  - ADDR OF DISK I/O QCB                                     01600020
*    REG. 11 - ADDR OF TCAM DISPATCHER                                  01620020
*    REG. 13 - ADDR OF AVTSAVE2                                         01640020
*    REG. 15 - ENTRY POINT ADDRESS                                      01660020
*                                                                       01680020
*         IEDAYO02 -                                                    01700020
*    REG. 1  - ADDR OF BASIC UNIT OR QCB                                01720020
*    REG. 3  - ADDR OF STCB                                             01740020
*    REG. 7  - ADDR OF CPB CLEANUP QCB                                  01760020
*    REG. 11 - ADDR OF TCAM DISPATCHER                                  01780020
*    REG. 13 - ADDR OF AVTSAVE2                                         01800020
*    REG. 15 - ENTRY POINT ADDRESS                                      01820020
*                                                                       01840020
* OUTPUT - WHEN A REQUEST FOR TCAM BUFFERS HAS BEEN SATISFIED,          01848020
*    TCAM BUFFER(S) CONTAINING OUTPUT DATA ARE TPOSTED TO THE ACTIVATE  01856020
*    ROUTINE (FOR INITIAL REQUESTS) OR TO THE MESSAGE HANDLER           01864020
*    (PCI REQUESTS).                                                    01872020
*                                                                       01880020
* EXTERNAL REFERENCES --                                                01900020
*         IEDAYOO - THIS IS THE MODULE CONTAINING THE QTIP ROUTINES     01905020
*    FOR TSOUTPUT.  THESE ROUTINES PERFORM FUNCTIONS WHICH MUST BE      01910020
*    DONE WITH A ZERO PROTECTION KEY OR DISABLED FOR INTERRUPTS.        01915020
*         IEDQFA - WHEN IEDAYO GAINS CONTROL AND THE TERMINAL INVOLVED  01920020
*    IS NOT IN A TIME-SHARING SESSION, CONTROL IS PASSED TO IEDQFA.     01940020
*         IEDQFQ - WHEN IEDAYO GAINS CONTROL AT ENTRY IEDAYO02 AND THE  01960020
*    TERMINAL INVOLVED IS NOT IN A TIME-SHARING SESSION, CONTROL IS     01980020
*    PASSED TO IEDQFQ.                                                  02000020
*         MSGGEN - IEDAYO EXITS TO MSGGEN TO PUT OUT TS ABENDING        02020020
*    LOGOFF AND AUTOMATIC PROMPTING MESSAGES.                           02040020
*         IEDAYE - IEDAYO BRANCHES TO IEDAYE TO EDIT THE OUTPUT         02060020
*    DATA AND TO DO THE ACTUAL MOVE OF THE DATA FROM TS TO TCAM         02080020
*    BUFFERS.  IEDAYE RETURNS TO IEDAYO WHEN DONE.                      02100020
*                                                                       02120020
* EXITS,NORMAL -- (NOTE, 'DSP-----' LABELS REFER TO ENTRY POINTS        02140020
*    IN THE TCAM DISPATCHER, SEE TDISPD DSECT).                         02160020
*         MSGGEN - TO PUT OUT TS ABENDING OR AUTOMATIC LINE             02180020
*    NUMBERING PROMPT MESSAGES.                                         02200020
*         DSPBYPAS - WHEN THIS MODULE GAINS CONTROL AND THE TERMINAL    02220020
*    IS NOT IN A TIME SHARING SESSION.                                  02240020
*         DSPDISP - WHEN IEDAYO GAINS CONTROL WITH A PCI REQUEST FOR    02320020
*    BUFFERS AND A HARDWARE ATTENTION HAS OCCURRED.                     02340020
*         DSPDISP - WHEN THERE IS NO OUTPUT.                            02370020
*         DSPPOST - WHEN INITIAL REQUEST FOR BUFFERS SATISFIED,         02400020
*    (ERB TPOSTED TO ACTIVATE QCB).                                     02420020
*         DSPPOST - WHEN PCI REQUEST FOR BUFFER(S) SATISFIED,           02440020
*    (TCAM BUFFER(S) TPOSTED TO THE MESSAGE HANDLER).                   02460020
*         DSPPOST - WHEN MESSAGE SUCCESSFULLY SENT AND EMPTIED TS       02480020
*    BUFFER(S) FREED, (TCAM BUFFER TPOSTED TO BUFFER RETURN QCB).       02500020
*         DSPDISP - WHEN TCAM BASIC UNITS ARE NOT AVAILABLE AND         02520020
*    THE ERB IS PUT IN ELEMENT CHAIN OF BUFFER RETURN QCB.              02540020
*                                                                       02560020
* EXITS,ERROR --                                                        02580020
*         DSPCHAIN - WHEN BASIC UNIT IS TPOSTED TO IEDAYO02             02630020
*    AND LCBERROR IS ON, (ERB POSTED TO RECALL, BASIC UNITS             02640020
*    TPOSTED TO BUFFER RETURN).                                         02650020
*         DSPCHAIN - WHEN BASIC UNIT TPOSTED TO IEDAYO02 AND            02660020
*    SCBATTN ON, (BASIC UNITS TPOSTED TO BUFFER RETURN).                02670020
*                                                                       02680020
* TABLES/WORK AREAS -- SEE REMARKS ACCOMPANYING DATA DEFINITION         02690020
*    STATEMENTS.                                                        02700020
*                                                                       02720020
* ATTRIBUTES - REUSABLE, REFRESHABLE                                    02740020
*                                                                       02760020
* CHARACTER CODE DEPENDENCY -- EXECUTION CHARACTER SET MUST BE SAME     02766020
*    AS CHARACTER SET USED AT ASSEMBLY TIME.  IN ADDITION, THE EBCDIC   02772020
*    REPRESENTATION OF THE 'NL' CHARACTER (X'15') IS USED IN CONSTANTS  02778020
*    IN THE CONSTANT SECTION.  EACH SUCH CONSTANT IS REMARKED           02784020
*    'NEW LINE CHARACTER'.                                              02790020
*                                                                       02800020
* NOTES -- NONE                                                         02820020
*                                                                       02840020
*                                                                       03100020
*********************************************************************** 03150020
*                                                                       03200020
*   REGISTER EQUATES                                                    03250020
*                                                                       03300020
*********************************************************************** 03350020
*                                                                       03400020
R0       EQU   0                        PARAMETER REGISTER              03450020
R1       EQU   1                        PARAMETER REGISTER              03500020
R2       EQU   2                        WORK REGISTER                   03550020
R3       EQU   3                        REGISTER 3                      03600020
RSCB     EQU   3                        SCB REGISTER                    03650020
RLCB     EQU   4                        LCB REGISTER                    03700020
R5       EQU   5                                                        03750020
RPREF    EQU   6                        BUFFER REGISTER                 03800020
R6       EQU   6                                                        03820020
RQCB     EQU   7                        QCB REGISTER                    03850020
RTSB     EQU   8                        TSB REG.                        03900020
R8       EQU   8                                                        03950020
RPQ      EQU   9                        PRIORITY DESTINATION QCB        04000020
R9       EQU   9                                                        04050020
RDCB     EQU   10                       DCB REGISTER                    04100020
R10      EQU   10                       WORK REGISTER                   04150020
R11      EQU   11                                                       04200020
RBASE    EQU   12                       BASE REGISTER                   04250020
R12      EQU   12                                                       04300020
RSAVE    EQU   13                       ADDR OF AVTSAVE2                04350020
R14      EQU   14                       RETURN ADDRESS REGISTER         04400020
R15      EQU   15                       ENTRY POINT AND RETURN CODE     04450020
*                                       REGISTER                        04500020
*                                                                       04550020
*********************************************************************** 04600020
*                                                                       04650020
*   STCB FOR TSOUTPUT                                                   04700020
*                                                                       04750020
         DC    AL1(DSPMCPL8),AL3(0),A(0)  STCB FIELDS            S22029 04800001
*                                                                       04950020
*********************************************************************** 05000020
*                                                                       05050020
*   MASKS,EQU AND DISPLACEMENT                                          05100020
*                                                                       05150020
*********************************************************************** 05200020
*                                                                       05250020
NULL     EQU   0                        '0'                             05300020
TICCCW   EQU   X'08'                    COMMAND CODE = TIC              05350020
ONE      EQU   1                        '1'                             05400020
E2       EQU   2                        '2'                             05410020
E3       EQU   3                        '3'                             05420020
E4       EQU   4                        '4'                             05430020
TRMBUFSZ EQU   X'80'                    INDICATES BFR SIZE SPECIFIED    05440020
TWOIDLE  EQU   X'F2'                    CARRIAGE COUNT FOR 2 IDLES      05450020
E41      EQU   41                       '41'                            05480020
XXCTUSED EQU   X'80'                    INDICATE DISABLED COUNT IN USE  05510020
QCBNLCR  EQU   X'30'                    CARRIAGE POSITION FLAGS         05520020
QTIP1ST  EQU   11                       FIRST QTIP ENTRY CODE           05540020
QTIP2ND  EQU   12                       SECOND QTIP ENTRY CODE          05580020
         AIF   ('&LIB' EQ 'LIB4').LIB4BCA                       YM3082  05590000
QTIP3RD  EQU   13                       THIRD QTIP ENTRY CODE           05620020
.LIB4BCA ANOP                                                   YM3082  05630000
QTIP4TH  EQU   14                       FOURTH QTIP ENTRY CODE          05660020
QTIP5TH  EQU   15                       FIFTH QTIP ENTRY CODE           05700020
QTIP6TH  EQU   16                       SIXTH QTIP ENTRY CODE           05740020
NOT      EQU   X'FF'                                                    06050020
C5041    EQU   X'10'                    LINE = '5041'                   06300020
CBREAK   EQU   X'40'                    BREAK FEATURE IS SPECIFIED      06350020
CINHIBIT EQU   X'80'                    INHIBIT CCW                     06400020
DYNMBFFR EQU   X'10'                    PCI (DYNAMIC BUFFERING)         06500020
E48      EQU   48                       DISPLACEMENT OF DECIMAL 48      06600020
DOEOM    EQU   X'08'                    IN QCBRETCT TO TELL EDT SA61765 06630021
*                                       TO PROCESS END OF MSG           06660021
*                                                                       06700020
*********************************************************************** 06750020
*                                                                       06800020
*   INITIALIZE DSECT ADDRESSABILITY                                     06850020
*                                                                       06900020
*********************************************************************** 06950020
*                                                                       07000020
         USING AVTSAVE2,RSAVE           INITIALIZE AVT ADDRESSABILITY   07050020
         USING IEDQLCB,RLCB             INITIALIZE LCB                  07100020
         USING TIOCBUF,R2               INITIALIZE BUFFER               07150020
         USING IEDQSCB,RSCB             INITIALIZE SCB                  07200020
         USING IEDQPRF,RPREF            INITIALIZE BUFFER PREFIX        07250020
         USING IEDQPQCB,RPQ             INITIALIZE PRIORITY QCB         07300020
         USING IEDQDISP,R11             INITIALIZE DISPATCHER           07350020
         USING IEDQQCB,RQCB             INITIALIZE QCB                  07400020
         USING IEDQSTCB,R15             STCB                            07450020
         USING TSB,RTSB                 INITIALIZE TSB                  07500020
*                                                                       07550020
*********************************************************************** 07600020
*                                                                       07650020
TSOUTPUT EQU   *                                                        07700020
*                                                                       07750020
*********************************************************************** 07800020
*                                                                       07850020
*   FIRST ENTRY POINT                                                   07900020
*                                                                       07950020
*        INPUT - REG.1  - ADDR OF BFFR OR ERB                           08000020
*                REG.3  - ADDR OF STCB                                  08050020
*                REG.7  - ADDR OF DISK I/O QCB                          08100020
*                REG.11 - ADDR OF DISPATCHER                            08150020
*                REG.13 - ADDR OF AVTSAVE2                              08200020
*                REG.15 - ENTRY POINT                                   08250020
*                                                                       08300020
*        ELEMENT IS BFFR                                                08350020
*              1 - PRI=PRIDKSRV - NORMAL END OF SEND OPERATION          08400020
*              2 - PRFERMGN ON - REQUEST TO REBUILD MESSAGE THAT HAD    08450021
*                  ERROR DURING SEND OPERATION                          08500021
*        ELEMENT IS ERB                                                 08550020
*              3 - PRI=PRIINTRQ - INITIAL REQUEST                       08600020
*              4 - PRI=PRIFSPCI - FIRST PCI                             08650020
*              5 - PRI=PRISBPCI - SUBSEQUENT PCI                        08700020
*                                                                       08950020
*********************************************************************** 09000020
*                                                                       09050020
         USING TSOUTPUT,RBASE           INITIALIZE BASE                 09100020
         LR    RBASE,R15                LOAD BASE ADDR                  09150020
         B     CHKELMNT                 GOTO CHECK ELEMENT              09200020
*                                                                       09250020
         DC    C'IEDAYO'                MODULE I.D.                     09280020
         DC    X'4116'                  DATE - 4/26/74                  09310021
*                                                                       09350020
CHKELMNT EQU   *                                                        09400020
*                                                                       09450020
         LR    RPREF,R1                 LOAD ELEMENT ADDR               09500020
         LA    RPREF,NULL(RPREF)        CLEAR HI-ORDER BYTE             09550020
         TM    PRFTIC,TICCCW            IS THIS A BFR?           S22029 09551001
         BNO   ERBTOLCB                 NO. SETUP LCB FROM ERB.  S22029 09552001
         TM    PRFSTAT1,PRFTSMSG        IS THIS A TSO MESSAGE    S22029 09553001
         BNO   CPBINIT                  NO, GIVE CTL TO TCAM CPB S22029 09554001
*                                       INITIALIZATION ROUTINE          09555001
         L     RLCB,PRFLCB-1            SETUP LCB FROM BFR PRFX  S22029 09556001
         B     SETUP                    CONTINUE CTL BLK SETUP   S22029 09557001
ERBTOLCB EQU   *                                                 S22029 09558001
         LR    RLCB,RPREF               LOAD ERB ADDR IN LCB REG S22029 09559001
         LA    R2,LCBERB-IEDQLCB        PICKUP ERB TO LCB OFFSET S22029 09560001
         SR    RLCB,R2                  BACKUP TO LCB.           S22029 09561001
SETUP    EQU   *                                                 S22029 09562001
         L     RSCB,LCBSCBA-1           PICKUP SCB               S22029 09563001
********                                                                09564001
******** PICK UP THE DESTINATION QCB FOR THIS LINE                      09565001
********                                                                09566001
         LH    R2,LCBTTCIN              GET CONNECT INDEX        S22029 09567001
         LTR   R2,R2                    IS INDEX ZERO            S22029 09568001
         BZ    CPBINIT                  YES, BYPASS TO TCAM      S22029 09569001
         LR    R1,R2                    USE INDEX TO PICKUP      S22029 09570001
         L     R15,AVTRNMPT             TERMINAL TABLE ENTRY.    S22029 09571001
         BALR  R14,R15                                           S22029 09572001
         USING IEDQTRM,R1                                        S22029 09573001
         L     RQCB,TRMDESTQ-1          PICKUP DESTINATION QCB   S22029 09574001
         DROP  R1                                                S22029 09575001
         LR    R1,RPREF                 RESTORE INPUT ELEMENT    S22029 09576001
         TM    PRFTIC,TICCCW            TEST IF THIS IS A BFFR          09600020
         BNO   ERBCHECK                 NO,GOTO CHECK ERB               09650020
*                                                                       09700020
*********************************************************************** 09750020
*                                                                       09800020
BUFFER   EQU   *                                                        09850020
*                                                                       09900020
*********************************************************************** 09950020
*                                                                       10000020
*   A TCAM BUFFER HAS BEEN TPOSTED TO TSOUTPUT AFTER A MESSAGE          10030020
*   HAS BEEN SENT.                                                      10060021
*                                                                       10100020
         NC    QCBTJID,QCBTJID          IS TJID PRESENT                 10470020
         BZ    RETBFR                   NO, GO RETURN BUFFER            10480020
         TM    AVTBIT3,AVTTSAB          TEST IF TSO HAS ABENDED  A44839 10486021
         BO    RETBFR                   YES, GO RETURN BUFFERS   A44839 10492021
         BAL   R14,TSBADDR              GO GET TSB & TIOCRPT ADDRS      10500020
*                                                                       10550020
*********************************************************************** 12500020
*                                                                       12550020
BFFRTN   EQU   *                                                        12600020
         TM    PRFSTAT1,PRFERMGN        DID OUTPUT ERRORS OCCUR SA70323 12610021
         BNO   SUCCSEND                 NO, PROCESS NORMALLY    SA70323 12620021
         SPACE 2                                                        12630021
*********************************************************************** 12640021
*                                                                       12642021
*        ELEMENT IS BUFFER, PFRERMGN IS ON - ERROR DURING SEND          12644021
*        OPERATION.  CALL QTIP13 TO REBUILD MESSAGE.  SINCE WE          12646021
*        DON'T TURN OFF QCBTPUT, WE WILL GET CONTROL AGAIN TO           12648021
*        SEND OUT THIS REBUILT MESSAGE.                                 12648421
*********************************************************************** 12648521
         QTIP  QTIP3RD,(RSAVE)          CALL QTIP TO REBUILD    SA70323 12648621
         B     RETBFR                   GO RETURN TCAM BUFFER   SA70323 12648721
         SPACE 3                                                        12661521
SUCCSEND EQU   *                                                SA70323 12671521
*********************************************************************** 12700020
*                                                                       12750020
*   ELEMENT IS BFFR AND PRI=PRIDKSRV - NORMAL END OF SEND OPERATION     12800020
*        1 - RETURN TS BFFR TO FREE Q                                   12850020
*        2 - REMOVE WAIT CONDITION                                      12900020
*        3 - FREE TCAM BFFR                                             12950020
*                                                                       13000020
*********************************************************************** 13050020
*                                                                       13250020
*   ISSUE QTIP SVC TO FREE TSO BFR & REMOVE WAITS IF APPROPRIATE        13300020
*                                                                       13350020
         QTIP  QTIP2ND,(RSAVE)                                          13400020
         TM    TIOCFLG-TIOCRPT(R10),TIOCSYLW  IS SYSTEM IN LWAIT        13450020
         BNO   RETBFR                   NO, NO NEED TO LOCK KEYBOARD    13500020
         OI    QCBTSOF1,QCBNOBUF        LOCK USER'S KEYBOARD            13550020
*                                                                       13600020
*   TPOST TCAM BUFFER TO BUFFER RETURN                                  13800020
*                                                                       14000020
RETBFR   EQU   *                                                        14100020
         LR    R1,RPREF                 LOAD ELEMENT ADDR               14200020
         LA    R2,AVTBFRTB              LOAD ADDR OF BFR RETURN QCB     14400020
         MVI   PRFPRI,PRIBFRTB          SET TPOST PRIORITY = BFR RETURN 14600020
         B     POST                     GO SET UP TO GO TO DISPATCHER   14800020
*                                                                       15450020
*********************************************************************** 15500020
*                                                                       15550020
SESCLEAN EQU   *                                                        15600020
*                                                                       15650020
*********************************************************************** 15700020
*                                                                       15750020
*   THIS ROUTINE CLEANS UP TCAM CONTROL BLOCKS FOR LOGOFF,              15800020
*   AND TS ABENDING SITUATIONS.                                         15850020
*                                                                       15900020
*   IT USES REGISTERS 0,1,2,5,6,14,15                                   15910020
*                                                                       15920020
*********************************************************************** 15950020
*                                                                       16000020
         TM    LCBINSRC+2,QCBDELAY      IS LCB ON DELAY QUEUE           16100020
         BNO   PASTRLCB                 NO, DON'T REMOVE IT             16120020
         LR    R1,RLCB                  ADDR LCB TO BE REMOVED          16140020
         L     R15,AVTHG02              REMOVAL ROUTINE ADDR            16160020
         BALR  R14,R15                  GO REMOVE LCB                   16180020
*                                                                       16200020
         LR    R2,R3                    SAVE REGISTER CONTENTS          16220020
         LR    R6,RQCB                  SAVE REGISTER CONTENTS          16240020
*                                                                       16260020
         LA    RQCB,LCBRSKEY            LOAD STCB ADDR                  16280020
         LR    R1,RQCB                  LOAD STCB ADDR                  16300020
         BAL   R14,DSPPRIOR             PUT RECEIVE SCHEDULER           16320020
*                                       IN STCB CHAIN                   16340020
         LR    R3,R2                    RESTORE REGISTER CONTENTS       16360020
         LR    RQCB,R6                  RESTORE REGISTER CONTENTS       16380020
*                                                                       16400020
PASTRLCB EQU   *                                                        16420020
         NI    LCBTSOB,NOT-LCBTSBUF-LCBSATRD-LCBCIRCD  RESET FLAG       16427020
         MVI   LCBSENS0,NULL            RESET SENSE BYTE                16435020
         XC    SCBERRST(SCBSRCE-SCBERRST),SCBERRST  RESET SCB           16440020
*                                                                       16460020
         NI    QCBFLAG,NOT-QCBREAD-QCBNOBRK   RESET BITS         S22029 16510001
*              QCBTSSES WILL BE TURNED OFF BY IEDAYZ             S22029 16560001
         NI    QCBDSFLG,NOT-QCBALTMH    RESET ALTERNATE MH PATH  S22029 16670001
         MVI   QCBRETCT,NULL            CLEAR ERROR RETRY COUNT         16750020
         MVI   QCBCARCT,NULL            CLEAR CARRIAGE COUNT            16850020
         XC    QCBTJID,QCBTJID          CLEAR TJID                      16870020
*                                                                       16900020
         LH    R1,AYOSRCE               GET TERMINAL INDEX       A44839 16950021
         L     R15,AVTRNMPT             LOAD ADDR OF TERM NAME ENTRY    17000020
*                                                                       17050020
         BALR  R14,R15                  GOTO TERM NAME ROUTINE          17100020
*                                                                       17150020
         USING IEDQTRM,R1               ESTABLISH BASE                  17200020
         XC    QCBINSRC,QCBINSRC        CLEAR STATUS BYTES              17220020
*                                                                       17250020
         SR    R15,R15                  CLEAR REG.15                    17300020
         IC    R15,TRMCHCIN                                             17350020
         BCTR  R15,NULL                 DECREMENT BY '1'                17400020
         SLL   R15,2                    MULTIPLY BY '4'                 17450020
         A     R15,AVTCSTCS             ADD BASE FOR DEVICE CHAR TABLE  17500020
*                                                                       17550020
         TM    ONE(R15),CBREAK          IS BREAK FEATURE PRESENT        17600020
         BCR   1,R5                     YES, RETURN                     17650020
*                                                                       17700020
         OI    QCBFLAG,QCBNOBRK         SET 'NO BREAK' ON               17750020
         BR    R5                       RETURN TO SUBROUTINE CALLER     18700020
*                                                                       19400020
*********************************************************************** 19600020
*                                                                       19650020
ERBCHECK EQU   *                                                        19700020
*                                                                       19750020
*********************************************************************** 19800020
*                                                                       19850020
*   WHEN ERB IS POSTED                                                  19900020
*        1 - PRI=PRINTRQ - INITIAL REQUEST                              19950001
*        2 - PRI=PRIFSPCI - FIRST PCI                                   20000001
*        3 - LCBRCLLN/LCBSENDN - REBUILD OUTPUT BFFR                    20150001
*                                                                       20200020
*********************************************************************** 20250020
*                                                                       20300020
         TM    LCBSTAT1,LCBRCLLN        RECALLED BUFFER REQUEST SS22029 20350001
         BO    CPBINIT                  YES, GO RECALL BUFFER   SS22029 20400001
         L     RQCB,SCBDESTQ-1          NO, USE DESTINATION      S22029 20490001
*                                       TERMINAL'S QCB.                 20560001
*                                                                       20650020
         TM    QCBFLAG,QCBTSSES         TEST IF TSO IN SESSION          20700020
         BNO   CPBINIT                  NO, GIVE CTL TO TCAM CPB S22029 20750001
*                                       INITIALIZATION RTN              20770001
*                                                                       20800020
*   SET LCBDLNKN SWTCH OFF TO INDICATE THIS ERB IS BEING USED           20850020
*                                                                       20900020
         NI    LCBERBST,LCBDLNKF        SET DLINK SWITCH OF ERB OFF     20950020
         XC    LCBERBCH,LCBERBCH        CLEAR ERB CHAIN FIELD           21000020
         XC    AYOSWTCH(AYOWRKL),AYOSWTCH  CLEAR TSOUTPUT'S WORK AREA   21050020
         STH   R2,AYOSRCE               SAVE TERMINAL INDEX      S22029 21060001
*********************************************************************** 26550020
*                                                                       26600020
*   CHECK PRIORITY TO DETERMINE                                         26650020
*        1 - INITIAL REQUEST                                            26700020
*        2 - INITIAL PCI                                                26750020
*        3 - SUBSEQUENT PCI                                             26800020
*                                                                       26850020
*********************************************************************** 26900020
*                                                                       26950020
         CLI   LCBERBPY,PRIINTRQ        TEST IF INITIAL REQUEST         27000020
         BE    INTLRQST                 YES,GOTO HANDLE INITIAL REQUEST 27050020
*                                                                       27100020
*   IF NOT INITIAL REQUEST,CHECK IF LCBERROR IS ON                      27150020
*        YES - POST ERB TO ADDRESS IN LCBRCQCB                          27200020
*            - CHECK IF ATTENTION HAS BEEN HIT                          27250020
*                                                                       27300020
         TM    LCBERBST,LCBERROR        TEST IF ANY ERROR               27350020
         BNO   CHKATTN                  NO,GOTO CHECK ATTENTION         27400020
*                                                                       27450020
*   WHEN LCBERROR BIT IS ON                                             27500020
*        1.- ZERO LCBERBCH                                              27550020
*        2 - SET PRI=PRIRCQCB                                           27600020
*        3 - POST ERB TO ADDR IN LCBRCQCB                               27650020
*                                                                       27700020
         XC    LCBERBCH,LCBERBCH        ZERO ERB CHAIN FIELD            27750020
         LA    R1,LCBERB                LOAD ADDR OF ERB                27800020
         MVI   PRFPRI-IEDQPRF(R1),PRIRCQCB   SET PRI=PRIRCQCB           27850020
         L     R2,LCBRCQCB              LOAD ADDR IN LCBRCQCB           27900020
         B     POST                     GOTO TCAM/DSPPOST               27950020
*                                                                       28000020
CHKATTN  EQU   *                                                        28050020
         TM    SCBERR3,SCBATTN          TEST IF ATTENTION BEEN HIT      28250020
         BO    DISP                     YES, EXIT TO TCAM DISPATCHER    28550020
         CLI   LCBERBPY,PRIFSPCI        TEST IF INITIAL PCI             28950020
         BE    FIRSTPCI                 YES,GOTO PROCESS INITIAL PCI    29000020
*                                                                       29050020
*********************************************************************** 29300020
*                                                                       29350020
*   THIS IS SUBSEQUENT PCI                                              29400020
*                                                                       29450020
*               1 - BUILD ONE TCAM BFFR                                 29500020
*               2 - POST TO MH (PRI=PRIMHBFR)                           29550020
*               3 - IF ERB COUNT IS NOT '0',POST AVTDSIOB -PRI=PRISBPCI 29600020
*               4 - IF NO MSG TO SEND,SET END OF MSG AND POST TO MH     29650020
*                                                                       29700020
*                                                                       29750020
*********************************************************************** 29800020
*                                                                       29850020
         OI    AYOSWTCH,SUBPCI          SET SUBSEQUENT PCI BIT 'ON'     29900020
         B     CHKTSAB                  GO CHECK FOR TSO ABENDING       29950020
*                                                                       30000020
*********************************************************************** 30050020
*                                                                       30100020
FIRSTPCI EQU   *                                                        30150020
*                                                                       30200020
*********************************************************************** 30250020
*                                                                       30300020
*   THIS IS THE FIRST PCI REQUEST                                       30350020
*        1 - BUILD NO. OF TCAM BFFR REQUESTED IN ERB COUNT              30400020
*        2 - POST EACH BFFR TO MH (PRI=PRIMHBFR)                        30450020
*        3 - IF NO MSG TO SEND,SET END OF MSG AND POST TO MH            30500020
*                                                                       30550020
*********************************************************************** 30600020
*                                                                       30650020
         OI    AYOSWTCH,INTLPCI         SET INITIAL PCI REQUEST         30700020
         B     CHKTSAB                  GO CHECK FOR TSO ABENDING       30750020
*                                                                       30800020
*********************************************************************** 30850020
*                                                                       30900020
INTLRQST EQU   *                                                        30950020
*                                                                       31000020
*********************************************************************** 31050020
*                                                                       31100020
*   THIS IS AN INITIAL REQUEST FOR TCAM BUFFERS                         31400020
*                                                                       31850020
*********************************************************************** 31900020
*                                                                       31950020
         OI    AYOSWTCH,INTLRQ          SET THIS IS A INITIAL REQUEST   32000020
         MVI   LCBERBCT+1,NULL          CLEAR DISABLED COUNT            32020020
*                                                                       32050020
CHKTSAB  EQU   *                                                        32060020
*                                                                       32070020
         TM    AVTBIT3,AVTTSAB          TEST IF TSO HAS ABENDED         32100020
         BNO   GETADDRS                 NO, GET TSB, TIOCRPT ADDRS      32110020
         DROP  R15                                               A52381 32110521
         USING IEDQTNTD,R15             ADDRESSABILITY FOR TNT   A52381 32111021
         USING IEDQTRM,R1               ADDRESSABILITT FOR TRM   A52381 32111521
         L     R15,AVTRNMPT             GET TNT ADDRESS          A52381 32112021
         LH    R2,TNTLEN                HIGHEST TERMINAL INDEX   A52381 32112521
TTABLE   EQU   *                                                 A52381 32113021
         LR    R1,R2                    PUT INDEX IN REG 1       A52381 32113521
         BALR  R14,R15                  GO GET TTABLE ENTRY ADDR A52381 32114021
         CLC   TRMDESTQ,SCBDESTQ        ARE ADDRESSES THE SAME   A52381 32114521
         BE    RAYOSRCE                 YES, TERMINAL INDEX IS   A52381 32115021
*                                       CORRECT                  A52381 32115521
         BCT   R2,TTABLE                TRY WITH NEW INDEX VALUE A52381 32116021
         LH    R2,LCBTTCIN              GET INDEX FROM LCB       A52381 32116521
RAYOSRCE EQU   *                                                 A52381 32117021
         STH   R2,AYOSRCE               RESET TERMINAL INDEX     A52381 32117521
         DROP  R1                                                A52381 32118021
         DROP  R15                                               A52381 32118521
         TM    AYOSWTCH,INTLRQ          IS THIS AN INITIAL REQUEST      32120020
         BO    TSABEND                  YES,GOTO TSO ABEND RTN          32150020
         B     NOTINTL                  BRANCH TO SEND 1 IDLE CHARACTER 32170020
*                                                                       32200020
GETADDRS EQU   *                                                        32500020
*                                                                       32908020
         BAL   R14,TSBADDR              GET TSB,TIOCRPT ADDRS           32918020
*                                                                       32928020
         TM    TSBFLG2,TSBBRKIN         COULD THIS BE FLASHBACK REQUEST 32939020
         BZ    BUILDBFF                 NO, GO BUILD TCAM BFR           32940020
         TM    TSBSTAT,TSBDSPLY         IS THIS A FLASHBACK REQUEST?    32941020
         BZ    BUILDBFF                 NO, GO BUILD TCAM BFR           32942020
*                                                                       32943020
         TM    TSBFLG3,TSBSPIT          IS TCLEARQ IN PROGRESS          32943320
         BO    BUILDBFF                 YES, DON'T FLASHBACK            32943620
         CLC   TSBOTBFP,AVTFZERO        IS TRAILER QUEUE EMPTY          32944020
         BE    CHKBRKIN                 YES, GO SET UP TO FLASH BACK    32945020
*                                                                       32950020
*********************************************************************** 33000020
*                                                                       33050020
BUILDBFF EQU   *                                                        33100020
*                                                                       33150020
*********************************************************************** 33200020
*                                                                       33250020
*    BUILD TCAM BUFFER                                                  33300020
*                                                                       33350020
*********************************************************************** 33400020
*                                                                       33450020
*        NOTE -- THE TERM 'HEADER BASIC UNIT', AS USED IN COMMENTS      33500020
*        IN THIS LISTING, REFERS TO THE FIRST BASIC UNIT IN A BUFFER,   33550020
*        THAT IS, THE BASIC UNIT WHICH CONTAINS THE BUFFER PREFIX.      33600020
*                                                                       33650020
**********************************************************************  33700020
*                                                                       33950020
*   CALCULATE NO. OF BASIC UNITS PER BUFFER                             34000020
*                                                                       34050020
*********************************************************************** 34100020
*                                                                       34150020
         LH    R1,AYOSRCE               GET INDEX TO TERMINAL    A44839 34180021
*                                       TABLE                    A44839 34210021
         L     R15,AVTRNMPT             LOAD ADDR OF TERM. NAME TABLE   34250020
         BALR  R14,R15                  GO GET TTABLE ENTRY ADDR        34300020
*                                                                       34350020
*   TERM TABLE ENTRY ADDR IS IN R1,IF BUFFER SIZE IS SPECIFIED IN       34400020
*   TTABLE, PUT IT IN LCBERBQP+1.  IF NOT, USE DCBBFSZE                 34450020
*                                                                       34500020
         USING IEDQTRM,R1                                               34550020
         TM    TRMDEVFL,TRMBUFSZ        IS A BUFFER SIZE SPECIFIED      34600020
         BNO   USEDCB                   NO,GOTO USE DCB                 34650020
*                                                                       34700020
*   YES,OBTAIN BUFFER SIZE AND NO. OF BASIC UNIT FROM TRM TABLE         34750020
*                                                                       34800020
         SR    R10,R10                  ZERO R10                        34850020
         LA    R5,TRMOPNO+1             LOCATION BFFR SIZE OF NO OPTION 34900020
         TM    TRMSTATE,TRMOPTFN        TEST IF OPTION SPECIFIED        34950020
         BNO   NOOPTION                 NO,GOTO OBTAIN QCB FROM ERB     35000020
*                                                                       35050020
         LR    R5,R10                   ZERO R5                         35100020
         IC    R5,TRMOPNO               NO OF OPTION FIELDS             35150020
         LA    R5,TRMOPT+1(R5)          ADDR OF OPT FLD + 1 + NO. OF    35200020
*                                       OPT FLD = LOCATION OF BFR SIZE  35250020
         DROP  R1                                                       35300020
*                                                                       35350020
NOOPTION EQU   *                                                        35400020
*                                                                       35450020
         MVC   LCBERBQB+1(E2),NULL(R5)  SET SIZE OF BFR IN ERBQB+1      35500020
         LH    R1,LCBERBQB+1            LOAD SIZE OF BFFR               35550020
*                                                                       35600020
CNTBFUNT EQU   *                                                        35650020
*                                                                       35700020
         LA    R10,ONE(R10)             INCREMENT R10 BY '1'            35750020
         SH    R1,AVTKEYLE              SUBTRACT (B.U. - PREFIX)        35800020
         BP    CNTBFUNT                 IF THERE ARE REMAINING,REPEAT   35850020
         B     SIZEDONE                 END OF B.U. COUNT               35900020
*                                                                       35950020
USEDCB   EQU   *                                                        36000020
*                                                                       36050020
         USING IHADCB,RDCB                                              36100020
         L     RDCB,LCBDCBPT            LOAD DCB ADDR                   36150020
         LH    R1,DCBBUFSI              OBTAIN BUFFER SIZE              36200020
         STH   R1,LCBERBQB+1            STORE IT IN LCB                 36250020
         IC    R10,DCBUNTCT                                             36300020
*                                                                       36350020
SIZEDONE EQU   *                                                        36400020
*                                                                       36450020
         STC   R10,LCBERBQB             STORE NO. B.U. IN LCB           36500020
         MVI   LCBERBKY,AVTEZERO        SET PRIORITY KEY TO '0'         36550020
*                                                                       36600020
*        LCBERBQB+1 - SIZE OF BUFFER                                    36650020
*        LCBERBQB   - NO. OF B.U. PER BUFFER                            36700020
*                                                                       36750020
*********************************************************************** 36800020
*                                                                       36850020
CHAINBUF EQU   *                                                        36900020
*                                                                       36950020
*********************************************************************** 37000020
*                                                                       37050020
*   ISSUE QTIP SVC TO MOVE A TSO MESSAGE FROM THE OUTPUT HEADER         37150020
*   QUEUE TO THE OUTPUT TRAILER QUEUE UNLESS THERE IS ALREADY           37250020
*   SOMETHING ON THE TRAILER QUEUE.                                     37350020
*                                                                       37450020
         QTIP  QTIP1ST,(RSAVE)                                          37550020
*                                                                       37650020
         L     R2,TSBOTBFP-1            LOAD TS BFFR AADR               37700020
         LTR   R15,R15                  ANY DATA TO MOVE        SA70323 37780021
         BZ    NOOUTPUT                 NO, GO TO 'NO OUTPUT' ROUTINE   37940020
         ST    R2,AYOTSBFF              STORE TS MSSG ADDR              38050020
         SPACE 2                                                YS6327  38057021
WATSLEFT EQU   *                                                YS6327  38064021
*                                                               YS6327  38071021
         SR    R15,R15                  CLEAR FOR COMPARISON    YS6327  38078021
         CH    R15,AYOBULEN             IS THERE SPACE LEFT     YS6327  38085021
         BNZ   MOVEDATA                 YES, DON'T GET NEW BU   YS6327  38092021
*                                                                       38100020
GETBASIC EQU   *                                                        38150020
*                                                                       38200020
         NC    AVTBFREB+1(E3),AVTBFREB+1  ARE ANY B.U.'S AVAILABLE      38250020
         BZ    NOBFRS                   NO,GOTO CHAIN ERB TO BFF RTN    38300020
*                                       QCB                             38350020
*                                                                       38400020
*   WHEN B.U. IS AVAILABLE,GET ONE                                      38450020
*                                                                       38500020
         LH    R5,AVTAVFCT              LOAD NO. OF B.U. IN POOL        38550020
         BCTR  R5,NULL                  SUBTRACT '1'                    38600020
         STH   R5,AVTAVFCT              STORE NEW BUFFER NO.            38650020
         L     R5,AVTBFREB              LOAD ADDR OF AVAILABLE UNIT     38700020
         L     R1,PRFLINK-1-IEDQPRF(R5) LOAD ADDR OF NEXT B.U,          38750020
         ST    R1,AVTBFREB              STORE IT AS 1ST AVAILABLE       38800020
*                                                                       38850020
CHKCHAIN EQU   *                                                        38900020
*                                                                       38950020
*   CHECK IF THERE ARE ANY B.U. IN BUFFER CHAIN                         39000020
*      YES - TIC LAST B.U. TO THIS B.U.                                 39050020
*      NO  - START TO BUILD BUFFER PREFIX                               39100020
*                                                                       39150020
         XC    NULL(PREFL,R5),NULL(R5)  CLEAR B.U. PREFIX AREA          39200020
         L     R1,AYOLSTBU              GET ADDR OF LAST B.U. IN CHAIN  39250020
         LA    R5,NULL(R5)              RESET HI-ORDER BYTE             39300020
         ST    R5,AYOLSTBU              SAVE B.U. ADDR IN SCB           39350020
         NC    LCBERBCH,LCBERBCH        TEST IF ANY BUFFER IN CHAIN     39400020
         BZ    BUILDPRF                 NO,GOTO BUILD HEADER BUFFER     39450020
*                                                                       39500020
         L     R9,AYOHDRBU              GET ADDR OF LAST BFR PREFIX     39540020
         CLC   LCBERBQB(ONE),PRFNBUNT-IEDQPRF(R9)  TEST IF THIS BASIC   39580020
*                                       UNIT STARTS A NEW BUFFER        39620020
         BE    LINKBFR                  YES, GO LINK BFR INTO CHAIN     39660020
*                                                                       39700020
         ST    R5,PRFTIC-IEDQPRF(,R1)   TIC LAST B.U. TO THIS           39740020
         MVI   PRFTIC-IEDQPRF(R1),TICCCW  SET TIC COMMAND               39780020
         B     ADDBUCT                  GO UPDATE B.U. COUNT            39820020
*                                                                       39860020
LINKBFR  EQU   *                                                        39900020
*                                                                       39950020
*   WHEN THIS B.U. STARTS A NEW BUFFER,LINK THIS BUFFER TO THE BUFFER   40000020
*   CHAIN.                                                              40050020
*                                                                       40100020
         OI    PRFSTAT1-IEDQPRF(R5),PRFNHDRN+PRFNLSTN+PRFTSMSG   S22029 40150001
*                                       SET 'NOT HDR','NOT LAST'        40180001
*                                       , AND 'TS MESSAGE'              40210001
         ST    R5,PRFLINK-1-IEDQPRF(R9)  LINK LAST BFR TO THIS BFR      40250020
         B     INITPRF                  SET UP BFR PREFIX        S22029 40300001
*                                                                       40350020
BUILDPRF EQU   *                                                        40400020
*                                                                       40450020
         ST    R5,LCBERBCH-1            STOREB.U. ADDR IN ERB           40500020
         OI    PRFSTAT1-IEDQPRF(R5),PRFNLSTN+PRFTSMSG SET 'NOT   S22029 40550001
*                                       LAST' AND 'TS MESSAGE'          40600001
         TM    AYOSWTCH,INTLRQ          TEST IF INITIAL REQUEST         40650020
         BO    INITPRF                  YES, DON'T SET 'NOT HDR' S22029 40700001
*                                                                       40750020
         OI    PRFSTAT1-IEDQPRF(R5),PRFNHDRN SET 'NOT HDR' FOR          40800020
*                                       SUBSEQUENT REQUEST              40850020
*                                                                       40900020
INITPRF  EQU   *                                                 S22029 40950001
*                                                                       41000020
         LR    R9,R5                    LD ADDR OF LATEST BFR PREFIX    41050020
         LA    R9,NULL(R9)              RESET HI-ORDER BYTE             41100020
         ST    R9,AYOHDRBU                                              41150020
         TM    PRFSTAT1-IEDQPRF(R9),PRFNHDRN HEADER BFR          S22029 41200001
         BO    TXTSIZE                  NO, USE TEXT SIZE        S22029 41210001
         MVI   PRFSIZE+1-IEDQPRF(R9),AVTHDRSZ  UPDATE PRFX WITH  S22029 41220001
*                                       HEADER PREFIX SIZE              41230001
         B     INITPRF1                 CONTINUE PREFIX SETUP    S22029 41240001
TXTSIZE  EQU   *                                                 S22029 41250001
         MVI   PRFSIZE+1-IEDQPRF(R9),AVTTXTSZ  UPDATE PRFX WITH  S22029 41260001
*                                       TEXT PREFIX SIZE                41270001
INITPRF1 EQU   *                        CONTINUE UPDATING PREFIX S22029 41280001
         LA    RLCB,NULL(RLCB)          CLEAR HI-ORDER BYTE             41300020
         ST    RLCB,PRFLCB-1-IEDQPRF(R9)  STORE LCB ADDR INTO PREF      41350020
*                                                                       41400020
ADDBUCT  EQU   *                                                        41450020
*                                                                       41500020
         MVC   PRFTIC-IEDQPRF(,R5),INVLDTIC  SET INVALID TIC            41550020
         SR    R1,R1                    RESET R1                        41600020
         IC    R1,PRFNBUNT-IEDQPRF(R9)  INSERT NO OF B.U. IN BUFFER     41650020
         LA    R1,ONE(R1)               INCREMENT NO. OF B.U.           41700020
         STC   R1,PRFNBUNT-IEDQPRF(R9)  STORE UPDATED NO. OF B.U.       41750020
*                                                                       41800020
*********************************************************************** 41850020
*                                                                       41900020
MOVEDATA EQU   *                                                        41950020
*                                                                       42000020
*********************************************************************** 42050020
*                                                                       42100020
*   ENTRY TO OUTPUT EDIT ROUTINE                                        42150020
*                                                                       42200020
*   ENTRY--  REG.0 - HI-ORDER 2 BYTES                                   42250020
*                    SIZE OF FIELD TO WHICH DATA IS TO BE MOVED-INTO    42300020
*                                                                       42350020
*                  - LOW-ORDER 2 BYTES                                  42400020
*                    SIZE OF THE MSSG TO BE MOVED                       42450020
*                                                                       42500020
*            REG.1 - HI-ORDER BYTE                                      42550020
*                    BIT 0 - TSO MESSAGE                                42600020
*                    BIT 1 - CONTROL OPTION                             42650020
*                    BIT 2 - ASIS OPTION                                42700020
*                    BITS 1&2 TOGETHER - FULL SCREEN OPTION             42800021
*                                                                       43000020
*                  - LOW-ORDER 3 BYTES                                  43050020
*                    ADDR OF FIELD TO WHICH DATA IS TO BE MOVED INTO    43100020
*                                                                       43150020
*            REG.2 - ADDR OF MSSG TO BE MOVED                           43200020
*                     ZERO MEANS SEND IDLES ONLY UNLESS CARRIAGE        43210020
*                     COUNT EQUALS LINE SIZE, IN WHICH CASE             43220020
*                     RETURN CARRIAGE.                                  43230020
*                                                                       43233021
*                    WHEN QCBRETCT HAS X'08' ON, OUTPUT EDIT PERFORMS   43236021
*                     ONLY SPECIAL END OF MESSAGE PROCESSING.  IN THIS  43239021
*                     CASE, REG. 2 NEED ONLY BE NONZERO.                43242021
*                                                                       43245021
*            REG.3  - ADDR OF SCB                                       43250020
*            REG.4  - ADDR OF LCB                                       43300020
*            REG.8  - ADDR OF TSB                                       43350020
*            REG.11 - ADDR OF TCAM DISPATCHER                           43400020
*            REG.13 - ADDR OF AVT                                       43450020
*            REG.14 - RETURN ADDR                                       43500020
*            REG.15 - ENTRY ADDR                                        43550020
*                                                                       43600020
*********************************************************************** 43650020
*                                                                       43700020
         L     R1,AYONXTCH              GET PT TO NEXT SPACE            43708021
         LH    R0,AYOBULEN              GET LENGTH OF SPACE             43716021
         LTR   R0,R0                    ANY SPACE LEFT IN BU            43724021
         BNZ   SHIFTSIZ                 YES, SKIP SIZING CODE           43732021
         SPACE 1                                                        43740021
         L     R1,AYOLSTBU              LOAD ADDR OF CURRENT B.U.       43750020
         LA    R1,PRFSUNIT-IEDQPRF(R1)  NOW R1 POINTS TO 'TO-FIELD' TO  43850020
*                                       WHICH DATA MOVEMENT STARTS      43900020
*                                       UNLESS THIS IS A HDR B.U.       43950020
         LR    R0,R1                    SAVE START OF UNIT ADDR         43970020
         CLC   AYOHDRBU+1(E3),AYOLSTBU+1  TEST IF HDR B.U.              44010020
         BNE   GTBUSIZE                 NO, GO TO GET DATA LENGTH       44050020
*                                                                       44100020
         TM    PRFSTAT1-IEDQPRF(R9),PRFNHDRN HEADER PREFIX       S22029 44150001
         BO    TXTPRFX                  NO, ADJUST FOR TEXT PRF  S22029 44158001
         LA    R1,AVTHDRSZ(R1)          ADJUST FOR HEADER PRF    S22029 44166001
         B     GTBUSIZE                                          S22029 44174001
TXTPRFX  EQU   *                                                 S22029 44182001
         LA    R1,AVTTXTSZ(R1)          ADJUST FOR TEXT PRF      S22029 44190001
*                                                                       44200020
GTBUSIZE EQU   *                                                        44250020
*                                                                       44300020
         ST    R1,AYONXTCH              STORE STARTING POSITION         44320021
         AH    R0,AVTKEYLE              GET END OF B.U. ADDR(+1)        44350020
         SR    R0,R1                    OBTAIN AVAILABLE BYTES          44400020
         STH   R0,AYOBULEN              STORE AVAILABLE LENGTH          44420021
         SPACE 2                                                        44440021
SHIFTSIZ EQU   *                                                        44460021
         SLL   R0,16                    SHIFT TO-LENGTH TO HI-ORDER     44500020
*                                                                       44550020
         TM    AYOSWTCH,SENDNL          SHOULD ONLY IDLES BE SENT?      44600020
         BNZ   ENDOFBFF                 YES, GO TO END OF BFFR RTN      44650020
         TM    AYOSWTCH,CHAINEND        IS THIS END OF 3270 CHN SA61765 44654021
         BNO   NOTCHEND           NO, PROCESS NORMALLY          SA61765 44658021
         SPACE 2                                                SA61765 44662021
*   THIS IS THE END OF A 3270 CHAIN.  THERE IS NOTHING ON THE Q         44666021
*   SO WE MUST FAKE A TS BUFFER ADDRESS AND SKIP LENGTH CHECKING        44670021
         LA    R2,1                     ANY NONZERO VALUE IS OK SA61765 44674021
         ST    R2,AYOTSBFF              STORE 'ADDR' IN W.A.    SA61765 44678021
         OR    R0,R2                    LENGTH MUST BE NONZERO  SA61765 44682021
         B     ENDOFBFF                 GO SET BITS FOR EDIT    SA61765 44686021
         SPACE 2                                                SA61765 44690021
NOTCHEND EQU   *                                                SA61765 44694021
         L     R2,AYOTSBFF              LOAD ADDR OF CURRENT TSO BFFR   44700020
         IC    R0,BUFFLNTH-TIOCBUF(R2)  INSERT LENGTH OF TSO MSG        44750020
         SR    R15,R15                  RESET R15 TO '0'                44800020
*                                                                       44850020
TSTHDRBF EQU   *                                                        44900020
*                                                                       44950020
         CLC   BUFFTRLR,ZEROS           TEST IF ANY MORE IN CHAIN       45350020
         BE    ENDOFBFF                 NO, GOTO END OF BFF             45800020
*                                                                       45850020
         L     R2,BUFFTRLR-1-TIOCBUF(R2) LOAD NEXT BUFFER ADDR          45900020
*                                                                       45950020
*   UPDATE CURRENT TS BUFFER POINTER IF THIS TS BUFFER HAS              46000020
*   BEEN EMPTIED.                                                       46050020
*                                                                       46100020
         LR    R14,R0                   MOVE R0 FOR DESTRUCTIVE TEST    46130020
         N     R14,AVTCLRHI             IS THERE ANY DATA TO BE MOVED?  46160020
         BNZ   INSRTLNG                 YES,GOTO INSERT DATA LENGTH     46200020
         LA    R2,NULL(R2)              CLEAR HI-ORDER BYTE             46250020
         ST    R2,AYOTSBFF              UPDATE TS BFFR POINTER          46300020
*                                                                       46350020
INSRTLNG EQU   *                                                        46400020
*                                                                       46450020
         IC    R15,BUFFLNTH-TIOCBUF(R2) INSERT TEXT LENGTH              46500020
         AR    R0,R15                   ADD TEXT LENGTH TO TSO MSG LNTH 46550020
         B     TSTHDRBF                 GO BACK TO CHECK NEXT BUFFER    46600020
*                                                                       46610020
CLEARQ   EQU   *                                                        46620020
         BAL   R14,TSBADDR              GET TSB AND TIOCPT       TS1638 46623020
*                                       ADDR'S                   TS1638 46626020
         STM   R0,R1,AVTSAVE2+E48       SAVE REGS. ACROSS QTIP          46628020
         SR    R15,R15                  INDICATE Q FLUSH ALLOWED        46629020
         QTIP  QTIP2ND,(RSAVE)          CLEAR OUTPUT TRAILER QUEUE      46630020
*                                                                       46633020
         LM    R0,R1,AVTSAVE2+E48       RESTORE REGS. AFTER QTIP        46636020
         CLI   QCBCARCT,NULL            IS CARRIAGE AT LEFT MARGIN      46636820
         BE    SENDIDLE                 YES, NO NEED TO RETURN          46637620
         MVC   QCBCARCT,TSBLNSZ         TELL OUTPUT EDIT...             46638420
         NI    QCBRETCT,NOT-QCBNLCR     ...TO RETURN CARRIAGE           46639220
         B     SENDIDLE                 GO SEND IDLES INSTEAD OF DATA   46640020
*                                                                       46650020
ENDOFBFF EQU   *                                                        46700020
*                                                                       46750020
         L     R2,AYOTSBFF              LOAD ADDR OF CURRENT TS BUFFER  47000020
*                                                                       47050020
         LA    R1,NULL(R1)              CLEAR HI-ORDER BYTE             47100020
         O     R1,TSOMSGC               SET TSO MSG BIT 'ON'            47150020
*                                                                       47158020
         LR    R15,R0                   MOVE FIELD LENGTHS FOR TESTING  47166020
         N     R15,AVTCLRHI             IS THERE ANY OUTPUT MESSAGE?    47174020
         BZ    SENDIDLE                 NO, GO SEND IDLES ONLY          47182020
*                                                                       47190020
         TM    AYOSWTCH,SENDNL          TEST IF TO SEND ONLY IDLES      47220020
         BNO   CHCKEDIT                 NO, GO CHECK EDIT OPTION        47250020
*                                                                       47300020
SENDIDLE EQU   *                                                        47400020
         SR    R2,R2                    INDICATE SEND IDLES ONLY        47500020
*                                                                       47520020
         CLI   QCBCARCT,E41             ENOUGH IN CARRIAGE COUNT        47540020
         BH    CHCKEDIT                 YES, NO NEED TO SET IT UP       47560020
         MVI   QCBCARCT,TWOIDLE         SET CARRIAGE POSITION TO        47600020
*                                       CAUSE IDLES                     47700020
         B     PASTFLSH                 GO TO OUTPUT EDIT        A44839 47770021
*                                                                       47850020
CHCKEDIT EQU   *                                                        47900020
*                                                                       47950020
         TM    AYOSWTCH,CHAINEND        END OF 3270 MSG CHAIN   SA61765 47960021
         BO    PASTFLSH                 YES, SKIP CHECKS        SA61765 47970021
*                                                                       48000021
*        SET BITS IN REGISTER ACCORDING TO TPUT OPTION -                48010021
*        TSOASISC MEANS ASIS, TSOCNTLC MEANS CONTROL, BOTH MEANS        48020021
*        FULL SCREEN                                                    48030021
*                                                                       48040021
         TM    BUFFFL1,BUFFEDIT+BUFFCNTL TEST FOR BOTH, NEITHER SA60002 48050021
         BO    SETFULLS                 BOTH ON, FULL SCREEN    SA60002 48060021
         BZ    SETASIS                  NEITHER, MUST BE ASIS   SA60002 48070021
         SPACE 2                                                SA60002 48080021
*        MUST BE EDIT OR CONTROL                                SA60002 48090021
*                                                                       48100021
         TM    BUFFFL1,BUFFEDIT         CHECK FOR EDIT          SA60002 48110021
         BO    GOEDIT                   SET NO BITS FOR EDIT    SA60002 48120021
         O     R1,TSOCNTLC              SET CONTROL BIT         SA60002 48130021
         B     GOEDIT                   GO CALL EDIT RTN        SA60002 48140021
         SPACE 2                                                SA60002 48150021
SETASIS  EQU   *                                                SA60002 48160021
         O     R1,TSOASISC              SET ASIS BIT            SA60002 48170021
         B     GOEDIT                   GO CALL EDIT RTN        SA60002 48180021
         SPACE 2                                                SA60002 48190021
SETFULLS EQU   *                                                SA60002 48200021
         O     R1,TSOASISC              SET ASIS FOR FULLSCR,   SA60002 48210021
         O     R1,TSOCNTLC              AND ALSO SET CNTL       SA60002 48220021
*                                                                       48300020
GOEDIT   EQU   *                                                        48350020
*                                                                       48400020
         TM    TSBFLG3,TSBTJMSG         IS MESSAGE NON-FLUSHABLE?       48403020
         BO    PASTFLSH                 YES, SKIP FLUSH CHECK           48406020
         TM    TSBFLG1,TSBOFLSH         SHOULD OUTPUT TRAILER QUEUE     48410020
*                                       BE CLEARED?                     48420020
         BO    CLEARQ                   YES, DON'T SEND REST OF MSG     48430020
*                                                                       48440020
PASTFLSH EQU   *                                                        48445020
*          REG.2  - ADDR OF LAST TS BUFFER FROM WHICH DATA WAS MOVED    48465020
         L     R15,AVTTSOPT             LOAD ADDR OF TSINPUT QCB        48500020
         USING IEDQTSI,R15                                              48550020
         L     R15,TSIEDIT              LOAD ADDR OF EDIT ROUTINE       48600020
         TM    AYOSWTCH,INTLRQ          INITIAL REQUEST?        YM2865  48610000
         BNO   DONTINIT                 IF NOT, DON'T TOUCH     YM2865  48612000
*                                       LCBTTBIN (ERP'S USE IT) YM2865  48614000
         MVC   LCBTTBIN,AYOSRCE         SET INDEX TO TNT         A44839 48620021
DONTINIT EQU   *                                                YM2865  48630000
*                                                                       48650020
         BALR  R14,R15                  GOTO EDIT ROUTINE               48700020
*                                                                       48750020
         DROP  R15                                                      48760020
*                                                                       48770020
*********************************************************************** 48800020
*                                                                       48850020
*   RETURN FROM OUTPUT EDIT ROUTINE                                     48900020
*                                                                       48950020
*   EXIT - REG.0  - NO. OF CHARACTERS MOVED INTO TO-FIELD               49000020
*          REG.1  - LENGTH OF DATA MOVED FROM FROM-FIELD                49050020
*          REG.2  - ADDR OF LAST TS BUFFER FROM WHCICH DATA WAS MOVED   49100020
*          REG.15 - RETURN CODE                                         49150020
*                   X'00' - COMPLETE MSSG HAS BEEN MOVED                49200020
*                           (AND 3270 SCREEN IS FULL)                   49210021
*                   X'08' - COMPLETE MSG HAS BEEN MOVED, BUT            49220021
*                           SCREEN IS NOT FULL                          49230021
*                   X'0C' - ONLY PART OF MSSG HAS BEEN MOVED            49250020
*                           AND LINE (OR, FOR 3270, SCREEN)             49260021
*                           ONLY PARTLY FILLED.                         49265021
*                   X'10' - ONLY PART OF TS MSG MOVED BUT TERMINAL      49270020
*                           LINE (OR SCREEN) IS FULL.                   49280021
*                                                                       49300020
*********************************************************************** 49350020
*                                                                       49400020
         LA    R2,NULL(R2)              CLEAR HI-ORDER BYTE             49450020
         ST    R2,AYOTSBFF              STORE IT IN WORK AREA           49500020
*                                                                       49550020
         L     RPREF,AYOHDRBU           LOAD ADDR OF HDR B.U.           50360020
         LH    R14,AYOBULEN             GET PREV NO. AVAILABLE  YS6327  50367021
         SR    R14,R0                   SUBTRACT AMOUNT JUST    YS6327  50374021
*                                       MOVED                   YS6327  50381021
         STH   R14,AYOBULEN             STORE NEW AVAIL SPACE   YS6327  50388021
         L     R14,AYONXTCH             PREV. POINTER           YS6327  50395021
         AR    R14,R0                   ADD AMOUNT MOVED        YS6327  50402021
         ST    R14,AYONXTCH             STORE UPDATED POINTER   YS6327  50409021
         AH    R0,PRFSIZE               GET UPDATED DATA LENGTH YS6327  50420021
         STH   R0,PRFSIZE               STORE UPDATED LENGTH    YS6327  50480021
         DROP  R2                                               YS6327  50510021
*                                                                       50550020
*********************************************************************** 50850020
*                                                                       50900020
*   IF THIS LATEST BASIC UNIT IS THE LAST IN A TCAM BUFFER, DECREMENT   50940020
*   THE COUNT OF TCAM BUFFERS PERMITTED ON THIS REQUEST (LCBERBCT).     50980020
*   IF THE COUNT HAS BEEN EXHAUSTED, TCAM BUFFER BUILDING MUST STOP     51020020
*   FOR THIS REQUEST.                                                   51060020
*                                                                       51100020
*********************************************************************** 51150020
*                                                                       51200020
         LA    R14,AVTECD12             RETURN CODE COMPARISON VALUE    51270020
         LTR   R15,R15                  WAS RETURN CODE = X'00'?YA00526 51280021
         BZ    CANT                     YES, ALL IS OK, SENDMSG YA00526 51290021
         CR    R15,R14                  COMPARE RC WITH X'0C'   YA00526 51300021
         BH    CANT                     GREATER,(10=SCREEN FULL)YA00526 51310021
*                                                                       51350020
*   TEST IF A BUFFER HAS BEEN CONSTRUCTED                               51400020
*                                                                       51550020
         L     R9,AYOHDRBU              LOAD ADDR OF HDR B.U.           51600020
         CLC   AYOBULEN(2),ZEROS        IS CURRENT BU FULL?     YA00526 51640021
         BNE   OVER                     NO, DONT CHECK ERBCNT   YA00526 51680021
         CLC   LCBERBQB(ONE),PRFNBUNT-IEDQPRF(R9) LAST BU IN    YA00526 51740021
*                                                TCAM BUFFER?   YA00526 51748021
         BE    BFRBUILT                 YES, DECREMENT ERBCNT   YA00526 51760021
OVER     CR    R15,R14                  COMPARE RC WITH X'0C'   YA00526 51770021
         BE    GETBASIC                 EQUAL, GET ANOTHER BU   YA00526 51780021
         B     NEXTMSG                  NOTEQUAL (X'08') GET    YA00526 51790021
*                                       GET NEXT TS MESSAGE     YA00526 51800021
*                                                                       51810020
BFRBUILT EQU   *                                                        51850020
         SLR   R0,R0                    CLEAR FOR IC                    51890020
         IC    R0,LCBERBCT              INSERT ENABLED COUNT            51970020
         BCTR  R0,0                     DECREMENT                       52050020
         STC   R0,LCBERBCT              STORE UPDATED ENABLED COUNT     52130020
*                                                                       52210020
         LTR   R0,R0                    IS ENABLED COUNT EXHAUSTED?     52290020
         BNZ   CAN                      NO, BFR BUILDING MAY CONTINUE   52370020
*                                                                       52630020
*   NOTE.  WHEN THE HI-ORDER BIT IS ON IN THE DISABLED COUNT, THE       52637020
*   PCI APPENDAGE WILL UPDATE THE ENABLED COUNT RATHER THAN THE         52644020
*   DISABLED COUNT.                                                     52651020
*                                                                       52660020
         OI    LCBERBCT+1,XXCTUSED      SHOW DISABLED COUNT IN USE      52660320
         CLI   LCBERBCT+1,XXCTUSED      WAS DISABLED COUNT ZERO         52660620
         BNE   MERGCNTS                 NO, GO MERGE COUNTS             52660920
         OI    LCBERBST,LCBDLNKN        MAKE ERB POSTABLE               52661220
         NI    LCBERBCT+1,NOT-XXCTUSED  MAKE DISABLED COUNT USABLE      52661520
         NC    LCBERBCT,LCBERBCT        IS ERB COUNT STILL ZERO         52661820
         BZ    CANNOT                   YES, BFR BUILDING MUST CEASE    52662120
*                                                                       52662420
*   ARRIVAL AT THIS POINT MEANS AN INTERRUPTION OCCURRED DURING         52662720
*   EXECUTION OF THE PREVIOUS 7 INSTRUCTIONS.  LCBDLNKN IS TESTED       52663020
*   TO SEE WHEN THE INTERRUPTION OCCURRED.                              52663320
*   -----IF OFF, THIS MEANS THE INTERRUPT OCCURRED AFTER THE ERB        52663620
*        WAS MARKED POSTABLE.  THE PCI APPENDAGE HAS POSTED THE         52663920
*        ERB TO TSOUTPUT AGAIN.  BUFFER BUILDING SHOULD STOP FOR        52664220
*        THIS REQUEST.                                                  52664520
*   -----IF ON, PCI APPENDAGE COULDN'T POST THE ERB.  BUFFER BUILDING   52664820
*        MAY CONTINUE.  NOTE THAT THE ERB COUNTS NEEDN'T BE             52665120
*        MERGED SINCE THE PCI APPENDAGE UPDATED THE ENABLED COUNT.      52665420
*                                                                       52665720
         TM    LCBERBST,LCBDLNKN        HAS ERB BEEN REPOSTED           52666020
         BNO   CANNOT                   YES, CEASE BFR BUILDING         52666320
         NI    LCBERBST,LCBDLNKF        MAKE ERB NON-POSTABLE           52666620
         B     CAN                      MAY CONTINUE BFR BUILDING       52666920
*                                                                       52667220
*   MERGE DISABLED & ENABLED ERB COUNTS                                 52667520
*                                                                       52667820
MERGCNTS EQU   *                                                        52668120
         IC    R0,LCBERBCT+1            PICK UP DISABLED COUNT          52670020
         MVI   LCBERBCT+1,NULL          DISABLED COUNT NOW 0 & USABLE   52680020
         LA    R1,NOT-XXCTUSED          LOAD MASK TO RESTORE COUNT      52690020
         NR    R0,R1                    CLEAR IN USE BIT                52700020
         IC    R1,LCBERBCT              GET ANYTHING PUT IN ENABLED     52710020
*                                       CNT WHILE DISABLED COUNT        52720020
*                                       WAS IN USE                      52730020
         AR    R0,R1                    MERGE COUNTS                    52740020
         STC   R0,LCBERBCT              STORE MERGED COUNT              52750020
*                                                                       52850020
CAN      EQU   *                                                        52930020
*                                                               YA00526 52940021
*     AT THIS POINT, THE RETURN CODE FROM THE OUTPUT EDIT       YA00526 52950021
*     MUST HAVE BEEN EITHER                                     YA00526 52960021
*                         X'08' -- MEANING ANOTHER TSO MESSAGE  YA00526 52970021
*                                  SHOULD BE OBTAINED AND PACKEDYA00526 52980021
*                                  INTO THE TCAM BUFFERS        YA00526 52990021
*                         X'0C' -- MEANING ANOTHER BASIC UNIT   YA00526 53000021
*                                  IS NEEDED                    YA00526 53010021
*                                                               YA00526 53020021
         CR    R15,R14                  IS ANOTHER BASIC UNIT NEEDED    53030020
         BNE   NEXTMSG                  NO, GET ANOTHER TSO MSG YA00526 53070021
         TM    AYOSWTCH,INTLRQ          IS THIS A PCI REQUEST           53110020
         BNO   SENDMSG                  YES, THIS BFR MUST BE POSTED    53150020
         B     GETBASIC                 NO, GO CONTINUE BFR BUILDING    53190020
*                                                                       53250020
CANT     EQU   *                                                        53330020
         OI    LCBERBST,LCBDLNKN        MAKE ERB 'POSTABLE'             53410020
CANNOT   EQU   *                                                        53414020
         CR    R15,R14                  BFR ALLOCATION ALL USED UP?     53418020
         BE    SENDMSG                  YES, GO SEND MESSAGE            53426020
*                                                                       53434020
*   SET END OF MESSAGE CONDITION FOR THE TCAM MESSAGE                   53442020
*                                                                       53450020
         NI    PRFSTAT1,PRFNLSTF        INDICATE BFR IS LAST            53458020
         OI    LCBERBST,LCBEOMSG        INDICATE END OF MESSAGE         53466020
         MVI   LCBERBCT+1,NULL          CLEAR DISABLED COUNT            53470020
*                                                                       53474020
         LTR   R15,R15                  WAS WHOLE TS MSG MOVED INTO     53490020
*                                       TCAM BUFFERS?                   53570020
         BNZ   SENDMSG                  NO, SKIP END OF MSG PROCESSING  53650020
*                                                                       53950020
*********************************************************************** 54000020
*                                                                       54050020
*   ONE COMPLETE TS MSG HAS BEEN MOVED INTO TCAM BUFFER                 54100020
*                                                                       54350020
*********************************************************************** 54400020
*                                                                       54600020
*   IF THIS MESSAGE IS A PARTIAL INPUT LINE CAUSED BY BREAK-IN, GIVE    56080020
*   PRIORITY TO INPUT ON THIS TERMINAL IN ORDER TO READ REST OF         56160020
*   INPUT MESSAGE.                                                      56240020
*                                                                       56320020
         TM    TSBFLG2,TSBBIPI          IS THIS A PARTIAL LINE?         56400020
         BNO   MOREBFF                  NO, GO CHK FOR MORE MSG'S       56480020
         TM    TSBSTAT,TSBDSPLY         IS THIS A FLASHBACK MSG         56500020
         BO    MOREBFF                  YES, GO CHK FOR MORE MSG'S      56520020
         OI    QCBFLAG,QCBREAD          GIVE READ PRIORITY ON TERM      56560020
         B     SENDMSG                  GO SEND MESSAGE                 56640020
*                                                                       57050020
MOREBFF  EQU   *                                                        57100020
*                                                                       57150020
         CLC   TSBOBFP,ZEROS            TEST IF ANY MORE TS MSG         57200020
         BNE   SENDMSG                  YES,GOTO SEND THIS TS MSG       57250020
*                                                                       57300020
         TM    TSBFLG2,TSBAUTON         IS AUTO PROMPTING REQUESTED?    57400020
         BZ    SENDMSG                  NO, GO SEND MESSAGE             57500020
*                                                                       57510020
         TM    QCBTSOF1,QCBPARTO        IS REST OF MSG YET TO    TS1638 57520020
*                                       COME                     TS1638 57530020
         BO    SENDMSG                  YES, DON'T AUTO PROMPT   TS1638 57540020
*                                       YET                      TS1638 57550020
*                                                                       57560020
         TM    TSBFLG3,TSBSPIT          IS TCLEARQ IN PROGRESS          57570020
         BO    SENDMSG                  YES, DON'T AUTO PROMPT          57580020
         OI    SCBERR2,SCBALN           REQUEST AUTO PROMPTING          57600020
*                                       BY MSGGEN                       57700020
         B     SENDMSG                  GO SEND MESSAGE                 57800020
*                                                                       58400020
*********************************************************************** 58402021
*                                                                       58404021
NEXTMSG  EQU   *                                                SA61765 58406021
*                                                                       58408021
*********************************************************************** 58410021
*                                                                       58412021
*   FOR 3270, OUTPUT EDIT HAS INDICATED THAT A COMPLETE TS MESSAGE      58414021
*    HAS BEEN PUT INTO TCAM BUFFERS, BUT THE SCREEN IS NOT FULL.        58416021
*        1 - CALL QTIP 12 TO CLEAR THE TRAILER QUEUE,                   58418021
*        2 - BRANCH BACK TO GET ANY MORE TS MESSAGES AND BLOCK          58420021
*            THEM IN THE TCAM BUFFERS                                   58422021
*                                                                       58426021
*********************************************************************** 58428021
         BAL   R14,TSBADDR              SET UP ADDRESSES FOR QTPSA61765 58430021
         QTIP  QTIP2ND,(RSAVE)          CLEAR TRAILER QUEUE     SA61765 58432021
         SPACE 2                                                SA61765 58434021
         OI    AYOSWTCH,MSGCHAIN        SHOW A CHAIN HAS BEGUN  SA61765 58436021
         B     CHAINBUF                 GO CHECK FOR MORE MSGS  SA61765 58442021
         SPACE 2                                                SA61765 58444021
*********************************************************************** 58450020
*                                                                       58500020
NOOUTPUT EQU   *                                                        58550020
*                                                                       58600020
*********************************************************************** 58650020
*                                                                       58700020
*   NO OUTPUT TO SEND                                                   58750020
*        1 - CHECK FOR END OF 3270 MESSAGE CHAIN AND HANDLE IF SO       58800021
*        2 - CHECK EXCEPTIONAL CONDITIONS AND HANDLE, OTHERWISE         58850021
*            POST LCB TO ITSELF                                         58950020
*        3 - INITIAL OR SUBSEQUENT PCI                                  59100021
*            COMPLETE REQUEST BY SENDING ONE IDLE CHARACTER             59150020
*                                                                       59200020
*********************************************************************** 59250020
*                                                                       59300020
         TM    AYOSWTCH,MSGCHAIN        WAS A 3270 CHAIN BEGUN  SA61765 59300521
         BNO   REALLYNO                 NO, GO DO NOOUTPUT      SA61765 59301021
         SPACE 2                                                SA61765 59301521
*********************************************************************** 59302021
*                                                                       59302521
         OI    QCBRETCT,DOEOM           SIGNAL EOM TO EDIT      SA61765 59306021
         OI    AYOSWTCH,CHAINEND        SIGNAL EOM TO TSOUTPUT  SA61765 59306521
         B     WATSLEFT                 USE CURRENT BU IF POSS  YS6327  59307021
         SPACE 2                                                SA61765 59307521
REALLYNO EQU   *                                                SA61765 59308021
         TM    AYOSWTCH,INTLRQ          IS THIS AN INITIAL REQUEST      59310020
         BNO   NOTINTL                  NO, SET UP TO SEND 1 IDLE       59320020
*                                                                       59330020
         SR    R9,R9                    CLEAR MSGGEN MASK REG    M0141  59390021
         TM    TSBSTAT,TSBDISC          USER BEING LOGGED OFF?          59451020
         BNO   CKBRK1                   NO, DON'T CK SPECIAL MSG M0141  59455021
         L     R1,TSBTJB-1              GET TJB                  M0141  59459021
         USING TJB,R1                                            M0141  59463021
*                                                                       59467021
*   TEST FOR SPECIAL MESSAGES TO BE SENT                                59471021
*                                                                       59475021
         TM    TJBSTAT2,TJBOCAB         OUT-OF-CORE ABEND        M0141  59479021
         BZ    TESTRNAV                 NO, CHECK NEXT MSG       M0141  59483021
         LA    R9,MSKOCAB               SET MSGGEN MASK          M0141  59487021
         B     PASTLCB                  GO CHECK FOR CLEANUP     M0141  59491021
*                                                                       59495021
TESTRNAV EQU   *                                                 M0141  59499021
         TM    TJBSTAT2,TJBRNAV         REGION NOT AVAILABLE     M0141  59503021
         BZ    POSTLCB                  NO, GO POST LCB         YM2814  59507000
         LA    R9,MSKRNAV               SET MSGGEN MASK          M0141  59511021
         B     PASTLCB                  GO CHECK FOR CLEANUP     M0141  59515021
*                                                                       59519021
CKBRK1   EQU   *                                                 M0141  59523021
         TM    QCBTSOF2,QCBBUFQ         IS TSINPUT HOLDING BFRS  M0141  59527021
         BO    POSTLCB                  YES, POST LCB            M0141  59531021
*                                                                       59535021
         TM    TSBFLG3,TSBSPIT          IS TCLEARQ IN PROGRESS   M0141  59539021
         BO    POSTLCB                  YES, DON'T WORRY BREAKIN M0141  59543021
*                                                                       59547021
         TM    QCBTSOF1,QCBPARTO        MORE MSGS TO COME        M0141  59551021
         BO    POSTLCB                  YES, DON'T PROMPT IN     M0141  59555021
*                                       MIDDLE OF MESSAGE               59559021
         TM    TSBFLG2,TSBBRKIN         DID BREAKIN OCCUR        M0141  59563021
         BO    PASTLCB                  YES, DON'T FREE LINE     M0141  59567021
*                                                                       59571021
POSTLCB  EQU   *                                                 M0141  59575021
*                                                                       59579021
*   ISSUE QTIP SVC TO RESET QCBTPUT AND QCBWRBRK, AND TPOST THE         59583000
*   LCB TO ITSELF, ALL WHILE DISABLED.                                  59587021
*                                                                       59591021
         QTIP  QTIP6TH,(RSAVE)                                   M0141  59595021
*                                                                       59599021
         STC   R15,AYORC                SAVE RETURN CODE        YM2814  59603000
         BCTR  R9,R0                    MAKE REG NEG, TO SHOW   YM2814  59611000
*                                       THAT QTIP WAS CALLED    YM2814  59613000
*                                                                       59615021
PASTLCB  EQU   *                                                 M0141  59619021
*                                                                       59623021
*   CLEAN UP TCAM AND TSO CONTROL BLOCKS IF REQUESTED                   59627021
*                                                                       59631021
         TM    TSBSTAT,TSBDISC          CLEANUP REQUESTED        M0141  59635021
         BNO   CKBRK2                   NO, GO SEE WHAT ELSE TO  M0141  59639021
*                                       DO                              59643021
         QTIP  QTIP4TH,(RSAVE)          CLEAN UP TSO CONTROL BLK M0141  59647021
*                                                                       59651021
         BAL   R5,SESCLEAN              CLEAN UP TCAM CNTRL BLKS M0141  59655021
CKBRK2   EQU   *                                                 M0141  59667021
         CLI   AYORC,NULL               WAS RETURN FROM OO ZERO YM2814  59671000
         BNE   AUTOPRMT                 NO, GO START AUTO PRMPT YM2814  59675000
         LTR   R9,R9                    DID WE CALL QTIP TO     YM2814  59685000
*                                       TPOST LCB, ETC.         YM2814  59695000
         BP    GOMSGGEN                 NO, THERE IS A LOGOFF   YM2814  59705000
*                                       MESSAGE TO SEND         YM2814  59715000
         BZ    CHKBRKIN                 NO CALL, NO MSG, CK BRK YM2814  59725000
*                                                                       59750020
*                                                                       59753020
*   THERE IS NO OUTPUT TO SEND SO CLEAN-UP TCAM STATUS INDICATORS       59756020
*   WHICH WERE SET UP FOR OUTPUT                                        59759020
*                                                                       59762020
CLEANOUT EQU   *                                                        59765020
         SR    R0,R0                    CLEAR REGISTER                  59768020
         ST    R0,SCBERRST              ZERO ERROR INDICATORS           59771020
         ST    R0,SCBDEOB               ZERO SCB STATUS                 59774020
         STH   R0,SCBEOB                ZERO SCB FIELD                  59777020
         MVI   LCBSENS0,NULL            ZERO SENSE BYTE                 59780020
         ST    R0,LCBERBCH-1            CLEAR ERB STATUS & CHAIN        59783020
         XC    LCBLSPCI,LCBLSPCI        LAST SERVICED PCI               59786020
         NI    LCBCHAIN,NOT-LCBBFRSZ-LCBABRTN-LCBEXCP                   59789020
         NI    LCBTSOB,NOT-LCBTSBUF-LCBINHBN-LCBWRBRK                   59792020
         NI    LCBSTAT2,LCBMSGNF        RESET MSGGEN BIT                59795020
         NI    LCBSTAT1,NOT-LCBRCLLN    RESET RECALL BIT                59798020
*                                                                       59801020
         LA    R1,X0100                 GET MASK ADDRESS                59804020
         IC    R0,SCBMACR-1             SAVE HI-ORDER BYTE              59807020
         ST    R1,SCBMACR-1             STORE MASK ADDRESS              59810020
         STC   R0,SCBMACR-1             RESTORE HI-ORDER BYTE           59813020
         LA    R1,AVTBFRTB              GET ADDR OF BFR RET Q           59816020
         IC    R0,SCBDESTQ-1            SAVE HI-ORDER BYTE              59819020
         ST    R1,SCBDESTQ-1            STORE BFR RET Q ADDR            59822020
         STC   R0,SCBDESTQ-1            RESTORE HI-ORDER BYTE           59825020
         B     DISP                     GO EXIT TO TCAM DISPATCHER      59850020
*                                                                       59950020
*********************************************************************** 60200020
*                                                                       60250020
TSABEND  EQU   *                                                        60300020
*                                                                       60350020
*********************************************************************** 60400020
*                                                                       60450020
*   TS HAS ABENDED                                                      60500020
*        -- CLEAN UP TCAM CONTROL BLOCKS                                60560020
*        -- SEND TS ABEND MESSAGE USING MSGGEN INTERFACE                60620020
*                                                                       60700020
         BAL   R5,SESCLEAN              GO CLEAN-UP TCAM BLOCKS         60740020
         LA    R9,ABNDMSK               PT TO PROPER MSGGEN MASK        60780020
         B     GOMSGGEN                 GO PUT OUT MESSAGE              60820020
*                                                                       60860020
*********************************************************************** 60900020
*                                                                       60950020
AUTOPRMT EQU   *                                                        61000020
*                                                                       61050020
*   USE MSGGEN INTERFACE TO SEND AUTO PROMPT SEQUENCE                   61057020
*                                                                       61064020
         OI    SCBERR2,SCBALN           ASK MSGGEN FOR AUTO LINE NO.    61071020
         LA    R9,AUTOMSK               PT TO PROPER MSGGEN MASK        61078020
*                                                                       61092020
*********************************************************************** 61100020
*                                                                       61150020
*   THIS ROUTINE IS AN INTERFACE TO GO TO MSGGEN TO SEND A MESSAGE      61200020
*                                                                       61250020
*        REGISTERS AT EXIT TO MSGGEN--                                  61300020
*          REG 1 = 0                                                    61350020
*          REG 3 = ADDR OF SCB                                          61400020
*          REG 4 = ADDR OF LCB                                          61450020
*          REG 8 = ADDR OF MSSGEN MASK                                  61500020
*          REG 9 = IC REG                                               61550020
*          REG 11= ADDR OF DISPATCHER                                   61600020
*          REG 12= ADDR IN TSIMSGEN                                     61650020
*          REG 13= ADDR OF AVTSAVE2                                     61700020
*                                                                       61750020
GOMSGGEN EQU   *                                                        61950020
*                                                                       62150020
         MVC   LCBTTCIN,AYOSRCE         MOVE IN TERMINAL INDEX          62350020
         MVI   LCBSTAT1,LCBRECVN        SET RECEIVE MODE                62550020
         LA    R15,X0100                LOAD ADDR OF X0100              62600020
         IC    R0,SCBMACR-1             SAVE SIM ATTN LEVEL             62650020
         ST    R15,SCBMACR-1            STORE IT IN SCB                 62700020
         STC   R0,SCBMACR-1             STORE SIM ATTN LEVEL            62750020
         LR    R8,R9                    GET MSGGEN MASK POINTER         63050020
*                                                                       63400020
         L     R2,AVTTSOPT              LOAD ADDR OF TSI                63450020
         USING IEDQTSI,R2                                               63500020
         L     R12,TSIMSGEN             LOAD ADDR OF MSSGEN RTN         63550020
         SR    R1,R1                    SET R1=0                        63600020
         L     R11,AVTEA                LOAD DISPATCHER ADDR            63650020
         BR    R12                      GOTO MSSGEN ROUTINE             63700020
*                                                                       63710020
         DROP  R2                                                       63720020
*                                                                       63750020
*********************************************************************** 63800020
*                                                                       63850020
NOTINTL  EQU   *                                                        63900020
*                                                                       63950020
*********************************************************************** 64000020
*                                                                       64050020
*   THERE IS NO OUTPUT FOR INITIAL AND SUBSEQUENT PCI                   64100020
*        1 - TO TERMINATE SEND OPERATION,SET-UP TO SEND 1 IDLE          64150020
*        2 - THEN TREAT LIKE A NORMAL OPERATION                         64200020
*                                                                       64250020
*********************************************************************** 64300020
*                                                                       64350020
         XC    AYOTSBFF(E4),AYOTSBFF    RESET TS BUFFER POINTER         64400020
*                                                                       64450020
         OI    AYOSWTCH,SENDNL          SET TO SEND 1 DUMMY IDLE CHAR   64500020
         B     GETBASIC                 GOTO GET BASIC UNIT             64550020
*                                                                       64600020
*********************************************************************** 64800020
*                                                                       64850020
CHKBRKIN EQU   *                                                        64900020
*                                                                       64950020
*********************************************************************** 65000020
*                                                                       65050020
*   'TSBBRKIN' ON CAUSED ARRIVAL AT THIS POINT.  THIS MEANS ONE OF      65060020
*   THE FOLLOWING--                                                     65070020
*        --THE USER WAS INTERRUPTED BY A BREAK-IN MESSAGE WHILE         65080020
*          ENTERING INPUT AND NEEDS TO HAVE THAT INPUT SENT OUT TO HIM  65090020
*          TO PROMPT HIM TO COMPLETE HIS MESSAGE.                       65100020
*        --THE USER'S SCREEN FILLED UP AND WAS ERASED WHILE HE WAS      65110020
*          ENTERING INPUT, SO THE LAST PART OF HIS INPUT NEEDS TO BE    65120020
*          SENT TO REORIENT HIM.                                        65130020
*                                                                       65200020
*********************************************************************** 65250020
*                                                                       65300020
*  ISSUE QTIP CALL TO PUT MSG ON TRAILER QUEUE                          65370020
*                                                                       65450020
         QTIP  QTIP5TH,(RSAVE)          PUT PARTIAL MSG ON TRLR Q       65500020
*                                                                       65550020
         B     BUILDBFF                 GO SEND REPROMPT                65750020
*                                                                       66050020
*********************************************************************** 66100020
*                                                                       66150020
SENDMSG  EQU   *                                                        66200020
*                                                                       66250020
*********************************************************************** 66300020
*                                                                       66350020
*   ON AN INITIAL REQUEST TPOST THE ERB TO THE ACTIVATE ROUTINE.        66390020
*   ON A PCI REQUEST TPOST THE BUFFER TO THE MESSAGE HANDLER.           66470020
*   ADDITIONALLY, ON A SUBSEQUENT PCI REQUEST, TPOST ERB TO             66510020
*   TSOUTPUT IF LCBERBCT IS NOT EXHAUSTED.                              66550020
*                                                                       66600020
*********************************************************************** 66650020
*                                                                       66700020
         MVC   PRFLINK,ZEROS            CLEAR LINK FIELD                66770020
         L     R2,LCBERBCH-1            LOAD ADDR OF 1ST BFFR           66850020
*                                                                       66950020
         ST    RQCB,SCBSCSEG-1          STORE DESTINATION QCB ADDR      67150020
         OI    LCBTSOB,LCBTSBUF         SET THIS IS A TSBUF BIT         67350020
         L     RDCB,LCBDCBPT            LOAD DCB ADDR                   67400020
*                                                                       67450020
         LA    R1,LCBERB                LOAD ADDR OF ERB                67500020
*                                                                       67550020
         TM    AYOSWTCH,INTLRQ          TEST IF INTIAL REQUEST          67900020
         BNO   POSTMH                   NO ,POST TO MH                  67950020
*                                                                       68000020
*   WHEN IT IS INITIAL REQUEST                                          68050020
*        1 - IF DYNAMIC BFFRING IS NOT SPECIFIED,MAKE THIS AS END OF    68100020
*            TCAM MSG                                                   68150020
*        2 - POST ERB TO ACTIVATE (PRI=PRIACTIV)                        68200020
*                                                                       68250020
         MVC   LCBTTBIN(R2),AYOSRCE     SET INDEX TO TNT         YM2865 68300000
         TM    DCBPCI,DYNMBFFR          TEST IF DYNAMIC BFFRING SPEC.   68350020
         BO    DYNAMIC                  YES,DYNAMIC BFFRING SPECIFIED   68400020
*                                                                       68450020
*   WHEN DYNAMIC BFFRING IS NOT SPECIFIED - TREAT THIS MSG AS END OF    68500020
*        1 - TURN 'NOT LAST BFFR' BIT OFF              TCAM MSG         68550020
*        2 - SET LCBEOMSG 'ON'                                          68600020
*                                                                       68650020
         NI    PRFSTAT1,PRFNLSTF        RESET 'NOT LAST BFFR' BIT       68750020
         OI    LCBERBST,LCBEOMSG        SET END OF MSG BIT              68800020
         MVI   LCBERBCT+1,NULL          CLEAR DISABLED COUNT            68820020
*                                                                       68850020
DYNAMIC  EQU   *                                                        68900020
*                                                                       68950020
*                                                                       69650020
*   WHEN INITIAL REQUEST - POST ERB TO ACTIVATE                         69700020
*                                                                       69750020
         LA    R2,AVTACTIB              LOAD ADDR OF ACTIVATE QCB       69800020
         LA    R1,LCBERB                LOAD ERB ADDR                   69850020
         MVI   LCBERBPY,PRIACTIV        SET PRI=PRIACTIV                69900020
         B     POST                     GOTO DSPPOST                    69950020
*                                                                       70000020
POSTMH   EQU   *                                                        70100020
*                                                                       70150020
         XC    LCBERBCH,LCBERBCH        CLEAR LCB CHAIN FIELD           70200020
         LR    R1,RPREF                 LOAD BUFFER ADDR                70340020
         L     R2,DCBMH-1               LOAD MH QCB ADDR                70410020
         MVI   PRFPRI,PRIMHBFR          SET PRIORITY                    70480020
*                                                                       70550020
         NC    LCBERBCT,LCBERBCT        IS ERB COUNT EXHAUSTED?         70620020
         BZ    POST                     YES, GO TPOST TO MH             70690020
*                                                                       70760020
         BAL   R14,POSTR                TPOST TO MH & COME BACK         70830020
         TM    LCBERBST,LCBEOMSG        IS IT END OF MSG                70837020
         BO    DISP                     YES, TSOUTPUT NEEDN'T REGAIN    70844020
*                                       CONTROL                         70851020
         L     RSCB,LCBSCBA-1           RESTORE RSCB AFTER DSPPOSTR     70860020
*                                                                       70900020
         TM    AYOSWTCH,SUBPCI          TEST IF SUBSEQUENT PCI          70970020
         BO    POSTAYO                  YES, GO TPOST TSOUTPUT          71040020
*                                                                       71110020
         L     RQCB,SCBDESTQ-1          RESTORE RQCB AFTER DSPPOSTR     71250020
         B     GETBASIC                 GO BUILD ANOTHER TCAM BFR       71320020
*                                                                       71390020
POSTAYO  EQU   *                                                        71460020
         LA    R2,AVTDSIOB              LOAD ADDR OF TSOUTPUT'S QCB     71530020
         LA    R1,LCBERB                LOAD ADDR OF ERB                71600020
         MVI   LCBERBPY,PRISBPCI        SET PRIORITY                    71670020
         B     POST                     GO TPOST ERB TO TSOUTPUT        71770020
*                                                                       72000020
*********************************************************************** 72050020
*                                                                       72100020
NOBFRS   EQU   *                                                        72150020
*                                                                       72200020
*********************************************************************** 72250020
*                                                                       72300020
*   IF TSOUTPUT RUNS OUT OF BASIC UNITS WHILE BUILDING TCAM BUFFERS,    72320020
*   IT PUTS THE ERB IN THE TOP OF THE ELEMENT CHAIN OF THE BUFFER       72340020
*   RETURN QCB TO WAIT FOR A BASIC UNIT TO BECOME AVAILABLE.  WHEN      72360020
*   ONE DOES, IT WILL BE TPOSTED TO TSOUTPUT AT ITS SECONDARY ENTRY     72380020
*   POINT, IEDAYO02.                                                    72400020
*                                                                       72450020
*********************************************************************** 72500020
*                                                                       72550020
         TM    LCBERBST,LCBINQ          TEST IF ERB ALREADY IN Q        72600020
         BO    CHCKBFF                  YES, DON'T PUT IN AGAIN         72650020
*                                                                       72700020
         OI    LCBERBST,LCBINQ          SHOW ERB ENQUEUED               72750020
         MVI   LCBERBPY,PRIDSKBF        SET PRI TO OBTAIN BFF FROM BFFR 72800020
*                                       RETURN                          72850020
*                                                                       72900020
         MVC   LCBERBLK(E3),AVTBFRTB+1  LINK ERB TO CURRENT FIRST ON Q  72950020
         LA    R1,LCBERB                LOAD ADDR OF THIS ERB           73000020
         ST    R1,AVTBFRTB              STORE IT INTO BFF RTN QCB       73050020
*                                                                       73100020
CHCKBFF  EQU   *                                                        73150020
*                                                                       73200020
DISP     EQU   *                                                        73220020
         L     R11,AVTEA                LOAD ADDR OF DISPATCHER         73240020
         B     DSPDISP                  EXIT TO TCAM DISPATCHER         73260020
*                                                                       73300020
*********************************************************************** 73350020
*                                                                       73400020
         CNOP  0,4                                                      73450020
*                                                                       73500020
*********************************************************************** 73550020
*                                                                       73600020
*********************************************************************** 73650020
*                                                                       73700020
IEDAYO02 EQU   *                                                        73750020
*                                                                       73800020
*********************************************************************** 73850020
*                                                                       73900020
*   STCB FOR SECOND ENTRY                                               73950020
*                                                                       74000020
         DC    AL1(DSPMCPL8),AL3(0),A(0)  STCB FIELDS            S22029 74050001
*                                                                       74200020
*********************************************************************** 74250020
*                                                                       74300020
*   SECOND ENTRY POINT                                                  74350020
*                                                                       74400020
*        INPUT - REG.1 - ADDR OF BASIC UNIT OR QCB                      74450020
*                REG.3 - ADDR OF STCB                                   74500020
*                REG.7 - ADDR OF CPB CLEAN-UP QCB                       74550020
*                REG.11 - ADDR OF DISPATCHER                            74600020
*                REG.13 - ADDR OF AVTSAVE2                              74650020
*                REG.15 - ENTRY ADDR                                    74700020
*                                                                       74750020
*        ELEMENT IS QCB - EXIT TO DSPBYPAS                              74800020
*                                                                       74850020
*        ELEMENT IS BASIC UNIT                                          74900020
*                A - IF LCBERROR IS 'ON' - POST THE BASIC UNIT AND      74950020
*                                          OTHER TCAM BUFFER TO BUFFER  75000020
*                                          RETURN.                      75050020
*                                  'OFF' - CONTINUE TO BUILD BUFFER     75100020
*                                                                       75150020
*        IF LCBTSBUF IS NOT 'ON' - EXIT TO DSPBYPAS                     75200020
*                                                                       75250020
*********************************************************************** 75300020
*                                                                       75350020
         USING *,R15                                                    75400020
         L     RBASE,BASE               INITIALIZE BASE                 75450020
         DROP  R15                                                      75500020
*                                                                       75550020
         LA    RQCB,0(RQCB)                                      S22029 75600001
         LA    R1,0(R1)                                          S22029 75605001
         LTR   R1,R1                    IS ELEMENT ADDRESS ZERO         75610020
         BZ    CPBCLNUP                 YES, GIVE CTL TO TCAM    S22029 75620001
*                                       CPB CLEANUP RTN                 75640001
         CLR   RQCB,R1                  IS ELEMENT CPB CLEANUP'S S22029 75660001
*                                       QCB                             75680001
         BNE   MUSTBEBU                 NO,MUST BE BASIC UNIT           75700020
*                                       WHEN CPB CLEANUP'S QCB          75750001
*                                       IS POSTED, EXIT TO CPB          75780001
*                                       CLEANUP                         75810001
*                                                                       75850020
*********************************************************************** 76100020
*                                                                       76150020
*   EXIT TO TCAM CPB CLEANUP/INIT ROUTINE                               76200001
*                                                                       76500020
*********************************************************************** 76550020
*                                                                       76600020
         DROP  R3                                                       76650020
         USING IEDQTSI,R3                                        S22029 76700001
CPBCLNUP EQU   *                                                 S22029 76710001
         L     R3,AVTTSOPT              PICKUP TSINPUT QCB       S22029 76720001
         L     R3,TSICPBC               PICKUP STCB ADDRESS OF   S22029 76730001
*                                       TCAM CPB CLEANUP RTN            76740001
         B     DSPBYPAS                 GO TO CPB CLEANUP        S22029 76750001
*                                                                       76760001
CPBINIT  EQU   *                                                 S22029 76770001
         L     R3,AVTTSOPT              PICKUP TSINPUT QCB       S22029 76780001
         L     R3,TSICPBI               PICKUP STCB ADDRESS OF   S22029 76790001
*                                       CPB INITIALIZATION RTN          76800001
         L     RQCB,0(,R1)              INSURE QCB POINTER OK   SS22029 76802001
         B     DSPBYPAS                 GO TO CPB INITIALIZATION S22029 76810001
*                                                                       76900020
*********************************************************************** 76950020
*                                                                       77000020
MUSTBEBU EQU   *                                                        77050020
*                                                                       77100020
*********************************************************************** 77150020
*                                                                       77200020
*                                                                       77250020
*   WHEN BASIC UNIT IS PASSED                                           77300020
*                                                                       77350020
*              1 - IF QCBTSSES IS 'OFF' - EXIT TO DSPBYPAS              77400020
*              2 - IF QCBTSSES IS 'ON'                                  77450020
*                   A - IF LCBERROR 'ON' - POST THE BASIC UNIT AND BFFR 77500020
*                                          IN CHAIN TO BFFR RETURN      77550020
*                   B - IF LCBERROR 'OFF'- CONTINUE TO BUILD BFFR       77600020
*                                                                       77650020
*********************************************************************** 77700020
*                                                                       77750020
         DROP  R3                                                       77800020
         USING IEDQSCB,R3                                               77850020
         LR    RPREF,R1                 LOAD ELEMENT ADDR               77900020
         L     RLCB,PRFLCB-1            LOAD ADDR OF LCB                77950020
         L     RSCB,LCBSCBA-1           LOAD SCB ADDR                   78000020
         TM    LCBSTAT1,LCBRCLLN+LCBRECVN RECALLING OR RECVING  SA64036 78010021
         BNZ   CPBCLNUP                 YES, TREAT AS NON-TSO   SA64036 78020021
         L     RQCB,SCBDESTQ-1          LOAD QCB ADDR                   78050020
*                                                                       78100020
         TM    QCBFLAG,QCBTSSES         TEST IF TSO IN SESSION          78150020
         BNO   CPBCLNUP                 GO TO CPB CLEANUP        S22029 78200001
*                                                                       78250020
         NI    LCBERBST,NOT-LCBINQ      ERB NO LONGER ENQUEUED          78270020
         TM    LCBERBST,LCBERROR        TEST IF ANY I/O ERROR OCCURRED  78300020
         BNO   BUGOTTEN                 NO,GOTO PROCESS THE BASIC UNIT  78350020
*                                                                       78420020
*   TPOST ERB TO RECALL, TPOST BASIC UNITS TO BUFFER RETURN.            78490020
*                                                                       78560020
         MVC   LCBERBQB,LCBRCQCB+1      GET RECALL QCB ADDR             78630020
         ST    RPREF,LCBERBLK-1         LINK ERB TO BASIC UNIT          78700020
         MVI   LCBERBPY,PRIRCQCB        SET RECALL PRIORITY             78770020
         LA    R1,LCBERB                POINT ELEMENT POINTER AT ERB    78840020
*                                                                       78910020
RETURNBU EQU   *                                                        78980020
         LA    R2,AVTBFRTB              GET ADDR OF BFR RETURN QCB      79120020
         ST    R2,PRFQCBA-1             PUT QCB ADDR IN ELEMENT         79190020
         MVI   PRFPRI,PRIBFRTB          SET PRIORITY                    79260020
*                                                                       79330020
         MVC   PRFLINK,LCBERBCH         LINK BFR CHAIN WITH B.U.        79400020
         NC    LCBERBCH,LCBERBCH        ANYTHING IN CHAIN               79470020
         BZ    CHAIN                    GO TPOST IF NOTHING IN CHAIN    79540020
*                                                                       79610020
         XC    LCBERBCH,LCBERBCH        CLEAR BFR CHAIN POINTER         79630020
*                                                                       79650020
RDYELEM  EQU   *                                                        79670020
         L     RPREF,PRFLINK-1          POINT AT NEXT BFR               79690020
         ST    R2,PRFQCBA-1             PUT QCB ADDR IN ELEM            79710020
         MVI   PRFPRI,PRIBFRTB          SET TPOST PRIORITY              79730020
*                                                                       79750020
         NC    PRFLINK,PRFLINK          LAST BFR IN CHAIN               79770020
         BZ    CHAIN                    YES, GO TPOST                   79790020
         B     RDYELEM                  CONTINUE MAKING ELEMENTS        79810020
*                                       READY TO TPOST                  79830020
*                                                                       80000020
*********************************************************************** 80050020
*                                                                       80100020
BUGOTTEN EQU   *                                                        80150020
*                                                                       80200020
*   IF ATTENTION HAS BEEN HIT, FREE ALL BASIC UNITS ASSOCIATED          80260020
*   WITH THIS REQUEST.                                                  80320020
*                                                                       80400020
         TM    SCBERR3,SCBATTN          TEST IF ATTN HIT                80450020
         BO    RETURNBU                 YES, GO RETURN ALL BASIC UNITS  80750020
*                                                                       81200020
         TM    AVTBIT3,AVTTSAB          TEST IF TSO HAS ABENDED  A44839 81210021
         BO    TESTRQST                 YES, CHECK FOR INIT      A44839 81220021
*                                       REQUEST                  A44839 81230021
         BAL   R14,TSBADDR              GOTO GET TSB ADDR               81250020
*                                                                       81300020
         LR    R5,RPREF                 POINT TO NEWEST BASIC UNIT      81320020
         B     CHKCHAIN                 GOTO BUILD TCAM BFFR RTN        81350020
*                                                                       81400020
*   WHEN TSO HAS ABENDED, IF IT IS AN INITIAL REQUEST, FREE ALL BASIC   81403021
*   UNITS, IF IT IS A PCI REQUEST, TERMINATE SEND OPERATION AND SET     81406021
*   UP TO SEND 1 IDLE                                                   81409021
*                                                                       81412021
TESTRQST EQU   *                                                 A44839 81415021
         TM    AYOSWTCH,INTLRQ          CHECK FOR INITIAL        A44839 81418021
*                                       REQUEST                  A44839 81421021
         BO    RETURNBU                 YES, RETURN ALL BASIC    A44839 81424021
*                                       UNITS                    A44839 81427021
         XC    AYOTSBFF(E4),AYOTSBFF    RESET TS BUFFER POINTER  A44839 81430021
         OI    AYOSWTCH,SENDNL          SET TO SEND 1 DUMMY IDLE A44839 81433021
*                                       CHAR                     A44839 81436021
         B     CHKCHAIN                 GOTO BUILD TCAM BFR RTN  A44839 81439021
*********************************************************************** 81450020
*                                                                       81500020
*                                                                       81550020
*********************************************************************** 81600020
*                                                                       81650020
POSTR    EQU   *                                                        81700020
*                                                                       81750020
*********************************************************************** 81800020
*                                                                       81850020
*   EXIT TO TCAM - DSPPOSTR (SEE TDISPD DSECT)                          81900020
*                                                                       81950020
*        AT RETURN REG.3 AND 7 MAY BE DESTROYED                         82000020
*                                                                       82050020
*********************************************************************** 82100020
*                                                                       82150020
         ST    R2,PRFQCBA-1-IEDQPRF(R1) STORE QCB ADDR                  82200020
         L     R11,AVTEA                LOAD ADDR OF DISPATCHER         82250020
         B     DSPPOSTR                 GOTO DISPATCHER TO POST AND RTN 82300020
*                                                                       82350020
*********************************************************************** 82400020
*                                                                       82450020
*                                                                       82500020
*********************************************************************** 82550020
*                                                                       82600020
POST     EQU   *                                                        82650020
*                                                                       82700020
*********************************************************************** 82750020
*                                                                       82800020
*   EXIT TO TCAM - DSPPOST (SEE TDISPD DSECT)                           82850020
*                                                                       82900020
*********************************************************************** 82950020
*                                                                       83000020
         ST    R2,PRFQCBA-1-IEDQPRF(R1) STORE QCB ADDR                  83050020
         L     R11,AVTEA                LOAD ADDR OF DISPATCHER         83100020
         B     DSPPOST                  GOTO TCAM DSPPOST               83150020
*                                                                       83200020
*********************************************************************** 83250020
*                                                                       83300020
CHAIN    EQU   *                                                        83350020
*                                                                       83400020
*********************************************************************** 83450020
*                                                                       83500020
*   EXIT TO TCAM - DSPCHAIN (SEE TDISPD DSECT)                          83550020
*                                                                       83600020
*********************************************************************** 83650020
*                                                                       83700020
         L     R11,AVTEA                LOAD ADDR OF DISPATCHER         83800020
         B     DSPCHAIN                 GOTO TCAM DSPCHAIN              83850020
*                                                                       83900020
*********************************************************************** 83950020
*                                                                       84000020
*                                                                       84050020
*********************************************************************** 84100020
*                                                                       84150020
TSBADDR  EQU   *                                                        84200020
*                                                                       84250020
*********************************************************************** 84300020
*                                                                       84350020
*   OBTAIN TSB ADDR IN RTSB & TIOCRPT ADDR IN R10                       84400020
*                                                                       84450020
*********************************************************************** 84500020
*                                                                       84550020
         L     R10,CVTPTR               LOAD CVT ADDR                   84600020
         DROP  R10                                                      84650020
         USING CVT,R10                                                  84700020
         L     R10,CVTTSCVT             LOAD TSCVT ADDR                 84750020
         USING TSCVT,R10                                                84800020
         LH    R15,TSCVTSZU             LOAD TJB SIZE                   84850020
         MH    R15,QCBTJID              TJID * TJB SIZE = OFFSET        84900020
         A     R15,TSCVTTJB             OFFSET + START ADDR             84950020
         L     RTSB,TJBTSB-TJB(R15)     LOAD TSB ADDR                   85000020
         L     R10,TSCVTRPT             LOAD TIOCRPT ADDR               85050020
         MVC   AYOSRCE,TSBASRCE         SAVE TERMINAL INDEX      M1193  85070021
         BR    R14                      RETURN TO CALLER                85100020
*                                                                       85150020
*********************************************************************** 85200020
*                                                                       85250020
*                                                                       85300020
*********************************************************************** 85350020
*                                                                       85400020
*   CONSTANTS                                                           85450020
*                                                                       85500020
*********************************************************************** 85550020
*                                                                       85600020
BASE     DC    A(TSOUTPUT)              BASE ADDR OF IEDAYO             85650020
*                                                                       85700020
*   MASKS TO SET INDICATORS FOR CALL TO IEDAYE (OUTPUT EDIT).           85740020
*                                                                       85780020
TSOMSGC  DC    X'80000000'              INDICATES A TSO MESSAGE         85820020
TSOASISC DC    X'20000000'              INDICATES ASIS OPTION           85860020
TSOCNTLC DC    X'40000000'              INDICATES CONTROL OPTION        85900020
*                                                                       85950020
*                                                                       86100020
ZEROS    DC    F'0'                     CONSTANT = '0'                  86150020
AYOPATCH DC    20F'0'                                            S22029 86170001
         DS    0F                                                       86200020
INVLDTIC DC    X'08000002'              INVALID TIC CCW                 86250020
*                                                                       86350020
AUTOMSK  DC    X'01088000',A(AUTOLNNO)  MSGGEN MASK FOR AUTO LINE NO.   86360020
ABNDMSK  DC    X'01088000',A(ABENDMSG)  MSGGEN MASK FOR ABEND MSG       86370020
MSKOCAB  DC    X'01088000',A(MSGOCAB)   MSGGEN MASK                     86380020
MSKRNAV  DC    X'01088000',A(MSGRNAV)   MSGGEN MASK                     86390020
*                                                                       86410020
X0100    DC    X'0100'                  MSGGEN INDICATOR                86420020
*                                                                       86430020
MSGOCAB  DC    AL1(L'MOCAB+1)           MESSAGE LENGTH                  86440020
MOCAB    DC    C'IKJ54003I SYSTEM FAILURE - PLEASE LOGON AGAIN'  MSG    86450020
         DC    X'15'                    NEW LINE CHARACTER              86460020
MSGRNAV  DC    AL1(L'MRNAV+1)           MESSAGE LENGTH                  86470020
MRNAV    DC    C'IKJ54002I LOGON FAILED - RESOURCES NOT NOW AVAILABLE'  86480020
         DC    X'15'                    NEW LINE CHARACTER              86490020
AUTOLNNO DC    X'01FF'                  AUTO LINE NO.                   86550020
ABENDMSG DC    AL1(L'MABEND+1)          MESSAGE LENGTH                  86570020
MABEND   DC    C'IKJ54001I SYSTEM FAILURE - ALL USERS TERMINATED' MSG   86590020
         DC    X'15'                    NEW LINE CHARACTER              86610020
*                                                                       86650020
*********************************************************************** 86700020
*                                                                       86750020
         EJECT                                                          86800020
         TAVTD                                                          86850020
         EJECT                                                          86900020
         IKJTIOCB                                                       86950020
         EJECT                                                          87000020
CVT      DSECT                                                          87050020
         CVT                                                            87100020
         EJECT                                                          87150020
         DCBD  DSORG=TX                                                 87200020
         EJECT                                                          87250020
         TDISPD                                                         87300020
         EJECT                                                          87350020
         TLCBD                                                          87400020
         EJECT                                                          87450020
         TPRFD                                                          87500020
         EJECT                                                          87550020
         TPRIOR                                                         87600020
         EJECT                                                          87650020
         TQCBD                                                          87700020
         EJECT                                                          87750020
         TSCBD                                                          87800020
         EJECT                                                          87850020
         TSTCBD                                                         87900020
         EJECT                                                          87950020
         IKJTIOCP                                                       88000020
         EJECT                                                          88050020
         IKJTJB                                                         88100020
         EJECT                                                          88110021
         TTNTD                                                          88120021
         EJECT                                                          88150020
         TTRMD                                                          88200020
         EJECT                                                          88250020
         IKJTSB                                                         88300020
         EJECT                                                          88350020
         IKJTSCVT                                                       88400020
         EJECT                                                          88550020
         TTSID                                                          88600020
         EJECT                                                          88650020
*                                                                       88700020
*******************************************************************     88750020
*                                                                       88800020
*   TSOUTPUT'S WORK AREA                                                88850020
*                                                                       88900020
*******************************************************************     88950020
AYOWRKL  EQU   24                       LENGTH OF WORK AREA             88970021
AYOSWTCH EQU   SCBSRCE                  SWITCHES                        89000020
*                                                                       89050020
MSGCHAIN EQU   X'80'                    3270 MSG-CHAIN IN PROG. SA61765 89080021
STAUT    EQU   X'40'                    START AUTMOATIC PRMPTING M0141  89120021
CHAINEND EQU   X'20'                    3270 MSG-CHAIN ENDED    SA61765 89160021
SENDNL   EQU   X'10'                    SEND 'NL' AND 'EOT'             89200020
SUBPCI   EQU   X'08'                    SUBSEQUENT PCI REQUEST          89250020
INTLRQ   EQU   X'04'                    THIS IS INTIAL REQUEST          89300020
INTLPCI  EQU   X'02'                    INITIAL PCI REQUEST             89350020
*                                                                       89450020
AYORC    EQU   SCBSRCE+1                SAVE AREA FOR RETURN    YM2814  89460000
*                                       CODE                    YM2814  89470000
*                                                                       89500020
AYOBULEN EQU   SCBSRCE+2                NO. OF BYTES AVAILABLE  YS6327  89550021
*                                       IN CURRENT BASIC UNIT   YS6327  89600021
*                                                                       89650020
AYOTSBFF EQU   SCBSRCE+4                ADDR OF LAST TS BUFFER FROM     89700020
*                                       WHICH A DATA HAS BEEN MOVED     89750020
*                                                                       89800020
AYOHDRBU EQU   SCBSRCE+8                ADDR OF LAST HDR B.U. IN CHAIN  89850020
*                                                                       89900020
AYOLSTBU EQU   SCBSRCE+12               ADDR OF B.U. IN CHAIN           89950020
*                                                                       90000020
AYOSRCE  EQU   SCBSRCE+16               TERMINAL INDEX                  90100020
*                                                                       90200020
AYONXTCH EQU   SCBSRCE+20               POINTER TO NEXT AVAIL   YS6327  90210021
*                                       BYTE IN CURRENT B.U.    YS6327  90220021
*                                                                       90230021
PREFL    EQU   PRFSHDR-IEDQPRF          LENGTH OF BUFFER PREFIX  S22029 90250001
*                                                                       90300020
*********************************************************************** 90350020
*                                                                       90400020
         END                                                            90450020
