A001     TITLE '''IEDQA0'' - SKIP BACKWARDS ROUTINE'                    00400020
IEDQA0   CSECT                                                          00800020
         SPACE 3                                                OX01439 00820052
*  CHANGE ACTIVITY AS FOLLOWS                                           00840052
******************** MICROFICHE FLAGS *********************** SUPT CODE 00860052
*A502000,774000,832000,886000,900300-903000                      S22025 00900052
*C056000,096000,616000,776000,836000,888000                      S22025 00900152
*D320000,324000,332000,336000,620000,624000                      S22025 00900252
*C684000,756000-772000,856000                                   OX01439 00900352
*D764000                                                        0X03938 00900453
*A768000                                                        0X03938 00900553
         SPACE                                                          01200020
*********************************************************************** 01600020
*                                                                     * 02000020
*TITLE:  'IEDQA0' -- SKIP BACKWARDS ROUTINE                           * 02400052
*                                                                     * 02440052
*  MODULE NAME = IEDQA0                                               * 02480052
*                                                                     * 02520052
*  DESCRIPTIVE NAME = SKIP BACKWARDS ROUTINE                          * 02560052
*                                                                     * 02600052
*  COPYRIGHT = 'NONE'                                                 * 02640052
*                                                                     * 02680052
*  STATUS CHANGE LEVEL 5                                              * 02720052
*                                                                     * 02800020
*FUNCTION --                                                          * 03200020
*   MOVES THE SCAN POINTER BACKWARDS IN THE HEADER A SPECIFIED        * 03600020
*   NUMBER OF BYTES.                                                  * 04000020
*                                                                     * 04400020
*   THE PREFIX SCAN POINTER OFFSET (PRFSCAN) IS ACCESSED.  A LINK     * 04800020
*   IS MADE TO A SUBROUTINE (NEWSOU) WHICH LINKS TO THE ADDRESS       * 05200020
*   FINDER ROUTINE TO GET THE ADDRESS  OF  THE  SCAN POINTER     S22025 05600022
*   AND OF THE UNIT IN WHICH IT IS LOCATED AND SETS THE ADDRESS OF    * 06000020
*   THE LAST BYTE OF THE UNIT'S RECB IN A START-OF-UNIT REGISTER.     * 06400020
*   THE SKIP COUNT SPECIFIED IN THE PARAMETER LIST IS SET IN A        * 06800020
*   COUNT REGISTER.                                                   * 07200020
*                                                                     * 07600020
*   THE MAIN LOOP IS ENTERED AT THE LABEL DECLOOP.  THE SCAN          * 08000020
*   POINTER OFFSET REGISTER IS DECREMENTED BY ONE.  IF IT GOES TO     * 08400020
*   ZERO,  THE BACKWARDS SKIP IS INTO THE PREFIX:  AN ERROR CODE OF   * 08800020
*   X'04' IS SET IN REGISTER 15 AND RETURN IS MADE TO THE CALLER      * 09200020
*   VIA THE RETURN INTERFACE ROUTINE.                            S22025 09600022
*                                                                     * 10000020
*   THE SCAN POINTER ADDRESS REGISTER IS DECREMENTED BY ONE AND       * 10400020
*   COMPARED TO THE START-OF-UNIT REGISTER.  IF THE SCAN POINTER      * 10800020
*   ADDRESS REGISTER IS HIGH,  NORMAL PROCESSING CONTINUES.           * 11200020
*   OTHERWISE A LINK IS MADE TO THE SUBROUTINE NEWSOU TO GET A NEW    * 11600020
*   SCAN POINTER ADDRESS AND A NEW START-OF-UNIT ADDRESS IN THE       * 12000020
*   PRECEDING UNIT.                                                   * 12400020
*                                                                     * 12800020
*   IF THE BYTE LOCATED AT THE SCAN POINTER IS A BLANK,  THE          * 13200020
*   ROUTINE RETURNS TO THE MAIN LOOP AT THE LABEL DECLOOP.  IF IT     * 13600020
*   IS NOT A BLANK,  THE COUNT REGISTER IS DECREMENTED BY ONE.  IF    * 14000020
*   THE COUNT REGISTER DOES NOT GO TO ZERO,  THE ROUTINE RETURNS TO   * 14400020
*   THE MAIN LOOP AT THE LABEL DECLOOP.                               * 14800020
*                                                                     * 15200020
*   IF THE COUNT REGISTER DOES GO TO ZERO,  THE SKIP BACKWARDS IS     * 15600020
*   COMPLETE.  THE PREFIX SCAN POINTER IS UPDATED FROM THE SCAN       * 16000020
*   POINTER OFFSET REGISTER.  A RETURN CODE OF X'00' IS SET IN        * 16400020
*   REGISTER 15 AND RETURN IS MADE TO THE CALLER VIA THE RETURN       * 16800020
*   INTERFACE ROUTINE.                                                * 17200020
*                                                                     * 17600020
*ENTRY POINTS --                                                      * 18000020
*   'IEDQA0' TO SKIP BACKWARDS A SPECIFIED LENGTH.  CALLING           * 18400020
*   SEQUENCE FROM USER INTERFACE IS:                                  * 18800020
*                                                                     * 19200020
*        L     R12,AVTMSGS-1            GET ADDR OF VCON TABLE        * 19600020
*        IC    R15,AVTEZERO(,R1)        GET INDEX TO ROUTINE ADDR     * 20000020
*        L     R12,AVTEZERO(R12,R15)    GET ROUTINE ADDRESS           * 20400020
*        BR    R12                      EXIT TO ROUTINE               * 20800020
*                                                                     * 21200020
*INPUT --                                                             * 21600020
*   REGISTER 1 -- THE ADDRESS OF A PARAMETER LIST BUILT BY THE        * 22000020
*   SETSCAN MACRO EXPANSION.  PARAMETER LIST FORMAT IS:               * 22400020
*                                                                     * 22800020
*        *********************************                            * 23200020
*        *       * PARAM *               *                            * 23600020
*        * INDEX * LIST  *  SKIP COUNT   *                            * 24000020
*        *       * LNGTH *               *                            * 24400020
*        *********************************                            * 24800020
*                                                                     * 25200020
*   REGISTER 6 -- THE ADDRESS OF THE CURRENT BUFFER.                  * 25600020
*                                                                     * 26000020
*   REGISTER 9 -- THE ADDRESS OF THE AVT.                             * 26400020
*                                                                     * 26800020
*   REGISTER 12 -- THE ENTRY POINT ADDRESS AND BASE REGISTER FOR      * 27200020
*   THIS ROUTINE.                                                     * 27600020
*                                                                     * 28000020
*OUTPUT --                                                            * 28400020
*   REGISTER 15 -- RETURN CODE.  ITS VALUE IS X'00' FOR SUCCESSFUL    * 28800020
*   COMPLETION OR X'04' IF THE SKIP BACKWARDS RUNS INTO THE PREFIX.   * 29200020
*                                                                     * 29600020
*   PREFIX SCAN POINTER OFFSET (PRFSCAN) -- ON SUCCESSFUL             * 30000020
*   COMPLETION,  UPDATED TO POINT TO A LOCATION THE SPECIFIED         * 30400020
*   NUMBER OF DATA BYTES BEFORE ITS FORMER LOCATION.                  * 30800020
*                                                                     * 31200020
*EXTERNAL REFERENCES --                                               * 31600020
*                                                                     * 32800020
*   AVT -- ADDRESS VECTOR TABLE.                                      * 34000020
*                                                                     * 34400020
*   BUFFER CURRENTLY BEING PROCESSED.                                 * 34800020
*                                                                     * 35200020
*EXITS,  NORMAL -- SUCCESSFUL COMPLETION.  THE PREFIX SCAN POINTER    * 35600020
*   (PRFSCAN) POINTS TO A LOCATION THE SPECIFIED NUMBER OF DATA       * 36000020
*   BYTES BEFORE ITS FORMER LOCATION.  REGISTER 15 CONTAINS A         * 36400020
*   RETURN CODE OF X'00'.                                             * 36800020
*                                                                     * 37200020
*EXITS,  ERROR -- SKIP BACKWARDS ATTEMPTED TO RUN INTO THE PREFIX.    * 37600020
*   REGISTER 15 CONTAINS A RETURN CODE OF X'04'.                      * 38000020
*                                                                     * 38400020
*TABLES/WORK AREAS -- N/A.                                            * 38800020
*                                                                     * 39200020
*ATTRIBUTES -- SERIALLY REUSABLE,ENABLED,RESIDENT,PROBLEM PROGRAM MODE* 39600052
*                                                                     * 40400020
*NOTES -- THE OPERATION OF THIS MODULE DOES NOT DEPEND UPON AN        * 40800020
*   INTERNAL REPRESENTATION OF THE EXTERNAL CHARACTER SET.            * 41200020
*                                                                     * 41600020
*********************************************************************** 42000020
         EJECT                                                          42400020
********* REGISTER EQUATES *********                                    42800020
         SPACE                                                          43200020
R1       EQU   1                        PARAMETER LIST REG              43600020
         SPACE 1                                                 S22025 43700022
RWORK2   EQU   2                        WORK REGISTER            S22025 43800022
         SPACE                                                          44000020
REOPOFF  EQU   3                        END-OF-PREFIX OFFSET            44400020
         SPACE                                                          44800020
RLCB4    EQU   4                        ADDRESS OF LCB                  45200020
         SPACE                                                          45600020
RSCAN    EQU   5                        SCAN POINTER ADDRESS            46000020
         SPACE                                                          46400020
RPREFIX  EQU   6                        ADDR OF BUFFER                  46800020
         SPACE                                                          47200020
RSCANOFF EQU   7                        SCAN POINTER OFFSET             47600020
         SPACE                                                          48000020
RBLANK8  EQU   8                        BLANK CHARACTER                 48400020
         SPACE                                                          48800020
RAVT     EQU   9                        ADDRESS OF AVT                  49200020
         SPACE                                                          49600020
RPARLEN  EQU   10                       LENGTH OF SKIP REQUESTED        50000020
         SPACE 1                                                 S22025 50100022
REOUAD   EQU   11                       ADDR OF CURRENT END OF UNS22025 50200022
         SPACE                                                          50400020
RBASE    EQU   12                       BASE REGISTER                   50800020
         SPACE                                                          51200020
R13      EQU   13                       ADDR OF SAVE AREA               51600020
R14      EQU   14                       RETURN REGISTER                 52000020
R15      EQU   15                       BRANCH REGISTER &               52400020
*                                         RETURN CODE REGISTER          52800020
         SPACE                                                          53200020
********* PARAMETER LIST OFFSETS *********                              53600020
         SPACE                                                          54000020
PARMINDX EQU   0                        INDEX BYTE                      54400020
PARMLEN  EQU   1                        PARAMETER LIST LENGTH           54800020
PARMSKIP EQU   2                        LENGTH OF SKIP                  55200020
PARMBLNK EQU   4                        BLANK CHARACTER                 55600020
         SPACE                                                          56000020
********* OTHER EQUATES *********                                       56400020
         SPACE                                                          56800020
NOBLANKN EQU   X'02'                    'NO BLANK' FLAG                 57200020
FOUR     EQU   4                        PARAMETER LIST LENGTH           57600020
*                                         IF EBCDIC BLANK               58000020
         EJECT                                                          58400020
         USING IEDQAVTD,RAVT                                            58800020
         USING IEDQLCB,RLCB4                                            59200020
         USING IEDQPRF,RPREFIX                                          59600020
         USING IEDQA001,RBASE                                           60000020
         SPACE                                                          60400020
IEDQA001 EQU   *                                                        60800020
IEDQA0   IEDHJN SKIPBACK                                                61800022
         LA    R15,AVTECD4              SET MBH RETURN CODE             62800020
         LNR   R15,R15                    FOR THIS TEST                 63200020
         CLC   PRFSCAN,PRFSIZE          SCAN PT BEYOND END OF BFR       63600020
         BH    EXIT                     YES, RETURN IMMEDIATELY         64000020
         SPACE                                                          64400020
         LH    RSCANOFF,PRFSCAN         GET SCAN POINTER                64800020
         N     RSCANOFF,AVTCLRHI        CLEAR TOP HALF OF REGISTER      65200020
         LH    RPARLEN,PARMSKIP(,R1)    GET SKIP LENGTH                 66000020
         N     RPARLEN,AVTCLRHI         CLEAR TOP HALF OF REGISTER      66400020
         BZ    ADDRONLY                 RETURN ADDR ONLY IF ZERO        66800020
         SPACE                                                          67200020
         SR    REOPOFF,REOPOFF          (CLEAR FOR INSERT)              67600020
         IC    REOPOFF,LCBISZE          PICK UP NO. OF RESERVES         68000020
         LA    REOPOFF,AVTTXTSZ(,REOPOFF)  ADD TEXT PREFIX SIZE OX01439 68400052
*                                         OF TEXT PREFIX                68800020
         TM    PRFSTAT1,PRFNHDRN        IS THIS A HEADER BUFFER         69200020
         BO    TESTBLNK                 NO, EOP OFFSET IS RIGHT         69600020
         SPACE                                                          70000020
         LA    REOPOFF,AVTHDRSZ-AVTTXTSZ(,REOPOFF) YES, ADD EXTRA       70400020
         SPACE                                                          70800020
TESTBLNK EQU   *                                                        71200020
         TM    PARMINDX(R1),NOBLANKN    IS BLANK DEFINED                71600020
         BO    SKIPSUBT                 NO, SUBTRACT DIRECTLY           72000020
         SPACE                                                          72400020
         CLI   PARMLEN(R1),FOUR         IS IT EBCDIC BLANK              72800020
         LA    RBLANK8,AVTEBLNK         ASSUME YES                      73200020
         BE    LOOP                     YES, IT IS SET RIGHT            73600020
         SPACE                                                          74000020
         IC    RBLANK8,PARMBLNK(,R1)    NO, PICK UP FROM PARM LIST      74400020
         SPACE                                                          74800020
LOOP     EQU   *                                                        75200020
         CR    RSCANOFF,REOPOFF         TEST IF INTO PREFIX     OX01439 75600052
         BNH   ERROR                    YES,ERROR,BRANCH        OX01439 76000052
         BCTR  RSCANOFF,AVTEZERO        DECREMENT SCAN OFFSET   OX01439 76800052
         LR    RSCAN,RSCANOFF           PASS OFFSET             0X03938 77100053
         LR    RWORK2,RPREFIX           LOAD PREFIX ADDR         S22025 77400022
         BAL   R14,ENTERLOP             GET ADDR OF SCAN POINTER S22025 77600022
         SPACE                                                          78000020
         EX    RBLANK8,CLIX             IS BYTE A BLANK                 78400020
         BE    LOOP                     YES, DON'T COUNT IT, LOOP       78800020
         SPACE                                                          79200020
         BCT   RPARLEN,LOOP             NO, COUNT, LOOP IF NOT ZERO     79600020
         SPACE                                                          80000020
SETSCAN  EQU   *                                                        80400020
         STH   RSCANOFF,PRFSCAN         RESET SCAN POINTER              80800020
         SPACE                                                          81200020
GOODRTN  EQU   *                                                        81600020
         SR    R15,R15                  SET GOOD RETURN CODE            82000020
         SPACE                                                          82400020
EXIT     EQU   *                                                        82800020
         L     RBASE,AVTUI              GET RET INTERFACE ADDR   S22025 83200022
         B     FOUR(RBASE)              BRANCH TO RETURN ROUTINE S22025 83600022
         SPACE                                                          84000020
SKIPSUBT EQU   *                                                        84400020
         SR    RSCANOFF,RPARLEN         SUBTRACT REQUESTED SKIP LNG     84800020
         CR    RSCANOFF,REOPOFF         TEST IF INTO PREFIX             85200020
         BNL   SETSCAN                  NO,GO SET SCAN PTR      OX01439 85600052
         SPACE                                                          86000020
ERROR    EQU   *                                                        86400020
         LA    R15,AVTECD4              SET ERROR RETURN CODE           86800020
         B     EXIT                     RETURN TO CALLER                87200020
         SPACE                                                          87600020
ADDRONLY EQU   *                                                        88000020
         LR    RSCAN,RSCANOFF           PASS SCAN POINTER OFFSET        88400020
         LR    RWORK2,RPREFIX           LOAD PREFIX ADDR         S22025 88600022
         BAL   R14,ENTERLOP             GET ADDR OF SCAN POINTER S22025 88800022
         SPACE                                                          89200020
         LR    R1,RSCAN                 RETURN IT IN REGISTER 1         89600020
         B     GOODRTN                  SET GOOD RETURN AND EXIT        90000020
ADDRLOOP EQU   *                                                 S22025 90030022
         L     RWORK2,PRFTIC-IEDQPRF(,RWORK2) POINT TO NEXT UNIT S22025 90060022
         SH    RSCAN,AVTKEYLE           SUBT NO OF BYTES PASSED  S22025 90090022
ENTERLOP EQU   *                                                 S22025 90120022
         CH    RSCAN,AVTKEYLE           IS ITEM IN THIS UNIT     S22025 90150022
         BH    ADDRLOOP                 NO, TEST NEXT UNIT       S22025 90180022
         LA    RSCAN,AVTUMALN-1(RSCAN,RWORK2) YES, UNIT ADDR     S22025 90210022
         LH    REOUAD,AVTKEYLE          GET KEY LENGTH           S22025 90240022
         LA    REOUAD,AVTUMALN(RWORK2,REOUAD) END OF UNIT ADDR   S22025 90270022
         BR    R14                      RETURN TO CALLER         S22025 90300022
         SPACE                                                          90400020
********* EXECUTED INSTRUCTIONS *********                               90800020
         SPACE                                                          91200020
CLIX     CLI   AVTEZERO(RSCAN),AVTEZERO TEST FOR BLANK IN BUFFER        91600020
         EJECT                                                          92000020
********* DSECTS *********                                              92400020
         SPACE                                                          92800020
         TAVTD                                                          93200020
         EJECT                                                          93600020
         TLCBD                                                          94000020
         EJECT                                                          94400020
         TPRFD                                                          94800020
         SPACE                                                          95200020
         END                                                            95600020
