A501     TITLE '''IEDQA5'' -- FORWARD ROUTINE'                          00400020
IEDQA5   CSECT                                                          00800020
         SPACE 3                                                        00806005
*  CHANGE ACTIVITY AS FOLLOWS                                           00808005
******************** MICROFICHE FLAGS *********************** SUPT CODE 00810005
*C721200                                                        SA59039 00812005
*C856000-861000                                                 SA59523 00812105
*C293000                                                         S22029 00812205
*A066000,192500,214000,215000,222000,270000,489000,491000        S22025 00812305
*A497000,498000,519000,708600-721200,731700,731800,884010-884220 S22025 00812405
*A891000-898600,290200-291800,690000,701000-703000               S22025 00812505
*C492000-496000,512000,712000,720000                             S22025 00812605
*D264000-280000,500000,888000-896000,298000                      S22025 00812705
*A214200-214600,234000,340500-341500,356200-357600,404500-406500 S22027 00812805
*A676800-679200                                                  S22027 00812905
*C013470-013480,013500-013510,013530-013550,304000,372000,380000 S22027 00813005
*C404000                                                         S22027 00813105
*A884045-884046,885000                                          SA56226 00813205
*C833800                                                        OX01422 00813305
*A839000                                                        OX01422 00813405
*C833800                                                        SA67104 00813553
*D839200-839600                                                 SA67104 00813653
         SPACE                                                          01200020
*********************************************************************** 01201020
*                                                                     * 01201105
*  TITLE:  'IEDQA5' -- FORWARD ROUTINE                                * 01201305
*                                                                     * 01201505
*  MODULE NAME = IEDQA5                                               * 01201705
*                                                                     * 01201905
*  DESCRIPTIVE NAME = FORWARD ROUTINE                                 * 01202105
*                                                                     * 01202305
*  COPYRIGHT = 'NONE'                                                 * 01202505
*                                                                     * 01202705
*STATUS: CHANGE LEVEL 5                                               * 01202953
*                                                                     * 01204020
*FUNCTION --                                                          * 01205020
*   DETERMINES THE DESTINATION TO WHICH A MESSAGE IS TO BE SENT ON    * 01206020
*   ENTRY FROM THE MCP OR FROM THE MULTIPLE ROUTING SUBTASK.          * 01207020
*                                                                     * 01208020
*   IF THE BUFFER IS A ZERO-LENGTH BUFFER,  RETURN IS MADE TO THE     * 01209020
*   CALLER IMMEDIATELY.                                               * 01210020
*                                                                     * 01211020
*   WHEN THE FORWARD ROUTINE IS ENTERED REGISTER 1 POINTS TO A        * 01212020
*   STRING OF UP TO THREE PARAMETER LISTS,  THE FIRST LIST OF WHICH   * 01213020
*   IS THE PARAMETER LIST FOR THE FORWARD ROUTINE ITSELF.  THE        * 01214020
*   FORWARD ROUTINE SAVES THE ADDRESS OF THE FIRST PARAMETER LIST     * 01215020
*   IN THE SCB MULTIPLE-ROUTE FORWARD LIST FIELD (SCBMRFPL).  THE     * 01216020
*   FORWARD ROUTINE PASSES THE ADDRESS OF THE SECOND PARAMETER LIST   * 01217020
*   TO THE USER INTERFACE ROUTINE,  THUS LINKING TO ONE OF THREE      * 01218020
*   POSSIBLE SUBSIDIARY ROUTINES.                                     * 01219020
*                                                                     * 01220020
*   UPON RETURN,  THE FORWARD ROUTINE DETERMINES WHAT SUBSIDIARY      * 01221020
*   ROUTINE WAS EXECUTED BY TESTING A STATUS BYTE IN THE FORWARD      * 01222020
*   PARAMETER LIST.                                                   * 01223020
*                                                                     * 01224020
*                                                                     * 01225020
*   RETURN FROM IEDQAI:                                               * 01226020
*                                                                     * 01227020
*   IF THE SUBSIDIARY ROUTINE WAS THE SKIP FORWARD AND SCAN           * 01228020
*   ROUTINE (IEDQAI), THE NAME OF THE DESTINATION HAS BEEN PICKED     * 01229020
*   UP FROM THE BUFFER.  IF REGISTER 15 CONTAINS A NEGATIVE RETURN    * 01230020
*   CODE,  THE DESTINATION NAME IS NOT COMPLETE IN THE CURRENT        * 01231020
*   BUFFER.  IF THE CALLER IS THE MULTIPLE ROUTING SUBTASK,  THE      * 01232020
*   FORWARD ROUTINE RETURNS TO IT WITH THE NEGATIVE RETURN CODE.      * 01233020
*   OTHERWISE CONTROL PASSES TO THE ERROR RECOVERY PROCEDURE.         * 01234020
*                                                                     * 01235020
*   THE FORWARD ROUTINE TESTS IF AN END-OF-ADDRESS STRING WAS         * 01236020
*   DEFINED IN THE MACRO (INDICATED BY THE STATUS BYTE).  IF SO,      * 01237020
*   THE FIELD RETURNED BY IEDQAI MAY BE THAT STRING,  AND THE         * 01238020
*   FORWARD ROUTINE COMPARES THE STRING RETURNED WITH THE END-OF-     * 01239020
*   ADDRESS STRING.  IF THEY MATCH,  THE FORWARD ROUTINE TESTS TO     * 01240020
*   SEE IF IT HAS BEEN ENTERED FROM THE MULTIPLE ROUTING SUBTASK.     * 01241020
*   IF IT HAS NOT,  NO VALID DESTINATION HAS BEEN FOUND,  AND THE     * 01242020
*   FORWARD ROUTINE PROCEEDS TO THE ERROR RECOVERY PROCEDURE.  IF     * 01243020
*   ENTRY IS FROM THE MULTIPLE ROUTING SUBTASK,  THE FORWARD          * 01244020
*   ROUTINE CLEARS THE SECONDARY DESTINATION FIELD IN THE SCB         * 01245020
*   (SCBMRFSD) TO ZERO AND RETURNS TO THE CALLER WITH A RETURN CODE   * 01246020
*   OF X'08' IN REGISTER 15.                                          * 01247020
*                                                                     * 01248020
*   IF THE STRINGS DO NOT MATCH,  OR IF NO END-OF-ADDRESS STRING      * 01249020
*   WAS DEFINED,  THE FORWARD ROUTINE BUMPS THE PREFIX SCAN POINTER   * 01250020
*   (PRFSCAN) PAST THE STRING RETURNED AND PREPARES TO LINK TO THE    * 01251020
*   ROUTINE REPRESENTED BY THE THIRD PARAMETER LIST,  WHICH IS THE    * 01252020
*   BINARY SEARCH ROUTINE (IEDQA1).  THE ADDRESS AND LENGTH OF THE    * 01253020
*   STRING RETURNED ARE SET IN THE IEDQA1 PARAMETER LIST AND LINK-    * 01254020
*   AGE IS MADE TO IEDQA1 VIA THE USER INTERFACE ROUTINE.             * 01255020
*                                                                     * 01256020
*                                                                     * 01257020
*   RETURN FROM IEDQAE:                                               * 01258020
*                                                                     * 01259020
*   IF THE SUBSIDIARY ROUTINE WAS THE LOCATE OPTION FIELD ROUTINE     * 01260020
*   (IEDQAE),  THE NAME OF THE DESTINATION IS LOCATED IN AN OPTION    * 01261020
*   FIELD WHOSE ADDRESS SHOULD BE RETURNED BY IEDQAE IN REGISTER      * 01262020
*   15.  IF REGISTER 15 CONTAINS ZERO,  THE FORWARD ROUTINE           * 01263020
*   PROCEEDS TO THE ERROR RECOVERY PROCEDURE.  IF REGISTER 15 DOES    * 01264020
*   CONTAIN THE ADDRESS OF THE OPTION FIELD,  THE FORWARD ROUTINE     * 01265020
*   SETS THE ADDRESS AND LENGTH OF THE STRING IN THE OPTION FIELD     * 01266020
*   INTO THE THIRD PARAMETER LIST,  WHICH IS THE PARAMETER LIST FOR   * 01267020
*   IEDQA1.  THE FORWARD ROUTINE THEN LINKS TO IEDQA1 VIA THE USER    * 01268020
*   INTERFACE ROUTINE.                                                * 01269020
*                                                                     * 01270020
*                                                                     * 01271020
*   RETURN FROM IEDQA1:                                               * 01272020
*                                                                     * 01273020
*   THE BINARY SEARCH ROUTINE (IEDQA1) MAY BE THE SUBSIDIARY          * 01274020
*   ROUTINE FIRST LINKED TO BY THE FORWARD ROUTINE.  IF SO,  THE      * 01275020
*   DESTINATION NAME IS DIRECTLY DEFINED BY THE FORWARD MACRO.        * 01276020
*   SUBSEQUENT PROCESSING IS THE SAME FOR THIS CASE AS FOR RETURN     * 01277020
*   FROM SEARCHING FOR A STRING DEFINED IN THE BUFFER OR IN AN        * 01278020
*   OPTION FIELD.                                                     * 01279020
*                                                                     * 01280020
*   UPON RETURN FROM IEDQA1,  IF REGISTER 15 CONTAINS A ZERO,  NO     * 01281020
*   DESTINATION NAME MATCHING THE STRING PASSED TO IEDQA1 WAS         * 01282020
*   FOUND.  THE FORWARD ROUTINE PROCEEDS TO THE ERROR RECOVERY        * 01283020
*   PROCEDURE.                                                        * 01284020
*                                                                     * 01285020
*   IF IEDQA1 DOES NOT RETURN A ZERO IN REGISTER 15,  A MATCH HAS     * 01286020
*   BEEN FOUND AND THE REGISTER CONTAINS THE OFFSET TO THE TERMINAL   * 01287020
*   TABLE ENTRY FOR THE DESTINATION.  THIS OFFSET IS PASSED TO THE    * 01288020
*   LOOKUP ROUTINE (IEDQAV) TO GET THE DESTINATION QCB ADDRESS.  ON   * 01289020
*   RETURN FROM IEDQAV, THE FORWARD ROUTINE CHECKS TO SEE IF THE      * 01289522
*   THRESH OPERAND WAS SPECIFIED. IF IT WAS, AND THE DESTINATION HAS  * 01289622
*   MAIN-STORAGE ONLY QUEUEING, THIS ROUTINE CHECKS TO SEE IF THE     * 01289722
*   NUMBER OF MESSAGES ON THE QUEUE IS GREATER THAN OR EQUAL TO THE   * 01289822
*   THRESHOLD.  IF THE THRESHOLD HAS BEEN REACHED, BIT 6 IS TURNED ON * 01289922
*   IN BYTE THREE OF SCBERRST.NEXT THIS ROUTINE CHECKS TO SEE IF THE  * 01290022
*   DESTINATION REQUESTED AUTOMATIC DATE/TIME INSERTION.   IF SO,     * 01290122
*   THE FORWARD ROUTINE LINKS TO IEDQB3 FOR INSERTION.  UPON          * 01290522
*   RETURN FROM IEDQB3, THE FORWARD ROUTINE RETURNS TO THE            * 01291022
*   KCALLER WITH  A RETURN CODE OF X'00' IN REGISTER 15.              * 01291522
*                                                                     * 01292020
*                                                                     * 01293020
*   ERROR RECOVERY PROCEDURE:                                         * 01294020
*                                                                     * 01295020
*   THE FORWARD ROUTINE TESTS THE STATUS BYTE TO DETERMINE IF A       * 01296020
*   USER-WRITTEN ROUTINE TO ATTEMPT RECOVERY HAS BEEN DEFINED.  IF    * 01297020
*   SO,  THE FORWARD ROUTINE LINKS TO THE USER'S ROUTINE,  SAVING     * 01298020
*   AND RESTORING ITS OWN REGISTERS.  IF THE USER'S ROUTINE RETURNS   * 01299020
*   THE ADDRESS OF ANOTHER CHARACTER STRING IN REGISTER 15,  THE      * 01300020
*   FORWARD ROUTINE LINKS TO IEDQA1 TO TRY TO MATCH THIS STRING       * 01301020
*   WITH AN ENTRY IN THE TERMINAL NAME TABLE.  A RETURN REGISTER IS   * 01302020
*   SET,  HOWEVER,  TO PREVENT A RELINKAGE TO THE USER ROUTINE IF     * 01303020
*   THIS STRING FAILS TO FIND A MATCH.                                * 01304020
*                                                                     * 01305020
*   IF THIS STRING FINDS NO MATCH,  IF THE USER ROUTINE RETURNS A     * 01306020
*   ZERO IN REGISTER 15,  OR IF NO USER ROUTINE WAS DEFINED,  THE     * 01307020
*   FORWARD ROUTINE DETERMINES IF A DEAD-LETTER QUEUE HAS BEEN        * 01308020
*   DEFINED.  IF SO,  THE FORWARD ROUTINE PASSES ITS OFFSET TO        * 01309020
*   IEDQAV AND THEN RETURNS TO THE CALLER.  IF NO DEAD-LETTER QUEUE   * 01310020
*   IS DEFINED,  A RETURN CODE OF X'04' IS SET IN REGISTER 15.  IF    * 01311020
*   RETURN IS TO THE MESSAGE HANDLER,  THE SCB SECONDARY DESTINA-     * 01312020
*   TION FIELD (SCBMRFSD) IS CLEARED IN CASE MULTIPLE ROUTING IS      * 01313020
*   BEING ATTEMPTED.  RETURN IS THEN MADE TO THE CALLER.              * 01314020
*                                                                     * 01315020
*ENTRY POINTS --                                                      * 01316020
*        'IEDQA501' TO DETERMINE THE DESTINATION OF A MESSAGE.        * 01317020
*   CALLING SEQUENCE FROM USER INTERFACE IS:                          * 01318020
*                                                                     * 01319020
*        L     R12,AVTMSGS-1            GET ADDR OF VCON TABLE        * 01320020
*        IC    R15,AVTEZERO(,R1)        GET INDEX TO ROUTINE ADDR     * 01321020
*        L     R12,AVTEZERO(R12,R15)    GET ROUTINE ADDRESS           * 01322020
*        BR    R12                      EXIT TO ROUTINE               * 01323020
*                                                                     * 01324020
*INPUT --                                                             * 01325020
*   REGISTER 1 - THE ADDRESS OF A PARAMETER LIST GENERATED BY A       * 01326020
*   FORWARD MACRO.  PARAMETER LIST FORMAT IS:                         * 01327020
*                                                                     * 01328020
*        *********************************         STATUS BYTE        * 01329020
*        * INDEX * PARAM *       * INDEX *                            * 01330020
*        *  TO   * LIST  *STATUS * TO BA *         X'80': DEST NAME   * 01331020
*        *   A5  *  LNG  *       * (OPT) *         DEFINED IN MACRO   * 01332020
*        *********************************                            * 01333020
*        *LNG OF *      ADDRESS  OF      *         X'40': DEST NAME   * 01334020
*        *  EOA  *    END-OF-ADDRESS     *OPTIONAL IN OPTION FIELD    * 01335020
*        * STRING*   CHARACTER STRING    *                            * 01336020
*        *********************************         X'20': DEST NAME   * 01337020
*        *       ADDRESS OF USER'S       *         IN BUFFER          * 01338020
*        *        ERROR RECOVERY         *OPTIONAL                    * 01339020
*        *            ROUTINE            *         X'10': ERROR RE-   * 01340020
*        *********************************         COVERY ROUTINE     * 01341020
*        *                               *         SPECIFIED          * 01342020
*        *         VARIABLE DATA         *OPTIONAL                    * 01343020
*        *                               *         X'08': EOA CHAR    * 01344020
*        *********************************         STRING SPECIFIED   * 01345020
*        * INDEX * PARAM * (UN-  * LNG   *                            * 01346020
*        *  TO   * LIST  * USED) *(MAY BE*         X'04': THRESH      * 01347022
*        *   A1  *  LNG  *       * INIT) *         CODED              * 01348022
*        *********************************                            * 01349020
*        *          ADDRESS OF           *         X'02': DEST=ORIGIN * 01350022
*        *       CHARACTER STRING        *         SPECIFIED          * 01351022
*        *     (MAY BE INITIALIZED)      *                            * 01352020
*        *********************************         X'01': DESTINATION * 01353022
*        *               *               *         SPECIFIED IN REG   * 01354022
*        *   THRESHOLD   *    (UNUSED)   *                            * 01354222
*        *               *               *                            * 01354422
*        *********************************                            * 01354622
*                                                                     * 01354822
*        VARIABLE DATA:                                               * 01356020
*                                                                     * 01357020
*        *********************************                            * 01358020
*        * INDEX * PARAM *  OPT  *       *                            * 01359020
*        *  TO   * LIST  *  FLD  * X'10' *                            * 01360020
*        *   AE  *   LNG *OFFSET *       *                            * 01361020
*        *********************************                            * 01362020
*                                                                     * 01363020
*        *********************************                            * 01364020
*        * INDEX * PARAM *       * SCAN  *                            * 01365020
*        *  TO   * LIST  * X'10' *  LNG  *                            * 01366020
*        *   AI  *   LNG *       *       *                            * 01367020
*        *********************************                            * 01368020
*                                                                     * 01369020
*   REGISTER 3 - THE ADDRESS OF THE SCB.                              * 01370020
*                                                                     * 01371020
*   REGISTER 6 - THE ADDRESS OF THE CURRENT BUFFER.                   * 01372020
*                                                                     * 01373020
*   REGISTER 9 - THE ADDRESS OF THE AVT.                              * 01374020
*                                                                     * 01375020
*   REGISTER 12 - THE ENTRY POINT ADDRESS AND BASE REGISTER FOR THE   * 01376020
*   ROUTINE.                                                          * 01377020
*                                                                     * 01378020
*   REGISTER 13 - THE ADDRESS OF THE CALLER'S SAVE AREA.              * 01379020
*                                                                     * 01380020
*OUTPUT --                                                            * 01381020
*   REGISTER 15 - RETURN CODE.  ITS VALUE IS (1) -X'04' IF A          * 01382020
*   DESTINATION NAME SPECIFIED IN THE BUFFER IS INCOMPLETE IN THE     * 01383020
*   CURRENT BUFFER (MULTIPLE BUFFER HEADER SITUATION);  (2) X'00'     * 01384020
*   ON SUCCESSFUL COMPLETION;  (3) X'04' IF A VALID DESTINATION       * 01385020
*   CANNOT BE DETERMINED (NOTE:  THE DEAD-LETTER QUEUE IS A VALID     * 01386020
*   DESTINATION);  OR (4) X'08' IF AN END-OF-ADDRESS STRING IS        * 01387020
*   DETECTED ON ENTRY FROM THE MULTIPLE ROUTING SUBTASK.              * 01388020
*                                                                     * 01389020
*   SCB SECONDARY DESTINATION FIELD (SCBMRFSD) - IF MULTIPLE          * 01390020
*   ROUTING IS SPECIFIED (END-OF-ADDRESS STRING DEFINED BY THE        * 01391020
*   FORWARD MACRO),  THE OFFSET IN THE BUFFER TO THE LAST BYTE OF     * 01392020
*   THE CHARACTER STRING FOUND BY THIS EXECUTION OF THE ROUTINE.      * 01393020
*   EXCEPTIONS ((FIELD RESET TO ZERO): (1) DETECTION OF AN END-OF-    * 01394020
*   ADDRESS STRING,  OR (2) FAILURE TO FIND AN INITIAL (BUT NOT       * 01395020
*   SECONDARY) VALID DESTINATION.                                     * 01396020
*                                                                     * 01396322
*   BIT 6 OF SCBERR3 (BYTE 3 OF SCBERRST) SET IF THRESHOLD REACHED    * 01396622
*                                                                     * 01397020
*EXTERNAL REFERENCES --                                               * 01398020
*   'IEDQAE' - LOCATE OPTION FIELD ROUTINE TO RETURN THE ADDRESS      * 01399020
*   OF THE OPTION FIELD CONTAINING THE NAME OF THE DESTINATION.       * 01400020
*                                                                     * 01401020
*   'IEDQAI' - SKIP FORWARD AND SCAN ROUTINE TO RETURN THE NAME OF    * 01402020
*   A DESTINATION (OR AN END-OF-ADDRESS STRING) FROM THE BUFFER.      * 01403020
*                                                                     * 01404020
*   'IEDQA1' - BINARY SEARCH ROUTINE TO SEARCH THE TERMINAL NAME      * 01405020
*   TABLE FOR A DESTINATION NAME PASSED.                              * 01406020
*                                                                     * 01407020
*   'IEDQAV' - LOOKUP ROUTINE TO SET THE ADDRESS OF A DESTINATION     * 01408020
*   QCB IN THE SCB.                                                   * 01409020
*                                                                     * 01409322
*   'IEDQB3' - ROUTINE TO INSERT DATE/TIME FOR APPLICATION PGMS.      * 01409622
*                                                                     * 01410020
*   AVT - ADDRESS VECTOR ATBLE.                                       * 01411020
*                                                                     * 01412020
*   SCB - STATION CONTROL BLOCK.                                      * 01413020
*                                                                     * 01414020
*   BUFFER CURRENTLY BEING PROCESSED.                                 * 01415020
*                                                                     * 01416020
*EXITS,  NORMAL -- SUCCESSFUL COMPLETION.  REGISTER 15 CONTAINS A     * 01417020
*   RETURN CODE OF X'00'.  IF MULTIPLE ROUTING IS SPECIFIED,  THE     * 01418020
*   SCB SECONDARY DESTINATION FIELD (SCBMRFSD) CONTAINS THE OFFSET    * 01419020
*   IN THE BUFFER OF THE LAST BYTE OF THE CHARACTER STRING FOUND BY   * 01420020
*   THIS EXECUTION OF THE ROUTINE.                                    * 01421020
*                                                                     * 01422020
*   A DESTINATION NAME SPECIFIED IN THE BUFFER IS INCOMPLETE IN THE   * 01423020
*   CURRENT BUFFER (MULTIPLE BUFFER HEADER SITUATION).  REGISTER 15   * 01424020
*   CONTAINS A RETURN CODE OF -X'04'.                                 * 01425020
*                                                                     * 01426020
*   AN END-OF-ADDRESS STRING IS DETECTED ON ENTRY FROM THE MULTIPLE   * 01427020
*   ROUTING SUBTASK.  REGISTER 15 CONTAINS A RETURN CODE OF X'08'.    * 01428020
*   SCBMRFSD IS CLEARED TO ZERO.                                      * 01429020
*                                                                     * 01430020
*EXITS,  ERROR -- A VALID DESTINATION CANNOT BE DETERMINED.           * 01431020
*   REGISTER 15 CONTAINS A RETURN CODE OF X'04'.  IF MULTIPLE         * 01432020
*   ROUTING HAS BEEN SPECIFIED,  SCBMRFSD IS EITHER CLEARED TO ZERO   * 01433020
*   ON RETURN TO THE MESSAGE HANDLER OR CONTAINS THE OFFSET IN THE    * 01434020
*   BUFFER TO THE LAST BYTE OF THE CHARACTER STRING FOUND BY THIS     * 01435020
*   EXECUTION OF THE ROUTINE ON RETURN TO THE MULTIPLE ROUTING        * 01436020
*   SUBTASK.                                                          * 01437020
*                                                                     * 01438020
*TABLES/WORK AREAS -- N/A.                                            * 01439020
*                                                                     * 01440020
*ATTRIBUTES -- SERIALLY REUSABLE, REFRESHABLE, ENABLED, RESIDENT,     * 01441020
*   PROBLEM PROGRAM MODE.                                             * 01442020
*                                                                     * 01443020
*NOTES -- THE OPERATION OF THIS MODULE DOES NOT DEPEND UPON AN        * 01444020
*   INTERNAL REPRESENTATION OF THE EXTERNAL CHARACTER SET.            * 01445020
*                                                                     * 01446020
*********************************************************************** 01447020
         EJECT                                                          01448020
********* REGISTER EQUATES *********                                    01600020
         SPACE                                                          02000020
R0       EQU   0                        WORK REGISTER                   02400020
         SPACE                                                          02800020
R1       EQU   1                        PARAMETER LIST ADDRESS          03200020
         SPACE                                                          03600020
RPARM2   EQU   2                        IEDQA5 PARAMETER LIST           04000020
         SPACE                                                          04400020
RSCB3    EQU   3                        SCB ADDRESS                     04800020
         SPACE                                                          05200020
RLCB4    EQU   4                        LCB ADDRESS                     05300020
         SPACE                                                          05400020
RWORK5   EQU   5                        WORK REGISTER                   05600020
         SPACE                                                          06000020
RPREFIX  EQU   6                        BUFFER ADDRESS                  06400020
         SPACE 1                                                 S22025 06500022
RWORK    EQU   7                        WORK REGISTER            S22025 06600022
         SPACE                                                          06800020
RA18     EQU   8                        ADDR OF IEDQA1 PARM LIST        08000020
         SPACE                                                          08400020
RAVT9    EQU   9                        ADDRESS OF AVT                  08800020
         SPACE                                                          09200020
RRET10   EQU   10                       LOCAL RETURN REGISTER           09600020
         SPACE                                                          10000020
REX11    EQU   11                       EXECUTE REGISTER                10400020
         SPACE                                                          10800020
RBASE    EQU   12                       BASE REGISTER                   11200020
         SPACE                                                          11600020
R13      EQU   13                       SAVE AREA ADDRESS               12000020
R14      EQU   14                       RETURN REGISTER                 12400020
R15      EQU   15                       LINK REGISTER                   12800020
         EJECT                                                          13200020
********* OTHER EQUATES *********                                       13600020
         SPACE                                                          14000020
PARMLEN  EQU   1                        PARAMETER LIST LENGTH           14400020
PARMSTAT EQU   2                        STATUS BYTE                     14800020
TWO      EQU   2                        SHIFT LENGHT FOR CLEARINGS22025 15000022
PARMEOA  EQU   4                        EOA CHARACTERS                  15200020
PARMUSER EQU   8                        USER ERROR RECOVERY ROUTINE     15600020
         SPACE                                                          16000020
A1LEN    EQU   3                        IEDQA1 LENGTH BYTE              16400020
A1CHARS  EQU   4                        IEDQA1 CHARACTERS ADDR          16800020
         SPACE                                                          17200020
ONE      EQU   1                        INCREMENT VALUE OF ONE          17600020
FOUR     EQU   4                        FULLWORD OFFSET                 18000020
EIGHT    EQU   8                        DOUBLE-WORD OFFSET              18400020
         SPACE                                                          18800020
REG2OFF  EQU   28                       OFFSET TO R2 IN SAVE AREA       19200020
OPTOUT   EQU   4                        SHIFT LENGTH             S22025 19250022
         SPACE                                                          19300020
MREOA1   EQU   X'01'                    MULTIPLE-ROUTE                  19400020
MREOA2   EQU   X'02'                      EOA FLAGS                     19500020
         SPACE                                                          19600020
DESTNAME EQU   X'80'                    DESTINATION = NAME              20000020
DESTOPT  EQU   X'40'                    DESTINATION IN OPTION FIELD     20400020
USERFLAG EQU   X'10'                    USER ERR REC RTN PRESENT        20800020
EOAFLAG  EQU   X'08'                    EOA CHARACTERS PRESENT          21200020
THRSHFLG EQU   X'04'                    THRESH CODED             S22025 21400022
DESTORGN EQU   X'02'                    DEST=ORIGIN SPECIFIED    S22027 21420022
DESTREG  EQU   X'01'                    DEST ADDR SPECD IN REG   S22027 21440022
DESTBOTH EQU   X'81'                    DEST NAME IN MACRO FIELD S22027 21460022
CASDIST  EQU   X'40'                    CASCADE/DISTRIBUTION QCB S22025 21500022
         SPACE                                                          21600020
ZERO     EQU   8                        ZERO CONDITION CODE             22000020
ZEROOFF  EQU   0                        ZERO OFFSET              S22025 22200022
ALOW     EQU   4                        A FIELD LOW COND CODE    S22027 22300022
         SPACE                                                          22400020
INDEXAV  EQU   X'10'                    INDEX OF IEDQAV                 22800020
PUTSCHED EQU   X'12'                    RS KEY FOR PUT SCHEDULER        23000020
UNIQUE   EQU   X'DF'                    MULTIPLE ROUTE BYTE             23200020
TNTSTOR  EQU   X'80'                    TNT OFFSET STORED        S22027 23400022
         EJECT                                                          23600020
         USING IEDQAVTD,RAVT9                                           24000020
         USING IEDQLCB,RLCB4                                            24200020
         USING IEDQPRF,RPREFIX                                          24400020
         USING IEDQSCB,RSCB3                                            24800020
         USING IEDQA5,RBASE                                             25200020
         SPACE                                                          25600020
IEDQA501 EQU   *                                                        26000020
IEDQA5   IEDHJN FORWARD                                          S22025 27000022
         LH    RWORK5,PRFSIZE           LOAD BUFFER SIZE                28400020
         LTR   RWORK5,RWORK5            ZERO-LENGTH BUFFER              28800020
         BZ    EXIT1                    YES, RETURN IMMEDIATELY         29000020
         SPACE 1                                                 S22025 29010022
         LR    RPARM2,R1                SAVE PARMLIST START      S22025 29020022
         CLI   PARMLEN(R1),TWO          DEST=PUT SPECIFIED       S22025 29030022
         BNE   CKDUPL                   NO, CHECK TYPE           S22025 29040022
         SPACE 1                                                 S22025 29050022
         TM    PRFSTAT1,PRFNHDRN        TEXT BUFFER              S22025 29060022
         BO    EXITERR                  YES, CANNOT FORWARD      S22025 29070022
         SPACE 1                                                 S22025 29080022
         SR    R1,R1                    USE DEST KEY IN BUFFER   S22025 29090022
         B     LINKAV1                  LINK TO IEDQAV      ER   S22025 29100022
         SPACE 1                                                 S22025 29110022
CKDUPL   EQU   *                                                 S22025 29120022
         SPACE                                                          29250020
         TM    PRFSTAT1,PRFTSMSG       IS THIS A TSO MESSAGE     S22029 29300022
         BO    EXIT1                    YES, DO NOT FORWARD             29400020
         SPACE                                                          29600020
         TM    PRFSTAT1,PRFDUPLN        IS THIS A RECALLED BUFFER       30000020
         BO    TESTDEST                 YES,MAY BE TEXT,PROCEED  S22027 30400022
         SPACE                                                          30800020
         TM    PRFSTAT1,PRFNHDRN        NO, MUST BE HEADER, IS IT       31200020
         BO    EXITERR                  IT IS NOT, GO TO ERROR EXIT     31600020
         SPACE                                                          32000020
         CLI   LCBRSKEY,PUTSCHED        TEST FOR PUT SCHEDULER          32050020
         BE    SAVEPARM                 YES, WON'T BE EXTENDED LOCK     32100020
         SPACE                                                          32150020
         TM    SCBSTATE,SCBLCK1N       IN EXTENDED LOCK MODE            32200020
         BO    EXITCLR                 YES, BRANCH                      32250020
         SPACE                                                          32300020
SAVEPARM EQU   *                                                        32400020
         IC    R0,SCBMRFPL-1                                            33200020
         ST    R1,SCBMRFPL-1            SAVE FORWARD PARAM LIST         33600020
         STC   R0,SCBMRFPL-1                                            34000020
TESTDEST EQU   *                                                 S22027 34050022
         TM    PARMSTAT(RPARM2),DESTORGN  DOES DEST=ORIGIN       S22027 34100022
         BO    GETORGN                  YES, GET ORIGIN          S22027 34150022
         SPACE                                                          34200020
INCPARM  EQU   *                                                        34400020
         IC    R15,PARMLEN(,R1)         BUMP TO FIRST                   34800020
         LA    R1,AVTEZERO(R15,R1)        PARAMETER LIST                35200020
         LR    RA18,R1                  SAVE FIRST RTN'S PARM LIST      35600020
         TM    PARMSTAT(RPARM2),DESTNAME  NAME SPECD IN MACRO    S22027 35620022
         BZ    FIRSTRTN                 NO, SKIP THIS TEST       S22027 35640022
         TM    A1CHARS(RA18),TNTSTOR    TNT OFFSET STORED        S22027 35660022
         BZ    FIRSTRTN                 NO, GO GET IT            S22027 35680022
         L     R15,A1CHARS(RA18)        YES, PUT IT IN REG 15    S22027 35700022
         LA    R15,0(R15)               CLEAR FLAG BIT           S22027 35720022
         B     LINKAV                   GO TO IEDQAV LINK        S22027 35740022
FIRSTRTN EQU   *                                                 S22027 35760022
         LA    RRET10,ERRTEST           SET ERROR RETURN         S22027 35764022
         TM    PARMSTAT(RPARM2),DESTBOTH  IS DEST IN MACRO       S22027 35768022
         BZ    GOTOFIRS                 BRANCH IF NO             S22027 35772022
         CLI   A1LEN(RA18),PARMLEN      IS LENGTH LESS THAN 1    S22027 35776022
         BCR   ALOW,RRET10              BRANCH IF YES            S22027 35780022
         CLI   A1LEN(RA18),EIGHT        IS LENGTH GT 8           S22027 35784022
         BCR   TWO,RRET10               BRANCH IF YES            S22027 35788022
GOTOFIRS EQU   *                                                 S22027 35792022
         L     R15,AVTUI                GET USER INTERFACE ADDRESS      35800020
         BALR  R14,R15                  LINK TO FIRST ROUTINE           36100020
         SPACE                                                          36400020
TESTRET  EQU   *                                                        36800020
         TM    PARMSTAT(RPARM2),DESTBOTH  IS DEST IN MACRO       S22027 37200022
         BM    RETURNA1                 YES, RETURN IS FROM A1   S22027 38000022
         SPACE                                                          38400020
         LA    RA18,FOUR(,RA18)         BUMP TO A1 PARAM LIST           38800020
         TM    PARMSTAT(RPARM2),DESTOPT IS DEST IN OPT FIELD            39200020
         BO    RETURNAE                 YES, RETURN IS FROM AE          39600020
         SPACE                                                          40000020
         B     RETURNAI                 ELSE RETURN IS FROM AI   S22027 40400022
GETORGN  EQU   *                                                 S22027 40450022
         LH    R15,PRFSRCE              GET TNT OFFSET TO SOURCE S22027 40500022
         LTR   R15,R15                  TEST FOR ZERO            S22027 40550022
         BZ    ERRTEST                  YES, NO SOURCE OFFSET    S22027 40600022
         B     LINKAV                   NO, GO TO TNT LOOKUP RTN S22027 40650022
         EJECT                                                          40800020
RETURNAI EQU   *                                                        41200020
         LTR   R15,R15                  TEST FOR MBH RETURN             41600020
         BM    MBHEXIT                  YES, GO TEST ENTRY              42000020
         SPACE                                                          42400020
         TM    PARMSTAT(RPARM2),EOAFLAG IS THERE AN EOA STRING          43200020
         BNO   SETSCAN                  NO, MUST BE TERM NAME           43600020
         SPACE                                                          44000020
         SR    REX11,REX11                                              44400020
         TM    SCBMRFPL+2,MREOA1        WAS EOA FOUND LAST TIME         44500020
         BO    EXITCLR1                 YES, RETURN TO CALLER           44600020
         SPACE                                                          44700020
         IC    REX11,PARMEOA(,RPARM2)   GET COUNT AND ADDRESS           44800020
         L     RWORK5,PARMEOA(,RPARM2)    OF EOA CHARS                  45200020
         BCTR  REX11,AVTEZERO           COMPARE STRING FOUND            45600020
         EX    REX11,CLCX                 WITH EOA CHARACTERS           46000020
         BE    EXITEOA                  EQUAL, SET EOA & RETURN         46400020
         SPACE                                                          46800020
         LTR   REX11,REX11              ONE-CHARACTER EOA               46820020
         BNZ   SETMRFSD                 NO, BYPASS INTERNAL CHECK       46840020
         SPACE                                                          46860020
         IC    REX11,AVTPARM+1          YES, GET LENGTH OF STRING       46880020
         SPACE                                                          46900020
EOALOOP  EQU   *                                                        46920020
         IC    R14,AVTDOUBL-1(REX11)    PICK UP BYTE FROM STRING        46940020
         EX    R14,CLIX                 DOES IT MATCH EOA BYTE          46960020
         BE    EXITEOA                  YES, EOA FOUND, BRANCH          46980020
         SPACE                                                          47000020
         BCT   REX11,EOALOOP            NO, LOOP TILL ALL TESTED        47020020
         SPACE                                                          47040020
SETMRFSD EQU   *                                                        47060020
         STH   R15,SCBMRFSD             SAVE OFFSET TO SECOND DEST      47200020
         TM    PRFSTAT1,PRFDUPLN        ENTRY FROM MULTIPLE ROUTE       47600020
         BO    PREPA1                   YES, GO LINK TO BINARY SEAR     48000020
         SPACE                                                          48400020
SETBYTE  EQU   *                                                        48800020
         LR    RPARM2,RPREFIX           LOAD PREFIX ADDR         S22025 48900022
         STH   R15,PRFSCAN              POINT TO END OF DEST            49000020
         B     ENTERLOP                 GET ADDR OF SCAN PTR     S22025 49100022
ADDRLOOP EQU   *                                                 S22025 49200022
         L     RPARM2,PRFTIC-IEDQPRF(RPARM2) POINT TO NEXT UNIT  S22025 49300022
         SH    R15,AVTKEYLE             SUBT NO OF BYTES PASSED  S22025 49400022
ENTERLOP EQU   *                                                 S22025 49500022
         CH    R15,AVTKEYLE             IS ITEM IN THIS UNIT     S22025 49600022
         BH    ADDRLOOP                 NO, TEST NEXT UNIT       S22025 49700022
         LA    R15,AVTUMALN-1(R15,RPARM2) YES, GET ADDR OF ITEM  S22025 49800022
         SPACE                                                          50400020
         L     RPARM2,SCBMRFPL-1        RESTORE PARM LIST ADDR          50800020
         IC    R0,AVTEZERO(,R15)        PICK UP LAST BYTE        S22025 51200022
         STC   R0,SCBMRFSD+1            SAVE IT IN SCB                  51600020
         MVI   AVTEZERO(R15),UNIQUE     REPLACE WITH UNIQUE BYTE S22025 51900022
         B     PREPA1                   GO LINK TO BINARY SEARCH        52200020
         SPACE                                                          52400020
SETSCAN  EQU   *                                                        52500020
         STH   R15,PRFSCAN              POINT TO END OF DEST            52600020
         SPACE                                                          52800020
PREPA1   EQU   *                                                        53200020
         IC    R15,AVTPARM+1            PICK UP LNG OF FIELD FOUND      53600020
         LA    RRET10,ERRTEST           SET RETURN TO TRY RECOVERY      54000020
         LA    RWORK5,AVTDOUBL          GET ADDR OF FIELD FOUND         54400020
         B     LINKA1                   GO SET PARMS & LINK TO A1       54800020
         SPACE                                                          55200020
EXITEOA  EQU   *                                                        55600020
         TM    PRFSTAT1,PRFDUPLN        IS THIS VALID EOA               56000020
         BZ    ERRTEST                  NO, TRY TO RECOVER              56400020
         SPACE                                                          56800020
         OI    SCBMRFPL+2,MREOA2        SET EOA-FOUND CODE              57100020
         EX    REX11,CLCX         WAS EOA CHARACTER STRING FOUND        57500020
         BE    EXITCLR            YES, RETURN TO CALLER                 57600020
         B     ERRTEST1           NO, INVALID DEST. TEST USER EXIT      57700020
         SPACE                                                          58000020
MBHEXIT  EQU   *                                                        58400020
         TM    PRFSTAT1,PRFDUPLN        ENTRY FROM MULTIPLE ROUTE       58800020
         BO    EXIT1                    YES, RETURN WITH -4 CODE        59200020
         SPACE                                                          59600020
         B     ERRTEST                  NO, GO TRY TO RECOVER           60000020
         EJECT                                                          60400020
RETURNAE EQU   *                                                        60800020
         LTR   R15,R15                  TEST FOR OPT FLD NOT FOUND      61200020
         LA    RRET10,ERRTEST           SET ERROR EXIT ADDRESS          61600020
         BCR   ZERO,RRET10              NOT FOUND, TRY TO RECOVER       62000020
         SPACE                                                          62400020
         LR    RWORK5,R15               SET ADDR OF CHARACTERS          62800020
         IC    R15,AVTEZERO(,R1)        GET LNG FROM OP C ENTRY         63200020
         LA    R15,ONE(,R15)            ADD ONE FOR TRUE LENGTH         63600020
         SPACE                                                          64000020
LINKA1   EQU   *                                                        64400020
         STC   R15,A1LEN(,RA18)         SET LENGTH OF NAME              64800020
         ST    RWORK5,A1CHARS(,RA18)    SET ADDRESS OF NAME             65200020
         LR    R1,RA18                  POINT TO IEDQA1'S PARM LIST     65600020
         L     R15,AVTUI                GET USER INTERFACE ADDRESS      65800020
         BALR  R14,R15                  LINK TO IEDQA1                  66100020
         SPACE                                                          66400020
RETURNA1 EQU   *                                                        66800020
         LTR   R15,R15                  TEST IF TERM NAME FOUND         67200020
         BCR   ZERO,RRET10              NO, TRY TO RECOVER              67600020
         TM    PARMSTAT(RPARM2),DESTNAME  NAME SPECD IN MACRO    S22027 67680022
         BZ    LINKAV                   NO, CARRY ON             S22027 67760022
         ST    R15,A1CHARS(RA18)        YES, STORE TNT OFFSET    S22027 67840022
         OI    A1CHARS(RA18),TNTSTOR    SET STORED FLAG          S22027 67920022
         SPACE                                                          68000020
LINKAV   EQU   *                                                        68400020
         LR    R1,R15                   PASS DEST KEY TO IEDQAV         68800020
LINKAV1  EQU   *                                                 S22025 69000022
         L     R15,AVTMSGS-1            GET MH VCON TABLE ADDRESS       69200020
         L     R15,INDEXAV(,R15)        GET IEDQAV ADDRESS              69600020
         BALR  R14,R15                  LINK TO IEDQAV                  70000020
         SPACE 1                                                 S22025 70100022
         CLI   PARMLEN(RPARM2),TWO      DEST=PUT SPECIFIED       S22025 70200022
         BE    EXIT                     YES, CHECK DATE/TIME     S22025 70300022
         SPACE                                                          70400020
         LTR   R15,R15                  TEST IF TSO TERMINAL            70800020
         BNZ   ERRTEST                  YES, TEST FOR ERROR      S22025 70860022
         SPACE 1                                                        70867022
         L     R14,AVTPARM              GET TERM ADDRESS         S22025 70874022
         USING IEDQTRM,R14                                       S22025 70881022
         SPACE 1                                                        70888022
         TM    TRMSTATE,CASDIST         CASCADE OR DIST LIST QCB S22025 70895022
         BO    EXIT                     YES, BRANCH TO RETURN    S22025 70902022
         SPACE 1                                                        70909022
         SPACE                                                          70920022
         TM    PARMSTAT(RPARM2),THRSHFLG IS THRES CODED          S22025 70980022
         BNO   EXIT                     NO, RETURN TO CALLER     S22025 71040022
         SPACE                                                          71100022
         BAL   R14,GETOFF               BRANCH TO BUMP PARM ADDR S22025 71160022
         SPACE                                                          71220022
         L     REX11,SCBDESTQ-1         GET DESTINATION QCB      S22025 71280022
         USING IEDQQCB,REX11            SET ADDRESSABILITY       S22025 71340022
         SPACE                                                          71400022
         TM    QCBDSFLG,QCBDISK         IS IT DISK QUEUES               71460022
         BNZ   EXIT                     YES, RETURN TO CALLER           71520022
         SPACE                                                          71580022
         TM    QCBDSFLG,QCBCORE         IS IT CORE QUEUES               71640022
         BNO   EXIT                     NO, RETURN TO CALLER            71700022
         SPACE                                                          71760022
         NI    SCBERR1,AVTEFF-SCBTHRSN  TURN OFF CORE THRESH BIT S22025 71820022
         SPACE                                                          71880022
         CLC   QCBMSGCT,FOUR(RWORK5)    HAS THRESH BEEN REACHED  S22025 71940022
         BL    EXIT                     NO, RETURN TO CALLER     S22025 72000022
         OI    SCBERR3,SCBTHRSN         SET THRESH LIMIT REACHED S22025 72060022
         IC    RWORK,SCBSTATE           SAVE STATUS BYTE        SA59039 72120022
         LA    R14,AVTBFRTB             BUFFER RETURN QUEUE     SA59039 72170022
         ST    R14,SCBDESTQ-1           SAVE DEST QUEUE         SA59039 72220022
         STC   RWORK,SCBSTATE           RESTORE STATUS BYTE     SA59039 72270022
         B     EXIT                     HANDLE AS DEST ERROR    SA59039 72320022
         EJECT                                                          72400020
ERRTEST  EQU   *                                                        72800020
          TM    PRFSTAT1,PRFDUPLN       ENTRY FROM FORWARD MACRO        72850020
          BO    ERRTEST1                NO, LEAVE OFF BIT               72900020
         SPACE                                                          72950020
         OI    SCBERR2,SCBFRWDN         SET FORWARD ERROR BIT           73000020
         SPACE                                                          73020020
ERRTEST1 EQU   *                                                        73040020
         TM    SCBMRFPL+2,MREOA2        WAS EOA FOUND                   73060020
         BNO   GETUSER1                 NO, BRANCH                      73080020
         SPACE                                                          73100020
         NI    SCBMRFPL+2,AVTEFF-MREOA2 YES, RESET TO INDICATE          73110020
         OI    SCBMRFPL+2,MREOA1          USER RECOVERY                 73120020
         SPACE                                                          73140020
GETUSER1 EQU   *                                                        73160020
         BAL   R14,GETOFF               BRANCH TO BUMP PARM ADDR S22025 73170022
         LR    R15,RWORK5               LOAD CORRECT OFFSET      S22025 73180022
         TM    PARMSTAT(RPARM2),USERFLAG IS THERE A USER ROUTINE        73200020
         BNO   PERMERR                  NO, PERMANENT ERROR             73600020
         SPACE                                                          74000020
         SPACE                                                          76400020
GETUSER  EQU   *                                                        76800020
         L     R15,AVTEZERO(,R15)       GET ADDR OF USER ROUTINE        77200020
         LR    R1,RPREFIX               PASS ADDRESS OF BUFFER          77600020
         STM   RPARM2,RBASE,REG2OFF(R13) SAVE REGISTERS                 78000020
         BALR  R14,R15                  LINK TO USER ROUTINE            78400020
         SPACE                                                          78800020
         LM    RPARM2,RBASE,REG2OFF(R13) RESTORE REGISTERS              79200020
         LTR   R15,R15                  TEST IF RECOVERY MADE           79600020
         BZ    PERMERR                  NO, PERMANENT ERROR             80000020
         SPACE                                                          80400020
         LA    RWORK5,ONE(,R15)         POINT TO START OF CHARS         80800020
         IC    R15,AVTEZERO(,R15)       PICK UP LNG OF CHARACTERS       81200020
         BAL   RRET10,LINKA1            GO LINK TO IEDQA1               81600020
         SPACE                                                          82000020
PERMERR  EQU   *                                                        82400020
         LH    R15,AVTDLQX              GET DEAD-LETTER QUEUE KEY       82800020
         LTR   R15,R15                  IS IT ZERO                      83200020
         BZ    EXITERR                  YES, PERMANENT ERROR, EXIT      83270020
         SPACE                                                          83340020
         TM    PRFSTAT1,PRFDUPLN        ENTRY FROM FORWARD MACRO        83360020
         BNO   LINKAV                   YES, GO SET DLQ AS DEST SA67104 83380053
         SPACE                                                          83400020
         TM    SCBERR2,SCBFRWDN         NO, IS MSG ALREADY ON DLQ       83420020
         BO    EXITERR                  YES, DON'T SEND ANOTHER         83480020
         SPACE                                                          83550020
         OI    SCBERR2,SCBFRWDN         NO, TURN ON DLQ FLAG            83650020
         B     LINKAV                   GO SET DLQ AS DEST              83900020
         SPACE                                                          84000020
EXITERR  EQU   *                                                        84400020
         LA    R15,AVTECD4              SET RETURN CODE                 84800020
         SPACE                                                          85200020
         B     EXIT                     GO CLEAN UP             SA59523 85600022
         SPACE                                                          86200020
         SPACE                                                          86400020
EXITCLR1 EQU   *                                                        86500020
         NI    SCBMRFPL+2,AVTEFF-MREOA1 RESET TO INDICATE               86600020
         OI    SCBMRFPL+2,MREOA2          EOA FOUND                     86700020
EXITCLR  EQU   *                                                        86800020
         SR    R0,R0                    CLEAR SECONDARY                 87200020
         STH   R0,SCBMRFSD                DESTINATION FIELD             87600020
         SPACE                                                          88000020
EXIT     EQU   *                                                        88400020
         TM    PRFSTAT1,PRFNHDRN        HEADER                   S22025 88401022
         BO    EXIT2                    NO, NO DATE/TIME         S22025 88402022
         CH    R15,AVTHA4               PERM ERROR               S22025 88403022
         BE    EXIT2                    YES                      S22025 88404022
         TM    SCBMRFPL+2,MREOA2        WAS EOA FOUND            S22025 88404322
         BO    EXIT2                    YES RETURN TO CALLER     S22025 88404422
         TM    PRFSTAT1,PRFDUPLN        DUPLICATE HDR           SA56226 88404522
         BO    EXIT2                    BRANCH IF YES           SA56226 88404622
         LR    RWORK,R15                SAVE RETURN CODE         S22025 88404822
         L     R15,AVTRNMPT             LOAD TERM TABLE ROUTINE  S22025 88405022
         LH    R1,PRFDEST               LOAD DESTINATION         S22025 88405222
         N     R1,AVTCLRHI              CLEAR TOP HALF           S22025 88405422
               SPACE                                                    88405622
         BALR  R14,R15                  BRANCH TO TERM TAB ROUT  S22025 88405822
         LR    R14,R1                   LOAD TERM ADDRESS        S22025 88406022
         LR    R15,RWORK                RESTORE RET CODE         S22025 88406222
         SR    RWORK,RWORK              CLEAR                    S22025 88407022
         IC    RWORK,TRMSTATE           GET THE STATUS           S22025 88408022
         SRL   RWORK,OPTOUT             SHIFT OUT UNWANTED OPTS  S22025 88409022
         CH    RWORK,AVTHA3             PROCESS ENTRY WITH DATE  S22025 88410022
         BNE   EXIT2                    NO, CONTINUE             S22025 88411022
         SPACE 1                                                 S22025 88412022
         LR    R0,R15                   SAVE                     S22025 88413022
         L     REX11,TRMDESTQ-1         YES, GET DEST QCB        S22025 88414022
         L     RWORK5,QCBDCBAD-1        GET ADDRES OF PCB        S22025 88416022
         USING IEDQPCB,RWORK5                                    S22025 88417022
         L     R15,PCBDTRTN-1           GET ADDRESS OF DATE RTN  S22025 88418022
         BALR R14,R15                   LINK TO DATE RTN         S22025 88419022
         SPACE 1                                                 S22025 88420022
         LR    R15,R0                   RESTORE RETURN CODE      S22025 88421022
EXIT2    EQU   *                                                 S22025 88422022
         TM    SCBMRFPL+2,MREOA2        WAS EOA FOUND                   88440020
         BNO   EXIT1                    NO, BRANCH                      88480020
         NI    SCBBSCFM,AVTEFF-SCBDATEN RESET DATE INSERTED     SA56226 88500022
         SPACE                                                          88520020
         LA    R15,AVTECD8              SET EOA RETURN CODE             88560020
         NI    SCBMRFPL+2,AVTEFF-MREOA1-MREOA2 RESET FLAGS TO ZERO      88600020
         SPACE                                                          88640020
EXIT1    EQU   *                                                        88700020
         L     RBASE,AVTUI              GET RET INTERFACE ADDR   S22025 89100022
         B     FOUR(RBASE)              RETURN TO CALLER         S22025 89500022
         SPACE                                                          89520022
GETOFF   EQU   *                                                 S22025 89540022
         L     RPARM2,SCBMRFPL-1        RESTORE PARM LIST ADDR   S22025 89560022
         SRL   RPARM2,TWO               CLEAR FLAG BITS          S22025 89566022
         SLL   RPARM2,TWO               OUT OF ADDRESS           S22025 89572022
         LR    RWORK5,RPARM2            LOAD PARM LIST ADDR      S22025 89580022
         SPACE                                                          89600022
         TM    PARMSTAT(RPARM2),USERFLAG IS THERE A USER EXIT    S22025 89620022
         BNO   EOAOFF                   NO, CHECK FOR EOA STRING S22025 89640022
         SPACE                                                          89660022
         LA    RWORK5,FOUR(RWORK5)      YES, BUMP ADDR BY FOUR   S22025 89680022
         SPACE                                                          89700022
EOAOFF   EQU   *                                                 S22025 89720022
         SPACE                                                          89740022
         TM    PARMSTAT(RPARM2),EOAFLAG IS THERE A EOA STRING    S22025 89760022
         BNO   ZEROOFF(R14)             NO, RETURN TO CALLER     S22025 89780022
         SPACE                                                          89800022
         LA    RWORK5,FOUR(RWORK5)      YES, BUMP ADDR BY FOUR   S22025 89820022
         SPACE                                                          89840022
         BR    R14                      RETURN TO CALLER                89860022
         SPACE 3                                                        90000020
********* EXECUTED INSTRUCTIONS *********                               90400020
         SPACE                                                          90800020
CLCX     CLC   AVTDOUBL(AVTEZERO),AVTEZERO(RWORK5)                      91200020
         SPACE                                                          91300020
CLIX     CLI   AVTEZERO(RWORK5),AVTEZERO                                91400020
         EJECT                                                          91600020
********* DSECTS *********                                              92000020
         TQCBD                                                   S22025 92100022
         TPCBD                                                   S22025 92200022
         TTRMD                                                   S22025 92300022
         SPACE                                                          92400020
         TAVTD                                                          92800020
         EJECT                                                          93200020
         TLCBD                                                          93300020
         EJECT                                                          93400020
         TPRFD                                                          93600020
         EJECT                                                          94000020
         TSCBD                                                          94400020
         SPACE                                                          94800020
         END                                                            95200020
