AE01     TITLE '''IEDQAE'' - LOCATE OPTION FIELD ADDRESS ROUTINE'       00300020
IEDQAE   CSECT                                                          00600020
*A487000,488000,499200,709000,718000                             S22025 00670022
*C681000,726000,729000                                           S22025 00740022
*D498600-499800                                                  S22025 00810022
*                                                                       00900020
*                                                                       01200020
*                                                                       01500020
*                                                                       01800020
*********************************************************************** 02100020
*                                                                     * 02400020
*STATUS -- CHANGE LEVEL                                               * 02700020
*                                                                     * 03000020
*FUNCTION -- RETURNS THE ADDRESS OF AN OPTION FIELD WHEN PASSED THE   * 03300020
*   INDEX TO THE OPTION FIELD.                                        * 03600020
*                                                                     * 03900020
*   THE KEY (ORDINAL INDEX) OF THE CURRENTLY CONNECTED TERMINAL IS    * 04200020
*   ACCESSED FROM THE LCB (LCBTTCIN) AND IS PASSED TO THE TERMINAL    * 04500020
*   NAME TABLE CODE,  WHOSE ADDRESS IS ACCESSED FROM THE AVT          * 04800020
*   (AVTRNMPT),  AND WHICH RETURNS THE ADDRESS OF THE TERMINAL        * 05100020
*   TABLE ENTRY FOR THE TERMINAL.                                     * 05400020
*                                                                     * 05700020
*   THE 'OPTION FIELDS USED' FLAG IN THE TERMINAL STATUS FIELD        * 06000020
*   (TRMSTATE) IS TESTED.  IF IT IS NOT ON,  THE ERROR EXIT IS        * 06300020
*   TAKEN.                                                            * 06600020
*                                                                     * 06900020
*   THE NUMBER-OF-OPTION-ENTRIES FIELD (TRMOPNO) IS COMPARED WITH     * 07200020
*   THE NUMBER OF THE OPTION ENTRY PASSED IN THE PARAMETER LIST.      * 07500020
*   IF THE NUMBER OF THE OPTION ENTRY PASSED IS HIGH,  THE ERROR      * 07800020
*   EXIT IS TAKEN.                                                    * 08100020
*                                                                     * 08400020
*   THE OFFSET BYTE FOR THE OPTION FIELD SOUGHT (TRMOPT,  INDEXED     * 08700020
*   BY THE PARAMETER LIST OFFSET PASSED) IS ACCESSED AND TESTED.      * 09000020
*   IF IT IS X'FF',  THE OPTION FIELD IS NOT DEFINED FOR THIS         * 09300020
*   ENTRY.  THE ERROR EXIT IS TAKEN.                                  * 09600020
*                                                                     * 09900020
*   THE ADDRESS OF THE OPTION FIELD SOUGHT IS COMPUTED BY ADDING      * 10200020
*   THE ADDRESS OF THE OPTION TABLE,  ACCESSED FROM THE AVT           * 10500020
*   (AVTOPTPT);  THE OFFSET TO THE SET OF OPTION FIELDS FOR THIS      * 10800020
*   ENTRY,  ACCESSED FROM THE ENTRY (TRMOPTBL);  AND THE OFFSET       * 11100020
*   BYTE TO THE INDIVIDUAL OPTION FIELD PREVIOUSLY ACCESSED.          * 11400020
*                                                                     * 11700020
*   IF THE RETURN REGISTER SPECIFIED IS REGISTER 15,  THE ADDRESS     * 12000020
*   IS PLACED IN REGISTER 15.  OTHERWISE,  THE ADDRESS IS STORED      * 12300020
*   IN THE PROPER WORD IN THE REGISTER SAVE AREA AND REGISTER 15 IS   * 12600020
*   SET TO A RETURN CODE OF X'00'.  RETURN IS MADE TO THE CALLER      * 12900020
*   VIA THE RETURN INTERFACE ROUTINE.                                 * 13200020
*                                                                     * 13500020
*   ERROR EXIT:                                                       * 13800020
*   IF THE RETURN REGISTER IS 15,  IT IS SET TO A RETURN CODE OF      * 14100020
*   X'00'.  IF THE RETURN REGISTER IS NOT 15,  A RETURN CODE OF       * 14400020
*   X'FF' IS STORED IN THE PROPER WORD IN THE REGISTER SAVE AREA      * 14700020
*   AND REGISTER 15 IS SET TO A RETURN CODE OF X'04'.                 * 15000020
*                                                                     * 15300020
*ENTRY POINTS --                                                      * 15600020
*       'IEDQAE' TO RETURN THE ADDRESS OF AN OPTION FIELD WHEN        * 15900020
*   PASSED THE INDEX TO THE OPTION FIELD.  CALLING SEQUENCE FROM      * 16200020
*   USER INTERFACE IS:                                                * 16500020
*                                                                     * 16800020
*        L     R12,AVTMSGS-1            GET ADDR OF VCON TABLE        * 17100020
*        IC    R15,AVTEZERO(,R1)        GET INDEX TO ROUTINE ADDR     * 17400020
*        L     R12,AVTEZERO(R12,R15)    GET ROUTINE ADDRESS           * 17700020
*        BR    R12                      EXIT TO ROUTINE               * 18000020
*                                                                     * 18300020
*INPUT --                                                             * 18600020
*   REGISTER 1 -- THE ADDRESS OF A MACRO-GENERATED PARAMETER LIST.    * 18900020
*   PARAMETER LIST FORMAT IS:                                         * 19200020
*                                                                     * 19500020
*        *********************************                            * 19800020
*        *       * PARAM *  OPT  *  RTN  *                            * 20100020
*        * INDEX * LIST  *  FLD  *  REG  *                            * 20400020
*        *       * LNGTH * OFFST * OFFST *                            * 20700020
*        *********************************                            * 21000020
*                                                                     * 21300020
*   REGISTER 4 - ADDRESS OF THE LCB.                                  * 21600020
*                                                                     * 21900020
*   REGISTER 9 - ADDRESS OF THE AVT.                                  * 22200020
*                                                                     * 22500020
*   REGISTER 12 - ENTRY POINT ADDRESS AND BASE REGISTER.              * 22800020
*                                                                     * 23100020
*OUTPUT --                                                            * 23400020
*   REGISTER 15 - IF OPTION FIELD IS FOUND AND REGISTER 15 IS THE     * 23700020
*   RETURN REGISTER,  CONTAINS THE ADDRESS OF THE OPTION FIELD.  IF   * 24000020
*   OPTION FIELD IS FOUND AND REGISTER 15 IS NOT THE RETURN           * 24300020
*   REGISTER,  CONTAINS A RETURN CODE OF X'00'.  IF OPTION FIELD IS   * 24600020
*   NOT FOUND AND REGISTER 15 IS THE RETURN REGISTER,  CONTAINS A     * 24900020
*   RETURN CODE OF X'00'.  IF OPTION FIELD IS NOT FOUND AND           * 25200020
*   REGISTER 15 IS NOT THE RETURN REGISTER,  CONTAINS A RETURN CODE   * 25500020
*   OF X'04'.                                                         * 25800020
*                                                                     * 26100020
*EXTERNAL REFERENCES --                                               * 26400020
*   'IEDQLM' - RETURN INTERFACE ROUTINE FOR EXIT.                     * 26700020
*                                                                     * 27000020
*   TERMINAL NAME TABLE CODE (AVTRNMPT) TO GET THE ADDRESS OF THE     * 27300020
*   TERMINAL TABLE ENTRY.                                             * 27600020
*                                                                     * 27900020
*   AVT - ADDRESS VECTOR TABLE.                                       * 28200020
*                                                                     * 28500020
*   LCB - LINE CONTROL BLOCK.                                         * 28800020
*                                                                     * 29100020
*   TERMINAL TABLE.                                                   * 29400020
*                                                                     * 29700020
*   OPTION TABLE.                                                     * 30000020
*                                                                     * 30300020
*EXITS,  NORMAL -- OPTION FIELD IS FOUND.  REGISTER 15 IS THE         * 30600020
*   RETURN REGISTER AND CONTAINS THE ADDRESS OF THE OPTION FIELD.     * 30900020
*                                                                     * 31200020
*   OPTION FIELD IS FOUND.  RETURN REGISTER (NOT REGISTER 15) IN      * 31500020
*   SAVE AREA CONTAINS THE ADDRESS OF THE OPTION FIELD.  REGISTER     * 31800020
*   15 CONTAINS A RETURN CODE OF X'00'.                               * 32100020
*                                                                     * 32400020
*EXITS,  ERROR -- OPTION FIELD IS NOT FOUND.  REGISTER 15 IS THE      * 32700020
*   RETURN REGISTER AND CONTAINS A RETURN CODE OF X'00'.              * 33000020
*                                                                     * 33300020
*   OPTION FIELD IS NOT FOUND.  RETURN REGISTER (NOT REGISTER 15)     * 33600020
*   IN SAVE AREA CONTAINS A RETURN CODE OF X'FF'.  REGISTER 15        * 33900020
*   CONTAINS A RETURN CODE OF X'04'.                                  * 34200020
*                                                                     * 34500020
*TABLES/WORK AREAS -- N/A.                                            * 34800020
*                                                                     * 35100020
*ATTRIBUTES -- REENTRANT,  SERIALLY REUSABLE,  REFRESHABLE,           * 35400020
*   ENABLED,  RESIDENT,  PROBLEM PROGRAM MODE.                        * 35700020
*                                                                     * 36000020
*   NOTES -- THE OPERATION OF THIS MODULE DOES NOT DEPEND UPON AN     * 36300020
*   INTERNAL REPRESENTATION OF THE EXTERNAL CHARACTER SET.            * 36600020
*                                                                     * 36900020
*********************************************************************** 37200020
         EJECT                                                          37500020
********* REGISTER EQUATES *********                                    37800020
        SPACE                                                           38100020
R1       EQU   1                        PARAMETER REGISTER              38400020
*                                                                       38700020
RWORK    EQU   2                        GENERAL WORK REGISTER           39000020
*                                                                       39300020
RSAVE    EQU   3                        SAVE AREA FOR PARAMETER         39600020
*                                                                       39900020
RLCB     EQU   4                        BASE FOR LCB                    40200020
*                                                                       40500020
RCOMP    EQU   5                        SECONDARY WORK REGISTER         40800020
*                                                                       41100020
RWORK7   EQU   7                        WORK REGISTER                   41400020
         SPACE                                                          41700020
RTERM    EQU   8                        TERMINAL ENTRY REGISTER         42000020
*                                                                       42300020
RAVT     EQU   9                        BASE REGISTER FOR AVT           42600020
*                                                                       42900020
RBASE    EQU   12                       BASE REGISTER FOR MODULE        43200020
*                                                                       43500020
R13      EQU   13                       ADDRESS OF CALLER SAVE AREA     43800020
*                                                                       44100020
R14      EQU   14                       RETURN ADDRESS REGISTER         44400020
*                                                                       44700020
R15      EQU   15                       ENTRY POINT AND RETURN CODE     45000020
*                                                                       45300020
         SPACE                                                          45600020
********* PARAMETER LIST OFFSETS *********                              45900020
OPTOFF   EQU   2                        OFFSET OF OPTION FIELD          46200020
SAVEOFF  EQU   3                        OFFSET INTO SAVE AREA           46500020
         SPACE                                                          46800020
********* OTHER EQUATES *********                                       47100020
         SPACE                                                          47400020
ONE      EQU   1                        ONE BYTE LENGTH                 47700020
THREE    EQU   3                        SHIFT VALUE OF THREE            48000020
FOUR     EQU   4                        OFFSET TO 2ND WORD OF PARM      48300020
OFF15    EQU   16                       OFFSET TO REG 15 IN SAVE        48600020
PREVSAVE EQU   4                        PREVIOUS SAVE AREA ADDR  S22025 48700022
NEXTSAVE EQU   8                        NEXT SAVE AREA ADDRESS   S22025 48800022
         EJECT                                                          48900020
         USING IEDQAVTD,RAVT            ESTABLISH BASE FOR AVT          49200020
         USING IEDQLCB,RLCB             ESTABLISH ADDRESSABILITY        49500020
         USING IEDQAE,RBASE             GIVE ROUTINE A BASE             49800020
         SPACE                                                          49830022
IEDQAE   IEDHJN LOCOPT                  ID AND DATE              S22025 49920022
         SPACE                                                          50010022
**************************************************************** S22025 50040022
*                                                                       50100020
* THIS SECTION LOCATES AND GIVES CONTROL TO THE ROUTINE WHICH           50400020
* LOCATES THE TERMINAL ENTRY.                                           50700020
        SPACE                                                           51000020
         LR    RSAVE,R1                 SAVE PARAMETER LIST             51300020
         LH    R1,LCBTTCIN              PICK UP TERMNAME INDEX          51600020
         N     R1,AVTCLRHI              CLEAR HI-ORDER TWO BYTES        51900020
         BZ    NOTFOUND                 ERROR IF ZEROES                 52200020
         SPACE                                                          52500020
         L     R15,AVTRNMPT             GET ADDR OF TERMNAME RTN        52800020
         BALR  R14,R15                  GIVE IT CONTROL                 53100020
*                                                                       53400020
* THIS SECTION GOES THROUGH THE NECESSARY THREE TESTS TO DETERMINE      53700020
* IF THE REQUESTED OPTION FIELD IS PRESENT.  IF NOT, ABNORMAL EXIT      54000020
* IS MADE.  OTHERWISE A SUCCESSFUL EXIT IS PREPARED AND TAKEN.          54300020
*                                                                       54600020
         LR    RTERM,R1                 SET UP BASE FOR TERM ENTRY      54900020
         USING IEDQTRM,RTERM            GIVE IT ADDRESSABILITY          55200020
         TM    TRMSTATE,TRMOPTFN        ARE OPTION FIELDS PRESENT       55500020
         BNO   NOTFOUND                 NO - RETURN TO CALLER           55800020
*                                                                       56100020
         CLC   OPTOFF(ONE,RSAVE),TRMOPNO COMPARE TO COUNT OF OPTIONS    56400020
         BH    NOTFOUND                 HIGHER - RETURN TO CALLER       56700020
*                                                                       57000020
         SR    RWORK,RWORK              CLEAR                           57300020
         IC    RWORK,OPTOFF(,RSAVE)     PICK UP OPTION OFFSET           57600020
         SR    RCOMP,RCOMP              CLEAR OPTION OFFSET REG         57900020
         IC    RCOMP,TRMOPT-1(RWORK)    GET TRUE OFFSET                 58200020
         IC    RWORK,AVTHFF+1           LOAD IT WITH AN X'FF'           58500020
         CR    RCOMP,RWORK              IS OFFSET A X'FF'               58800020
         BE    NOTFOUND                 YES - RETURN TO CALLER          59100020
*                                                                       59400020
* THIS SECTION DETERMINES THE ACTUAL ADDRESS OF THE OPTION FIELD        59700020
* AND OF THE OPTION CSECT TABLE ENTRY FOR THE OPTION FIELD              60000020
* AND BRANCHES TO THE COMMON EXIT ROUTINE                               60300020
*                                                                       60600020
         L     RWORK,AVTOPTPT           GET ADDRESS OF OPTION TABLE     60900020
         L     R1,FOUR(,RWORK)          GET OPT CSECT TABLE ADDR        61200020
         SPACE                                                          61500020
         AH    RWORK,TRMOPTBL           ADD OFFSET FOR THIS ENTRY       61800020
         AR    RWORK,RCOMP              ADD OFFSET FOR THIS OPTION      62100020
*                                                                       62400020
         IC    RCOMP,OPTOFF(,RSAVE)     PICK UP OPTION OFFSET           62700020
         BCTR  RCOMP,AVTEZERO           DECREMENT FOR INDEX             63000020
         LA    RWORK7,AVTEZERO(RCOMP,RCOMP) MULTIPLY INDEX              63300020
         SLL   RCOMP,THREE              BY TEN TO GET                   63600020
         LA    RCOMP,AVTEZERO(RWORK7,RCOMP) ACTUAL OFFSET               63900020
         LA    R1,AVTEZERO(RCOMP,R1)    POINT TO ENTRY                  64200020
         EJECT                                                          64500020
         CLI   SAVEOFF(RSAVE),OFF15     IS OUTPUT REG 15                64800020
         BE    DEFAULT                  YES - PUT RESULT IN 15          65100020
*                                                                       65400020
         SR    R15,R15                  SET NORMAL RETURN CODE          65700020
         B     STOREREG                 GO STORE IN RTN REG             66000020
*                                                                       66300020
ERROR    EQU   *                                                        66600020
         SR    RWORK,RWORK              CLEAR ADDR REG TO ZERO          66900020
*                                                                       67200020
DEFAULT  EQU   *                                                        67500020
         LR    R15,RWORK                PUT RESULT IN REG 15            67800020
         B     EXIT                     RETURN TO CALLER         S22025 68100022
*                                                                       68400020
NOTFOUND EQU   *                                                        68700020
         CLI   SAVEOFF(RSAVE),OFF15     IS OUTPUT REG 15                69000020
         BE    ERROR                    YES, SET ERROR RETURN           69300020
*                                                                       69600020
         LA    RWORK,AVTEFF             PLACE NOT FOUND INDICATOR       69900020
         LA    R15,AVTECD4              SET ERROR RETURN CODE           70200020
*                                                                       70500020
STOREREG EQU   *                                                        70800020
         L     R13,PREVSAVE(R13)        POINT TO PREV SAVE AREA  S22025 70900022
         SR    RCOMP,RCOMP                                              71100020
         IC    RCOMP,SAVEOFF(,RSAVE)    PICK UP SAVE AREA OFFSET        71400020
         ST    RWORK,AVTEZERO(RCOMP,R13) STORE OFFSET IN SAVE AREA      71700020
         L     R13,NEXTSAVE(R13)        CURRENT SAVE AREA        S22025 71800022
*                                                                       72000020
EXIT     EQU   *                                                        72300020
         L     RBASE,AVTUI              GET RET INTERFACE ADDR   S22025 72600022
         B     FOUR(RBASE)              RETURN TO CALLER         S22025 72900022
        EJECT                                                           73200020
********* DSECTS *********                                              73500020
        SPACE                                                           73800020
         TTRMD                                                          74100020
         TLCBD                                                          74400020
         TAVTD                                                          74700020
*                                                                       75000020
         END                                                            75300020
