A401     TITLE '''IEDQA4'' - INCOMING MESSAGE DELIMITER ROUTINE'        00200020
IEDQA4   CSECT                                                          00400020
*A053000,254000,258000,389000,602200-603600                      S22025 00400122
*C004304,005320,108000,114000,246000-252000,256000,260000,262000 S22025 00400222
*C274000-278000,386000                                           S22025 00400322
*D110000-113000,206000-220000,388000,390000                      S22025 00400422
*A278222                                                        SA59523 00400622
*********************************************************************** 00400897
*                                                                     * 00401697
*STATUS -- CHANGE LEVEL 5                                        S22024 00402422
*A312000                                                        A42391  00403297
*                                                                     * 00404097
*FUNCTION -- INITIALIZES THE BUFFER AND SELECTS EXIT FROM THE         * 00404897
*   MESSAGE HANDLER,  VIA EITHER A BRANCH TO BUFFER ASSOCIATION,      * 00405697
*   A BRANCH TO THE TRANSPARENT CCW BUILDER,  OR BY A POST OF THE     * 00406497
*   BUFFER TO THE PROPER QCB.                                         * 00407297
*                                                                     * 00408097
*   THE 'NOT-LAST-BUFFER' BIT IN THE BUFFER PREFIX STATUS FIELD       * 00408897
*   (PRFSTATE) IS TESTED.  IF THIS IS THE LAST BUFFER,  THE           * 00409697
*   PARAMETER LIST ADDRESS IS STORED IN THE SCB INMSG/OUTMSG MACRO    * 00410497
*   FIELD (SCBMACR).                                                  * 00411297
*                                                                     * 00412097
*   IF THE BUFFER IS A DUPLICATE HEADER,  THE DUPLICATE HEADER BIT    * 00412897
*   IN THE PREFIX (PRFDUPLN IN PRFSTAT1) IS TURNED OFF AND CONTROL    * 00413697
*   PASSES TO INMSG OR OUTMSG PROCESSING.                             * 00414497
*                                                                     * 00415297
*   IF THE BUFFER IS A ZERO-LENGTH BUFFER,  CONTROL PASSES TO INMSG   * 00416097
*   OR OUTMSG PROCESSING.                                             * 00416897
*                                                                     * 00417697
*   IF THE SCAN POINTER IS BEYOND THE END OF THE BUFFER AND THIS IS   * 00418497
*   THE LAST BUFFER,  THE INCOMPLETE HEADER BIT IN THE SCB            * 00419297
*   (SCBHDRRN IN SCBERR1) IS TURNED ON.  CONTROL THEN PASSES TO       * 00420097
*   INMSG OR OUTMSG PROCESSING.                                       * 00420897
*                                                                     * 00421697
*   SELECTION OF INMSG OR OUTMSG PROCESSING IS DETERMINED BY THE      * 00422497
*   SETTING OF THE SEND BIT IN THE LCB (LCBSENDN IN LCBSTATE).        * 00423297
*                                                                     * 00424097
*   ENTRY FROM INMSG MACRO EXPANSION:                                 * 00424897
*   THE SCB DESTINATION QUEUE FIELD (SCBDESTQ) IS EXAMINED.  IF IT    * 00425697
*   IS ZEROES,  NO VALID DESTINATION HAS BEEN FOUND.  THE ADDRESS     * 00426497
*   OF THE BUFFER RETURN QCB,  WHICH IS IN THE AVT (AVTBFRTB),  IS    * 00427297
*   ACCESSED AND STORED IN SCBDESTQ.                                  * 00428097
*                                                                     * 00428897
*   IF THIS IS THE FIRST BUFFER OF A MESSAGE BEING MULTIPLY ROUTED,   * 00429697
*   THE ROUTINE LINKS TO THE BUFFER SCAN ROUTINE (IEDQAX) TO FIND THE * 00430422
*   UNIQUE CHARACTER X'DF',  WHICH FLAGS THE END OF THE FIRST         * 00431297
*   DESTINATION NAME,  IS FOUND.  THE UNIQUE CHARACTER IS THEN        * 00432097
*   REPLACED WITH THE REAL LAST CHARACTER OF THE NAME,  AND ITS       * 00432897
*   OFFSET IS SET INTO THE SCB MULTIPLE ROUTE FIRST SECONDARY         * 00433697
*   DESTINATION FIELD (SCBMRFSD).  IF THE UNIQUE CHARACTER IS NOT     * 00434497
*   FOUND,  SCBMRFSD IS CLEARED TO ZEROES.                            * 00435297
*                                                                     * 00436097
*   IF THIS IS THE LAST BUFFER,  OR IF THE LOGICAL EOM BIT IN THE     * 00436897
*   TIC FIELD OF THE BUFFER IS SET,  THE ADDRESS OF THE BUFFER        * 00437697
*   DISPOSITION QCB IS SET IN THE BUFFER.  OTHERWISE THE DESTINA-     * 00438497
*   TION QCB ADDRESS IN THE SCB (SCBDESTQ) IS SET IN THE BUFFER.      * 00439297
*                                                                     * 00440097
*   UNLESS THIS IS A TSO BUFFER,  THE NUMBER OF UNUSED RESERVE        * 00440897
*   CHARACTERS (FOUND IN LCBISZE) IS SET INTO THE SCAN POINTER        * 00441697
*   FIELD (PRFSCAN).  THE BUFFER IS POSTED TO THE QCB VIA AN EXIT     * 00442497
*   TO THE DISPATCHER AT THE LABEL DSPPOST.                           * 00443297
*                                                                     * 00444097
*   ENTRY FROM OUTMSG MACRO EXPANSION:                                * 00444897
*   IF THIS IS A ZERO-LENGTH BUFFER,  CONTROL PASSES TO INMSG         * 00445697
*   PROCESSING TO POST THE BUFFER TO THE BUFFER DISPOSITION QCB.      * 00446497
*                                                                     * 00447297
*   IF THERE ARE ANY EMPTY UNITS AT THE END OF THE BUFFER (I.E.,      * 00448097
*   UNITS NOT CONTAINING MESSAGE TEXT),  THEY ARE COUNTED AND THEN    * 00448897
*   DE-LINKED FROM THE BUFFER.  AFTER THE UNIT COUNTS (PRFNBUNT) IN   * 00449697
*   EACH STRING OF UNITS IS RESET,  THE STRING OF EMPTY UNITS IS      * 00450497
*   POSTED TO THE BUFFER RETURN QCB VIA A LINK TO THE DISPATCHER AT   * 00451297
*   THE LABEL DSPPOSTR.                                               * 00452097
*                                                                     * 00452897
*   IF THE DESTINATION IS A PROCESS QCB,  THE NUMBER OF UNUSED        * 00453697
*   RESERVE CHARACTERS IS SET IN PRFSCAN AND THE BUFFER IS POSTED     * 00454497
*   TO THE READ-AHEAD QCB VIA AN EXIT TO THE DISPATCHER AT THE        * 00455297
*   LABEL DSPPOST.                                                    * 00456097
*                                                                     * 00456897
*   TESTS ARE MADE TO DETERMINE IF AN UNNEEDED EOA STRING IN THE      * 00457697
*   BUFFER SHOULD BE LOGICALLY REMOVED.  IT SHOULD NOT BE REMOVED     * 00458497
*   IF (1) LINE CONTROL INSERTION HAS BEEN PERFORMED,  (2) IF THE     * 00459297
*   BUFFER IS A TSO BUFFER,  (3) IF THE DESTINATION IS A BINARY       * 00460097
*   SYNCHRONOUS (BISYNC) DEVICE,  (4) IF THE DESTINATION IS AN IBM    * 00460897
*   2260 REMOTE,  OR (5) IF THE DESTINATION IS AN IBM 2760 IN         * 00461697
*   TETE-A-TETE MODE.  THE STRING WILL NOT BE PRESENT IF (1) THE      * 00462497
*   BUFFER IS NOT A HEADER OR (2) THERE IS NO SPECIAL CHARACTERS      * 00463297
*   TABLE FOR THE DESTINATION.  ONLY IF NONE OF THESE CONDITIONS IS   * 00464097
*   PRESENT IS THE EOA STRING (IF PRESENT) LOGICALLY REMOVED.         * 00464897
*                                                                     * 00465697
*   THE CONFIGURATION FOR AN EOA STRING FOR THE DESTINATION IS        * 00466497
*   ACCESSED FROM THE SPECIAL CHARACTERS TABLE AND COMPARED WITH      * 00467297
*   THE FIRST DATA CHARACTERS IN THE BUFFER.  IF THE STRING IS        * 00468097
*   PRESENT,  IT IS LOGICALLY REMOVED BY INCREMENTING THE NUMBER OF   * 00468897
*   UNUSED RESERVE CHARACTERS BY THE LENGTH OF THE EOA STRING.        * 00469697
*                                                                     * 00470497
*   IF THE DESTINATION IS A BISYNC DEVICE IN TRANSPARENT MODE,        * 00471297
*   EXIT IS MADE TO THE TRANSPARENT CCW BUILDER (IEDQGT).  IF NOT,    * 00472097
*   EXIT IS MADE TO THE BUFFER ASSOCIATION ROUTINE (IEDQGD).          * 00472897
*                                                                     * 00473697
*ENTRY POINTS --                                                      * 00474497
*       'IEDQA401' TO INITIALIZE THE BUFFER AND SELECT EXIT FROM      * 00475297
*   THE MESSAGE HANDLER.  ENTRY IS EITHER FROM THE USER INTERFACE     * 00476097
*   ROUTINE OR BY A DIRECT BRANCH FROM THE LINE CONTROL INSERTION     * 00476897
*   ROUTINE (IEDQAK).  CALLING SEQUENCE FROM USER INTERFACE IS:       * 00477697
*                                                                     * 00478497
*        L     R12,AVTMSGS-1            GET ADDR OF VCON TABLE        * 00479297
*        IC    R15,AVTEZERO(,R1)        GET INDEX TO ROUTINE ADDR     * 00480097
*        L     R12,AVTEZERO(R12,R15)    GET ROUTINE ADDRESS           * 00480897
*        BR    R12                      EXIT TO ROUTINE               * 00481697
*                                                                     * 00482497
*   CALLING SEQUENCE FROM IEDQAK IS:                                  * 00483297
*                                                                     * 00484097
*        LA    R15,INDEXA4              SET IEDQA4 INDEX IN R15       * 00484897
*        L     RBASE,AVTMSGS-1          GET MH VCON TABLE ADDRESS     * 00485697
*        L     RBASE,AVTEZERO(R15,RBASE) GET ADDRESS OF IEDQA4        * 00486497
*        BR    RBASE                    ENTER INMSG/OUTMSG ROUTINE    * 00487297
*                                                                     * 00488097
*INPUT --                                                             * 00488897
*   REGISTER 1 - THE ADDRESS OF A MACRO-GENERATED PARAMETER LIST.     * 00489697
*   PARAMETER LIST FORMAT ON ENTRY FROM USER INTERFACE IS:            * 00490497
*                                                                     * 00491297
*        *****************                                            * 00492097
*        * INDEX *       *                                            * 00492897
*        *  TO   * X'02' *                                            * 00493697
*        *   A4  *       *                                            * 00494497
*        *****************                                            * 00495297
*                                                                     * 00496097
*   PARAMETER LIST FORMAT ON ENTRY FROM IEDQAK IS:                    * 00496897
*                                                                     * 00497697
*        *********************************                            * 00498497
*        * INDEX *       * INDEX * INDEX *                            * 00499297
*        *  TO   * X'04' *  TO   *  TO   *                            * 00500097
*        *   AK  *       *   AF  *   AO  *                            * 00500897
*        *********************************                            * 00501697
*                                                                     * 00502497
*   REGISTER 3 - THE ADDRESS OF THE SCB.                              * 00503297
*                                                                     * 00504097
*   REGISTER 4 - THE ADDRESS OF THE LCB                               * 00504897
*                                                                     * 00505697
*   REGISTER 6 - THE ADDRESS OF THE BUFFER.                           * 00506497
*                                                                     * 00507297
*   REGISTER 9 - THE ADDRESS OF THE AVT.                              * 00508097
*                                                                     * 00508897
*   REGISTER 12 - THE ENTRY POINT ADDRESS AND BASE REGISTER FOR       * 00509697
*   THIS ROUTINE.                                                     * 00510497
*                                                                     * 00511297
*OUTPUT --                                                            * 00512097
*   SCB INMSG/OUTMSG MACRO FIELD (SCBMACR) - IF LAST BUFFER,  THE     * 00512897
*   ADDRESS OF THE PARAMETER LIST.                                    * 00513697
*                                                                     * 00514497
*   SCB DESTINATION QCB FIELD (SCBDESTQ) - IF NO VALID DESTINATION    * 00515297
*   ON ENTRY FROM INMSG MACRO EXPANSION,  THE ADDRESS OF THE          * 00516097
*   BUFFER RETURN QCB.                                                * 00516897
*                                                                     * 00517697
*   BUFFER RECB QCB ADDRESS FIELD (PRFQCBA) - IF ENTRY FROM INMSG     * 00518497
*   MACRO EXPANSION AND NOT LAST BUFFER,  THE QCB ADDRESS FROM        * 00519297
*   SCBDESTQ.  IF ENTRY FROM INMSG EXPANSION AND LAST BUFFER,  THE    * 00520097
*   ADDRESS OF THE BUFFER DISPOSITION QCB.  IF ENTRY FROM OUTMSG      * 00520897
*   MACRO EXPANSION AND THE DESTINATION IS A PROCESSING PROGRAM,      * 00521697
*   THE ADDRESS OF THE READ-AHEAD QCB FOR THE PROCESSING PROGRAM.     * 00522497
*                                                                     * 00523297
*   BUFFER RECB PRIORITY BYTE (PRFPRI) - IF THE BUFFER IS BEING       * 00524097
*   POSTED TO THE QCB INDICATED IN PRFDESTQ,  THE DESTINATION-QCB     * 00524897
*   PRIORITY (PRIDESTQ).  IF THE BUFFER IS BEING POSTED TO THE        * 00525697
*   BUFFER DISPOSITION ROUTINE,  THE DISPOSITION-LAST-BUFFER          * 00526497
*   PRIORITY (PRIDSPLB).  IF THE BUFFER IS BEING POSTED TO A          * 00527297
*   PROCESSING PROGRAM,  THE APPLICATION-PROGRAM-BUFFER PRIORITY.     * 00528097
*                                                                     * 00528897
*   REGISTER 1 - ON A POSTING EXIT,  THE ADDRESS OF THE BUFFER.       * 00529697
*                                                                     * 00530497
*EXTERNAL REFERENCES --                                               * 00531297
*   'IEDQAX' - BUFFER SCAN ROUTINE.                              S22025 00532022
*                                                                     * 00532897
*   AVTRNMPT - TNT CODE                                               * 00533697
*                                                                     * 00534497
*   AVT - ADDRESS VECTOR TABLE.                                       * 00535297
*                                                                     * 00536097
*   BUFFER CURRENTLY BEING PROCESSED.                                 * 00536897
*                                                                     * 00537697
*   LCB - LINE CONTROL BLOCK                                          * 00538497
*                                                                     * 00539297
*   SCB - STATION CONTROL BLOCK FOR CURRENT STATION.                  * 00540097
*                                                                     * 00540897
*   DCB - DATA CONTROL BLOCK                                          * 00541697
*                                                                     * 00542497
*   SCT - SPECIAL CHARACTERS TABLE                                    * 00543297
*                                                                     * 00544097
*   TERMINAL TABLE.                                                   * 00544897
*                                                                     * 00545697
*   QCB - THE QUEUE CONTROL BLOCK.                                    * 00546497
*                                                                     * 00547297
*   PEWA - THE PROCESS ENTRY WORK AREA.                               * 00548097
*                                                                     * 00548897
*EXITS,  NORMAL --                                                    * 00549697
*   A BUFFER,  NOT THE LAST BUFFER,  IS PASSED FROM AN INMSG MACRO    * 00550497
*   EXPANSION.  A VALID DESTINATION IS INDICATED IN THE SCB DESTI-    * 00551297
*   NATION QCB FIELD (SCBDESTQ).  THE BUFFER RECB QCB ADDRESS FIELD   * 00552097
*   (PRFQCBA) CONTAINS THE ADDRESS OF THE QCB INDICATED IN            * 00552897
*   SCBDESTQ.  THE BUFFER RECB PRIORITY BYTE (PRFPRI) CONTAINS THE    * 00553697
*   DESTINATION-QUEUE PRIORITY (PRIDESTQ).  REGISTER 1 CONTAINS THE   * 00554497
*   ADDRESS OF THE BUFFER.  EXIT IS TO THE DISPATCHER AT ENTRY        * 00555297
*   POINT DSPPOST.                                                    * 00556097
*                                                                     * 00556897
*   A BUFFER,  NOT THE LAST BUFFER,  IS PASSED FROM AN INMSG MACRO    * 00557697
*   EXPANSION.  SCBDESTQ CONTAINED ZEROES UPON ENTRY,  INDICATING     * 00558497
*   VALID DESTINATION NOT FOUND;  ON EXIT,  SCBDESTQ CONTAINS THE     * 00559297
*   ADDRESS OF THE BUFFER RETURN QCB.  PRFQCBA ALSO CONTAINS THE      * 00560097
*   ADDRESS OF THE BUFFER RETURN QCB.  PRFPRI CONTAINS PRIDESTQ.      * 00560897
*   REGISTER 1 CONTAINS THE ADDRESS OF THE BUFFER.  EXIT IS TO THE    * 00561697
*   DISPATCHER AT ENTRY POINT DSPPOST.                                * 00562497
*                                                                     * 00563297
*   THE LAST BUFFER OF A MESSAGE IS PASSED FROM AN INMSG MACRO        * 00564097
*   EXPANSION.  THE SCB INMSG/OUTMSG MACRO FIELD (SCBMACR) CONTAINS   * 00564897
*   THE ADDRESS OF THE PARAMETER LIST.  A VALID DESTINATION IS        * 00565697
*   INDICATED IN SCBDESTQ.  PRFQCBA CONTAINS THE ADDRESS OF THE       * 00566497
*   BUFFER DISPOSITION QCB.  PRFPRI CONTAINS THE DISPOSITION-LAST-    * 00567297
*   BUFFER PRIORITY (PRIDSPLB).  REGISTER 1 CONTAINS THE ADDRESS      * 00568097
*   OF THE BUFFER.  EXIT IS TO THE DISPATCHER AT ENTRY POINT          * 00568897
*   DSPPOST.                                                          * 00569697
*                                                                     * 00570497
*   THE LAST BUFFER OF A MESSAGE IS PASSED FROM AN INMSG MACRO        * 00571297
*   EXPANSION.  SCBMACR CONTAINS THE ADDRESS OF THE PARAMETER LIST.   * 00572097
*   SCBDESTQ CONTAINED ZEROES UPON ENTRY,  INDICATING VALID DESTI-    * 00572897
*   NATION NOT FOUND;  ON EXIT,  SCBDESTQ CONTAINS THE ADDRESS OF     * 00573697
*   THE BUFFER RETURN QCB.  PRFQCBA CONTAINS THE ADDRESS OF THE       * 00574497
*   BUFFER DISPOSITION QCB.  PRFPRI CONTAINS PRIDSPLB.  REGISTER 1    * 00575297
*   CONTAINS THE ADDRESS OF THE BUFFER.  EXIT IS TO THE DISPATCHER    * 00576097
*   AT ENTRY POINT DSPPOST.                                           * 00576897
*                                                                     * 00577697
*   A BUFFER IS PASSED FROM AN OUTMSG MACRO EXPANSION OR FROM THE     * 00578497
*   LINE CONTROL INSERTION ROUTINE.  THE DESTINATION IS EITHER NOT    * 00579297
*   A BISYNC DEVICE OR A BISYNC DEVICE NOT IN TRANSPARENT MODE.       * 00580097
*   EXIT IS TO THE BUFFER ASSOCIATION ROUTINE.                        * 00580897
*                                                                     * 00581697
*   A BUFFER IS PASSED FROM AN OUTMSG MACRO EXPANSION OR FROM THE     * 00582497
*   LINE CONTROL INSERTION ROUTINE.  THE DESTINATION IS A BISYNC      * 00583297
*   DEVICE IN TRANSPARENT MODE.  EXIT IS TO THE TRANSPARENT CCW       * 00584097
*   BUILDER.                                                          * 00584897
*                                                                     * 00585697
*   A BUFFER IS PASSED FROM AN OUTMSG MACRO EXPANSION OR FROM THE     * 00586497
*   LINE CONTROL INSERTION ROUTINE.  THE DESTINATION IS A PROCESS-    * 00587297
*   ING PROGRAM.  THE BUFFER IS POSTED TO THE READ-AHEAD QCB VIA      * 00588097
*   A BRANCH TO THE DISPATCHER AT THE LABEL DSPPOST.                  * 00588897
*                                                                     * 00589697
*EXITS,  ERROR -- N/A.                                                * 00590497
*                                                                     * 00591297
*TABLES/WORK AREAS -- N/A.                                            * 00592097
*                                                                     * 00592897
*ATTRIBUTES -- SERIALLY REUSABLE, REFRESHABLE, ENABLED, RESIDENT,     * 00593697
*   PROBLEM PROGRAM MODE.                                             * 00594497
*                                                                     * 00595297
*NOTES -- THE OPERATION OF THIS MODULE DOES NOT DEPEND UPON AN        * 00596097
*   INTERNAL REPRESENTATION OF THE EXTERNAL CHARACTER SET.            * 00596897
*                                                                     * 00597697
*********************************************************************** 00598497
         EJECT                                                          00599297
********* REGISTER EQUATES *********                                    00600020
         SPACE                                                          00800020
R0       EQU   0                        WORK REGISTER                   01000020
         SPACE                                                          01200020
R1       EQU   1                        PROGRAM PARAMETER REGISTER      01400020
*                                                                       01600020
RWORK    EQU   2                        WORK REG                 S22024 01800022
*                                                                       02000020
RSCB     EQU   3                        BASE REGISTER FOR SCB           02200020
R3       EQU   3                        WORK REGISTER            S22024 02300022
*                                                                       02400020
RLCB     EQU   4                        BASE REGISTER FOR LCB           02600020
         SPACE                                                          02800020
RSCAN5   EQU   5                        WORK REGISTER                   03000020
         SPACE                                                          03200020
RPREFIX  EQU   6                        BASE REGISTER FOR BUFFER        03400020
         SPACE                                                          03600020
RSCT7    EQU   7                        SPECIAL CHARS TABLE ADDRESS     03800020
RSCANOFF EQU   7                        BUFFER STEP OFFSET REGISTER     04000020
RQCB     EQU   7                        QCB ADDRESS              S22024 04100022
         SPACE                                                          04200020
RAVT     EQU   9                        BASE FOR AVT                    04400020
         SPACE                                                          04600020
RDISP    EQU   11                       ENTRY TO DISPATCHER             04800020
         SPACE                                                          05000020
R12      EQU   12                       REG 12                   S22024 05200022
R13      EQU   13                       ADDRESS OF AVT           S22025 05300022
         SPACE                                                          05400020
R14      EQU   14                       WORK REGISTER                   05600020
R15      EQU   15                       ENTRY POINT AND RETURN CODE     05800020
*                                                                       06000020
********* OTHER EQUATES *********                                       06200020
         SPACE                                                          06400020
ONE      EQU   1                        INCREMENT VALUE OF ONE          06600020
TWO      EQU   2                        COMPARE LNG FOR LAST UNIT       06800020
THREE    EQU   3                        LENGTH OF A 3-BYTE ADDRESS      07000020
         SPACE                                                          07200020
LEOMFLAG EQU   X'80'                    LOGICAL EOM FLAG                07400020
F2260R   EQU   X'02'                    IBM 2260 REMOTE FLAG            07600020
F2760    EQU   X'01'                    IBM 2760 FLAG                   07800020
UNIQUE   EQU   X'DF'                    MULTIPLE ROUTE BYTE             08000020
         SPACE                                                          08200020
SCTEOA   EQU   1                        SCT INDEX BYTE TO EOA           08400020
         SPACE                                                          08600020
ZERO     EQU   8                        CONDITION CODE: ZERO            08800020
         EJECT                                                          09000020
         USING IEDQAVTD,RAVT                                            09200020
         USING IEDQDISP,RDISP                                           09400020
         USING IEDQSCB,RSCB             GIVE SCB A BASE                 09600020
         USING IEDQLCB,RLCB             GIVE LCB A BASE                 09800020
         USING IEDQPRF,RPREFIX          GIVE PREFIX A BASE              10000020
         USING IEDQA4,R12                                               10200020
         SPACE                                                          10400020
IEDQA401 EQU   *                                                        10600020
IEDQA4   IEDHJN INOUTMSG                ID AND DATE              S22025 10800022
         LA    R13,AVTSAVE2             SET R13 FOR TCAM         S22025 11400022
         TM    PRFSTAT1,PRFNLSTN        LAST BUFFER                     11600020
         BO    TESTTSO                  NO, DON'T SAVE PARM ADDR        11800020
*                                       YES, SAVE IT                    12000020
         SPACE                                                          12200020
         IC    R15,SCBMBHEN-1           SAVE HI-ORDER BYTE              12400020
         ST    R1,SCBMBHEN-1            STORE PARAM LIST ADDR           12600020
         STC   R15,SCBMBHEN-1           RESTORE HI-ORDER BYTE           12800020
         SPACE                                                          13000020
TESTTSO  EQU   *                                                        13100020
         TM    LCBTSOB,LCBTSBUF         IS THIS TSO                 TSO 13200020
         BO    TSTENTRY                 YES, DON'T PASS SCAN PTR,   TSO 13300020
*                                         DON'T SET INCL HDR        TSO 13400020
         SPACE                                                          13500020
         SR    R0,R0                    TEST IF ZERO-                   13600020
         CH    R0,PRFSIZE                 LENGTH BUFFER                 13700020
         BE    TSTENTRY                 YES, DON'T SET INCL HDR,        13800020
*                                         DON'T PASS SCAN POINTER       13900020
         SPACE                                                          14000020
         CLC   PRFSCAN,PRFSIZE          SCAN PTR BEYOND END OF BFR      14100020
         BNH   PASSSCAN                 NO, DON'T SET INCL HDR          14200020
         SPACE                                                          14300020
         TM    PRFSTAT1,PRFDUPLN+PRFNLSTN DUPL HDR OR NOT LAST BFR      14400020
         BNZ   PASSSCAN                 YES, DON'T SET INCL HDR         14500020
         SPACE                                                          14600020
         OI    SCBERR1,SCBHDRRN         SET INCOMPLETE HEADER BIT       14700020
         SPACE                                                          14800020
PASSSCAN EQU   *                                                        14900020
         TM    PRFSTAT1,PRFNHDRN        IS THIS A TEXT BUFFER           15000020
         BO    TSTENTRY                 YES, DON'T PASS SCAN PTR        15100020
         SPACE                                                          15200020
         LA    RWORK,AVTEFF             SET DEFAULT VALUE               15300020
         CLC   PRFSCAN,AVTCLRHI+1       SCAN HIGHER THAN 255            15400020
         BH    SETSCAN                  YES, PASS DEFAULT VALUE         15500020
         SPACE                                                          15600020
         IC    RWORK,PRFSCAN+1          NO, PASS TRUE SCAN POINTER      15700020
         SPACE                                                          15800020
SETSCAN  EQU   *                                                        15900020
         STC   RWORK,PRFSCAN            PASS SCAN PTR IN BUFFER         16000020
         SPACE                                                          18800020
TSTENTRY EQU   *                                                        19000020
         NI    PRFSTAT1,PRFDUPLF        MAKE SURE DUPL HDR FLAG OFF     19100020
         TM    LCBSTATE,LCBSENDN        SENDING OR RECEIVING?           19200020
         BO    OUTMSG                   SENDING, OUTMSG PROCESSING      19400020
*        B     INMSG                    RECEIVE, INMSG PROCESSING       19600020
         EJECT                                                          19800020
* THIS SECTION OF CODE PROVIDES FOR ENTRY FROM INMSG MACRO              20000020
         SPACE                                                          20200020
INMSG    EQU   *                                                        20400020
         NI    PRFSTAT1,PRFCNCLF        TURN OFF CANCEL BIT IF ON       20500020
         SPACE                                                          22200020
TESTMLTR EQU   *                                                        22400020
         TM    PRFSTAT1,PRFNHDRN        IS THIS A HEADER BUFFER         22600020
         BO    TESTPOST                 NO, BYPASS MULT ROUTE TEST      22800020
         SPACE                                                          23000020
         LH    R15,SCBMRFSD             IS THERE MULT ROUTING           23200020
         LTR   R15,R15                                                  23400020
         BZ    TESTPOST                 NO, PROCEED                     23600020
         SPACE                                                          23800020
         SR    RSCANOFF,RSCANOFF        YES, PICK UP NO. OF             24000020
         IC    RSCANOFF,LCBISZE           RESERVE CHARACTERS            24200020
         LA    RSCANOFF,AVTHDRSZ(,RSCANOFF) ADD PREFIX SIZE             24400020
         LR    R0,RSCANOFF              PASS SCAN PTR OFFSET     S22025 24600022
         LNR   RWORK,R12                INSURE REG 2 IS NEGATIVE S22025 24800022
         MVI   AVTPARM,X'01'            MOVE CHAR COUNT TO PARM  S22025 25000022
         MVI   AVTPARM+1,X'DF'          MOVE CHAR STRING TO PARM S22025 25200022
         LA    R1,AVTPARM               LOAD ADDR OF CHAR STRING S22025 25400022
         L     R15,AVTAX                LOAD SCAN ROUTINE ADDR   S22025 25600022
         BALR  R14,R15                  BRANCH TO SCAN ROUTINE   S22025 25800022
         LTR   R15,R15                  OUT OF BUFFER            S22025 26000022
         BZ    NOMULTR                  YES, CLEAR               S22025 26200022
         SPACE                                                          26400022
         SPACE                                                          27200020
         IC    R15,SCBMRFSD+1           REPLACE 'DF' WITH        S22025 27400022
         STC   R15,AVTEZERO(,R1)          SAVED CHARACTER        S22025 27600022
         STH   R0,SCBMRFSD              SAVE OFFSET IN SCB       S22025 27800022
         TM    SCBERR2,SCBFRWDN         FORWARD ERROR           SA59523 27840022
         BNO   TESTPOST                 BRANCH IF NO            SA59523 27880022
         SR    RWORK,RWORK              CLEAR OFFSET            SA59523 27920022
         B     NOMULTR                  PROCEED                 SA59523 27960022
         SPACE                                                          28200020
NOMULTR  EQU   *                                                        28400020
         STH   RWORK,SCBMRFSD             TO ZEROES                     28800020
         SPACE                                                          29000020
TESTPOST EQU   *                                                        29200020
         TM    PRFSTAT1,PRFNLSTN        IS IT END OF MESSAGE            29400020
         BZ    POSTDISP                 YES - GO TO POST TO DISPOSIT    29600020
         SPACE                                                          29800020
         TM    PRFTIC,LEOMFLAG          TEST FOR LOGICAL EOM            30000020
         BO    POSTDISP                 ON, POST TO DISPOSITION         30200020
*                                                                       30400020
* THIS SECTION POSTS THE BUFFER, WHICH IS NOT THE LAST BUFFER OF A      30600020
* MESSAGE, TO THE QCB FOR ITS DESTINATION                               30800020
*                                                                       31000020
         MVC   PRFRCB+1(THREE),SCBDESTQ                                 31200020
         L     R15,SCBDESTQ-1          GET DESTINATION           A42391 31220097
         LA    R15,AVTEZERO(,R15)      CLEAR HI ODER BYTE        A42391 31240097
         LA    RLCB,AVTBFRTB           ADDR OF BUF RTN QCB       A42391 31260097
         CR    RLCB,R15                BUF RTN THE DEST ?        A42391 31280097
         BNE   NORTN                   BRANCH NO                 A42391 31300097
         MVI   PRFPRI,PRILNFRE         POST WITH LOW PRIORITY    A42391 31320097
         B     SETRESER                GO PASS NO IDLES          A42391 31340097
NORTN    EQU   *                                                        31360097
         MVI   PRFPRI,PRIDESTQ          SET PRIORITY                    31400020
         TM    PRFSTAT1,PRFNHDRN        IS THIS A HEADER BUFFER         31600020
         BO    SETRESER                 NO, GO PASS NO. IDLES           31800020
         SPACE                                                          32000020
         MVI   PRFPRI,PRIDESTQ+1        YES, SET HIGHER PRIORITY        32200020
         B     SETRESER                 GO PASS NO. REMAINING IDLES     32400020
*                                                                       32600020
POSTDISP EQU   *                                                        32800020
*                                                                       33000020
* THIS SECTION POSTS THE LAST BUFFER OF A MESSAGE TO THE QCB FOR        33200020
* THE DISPOSITION ROUTINE                                               33400020
*                                                                       33600020
         L     RWORK,AVTMSGS-1          GET VCON TABLE ADDR             33800020
         MVC   PRFQCBA,ONE(RWORK)       PUT BUF DISP QCB IN PREF S22025 34000022
         MVI   PRFPRI,PRIDSPLB          SET PRIORITY                    34800020
         SPACE                                                          35000020
SETRESER EQU   *                                                        35200020
         L     RLCB,PRFLCB-1            RESET LCB ADDRESS               35400020
         TM    LCBTSOB,LCBTSBUF         IS THIS A TSO BUFFER            35600020
         BO    EXIT                     YES, DON'T PASS IDLES           35800020
         SPACE                                                          36000020
         B     MOVEIDL                  BRANCH TO PASS IDLES     S22025 36200022
         EJECT                                                          37000020
* THIS SECTION OF CODE PROVIDES FOR ENTRY FROM OUTMSG MACRO             37200020
         SPACE                                                          37400020
OUTMSG   EQU   *                                                        37600020
         LH    RSCAN5,PRFSIZE           PICK UP LENGTH OF BUFFER        37800020
         N     RSCAN5,AVTCLRHI          IS IT ZERO-LENGTH BUFFER        38000020
         BZ    POSTDISP                 YES, POST IT TO BFR DISP        38200020
         SPACE                                                          38400020
         LR    RWORK,RPREFIX            LOAD PREFIX ADDR         S22025 38600022
         BAL   R14,ENTERLOP             GET ADDR OF SCAN POINTER S22025 38900022
         SPACE                                                          39200020
         CLC   PRFTIC+1-IEDQPRF(TWO,RWORK),AVTFZERO IS IT LAST UNIT     39400020
         BE    TESTPROC                 YES, NONE EMPTY, PROCEED        39600020
         SPACE                                                          39800020
         LR    RSCAN5,RWORK             NO, SAVE LAST DATA UNIT         40000020
         SR    R1,R1                    CLEAR COUNT REG                 40200020
         SPACE                                                          40400020
NOTLAST  EQU   *                                                        40600020
         LA    R1,ONE(,R1)              COUNT EMPTY UNIT                40800020
         L     RWORK,PRFTIC-IEDQPRF(,RWORK) GET EMPTY UNIT'S ADDR       41000020
         CLC   PRFTIC+1-IEDQPRF(TWO,RWORK),AVTFZERO IS IT LAST UNIT     41200020
         BNE   NOTLAST                  NO, COUNT IT & GET NEXT ONE     41400020
         SPACE                                                          41600020
         LR    R0,R1                    YES, SAVE NO. EMPTY UNITS       41800020
         IC    R1,PRFNBUNT              RESET COUNT IN                  42000020
         SR    R1,R0                      PREFIX TO NUMBER              42200020
         STC   R1,PRFNBUNT                OF UNITS WITH DATA            42400020
         SPACE                                                          42600020
         L     R1,PRFTIC-IEDQPRF(,RSCAN5) GET ADDR FIRST EMPTY UNIT     42800020
         MVC   PRFTIC+1-IEDQPRF(THREE,RSCAN5),PRFTIC+1-IEDQPRF(RWORK)   43000020
*                                       INDICATE LAST DATA UNIT         43200020
*                                         IS LAST UNIT                  43400020
         LA    RWORK,AVTBFRTB           SET BUFFER RETURN QCB ADDR      43600020
         ST    RWORK,PRFQCBA-1-IEDQPRF(,R1) IN FIRST EMPTY UNIT         43800020
         MVI   PRFPRI-IEDQPRF(R1),PRIBFRTB SET BUFFER PRIORITY          44000020
         STC   R0,PRFNBUNT-IEDQPRF(,R1) SET NUMBER OF EMPTY UNITS       44200020
         L     RDISP,AVTEA              GET ADDRESS OF DISPATCHER       44400020
         BAL   R14,DSPPOSTR             LINK TO POST EMPTY UNITS        44600020
         SPACE                                                          44800020
         L     RSCB,LCBSCBA-1           RESTORE SCB ADDRESS             45000020
         SPACE                                                          45200020
TESTPROC EQU   *                                                        45400020
         L     R1,SCBDESTQ-1            GET QCB ADDRESS                 45600020
         USING IEDQQCB,R1                                               45800020
         SPACE                                                          46000020
         TM    QCBFLAG,QCBPROC          IS IT PROCESS QCB               46200020
         BO    POSTMPP                  YES, GO GET QCB ADDRESS         46400020
         SPACE                                                          46600020
DOUBLEOA EQU   *                                                        46800020
         TM    PRFSTAT1,PRFNHDRN        IS THIS A HEADER BUFFER         47000020
         BO    SELEXIT                  NO, NO DOUBLE EOA, GO ON        47200020
         SPACE                                                          47400020
         TM    SCBSTATE,SCBMGFMN        WAS LINE CONTROL INSERTED       47600020
         BO    SELEXIT                  YES, NO DOUBLE EOA, GO ON       47800020
         SPACE                                                          48000020
         TM    LCBSTAT2,LCBSYNC         IS DESTINATION BISYNC           48200020
         BO    SELEXIT                  YES, LEAVE STX IN BUFFER        48400020
         SPACE                                                          48600020
         TM    LCBTSOB,LCBTSBUF         IS THIS A TSO BUFFER            48800020
         BO    SELEXIT                  YES, NO DOUBLE EOA, GO ON       49000020
         SPACE                                                          49200020
         LH    R1,PRFDEST               GET DESTINATION KEY             49400020
         N     R1,AVTCLRHI              CLEAR TOP HALF OF REGISTER      49600020
         L     R15,AVTRNMPT             LINK TO GET ADDRESS OF          49800020
         BALR  R14,R15                    TERMINAL TABLE ENTRY          50000020
         SPACE                                                          50200020
         USING IEDQTRM,R1                                               50400020
         SR    R15,R15                  (CLEAR FOR INSERT)              50600020
         IC    R15,TRMCHCIN             PICK UP DEV CHAR TBL INDEX      50800020
         BCTR  R15,AVTEZERO             DECR TO MAKE TRUE INDEX         51000020
         SLL   R15,TWO                  SHIFT TO MAKE OFFSET            51200020
         A     R15,AVTCSTCS             GET THIS TERM'S ENTRY ADDR      51400020
         TM    THREE(R15),F2260R        TEST IF 2260 REMOTE             51600020
         BO    SELEXIT                  YES, LEAVE STX IN BUFFER        51800020
         SPACE                                                          52000020
         TM    THREE(R15),F2760         TEST IF IBM 2760                52200020
         BNO   ELIMEOA                  NO, GO ELIMINATE EOA            52400020
         SPACE                                                          52600020
         TM    LCBSTAT2,LCBRESP         YES, TEST IF TETE-A-TETE        52800020
         BO    SELEXIT                  YES, LEAVE IN EOA               53000020
         SPACE                                                          53200020
ELIMEOA  EQU   *                                                        53400020
         L     RSCT7,LCBDCBPT           GET DCB ADDRESS FROM LCB        53600020
         USING IHADCB,RSCT7                                             53800020
         L     RSCT7,DCBSCTAD-1         GET SCT ADDRESS FROM DCB        54000020
         LA    RSCT7,AVTEZERO(,RSCT7)   CLEAR HIGH-ORDER BYTE           54200020
         LTR   RSCT7,RSCT7              IS THERE AN SCT                 54400020
         BZ    SELEXIT                  NO, NO DOUBLE EOA, GO ON        54600020
         SPACE                                                          54800020
         SR    R15,R15                  (CLEAR FOR INSERT)              55000020
         IC    R15,SCTEOA(,RSCT7)       GET EOA INDEX BYTE              55200020
         LA    RWORK,ONE(R15,RSCT7)     POINT TO EOA                    55400020
         IC    R15,AVTEZERO(R15,RSCT7)  PICK UP LENGTH OF EOA           55600020
         LR    RSCT7,RWORK              RESET EOA ADDRESS               55800020
         SPACE                                                          56000020
         LR    R14,R15                  (CLEAR FOR INSERT)              56200020
         IC    R14,LCBISZE              PICK UP RESERVE CHARS COUNT     56400020
         LA    RWORK,PRFSHDR(R14)       POINT TO START OF DATA          56600020
         BCTR  R15,AVTEZERO             (DECREMENT FOR EXECUTE)         56800020
         EX    R15,CLCEOA               IS EOA STRING IN BUFFER         57000020
         BNE   SELEXIT                  NO, NO DOUBLE EOA, GO ON        57200020
         SPACE                                                          57400020
         LA    R15,ONE(R14,R15)         YES, BUMP RESERVE COUNT BY      57600020
         STC   R15,LCBISZE                EOA LENGTH AND STORE BACK     57800020
         SPACE                                                          58000020
SELEXIT  EQU   *                                                        58200020
         NI    LCBSTAT2,AVTEFF-LCBRESP  TURN OFF TETE-A-TETE FLAG       58400020
         CLI   LCBFLAG1,AVTEZERO        IS THIS A 3705 PLCB ?    S22024 58450022
         BE    PLCB3705                 YES, PROCESS NEXT STCB INS22024 58500022
*                                       OUTDH QCB                S22024 58550022
         L     R15,AVTGD                NO, GET ADDR OF BFR ASSOC       58600020
         TM    LCBSTAT2,LCBSYNC         TEST IF BISYNC                  58800020
         BCR   ZERO,R15                 NO, GO TO BFR ASSOCIATION       59000020
         SPACE                                                          59200020
         TM    SCBSTATE,SCBTRANP        TEST IF TRANSPARENT             59400020
         BCR   ZERO,R15                 NO, GO TO BFR ASSOCIATION       59600020
         SPACE                                                          59800020
         L     R15,AVTGT                ELSE GET TRANS CCW BUILDER      60000020
         BR    R15                        ADDR & GO TO IT               60200020
         SPACE 2                                                        60201022
PLCB3705 EQU   *                                                 S22024 60202022
         L     RQCB,AVTSAVTP            SECONDARY AVT ADDRESS    S22024 60203022
         L     RQCB,SAVTODQB-IEDNSVTD(RQCB) GET OUTDH QCB ADDR   S22024 60204022
         L     R3,QCBSTCHN-ONE-IEDQQCB(RQCB) GET NEXT STCB ADDR  S22024 60205022
         MVI   PRFPRI,PRIMHBFR          SET PRIORITY FOR MH      S22024 60206022
         LR    R1,RPREFIX               PARAMETER FOR POST       S22024 60207022
         L     RDISP,AVTEA              ADDR OF DISPATCHER       S22024 60208022
         B     DSPBYPAS                 RETURN TO DISPATCHER TO  S22024 60209022
*                                       PROCESS NEXT STCB        S22024 60210022
         SPACE 3                                                        60211022
ADDRLOOP EQU   *                                                 S22025 60220022
         L    RWORK,PRFTIC-IEDQPRF(RWORK) POINT TO NEXT UNIT     S22025 60240022
         SH    RSCAN5,AVTKEYLE          SUBTRACT NO. BYTES PASSEDS22025 60260022
ENTERLOP EQU   *                                                 S22025 60280022
         CH    RSCAN5,AVTKEYLE          IS ITEM IN THIS UNIT     S22025 60300022
         BH    ADDRLOOP                 NO, TEST NEXT UNIT       S22025 60320022
         LA    RSCAN5,AVTUMALN-1(RSCAN5,RWORK) GET ADDR OF ITEM  S22025 60340022
         BR    R14                      RETURN TO CALLER         S22025 60360022
         EJECT                                                          60400020
POSTMPP  EQU   *                                                        60600020
         SPACE                                                          61400020
         USING IEDQQCB,R1                                               61600020
         L     R1,QCBPREN               GET TERM TABLE ENTRY ADDR       61800020
         USING IEDQTRM,R1                                               62000020
         SPACE                                                          62200020
         L     R1,TRMSTAT               GET ADDR OF PROCESS ENTRY       62400020
*                                         WORK AREA                     62600020
         USING IEDQPEWA,R1                                              62800020
         SPACE                                                          63000020
         LA    R1,PERAQCB               GET READ-AHEAD QCB ADDR         63200020
         ST    R1,PRFRCB                PUT IT IN THE RECB              63400020
         MVI   PRFPRI,PRIAPBFR          SET PRIORITY                    63600020
MOVEIDL  EQU   *                                                 S22025 63650022
         IC    RWORK,LCBISZE            PICK UP RESERVE COUNT    S22025 63700022
         STC   RWORK,PRFSCAN+1          PUT IN SCAN PTR FIELD    S22025 63750022
         SPACE                                                          63800020
EXIT     EQU   *                                                        64000020
*                                                                       64200020
* THIS SECTION COMPLETES CONSTRUCTION OF THE POST PARAMETER LIST        64400020
* AND RETURNS CONTROL TO THE DISPATCHER                                 64600020
         SPACE                                                          64800020
         LR    R1,RPREFIX               GET RECB ADDR IN R1             65000020
         L     RDISP,AVTEA              GET ADDRESS OF DISPATCHER       65200020
         B     DSPPOST                  EXIT TO POST RECB               65400020
         SPACE                                                          65600020
********* EXECUTED INSTRUCTION *********                                65800020
         SPACE                                                          66000020
CLCEOA   CLC   AVTEZERO(AVTEZERO,RWORK),AVTEZERO(RSCT7) COMPARE  S22024 66200022
         EJECT                                                          66400020
********* DSECTS *********                                              66600020
         SPACE 3                                                        66800020
         TAVTD                                                          67000020
         SPACE                                                          67200020
AVTGT    EQU   AVTA3                    TRANSPARENT CCW BUILDER         67400020
         EJECT                                                          67600020
         DCBD  DSORG=TX                                                 67800020
         EJECT                                                          68000020
         TDISPD                                                         68200020
         EJECT                                                          68400020
         TLCBD                                                          68600020
         EJECT                                                          68800020
         TPEWAD                                                         69000020
         EJECT                                                          69200020
         TPRFD                                                          69400020
         EJECT                                                          69600020
         TPRIOR                                                         69800020
         EJECT                                                          70000020
         TQCBD                                                          70200020
         EJECT                                                          70400020
         TSCBD                                                          70600020
         EJECT                                                          70800020
         TTRMD                                                          71000020
         END                                                            71200020
