IEDQAB   CSECT                                                          01000022
*********************************************************************** 02000022
*                                                                     * 03000022
*STATUS -- CHANGE LEVEL                                               * 04000022
*                                                                     * 05000022
*FUNCTION -- COMPLETES INITIALIZATION FUNCTIONS FOR THE PROCESSING    * 06000022
*   OF A BUFFER BY THE MESSAGE HANDLER.                               * 07000022
*                                                                     * 08000022
*   THIS MODULE IS A LOGICAL EXTENSION OF THE STARTMH SUB-TASK FOR    * 09000022
*   INPUT BUFFERS. IT ALLOWS CODING OF INBLOCK SUBGROUP AND EXECUTION * 10000022
*   OF SETEOM MODULE FOR ALL BUFFERS BEFORE (OR AFTER) 'CODE' MACRO   * 11000022
*   THE ROUTINE DETERMINES IF TRANSLATION IS TO BE DONE. IF SO, LINKS * 12000022
*   TO THE ROUTINE IEDQAW.  IF THIS IS A BUFFER OF A MULTI-BUFFER     * 13000022
*   HEADER, THE ROUTINE LINKS TO THE MODULE ADDR IN SCBMBHEN.  IF NOT * 14000022
*   CONTROL RETURNS TO THE MACRO FOR INHDR/INBUF PROCESSING.          * 15000022
*                                                                     * 16000022
*ENTRY POINTS --                                                      * 17000022
*        'IEDQAB01' FOR PROCESSING                                    * 18000022
*INPUT --                                                             * 19000022
*   REGISTER 1 - PARAMETER LIST ADDRESS                               * 20000022
*                                                                     * 21000022
*        *****************                                            * 22000022
*        *       * PARAM *                                            * 23000022
*        * INDEX *  LIST *                                            * 24000022
*        *       * LNGTH *                                            * 25000022
*        *       *       *                                            * 26000022
*        *****************                                            * 27000022
*   REGISTER 3 - SCB ADDRESS                                          * 28000022
*   REGISTER 4 - LCB ADDRESS                                          * 29000022
*   REGISTER 6 - BUFFER ADDRESS                                       * 30000022
*   REGISTER 9 - AVT ADDRESS                                          * 31000022
*   REGISTER 12 - ENTRY POINT AND BASE REGISTER                       * 32000022
*   REGISTER 13 - SAVE AREA                                           * 33000022
*                                                                     * 34000022
*OUTPUT --                                                            * 35000022
*   N/A                                                               * 36000022
*                                                                     * 37000022
*EXTERNAL REFERENCES -                                                * 38000022
*   'IEDQAW' - TRANSLATE ROUTINE                                      * 39000022
*   AVT - ADDRESS VECTOR TABLE                                        * 40000022
*   SCB - STATION CONTROL BLOCK                                       * 41000022
*                                                                     * 42000022
*EXITS NORMAL - THE BUFFER IS PASSED TO THE NEXT MACRO TO BE EXECUTED * 43000022
*   (AFTER TRANSLATION, IF APPLICABLE)                                * 44000022
*                                                                     * 45000022
*EXITS,ERROR - N/A                                                    * 46000022
*                                                                     * 47000022
*TABLES/WORK AREAS -- N/A                                             * 48000022
*                                                                     * 49000022
*ATTRIBUTES -- SERIALLY REUSABLE, REFRESHABLE, ENABLED, RESIDENT,     * 50000022
*   PROBLEM PROGRAM MODE.                                             * 51000022
*                                                                     * 52000022
*NOTES - THE OPERATION OF THIS MODULE DOES NOT DEPEND UPON AN         * 53000022
*   INTERNAL REPRESENTATION OF THE EXTERNAL CHARACTER SET.            * 54000022
*                                                                     * 55000022
*********************************************************************** 56000022
         EJECT                                                          57000022
*********** REGISTER EQUATES *************                              58000022
         SPACE 1                                                        59000022
R1       EQU   1    PARAMETER LIST                                      60000022
R2       EQU   2                                                        61000022
RSCB     EQU   3    SCB BASE                                            62000022
RPRF     EQU   6                        BUFFER ADDRESS                  62500022
RAVT     EQU   9    AVT BASE                                            63000022
RBASE    EQU   12   BASE FOR MODULE                                     64000022
RSAVE    EQU   13       REGISTER SAVE AREA                              65000022
R14      EQU   14   RETURN REGISTER                                     66000022
R15      EQU   15   LINK REGISTER TO IEDQUI                             67000022
FOUR     EQU   4                        DISPLACEMENT                    67500022
         SPACE 3                                                        68000022
         USING IEDQAB01,RBASE      SET BASE FOR MODULES                 69000022
         USING IEDQSCB,RSCB        BASE FOR SCB DSECT                   70000022
         USING IEDQAVTD,RAVT       BASE FOR AVT DSECT                   71000022
         USING IEDQPRF,RPRF             BASE FOR BUFFER PREFIX          71500022
         SPACE 2                                                        72000022
IEDQAB01 EQU   *                                                        73000022
IEDQAB   IEDHJN STARTAB                                                 75000022
         L     R15,AVTUI           GET INTERFACE MODULE ADDRESS         78000022
         TM    SCBSTATE,SCBCODE    IS TRANSLATION REQUESTED             79000022
         BNO   TESTMBH             NO, GO TEST FOR MULTI-BFR HDR        80000022
         L     R1,SCBTRANS-1       YES, GET CODE PARA LIST ADDR         81000022
         BALR  R14,R15             LINK TO TRANSLATE BUFFER             82000022
TESTMBH  EQU   *                                                        83000022
         L     R1,SCBMBHEN-1       GET NEXT MACRO ADDRESS               84000022
         SR    R15,R15                  ZERO REGISTER                   84300022
         CH    R15,PRFSIZE              ZERO LENGTH BUFFER              84600022
         L     R15,AVTUI                GET ADDRESS OF INTERFACE        85000022
         BE    FOUR(R15)                YES, EXIT                       85500022
         CLC   AVTINOUT,0(R1)      IS IT END-OF-LIST-                   86000022
         BE    FOUR(R15)                YES RETURN TO MH                87000022
         LA    RSAVE,AVTSAVE2           RESTORE SAVE AREA               88000022
         LM    R2,RBASE,28(RSAVE)       RESTORE MH REGISTERS            89000022
         BCT   R1,0(R15)           NO, BRANCH TO NEXT MACRO             90000022
         DC    X'0000'                  INT PROG CHK IF FALL THROUGH    90500022
         EJECT                                                          91000022
********* DSECTS ***********                                            92000022
         TAVTD                                                          93000022
         TPRFD                          BUFFER PREFIX DSECT MACRO       93500022
         TSCBD                                                          94000022
         END                                                            95000022
