         TITLE 'IEDAYX - TSO LINKOR ROUTINE'                            01000020
IEDAYX   CSECT                                                          02000020
*A330000                                                         S22029 02003022
*C370000-390000                                                  S22029 02006022
*C115800-315800                                                  S21903 02008022
*D500000                                                         S21903 02009022
*********************************************************************** 02010020
*TITLE  'IEDAYX'  TSO INMSG/OUTMSG LINKER                             * 02020020
*                                                                     * 02030020
*STATUS -- CHANGE LEVEL 20.0                                          * 02040020
*                                                                     * 02050020
*FUNCTION -- THE TSO INMSG/OUTMSG LINKER PROVIDES LINKAGE TO THE      * 02060020
*   ATTEN AND HANGUP ROUTINES (IEDQATTN AND IEDAYH, RESPECTIVELY).    * 02070020
*   IF LINKAGE IS TO HANGUP, THE ROUTINE ADDRESS IS GOTTEN FROM THE   * 02080020
*   MACRO EXPANSION PASSED TO THIS ROUTINE.  FOR LINKAGE TO ATTEN,    * 02090020
*   THE ROUTINE ADDRESS IS GOTTEN FROM THE STARTMH MACRO POINTED TO   * 02100020
*   IN THE DCB.  BEFORE BRANCHING TO THE ROUTINE, THE ERB PRIORITY    * 02110020
*   IS SET, AND THE ERB IS POSTED TO BUFFER DISPOSITION.              * 02120020
*                                                                     * 02130020
*ENTRY POINT -- IEDAYX - TO PROVIDE LINKAGE TO THE ATTEN OR HANGUP    * 02140020
*   ROUTINE WHEN ATTEN OR HANGUP MACRO INSTRUCTIONS ARE CODED IN THE  * 02150020
*   INMSG OR OUTMSG SUBGROUPS.                                        * 02160020
*   CALLING SEQUENCE          L    R12,AVTMSGS+OFFSET                 * 02170020
*                             BR   R12                                * 02180020
*                                                                     * 02190020
*INPUT -- IEDAYX IS CALLED BY BUFFER DISPOSITION WHEN ATTEN OR        * 02200020
*   HANGUP MACRO INSTRUCTIONS ARE CODED IN THE INMSG OR OUTMSG        * 02210020
*   SUBGROUPS, WITH THE FOLLOWING REGISTERS SET.                      * 02220020
*   R1 HAS THE ADDRESS OF A LIST OF THINGS TO BE POSTED, OR ZERO      * 02230020
*   R3 HAS THE SCB ADDRESS                                            * 02240020
*   R4 HAS THE LCB ADDRESS                                            * 02250020
*   R8 HAS THE ADDRESS OF THE MACRO EXPANSION                         * 02260020
*   R11 HAS THE DISPATCHER ADDRESS                                    * 02270020
*   R12 HAS THE ENTRY POINT ADDRESS                                   * 02280020
*   R13 HAS THE ADDRESS OF AVTSAVE2                                   * 02290020
*                                                                     * 02300020
*   FORMAT OF MACRO EXPANSION:                                        * 02310020
*   BYTE 1 -- X'02' = RECALL NECESSARY                                * 02320020
*             X'01' = UNCONDITIONAL EXECUTION                         * 02330020
*   BYTE 2 -- LENGTH OF MACRO EXPANSION                               * 02340020
*             X'01' = AND FUNCTION, AS OPPOSED TO OR FUNCTION         * 02350020
*   BYTE 3 -- X'02' = ADDRESS OF ROUTINE IN MACRO EXPANSION           * 02360020
*             X'01' = ADDRESS OF ROUTINE IN STARTMH MACRO             * 02370020
*   BYTES 4-8 -- MASK, IF CONDITIONAL EXECUTION                       * 02380020
*                                                                     * 02390020
*OUTPUT -- THE ERB IS POSTED TO BUFFER DISPOSITION, AND REGISTER 12   * 02400020
*   CONTAINS THE ENTRY POINT ADDRESS IN THE ATTEN OR HANGUP ROUTINE.  * 02410020
*                                                                     * 02420020
*EXTERNAL ROUTINES -- NONE                                            * 02430020
*                                                                     * 02440020
*EXITS-NORMAL -- TO THE ATTEN ROUTINE OR THE HANGUP ROUTINE           * 02450020
*                                                                     * 02460020
*EXITS-ERROR -- NONE                                                  * 02470020
*                                                                     * 02480020
*TABLES/WORKAREAS -- AVT, LCB, DCB.                                   * 02490020
*                                                                     * 02500020
*ATTRIBUTES -- SERIALLY REUSABLE, REFRESHABLE, ENABLED, RESIDENT,     * 02510020
*   PROBLEM PROGRAM MODE                                              * 02520020
*                                                                     * 02530020
*NOTES -- THE OPERATION OF THIS MODULE DOES NOT DEPEND UPON A         * 02540020
*   PARTICULAR INTERNAL REPRESENTATION OF THE EXTERNAL CHARACTER      * 02550020
*   SET.                                                              * 02560020
*                                                                     * 02570020
*********************************************************************** 02580020
R1       EQU   1                        REGISTER EQUATE          S21903 11580022
RLCB     EQU   4                        REGISTER EQUATE          S21903 16580022
R7       EQU   7                        REGISTER EQUATE          S21903 19580022
R8       EQU   8                        REGISTER EQUATE          S21903 21580022
RDCB     EQU   10                       REGISTER EQUATE          S21903 23580022
R12      EQU   12                       REGISTER EQUATE          S21903 24580022
R13      EQU   13                       REGISTER EQUATE          S21903 25580022
R14      EQU   14                       REGISTER EQUATE          S21903 26580022
X01      EQU   1                        CONSTANT                 S21903 27580022
         USING IEDQLCB,RLCB             BASE FOR LCB             S21903 28580022
         USING AVTSAVE2,R13             BASE FOR SAVE            S21903 29580022
         USING IHADCB,RDCB              BASE FOR DCB             S21903 30580022
         USING *,R12                    PROGRAM BASE             S21903 31580022
IEDAYX   IEDHJN  AYX000                                                 33500022
         L     R7,4(,R8)                ASSUME HANGUP RTN AND NO MASK   34000020
         TM    0(R8),X01                IS THE MASK PRESENT?            35000020
         BO    AYX050                   BRANCH ON NO                    36000020
         L     R7,8(,R8)               ADDRESS OF ATTENTION RTN  S22029 37000022
AYX050   EQU   *                                                        40000020
         ST    R1,LCBERBLK-1            LINK ELEMENTS                   41000020
         MVI   LCBERBPY,PRIRCQCB        PRIORITY                        42000020
         L     R14,AVTMSGS-1            ACCESS MH MACRO RTN ADDRESSES   43000020
         L     R14,0(,R14)              ADDRESS OF BUFFER DISPOSITION   44000020
         IC    R12,LCBERBKY             SAVE ERB KEY                    44500020
         ST    R14,LCBERBQB-1           POST TO BUFFER DISPOSITION      45000020
         STC   R12,LCBERBKY             RESTORE ERB KEY                 45500020
         LR    R12,R7                   SET ROUTINE BASE ADDRESS        46000020
         BR    R12                      BRANCH TO ROUTINE               47000020
         TAVTD                                                          48000020
         TLCBD                                                          49000020
         TPRIOR                                                         51000020
         DCBD  DSORG=TX                                                 52000020
         END                                                            53000020
