         TITLE 'IEDQA1  -  BINARY SEARCH ROUTINE'                       00300020
IEDQA1   CSECT                                                          00600020
*A042700-044100,216300-218100,220000,279300-281100,373200-374400 S22025 00660022
*A457000,458000,508000,523000,524000,537100-539700               S22025 00720022
*C036000,372000,588000,591000,777000,78000                       S22025 00780022
*D306000,309000,543000-550000                                    S22025 00840022
*C539400-539450,711000                                           S22027 00870022
*********************************************************************** 00900020
*                                                                     * 01200020
*STATUS -- CHANGE LEVEL 0                                             * 01500020
*                                                                     * 01800020
*FUNCTION -- SEARCHES THE TERMINAL NAME TABLE TO FIND THE ENTRY       * 02100020
*   NAME PASSED.                                                      * 02400020
*                                                                     * 02700020
*   THE ADDRESS OF THE FIELD CONTAINING THE TERMINAL NAME SOUGHT      * 03000020
*   AND THE LENGTH OF THE FIELD ARE LOADED FROM THE PARAMETER LIST    * 03300020
*   INTO REGISTERS 2 AND 5 RESPECTIVELY. REGISTER 4 IS INITIALIZED    * 03600022
*   TO THE ADDRESS OF THE TERMINAL NAME TABLE (AVTRNMPT) AND          * 03900020
*   REGISTER 7 TO THE ENTRY LENGTH FROM THE TERMINAL NAME TABLE.      * 04200020
*   IF PLUS 4 ENTRY INTO THIS MODULE IS USED REGISTERS 0 HAS THE S22025 04270022
*   LENGTH AND REGISTER 1 HAS ADDRES.BECAUSE NO PARMETER LIST IS S22025 04340022
*   USED.                                                               04410022
*                                                                     * 04500020
*   THE LENGTH FROM THE PARAMETER LIST IS COMPARED WITH THE LENGTH    * 04800020
*   FROM THE TERMINAL NAME TABLE.  IF THE LENGTH FROM THE TABLE IS    * 05100020
*   HIGHER THAN OR EQUAL TO THE LENGTH PASSED,  THE LENGTH PASSED     * 05400020
*   IS TO BE USED AS THE COMPARE LENGTH.  IT IS LEFT IN REGISTER 1.   * 05700020
*   IF THE LENGTH FROM THE TABLE IS LOW,  THE LENGTH FROM THE TABLE   * 06000020
*   IS USED AS THE COMPARE LENGTH.  IT IS MOVED INTO REGISTER 1       * 06300020
*   FROM REGISTER 7.                                                  * 06600020
*                                                                     * 06900020
*   REGISTER 1 IS DECREMENTED TO BE USED FOR EXECUTING THE SUBSE-     * 07200020
*   QUENT COMPARE.  REGISTER 10 IS INITIALIZED TO THE ADDRESS OF      * 07500020
*   THE MIDDLE ENTRY FROM THE TERMINAL NAME TABLE.  REGISTER 7 IS     * 07800020
*   INCREMENTED BY 3 TO GET THE FULL LENGTH OF A TERMINAL NAME        * 08100020
*   TABLE ENTRY,  AND THIS VALUE IS SAVED IN REGISTER 11.  REGISTER   * 08400020
*   8 IS SET TO POINT ONE ENTRY BEYOND THE LAST ENTRY IN THE TABLE.   * 08700020
*   REGISTER 7 IS MULTIPLIED BY THE SEARCH EXTENT FACTOR IN THE       * 09000020
*   TERMINAL NAME TABLE TO GET THE LENGTH OF THE FIRST SEARCH         * 09300020
*   EXTENT.  THE SEARCH LOOP IS THEN ENTERED.                         * 09600020
*                                                                     * 09900020
*   REGISTER 10 (THE ADDRESS OF THE ENTRY TO BE COMPARED) IS          * 10200020
*   COMPARED TO REGISTER 8 (THE ADDRESS OF THE LAST ENTRY,  PLUS      * 10500020
*   THE LENGTH OF ONE ENTRY) TO DETERMINE IF THE SEARCH IS BEYOND     * 10800020
*   THE END OF THE TABLE.  IF SO,  THE CURRENT ENTRY IS NOT           * 11100020
*   COMPARED (BECAUSE IT IS NOT A REAL ENTRY).  INSTEAD IT IS         * 11400020
*   IMMEDIATELY DECREMENTED BY THE SEARCH EXTENT IN REGISTER 7 AND    * 11700020
*   COMPARED WITH REGISTER 11.                                        * 12000020
*                                                                     * 12300020
*   IF THE CURRENT ENTRY IS A REAL ENTRY,  IT IS COMPARED TO THE      * 12600020
*   ENTRY PASSED (POINTED TO BY REGISTER 2).  IF THE CURRENT ENTRY    * 12900020
*   IS HIGH,  REGISTER 10 IS DECREMENTED BY REGISTER 7 (THE CURRENT   * 13200020
*   SEARCH EXTENT);  IF IT IS LOW,  IT IS INCREMENTED BY REGISTER     * 13500020
*   7.  REGISTER 7 IS THEN COMPARED WITH REGISTER 11 (THE LENGTH OF   * 13800020
*   ONE ENTRY).  IF REGISTER 7 IS LESS THAN THE LENGTH OF ONE         * 14100020
*   ENTRY,  THE SEARCH HAS FAILED.  REGISTER 15 IS SET TO A RETURN    * 14400020
*   CODE OF X'00',  THE ADDRESS OF THE SCB IS SET IN REGISTER 0 AND   * 14700020
*   RETURN IS MADE VIA THE RETURN INTERFACE ROUTINE.                  * 15000020
*                                                                     * 15300020
*   IF REGISTER 7 IS NOT LESS THAN THE LENGTH OF ONE ENTRY,  IT IS    * 15600020
*   DIVIDED BY TWO TO OBTAIN A NEW SEARCH EXTENT AND THE SEARCH       * 15900020
*   LOOP IS REENTERED.                                                * 16200020
*                                                                     * 16500020
*   IF THE CURRENT ENTRY IS EQUAL TO THE NAME PASSED,  THE SEARCH     * 16800020
*   IS COMPLETE.  THE KEY (ORDINAL INDEX) TO THE MATCHING ENTRY IS    * 17100020
*   COMPUTED BY DIVIDING THE LENGTH FROM THE FIRST ENTRY TO THE       * 17400020
*   MATCHING ENTRY BY THE LENGTH OF ONE ENTRY AND ADDING ONE.  THE    * 17700020
*   KEY IS RETURNED IN REGISTER 15.  THE ADDRESS OF THE SCB IS SET    * 18000020
*   IN REGISTER 0 AND RETURN IS MADE VIA THE RETURN INTERFACE         * 18300020
*   ROUTINE.                                                          * 18600020
*                                                                     * 18900020
*ENTRY POINTS --                                                      * 19200020
*       'IEDQA1' TO SEARCH THE TERMINAL NAME TABLE TO FIND THE        * 19500020
*   ENTRY NAME PASSED.  CALLING SEQUENCE FROM USER INTERFACE IS:      * 19800020
*                                                                     * 20100020
*        L     R12,AVTMSGS-1            GET ADDR OF VCON TABLE        * 20400020
*        IC    R15,AVTEZERO(,R1)        GET INDEX TO ROUTINE ADDR     * 20700020
*        L     R12,AVTEZERO(R12,R15)    GET ROUTINE ADDRESS           * 21000020
*        BR    R12                      EXIT TO ROUTINE               * 21300020
*                                                                     * 21600020
*       'IEDQA1+4' TO USE BINARY SEARCH WITHOUT PARMATER LIST.   S22025 21630022
*   CALLING SEQUENCE IS:                                         S22025 21660022
*                                                                S22025 21690022
*       L     R15,AVTMSGS-1            GET VCON TABLE ADDR       S22025 21720022
*       L     R15,8(R15)               LOAD ADDR OF IEDQA1       S22025 21750022
*       BAL   R14,4(R15)               LINK TO IEDQA1            S22025 21780022
*                                                                     * 21810022
*INPUT --                                                             * 21900020
*   PLUS 0 ENTRY:                                                S22025 22000022
*   REGISTER 1 - THE ADDRESS OF A PARAMETER LIST.  PARAMETER LIST     * 22200020
*   FORMAT IS:                                                        * 22500020
*                                                                     * 22800020
*        *********************************                            * 23100020
*        *       * PARAM * UN-   * CHAR  *                            * 23400020
*        * INDEX * LIST  *  USED * LNGTH *                            * 23700020
*        *       * LNGTH *       *       *                            * 24000020
*        *********************************                            * 24300020
*        *                               *                            * 24600020
*        *  ADDRESS OF CHARACTER STRING  *                            * 24900020
*        *                               *                            * 25200020
*        *********************************                            * 25500020
*                                                                     * 25800020
*   REGISTER 3 - THE ADDRESS OF THE SCB.                              * 26100020
*                                                                     * 26400020
*   REGISTER 9 - THE ADDRESS OF THE AVT.                              * 26700020
*                                                                     * 27000020
*   REGISTER 12 - THE ENTRY POINT ADDRESS AND BASE REGISTER FOR       * 27300020
*   THIS ROUTINE.                                                     * 27600020
*                                                                     * 27900020
*   PLUS 4 ENTRY:                                                S22025 27930022
*                                                                S22025 27960022
*   REGISTER 0 - LENGTH OF CHARACTER STRING.                     S22025 27990022
*                                                                S22025 28020022
*   REGISTER 1 - ADDRESS OF CHARACTER STRING.                    S22025 28050022
*                                                                S22025 28080022
*   OTHER REGISTERS SAME AS ABOVE.                               S22025 28110022
*OUTPUT --                                                            * 28200020
*   REGISTER 0 - THE ADDRESS OF THE SCB.                              * 28500020
*                                                                     * 28800020
*   REGISTER 15 - IF A MATCHING ENTRY IS FOUND,  THE KEY (ORDINAL     * 29100020
*   INDEX) TO THE MATCHING ENTRY.  IF NO MATCHING ENTRY IS FOUND,     * 29400020
*   A RETURN CODE OF X'00'.                                           * 29700020
*                                                                     * 30000020
*EXTERNAL REFERENCES --                                               * 30300020
*   TERMINAL NAME TABLE.                                              * 31200020
*                                                                     * 31500020
*   AVT - ADDRESS VECTOR TABLE.                                       * 31800020
*                                                                     * 32100020
*   SCB - STATION CONTROL BLOCK FOR CURRENT STATION.                  * 32400020
*                                                                     * 32700020
*EXITS,  NORMAL -- A MATCHING ENTRY IS FOUND.  REGISTER 0 CONTAINS    * 33000020
*   THE ADDRESS OF THE SCB.  REGISTER 15 CONTAINS THE KEY (ORDINAL    * 33300020
*   INDEX) TO THE MATCHING ENTRY.                                     * 33600020
*                                                                     * 33900020
*EXITS,  ERROR -- NO MATCHING ENTRY IS FOUND.  REGISTER 0 CONTAINS    * 34200020
*   THE ADDRESS OF THE SCB.  REGISTER 15 CONTAINS A RETURN CODE OF    * 34500020
*   X'00'.                                                            * 34800020
*                                                                     * 35100020
*TABLES/WORK AREAS -- N/A.                                            * 35400020
*                                                                     * 35700020
*ATTRIBUTES -- SERIALLY REUSABLE, REFRESHABLE, ENABLED, RESIDENT,     * 36000020
*   PROBLEM PROGRAM MODE.                                             * 36300020
*                                                                     * 36600020
*   NOTES -- THE OPERATION OF THIS MODULE DOES NOT DEPEND UPON AN     * 36900020
*   INTERNAL REPRESENTATION OF THE EXTERNAL CHARACTER SET.            * 37200020
*   WHEN CHANGING THIS MODULE FOR ANY REASON YOU MUST INSURE     S22025 37260022
*   THAT ALL CODE EXECUTED IN THE PLUS FOUR ENTRY REMAIN         S22025 37320022
*   RE-ENTRANT BECAUSE THIS MODULE IS BEING USED BY TOTE AND     S22025 37380022
*   APPLICATION PROGRAMS ALSO.                                   S22025 37440022
*                                                                     * 37500020
*********************************************************************** 37800020
********* REGISTER EQUATES **********                                   38100020
         SPACE                                                          38400020
R0       EQU   0                        DUMMY BASE REG                  38700020
         SPACE                                                          39000020
R1       EQU   1                        PARAMETER LIST ADDRESS          39300020
         SPACE                                                          39600020
RFLD     EQU   2                        ADDR OF FIELD PASSED            39900020
         SPACE                                                          40200020
RSCB     EQU   3                        ADDRESS OF SCB                  40500020
         SPACE                                                          40800020
RTAB     EQU   4                        ADDR OF TABLE TO BE             41100020
*                                         SEARCHED                      41400020
         SPACE                                                          41700020
RLEN     EQU   5                        LENGTH OF FIELD PASSED          42000020
         SPACE                                                          42300020
RSRCHX   EQU   7                        SEARCH EXTENT REGISTER          42600020
         SPACE                                                          42900020
RLAST    EQU   8                        ADDR OF LAST ENTRY + 1          43200020
         SPACE                                                          43500020
RAVT     EQU   9                        ADDRESS OF AVT                  43800020
RADDR    EQU   10                       ADDR OF CURRENT ENTRY IN        44100020
*                                         TABLE                         44400020
         SPACE                                                          44700020
RTRULEN  EQU   11                       FULL LENGTH OF A TABLE ENTRY    45000020
         SPACE                                                          45300020
RBASE    EQU   12                       BASE REGISTER                   45600020
R13      EQU   13                       CALLERS SAVE AREA ADDR   S22025 45700022
EIGHT    EQU   8                        OFFSET VALUE             S22025 45800022
         SPACE                                                          45900020
R14      EQU   14                       RETURN REGISTER                 46200020
R15      EQU   15                       BRANCH REGISTER, BASE           46500020
*                                         REGISTER AND RETURN CODE      46800020
*                                         REGISTER                      47100020
         SPACE                                                          47400020
********* OTHER EQUATES **********                                      47700020
         SPACE                                                          48000020
ADDRLEN  EQU   3                        LENGTH OF AN ADDR CONSTANT      48300020
         SPACE                                                          48600020
ONE      EQU   1                        OFFSET TO START OF NAME         48900020
         SPACE                                                          49200020
DIVIDE   EQU   1                        SHIFT LENGTH TO HALVE A         49500020
*                                         VALUE IN A REG                49800020
         SPACE                                                          50100020
         SPACE                                                          50400020
INCX     EQU   1                        FACTOR TO GET ORDINAL INDEX     50700020
CVTOFF   EQU   16                       ADDRESS OF THE CVT       S22025 50800022
         SPACE                                                          51000020
TWO      EQU   2                        OFFSET TO LENGTH FIELD          51300020
FOUR     EQU   4                        OFFSET TO FIELD ADDRESS         51600020
SEVEN    EQU   7                        LENGTH FACTOR FOR CLEARING      51900020
*                                         AVT WORK AREA                 52200020
TWELVE   EQU   12                       OFFSET FOR +4 SAVE ADDR  S22025 52300022
SIXTEEN  EQU   16                       OFFSET FOR +4 SAVE PTR   S22025 52400022
         SPACE                                                          52500020
MOVEFLAG EQU   X'01'                    INDEX FLAG: MOVE NAME           52800020
         EJECT                                                          53100020
         USING *,RBASE                                                  53700020
IEDQA101 EQU   *                                                 S22025 53710022
         B     ENTRY                    ENTRY FROM IEDQUI        S22025 53720022
IEDQA102 EQU   *                                                 S22025 53730022
         B     SAVEIT-IEDQA101(R15)     BRANCH AROUND ID         S22025 53740022
IEDQA1   IEDHJN ,                       MODULE ID                S22025 53750022
SAVEIT   DS    0H                                                S22025 53770022
         STM   R14,RBASE,12(R13)        SAVE CALLERS REGISTERS   S22025 53780022
         L     RAVT,CVTOFF              GET ADDRESS OF CVT       S22025 53790022
         L     RAVT,AVTCVTPT(,RAVT)     FIND POINTER TO AVT      S22025 53800022
         L     RAVT,AVTEZERO(,RAVT)     GET ADDRESS OF AVT       S22025 53810022
         USING IEDQAVTD,RAVT                                     S22025 53820022
         ST    R13,SIXTEEN(,R13)        STORE BACKWARD POINTER   S22025 53830022
         LA    R13,TWELVE(,R13)         ADJUST SAVE ADDRESS      S22025 53840022
         LR    RBASE,R15                SET R12 AS BASE REG      S22025 53870022
         LR    RFLD,R1                  INITIALIZE ADDR FIELD    S22025 53880022
         LR    RLEN,R0                  GET LENGTH OF FIELD      S22025 53890022
         B     BINSRCH                  BRANCH TO SEARCH         S22025 53900022
ENTRY    EQU   *                                                 S22025 53910022
         USING IEDQAVTD,RAVT                                     S22025 53920022
         L     RFLD,FOUR(,R1)           INITIALIZE ADDR FIELD    S22025 53930022
         SR    RLEN,RLEN                CLEAR REG                S22027 53940022
         IC    RLEN,ADDRLEN(,R1)        GET ENTRY LENGTH         S22027 53945022
         TM    0(R1),MOVEFLAG           MUST NAME BE MOVED       S22025 53950022
         BNO   BINSRCH                  NO, BRANCH TO COMPUTE    S22025 53960022
         SR    R1,R1                    YES, SET UP FOR MOVE     S22025 53970022
         SPACE                                                          54000020
         SPACE                                                          55200020
BINSRCH  DS    0H                                                       55400020
         L     RTAB,AVTRNMPT            GET ADDR OF TERMNAME TABLE      56100020
         USING IEDQTNTD,RTAB                                            56400020
         SPACE                                                          56700020
         SR    RSRCHX,RSRCHX            CLEAR REG                       57000020
         IC    RSRCHX,TNTENLEN          INSERT ENTRY LNG                57300020
         CR    RLEN,RSRCHX              LNG PASSED GT ENTRY LENGTH      57900020
         BH    BADRTN                   YES, IT IS INVALID, EXIT        58200020
         SPACE                                                          58500020
         LTR   R1,R1                    MUST NAME BE MOVED       S22025 58800022
         BNZ   SETLEN                   NO, BRANCH               S22025 59100022
         SPACE                                                          59400020
         MVI   AVTDOUBL,AVTEBLNK        CLEAR AVT WORK AREA             59700020
         MVC   AVTDOUBL+1(SEVEN),AVTDOUBL TO ZEROES                     60000020
         BCTR  RLEN,AVTEZERO            DECREMENT FOR EXECUTE           60300020
         EX    RLEN,MOVEX               MOVE NAME TO AVT WORK AREA      60600020
         LA    RFLD,AVTDOUBL            POINT TO AVT WORK AREA          60900020
         SPACE                                                          61200020
SETLEN   EQU   *                                                        61500020
         LR    RLEN,RSRCHX              SET COMPARE LENGTH              61800020
         SPACE                                                          62100020
BICKETER EQU   *                                                        62400020
         BCTR  RLEN,AVTEZERO            DECREMENT FOR COMPARE           62700020
         L     RADDR,TNTMIDEN-1         GET ADDR OF MIDDLE ENTRY        63000020
         LA    RADDR,AVTEZERO(,RADDR)   CLEAR HIGH-ORDER BYTE           63300020
         LA    RSRCHX,ADDRLEN(,RSRCHX)  GET FULL ENTRY LENGTH           63600020
         LR    RTRULEN,RSRCHX           SAVE FULL ENTRY LENGTH          63900020
         MH    RSRCHX,TNTLEN            GET OFFSET TO LAST + 1          64200020
         LA    RLAST,TNTFIRST           GET ADDR OF FIRST ENTRY         64500020
         AR    RLAST,RSRCHX             GET ADDR OF LAST + 1            64800020
         LR    RSRCHX,RTRULEN           GET FULL ENTRY LNG              65100020
         MH    RSRCHX,TNTSRCHX          MULTIPLY BY SEARCH EXTENT       65400020
*                                         FACTOR TO GET SEARCH          65700020
*                                         EXTENT                        66000020
         B     ENTRLOOP                 ENTER LOOP                      66300020
         SPACE                                                          66600020
LOOP     EQU   *                                                        66900020
         CR    RSRCHX,RTRULEN           SEARCH EXTENT LT TRUE LNG       67200020
         BL    BADRTN                   YES, ENTRY NOT FOUND            67500020
         SRL   RSRCHX,DIVIDE            DIVIDE EXTENT BY TWO            67800020
         CR    RADDR,RLAST              POINTING BEYOND TABLE END       68100020
         BNL   LO                       YES, GO ADJUST DOWN             68400020
         SPACE                                                          68700020
ENTRLOOP EQU   *                                                        69000020
         EX    RLEN,COMPEX              COMPARE ENTRY WITH FIELD        69300020
         BH    HI                       HIGH, GO ADJUST UP              69600020
         BE    FOUND                    EQUAL, ENTRY FOUND              69900020
*                                                                       70200020
LO       EQU   *                                                        70500020
         SR    RADDR,RSRCHX             LO, ADJUST DOWN                 70800020
         B     LOOP                     SEARCH AGAIN             S22027 71100022
         SPACE                                                          71400020
HI       EQU   *                                                        71700020
         BXH   RADDR,RSRCHX,LOOP        ADJUST UP AND LOOP              72000020
         SPACE                                                          72300020
FOUND    EQU   *                                                        72600020
         LA    RTAB,TNTOFF(,RTAB)       GET ADDRESS OF 1ST ENTRY        72900020
         SR    RADDR,RTAB               GET OFFSET TO OUR ENTRY         73200020
         SR    R0,R0                    CLEAR FOR DIVIDE                73500020
         LR    R1,RADDR                 MOVE OFFSET TO DIVIDE REG       73800020
         SPACE                                                          74100020
         DR    R0,RTRULEN               DIVIDE TO GET INDEX             74400020
         LA    R15,INCX(,R1)            INCREMENT TO GET ORDINAL        74700020
*                                         INDEX                         75000020
         SPACE                                                          75300020
         B     RETURN                   RETURN TO CALLER                75600020
         SPACE                                                          75900020
BADRTN   EQU   *                                                        76200020
         SR    R15,R15                  RETURN X'00' RETURN CODE        76500020
         SPACE                                                          76800020
RETURN   EQU   *                                                        77100020
         LR    R0,RSCB                  RETURN SCB ADDR TO MH           77400020
         L     RBASE,AVTUI              GET RET INTERFACE ADDR   S22025 77700022
         B     FOUR(RBASE)              RETURN TO CALLER         S22025 78000022
         SPACE                                                          78300020
********* EXECUTED INSTRUCTIONS **********                              78600020
         SPACE                                                          78900020
MOVEX    MVC   AVTDOUBL(ONE),AVTEZERO(RFLD) MOVE NAME TO                79200020
*                                         AVT WORK AREA                 79500020
         SPACE                                                          79800020
COMPEX   CLC   AVTEZERO(1,RFLD),AVTEZERO(RADDR) FIELD-ENTRY COMPARE     80100020
         EJECT                                                          80400020
********* DSECTS *********                                              80700020
         SPACE 2                                                        81000020
         TAVTD                                                          81300020
         EJECT                                                          81600020
         TTNTD                                                          81900020
         END                                                            82200020
