AI01     TITLE '''IEDQAI'' - SKIP FORWARD AND SCAN ROUTINE'             00200020
IEDQAI   CSECT                                                          00400020
         SPACE 3                                                        00400122
*C386000                                                        SA59004 00400222
*A260500,276600-277200,303000,313000,593000,599000,625600,647000 S22025 00400422
*A029000,097000,134600-135200,139000,166000,248040-249840,257000 S22025 00400522
*C030000,152000-156000,182000,190000,213000-218000,252400-255600 S22025 00400622
*C270000,354000,362000-366000,448000,462000,476000,562000-564000 S22025 00400722
*D164000-168000,180000,184000,236000,280000-294000,300000-306000 S22025 00400822
*D312000-316000,318000-332000,398000-444000,570000-574000        S22025 00400922
*C194000-196000                                                 SA55417 00401022
*A652000                                                        SA54273 00401122
*C584800                                                        SA54273 00401222
*                                                                       00401322
         SPACE 3                                                        00401422
*********************************************************************** 00401522
*C606000                                                         S22029 00401922
*D170000-172000,178000                                           S22029 00402022
*                                                                     * 00405722
*C504000                                                         S21903 00406022
*TITLE: 'IEDQAI' - SKIP FORWARD AND SCAN ROUTINE                      * 00406122
*                                                                     * 00406522
*STATUS -- CHANGE LEVEL 0                                             * 00406922
*                                                                     * 00407322
*FUNCTION -- MOVES THE SCAN POINTER FORWARD IN THE HEADER A           * 00407822
*   SPECIFIED NUMBER OF BYTES, OR ACCESSES AND RETURNS TO THE         * 00408322
*   CALLER THE NEXT FIELD BEYOND THE SCAN POINTER AND OPTIONALLY      * 00408822
*   COMPARES THE FIELD FOUND WITH A FIELD WHOSE ADDRESS IS PASSED.    * 00409322
*                                                                     * 00409822
*   ENTRY FOR SKIP FORWARD --                                         * 00410322
*                                                                     * 00412322
*   THE SCAN POINTER IS UPDATED BY THE SPECIFIED NUMBER OF NON-BLANK  * 00414322
*   CHARACTERS.                                                       * 00416322
*                                                                     * 00419220
*   RETURN CODES -- REGISTER 15                                       * 00420222
*         X'00' IF NORMAL COMPLETION                                  * 00421222
*         X'04' IF OUT-OF-BUFFER DETECTED BEFORE SKIP COUNT COMPLETE  * 00422222
*                                                                     * 00423220
*   ENTRY FOR FIXED SCAN --                                           * 00424020
*                                                                     * 00424422
*   THE CALLER MAY DEFINE THE NEXT FIELD AS THE NEXT 'N' DATA         * 00424820
*   BYTES  IN THE BUFFER.  IF THE CHARACTER STRING HAS BEEN PASSED    * 00425822
*   IN THE PARAMETER LIST, THE FIELD FOUND IS COMPARED TO IT.         * 00426822
*                                                                     * 00430420
*   RETURN CODES -- REGISTER 15                                       * 00432422
*         X'00'  CHARACTERS NOT FOUND                                 * 00434422
*         OFFSET TO NEXT FIELD IF STRING FOUND                        * 00436422
*                                                                     * 00439220
*   IF END-OF-BUFFER DETECTED, THE MULTIPLE BUFFER HEADER EXIT        * 00440222
*   IS TAKEN.                                                         * 00441222
*                                                                     * 00442420
*   ENTRY FOR VARIABLE SCAN --                                        * 00443220
*   THE CALLER MAY DEFINE THE NEXT FIELD AS THE NEXT CONTIGUOUS       * 00444020
*   STRING OF DATA BYTES, DELIMITED BY A BLANK.  THIS IS THE          * 00444820
*   VARIABLE SCAN FUNCTION.  FOR THIS FUNCTION,  THE ROUTINE LOOPS    * 00445620
*   TO THE BUFFER STEP ROUTINE UNTIL A NON-BLANK CHARACTER IS         * 00446420
*   RETURNED.  THIS CHARACTER IS STORED IN THE AVT WORK AREA.  THE    * 00447220
*   ROUTINE LOOPS AGAIN TO THE BUFFER STEP ROUTINE,  ADDING DATA      * 00448020
*   BYTES TO THE AVT WORK AREA UNTIL (1) A BLANK DELIMITER IS         * 00448820
*   FOUND OR (2) THE EIGHT-BYTE AVT WORK AREA IS FILLED.  AT THIS     * 00449620
*   POINT THE NORMAL SCAN END EXIT IS TAKEN.                          * 00450420
*                                                                     * 00451220
*   IF RETURN FROM THE BUFFER STEP ROUTINE INDICATES THAT THE END     * 00452020
*   OF THE BUFFER HAS BEEN PASSED,  THE MULTIPLE BUFFER HEADER EXIT   * 00452820
*   IS TAKEN.                                                         * 00453620
*                                                                     * 00454420
*   NORMAL SCAN END EXIT --                                           * 00455220
*   THE OFFSET TO THE END OF THE FIELD IN THE BUFFER IS STORED        * 00456020
*   EITHER IN THE PREFIX SCAN POINTER (PRFSCAN) OR IN A REGISTER      * 00456820
*   SPECIFIED BY THE CALLER.  A RETURN CODE OF ZERO IS SET IN         * 00457620
*   REGISTER 15,  UNLESS REGISTER 15 ITSELF CONTAINS THE SCAN         * 00458420
*   POINTER OFFSET,  AND RETURN IS MADE TO THE CALLER VIA THE         * 00459220
*   RETURN INTERFACE ROUTINE.                                         * 00460020
*                                                                     * 00460820
*   MULTIPLE BUFFER HEADER EXIT --                                    * 00461620
*   A NEGATIVE RETURN CODE IS SET IN REGISTER 15.  IF THE CALLER      * 00462420
*   HAS SPECIFIED A RETURN REGISTER,  RETURN IS MADE TO THE CALLER    * 00463220
*   VIA THE RETURN INTERFACE ROUTINE.                                 * 00464020
*                                                                     * 00464820
*   IF NO RETURN REGISTER IS SPECIFIED,  THE PORTION OF THE FIELD     * 00465620
*   THAT HAS BEEN ACCESSED IS MOVED FROM THE AVT WORK AREA TO THE     * 00466420
*   SCB SAVE AREA (SCBMBSSA).  THE USER'S REGISTERS,  SAVED IN THE    * 00467220
*   AVT,  ARE MOVED TO THE SCB REGISTER SAVE AREA (SCBRGSAV).  THE    * 00468020
*   PREFIX SCAN POINTER (PRFSCAN) IS UPDATED TO POINT BEYOND THE      * 00468820
*   END OF THE BUFFER.  THE ADDRESS OF THE PARAMETER LIST IS SAVED    * 00469620
*   IN THE SCB (SCBMBHEN).  RETURN IS MADE TO THE CALLER VIA THE      * 00470420
*   RETURN INTERFACE ROUTINE.                                         * 00471220
*                                                                     * 00472020
*   MULTIPLE BUFFER HEADER ENTRY --                                   * 00472820
*   THE ROUTINE MAY BE ENTERED DIRECTLY FROM THE START MH ROUTINE     * 00473620
*   TO COMPLETE A SCAN FUNCTION INTERRUPTED BY A MULTIPLE BUFFER      * 00474420
*   HEADER SITUATION,  OR FROM THE FORWARD ROUTINE TO FIND SECOND-    * 00475220
*   ARY DESTINATIONS FOR MULTIPLE ROUTING.  IF ENTRY IS FROM START    * 00476020
*   MH,  THE USER'S REGISTERS,  SAVED IN THE SCB,  ARE MOVED TO THE   * 00476820
*   AVT SAVE AREA FOR THIS ROUTINE AND A NEW RETURN ADDRESS IS        * 00477620
*   COMPUTED AND STORED IN THE SAVE AREA.  THE SCB SAVE AREA IS       * 00478420
*   EXAMINED TO DETERMINE IF THE FIRST CHARACTER HAS BEEN FOUND.      * 00479220
*   IF IT HAS NOT,  A HALFWORD X'FFFF' IS SET IN THE SCB SAVE AREA    * 00480020
*   AND THE APPROPRIATE SCAN FUNCTION IS RESUMED AS IF INITIALLY      * 00480820
*   ENTERED.  IF THE FIRST CHARACTER HAS BEEN FOUND,  THE PORTION     * 00481620
*   OF THE FIELD FOUND IS MOVED BACK FROM THE SCB SAVE AREA TO THE    * 00482420
*   AVT WORK AREA.  A HALFWORD X'FFFF' IS SET IN THE SCB SAVE AREA.   * 00483220
*   IF A FIXED SCAN FUNCTION IS BEING COMPLETED,  THE FUNCTION IS     * 00484020
*   RESUMED AS IF INITIALLY ENTERED.  IF A VARIABLE SCAN FUNCTION     * 00484820
*   IS BEING COMPLETED,  THE FUNCTION IS RESUMED AT AN ENTRY PAST     * 00485620
*   THE POINT WHERE THE FIRST CHARACTER IS BEING FOUND.               * 00486420
*                                                                     * 00487220
*ENTRY POINTS --                                                      * 00488020
*       'IEDQAI' TO SKIP FORWARD A FIXED LENGTH OR TO SCAN FOR AND    * 00488820
*   RETURN THE NEXT FIELD. CALLING SEQUENCE FROM USER INTERFACE IS:   * 00489620
*                                                                     * 00490420
*        L     R12,AVTMSGS-1            GET ADDR OF VCON TABLE        * 00491220
*        IC    R15,AVTEZERO(,R1)        GET INDEX TO ROUTINE ADDR     * 00492020
*        L     R12,AVTEZERO(R12,R15)    GET ROUTINE ADDRESS           * 00492820
*        BR    R12                      EXIT TO ROUTINE               * 00493620
*                                                                     * 00494420
*INPUT --                                                             * 00495220
*   REGISTER 1 - THE ADDRESS OF A PARAMETER LIST BUILT BY THE         * 00496020
*   CALLER (EITHER THE SETSCAN MACRO EXPANSION OR A HIGHER LEVEL MH   * 00496820
*   ROUTINE).  PARAMETER LIST FORMAT IS:                              * 00497620
*                                                                     * 00498420
*   SCAN FUNCTION PARAMETER LIST (INDEX FLAG = X'00')                 * 00499220
*        *********************************                            * 00500020
*        *       * PARAM *  REG  * SCAN  *                            * 00500820
*        * INDEX * LIST  * OFF-  *  LNG  *                            * 00501620
*        *       *  LNG  *  SET  *       *                            * 00502420
*        *********************************                            * 00503220
*        *          ADDRESS OF          *                             * 00504020
*        *       CHARACTER STRING       *                             * 00504820
*        *          (OPTIONAL)          *                             * 00505620
*        *********************************                            * 00506420
*                                                                     * 00507220
*   SKIP FORWARD FUNCTION PARAMETER LIST (INDEX FLAG = X'01')         * 00508020
*        *********************************                            * 00508820
*        *       * PARAM *               *                            * 00509620
*        * INDEX * LIST  *  SKIP COUNT   *                            * 00510420
*        *       * LNGTH *               *                            * 00511220
*        *********************************                            * 00512020
*                                                                     * 00512820
*   REGISTER 3 - THE ADDRESS OF THE SCB.                              * 00513620
*                                                                     * 00514420
*   REGISTER 4 - THE ADDRESS OF THE LCB.                              * 00515220
*                                                                     * 00516020
*   REGISTER 6 - THE ADDRESS OF THE CURRENT BUFFER.                   * 00516820
*                                                                     * 00517620
*   REGISTER 9 - THE ADDRESS OF THE AVT.                              * 00518420
*                                                                     * 00519220
*   REGISTER 12 - THE ENTRY POINT ADDRESS AND BASE REGISTER FOR       * 00520020
*                                                                     * 00520820
*   REGISTER 13 - THE ADDRESS OF THE CALLING ROUTINE'S SAVE AREA.     * 00521620
*                                                                     * 00522420
*OUTPUT --                                                            * 00523220
*   REGISTER 15 - RETURN CODE.  ITS VALUE IS X'00' FOR SUCCESSFUL     * 00524020
*   COMPLETION,  A NEGATIVE VALUE IF A SCAN FUNCTION FAILS TO         * 00524820
*   COMPLETE (MULTIPLE BUFFER HEADER DETECTED), OR X'04' IF THE       * 00525620
*   SKIP FAILS TO COMPLETE.  FOR SETSCAN 0,  REGISTER 15 CONTAINS     * 00526420
*   THE ADDRESS OF THE CURRENT SETTING OF THE SCAN POINTER.           * 00527220
*                                                                     * 00528020
*   AVT WORK AREA (AVTDOUBL) - ON SUCCESSFUL COMPLETION OF A SCAN     * 00528820
*   FUNCTION, THE NEXT FIELD IN THE BUFFER.                           * 00529620
*                                                                     * 00530420
*   AVT PARAMETER AREA (AVTPARM) - ON SUCCESSFUL COMPLETION OF A      * 00531220
*   SCAN FUNCTION,  THE FIRST HALFWORD CONTAINS THE LENGTH OF THE     * 00532020
*   FIELD RETURNED. IF REQUESTED BY THE CALLER, THE SECOND HALFWORD   * 00532820
*   CONTAINS THE OFFSET IN THE BUFFER TO THE END OF THE FIELD BEING   * 00533620
*   RETURNED.                                                         * 00534420
*                                                                     * 00535220
*   BUFFER PREFIX SCAN POINTER (PRFSCAN) - ON SUCCESSFUL COMPLETION   * 00536020
*   OF A SCAN FUNCTION, AND IF REQUESTED BY THE CALLER, THE OFFSET    * 00536820
*   IN THE BUFFER TO THE END OF THE FIELD BEING RETURNED. ON          * 00537620
*   SUCCESSFUL COMPLETION OF THE SKIP FORWARD FUNCTION, THE OFFSET    * 00538420
*   OF THE SCAN POINTER MOVED FORWARD THE SPECIFIED LENGTH.  ON A     * 00539220
*   MULTIPLE BUFFER HEADER EXIT,  THE OFFSET TO A POINT ONE BYTE      * 00540020
*   BEYOND THE END OF DATA IN THE BUFFER.                             * 00540820
*                                                                     * 00541620
*   SCB SAVE AREA (SCBMBSSA) - ON A MULTIPLE BUFFER HEADER EXIT FOR   * 00542420
*   A SCAN FUNCTION,  THE BYTES OF THE FIELD REQUESTED ACCESSED       * 00543220
*   FROM THIS BUFFER,  PADDED WITH BLANKS (IF NECESSARY TO FILL       * 00544020
*   SCBMBSSA) AT THE HIGH-ORDER END.                                  * 00544820
*                                                                     * 00545620
*   SCB MULTIPLE BUFFER HEADER ENTRY FIELD (SCBMBHEN) - ON A          * 00546420
*   MULTIPLE BUFFER HEADER EXIT,  THE ADDRESS OF THE PARAMETER LIST   * 00547220
*                                                                     * 00548020
*   SCB REGISTER SAVE AREA (SCBRGSAV) (IF DEFINED) - ON A MULTIPLE    * 00548820
*   BUFFER HEADER EXIT,  THE USER'S REGISTERS.                        * 00549620
*                                                                     * 00550420
*EXTERNAL REFERENCES --                                               * 00551220
*   AVT - ADDRESS VECTOR TABLE.                                       * 00558420
*                                                                     * 00559220
*   SCB - STATION CONTROL BLOCK FOR CURRENT STATION.                  * 00560020
*                                                                     * 00560820
*   BUFFER CURRENTLY BEING PROCESSED.                                 * 00561620
*                                                                     * 00562420
*EXITS,  NORMAL -- SUCCESSFUL COMPLETION OF A SCAN FUNCTION.  THE     * 00563220
*   AVT WORK AREA (AVTDOUBL) CONTAINS THE FIELD FROM THE BUFFER.      * 00564020
*   THE AVT PARAMETER AREA (AVTPARM) CONTAINS IN THE HIGH-ORDER       * 00564820
*   HALFWORD THE LENGTH OF THE FIELD.  THE OFFSET IN THE BUFFER TO    * 00565620
*   THE END OF THE FIELD IS STORED EITHER IN THE LOW-ORDER HALFWORD   * 00566420
*   OF THE AVT PARAMETER AREA OR IN THE BUFFER PREFIX SCAN POINTER    * 00567220
*   (PRFSCAN).  REGISTER 15 CONTAINS A RETURN CODE OF X'00'.          * 00568020
*                                                                     * 00568820
*   SUCCESSFUL COMPLETION OF A SKIP FUNCTION.  THE BUFFER PREFIX      * 00569620
*   SCAN POINTER CONTAINS THE OFFSET OF THE SCAN POINTER MOVED        * 00570420
*   FORWARD THE SPECIFIED LENGTH.  REGISTER 15 CONTAINS A RETURN      * 00571220
*   CODE OF X'00'.                                                    * 00572020
*                                                                     * 00572820
*   A SCAN FUNCTION FAILS TO COMPLETE IN THIS BUFFER.  THE BUFFER     * 00573620
*   PREFIX SCAN POINTER CONTAINS THE OFFSET TO A POINT ONE BYTE       * 00574420
*   BEYOND THE END OF DATA IN THE BUFFER.  THE SCB SAVE AREA          * 00575220
*   (SCBMBSSA) CONTAINS THE BYTES ACCESSED FROM THIS BUFFER,          * 00576020
*   PADDED WITH BLANKS (IF NECESSARY TO FILL SCBMBSSA) AT THE         * 00576820
*   HIGH-ORDER END.  THE SCB MULTIPLE BUFFER HEADER ENTRY FIELD       * 00577620
*   (SCBMBHEN) CONTAINS THE ADDRESS OF THE PARAMETER LIST.  THE       * 00578420
*   SCB REGISTER SAVE AREA (SCBRGSAV),  IF DEFINED,  CONTAINS THE     * 00579220
*   CALLER'S REGISTERS.  REGISTER 15 CONTAINS A NEGATIVE RETURN       * 00580020
*   CODE.                                                             * 00580820
*                                                                     * 00581620
*   SUCCESSFUL COMPLETION OF SETSCAN 0.  REGISTER 15 CONTAINS THE     * 00582420
*   ADDRESS OF THE CURRENT SETTING OF THE SCAN POINTER.               * 00583220
*                                                                     * 00584020
*EXITS,  ERROR -- THE SKIP FUNCTION FAILS TO COMPLETE.  REGISTER 15   * 00584820
*   CONTAINS A RETURN CODE OF X'04'.                                  * 00585620
*                                                                     * 00586420
*TABLES/WORK AREAS -- N/A.                                            * 00587220
*                                                                     * 00588020
*ATTRIBUTES -- SERIALLY REUSABLE, REFRESHABLE, ENABLED, RESIDENT,     * 00588820
*   PROBLEM PROGRAM MODE.                                             * 00589620
*                                                                     * 00590420
*NOTES -- THE OPERATION OF THIS MODULE DEPENDS UPON THE INTERNAL      * 00591220
*   REPRESENTATION OF AN EXTERNAL CHARACTER SET WHICH IS              * 00592020
*   EQUIVALENT TO THE ONE USED AT ASSEMBLY TIME.  THE CODING HAS      * 00592820
*   BEEN ARRANGED SO THAT REDEFINITION OF ''CHARACTER'' CONSTANTS,    * 00593620
*   BY REASSEMBLY, WILL RESULT IN CORRECT MODULE FOR THE NEW          * 00594420
*   DEFINITIONS.                                                      * 00595220
*                                                                     * 00596020
*********************************************************************** 00596820
         EJECT                                                          00600020
********* REGISTER EQUATES *********                                    00800020
         SPACE                                                          01000020
R0       EQU   0                        WORK REGISTER                   01200020
         SPACE                                                          01400020
R1       EQU   1                        ADDRESS OF PARAMETER LIST       01600020
         SPACE                                                          01800020
RBLANK2  EQU   2                        BLANK COMPARE REGISTER          02000020
RWORK2   EQU   2                        WORK REGISTER                   02200020
         SPACE                                                          02400020
RSCB     EQU   3                        ADDRESS OF SCB                  02600020
         SPACE                                                          02800020
RLCB     EQU   4                        ADDR OF LCB              S22025 02900022
RUNIT    EQU   8                        ADDRESS OF CURRENT UNIT  S22025 03000022
         SPACE                                                          03200020
RSCAN    EQU   5                        ADDRESS OF SCAN POINTER         03400020
         SPACE                                                          03600020
RPREFIX  EQU   6                        ADDRESS OF BUFFER               03800020
         SPACE                                                          04000020
RSCANOFF EQU   7                        OFFSET OF SCAN POINTER          04200020
         SPACE                                                          04400020
RCOMP8   EQU   8                        COMPARE CHARACTERS ADDRESS      04600020
         SPACE                                                          04800020
RAVT     EQU   9                        ADDRESS OF AVT                  05000020
         SPACE                                                          05200020
RPARLEN  EQU   10                       LENGTH PARAMETER                05400020
         SPACE                                                          05600020
REOUAD   EQU   11                       ADDR OF END OF CURRENT UNIT     05800020
         SPACE                                                          06000020
RBASE    EQU   12                       BASE REGISTER                   06200020
         SPACE                                                          06400020
R13      EQU   13                       ADDRESS OF SAVE AREA            06600020
R14      EQU   14                       RETURN REGISTER                 06800020
R15      EQU   15                       BRANCH & RTN CODE REGISTER      07000020
         SPACE                                                          07200020
********* OTHER EQUATES *********                                       07400020
         SPACE                                                          07600020
INC1     EQU   1                        INCREMENT VALUE OF 1            07800020
ONE      EQU   1                        MBH-ENTRY FLAG                  08000020
TWO      EQU   2                        LENGTH OF A HALFWORD            08200020
FOUR     EQU   4                        LENGTH OF A FULLWORD            08400020
LBALR    EQU   6                        LNG OF LOAD + BALR              08600020
SIX      EQU   6                        OFFSET TO MBSSA LAST BYTE       08800020
SEVEN    EQU   7                        CLEAR LENGTH FOR AVTDOUBL       09000020
MBSSALEN EQU   7                        LENGTH OF SCB SAVE AREA         09200020
COMP     EQU   8                        LNG OF COMPARE PARAM LIST       09400020
MAX      EQU   8                        SIZE OF AVT WORK AREA           09600020
HI       EQU   X'2'                     HIGH CONDITION           S22025 09700022
         SPACE                                                          09800020
PARMLEN  EQU   1                        PARAMETER LIST LENGTH           10000020
SKIPLEN  EQU   2                        OFFSET TO SKIP LENGTH           10200020
PARMREG  EQU   2                        OFFSET TO REGISTER OFFSET       10400020
SCANLEN  EQU   3                        OFFSET TO SCAN LENGTH           10600020
PARMBLNK EQU   4                        BLANK CHARACTER                 10800020
PARMCHAR EQU   4                        OFFSET TO COMPARE CHARS         11000020
REG14OFF EQU   12                       OFFSET TO REG 14                11200020
REG15OFF EQU   16                       OFFSET TO REG 15                11400020
         SPACE                                                          11600020
SKIPFLAG EQU   1                        SKIP FUNCTION FLAG              11800020
         SPACE                                                          12000020
SETSCAN  EQU   X'01'                    ENTRY FROM SETSCAN MACRO        12200020
MBHFLAG  EQU   X'01'                    MULT BFR HEADER FLAG            12400020
NOMBH    EQU   X'01'                    'NO MBH' FLAG                   12500020
MLTRFLAG EQU   X'02'                    MULTIPLE-ROUTE FLAG             12600020
NOBLANKN EQU   X'02'                    'NO BLANK' FLAG                 12800020
         SPACE                                                          13000020
CLERZONE EQU   X'0F'                    MASK TO CLEAR BYTES-FOUND       13200020
*                                         COUNT IN SCB                  13400020
PREVSAVE EQU   4                        PREVIOUS SAVE AREA ADDR  S22025 13460022
NEXTSAVE EQU   8                        NEXT SAVE AREA ADDRESS   S22025 13520022
         EJECT                                                          13600020
         USING IEDQAVTD,RAVT                                            13800020
         USING IEDQLCB,RLCB                                      S22025 13900022
         USING IEDQSCB,RSCB                                             14000020
         USING IEDQPRF,RPREFIX                                          14200020
         USING IEDQAI,RBASE                                             14400020
         SPACE                                                          14600020
IEDQAI01 EQU   *                                                        14800020
IEDQAI   IEDHJN SKIPSCAN                ID AND DATE              S22025 15300022
         CLC   PRFSCAN(TWO),PRFSIZE     RUNOUT FROM A PREVIOUS MACRO    15800020
         BH    MINUS4                   YES, EXIT                       16000020
         SPACE                                                          16200020
         SR    RSCANOFF,RSCANOFF        CLEAR REG SEVEN          S22025 16600022
         SPACE                                                          17300020
         LH    RSCANOFF,PRFSCAN         GET PREFIX SCAN POINTER         17400020
         N     RSCANOFF,AVTCLRHI        CLEAR TOP HALF OF REGISTER      17600020
         SPACE                                                          17700020
         LR    R15,RSCANOFF             INITIALIZE FOR SCAN      S22025 18200022
         SPACE                                                          18600020
         TM    AVTEZERO(R1),NOBLANKN    ARE BLANKS BYPASSED             18800020
         BO    LOADAXAD                 NO, INITIALIZE FOR SCAN  S22025 19000022
         SPACE                                                          19200020
         LA    RBLANK2,AVTEBLNK         ASSUME EBCDIC BLANK             19300020
         CLI   PARMLEN(R1),FOUR        IS PARM LIST LENGTH=4    SA55417 19400022
         BE    LOADAXAD                YES-PROCEED              SA55417 19600022
         SPACE                                                          19800020
         IC    RBLANK2,PARMBLNK(,R1)    PICK UP BLANK FROM PARMLIST     20800020
         SPACE                                                          21000020
LOADAXAD EQU   *                                                        21200020
         LR    RUNIT,RPREFIX            SET FIRST UNIT ADDR AND  S22025 21300022
         LH    REOUAD,AVTKEYLE            KEYLE FOR SCAN SUB-RTN S22025 21400022
         SR    RPARLEN,RPARLEN          INITIALIZE FOR COUNT     S22025 21500022
         L     R14,SCBMBHEN-1           GET ADDR IN MBH FIELD    S22025 21600022
         CLC   AVTINOUT,0(R14)          DOES IT POINT TO END     S22025 21700022
         BNE   MULTBUFN                 NO, MBH ENTRY, BRANCH           21900020
         SPACE                                                          22200020
         TM    AVTEZERO(R1),SKIPFLAG    IS IT SCAN FUNCTION             22400020
         BO    SKIP                     NO, GO PROCESS SKIP             22600020
         SPACE                                                          22800020
INITSCAN EQU   *                                                        23000020
         MVI   AVTDOUBL,AVTEBLNK        CLEAR AVT WORK AREA             23200020
         MVC   AVTDOUBL+1(SEVEN),AVTDOUBL TO ALL BLANKS                 23400020
         SPACE                                                          23800020
SELSCAN  EQU   *                                                        24000020
         CLI   SCANLEN(R1),AVTEFF       IS IT VARIABLE LENGTH           24200020
         BE    VAR                      YES, GO PROCESS VARIABLE        24400020
         SPACE                                                          24600020
         B     FIX                      NO, GO PROCESS FIXED            24800020
         SPACE                                                          24804022
**************************************************************** S22025 24808022
* VARIABLE LENGTH SCAN - NEXT FIELD IN BUFFER DELIMITED BY     * S22025 24812022
*  BLANKS MOVED TO AVTDOUBL (MAX 8 BYTES)                      * S22025 24816022
**************************************************************** S22025 24820022
         SPACE                                                          24824022
MOVAR    EQU   *                                                 S22025 24828022
         IC    R0,AVTEZERO(,RSCAN)      PUT DATA BYTE            S22025 24832022
         STC   R0,AVTDOUBL(RPARLEN)       INTO AVT SAVE AREA     S22025 24836022
         LA    RPARLEN,INC1(,RPARLEN)   INCREMENT COUNT REGISTER S22025 24840022
         STC   RPARLEN,AVTPARM+1        STORE LNG OF CHARS FOUND S22025 24844022
         CLI   AVTPARM+1,MAX            IS AVT WORK AREA FULL    S22025 24848022
         BE    SCANEND                  YES, GO TO SCAN EXIT     S22025 24852022
         SPACE                                                          24856022
VAR      EQU   *                                                 S22025 24860022
         BAL   R14,LOOP                 GET ADDR OF 1ST/NXT UNIT S22025 24864022
         B     SCANMBHX                 OUT-OF-BUF, EXIT         S22025 24868022
         SPACE                                                          24872022
         EX    RBLANK2,CLIBLANK         IS CHAR A BLANK          S22025 24876022
         SPACE                                                          24880022
         BNE   MOVAR                    NO, SAVE IT              S22025 24884022
         SPACE                                                          24888022
         LTR   RPARLEN,RPARLEN          HAS FST NON-BLNK BEEN FOUND     24892022
         BZ    LOOP                     NO, GET NEXT CHAR        S22025 24896022
         SPACE                                                          24900022
         B     SCANEND1                 YES, THIS IS BLANK DELEMITER    24904022
         SPACE 2                                                        24908022
**************************************************************** S22025 24912022
* LOOP THRU BUFFER UNITS TO FIND ADDR OF SCAN POINTER OFFSET   * S22025 24916022
*  R8 HAS ADDR OF 1ST/NXT UNIT, RB HAS VALUE OF AVTKEYLE       * S22025 24920022
**************************************************************** S22025 24924022
         SPACE                                                          24928022
NXTUNIT  EQU   *                                                 S22025 24932022
         L     RUNIT,PRFTIC-IEDQPRF(RUNIT)                       S22025 24936022
         SR    R15,REOUAD               DECREMENT OFFSET         S22025 24940022
LOOP     EQU   *                                                 S22025 24944022
         CR    R15,REOUAD               IS OFFSET IN THIS UNIT   S22025 24948022
         BNL   NXTUNIT                  NO, GET NEXT UNIT        S22025 24952022
         SPACE                                                          24956022
         LA    RSCANOFF,INC1(,RSCANOFF) YES, INCR SCAN OFFSET    S22025 24960022
         LA    R15,INC1(R15)            INCREMENT REG BY 1       S22025 24964022
         LA    RSCAN,AVTUMALN-1(R15,RUNIT) GET ADDR OF OFFSET    S22025 24968022
         CH    RSCANOFF,PRFSIZE         OUT OF BUFFER            S22025 24972022
         BCR   HI,R14                   YES, RETURN AS ERROR     S22025 24976022
         SPACE                                                          24980022
         B     FOUR(R14)                NO, CONTINUE PROCESSING  S22025 24984022
         EJECT                                                          25000020
**************************************************************** S22025 25240022
* IF ENTRY IS FROM A DIRECT BRANCH FROM STARTMH TO CONTINUE A  * S22025 25280022
* SCAN FROM PREVIOUS BUFFER, RESET FIELDS AND REGISTERS AS ON  * S22025 25320022
* ORIGINAL ENTRY                                               * S22025 25360022
**************************************************************** S22025 25400022
         SPACE                                                          25410022
MULTBUFN EQU   *                                                 S22025 25420022
         IC    RPARLEN,SCBDESTL         PICK UP BYTES FOUND CT   S22025 25440022
         NI    SCBDESTL,CLERZONE        RESET FIELD TO ZERO      S22025 25480022
         SRA   RPARLEN,FOUR             SHIFT TO ALIGN COUNT     S22025 25520022
         LA    RSCAN,LCBCPA             SET TO MOVE FROM LCB     S22025 25560022
         TM    SCBMBHEN+2,MLTRFLAG      ENTRY FROM MULTIPLE ROUTE       25600020
         BO    MRMBHENT                 YES, BRANCH                     25800020
         SPACE                                                          26000020
         LR    RSCAN,R13                SAVE CONTENTS OF R13     S22025 26030022
         LA    R13,AVTSAVE2             LOAD ADDR OF MH REGISTER S22025 26060022
         LA    R14,AVTINOUT             GET ADDR OF DUMMY INEND/        26100020
         IC    R0,SCBMBHEN-1              OUTEND PARM LIST AND          26200020
         ST    R14,SCBMBHEN-1             SET IT INTO SCB               26300020
         STC   R0,SCBMBHEN-1                                            26400020
         EX    AVTEZERO,AVTEXS2A        MOVE SAVED REGS TO AVT          26600020
         SPACE                                                          26800020
         SR    R14,R14                  CLEAR REGISTER           S22025 27000022
         IC    R14,PARMLEN(,R1)         PICK UP LNG OF PARM LIST        27200020
         LA    R14,LBALR(R14,R1)        ADD PARM LIST ADDR + OFFSET     27400020
         ST    R14,REG14OFF(,R13)       SET AS RETURN ADDRESS           27600020
         LR    R13,RSCAN                RESTORE CONTENTS OF R13  S22025 27650022
         LA    RSCAN,SCBMBSSA           RESET TO MOVE FROM SCB   S22025 27700022
         B     MBHSELSC                 BRANCH TO CHECK ENTRY           27750022
         SPACE                                                          27800020
         SPACE                                                          29600020
MRMBHENT EQU   *                                                        29800020
         NI    SCBMBHEN+2,X'FF'-MLTRFLAG-MBHFLAG CLEAR FLAGS     S22025 30100022
MBHSELSC EQU   *                                                 S22025 30200022
         LTR   RPARLEN,RPARLEN          ANDY BYTES SAVED         S22025 30400022
         BZ    INITSCAN                 ZERO COUNT, INITIAL ENTRY       30800020
         SPACE                                                          31000020
         MVC   AVTDOUBL(MBSSALEN),0(RSCAN)                       S22025 31300022
         MVI   AVTDOUBL+7,AVTEBLNK     MAKE LAST BYTE A BLANK           31700020
         B     SELSCAN                  RESUME PROCESSING        S22025 32500022
         EJECT                                                          33400020
SKIP     EQU   *                                                        33600020
         LH    RPARLEN,SKIPLEN(,R1)     SET LENGTH PARAMETER            33800020
         N     RPARLEN,AVTCLRHI         CLEAR TOP HALF OF REGISTER      34000020
         BZ    ADDRRET                  ZERO, GO RETURN ADDRESS         34200020
         SPACE                                                          34400020
         TM    AVTEZERO(R1),NOBLANKN    ARE BLANKS BYPASSED             34600020
         BO    SKIPADD                  NO, ADD TO SKIP                 34800020
         SPACE                                                          35000020
SKIPLOOP EQU   *                                                        35200020
         BAL   R14,LOOP                 GET CHAR ADDRESS         S22025 35400022
         B     SKPEOBUF                 RUN OUT OF BUFFER, EXIT         35600020
         SPACE                                                          35800020
         EX    RBLANK2,CLIBLANK         IS IT BLANK                     36000020
         BE    LOOP                     YES, GET NEXT CHAR       S22025 36200022
         SPACE                                                          36400022
         BCT   RPARLEN,LOOP             NO, IS COUNT COMPLETE    S22025 36600022
         SPACE                                                          36800020
         B     UPSCAN                   COUNT ZERO, UPDATE PREFIX       37000020
*                                         SCAN POINTER & EXIT           37200020
         SPACE                                                          37400020
SKIPADD  EQU   *                                                        37600020
         LH    RWORK2,PRFSIZE           GET TOTAL DATA SIZE             37800020
         N     RWORK2,AVTCLRHI                                          38000020
         AR    RSCANOFF,RPARLEN         ADD SKIP LNG TO SCAN PTR        38200020
         CR    RSCANOFF,RWORK2          RUN OUT OF BUFFER               38400020
         BL    UPSCAN                   NO, UPDATE AND EXIT     SA59004 38600022
         SPACE                                                          38800020
SKPEOBUF EQU   *                                                        39000020
         LA    R15,AVTECD4              SET BAD RETURN CODE             39200020
         B     EXIT                     LINK TO LM TO EXIT              39400020
         EJECT                                                          39600020
FIX      EQU   *                                                        44600020
         BAL   R14,LOOP                 GET CHAR ADDRESS         S22025 44800022
         B     SCANMBHX                 RUN OUT OF BUFFER, EXIT         45000020
         SPACE                                                          45200020
         TM    AVTEZERO(R1),NOBLANKN    ARE BLANKS BYPASSED             45400020
         BO    MOFIX                    NO, DON'T TEST FOR BLANK        45600020
         SPACE                                                          45800020
         EX    RBLANK2,CLIBLANK         IS IT BLANK                     46000020
         BE    LOOP                     YES, GET NEXT CHAR       S22025 46200022
         SPACE                                                          46400020
MOFIX    EQU   *                                                        46600020
         IC    R0,AVTEZERO(,RSCAN)      NO, PUT IT INTO                 46800020
         STC   R0,AVTDOUBL(RPARLEN)       AVT SAVE AREA                 47000020
         LA    RPARLEN,INC1(,RPARLEN)   INCREMENT COUNT REGISTER        47200020
         EX    RPARLEN,CLIX             IS COUNT SATISFIED              47400020
         BNE   LOOP                     NO, GET NEXT CHAR        S22025 47600022
         SPACE                                                          47800020
*        B     SCANEND                  YES, FALL THRU TO SCAN END      48000020
         EJECT                                                          48200020
SCANEND  EQU   *                                                        48400020
         LA    RSCANOFF,INC1(,RSCANOFF) BUMP SCAN OFFSET                48600020
         SPACE                                                          48800020
SCANEND1 EQU   *                                                        49000020
         STC   RPARLEN,AVTPARM+1        RETURN LNG OF FIELD FOUND       49200020
         TM    PARMLEN(R1),COMP         IS A COMPARE REQUESTED          49400020
         BNO   NOCOMP                   NO, RETURN TO CALLER            49600020
         SPACE                                                          49800020
         L     RCOMP8,PARMCHAR(,R1)     YES, GET ADDR OF COMPARE        50000020
*                                         CHARACTERS                    50200020
         BCTR  RPARLEN,AVTEZERO         DECREMENT CT FOR EXECUTE S21903 50400022
         EX    RPARLEN,CLCX             COMPARE STRING FOUND WITH       50600020
*                                         STRING SOUGHT                 50800020
         BNE   ZERORTN                  NOT EQUAL, SET RETURN           51000020
         SPACE                                                          51200020
* EQUAL, TREAT AS IF NO COMPARE.                                        51400020
         SPACE                                                          51600020
NOCOMP   EQU   *                                                        51800020
         BCTR  RSCANOFF,AVTEZERO        POINT TO LAST BYTE OF FIELD     52000020
         TM    AVTEZERO(R1),SETSCAN     IS ENTRY FROM SETSCAN MACRO     52200020
         BO    TESTREG                  YES, GO TEST FOR REG RETURN     52400020
         SPACE                                                          52600020
         CLI   PARMREG(R1),AVTEZERO     IS RETURN IN REG REQUESTED      52800020
         BE    UPSCAN                   NO, GO UPDATE SCAN POINTER      53000020
         SPACE                                                          53200020
         LR    R15,RSCANOFF             YES, RETURN OFFSET IN R15       53400020
         B     EXIT                     RETURN TO CALLER                53600020
         SPACE                                                          53800020
TESTREG  EQU   *                                                        54000020
         CLI   PARMREG(R1),AVTEZERO     IS RETURN IN REG REQUESTED      54200020
         BNE   LINKAL                   YES, GO LINK TO GET ADDRESS     54400020
         SPACE                                                          54600020
UPSCAN   EQU   *                                                        54800020
         STH   RSCANOFF,PRFSCAN         NO, UPDATE SCAN POINTER FLD     55000020
         SPACE                                                          55200020
ZERORTN  EQU   *                                                        55400020
         SR    R15,R15                  SET ZERO RETURN IN REG 15       55600020
         SPACE                                                          55800020
EXIT     EQU   *                                                        56000020
         L     RBASE,AVTUI              GET RET INTERFACE ADDR   S22025 56200022
         B     FOUR(RBASE)              BRANCH TO RETURN ROUTINE S22025 56400022
         SPACE                                                          56600020
LINKAL   EQU   *                                                        56800020
         SPACE                                                          57600020
         CLI   PARMREG(R1),REG15OFF     IS RETURN REQ IN REG 15         57800020
         BNE   SETSAVE                  NO, GO RETURN IN SAVE AREA      58000020
         SPACE 1                                                        58050022
         B     GOODRTN                   SET R15 AND RETURN      S22025 58100022
         SPACE 1                                                        58150022
         SPACE                                                          58200020
ADDRRET  EQU   *                                                        58400020
         SPACE 1                                                        58420022
         BAL   R14,LOOP                 GET ADDR OF SCAN PTR     S22025 58440022
         SPACE 1                                                        58460022
         B     NEGFOUR                 OUT OF BUFFER-RETURN     SA54273 58480022
         SPACE 1                                                        58500022
         BCTR  RSCAN,AVTEZERO           SET TO ORIGNAL SCAN PTR  S22025 58520022
         SPACE 1                                                        58540022
GOODRTN  EQU   *                                                 S22025 58560022
         LR    R15,RSCAN                YES, RETURN ADDR IN REG 15      58600020
         B     EXIT                     RETURN TO MH                    58800020
         SPACE                                                          59000020
SETSAVE  EQU   *                                                        59200020
         L     R13,PREVSAVE(R13)        POINT TO PREV SAVE AREA  S22025 59300022
         SR    RWORK2,RWORK2            PICK UP OFFSET TO RETURN        59400020
         IC    RWORK2,PARMREG(,R1)        REGISTER IN SAVE AREA         59600020
         ST    RSCAN,AVTEZERO(RWORK2,R13) SET ADDR IN RETURN REG        59800020
         L     R13,NEXTSAVE(R13)        CURRENT SAVE AREA        S22025 59900022
         B     ZERORTN                  CLEAR R15 AND RETURN TO MH      60000020
         EJECT                                                          60200020
SCANMBHX EQU   *                                                        60400020
         TM    PRFSTAT1,PRFTSMSG       TIME SHARING MESSAGE      S22029 60600022
         BO    SCANEND1                 BRANCH ON YES                   60800020
         SPACE                                                          61000020
         CLI   PARMREG(R1),AVTEZERO     IS RTN REQ IN REG               61200020
         BE    TESTLAST                 NO, GO TEST IF LAST BUFFER      61400020
         SPACE                                                          61408020
         L     R15,SCBMBHEN-1           GET MBH ENTRY FIELD             61416020
         CLC   AVTINOUT,AVTEZERO(R15)   DOES IT POINT TO X'0100'        61424020
         BE    TESTANY                  YES, INITIAL ENTRY FROM         61432020
*                                         MH, BRANCH                    61440020
         SPACE                                                          61448020
         TM    SCBMBHEN+2,MLTRFLAG     ENTRY FROM MULTIPLE ROUTE        61460020
         BO    TESTLAST                YES, GO DO MBH PROCESSING        61520020
         SPACE                                                          61600020
TESTANY  EQU   *                                                        61610020
         LTR   RPARLEN,RPARLEN          ANY BYTES FOUND                 61620020
         BNZ   MINUS4                   YES, SPLIT FIELD, BYPASS        61640020
*                                         MBH PROCESSING                61660020
         TM    PARMLEN(R1),FOUR+NOMBH   MBH-COMPARE REQUESTED           61680020
         BNZ   MINUS4                   NO, BYPASS MBH PROCESSING       61700020
         SPACE                                                          61720020
         B     SAVECONT                 YES, GO SAVE COUNT              61740020
         SPACE                                                          61760020
TESTLAST EQU   *                                                        61780020
         TM    PRFSTAT1,PRFNLSTN        IS IT LAST BUFFER               61800020
         BNO   MINUS4                   YES, BYPASS MBH PROCESSING      62000020
         SPACE                                                          62200020
         MVC   SCBMBSSA(MBSSALEN),AVTDOUBL SAVE DATA IN SCB             62400020
         SPACE                                                          62460020
SAVECONT EQU   *                                                        62520020
         LR    RSCAN,R13                SAVE CONTENTS OF R13     S22025 62540022
         LA    R13,AVTSAVE2             LOAD ADDR OF MH REGS     S22025 62560022
         SLL   RPARLEN,FOUR             SHIFT TO ALIGN COUNT            62600020
         EX    RPARLEN,OIX              SAVE BYTES-FOUND COUNT          62800020
         SPACE                                                          63000020
         EX    AVTEZERO,AVTEXA2S        MOVE REGS FROM AVT TO SCB       63200020
         SPACE                                                          63400020
         STH   RSCANOFF,PRFSCAN         POINT SC PT BEYOND BFR END      63600020
         SPACE                                                          63800020
         LA    R1,ONE(,R1)              SET MBH-ENTRY BIT               64000020
         IC    R0,SCBMBHEN-1            SAVE HIGH-ORDER BYTE            64200020
         ST    R1,SCBMBHEN-1            SAVE PARAM LIST ADDR IN SCB     64400020
         STC   R0,SCBMBHEN-1            RESTORE HIGH-ORDER BYTE         64600020
         LR    R13,RSCAN                RESTORE CONTENTS OF R13  S22025 64700022
         SPACE                                                          64800020
MINUS4   EQU   *                                                        65000020
         STC   RPARLEN,AVTPARM+1        PASS COUNT FOUND TO USER        65200020
NEGFOUR  EQU   *                                                SA54273 65300022
         LA    R15,AVTECD4              SET ERROR                       65400020
         LNR   R15,R15                    RETURN CODE                   65600020
         B     EXIT                     RETURN                          65800020
         SPACE 3                                                        66000020
********* EXECUTED INSTRUCTION *********                                66200020
         SPACE                                                          66400020
CLIX     CLI   SCANLEN(R1),AVTEZERO     TEST IF COUNT SATISFIED         66600020
         SPACE                                                          66800020
CLCX     CLC   AVTEZERO(INC1,RCOMP8),AVTDOUBL COMPARE STRING FOUND      67000020
*                                         WITH STRING SOUGHT            67200020
         SPACE                                                          67400020
CLIBLANK CLI   AVTEZERO(RSCAN),AVTEZERO COMPARE FOR BLANK               67600020
         SPACE                                                          67800020
OIX      OI    SCBDESTL,AVTEZERO        SAVE  SCB BYTES-FOUND FLD       68000020
         EJECT                                                          68200020
********* DSECTS *********                                              68400020
         SPACE                                                          68600020
         TAVTD                                                          68800020
         EJECT                                                          69000020
         TLCBD                                                          69200020
         EJECT                                                          69400020
         TPRFD                                                          69600020
         TSCBD                                                          69800020
         END                                                            70000020
