         TITLE 'IEDAYT - ABEND INTERFACE SUBTASK.'                      00600022
IEDAYT   CSECT                                                          00601022
*C007890,060000                                                  S22029 00602022
*D007960-008100,008940-009290,040000-052000,636000-708000        S22029 00604022
*C006000,240000,328000,420000,488000,724000-784000,800000-824000,S21903 00605022
*C844000                                                         S21903 00606022
*********************************************************************** 00607020
*TITLE  'IEDAYT'  ABEND INTERFACE SUBTASK                             * 00614020
*                                                                     * 00621020
*STATUS -- CHANGE LEVEL 20.0                                          * 00628020
*                                                                     * 00635020
*FUNCTION -- THE ABEND INTERFACE SUBTASK INFORMS TSO WHEN TCAM        * 00642020
*   ABENDS, WHEN AN ATTACHED TCAM SUBTASK ABENDS, OR WHEN, IN A       * 00649020
*   MIXED TSO/TCAM ENVIRONMENT, THE EXCP DRIVER ABENDS BECAUSE NO     * 00656020
*   SPACE IS AVAILABLE ON A NON-REUSABLE DISK QUEUE AND A FLUSH       * 00663020
*   CLOSEDOWN HAS BEEN INITIATED.                                     * 00670020
*      WHEN TCAM ABENDS, THIS SUBTASK ISSUES THE TCABEND MACRO IN-    * 00677020
*   STRUCTION, WHICH SETS OFF THE TCAM READY BIT IN THE CVT.  IF THE  * 00684020
*   CVTTSRDY BIT IN CVTTSFLG IS ON, INDICATING THAT TSO IS ACTIVE,    * 00691020
*   THE TCABEND MACRO INSTRUCTION ALSO INDICATES THAT THE TIME        * 00698020
*   SHARING CONTROLLER TASK IS TO STOP BY SETTING ON THE TSCASTOP BIT * 00705020
*   IN THE TIME SHARING CVT, AND BY POSTING THE TIME SHARING CON-     * 00712020
*   TROLLER'S ECB IN TSECBTAB COMPLETE.                               * 00719020
*      WHEN AN ATTACHED TCAM SUBTASK ABENDS, THE ABEND INTERFACE      * 00726020
*   SUBTASK GETS ALL ELEMENTS THAT ARE POSTED TO THE ABENDING SUBTASK * 00733020
*   FROM THE READY QUEUE AND THE SUBTASK'S QCB AND DISPOSES OF THEM.  * 00740020
*   IF THE ABENDING SUBTASK IS EITHER CHECKPOINT OR ON-LINE TEST,     * 00747020
*   THIS SUBTASK ALSO CLEARS THE QCB STCB LINK ADDRESS, SETS THE      * 00754020
*   QCB'S ELEMENT CHAIN TO POINT TO THE DUMMY LAST ELEMENT ADDRESS IN * 00761020
*   THE AVT, AND RESETS THE QCB FLAG INDICATING THAT IT IS A QCB.     * 00768020
*   THESE FUNCTIONS ARE PERFORMED TO INDICATE THAT THE ABENDING SUB-  * 00775020
*   TASK NO LONGER EXISTS.  IF THE ABENDING SUBTASK IS OPERATOR CON-  * 00782020
*   TROL, THE ABEND INTERFACE SUBTASK                                 * 00789022
*   ISSUES THE AQCTL SVC (SVC 102) TO POST THE ABEND ROUTINE'S ECB TO * 00817020
*   THE READY QUEUE.  IT ALSO ISSUES THE TCABEND MACRO INSTRUCTION,   * 00824020
*   WHICH PERFORMS THE SAME FUNCTIONS AS WHEN TCAM ABENDS.            * 00831020
*                                                                     * 00838020
*ENTRY POINTS -- IEDAYT0 - ON RECEIVING CONTROL WHEN TCAM ABENDS.     * 00845020
*   CALLING SEQUENCE          L    R15,'STAE EXIT ADDRESS'            * 00852020
*                             BALR R14,R15                            * 00859020
*   IEDAYT1 - ON RECEIVING CONTROL WHEN AN ATTACHED TCAM SUBTASK      * 00866020
*   ABENDS.                                                           * 00873020
*   CALLING SEQUENCE          L    R15,'STAE EXIT ADDRESS'            * 00880020
*                             BALR R14,R15                            * 00887020
*                                                                     * 00936020
*INPUT -- IEDAYT, WHEN SPECIFIED AS THE ABNORMAL EXIT ROUTINE ON A    * 00943020
*   STAE MACRO INSTRUCTION, IS CALLED BY THE ABEND/STAE INTERFACE     * 00950020
*   ROUTINE OF THE OS SUPERVISOR WHEN TCAM, AN ATTACHED TCAM SUBTASK, * 00957020
*   OR, IN A MIXED TSO/TCAM ENVIRONMENT, THE EXCP DRIVER ABENDS.  AT  * 00964020
*   ENTRY THE FOLLOWING REGISTERS ARE SET.                            * 00971020
*   R1 HAS THE ADDRESS OF THE 104-BYTE STAE WORK AREA, WHICH CONTAINS * 00978020
*      THE ENTRY POINT ADDRESS IN THE ABENDING PROGRAM.               * 00985020
*   R13 HAS THE ADDRESS OF A SUPERVISOR-PROVIDED REGISTER SAVE AREA.  * 00992020
*   R14 HAS THE RETURN ADDRESS (AN SVC 3 INSTRUCTION).                * 00999020
*   R15 HAS THE ENTRY POINT ADDRESS.                                  * 01006020
*                                                                     * 01013020
*OUTPUT -- ON LINKING TO THE AQCTL SVC 102 ROUTINE, REGISTER 1 CON-   * 01020020
*   TAINS THE ADDRESS OF THE AQCTL PARAMETER LIST.  ON RETURNING TO   * 01027020
*   THE CALLING ROUTINE, REGISTER 15 CONTAINS THE RETURN CODE.        * 01034020
*                                                                     * 01041020
*EXTERNAL ROUTINES -- THE TCABEND (SVC 94) ROUTINE - TO SET OFF THE   * 01048020
*   TCAM READY BIT AND STOP THE TIME SHARING CONTROLLER.              * 01055020
*   IGC102 - TO POST THE ABEND ROUTINE'S ECB TO THE READY QUEUE.      * 01062020
*                                                                     * 01069020
*EXITS-NORMAL -- TO THE ABEND/STAE INTERFACE ROUTINE AT THE SVC 3     * 01076020
*   INSTRUCTION FOLLOWING THE STAE MACRO INSTRUCTION NAMING IEDAYT    * 01083020
*   AS ABNORMAL EXIT ROUTINE.                                         * 01090020
*                                                                     * 01097020
*EXITS-ERROR -- NONE                                                  * 01104020
*                                                                     * 01111020
*TABLES/WORKAREAS -- AVT, QCB, CVT, TSID, STAE WORK AREA.             * 01118020
*                                                                     * 01125020
*ATTRIBUTES -- SERIALLY REUSABLE, ENABLED, PROBLEM PROGRAM MODE.      * 01132020
*                                                                     * 01139020
*NOTES -- THE OPERATION OF THIS MODULE DOES NOT DEPEND UPON A         * 01146020
*   PARTICULAR INTERNAL REPRESENTATION OF THE EXTERNAL CHARACTER      * 01153020
*   SET.                                                              * 01160020
*                                                                     * 01167020
*********************************************************************** 01174020
         SPACE 2                                                        01200020
         USING IEDQAVTD,RAVT                                            01600020
         USING IEDQQCB,RQCB                                             02000020
         USING *,REG15                                                  02400020
         B     IEDAYT0                  ENTRY POINT FOR STAE EXITS      02800020
         USING *,REG15                                                  03200020
         B     IEDAYT1                  ENTRY POINT FOR STAI EXITS      03600020
         DROP  REG15                    DROP REGISTER 15 AS BASE        05600020
IEDAYT   IEDHJN                                                         06000022
         SPACE 2                                                        06400020
*  THE FOLLOWING ROUTINE IS ENTERED WHEN TCAM ABENDS.                   06800020
         SPACE 2                                                        07200020
         USING IEDAYT,REG15                                             07600020
         DS    0H                                                       08000020
IEDAYT0  EQU   *                                                        08400020
         TCABEND                                                        08800020
         SPACE 2                                                        09200020
         SR    REG15,REG15              CLEAR RETRUN CODE REGISTER      09600020
         BR    RETURN                   RETURN                          10000020
         SPACE 2                                                        10400020
*  THE FOLLOWING ROUTINE IS ENTERED WHEN AN ATTACHED SUBTASK ABENDS.    10800020
         SPACE 2                                                        11200020
         DS    0H                                                       11600020
IEDAYT1  EQU   *                                                        12000020
         BALR  RBAS,0                   LOAD BASE REGISTER              12400020
         USING *,RBAS                   SET UP ADDRESSABILITY           12800020
         STC   REG0,NTRYCODE            STORE ENTRY CODE FOR TEST       13200020
         CLI   NTRYCODE,CODEX0C         IS CODE X'0C'                   13600020
         BE    AYTOUT                   BRANCH ON YES                   14000020
         L     RCVT,CVTPTR              ADDRESS OF CVT                  14400020
         L     RAVT,AVTCVTPT(RCVT)      ADDRESS OF AVT ADDRESS          14800020
         L     RAVT,AVTEZERO(RAVT)      ADDRESS OF AVT                  15200020
         L     RDSP,AVTEA               GET ADDRESS OF TCAM DISPATCHER  15600020
         USING IEDQDISP,RDSP                                            16000020
         L     RPRG,96(REG1)            ADDRESS OF ABENDING ROUTINE     16400020
         LA    RPRG,0(RPRG)             CLEAR HIGH ORDER BYTE           16800020
         L     RVCN,AVTCKPTB+8          ADDRESS OF CHECK POINT ROUTINE  17200020
         LA    RVCN,0(RVCN)             CLEAR HIGH ORDER BYTE           17600020
         CR    RPRG,RVCN                IS CHECK POINT ABENDING         18000020
         BE    AYT101                   YES, BRANCH                     18400020
         L     RVCN,AVTOPCOB+8          ADDRESS OF OPER CONTROL ROUT    18800020
         LA    RVCN,0(RVCN)             CLEAR HIGH ORDER BYTE           19200020
         CR    RPRG,RVCN                IS OPER CONTROL ABENDING        19600020
         BE    AYT102                   YES, BRANCH                     20000020
         L     RVCN,AVTOLTQB+8          ADDRESS OF ONLINE TEST ROUTINE  20400020
         LA    RVCN,0(RVCN)             CLEAR HIGH ORDER BYTE           20800020
         CR    RPRG,RVCN                IS ONLINE TEST ABENDING         21200020
         BE    AYT103                   YES, BRANCH                     21600020
         B     AYTOUT                   NONE OF ABOVE, RETURN           22000020
         SPACE 2                                                        22400020
*  THE CHECKPOINT SUBTASK IS ABENDING                                   22800020
         SPACE 2                                                        23200020
AYT101   LA    RQCB,AVTCKPTB            ADDRESS OF CHECK POINT QCB      23600020
         BAL   RLNK,AYT104              BRANCH TO CHECK QCB      S21903 24000022
         SPACE 2                                                        24400020
*  LCB'S, BUFFERS, AND SPECIAL ELEMENTS MAY BE POSTED TO CHECK POINT    24800020
         SPACE 2                                                        25200020
AYT141   CLI   0(RELE),ZERO             IS FIRST BYTE ZERO              25600020
         BE    AYT111                   YES, ELEMENT IS LCB             26000020
         TM    8(RELE),CCWTIC           IS TIC COMMAND PRESENT          26400020
         BO    AYT121                   YES, ELEMENT IS BUFFER          26800020
*  OTHERWISE IT IS SPECIAL ELEMENT AND IS IGNORED                       27200020
AYT131   L     RELE,4(RELE)             GET ADDRESS NEXT ELEMENT        27600020
         LA    RELE,0(RELE)             CLEAR HIGH ORDER BYTE           28000020
         LTR   RELE,RELE                IS ELEMENT LINK ZERO            28400020
         BZ    AYTOUT                   YES, RETURN                     28800020
         B     AYT141                   BRANCH TO CHECK ELEMENT         29200020
AYT111   BAL   RLNK,AYT201              DISPOSE OF LCB                  29600020
         B     AYT131                   CHECK NEXT ELEMENT              30000020
AYT121   BAL   RLNK,AYT301              DISPOSE OF BUFFER               30400020
         B     AYT131                   CHECK NEXT ELEMENT              30800020
         SPACE 2                                                        31200020
*  THE OPERATOR CONTROL SUBTASK IS ABENDING                             31600020
         SPACE 2                                                        32000020
AYT102   LA    RQCB,AVTOPCOB            ADDRESS OF OPER CONTROL QCB     32400020
         BAL   RLNK,AYT104              BRANCH TO CHECK QCB      S21903 32800022
         SPACE 2                                                        33200020
*  LCB'S, BUFFERS, AND SPECIAL ELEMENTS MAY BE POSTED TO OPERATOR       33600020
*  CONTROL                                                              34000020
         SPACE 2                                                        34400020
AYT151   CLI   4(RELE),LCBPRI           IS PRIORITY X'E8'               34800020
         BE    AYT161                   YES, ELEMENT IS LCB             35200020
         TM    8(RELE),CCWTIC           IS TIC COMMAND PRESENT          35600020
         BO    AYT171                   YES, ELEMENT IS BUFFER          36000020
*  OTHERWISE IT IS SPECIAL ELEMENT AND IS IGNORED                       36400020
AYT181   L     RELE,4(RELE)             GET ADDRESS NEXT ELEMENT        36800020
         LA    RELE,0(RELE)             CLEAR HIGH ORDER BYTE           37200020
         LTR   RELE,RELE                IS ELEMENT LINK ZERO            37600020
         BZ    AYTOUT                   YES, RETURN                     38000020
         B     AYT151                   BRANCH TO CHECK ELEMENT         38400020
AYT161   BAL   RLNK,AYT201              DISPOSE OF LCB                  38800020
         B     AYT181                   CHECK NEXT ELEMENT              39200020
AYT171   BAL   RLNK,AYT301              DISPOSE OF BUFFER               39600020
         B     AYT181                   CHECK NEXT ELEMENT              40000020
         SPACE 2                                                        40400020
*  THE ONLINE TEST SUBTASK IS ABENDING                                  40800020
         SPACE 2                                                        41200020
AYT103   LA    RQCB,AVTOLTQB            ADDRESS OF ONLINE TEST QCB      41600020
         BAL   RLNK,AYT104              BRANCH TO CHECK QCB      S21903 42000022
         SPACE 2                                                        42400020
*  BUFFERS ONLY ARE POSTED TO ONLINE TEST                               42800020
         SPACE 2                                                        43200020
AYT191   BAL   RLNK,AYT301              DISPOSE OF BUFFER               43600020
         L     RELE,4(RELE)             GET ADDRESS NEXT ELEMENT        44000020
         LA    RELE,0(RELE)             CLEAR HIGH ORDER BYTE           44400020
         LTR   RELE,RELE                IS ELEMENT LINK ZERO            44800020
         BNZ   AYT191                   CHECK NEXT ELEMENT              45200020
         L     RWRK,AVTTSOPT            ADDRESS OF TSINPUT MACRO        45600020
         USING IEDQTSI,RWRK                                             46000020
         LA    RWRK,TSIABEND            ADDRESS OF ABEND ROUTINE ECB    46400020
         ST    RWRK,AQCTLIST            ECB ADDRESS FOR AQCTL           46800020
         MVI   AQCTLIST,AQCTLPST        INDICATE POST TO AQCTL          47200020
         LA    REG1,AQCTLIST            ADDRESS OF PARAMETER LIST       47600020
         AQCTL                          POST ABEND ROUTINE ECB          48000020
         TCABEND                                                        48400020
         B     AYTOUT                   BRANCH TO EXIT           S21903 48800022
AYT104   ST    RQCB,QCBSTCHN-1          STCB ADDRESS POINTS TO QCB      49200020
         XC    QCBLINK-1(4),QCBLINK-1   CLEAR QCB STCB LINK ADDRESS     49600020
         LA    RWRK,AVTDELEM            ADDRESS OF DUMMY ELEMENT        50000020
         L     RELE,QCBELCHN-1          ADDRESS OF FIRST ELEMENT        50400020
*                                       IN CHAIN                        50800020
         LA    RELE,0(RELE)             CLEAR HIGH ORDER BYTE           51200020
         CR    RWRK,RELE                IS ELEMENT DUMMY ELEMENT        51600020
         BE    0(RLNK)                  YES, RETURN                     52000020
         ST    RWRK,QCBELCHN-1          ELEMENT CHAIN POINTS TO         52400020
*                                       DUMMY ELEMENT                   52800020
         MVI   QCBDSFLG,QCBFQCB         RESTORE QCBDSFLG                53200020
         BR    RLNK                     RETURN                          53600020
         SPACE 2                                                        54000020
*  DISPOSE OF LCB'S                                                     54400020
         SPACE 2                                                        54800020
AYT201   LR    RHLD,RLNK                SAVE RETURN ADDRESS             55200020
         ST    RELE,0(RELE)             LCB POSTED TO ITSELF            55600020
         MVI   4(RELE),PRIORITY         SET POST PRIORITY               56000020
         LR    REG1,RELE                ADDRESS OF ELEMENT TO BE POSTED 56400020
         BAL   RLNK,DSPPOSTR            LINK TO DISPATCHER              56800020
         LR    RLNK,RHLD                RESTORE RETURN REG              57200020
         BR    RLNK                     RETURN                          57600020
         SPACE 2                                                        58000020
*  DISPOSE OF BUFFERS                                                   58400020
         SPACE 2                                                        58800020
AYT301   LR    RHLD,RLNK                SAVE RETURN REG                 59200020
         LA    RWRK,AVTBFRTB            ADDRESS OF BUFFER RETURN        59600020
         ST    RWRK,0(RELE)             BUFFER POSTED TO BUFFER RETURN  60000020
         MVI   4(RELE),PRIORITY         SET POST PRIORITY               60400020
         LR    REG1,RELE                ADDRESS OF ELEMENT TO BE POSTED 60800020
         BAL   RLNK,DSPPOSTR            LINK TO DISPATCHER              61200020
         LR    RLNK,RHLD                RESTORE RETURN REG              61600020
         BR    RLNK                     RETURN                          62000020
AYTOUT   SR    REG15,REG15              CLEAR RETURN CODE REGISTER      62400020
         BR    RETURN                   RETURN                          62800020
         SPACE 2                                                        63200020
         SPACE 2                                                        71200020
*  REGISTER EQUATES.                                                    71600020
         SPACE 2                                                        72000020
REG0     EQU   0                        REGISTER EQUATE          S21903 72400022
REG1     EQU   1                        REGISTER EQUATE          S21903 72800022
RCVT     EQU   2                        REGISTER EQUATE          S21903 73200022
RAVT     EQU   3                        REGISTER EQUATE          S21903 73600022
RPRG     EQU   4                        REGISTER EQUATE          S21903 74000022
RVCN     EQU   5                        REGISTER EQUATE          S21903 74400022
RQCB     EQU   6                        REGISTER EQUATE          S21903 74800022
RWRK     EQU   7                        REGISTER EQUATE          S21903 75200022
RELE     EQU   8                        REGISTER EQUATE          S21903 75600022
RHLD     EQU   9                        REGISTER EQUATE          S21903 76000022
RLNK     EQU   10                       REGISTER EQUATE          S21903 76400022
RDSP     EQU   11                       REGISTER EQUATE          S21903 76800022
RBAS     EQU   12                       REGISTER EQUATE          S21903 77200022
RSAV     EQU   13                       REGISTER EQUATE          S21903 77600022
RETURN   EQU   14                       REGISTER EQUATE          S21903 78000022
REG15    EQU   15                       REGISTER EQUATE          S21903 78400022
         SPACE 2                                                        78800020
*  OTHER EQUATES.                                                       79200020
         SPACE 2                                                        79600020
ZERO     EQU   X'00'                    CONSTANT EQUATE          S21903 80000022
AQCTLPST EQU   X'02'                    FLAG EQUATE              S21903 80400022
CCWTIC   EQU   X'08'                    CCWTIC EQUATE            S21903 80800022
CODEX0C  EQU   X'0C'                    FLAG EQUATE              S21903 81200022
PRIORITY EQU   X'E4'                    PRIORITY EQUATE          S21903 81600022
LCBPRI   EQU   X'E8'                    PRIORITY EQUATE          S21903 82000022
CVTPTR   EQU   16                       CVT EQUATE               S21903 82400022
         SPACE 2                                                        82800020
*  CONSTANTS.                                                           83200020
         SPACE 2                                                        83600020
AQCTLIST DC    A(0),XL1'80',AL3(0)      PARAMETER LIST FOR AQCTL        84000020
NTRYCODE DC    X'00'                    ENTRY CODE STORAGE       S21903 84400022
         TAVTD                                                          84800020
         TQCBD                                                          85200020
         TTSID                                                          85600020
         TDISPD                                                         86000020
         END                                                            86400020
