A701     TITLE '''IEDQA7'' - COUNTER ROUTINE'                           01000020
IEDQA7   CSECT                                                          02000020
         SPACE                                                          02010020
*********************************************************************** 02020020
*STATUS -- CHANGE LEVEL 0                                             * 02030020
*                                                                     * 02040020
*FUNCTION --                                                          * 02050020
*   IF THE COUNTER MACRO WHICH GENERATED LINKAGE TO THE ROUTINE IS    * 02060020
*   IN AN INHDR OR OUTHDR SUBGROUP BUT THE BUFFER IS NOT A PHYSICAL   * 02070020
*   HEADER,  THE BUFFER IS NOT COUNTED.  RETURN IS MADE TO THE        * 02080020
*   CALLER WITH ZEROES IN REGISTER 15.                                * 02090020
*                                                                     * 02100020
*   THE ROUTINE DETERMINES IF THE CURRENT BUFFER IS A ZERO-LENGTH     * 02110020
*   BUFFER.  IF SO,  THE MESSAGE IS NOT COUNTED AND RETURN IS MADE    * 02120020
*   TO THE CALLER WITH X'FF' IN REGISTER 15.  OTHERWISE               * 02130020
*                                                                     * 02140020
*   THE ROUTINE LINKS THE LOCATE OPTION ROUTINE (IEDQAE) TO GET THE   * 02150020
*   ADDRESS OF THE OPTION FIELD.  IF THE OPTION FIELD CANNOT BE       * 02160020
*   FOUND,  THE MESSAGE IS NOT COUNTED AND RETURN IS MADE TO THE      * 02170020
*   CALLER WITH X'FF' IN REGISTER 15.  OTHERWISE                      * 02180020
*                                                                     * 02190020
*   THE COUNT IN THE OPTION IS INCREMENTED BY ONE.  RETURN IS MADE    * 02200020
*   TO THE CALLER WITH ZEROES IN REGISTER 15.                         * 02210020
*                                                                     * 02220020
*ENTRY POINT --                                                       * 02230020
*       'IEDQA701' TO COUNT A HEADER OR TEXT SEGMENT.  CALLING        * 02240020
*   SEQUENCE FROM THE MACRO EXPANSION IS:                             * 02250020
*                                                                     * 02260020
*        L     15,IEDMSGS-1             GET MH VCON TABLE ADDR        * 02270020
*        L     15,N(,15)                GET ADDR OF COUNTER RTN       * 02280020
*        BALR  1,15                     LINK TO COUNTER ROUTINE       * 02290020
*                                                                     * 02300020
*   WHERE 'N' IS THE INDEX TO THE ADDRESS OF THE COUNTER ROUTINE      * 02310020
*   IN THE MH VCON TABLE.                                             * 02320020
*                                                                     * 02330020
*INPUT --                                                             * 02340020
*   REGISTER 1 - THE ADDRESS OF A MACRO-GENERATED PARAMETER LIST      * 02350020
*   FOR THE LOCATE OPTION ROUTINE.                                    * 02360020
*                                                                     * 02370020
*OUTPUT --                                                            * 02380020
*   REGISTER 15 - RETURN CODE-  CONTAINS ZEROES IF SEGMENT IS         * 02390020
*   COUNTED.  CONTAINS X'FF' IF OPTION FIELD IS NOT FOUND OR IF       * 02400020
*   ZERO-LENGTH BUFFER.                                               * 02410020
*                                                                     * 02420020
*   OPTION FIELD - INCREMENTED BY ONE                                 * 02430020
*                                                                     * 02440020
*EXTERNAL REFERENCES -                                                * 02450020
*   'IEDQAE' - LOCATE OPTION ROUTINE                                  * 02460020
*                                                                     * 02470020
*   AVT - ADDRESS VECTOR TABLE                                        * 02480020
*                                                                     * 02490020
*   BUFFER CURRENTLY BEING PROCESSED                                  * 02500020
*                                                                     * 02510020
*   COUNTER OPTION FIELD                                              * 02520020
*                                                                     * 02530020
*EXITS,  NORMAL -- THE COUNTER OPTION FIELD IS INCREMENTED BY ONE.    * 02540020
*   REGISTER 15 CONTAINS A RETURN CODE OF ZERO.                       * 02550020
*                                                                     * 02560020
*EXITS,  ERROR --                                                     * 02570020
*   ZERO-LENGTH BUFFER.  THE COUNTER OPTION FIELD IS NOT CHANGED.     * 02580020
*   REGISTER 15 CONTAINS A RETURN CODE OF X'FF'.                      * 02590020
*                                                                     * 02600020
*   OPTION FIELD NOT FOUND.  REGISTER 15 CONTAINS A RETURN CODE OF    * 02610020
*   X'FF'.                                                            * 02620020
*                                                                     * 02630020
*TABLES/WORK AREAS -- W/A                                             * 02640020
*                                                                     * 02650020
*ATTRIBUTES -- REUSABLE,  REFRESHABLE, ENABLED,  RESIDENT, PROBLEM    * 02660020
*   PROGRAM MODE.                                                     * 02670020
*                                                                     * 02680020
*NOTES -- THE OPERATION OF THIS MODULE DOES NOT DEPEND UPON AN        * 02690020
*   INTERNAL REPRESENTATION OF THE EXTERNAL CHARACTER SET.            * 02700020
*                                                                     * 02710020
*********************************************************************** 02720020
         EJECT                                                          02730020
********* REGISTER EQUATES *********                                    03000020
         SPACE                                                          04000020
R1       EQU   1                        WORK REGISTER                   05000020
         SPACE                                                          06000020
R13      EQU   13                       ADDRESS OF AVT                  07000020
         SPACE                                                          08000020
R14      EQU   14                       RETURN REGISTER                 09000020
         SPACE                                                          10000020
R15      EQU   15                       ADDRESS OF OPTION FIELD         11000020
         SPACE                                                          12000020
********* OTHER EQUATES *********                                       13000020
         SPACE                                                          14000020
ONE      EQU   1                        INCREMENT VALUE OF ONE          15000020
FOUR     EQU   4                        LENGTH OF IEDQAE PARAMETER      16000020
*                                         LIST                          17000020
HEADER   EQU   X'01'                    INHDR/OUTHDR MACRO FLAG         18000020
         EJECT                                                          19000020
         USING AVTSAVE2,R13                                             20000020
         USING IEDQA701,R15                                             21000020
         SPACE                                                          22000020
IEDQA701 EQU   *                                                        23000020
         B     COUNTER                  BRANCH AROUND ID                24000020
         DC    CL12'IEDQA7 11/23'                                       25000020
         SPACE                                                          26000020
COUNTER  EQU   *                                                        27000020
         LA    R14,FOUR(,R1)            ADD 4 TO GET RETURN ADDRESS     28000020
         ST    R14,AVTPARM              SAVE RETURN ADDRESS             29000020
         L     R14,AVTADBUF             GET ADDRESS OF BUFFER           30000020
         USING IEDQPRF,R14                                              31000020
         TM    PRFSTAT1,PRFCNCLN        IS THIS A RECALLED BUFFER       31200020
         BO    ZERORTN                  YES, DON'T COUNT                31400020
         SPACE                                                          31600020
         TM    AVTEZERO(R1),HEADER      IS MACRO IN INHDR/OUTHDR        32000020
         BNO   NORMAL                   NO, BRANCH AND COUNT IT         33000020
         SPACE                                                          34000020
         TM    PRFSTAT1,PRFNHDRN        YES, IS THIS HEADER BUFFER      35000020
         BO    ZERORTN                  IT ISN'T, DON'T COUNT, EXIT     36000020
         SPACE                                                          37000020
NORMAL   EQU   *                                                        38000020
         LH    R14,PRFSIZE              PICK UP PREFIX SIZE FIELD       39000020
         LTR   R14,R14                  IS THIS A ZERO-LENGTH BFR       40000020
         BZ    ERROR                    YES, ERROR, RETURN              41000020
         SPACE                                                          42000020
         L     R15,AVTUI                GET USER INTERFACE ADDRESS      43000020
         BALR  R14,R15                  LINK TO LOCATE OPTION RTN       44000020
         SPACE                                                          45000020
         BALR  R1,AVTEZERO              SET NEW BASE                    46000020
         USING *,R1                                                     47000020
         LTR   R15,R15                  WAS OPTION FIELD FOUND          48000020
         BZ    ERROR                    NO, ERROR, RETURN               49000020
         SPACE                                                          50000020
         LH    R1,AVTEZERO(,R15)        GET COUNT IN OPTION FIELD       51000020
         LA    R1,ONE(,R1)              ADD ONE                         52000020
         STH   R1,AVTEZERO(,R15)        STORE IT BACK                   53000020
         SPACE                                                          54000020
ZERORTN  EQU   *                                                        55000020
         SR    R15,R15                  SET GOOD RETURN CODE            56000020
         L     R14,AVTPARM              GET RETURN ADDRESS              57000020
         BR    R14                      RETURN                          58000020
         SPACE                                                          59000020
ERROR    EQU   *                                                        60000020
         L     R14,AVTPARM              GET RETURN ADDRESS              61000020
         LA    R15,AVTEFF               SET ERROR RETURN CODE           62000020
         BR    R14                      RETURN                          63000020
         EJECT                                                          64000020
********* DSECTS *********                                              65000020
         TAVTD                                                          66000020
         EJECT                                                          67000020
         TPRFD                                                          68000020
         SPACE                                                          69000020
         END                                                            70000020
