AJ01     TITLE '''IEDQAJ'' - SKIP TO CHARACTER SET ROUTINE'             00100000
IEDQAJ   CSECT                                                          00200000
         SPACE 3                                                        00300000
*  CHANGE ACTIVITY AS FOLLOWS                                           00400000
******************** MICROFICHE FLAGS *********************** SUPT CODE 00420000
*A 508600,509200,556000-592000,615000,637000,763000,779000,841000S22025 00500000
*A 847000                                                       S22025  00500100
*C 540000,610000,630000,638000,642000,644000,658000-734000      S22025  00500200
*C 766000-768000,772000,776000,858000-860000                    S22025  00500300
*D 554000-602000,616000,652600-653200,658000,868000-870000      S22025  00500400
*D 882000                                                       S22025  00500500
*A675200-675800,676200                                          SA55932 00500600
*C676000                                                        SA55932 00500700
*C675000-676500                                                 SA59187 00500800
*C532000,772000,776000                                          SA48255 00500900
*A692000                                                        SA61803 00501000
         SPACE 3                                                        01000000
*********************************************************************** 01200020
*                                                                     * 01400020
*TITLE:  'IEDQAJ' - SKIP TO CHARACTER SET ROUTINE                     * 01600000
*                                                                     * 01620000
*  MODULE NAME = IEDQAJ                                               * 01640000
*                                                                     * 01660000
*  DESCRIPTIVE NAME = SKIP TO CHARACTER SET ROUTINE                   * 01680000
*                                                                     * 01700000
*  COPYRIGHT = 'NONE'                                                 * 01720000
*                                                                     * 01740000
*  STATUS:  CHANGE LEVEL 5                                            * 01760000
*                                                                     * 01800020
*FUNCTION -- ADVANCES THE SCAN POINTER TO THE END OF A SPECIFIED      * 02000020
*   CHARACTER STRING.                                                 * 02200020
*                                                                     * 02400020
*   THE SCAN POINTER OFFSET FROM THE PREFIX IS PASSED TO THE          * 02600020
*   ADDRESS FINDER ROUTINE TO GET ITS ADDRESS AND TO INITIALIZE THE   * 02800020
*   CURRENT-UNIT AND END-OF-UNIT REGISTERS.                           * 03000020
*                                                                     * 03200020
*   NORMAL ENTRY --                                                   * 03400020
*   THE ROUTINE LOOPS TO THE BUFFER STEP ROUTINE,  WHICH RETURNS      * 03600020
*   THE ADDRESS OF EACH SUBSEQUENT BYTE.  WHEN A NON-BLANK            * 03800020
*   CHARACTER IS FOUND,  IT IS INSERTED INTO THE AVT WORK AREA        * 04000020
*   (AVTDOUBL) AND A COUNTER OF DATA BYTES ACCESSED IS INCREMENTED    * 04200020
*   BY ONE.  THE CHARACTER FOUND IS COMPARED WITH THE FIRST           * 04400020
*   CHARACTER OF THE CHARACTER STRING PASSED.  IF THEY ARE EQUAL,     * 04600020
*   THE COUNTER IS COMPARED WITH THE LENGTH OF THE CHARACTER STRING   * 04800020
*   PASSED.  IF THE COUNT IS THE SAME,  THE CHARACTER STRING HAS      * 05000020
*   BEEN FOUND.  THE NORMAL EXIT IS TAKEN.                            * 05200020
*                                                                     * 05400020
*   IF THE COUNT IS NOT THE SAME,  THE ROUTINE LOOPS TO THE BUFFER    * 05600020
*   STEP ROUTINE TO GET THE NEXT DATA BYTE,  WHICH IS INSERTED INTO   * 05800020
*   THE AVT WORK AREA,  AND COMPARISON IS AGAIN MADE WITH THE         * 06000020
*   CHARACTER STRING PASSED.                                          * 06200020
*                                                                     * 06400020
*   IF THE CHARACTERS ACCESSED FROM THE BUFFER DO NOT MATCH THE       * 06600020
*   CHARACTER STRING PASSED,  THE CONTENTS OF THE AVT WORK AREA ARE   * 06800020
*   SUCCESSIVELY SHIFTED LEFT,  DROPPING ONE BYTE AT A TIME,  AND     * 07000020
*   COMPARED (TO A SUCCESSIVELY DIMINISHING LENGTH) TO THE            * 07200020
*   CHARACTER STRING.  THIS PROCEDURE CONTINUES UNTIL (1) AN EQUAL    * 07400020
*   COMPARE IS FOUND OR (2) THE CHARACTERS ACCESSED ARE EXHAUSTED.    * 07600020
*   AT THIS POINT THE ROUTINE RESUMES LOOPING TO THE BUFFER STEP      * 07800020
*   ROUTINE TO ACCESS THE NEXT DATA BYTE.                             * 08000020
*                                                                     * 08200020
*   NORMAL EXIT --                                                    * 08400020
*   THE ROUTINE RETURNS THE OFFSET TO THE LAST BYTE OF THE            * 08600020
*   CHARACTER STRING EITHER IN THE PREFIX SCAN POINTER (PRFSCAN)      * 08800020
*   OR IN A REGISTER SPECIFIED.  A RETURN CODE OF ZERO IS SET IN      * 09000020
*   REGISTER 15,  EXCEPT WHEN REGISTER 15 IS ITSELF SPECIFIED AS      * 09200020
*   THE PARAMETER RETURN REGISTER.  EXIT IS MADE TO THE RETURN        * 09400020
*   INTERFACE ROUTINE.                                                * 09600020
*                                                                     * 09800020
*   IF RETURN FROM THE BUFFER STEP ROUTINE INDICATES THAT THE END     * 10000020
*   OF THE BUFFER HAS BEEN PASSED,  THE ROUTINE TESTS IF A            * 10200020
*   PARAMETER RETURN REGISTER WAS SPECIFIED.  IF SO,  A RETURN CODE   * 10400020
*   OF X'04' IS SET IN REGISTER 15,  UNLESS REGISTER 15 IS ITSELF     * 10600020
*   THE PARAMETER RETURN REGISTER SPECIFIED,  IN WHICH CASE IT IS     * 10800020
*   SET TO ZERO.  EXIT IS MADE TO THE RETURN INTERFACE ROUTINE.       * 11000020
*                                                                     * 11200020
*   MULTIPLE BUFFER HEADER EXIT --                                    * 11400020
*   IF A PARAMETER RETURN REGISTER WAS NOT SPECIFIED,  THE DATA       * 11600020
*   ACCESSED FROM THE BUFFER IS MOVED FROM THE AVT WORK AREA TO THE   * 11800020
*   SCB SAVE AREA (SCBMBSSA).  THE PARAMETER LIST ADDRESS IS SAVED    * 12000020
*   IN THE SCB MULTIPLE BUFFER HEADER ENTRY FIELD (SCBMBHEN).  THE    * 12200020
*   USER'S REGISTERS,  SAVED IN THE AVT,  ARE MOVED TO THE SCB        * 12400020
*   REGISTER SAVE AREA (SCBRGSAV).  THE PREFIX SCAN POINTER           * 12600020
*   IS UPDATED TO POINT BEYOND THE END OF THE BUFFER.  A NEGATIVE     * 12800020
*   RETURN CODE IS SET IN REGISTER 15 AND EXIT IS MADE TO THE         * 13000020
*   RETURN INTERFACE ROUTINE.                                         * 13200020
*                                                                     * 13400020
*   MULTIPLE BUFFER HEADER ENTRY --                                   * 13600020
*   THE ROUTINE MAY BE ENTERED DIRECTLY FROM THE START MH ROUTINE     * 13800020
*   TO COMPLETE A SKIP INTERRUPTED BY A MULTIPLE BUFFER HEADER        * 14000020
*   SITUATION.  THE DATA ACCESSED FROM THE PREVIOUS BUFFER IS MOVED   * 14200020
*   BACK FROM THE SCB SAVE AREA TO THE AVT WORK AREA.  THE NUMBER     * 14400020
*   OF BYTES FOUND IS CALCULATED AND PROCESSING RESUMES AT THE        * 14600020
*   NORMAL ENTRY.                                                     * 14800020
*                                                                     * 15000020
*ENTRY POINTS --                                                      * 15200020
*       'IEDQAJ' TO ADVANCE THE SCAN POINTER TO THE END OF A          * 15400020
*   SPECIFIED FIELD.  CALLING SEQUENCE FROM USER INTERFACE IS:        * 15600020
*                                                                     * 15800020
*        L     R12,AVTMSGS-1            GET ADDR OF VCON TABLE        * 16000020
*        IC    R15,AVTEZERO(,R1)        GET INDEX TO ROUTINE ADDR     * 16200020
*        L     R12,AVTEZERO(R12,R15)    GET ROUTINE ADDRESS           * 16400020
*        BR    R12                      EXIT TO ROUTINE               * 16600020
*                                                                     * 16800020
*INPUT --                                                             * 17000020
*   REGISTER 0 - ENTRY CODE.  ITS VALUE IS X'00' ON INITIAL ENTRY     * 17200020
*   AND X'01' ON REENTRY FOR PROCESSING OF MULTIPLE BUFFER HEADERS.   * 17400020
*                                                                     * 17600020
*   REGISTER 1 - THE ADDRESS OF A PARAMETER LIST BUILT BY THE         * 17800020
*   CALLER (EITHER THE SETSCAN MACRO EXPANSION OR A HIGHER LEVEL MH   * 18000020
*   ROUTINE).  PARAMETER LIST FORMAT IS:                              * 18200020
*                                                                     * 18400020
*        *********************************                            * 18600020
*        *       * PARAM *  SET  *  REG  *                            * 18800020
*        * INDEX *  LIST *  FLAG * OFFST *                            * 19000020
*        *       * LNGTH *       *       *                            * 19200020
*        *********************************                            * 19400020
*        *       *                       *                            * 19600020
*        *       *  ADDR OF CHAR STRING  *                            * 19800020
*        *       *                       *                            * 20000020
*        *********************************                            * 20200020
*                                                                     * 20400020
*                                                                     * 20600020
*   REGISTER 3 - THE ADDRESS OF THE SCB.                              * 20800020
*                                                                     * 21000020
*   REGISTER 4 - THE ADDRESS OF THE LCB.                              * 21200020
*                                                                     * 21400020
*   REGISTER 6 - THE ADDRESS OF THE CURRENT BUFFER.                   * 21600020
*                                                                     * 21800020
*   REGISTER 9 - THE ADDRESS OF THE AVT.                              * 22000020
*                                                                     * 22200020
*   REGISTER 12 - THE ENTRY POINT ADDRESS AND BASE REGISTER FOR       * 22400020
*   THIS ROUTINE.                                                     * 22600020
*                                                                     * 22800020
*   REGISTER 13 - THE ADDRESS OF THE CALLING ROUTINE'S SAVE AREA.     * 23000020
*                                                                     * 23200020
*OUTPUT --                                                            * 23400020
*   REGISTER 15 - RETURN CODE.  ON SUCCESSFUL COMPLETION,  ITS        * 23600020
*   VALUE IS X'00' OR,  IF REGISTER 15 IS SPECIFIED AS THE            * 23800020
*   PARAMETER RETURN REGISTER,  THE OFFSET TO THE LAST BYTE OF THE    * 24000020
*   CHARACTER STRING.  IF THE SKIP FAILS TO COMPLETE AND A            * 24200020
*   PARAMETER RETURN REGISTER IS SPECIFIED,  ITS VALUE IS X'04' OR,   * 24400020
*   IF REGISTER 15 IS ITSELF SPECIFIED AS THE PARAMETER RETURN        * 24600020
*   REGISTER,  X'00'.  IF THE SKIP FAILS TO COMPLETE AND NO           * 24800020
*   PARAMETER RETURN REGISTER WAS SPECIFIED (MULTIPLE BUFFER HEADER   * 25000020
*   SITUATION),  ITS VALUE IS NEGATIVE.                               * 25200020
*                                                                     * 25400020
*   BUFFER PREFIX SCAN POINTER (PRFSCAN) - ON SUCCESSFUL COMPLETION   * 25600020
*   WITH NO PARAMETER RETURN REGISTER SPECIFIED,  THE OFFSET IN THE   * 25800020
*   BUFFER TO THE LAST BYTE OF THE CHARACTER STRING.  ON A MULTIPLE   * 26000020
*   BUFFER HEADER EXIT,  THE OFFSET TO A POINT ONE BYTE BEYOND THE    * 26200020
*   END OF DATA IN THE BUFFER.                                        * 26400020
*                                                                     * 26600020
*   SCB SAVE AREA (SCBMBSSA) - ON A MULTIPLE BUFFER HEADER EXIT,      * 26800020
*   THE DATA BYTES FROM THIS BUFFER ON WHICH A SUCCESSFUL COMPARE     * 27000020
*   WAS MADE,  PADDED WITH BLANKS (IF NECESSARY TO FILL SCBMBSSA)     * 27200020
*   AT THE HIGH-ORDER END.                                            * 27400020
*                                                                     * 27600020
*   SCB MULTIPLE BUFFER HEADER ENTRY FIELD (SCBMBHEN) - ON A          * 27800020
*   MULTIPLE BUFFER HEADER EXIT,  THE ADDRESS OF THE PARAMETER LIST   * 28000020
*                                                                     * 28200020
*   SCB REGISTER SAVE AREA (SCBRGSAV) (IF DEFINED) - ON A MULTIPLE    * 28400020
*   BUFFER HEADER EXIT,  THE USER'S REGISTERS.                        * 28600020
*                                                                     * 28800020
*EXTERNAL REFERENCES --                                               * 29000020
*    ' IEDQAX - SCAN BUFFER ROUTINE TO FIND CHARS AND PUT IN AVTDOUBL * 29800022
*                                                                     * 30600020
*   AVT - ADDRESS VECTOR TABLE.                                       * 30800020
*                                                                     * 31000020
*   SCB - STATION CONTROL BLOCK FOR CURRENT STATION.                  * 31200020
*                                                                     * 31400020
*   BUFFER CURRENTLY BEING PROCESSED.                                 * 31600020
*                                                                     * 31800020
*EXITS, NORMAL -- THE CHARACTER STRING IS FOUND IN THE BUFFER.  NO    * 32000020
*   PARAMETER RETURN REGISTER IS SPECIFIED.  THE OFFSET IN THE        * 32200020
*   BUFFER TO THE LAST BYTE OF THE CHARACTER STRING IS STORED IN      * 32400020
*   THE BUFFER PREFIX SCAN POINTER (PRFSCAN).  REGISTER 15 CONTAINS   * 32600020
*   A RETURN CODE OF X'00'.                                           * 32800020
*                                                                     * 33000020
*   THE CHARACTER STRING IS FOUND IN THE BUFFER.  A PARAMETER         * 33200020
*   RETURN REGISTER IS SPECIFIED.  THE OFFSET IN THE BUFFER TO THE    * 33400020
*   LAST BYTE OF THE CHARACTER STRING IS RETURNED IN THE REGISTER     * 33600020
*   SPECIFIED.  REGISTER 15 CONTAINS A RETURN CODE OF X'00'.          * 33800020
*                                                                     * 34000020
*   THE CHARACTER STRING IS FOUND IN THE BUFFER.  REGISTER 15 IS      * 34200020
*   SPECIFIED AS THE PARAMETER RETURN REGISTER.  THE OFFSET IN THE    * 34400022
*   BUFFER TO THE LAST BYTE OF THE CHARACTER STRING IS RETURNED IN    * 34600022
*   REGISTER 15.                                                      * 34800022
*                                                                     * 35000020
*EXITS,  ERROR -- THE CHARACTER STRING IS NOT FOUND IN THE BUFFER.    * 35200020
*   NO PARAMETER RETURN REGISTER IS SPECIFIED.  THE SCB SAVE AREA     * 35400020
*   (SCBMBSSA) CONTAINS EITHER BLANKS OR DATA BYTES ACCESSED FROM     * 35600020
*   THE BUFFER THAT MATCH PART OF THE LENGTH OF THE CHARACTER         * 35800020
*   STRING PASSED.  THE SCB MULTIPLE BUFFER HEADER ENTRY FIELD        * 36000020
*   (SCBMBHEN) CONTAINS THE ADDRESS OF THE PARAMETER LIST.  THE SCB   * 36200020
*   REGISTER SAVE AREA (SCBRGSAV),  IF DEFINED,  CONTAINS THE         * 36400020
*   CALLER'S REGISTERS.  THE PREFIX SCAN POINTER (PRFSCAN) POINTS     * 36600020
*   ONE BYTE BEYOND THE END OF DATA IN THE BUFFER.  REGISTER 15       * 36800020
*   CONTAINS A NEGATIVE RETURN CODE.                                  * 37000020
*                                                                     * 37200020
*   THE CHARACTER STRING IS NOT FOUND IN THE BUFFER.  A PARAMETER     * 37400020
*   RETURN REGISTER IS SPECIFIED.  REGISTER 15 CONTAINS A RETURN      * 37600020
*   CODE OF X'04'.                                                    * 37800020
*                                                                     * 38000020
*   THE CHARACTER STRING IS NOT FOUND IN THE BUFFER.  REGISTER 15     * 38200020
*   IS SPECIFIED AS THE PARAMETER RETURN REGISTER.  REGISTER 15       * 38400020
*   CONTAINS A RETURN CODE OF X'00'.                                  * 38600020
*                                                                     * 38800020
*TABLES/WORK AREAS -- N/A.                                            * 39000020
*                                                                     * 39200020
*ATTRIBUTES -- SERIALLY REUSABLE, REFRESHABLE, ENABLED, RESIDENT,     * 39400020
*   PROBLEM PROGRAM MODE.                                               39600020
*                                                                     * 39800020
*NOTES -- THE OPERATION OF THIS MODULE DOES NOT DEPEND UPON AN        * 40000020
*   INTERNAL REPRESENTATION OF THE EXTERNAL CHARACTER SET.            * 40200020
*                                                                     * 40400020
*********************************************************************** 40600020
         EJECT                                                          40800020
********* REGISTER EQUATES *********                                    41000020
         SPACE                                                          41200020
R0       EQU   0                        WORK REGISTER                   41400020
         SPACE                                                          41600020
R1       EQU   1                        PARAMETER LIST REGISTER         41800020
         SPACE                                                          42000020
RWORK2   EQU   2                        WORK REGISTER                   42200020
RBLANK2  EQU   2                        BLANK COMPARE REGISTER          42400020
         SPACE                                                          42600020
RSCB     EQU   3                        SCB ADDRESS                     42800020
         SPACE                                                          43000020
RUNIT    EQU   4                         ADDR OF CURRENT UNIT           43200020
        SPACE                                                           43400020
RSCAN    EQU   5                        ADDR OF SCAN POINTER            43600020
         SPACE                                                          43800020
RPREFIX  EQU   6                        ADDR OF BUFFER                  44000020
         SPACE                                                          44200020
RSCANOFF EQU   7                        OFFSET TO SCAN POINTER          44400020
         SPACE                                                          44600020
RCHAR8   EQU   8                        CHARACTER SET ADDRESS           44800020
         SPACE                                                          45000020
RAVT     EQU   9                        ADDRESS OF AVT                  45200020
         SPACE                                                          45400020
RCOMP     EQU  10                       COMPARE REGISTER                45600020
         SPACE                                                          45800020
REOUAD   EQU   11                       ADDR OF END OF CURRENT UNIT     46000020
         SPACE                                                          46200020
RBASE    EQU   12                       BASE REGISTER                   46400020
         SPACE                                                          46600020
R13      EQU   13                       ADDR OF SAVE AREA               46800020
R14      EQU   14                       RETURN REGISTER                 47000020
R15      EQU   15                       RETURN CODE REGISTER            47200020
         SPACE                                                          47400020
********* OTHER EQUATES *********                                       47600020
         SPACE                                                          47800020
ONE      EQU   1                        MOVE LENGTH OF ONE              48000020
TWO      EQU   2                        LENGTH OF A HALFWORD            48200020
FOUR     EQU   4                        LENGTH OF A FULLWORD            48400020
SEVEN    EQU   7                        MOVE LENGTH OF SEVEN            48600020
TWENTY4  EQU   24                       SHIFT LENGTH FOR COUNT   S22025 48700022
         SPACE                                                          48800020
PARMLEN  EQU   1                        PARAMETER LIST LENGTH           49000020
SETFLAG  EQU   2                        OFFSET TO SET FLAG              49200020
REGOFF   EQU   3                        OFFSET TO REGISTER OFFSET       49400020
PARMBLNK EQU   4                        BLANK CHARACTER                 49600020
LBALR    EQU   6                        LNG OF LOAD + BALR              49800020
         SPACE                                                          50000020
REG14OFF EQU   12                       OFFSET TO REG 14                50200020
REG15OFF EQU   16                       OFFSET TO REG 15 IN SAVEAREA    50400020
         SPACE                                                          50600020
SETSCAN  EQU   X'01'                    SETSCAN ENTRY FLAG              50800020
PREVSAVE EQU   4                        PREVIOUS SAVE AREA ADDR  S22025 50860022
NEXTSAVE EQU   8                        NEXT SAVE AREA ADDRESS   S22025 50920022
NOBLANKN EQU   X'02'                    'NO BLANK' FLAG                 51000020
         SPACE                                                          51200020
CLERZONE EQU   X'0F'                    MASK TO CLEAR BYTES-FOUND       51400020
         EJECT                                                          51600020
         USING IEDQPRF,RPREFIX                                          51800020
         USING IEDQAVTD,RAVT                                            52000020
         USING IEDQSCB,RSCB                                             52200020
         USING IEDQLCB,RUNIT                                     S22025 52300022
         USING IEDQAJ,RBASE                                             52400020
         SPACE                                                          52600020
IEDQAJ01 EQU   *                                                        52800020
IEDQAJ   IEDHJN  IDPASS                                                 53100022
         LR    RCHAR8,R1                SAVE PARM ADDRESS        S22025 53400022
         CLC   PRFSCAN,PRFSIZE          RUNOUT FROM PREVIOUS MACRO      53800020
         BNH   MULTBUFN                 NO, ENTER SCAN ROUTINE   S22025 54000022
         SPACE                                                          54200020
         CLI   SETFLAG(R1),AVTEZERO     IS RETURN IN REG REQUESTED      54400020
         BNE   MINUS4                   YES, RETURN CODE = -4           54600020
         SPACE                                                          54800020
         B     INITMBH                  NO, GO SELECT RETURN            55000020
         SPACE                                                          55200020
         SPACE                                                          55600022
*                                                                     * 56000022
* IF SCBMBHEN DOES NOT POINT TO DUMMY END (X'0100'), THIS IS   * S22025 56400022
* A CONTINUATION OF A CHARACTER SCAN BEGUN IN THE PREVIOUS     * S22025 56800022
* BUFFER.  RESET FIELDS AND REGISTERS AS ON ORIGINAL ENTRY     * S22025 57200022
*                                                              * S22025 57600022
         SPACE                                                          58000022
MULTBUFN EQU   *                                                 S22025 58400022
         SR    R0,R0                    CLEAR FOR INSERT         S22025 58800022
         L     R1,FOUR(,R1)             LOAD CHAR STRING ADDR    S22025 59200022
         SPACE                                                          60400020
         L     R14,SCBMBHEN-1           GET POINTER FROM MBH FIELD      60600020
         CLC   AVTINOUT,AVTEZERO(R14)   DOES IT POINT TO X'0100'        60800020
         BE    LOOP                     YES, ENTER MAIN LOOP     S22025 61000022
*                                       NO, IT IS MBH ENTRY,            61200020
         LR    RWORK2,R13               SAVE CONTENTS OF R13     S22025 61400022
         LA    R13,AVTSAVE2             LOAD MH REGS ADDRESS     S22025 61600022
         LA    R14,AVTINOUT             GET ADDR OF DUMMY INEND-        61800020
         IC    R0,SCBMBHEN-1              OUTEND PARM LIST AND          62000020
         ST    R14,SCBMBHEN-1             SET IT INTO SCB               62200020
         STC   R0,SCBMBHEN-1                                            62400020
         EX    AVTEZERO,AVTEXS2A        MOVE SAVED REGS TO AVT          62600020
         SPACE                                                          62800020
         SR    R14,R14                  INITIALIZE REGISTER      S22025 63000022
         IC    R14,PARMLEN(,RCHAR8)     PICK UP PARM LIST LNG    S22025 63200022
         LA    R14,LBALR(R14,RCHAR8)    ADD TO RETURN ADDRESS    S22025 63400022
         ST    R14,REG14OFF(,R13)       SET AS RETURN ADDRESS           63600020
         LR    R13,RWORK2               RESTORE CONTENTS OF R13  S22025 63660022
         SR    RWORK2,RWORK2            INITIALIZE REGISTER      S22025 63720022
         IC    RWORK2,SCBDESTL          PICK UP PREV BYTES FOUND S22025 63800022
         SRA   RWORK2,FOUR              SHIFT TO ALIGN COUNT     S22025 64100022
         SR    RSCAN,RSCAN              INITIALIZE REGISTER      S22025 64200022
         IC    RSCAN,0(,R1)             GET CHAR COUNT           S22025 64300022
         SR    RSCAN,RWORK2             SUBT NO BUTES FOUND      S22025 64400022
         LA    R1,ONE(RWORK2,R1)        BUMP TO NEXT CHAR        S22025 64500022
         LR    R0,RSCAN                 LOAD REMAINING COUNT     S22025 64600022
         SLL   R0,TWENTY4               SHIFT FOR SCAN ROUTINE   S22025 64700022
         EJECT                                                          65400020
LOOP     EQU   *                                                        65600020
         SPACE                                                          65700022
*                                                              * S22025 65800022
* INITIALIZE PARAMETERS FOR BUFFER SCAN SUBROUTINE             * S22025 65900022
* R0 - HIGH BYTE LENGHT OF CHAR STRING / LOW TWO BYTES OFFSET *  S22025 66000022
* R1 - ADDRESS OF CHARACTER STRING                             * S22025 66100022
* R2 - BLANK CHARACTER OR NEGATIVE                            *  S22025 66200022
*                                                              * S22025 66300022
         SPACE                                                          66400022
         SR    RBLANK2,RBLANK2          INITILIAZE REGISTER      S22025 66500022
         IC    RBLANK2,PARMBLNK(,RCHAR8) INSERT BLANK CHARACTER  S22025 66600022
         SPACE                                                          66700022
         TM    AVTEZERO(RCHAR8),NOBLANKN ARE BLANKS BYPASSED     S22025 66800022
         BNO   LINKSCAN                 NO, BRANCH TO LINK SCAN  S22025 66900022
         SPACE                                                          67000022
         LNR   RBLANK2,RBASE            YES, INSURE R2 NEG       S22025 67100022
         SPACE                                                          67200022
LINKSCAN EQU   *                                                 S22025 67300022
         SR    RSCANOFF,RSCANOFF        INITIALIZE REGISTER      S22025 67400022
         LH    RSCANOFF,TWENTY4(,RPREFIX)  LOAD SCAN PTR        SA59187 67500022
         ALR   R0,RSCANOFF              ADD OFFSET TO R0         S22025 67700022
         L     R15,AVTAX                LOAD SCAN ROUTINE ADDR   S22025 67800022
         BALR  R14,R15                  LINK TO SCAN ROUTINE     S22025 67900022
         SPACE                                                          68000022
*                                                              * S22025 68100022
* RETURN FROM AX - BUFFER SCAN                                 * S22025 68200022
* R15 - NUMBER OF CHARACTERS FOUND                             * S22025 68300022
* R0 - SCAN POINTER OFFSET TO LAST CHARACTER FOUND             * S22025 68400022
* R1 - CORE ADDRESS OF LAST CHARACTER FOUND                    * S22025 68500022
* AVTDOUBL - ACTUAL CHARS FOUND EXCLUDING BLANKS               * S22025 68600022
*                                                              * S22025 68700022
         SPACE                                                          68800022
         LR    RSCAN,R1                 SET ADDRESS OF SCAN PTR  S22025 68900022
         LR    R1,RCHAR8                RESTORE PARAMETER ADDR   S22025 69000022
         LR    RSCANOFF,R0              SET SCAN PTR OFFSET      S22025 69100022
         L     RCHAR8,FOUR(,R1)         GET ADDR OF CHAR STRING  S22025 69200022
         SR    R0,R0                    CLEAR FOR CHAR FOUND CT SA61803 69210000
         IC    R0,SCBDESTL              PICK UP NO OF PREV FOUND S22025 69220022
         SRA   R0,FOUR                  ALIGN FOR ADDING         S22025 69240022
         AR    R15,R0                   ADD TO COUNT JUST FOUND  S22025 69260022
         NI    SCBDESTL,CLERZONE        RESET FIELD TO ZERO      S22025 69280022
         SPACE                                                          69300022
         EX    R15,CLIX                 ENTIRE STRING FOUND      S22025 69400022
         BE    GOODRTN                  YES, SET RETURN CODE     S22025 69500022
         SPACE                                                          69600022
*                                                              * S22025 69700022
* PARTIAL STRING FOUND - SET SCB FOR RE-ENTRY ON NEXT BUFFER   * S22025 69800022
*                                                              * S22025 69900022
         SPACE                                                          70000022
         CLI   SETFLAG(R1),AVTEZERO     IS RETURN IN REG REQUESTED      73600020
         BNE   MBHPROC                  NO, PROCEED                     73800020
*                                       YES, THIS IS AN ERROR           74000020
INITMBH  EQU   *                                                        74200020
         CLI   REGOFF(R1),REG15OFF      IS RETURN REG 15                74400020
         BE    ZERORTN                  YES, SET IT TO ZERO             74600020
         SPACE                                                          74800020
         LA    R15,AVTECD4              NO, SET ERROR RTN CODE          75000020
         B     RETURN                     AND EXIT                      75200020
         SPACE                                                          75400020
MBHPROC  EQU   *                                                        75600020
         TM    PRFSTAT1,PRFNLSTN        IS IT LAST BUFFER               75800020
         BNO   BADRTN                   YES, BYPASS MBH PROCESSING      76000020
         SPACE                                                          76200020
         LR    RWORK2,R13               SAVE CONTENTS OF R13     S22025 76300022
         LA    R13,AVTSAVE2             LOAD MH REGS ADDRESS     S22025 76400022
         SLL   R15,FOUR                 ALIGN COUNT TO SAVE      S22025 76500022
         EX    R15,OIX                  SET CORRECT BITS         S22025 76700022
         LA    R1,ONE(,R1)              SET MBH-ENTRY BIT               77000020
         IC    R0,SCBSNDCT              SAVE HIGH ORDER BYTE     A48255 77200022
         ST    R1,SCBMBHEN-1            SAVE PARAM LIST ADDR IN SCB     77400020
         STC   R0,SCBSNDCT              RESTORE HIGH ORDER BYTE  A48255 77600022
         EX    AVTEZERO,AVTEXA2S        MOVE REGS FROM AVT TO SCB       77800020
         LR    R13,RWORK2               RESTORE CONTENTS OF R13  S22025 77900022
         SPACE                                                          78000020
BADRTN   EQU   *                                                        78200020
         LA    RSCANOFF,ONE(RSCANOFF)   BUMP FOR OUT-OF-BFR             78300022
         STH   RSCANOFF,PRFSCAN         STORE OFFSET IN PFX SCAN PT     78400020
         SPACE                                                          78600020
MINUS4   EQU   *                                                        78800020
         LA    R15,AVTECD4              SET MULT BUFFER HEADER          79000020
         LNR   R15,R15                    RETURN CODE                   79200020
         B     RETURN                   RETURN TO CALLER                79400020
         EJECT                                                          79600020
GOODRTN  EQU   *                                                        79800020
         CLI   SETFLAG(R1),AVTEZERO     IS RETURN IN REG REQUESTED      80000020
         BE    REGRTN                   YES, GO PROCESS                 80200020
         SPACE                                                          80400020
         STH   RSCANOFF,PRFSCAN         STORE OFFSET IN PFX SCAN PT     80600020
         B     ZERORTN                  GO SET ZERO RETURN CODE         80800022
         SPACE                                                          81000020
REGRTN   EQU   *                                                        81200020
         TM    AVTEZERO(R1),SETSCAN     IS ENTRY FROM SETSCAN MACRO     81400020
         BO    TESTREG                  YES, GO SELECT WHICH REG        81600020
         SPACE                                                          81800020
         LR    R15,RSCANOFF             SET OFFSET IN REG 15            82000020
         B     RETURN                   RETURN TO CALLER                82200020
         SPACE                                                          82400020
TESTREG  EQU   *                                                        82600020
         CLI   REGOFF(R1),REG15OFF      IS RETURN REQ IN REG 15         82800020
         BNE   SETSAVE                  NO, GO SET ADDR IN SAVEAREA     83000020
         SPACE                                                          83200020
         LR    R15,RSCAN                YES, PASS ADDRESS IN REG 15     83400020
         B     RETURN                   RETURN TO MH                    83600020
         SPACE                                                          83800020
SETSAVE  EQU   *                                                        84000020
         L     R13,PREVSAVE(R13)        POINT TO PREV SAVE AREA  S22025 84100022
         SR    RWORK2,RWORK2            CLEAR FOR INSERT                84200020
         IC    RWORK2,REGOFF(,R1)       INSERT REGISTER OFFSET          84400020
         ST    RSCAN,AVTEZERO(RWORK2,R13) STORE ADDR IN SAVE AREA       84600020
         L     R13,NEXTSAVE(R13)        CURRENT SAVE AREA        S22025 84700022
         SPACE                                                          84800020
ZERORTN  EQU   *                                                        85000020
         SR    R15,R15                  SET GOOD RETURN CODE            85200020
         SPACE                                                          85400020
RETURN   EQU   *                                                        85600020
         L     RBASE,AVTUI              GET RET INTERFACE ADDR   S22025 85800022
         B     FOUR(RBASE)              BRANCH TO RETURN ROUTINE S22025 86000022
         SPACE 3                                                        86200020
********* EXECUTED INSTRUCTIONS *********                               86400020
         SPACE                                                          86600020
         SPACE                                                          87200020
CLIX     CLI   AVTEZERO(RCHAR8),AVTEZERO COMPARE COUNT OF MATCHING      87400020
*                                         CHARS WITH COUNT OF           87600020
*                                         PASSED CHARS                  87800020
         SPACE                                                          88000020
         SPACE                                                          88400020
OIX      OI    SCBDESTL,AVTEZERO        SAVE SCB BYTES-FOUND COUNT      88600020
         EJECT                                                          88800020
********* DSECTS *********                                              89000020
         SPACE                                                          89200020
         TAVTD                                                          89400020
         TPRFD                                                          89600020
         TLCBD                                                          89700022
         TSCBD                                                          89800020
         PRINT GEN                                                      90000020
         END                                                            90200020
