IEDAYZZ  CSECT                                                          01000020
*********************************************************************** 01010020
*TITLE  'IEDAYZZ'  QTIP 25/26 SUBROUTINE                              * 01020020
*                                                                     * 01030020
*STATUS -- CHANGE LEVEL 20.0                                          * 01040020
*                                                                     * 01050020
*FUNCTION -- THE QTIP 25/26 SUBROUTINE IS A LINKEDITED SUBROUTINE OF  * 01060020
*   A LARGER ROUTINE - THE QTIP SVC 101 ROUTINE (IKJGGQT0).  SINCE    * 01070020
*   THIS SUBROUTINE IS PART OF A TYPE ONE SVC ROUTINE, IT RUNS IN DIS-* 01080020
*   ABLED STATE.  THIS PREVENTS ENABLED TSO CODE FROM TESTING CERTAIN * 01090020
*   STATUS BITS AT THE SAME TIME THAT THE BITS ARE BEING SET ON OR    * 01100020
*   OFF.                                                              * 01110020
*      IF THIS SUBROUTINE IS EXECUTED AS THE RESULT OF A QTIP MACRO   * 01120020
*   INSTRUCTION WITH AN ENTRY CODE OF 25, ITS FUNCTION IS TO PREPARE  * 01130020
*   A QCB FOR INSERTION INTO THE TIME DELAY QUEUE.  IF A SEND OPER-   * 01140020
*   ATION WAS REQUESTED, OR IF THE QCB IS ALREADY IN THE TIME DELAY   * 01150020
*   QUEUE, THIS SUBROUTINE SETS A RETURN CODE OF 4, INDICATING THAT   * 01160020
*   THE TIME DELAY SUBTASK IS NOT TO BE EXECUTED, AND RETURNS TO THE  * 01170020
*   CALLING ROUTINE VIA THE INTERRUPT HANDLER.  OTHERWISE, IT SETS    * 01180020
*   THE QCB TO BE POSTED TO THE SIMULATED ATTENTION QCB WHEN ITS TIME * 01190020
*   DELAY EXPIRES, AND SETS TIME DELAY PRIORITY.  THEN IT ACCESSES    * 01200020
*   THE TERMINAL STATUS BLOCK IN THE TSO REGION, AND UPDATES THE      * 01210020
*   QCB TIME DELAY INTERVAL FROM IT.  THE QCB TIME DELAY BIT IS SET   * 01220020
*   ON, AND THE CARRIAGE POSITION COUNT AND TSO JOB I.D. ARE SAVED IN * 01230020
*   THE QCB LINK FIELD.  FINALLY, THIS SUBROUTINE SETS A RETURN CODE  * 01240020
*   OF ZERO, INDICATING THAT THE CALLING ROUTINE MUST LINK TO THE     * 01250020
*   TIME DELAY SUBTASK TO INSERT THE QCB INTO THE TIME DELAY QUEUE,   * 01260020
*   AND RETURNS TO THE CALLING ROUTINE VIA THE INTERRUPT HANDLER.     * 01270020
*      IF THIS SUBROUTINE IS EXECUTED AS THE RESULT OF A QTIP MACRO   * 01280020
*   INSTRUCTION WITH AN ENTRY CODE OF 26, ITS FUNCTION IS TO DETER-   * 01290020
*   MINE WHETHER OR NOT A SEND OPERATION (TPUT) HAS BEEN REQUESTED.   * 01300020
*   IT FIRST INDICATES THAT THE QCB IS NO LONGER POSTED TO ITSELF.    * 01310020
*   IF A TPUT WAS REQUESTED, A RETURN CODE OF 4 IS SET.  IF NOT, A    * 01320020
*   RETURN CODE OF ZERO IS SET.  THEN THIS SUBROUTINE RETURNS TO THE  * 01330020
*   CALLING ROUTINE VIA THE INTERRUPT HANDLER.                        * 01340020
*                                                                     * 01350020
*ENTRY POINTS -- QTIP0250 - TO PREPARE A QCB FOR INSERTION INTO THE   * 01360020
*   TIME DELAY QUEUE                                                  * 01370020
*   CALLING SEQUENCE          L    R15,SVC TABLE + OFFSET (101)       * 01380020
*                             BR   R15                                * 01390020
*   QTIP0260 - TO DETERMINE WHETHER OR NOT A TPUT HAS BEEN REQUESTED  * 01400020
*   CALLING SEQUENCE          L    R15,SVC TABLE + OFFSET (101)       * 01410020
*                             BR   R15                                * 01420020
*                                                                     * 01430020
*INPUT -- IEDAYZZ IS ENTERED FROM THE SVC INTERRUPT HANDLER AT ENTRY  * 01440020
*   POINT QTIP0250 WHEN THE TIME SHARING SCHEDULER (IEDAYZ) ISSUES A  * 01450020
*   QTIP MACRO INSTRUCTION WITH AN ENTRY CODE OF 25.  AT ENTRY, THE   * 01460020
*   FOLLOWING REGISTERS ARE SET.                                      * 01470020
*   R0 HAS THE ENTRY CODE (25)                                        * 01480020
*   R1 HAS THE ADDRESS OF AVTSAVE2                                    * 01490020
*   R7 HAS THE QCB ADDRESS                                            * 01500020
*   R12 HAS THE ADDRESS OF THIS ENTRY POINT WITHIN IKJGGQT0           * 01510020
*   R13 HAS THE ADDRESS OF AVTSAVE2                                   * 01520020
*   R14 HAS THE RETURN ADDRESS IN THE SVC INTERRUPT HANDLER           * 01530020
*   R15 HAS THE ENTRY POINT ADDRESS FOR IKJGGQT0                      * 01540020
*                                                                     * 01550020
*   IEDAYZZ IS ENTERED FROM THE SVC INTERRUPT HANDLER AT ENTRY POINT  * 01560020
*   QTIP0260 WHEN THE SIMULATED ATTENTION ROUTINE (IEDAYS) ISSUES A   * 01570020
*   QTIP MACRO INSTRUCTION WITH AN ENTRY CODE OF 26.  AT ENTRY, THE   * 01580020
*   FOLLOWING REGISTERS ARE SET.                                      * 01590020
*   R0 HAS THE ENTRY CODE (26)                                        * 01600020
*   R1 HAS THE ADDRESS OF AVTSAVE2                                    * 01610020
*   R7 HAS THE QCB ADDRESS                                            * 01620020
*   R12 HAS THE ADDRESS OF THIS ENTRY POINT WITHIN IKJGGQT0           * 01630020
*   R14 HAS THE RETURN ADDRESS IN THE SVC INTERRUPT HANDLER           * 01640020
*   R15 HAS THE ENTRY POINT ADDRESS FOR IKJGGQT0                      * 01650020
*                                                                     * 01660020
*OUTPUT -- ON RETURN TO THE SVC INTERRUPT HANDLER, A RETURN CODE OF   * 01670020
*   EITHER FOUR OR ZERO IS SET IN REGISTER 15.  IF A QCB IS TO BE IN- * 01680020
*   SERTED INTO THE TIME DELAY QUEUE, THE QCB REFLECTS THIS, AND THE  * 01690020
*   FOLLOWING REGISTERS ARE ALSO SET.                                 * 01700020
*   R2 HAS THE CVT ADDRESS                                            * 01710020
*   R3 HAS THE TIME SHARING CVT ADDRESS                               * 01720020
*   R5 HAS THE ADDRESS OF THE TIOC REFERENCE POINTER TABLE            * 01730020
*   R6 HAS THE ADDRESS OF THE TERMINAL STATUS BLOCK                   * 01740020
*   R8 HAS THE ADDRESS OF THE TSINPUT QCB                             * 01750020
*                                                                     * 01760020
*EXTERNAL ROUTINES -- NONE                                            * 01770020
*                                                                     * 01780020
*EXITS-NORMAL -- TO THE SVC INTERRUPT HANDLER                         * 01790020
*                                                                     * 01800020
*EXITS-ERROR -- NONE                                                  * 01810020
*                                                                     * 01820020
*TABLES/WORKAREAS -- CVT, TSCVT, AVT, TSB, QCB, TSID, TPRIOR ERB.     * 01830020
*                                                                     * 01840020
*ATTRIBUTES -- REENTRANT, DISABLED, RESIDENT, SUPERVISOR MODE.        * 01850020
*                                                                     * 01860020
*NOTES -- THE OPERATION OF THIS MODULE DOES NOT DEPEND UPON A         * 01870020
*   PARTICULAR INTERNAL REPRESENTATION OF THE EXTERNAL CHARACTER      * 01880020
*   SET.                                                              * 01890020
*      THE SVC INTERRUPT HANDLER BRANCHES TO THE ENTRY POINT IKJGGQT0 * 01900020
*   FOR ALL QTIP SVC'S.  IKJGGQT0 DETERMINES, FROM THE ENTRY CODE IN  * 01910020
*   REGISTER 0, WHICH ENTRY POINT IN WHICH SUBROUTINE (CSECT) IS TO   * 01920020
*   RECEIVE CONTROL.                                                  * 01930020
*                                                                     * 01940020
*********************************************************************** 01950020
         ENTRY QTIP0250                                                 02000020
         ENTRY QTIP0260                                                 03000020
RPARM0   EQU   0                  PARAMETER REGISTER                    04000020
RPARM1   EQU   1                  PARAMETER REGISTER                    05000020
RBASE    EQU   12                 BASE REGISTER                         06000020
RSAVE    EQU   13                 SAVE AREA REGISTER                    07000020
RRETURN  EQU   14                 RETURN REGISTER                       08000020
RRCODE   EQU   15                 RETURN CODE REGISTER                  09000020
         USING *,RBASE                                                  10000020
         SPACE 8                                                        11000020
QTIP0250 EQU   *                                                        12000020
         SPACE 4                                                        13000020
RCVT     EQU   2                  ADDRESS OF COMM VECTOR TABLE          14000020
RTSCVT   EQU   3                  ADDR OF TIME-SHARING COMM VECTOR TABL 15000020
RTRM     EQU   4                  ADDRESS OF TERMINAL TABLE ENTRY       16000020
RTIOC    EQU   5                  ADDR OF TIOC REFERENCE PTR TABLE      17000020
RTSB     EQU   6                  ADDR OF TERMINAL STATUS BLOCK         18000020
RQCB     EQU   7                  ADDR OF DESTINATION QUEUE CTL BLOCK   19000020
RTSI     EQU   8                  ADDR OF TSINPUT QCB                   20000020
R10      EQU   10                                                       22000020
R11      EQU   11                                                       23000020
         USING AVTSAVE2,RSAVE                                           26000020
         USING CVTSECT,RCVT                                             27000020
         USING TSCVT,RTSCVT                                             28000020
         USING IEDQTRM,RTRM                                             29000020
         USING TIOCRPT,RTIOC                                            30000020
         USING TSB,RTSB                                                 31000020
         USING IEDQQCB,RQCB                                             32000020
         USING IEDQTSI,RTSI                                             33000020
         TM    QCBTSOF1,QCBTPUT+QCBDELAY  IF SEND OPERATION REQUESTED   34000020
*                                       OR ALREADY IN TIME DELAY QUEUE  35000020
         BNZ   AYZZ2601                 DO NOT PUT IN DELAY QUEUE.      36000020
         L     RTSI,AVTTSOPT            OBTAIN ADDR OF TSINPUT QCB      37000020
         MVC   QCBELCHN(3),TSISIMAT+1   SET UP TO POST THIS QCB TO THE  38000020
*                                       SIMULATED ATTENTION RTN WHEN    39000020
*                                       ITS' TIME DELAY EXPIRES.        40000020
         MVI   QCBPRI,PRITIME           MOVE IN PRIORITY                41000020
         L     RCVT,CVTPTR              ADDR OF COMM VECTOR TABLE       42000020
         L     RTSCVT,CVTTSCVT          ADDR OF TIME-SHARING CVT        43000020
         L     RTIOC,TSCVTRPT           ADDR OF TIOC TABLE              44000020
         SR    R11,R11                                                  45000020
         IC    R11,TIOCTSBS              GET SIZE OF TERMINAL STATUS BK 46000020
         LR    R10,R11                                                  47000020
         MH    R11,QCBTJID              DEVELOP OFFSET TO TERMINAL      48000020
         SR    R11,R10                  STATUS BLK FOR THIS TERMINAL    49000020
         A     R11,TIOCTSB-1              ADD ADDRESS OF TSBS           50000020
         LR    RTSB,R11                                                 51000020
         MVC   QCBEOLDT(2),TSBATNTC     UPDATE TIME INTERVAL IN QCB     52000020
         OI    QCBTSOF1,QCBDELAY        SET DELAY FLAG FOR DELAY RTN.   53000020
         MVC   QCBLINK(3),QCBCARCT      SAVE CARRIAGE CNT AND TJID      55000020
         MVI   QCBRETCT,X'00'           INDICATE ELEMENT IS A QCB       56000020
         B     AYZZ2600                 INDICATE TO CALLER TO PUT THIS  57000020
*                                       QCB IN THE TIME DELAY QUEUE.    58000020
         DROP  RSAVE                                                    60000020
         DROP  RCVT                                                     61000020
         DROP  RTSCVT                                                   62000020
         DROP  RTRM                                                     63000020
         DROP  RTIOC                                                    64000020
         DROP  RTSB                                                     65000020
         DROP  RQCB                                                     66000020
         DROP  RTSI                                                     67000020
         SPACE 4                                                        68000020
QTIP0260 EQU   *                                                        69000020
         SPACE 4                                                        70000020
*RQCB    EQU   7                                                        71000020
         USING IEDQQCB,RQCB                                             72000020
         NI    QCBTSOF2,AVTEFF-QCBPOSTO SET QCB POSTED FLAG OFF         73000020
         TM    QCBTSOF1,QCBTPUT         HAS TPUT BEEN REQUESTED         74000020
         BO    AYZZ2601                 BRANCH ON YES                   75000020
AYZZ2600 EQU   *                                                        75500020
         SR    RRCODE,RRCODE            RETURN CODE = 0                 76000020
         BR    RRETURN                  RETURN TO INTERRUPT HANDLER     77000020
AYZZ2601 EQU   *                                                        78000020
         LA    RRCODE,4                 RETURN CODE = 4                 79000020
         BR    RRETURN                  RETURN TO INTERRUPT HANDLER     80000020
         DROP  RQCB                                                     81000020
         SPACE 4                                                        82000020
CVTSECT  DSECT                                                          83000020
         CVT   TSO=YES                                                  84000020
         IKJTIOCP                                                       85000020
         IKJTSB                                                         86000020
         IKJTSCVT                                                       87000020
         TAVTD                                                          88000020
         TPRIOR                                                         89000020
         TQCBD                                                          90000020
         TTRMD                                                          91000020
         TTSID                                                          92000020
         END                                                            93000020
