A801     TITLE '''IEDQA8'' -- MULTIPLE INSERT AT OFFSET ROUTINE'        00400020
IEDQA8   CSECT                                                          00800020
*A158000,308000                                                 SA53607 00850000
*A008000,156000,172000,481000                                    S22025 00900022
*C201800,472000,700000-708000                                    S22025 01000022
*D212000                                                         S22025 01100022
*D436500-439000,640800-644800                                   SA58444 01150022
         SPACE                                                          01200020
*********************************************************************** 01202020
*STATUS -- CHANGE LEVEL 0                                             * 01204020
*                                                                     * 01206020
*FUNCTION --                                                          * 01208020
*   INSERTS A DATA STRING OF UP TO EIGHT CHARACTERS AT A SPECIFIED    * 01210020
*   INTERVAL OF UP TO 65,535 BYTES THROUGHOUT THE MESSAGE.            * 01212020
*                                                                     * 01214020
*   AN INITIAL LINK IS MADE TO THE LOCATE OPTION ROUTINE (IEDQAE)     * 01216020
*   TO FIND THE ADDRESS OF THE OPTION FIELD IN WHICH INTERVALS        * 01218020
*   ACROSS BUFFERS IS HELD.  IF THE FIELD IS NOT FOUND, CONTROL       * 01220020
*   RETURNS TO THE CALLER WITH A RETURN CODE OF FOUR IN REGISTER      * 01222020
*   15.                                                               * 01224020
*                                                                     * 01226020
*   THE INITIAL OFFSET FOR DATA IS COMPUTED.  IF IT IS NOT WITHIN     * 01228020
*   THIS BUFFER,  IT IS SAVED IN THE OPTION FIELD AND CONTROL         * 01230020
*   RETURNS TO THE CALLER.  OTHERWISE THE MAIN LOOP IS ENTERED.       * 01232020
*                                                                     * 01234020
*   IN THE MAIN LOOP,  A LINK IS MADE TO THE USER INTERFACE           * 01236020
*   (IEDQAO) TO INSERT THE DATA STRING,  THEN A LINK IS MADE TO THE   * 01238020
*   INSERT DATA ROUTINE (IEDQAF) TO SHIFT THE ORIGINAL DATA LEFT-     * 01240020
*   WARDS IN THE BUFFER UP TO THE NEXT INSERT POINT.  THE LOOP IS     * 01242020
*   RE-ENTERED UNTIL THE INSERT POINT IS BEYOND THE END OF THE        * 01244020
*   BUFFER.                                                           * 01246020
*                                                                     * 01248020
*   WHEN THIS OCCURS,  A FINAL LINK TO THE INSERT DATA ROUTINE IS     * 01250020
*   MADE TO SHIFT THE LOGICALLY EMPTY AREA TO THE END OF THE BUFFER   * 01252020
*   AND THE NEW FINAL DATA SIZE IS COMPUTED AND SET IN THE PREFIX     * 01254020
*   (PRFSIZE).  IF THERE IS A SUBSEQUENT BUFFER,  THE INITIAL         * 01256020
*   INSERT OFFSET FOR THAT BUFFER IS COMPUTED AND SET IN THE OPTION   * 01258020
*   FIELD.  CONTROL RETURNS TO THE CALLER WITH A RETURN CODE OF       * 01260020
*   ZERO IN REGISTER 15.                                              * 01262020
*                                                                     * 01264020
*ENTRY POINTS --                                                      * 01266020
*       'IEDQA801' TO INSERT A CHARACTER STRING AT SPECIFIED INTER-   * 01268020
*   VALS.  CALLING SEQUENCE FROM USER INTERFACE IS:                   * 01270020
*                                                                     * 01272020
*        L     R12,AVTMSGS-1            GET ADDR OF VCON TABLE        * 01274020
*        IC    R15,AVTEZERO(,R1)        GET INDEX TO ROUTINE ADDR     * 01276020
*        L     R12,AVTEZERO(R12,R15)    GET ROUTINE ADDRESS           * 01278020
*        BR    R12                      EXIT TO ROUTINE               * 01280020
*                                                                     * 01282020
*INPUT --                                                             * 01284020
*   REGISTER 1 - THE ADDRESS OF A MACRO-GENERATED PARAMETER LIST.     * 01286020
*   PARAMETER LIST FORMAT IS:                                         * 01288020
*                                                                     * 01290020
*        *********************************                            * 01292020
*        * INDEX * PARM  * INDEX * INDEX *                            * 01294020
*        *  TO   *  LIST *  TO   *  TO   *                            * 01296020
*        *   A8  * LNGTH *   AF  *   AO  *                            * 01298020
*        *********************************                            * 01300020
*        *          INSERT               *                            * 01302020
*        *                 DATA          *                            * 01304020
*        *                               *                            * 01306020
*        *********************************                            * 01308020
*        *   INTERVAL    * INDEX *  OPT  *                            * 01310020
*        *    BETWEEN    *  TO   * FIELD *                            * 01312020
*        *     INSERTS   *   AE  * OFFSET*                            * 01314020
*        *********************************                            * 01316020
*                                                                     * 01318020
*        INSERT DATA WORD:                                            * 01320020
*                                                                     * 01322020
*        *********************************                            * 01324020
*        *LENGTH *      ADDRESS OF       *   DATA =                   * 01326020
*        *  OF   *   CHARACTER STRING    *     CHARACTER STRING       * 01328020
*        * STRING*                       *                            * 01330020
*        *********************************                            * 01332020
*                                                                     * 01334020
*        *********************************                            * 01336020
*        * NO.   * IDLE  *               *   DATA =                   * 01338020
*        *  OF   *  CHAR *   (UNUSED)    *     IDLES                  * 01340020
*        * IDLES *       *               *                            * 01342020
*        *********************************                            * 01344020
*                                                                     * 01346020
*        A8 INDEX BYTE: X'01' OFF - DATA = CHARACTER STRING           * 01348020
*                       X'01' ON - DATA = IDLES                       * 01350020
*                                                                     * 01352020
*   REGISTER 4 - ADDRESS OF LCB                                       * 01354020
*                                                                     * 01356020
*   REGISTER 6 - ADDRESS OF CURRENT BUFFER                            * 01358020
*                                                                     * 01360020
*   REGISTER 9 - ADDRESS OF AVT                                       * 01362020
*                                                                     * 01364020
*   REGISTER 12 -  ENTRY POINT ADDRESS AND BASE FOR THIS ROUTINE      * 01366020
*                                                                     * 01368020
*   OPTION FIELD - ON FIRST BUFFER,  CONTENTS ON ENTRY IGNORED.  ON   * 01370020
*   TEXT BUFFERS,  CONTAINS THE OFFSET TO THE FIRST INSERT POINT IN   * 01372020
*   THE CURRENT BUFFER.                                               * 01374020
*                                                                     * 01376020
*OUTPUT --                                                            * 01378020
*   REGISTER 15 - CONTAINS ZEROES IF FUNCTION COMPLETED SUCCESS-      * 01380020
*   FULLY.  CONTAINS X'04' IF OPTION FIELD NOT FOUND.                 * 01382020
*                                                                     * 01384020
*   OPTION FIELD - ON NOT-LAST BUFFERS,  CONTAINS THE OFFSET TO THE   * 01386020
*   FIRST INSERT POINT IN THE NEXT BUFFER.                            * 01388020
*                                                                     * 01390020
*EXTERNAL REFERENCES --                                               * 01392020
*   'IEDQAF' - INSERT DATA ROUTINE                                    * 01394020
*                                                                     * 01396020
*   'IEDQAO' - UNIT REQUEST INTERFACE                                 * 01398020
*                                                                     * 01400020
*   AVT - ADDRESS VECTOR TABLE                                        * 01406020
*                                                                     * 01408020
*   LCB - LINE CONTROL BLOCK                                          * 01410020
*                                                                     * 01412020
*   BUFFER CURRENTLY BEING PROCESSED                                  * 01414020
*                                                                     * 01416020
*   USER-DEFINED OPTION FIELD                                         * 01418020
*                                                                     * 01420020
*EXITS,  NORMAL --                                                    * 01422020
*   THE REQUESTED DATA IS INSERTED IN THE BUFFER.  THE OPTION FIELD   * 01424020
*   CONTAINS THE OFFSET TO THE FIRST INSERT POINT IN THE NEXT         * 01426020
*   BUFFER,  UNLESS THE CURRENT BUFFER IS THE LAST BUFFER.  REGIS-    * 01428020
*   TER 15 CONTAINS A RETURN CODE OF X'00'.                           * 01430020
*                                                                     * 01432020
*EXITS,  ERROR --                                                     * 01434020
*   THE OPTION FIELD SPECIFIED CANNOT BE FOUND.  REGISTER 15 CON-     * 01436020
*   TAINS A RETURN CODE OF X'04'.                                     * 01438020
*                                                                     * 01440020
*TABLES/WORK AREAS -- N/A.                                            * 01442020
*                                                                     * 01444020
*ATTRIBUTES -- SERIALLY REUSABLE, REFRESHABLE, ENABLED, RESIDENT,     * 01446020
*   PROBLEM PROGRAM MODE.                                             * 01448020
*                                                                     * 01450020
*NOTE -- THE OPERATION OF THIS MODULE DEPENDS UPON AN INTERNAL        * 01452020
*   REPRESENTATION OF THE EXTERNAL CHARACTER SET WHICH IS             * 01454020
*   EQUIVALENT TO THE ONE USED AT ASSEMBLY TIME.  THE CODING HAS      * 01456020
*   BEEN ARRANGED SO THAT REDEFINITION OF ''CHARACTER'' CONSTANTS,    * 01458020
*   BY REASSEMBLY, WILL RESULT IN A CORRECT MODULE FOR THE NEW        * 01460020
*   DEFINITIONS.                                                      * 01462020
*                                                                     * 01464020
*********************************************************************** 01466020
         EJECT                                                          01468020
********* REGISTER EQUATES *********                                    01600020
         SPACE                                                          02000020
R0       EQU   0                        WORK REGISTER                   02400020
         SPACE                                                          02800020
R1       EQU   1                        PARAMETER LIST ADDRESS          03200020
         SPACE                                                          03600020
REXTN2   EQU   2                        EXTENT BETWEEN INSERTS          04000020
         SPACE                                                          04400020
RSCB3    EQU   3                        SCB ADDRESS                     04800020
         SPACE                                                          05200020
RLCB4    EQU   4                        LCB ADDRESS                     05600020
         SPACE                                                          06000020
RDATAD5  EQU   5                        WORK REGISTER                   06400020
         SPACE                                                          06800020
RPREFIX  EQU   6                        BUFFER ADDRESS                  07200020
         SPACE                                                          07600020
RPARM7   EQU   7                        PARAMETER LIST ADDRESS          08000020
         SPACE                                                          08400020
RLIM8    EQU   8                        SHIFT LIMIT                     08800020
         SPACE                                                          09200020
RAVT9    EQU   9                        AVT ADDRESS                     09600020
         SPACE                                                          10000020
ROPT10   EQU   10                       OPTION FIELD ADDRESS            10400020
         SPACE                                                          10800020
RBASE    EQU   12                       BASE REGISTER                   11200020
         SPACE                                                          11600020
R13      EQU   13                       SAVE AREA ADDRESS               12000020
R14      EQU   14                       RETURN REGISTER                 12400020
R15      EQU   15                       LINK REGISTER                   12800020
         SPACE                                                          13200020
********* OTHER EQUATES *********                                       13600020
         SPACE                                                          14000020
ONE      EQU   1                        ONE-BYTE INCREMENT FACTOR       14400020
SHIFT8   EQU   8                        ONE-BYTE SHIFT FACTOR           14800020
         SPACE                                                          15200020
INSOFF   EQU   4                        PREFIX INSERT OFFSET            15600020
FOUR     EQU   4                        OFFSET USED ON RETURN    S22025 15800022
EIGHT    EQU   8                       NUMB DATE/TIME CHAR      SA53607 15900000
DATOFF   EQU   6                        PREFIX DATA OFFSET              16000020
         SPACE                                                          16400020
IDLEFLAG EQU   X'01'                    DATA TYPE = IDLES FLAG          16800020
REG15OFF EQU   X'10'                    REG 15 OFFSET IN SAVE AREA      17200020
DATACHAR EQU   X'80'                    DATA=CHARACTERS          S22025 17300022
DATAIDLS EQU   X'40'                    DATA=IDLES               S22025 17400022
         EJECT                                                          17600020
         USING IEDQAVTD,RAVT9                                           18000020
         USING IEDQLCB,RLCB4                                            18400020
         USING IEDQPRF,RPREFIX                                          18800020
         USING IEDQA801,RBASE                                           19200020
         USING IEDQSCB,RSCB3                                            19400020
         SPACE                                                          19600020
IEDQA801 EQU   *                                                        20000020
IEDQA8   IEDHJN MLTATOFF                MODULE ID                S22025 20200022
         LR    RPARM7,R1                SAVE PARAMETER LIST ADDRESS     20400020
         USING IEDQPARM,RPARM7                                          20800020
         SPACE                                                          21600020
         IC    R15,PARMOPT              SET OPTION FIELD OFFSET         22000020
         STC   R15,AVTPARM+2              IN PARAMETER LIST             22400020
         MVI   AVTPARM+3,REG15OFF       SET RETURN REG = 15             22800020
         IC    R15,PARMAE               PICK UP LOCATE-OPTION INDEX     23200020
         BAL   R14,LINK                 LINK TO GET OPT FLD ADDRESS     23600020
         SPACE                                                          24000020
         LTR   ROPT10,R15               SET ADDRESS IN OPT REGISTER     24400020
         BNZ   INITEXTN                 OPT FIELD FOUND, PROCEED        24800020
         SPACE                                                          25200020
         LA    R15,AVTECD4              SET BAD RETURN CODE             25600020
         B     EXIT                     EXIT IMMEDIATELY                26000020
         SPACE                                                          26400020
INITEXTN EQU   *                                                        26800020
         LH    REXTN2,PARMEXTN          PICK UP                         27200020
         N     REXTN2,AVTCLRHI            EXTENT FIELD                  27600020
         SPACE                                                          28000020
         SR    RDATAD5,RDATAD5          (CLEAR FOR INSERT)              28400020
         IC    RDATAD5,LCBISZE          PICK UP RESERVE CHAR COUNT      28800020
         LA    RDATAD5,AVTTXTSZ+1(,RDATAD5) ADD SIZE OF TEXT PREFIX     29200020
         TM    PRFSTAT1,PRFNHDRN        TEST IF HEADER PREFIX           29600020
         BO    TEXT                     NO, GO ADD FROM OPT FIELD       30000020
         SPACE                                                          30400020
         LA    RDATAD5,AVTHDRSZ-AVTTXTSZ(REXTN2,RDATAD5) YES, ADD       30800020
         TM    LCBSTAT1,LCBRECVN       RECEIVE OPERATION        SA53607 30860000
         BZ    TESTFIT                 NO, PROCEED              SA53607 30920000
         TM    SCBBSCFM,SCBDATEN       DATE/TIME REQUESTED      SA53607 30980000
         BZ    TESTFIT                 NO, PROCEED              SA53607 31040000
         LA    RDATAD5,EIGHT(RDATAD5)  YES, ADD FOR DATE/DIME   SA53607 31100000
         B     TESTFIT                    FROM EXTENT AND PROCEED       31200020
         SPACE                                                          31600020
TEXT     EQU   *                                                        32000020
         SR    R0,R0                    PICK                            32400020
         IC    R0,AVTEZERO(,R15)         UP                             32800020
         SLL   R0,SHIFT8                  OPTION                        33200020
         IC    R0,ONE(,R15)                FIELD                        33600020
         AR    RDATAD5,R0               ADD TO GET INITIAL OFFSET       34000020
*        B     TESTFIT                  PROCEED                         34400020
         EJECT                                                          34800020
TESTFIT  EQU   *                                                        35200020
         LH    R0,PRFSIZE               PICK UP TOTAL                   35600020
         N     R0,AVTCLRHI                DATA SIZE                     36000020
         CR    RDATAD5,R0               IS 1ST OFFSET IN NEXT BFR       36400020
         BL    WILLFIT                  NO, GO SET INITIAL OFFSET       36800020
         BE    MIGHTFIT                 MAYBE, GO SEE                   37200020
         SPACE                                                          37600020
WONTFIT  EQU   *                                                        38000020
         TM    PRFSTAT1,PRFNLSTN        YES, SEE IF LAST BUFFER         38400020
         BNO   GOODRTN                  IT IS, GO EXIT NOW              38800020
         SPACE                                                          39200020
         SR    RDATAD5,R0               NO, SET INITIAL OFFSET FOR      39600020
         B     SETOPT                     NEXT BFR, GO SET OPT FLD      40000020
         SPACE                                                          40400020
MIGHTFIT EQU   *                                                        40800020
         TM    PRFSTAT1,PRFNLSTN        IS THIS LAST BUFFER             41200020
         BNO   WILLFIT                  YES, GO AHEAD AND INSERT        41600020
         SPACE                                                          42000020
         SR    RDATAD5,RDATAD5          NO, WAIT TILL NEXT BUFFER       42400020
         B     SETOPT                   GO SET ZERO IN OPT FLD          42800020
         SPACE                                                          43200020
WILLFIT  EQU   *                                                        43600020
         ST    RDATAD5,INSOFF(,RPREFIX) SET INITIAL INSERT OFFSETS      44000020
         LH    R0,PARMAF                SET INSERT-DATA AND UNIT-       44400020
         STH   R0,AVTPARM+2               REQUEST INDICES IN AVT        44800020
*        B     MAINLOOP                 ENTER MAIN LOOP                 45200020
         EJECT                                                          45600020
MAINLOOP EQU   *                                                        46000020
         MVI   AVTPARM+1,IDLEFLAG       ASSUME IDLES TO INSERT          46400020
         TM    PARMA8,IDLEFLAG          TEST IF IDLES TO INSERT         46800020
         BO    TESTSND                  YES                      S22025 47200022
         SPACE                                                          47600020
         MVI   AVTPARM+1,AVTEZERO       INDICATE CHARACTERS INSERT      48100020
TESTSND  EQU   *                                                 S22025 48110022
         TM    LCBSTAT1,LCBSENDN        SEND                     S22025 48120022
         BO    MAIN2                    YES                      S22025 48130022
         TM    PARMA8,IDLEFLAG          IDLES SPECIFIED          S22025 48140022
         MVI   PRFXTRA,DATAIDLS         INDICATE IDLES           S22025 48150022
         BO    MAIN2                    YES                      S22025 48160022
         MVI   PRFXTRA,DATACHAR         INDICATE CHARACTERS      S22025 48170022
         SPACE                                                          48200020
MAIN2    EQU   *                                                        48300020
         L     R0,PARMINS               SET INSERT DATA DATA            48400020
         ST    R0,AVTPARM3                INTO AVT PARM AREA            48800020
         IC    R15,AVTPARM+3            GET UNIT-REQUEST INDEX          49200020
         BAL   R14,LINK                 GO LINK TO INSERT DATA          50000020
         SPACE                                                          50400020
         MVI   AVTPARM+1,AVTEZERO       INDICATE CHARACTERS             50800020
         LH    RLIM8,PRFSIZE            GET TOTAL                       52400020
         N     RLIM8,AVTCLRHI             DATA SIZE                     52800020
         LA    RLIM8,ONE(,RLIM8)        POINT BEYOND LAST BYTE          53200020
         LH    R0,DATOFF(,RPREFIX)      GET CURRENT                     53600020
         N     R0,AVTCLRHI                DATA OFFSET                   54000020
         SR    RLIM8,R0                 SUBTRACT FOR RESIDUAL COUNT     54400020
         SPACE                                                          54460020
         LTR   R15,R15                  TEST IF NO MORE UNITS           54520020
         IC    R15,AVTPARM+2            PICK UP IEDQAF INDEX            54580020
         LA    R15,ONE(,R15)            REQUEST SHIFT-DATA FUNCTION     54640020
         BNZ   URUNOUT                  NO MORE UNITS, BRANCH           54700020
         SPACE                                                          54800020
         CR    RLIM8,REXTN2             CAN ANOTHER INSERT BE DONE      55200020
         BH    SHIFT                    YES, GO SHIFT                   55600020
         BL    CLOSEUP                  NO, GO CLOSE UP                 56000020
         SPACE                                                          56400020
         TM    PRFSTAT1,PRFNLSTN        JUST AT END, IS IT LAST BFR     56800020
         BO    CLOSEUP                  NO, WAIT NEXT BFR, CLOSE UP     57200020
         SPACE                                                          57600020
SHIFT    EQU   *                                                        58000020
         LR    RLIM8,REXTN2             SET SHIFT LIMIT = EXTENT        58400020
         LA    R14,MAINLOOP             SET RETURN TO INSERT AGAIN      58800020
*                                       SHIFT TO NEXT INSERT POINT      58900020
         SPACE                                                          59000020
LINK     EQU   *                                                        59100020
         STC   R15,AVTPARM              SET ROUTINE INDEX               59200020
         LA    R1,AVTPARM               POINT TO PARAMETER LIST         59300020
         L     R15,AVTUI                GET USER INTERFACE ADDRESS      59400020
         BR    R15                      LINK TO SUBROUTINE              59500020
         EJECT                                                          59600020
URUNOUT  EQU   *                                                        59700020
         OI    SCBERR1,SCBNOBFN         TURN ON NO-MORE-UNITS FLAG      59800020
         LTR   RLIM8,RLIM8              IS CLOSEUP NEEDED               59900020
         BZ    FINALSZE                 NO, BRANCH                      60000020
         SPACE                                                          60100020
CLOSEUP  EQU   *                                                        60200020
         BAL   R14,LINK                 GO SHIFT TO END OF BUFFER       60400020
         SPACE                                                          60800020
         SR    REXTN2,RLIM8             GET NEXT BFR INITIAL OFFSET     61200020
         SPACE                                                          61600020
FINALSZE EQU   *                                                        61800020
         LH    RDATAD5,DATOFF(,RPREFIX) GET CURRENT                     62000020
         N     RDATAD5,AVTCLRHI           DATA OFFSET                   62400020
         SH    RDATAD5,INSOFF(,RPREFIX) SUBTRACT TO GET TRUE OFFSET     62800020
         LR    R1,RDATAD5               SAVE IN CASE INCL HDR           63000020
         BCTR  RDATAD5,AVTEZERO         DECR TO POINT TO LAST BYTE      63200020
         STH   RDATAD5,PRFSIZE          SET AS FINAL DATA SIZE          63600020
         SPACE                                                          64000020
TESTLAST EQU   *                                                        64560020
         TM    PRFSTAT1,PRFNLSTN        IS THIS LAST BUEFFER            64640020
         BNO   TESTRTN                  NO, BRANCH                      64840020
         SPACE                                                          65200020
         LR    RDATAD5,REXTN2           PREPARE TO SET OPT FIELD        65600020
         SPACE                                                          66000020
SETOPT   EQU   *                                                        66400020
         STC   RDATAD5,ONE(,ROPT10)     SET INITIAL OFFSET FOR          66800020
         SRL   RDATAD5,SHIFT8             NEXT BUFFER INTO              67200020
         STC   RDATAD5,AVTEZERO(,ROPT10) OPTION FIELD                   67600020
         SPACE                                                          67660020
TESTRTN  EQU   *                                                        67720020
         LA    R15,AVTECD4              SET ERROR RETURN CODE           67780020
         TM    SCBERR1,SCBNOBFN         DID WE RUN OUT OF UNITS         67840020
         BO    EXIT                     YES, RETURN WITH ERROR CODE     67900020
         SPACE                                                          68000020
GOODRTN  EQU   *                                                        68400020
         SR    R15,R15                  SET GOOD RETURN CODE            68800020
         SPACE                                                          69200020
EXIT     EQU   *                                                        69600020
         L     RBASE,AVTUI              GET RET INTERFACE ADDR   S22025 70600022
         B     FOUR(RBASE)              BRANCH TO RETURN ROUTINE S22025 71600022
         EJECT                                                          73600020
********* DSECTS *********                                              74000020
         SPACE                                                          74400020
IEDQPARM DSECT                                                          74800020
         SPACE                                                          75200020
PARMA8   DS    XL1                      MULT INS AT OFFSET INDEX        75600020
PARMLEN  DS    XL1                      PARAMETER LIST LENGTH           76000020
PARMAF   DS    XL1                      INSERT DATA INDEX               76400020
PARMAO   DS    XL1                      UNIT REQUEST INDEX              76800020
PARMINS  DS    F                        INSERT DATA FIELD               77200020
PARMEXTN DS    H                        EXTENT BETWEEN INSERTS          77600020
PARMAE   DS    XL1                      LOCATE OPTION INDEX             78000020
PARMOPT  DS    XL1                      OPTION FIELD OFFSET             78400020
         EJECT                                                          78800020
         TAVTD                                                          79200020
         EJECT                                                          79600020
         TLCBD                                                          80000020
         EJECT                                                          80400020
         TPRFD                                                          80800020
         EJECT                                                          80900020
         TSCBD                                                          81000020
         SPACE                                                          81200020
         END                                                            81600020
