AT01     TITLE '''IEDQAT'' -- ERROR MESSAGE ROUTINE'                    00400020
IEDQAT   CSECT                                                          00800020
*C238000                                                         A42411 00900000
*A312000,323600                                                  A42411 01000000
*D724000-752000                                                  A42411 01100000
         SPACE                                                          01200020
*********************************************************************** 01202020
*STATUS -- CHANGE LEVEL 0                                             * 01204020
*                                                                     * 01206020
*FUNCTION -- BUILDS AN ERROR MESSAGE IN THE BUFFER AND POSTS THE      * 01208020
*   BUFFER TO THE DESTINATION.                                        * 01210020
*                                                                     * 01212020
*   ON ENTRY,  THE ROUTINE DETERMINES IF THIS MESSAGE ALREADY CON-    * 01214020
*   TAINS AN ERROR MESSAGE.  IF SO,  THE FUNCTION IS NOT PERFORMED.   * 01216020
*   EXIT IS MADE BY POSTING THE ERB    BACK TO BUFFER DISPOSITION.    * 01218020
*                                                                     * 01220020
*   THE LENGTH OF THE ERROR MESSAGE IS ACCESSED FROM THE PARAMETER    * 01222020
*   LIST OR,  IF THAT BYTE IS ZERO,  FROM THE FIRST BYTE OF THE       * 01224020
*   ERROR MESSAGE ITSELF.  IN THE LATTER CASE,  THE LENGTH IS         * 01226020
*   STORED IN THE PARAMETER LIST AND THE ADDRESS IN THE PARAMETER     * 01228020
*   LIST IS INCREMENTED BY ONE.                                       * 01230020
*                                                                     * 01232020
*   THE ROUTINE DETERMINES IF THE ERROR MESSAGE WILL FIT BETWEEN      * 01234020
*   THE SCAN POINTER (END OF HEADER) AND THE END OF THE BUFFER.       * 01236020
*   IF IT WILL NOT,  THE ROUTINE DETERMINES IF IT WILL FIT IN THAT    * 01238020
*   SPACE PLUS ONE ADDITIONAL UNIT.  IF IT WILL NOT,  THE ERROR       * 01240020
*   MESSAGE IS TRUNCATED TO FIT.                                      * 01242020
*                                                                     * 01244020
*   AN EMPTY UNIT (IF NEEDED) IS THEN ACCESSED BY POSTING THE ERB     * 01246020
*   TO THE BUFFER REQUEST QCB.  ON RETURN THE NEW UNIT IS LINKED      * 01248020
*   INTO THE BUFFER.                                                  * 01250020
*                                                                     * 01252020
*   AFTER THE NEW UNIT IS LINKED IN,  OR IF NO NEW UNIT IS NEEDED,    * 01254020
*   A LINK IS MADE TO THE INSERT DATA ROUTINE (IEDQAF) TO INSERT      * 01256020
*   THE ERROR MESSAGE INTO THE BUFFER.  IF THE USER HAS SPECIFIED     * 01258020
*   A USER-WRITTEN ROUTINE,  A LINK IS MADE TO IT.  EXIT IS THEN      * 01260020
*   MADE BY POSTING THE BUFFER TO THE DESTINATION.                    * 01262020
*                                                                     * 01264020
*   NOTE: THE DESTINATION IS DETERMINED BY THE REDIRECT SUBTASK,      * 01266020
*   WHICH IS DISPATCHED FROM BUFFER DISPOSITION AND ENTERS THE        * 01268020
*   ERROR MESSAGE VIA A BRANCH AFTER A VALID DESTINATION IS FOUND.    * 01270020
*                                                                     * 01272020
*ENTRY POINTS,  ERROR MESSAGE ROUTINE --                              * 01274020
*       'IEDQAT01' TO BUILD AN ERROR MESSAGE AND POST IT TO THE       * 01276020
*   DESTINATION.  THE ROUTINE IS ENTERED BY A BRANCH FROM THE         * 01278020
*   REDIRECT SUBTASK.                                                 * 01280020
*       'INSERT' TO PERFORM THE LINK TO THE INSERT DATA ROUTINE       * 01282020
*   (IEDQAF).  ENTRY IS FROM THE ERROR MESSAGE SUBTASK.               * 01284020
*                                                                     * 01286020
*ENTRY POINTS,  ERROR MESSAGE SUBTASK --                              * 01288020
*       'STCBAT' + 2 WHEN AN EXTRA UNIT IS RETURNED VIA A POST OF     * 01290020
*   THE ERB TO AN ERROR MESSAGE QCB BUILT IN THE BUFFER.              * 01292020
*                                                                     * 01294020
*INPUT,  ERROR MESSAGE ROUTINE --                                     * 01296020
*   REGISTER 3 -  SCB ADDRESS                                         * 01298020
*                                                                     * 01300020
*   REGISTER 4 - LCB ADDRESS                                          * 01302020
*                                                                     * 01304020
*   REGISTER 6 - BUFFER ADDRESS                                       * 01306020
*                                                                     * 01308020
*   REGISTER 8 - ADDRESS OF ERROR MESSAGE PARAMETER LIST.             * 01310020
*   PARAMETER LIST FORMAT IS:                                         * 01312020
*                                                                     * 01314020
*        *********************************                            * 01316020
*        * INDEX * PARAM * INDEX * INDEX *                            * 01318020
*        *  TO   * LIST  *  TO   *  TO   *                            * 01320020
*        *   AT  * LNGTH *   AF  *   AO  *                            * 01322020
*        *********************************                            * 01324020
*        *       *                       *                            * 01326020
*        *       *  ADDRESS OF MESSAGE   *                            * 01328020
*        *       *                       *                            * 01330020
*        *********************************                            * 01332020
*        *          ADDRESS OF           *                            * 01334020
*        *       USER EXIT ROUTINE       *                            * 01336020
*        *           (OPTIONAL)          *                            * 01338020
*        *********************************                            * 01340020
*                                                                     * 01342020
*   REGISTER 11 - ADDRESS OF THE DISPATCHER                           * 01344020
*                                                                     * 01346020
*   REGISTER 12 - ENTRY POINT ADDRESS AND BASE REGISTER FOR THIS      * 01348020
*   ROUTINE.                                                          * 01350020
*                                                                     * 01352020
*   REGISTER 13 - ADDRESS OF SAVE AREA AND BASE FOR AVT               * 01354020
*   ADDRESSABILITY.                                                   * 01356020
*                                                                     * 01358020
*INPUT,  ERROR MESSAGE SUBTASK --                                     * 01360020
*   REGISTER 7 - ADDRESS OF THE ERROR MESSAGE QCB                     * 01362020
*                                                                     * 01364020
*   REGISTER 8 - ADDRESS OF THE ERROR MESSAGE PARAMETER LIST          * 01366020
*                                                                     * 01368020
*   REGISTER 11 - ADDRESS OF THE DISPATCHER                           * 01370020
*                                                                     * 01372020
*   REGISTER 15 - ENTRY POINT ADDRESS AND BASE REGISTER FOR THE       * 01374020
*   SUBTASK.                                                          * 01376020
*                                                                     * 01378020
*   LCB ERB CHAIN FIELD (LCBERBCH) - ADDRESS OF THE NEW UNIT          * 01380020
*                                                                     * 01382020
*OUTPUT,  ERROR MESSAGE SUBTASK --                                    * 01384020
*   THE ERROR MESSAGE SUBTASK LINKS THE NEW UNIT INTO THE BUFFER      * 01386020
*   AND RE-ENTERS THE ERROR MESSAGE ROUTINE CODE.  THE OUTPUT FROM    * 01388020
*   THE SUBTASK IS THE SAME AS THE INPUT FOR THE ROUTINE.             * 01390020
*                                                                     * 01392020
*OUTPUT,  ERROR MESSAGE ROUTINE --                                    * 01394020
*   WHEN EXIT IS TO REQUEST A NEW UNIT,  AN ERROR MESSAGE QCB IS      * 01396020
*   BUILT IN THE BUFFER.  THE ADDRESS OF THIS QCB IS SET IN THE       * 01398020
*   LCB RETURN-CONTROL QCB FIELD (LCBRCQCB).  THE LCB ERB CHAIN       * 01400020
*   FIELD (LCBERBCH) IS CLEARED TO ZEROES AND A REQUEST FOR ONE       * 01402020
*   UNIT IS SET IN THE LCB ERB COUNT FIELD (LCBERBCT).                * 01404020
*                                                                     * 01406020
*EXTERNAL REFERENCES --                                               * 01408020
*   'IEDQAF' - INSERT DATA ROUTINE TO INSERT THE ERROR MESSAGE INTO   * 01410020
*   THE BUFFER                                                        * 01412020
*                                                                     * 01414020
*   AVT - ADDRESS VECTOR TABLE                                        * 01416020
*                                                                     * 01418020
*   BUFFER CURRENTLY BEING PROCESSED                                  * 01420020
*                                                                     * 01422020
*   LCB - LINE CONTROL BLOCK                                          * 01424020
*                                                                     * 01426020
*   SCB - STATION CONTROL BLOCK                                       * 01428020
*                                                                     * 01430020
*EXITS,  NORMAL,  ERROR MESSAGE ROUTINE --                            * 01432020
*   THE ERROR MESSAGE REQUESTED DOES NOT FIT INTO THE SPACE AVAIL-    * 01434020
*   ABLE IN THE BUFFER.  THE ERB IS POSTED TO THE BUFFER RETURN       * 01436020
*   QCB.                                                              * 01438020
*                                                                     * 01440020
*   THE ERROR MESSAGE HAS BEEN INSERTED INTO THE BUFFER.  THE         * 01442020
*   BUFFER IS POSTED TO THE DESTINATION.                              * 01444020
*                                                                     * 01446020
*EXITS, NORMAL,  ERROR MESSAGE SUBTASK --                             * 01448020
*   A NEW UNIT HAS BEEN LINKED INTO THE CURRENT BUFFER.  ENTRY IS     * 01450020
*   MADE TO THE ERROR MESSAGE ROUTINE.                                * 01452020
*                                                                     * 01454020
*EXITS,  ERROR --N/A                                                  * 01456020
*                                                                     * 01458020
*TABLES/WORK AREAS -- N/A                                             * 01460020
*                                                                     * 01462020
*ATTRIBUTES -- SERIALLY REUSABLE,  REFRESHABLE,  ENABLED,             * 01464020
*   RESIDENT,  PROBLEM PROGRAM MODE.                                  * 01466020
*                                                                     * 01468020
*NOTES -- THE OPERATION OF THIS MODULE DOES NOT DEPEND UPON AN        * 01470020
*   INTERNAL REPRESENTATION OF THE EXTERNAL CHARACTER SET.            * 01472020
*                                                                     * 01474020
*********************************************************************** 01476020
         EJECT                                                          01478020
********* REGISTER EQUATES *********                                    01600020
         SPACE                                                          02000020
R0       EQU   0                        WORK REGISTER                   02400020
         SPACE                                                          02800020
R1       EQU   1                        ADDR OF BFR BRING PROCESSED     03200020
         SPACE                                                          03600020
RWORK2   EQU   2                        WORK REGISTER                   04000020
         SPACE                                                          04400020
RSCB3    EQU   3                        SCB ADDRESS                     04800020
         SPACE                                                          05200020
RLCB4    EQU   4                        LCB ADDRESS                     05600020
         SPACE                                                          06000020
RMSG5    EQU   5                        ADDRESS OF ERROR MESSAGE        06400020
         SPACE                                                          06800020
RPREFIX  EQU   6                        BUFFER ADDRESS                  07200020
         SPACE                                                          07600020
RLNG7    EQU   7                        LNG OF DATA TO BE INSERTED      08000020
         SPACE                                                          08400020
R8       EQU   8                                                        08800020
RPARM8   EQU   8                        PARAMETER LIST ADDRESS          09200020
         SPACE                                                          09600020
R9       EQU   9                                                        10000020
R10      EQU   10                                                       10400020
RDISP    EQU   11                       ADDRESS OF DISPATCHER           10800020
         SPACE                                                          11200020
RBASE    EQU   12                       BASE REGISTER                   11600020
         SPACE                                                          12000020
R13      EQU   13                       SAVE AREA ADDRESS               12400020
R14      EQU   14                       RETURN REGISTER                 12800020
R15      EQU   15                       LINK REGISTER                   13200020
         SPACE                                                          13600020
********* OTHER EQUATES *********                                       14000020
         SPACE                                                          14400020
PARMAF   EQU   2                        IEDQAF INDEX                    14800020
PARMMLEN EQU   4                        LENGTH OF ERROR MESSAGE         15200020
PARMMSG  EQU   5                        ERROR MESSAGE ADDRESS           15600020
         SPACE                                                          16000020
INRTFLAG EQU   X'02'                    INSERT-AND-RETURN REQ FLAG      16400020
STAT02   EQU   X'02'                    ERB STATUS TO GET BUFFER        16800020
BUF1UNT1 EQU   X'0101'                  ONE-BUFFER-ONE-UNIT REQUEST     17200020
         SPACE                                                          17600020
INSOFF   EQU   4                        INSERT OFFSET                   18000020
         SPACE                                                          18400020
ONE      EQU   1                        INCREMENT VALUE OF ONE          18800020
EIGHT    EQU   8                        FAKE QCB'S OFFSET FROM BFR      19200020
         SPACE                                                          19300020
REG2OFF  EQU   28                       OFFSET TO R2 IN SAVE AREA       19400020
         EJECT                                                          19600020
         USING AVTSAVE2,R13                                             20000020
         USING IEDQDISP,RDISP                                           20400020
         USING IEDQLCB,RLCB4                                            20800020
         USING IEDQPRF,RPREFIX                                          21200020
         USING IEDQSCB,RSCB3                                            21600020
         USING IEDQAT,RBASE                                             22000020
         SPACE                                                          22400020
IEDQAT01 EQU   *                                                        22800020
         B     ERRORMSG                 BRANCH AROUND ID                23200020
         DC    C'IEDQAT'                                                23500020
         DC    C'1179'                                           A42411 23800000
         SPACE                                                          24100020
ERRORMSG DS    0H                                                       24400020
         LR    R10,R1                   SAVE POST LIST                  24800020
         TM    PRFSTAT1,PRFERMGN        ERROR MESSAGE IN THIS BUFFER    25200020
         BO    NOLOOP                   BRANCH YES - NO ERROR           25600020
*                                       MESSAGE LOOP                    26000020
*                                                                       26400020
         L     RMSG5,PARMMSG-1(,RPARM8) GET ADDR OF ERROR MESSAGE       26800020
         SR    RLNG7,RLNG7              (CLEAR FOR INSERT)              27200020
         IC    RLNG7,PARMMLEN(,RPARM8)   PICK UP LNG OF ERROR MSG       27600020
         LTR   RLNG7,RLNG7              IS LENGTH BYTE ZERO             28000020
         BNZ   ICSCAN                   NO, PARM LIST IS RIGHT          28400020
         SPACE                                                          28800020
         IC    RLNG7,AVTEZERO(,RMSG5)   YES, GET LNG FROM MESSAGE       29200020
         LA    RMSG5,ONE(,RMSG5)        POINT TO REAL MSG START         29600020
         ST    RMSG5,PARMMSG-1(,RPARM8) RESET PARAMETER                 30000020
         STC   RLNG7,PARMMLEN(,RPARM8)    LIST FIELDS                   30400020
         SPACE                                                          30800020
ICSCAN   EQU   *                                                        31200020
         CLI   ONE(RPARM8),EIGHT        WAS AN EXIT SPECIFIED           31230000
         BE    NOEXIT                   BRANCH NO                       31260000
*                                                                       31290000
         LR    R1,RPREFIX               BUFFER ADDRESS TO PARAMETER REG 31320000
         STM   RWORK2,RBASE,REG2OFF(R13) SAVE REGISTERS                 31350000
         L     R15,EIGHT(RPARM8)        ADDRESS OF USER EXIT            31380000
         BALR  R14,R15                  EXIT TO USER ROUTINE            31410000
*                                                                       31440000
         LM    RWORK2,RBASE,REG2OFF(R13) RESTORE REGISTERS              31470000
         SPACE                                                          31500000
NOEXIT   EQU   *                                                        31530000
         SR    RWORK2,RWORK2            PICK UP SCAN                    31600020
         IC    RWORK2,PRFSCAN             POINTER FROM PREFIX           32000020
         SR    R1,R1                    PICK UP NO. OF                  32040020
         IC    R1,PRFSCAN+1               RESERVES FROM PREFIX          32080020
         LA    R1,AVTHDRSZ(,R1)         ADD SIZE OF HEADER PREFIX       32120020
         CR    R1,RWORK2                IS SCAN POINTER VALID           32160020
         BNH   BUFSIZE                  YES, BRANCH                     32200020
         SPACE                                                          32240020
         LR    RWORK2,R1                NO, RESET IT                    32280020
         SPACE                                                          32320020
BUFSIZE  EQU   *                                                        32360020
         SR    R15,R15                  CLEAR FOR IC             A42411 32380000
         SPACE                                                          32400020
         IC    R15,PRFNBUNT             PICK UP NO. OF UNITS            32800020
         LH    R14,AVTKEYLE             GET LENGTH OF ONE UNIT          33200020
         MR    R14,R15-1                MULTIPLY TO GET BUFFER SIZE     33600020
         CR    RWORK2,R15               SCAN BEYOND END OF BUFFER       34000020
         BNH   TESTFRST                 NO, GO TEST FIT IN FIRST        34100020
         SPACE                                                          34200020
         CH    RLNG7,AVTKEYLE           WILL MSG FIT IN NEW UNIT        34300020
         BNH   NEWUNIT                  YES, GO GET NEW UNIT            34400020
         SPACE                                                          34500020
         LH    RLNG7,AVTKEYLE           NO, SET LNG = UNIT LENGTH       34600020
         B     NEWUNIT                     AND GO GET NEW UNIT          34700020
         SPACE                                                          34800020
TESTFRST EQU   *                                                        35000020
         SR    R15,RWORK2               GET SIZE BEYOND SCAN PTR        35200020
         CR    RLNG7,R15                WILL ERROR MSG FIT IN FIRST     35600020
         BNH   INSERT2                  YES, GO INSERT IT               36000020
         SPACE                                                          36400020
         AH    R15,AVTKEYLE             WILL ERROR MSG FIT IN FIRST     36460020
         CR    RLNG7,R15                  BUFFER PLUS ONE UNIT          36520020
         BNH   NEWUNIT                  YES, GO GET NEW UNIT            36580020
         SPACE                                                          36640020
         LR    RLNG7,R15                NO, SET LNG = WHAT WILL FIT     36700020
*        B     NEWUNIT                  NO, FALL THROUGH                36800020
         EJECT                                                          37200020
NEWUNIT  EQU   *                                                        37600020
         SR    RWORK2,RWORK2            (ZERO FOR CLEARING)             38000020
         STH   RWORK2,LCBERBCH+1        CLEAR CHAIN FIELD               38400020
         STC   RWORK2,LCBERBCH            TO ZEROES                     38800020
         MVI   LCBERBST,STAT02          SET ERB STATUS                  39200020
         LA    RWORK2,BUF1UNT1          REQUEST ONE BUFFER,             39600020
         STH   RWORK2,LCBERBCT            ONE UNIT LONG                 40000020
         SPACE                                                          40400020
         LA    RWORK2,STCBAT            GET ADDR OF OUR STCB            40800020
         ST    RWORK2,PRFRCB            SET IT IN BUFFER PREFIX         41200020
         STC   RLNG7,PRFKEY             SAVE MESSAGE LENGTH             41400020
         LA    RWORK2,EIGHT             GET ADDRESS OF SIMULATED        41600020
         SR    RPREFIX,RWORK2             QCB IN BUFFER                 42000020
         IC    RWORK2,LCBRCQCB                                          42400020
         ST    RPREFIX,LCBRCQCB         SET IT IN LCB RTN-CTL FIELD     42800020
         STC   RWORK2,LCBRCQCB                                          43200020
         SPACE                                                          43600020
         LA    R8,AVTBFREB              ADDRESS OF BUFFER RETURN        44000020
         LA    R9,PRIINTRQ              PRIORITY FOR INITIAL REQUEST    44400020
         B     ERBPST                   POST ERB                        44800020
         EJECT                                                          45200020
STCBAT   EQU   *                                                        45600020
         DC    AL1(DSPMCPL2),AL1(0)                                     46000020
         SPACE                                                          46400020
         USING *,R15                                                    46800020
         SR    R10,R10                  INDICATE END OF POST LIST       47200020
         LA    RPREFIX,EIGHT(,RLNG7)    INITIALIZE OLD BUFFER ADDR      47600020
         L     RLCB4,PRFLCB-1           GET LCB ADDRESS                 48000020
         L     RSCB3,LCBSCBA-1          GET SCB ADDRESS                 48400020
         SPACE                                                          48800020
         L     RPARM8,SCBMACR-1         GET PARAMETER LIST              49200020
         L     RMSG5,PARMMSG-1(,RPARM8) GET ADDR OF ERROR MESSAGE       49600020
         SR    RLNG7,RLNG7              (CLEAR FOR INSERT)              50000020
         IC    RLNG7,PRFKEY             GET LNG OF ERROR MESSAGE        50400020
         SPACE                                                          50800020
         SR    R1,R1                    (CLEAR FOR INSERT)              51200020
         IC    R1,PRFNBUNT              PICK UP NUMBER OF UNITS         51600020
         LA    R0,ONE(,R1)              ADD ONE                         52000020
         STC   R0,PRFNBUNT              STORE IT BACK                   52400020
         LR    RWORK2,RPREFIX           GET ADDRESS OF FIRST UNIT       52800020
         BAL   R14,ENTER                ENTER LOOP                      53200020
         SPACE                                                          53600020
         L     RWORK2,PRFTIC-IEDQPRF(,RWORK2) GET ADDR OF NEXT UNIT     54000020
         SPACE                                                          54400020
ENTER    EQU   *                                                        54800020
         BCTR  R1,R14                   LOOP TILL POINTING TO LAST      55200020
         SPACE                                                          55600020
         MVC   PRFTIC+1-IEDQPRF(3,RWORK2),LCBERBCH  LINK IN NEW UNIT    56000020
         EJECT                                                          56400020
INSERT   EQU   *                                                        56800020
         SR    RWORK2,RWORK2            RESET INSERT POINT              57200020
         IC    RWORK2,PRFSCAN             AT SCAN POINTER               57600020
         SPACE                                                          58000020
INSERT2  EQU   *                                                        58400020
         BALR  RBASE,AVTEZERO           ESTABLISH NEW BASE              58800020
         USING *,RBASE                                                  59200020
         SPACE                                                          59600020
         STH   RWORK2,AVTPARM           STORE SCAN PTR FOR COMPARE      59900020
         CLC   AVTPARM(2),PRFSIZE       SCAN PTR BEYOND END OF BFR      60200020
         BNH   INCR                     NO, INSERT PAST SCAN PTR        60500020
         SPACE                                                          60800020
         TM    PRFSTAT1,PRFNLSTN        YES, IS THIS LAST BUFFER        61200020
         BO    LINKAF                   IT IS NOT, INSERT AT SCAN       61600020
         SPACE                                                          62000020
         BCT   RWORK2,LINKAF            IT IS, INSERT BEFORE EOT        62400020
         SPACE                                                          62800020
INCR     EQU   *                                                        63200020
         LA    RWORK2,ONE(,RWORK2)      POINT PAST SCAN POINTER         63600020
         SPACE                                                          64000020
LINKAF   EQU   *                                                        64400020
         IC    R0,PARMAF(,RPARM8)       PICK UP IEDQAF OFFSET           64800020
         STC   R0,AVTPARM               SET IT IN PARAMETER LIST        65200020
         OI    AVTPARM,INRTFLAG         REQUEST INSERT AND RETURN       65600020
         MVI   AVTPARM+1,AVTEZERO       SET DATA TYPE FLAG              66000020
         SPACE                                                          66400020
         ST    RPREFIX,AVTADBUF         PASS BUFFER ADDRESS             66800020
         ST    RWORK2,INSOFF(,RPREFIX)   SET INSERT OFFSET              67200020
         ST    RMSG5,AVTPARM3           SET MESSAGE ADDRESS             67600020
         STC   RLNG7,AVTPARM3           SET MESSAGE LENGTH              68000020
         LA    R1,AVTPARM               POINT TO IEDQAF PARM LIST       68400020
         L     R15,AVTUI                GET USER INTERFACE ADDRESS      68800020
         BALR  R14,R15                  LINK TO INSERT ERROR MSG        69200020
         SPACE                                                          69600020
         AR    RWORK2,RLNG7             ADD SCAN POINTER & LENGTH       70000020
*                                         OF MESSAGE DATA INSERTED      70400020
         BCTR  RWORK2,AVTEZERO          POINT TO LAST BYTE              70800020
         STH   RWORK2,PRFSIZE           SET NEW DATA SIZE               71200020
         SPACE                                                          71600020
         MVI   PRFSTAT1,PRFERMGN        SET PREFIX STATUS               72000020
         L     R8,SCBDESTQ-1            DESTINATION QCB ADDRESS         75250020
         B     DESTQ                   GO POST BUFFER                   75300020
         SPACE 1                                                        75350020
NOLOOP   EQU   *                                                        75400020
         LA    R8,AVTBFRTB              SET TO FREE BUFFER              75450020
DESTQ    EQU   *                                                        75500020
         BALR  R14,0                    RESET BASE IF BRANCHED TO       75600020
         USING *,R14                                                    76000020
         LR    R1,RPREFIX               BUFFER TO BE POSTED             76400020
         LA    R9,PRIDESTQ              PRIORITY                        77200020
         BAL   R14,POSTSUB              ADD BUFFER TO POST LIST         77600020
         LR    R10,R1                   NEW POST LIST                   78000020
         L     R8,AVTMSGS-1             ADDRESS OF IEDQBD               78800020
         L     R8,0(,R8)                                                79200020
         LA    R9,PRIRCQCB              PRIORITY                        79600020
ERBPST   EQU   *                                                        80000020
         NI    LCBSTAT1,X'FF'-LCBRCLLN  RESET RECALL BIT                80400020
         LA    R1,LCBERB                ERB TO BE POSTED                80800020
         LA    R14,DSPCHAIN             EXIT TO SISPATCHER              81200020
POSTSUB  EQU   *                                                        81600020
         ST    R8,0(R1)                 QCB ADDRESS TO ELEMENT          82000020
         ST    R10,4(R1)                LINK IN POST LIST               82400020
         STC   R9,4(R1)                 SET PRIORITY                    82800020
         BR    R14                      RETURN                          83200020
         EJECT                                                          83600020
********* DSECTS *********                                              84000020
         SPACE                                                          84400020
         TAVTD                                                          84800020
         EJECT                                                          85200020
         TDISPD                                                         85600020
         EJECT                                                          86000020
         TLCBD                                                          86400020
         EJECT                                                          86800020
         TPRFD                                                          87200020
         EJECT                                                          87600020
         TPRIOR                                                         88000020
         EJECT                                                          88400020
         TSCBD                                                          88800020
         SPACE                                                          89200020
         END                                                            89600020
