AZ01     TITLE '''IEDQAZ'' - REDIRECT ROUTINE'                          00400020
IEDQAZ   CSECT                                                          00800020
         SPACE 3                                                        00850022
*  CHANGE ACTIVITY AS FOLLOWS:                                          00860022
******************** MICROFICHE FLAGS *********************** SUPT CODE 00870022
*A506000                                                         A42407 00900022
*C477600                                                         A42407 00900122
*C477600,509000                                                  A51765 00900222
*C824000                                                         A52511 00900322
*A828000,930000                                                  A52511 00900422
*C700000-704000                                                 SA55948 00900522
*     CLEAN-UP                                                   S21903 00900605
*C556000                                                        SA62385 00900705
*A 490000,692000                                                SA63999 00900851
*C 700000,703000                                                SA63999 00900951
*A SAME CHANGE FOR 63999                                        OY00468 00901051
         SPACE 3                                                        01200022
*********************************************************************** 01202020
*                                                                     * 01204022
*  TITLE: IEDQAZ - REDIRECT ROUTINE                                   * 01204322
*                                                                     * 01204622
*  MODULE NAME = IEDQAZ                                               * 01204922
*                                                                     * 01205222
*  DESCRIPTIVE NAME = REDIRECT / ERRORMSG ROUTINE                     * 01205551
*                                                                     * 01205822
*  COPYRIGHT = 'NONE'                                                 * 01206122
*                                                                     * 01206422
*  STATUS CHANGE LEVEL 5                                              * 01206751
*                                                                     * 01207022
*FUNCTION --                                                          * 01208020
*   REDIRECTS A MESSAGE TO THE DESTINATION SPECIFIED BY THE USER.     * 01210020
*                                                                     * 01212020
*   IF THE REDIRECT DESTINATION IS IN AN OPTION FIELD,  THE ROUTINE   * 01214020
*   LINKS TO THE LOCATE OPTION ROUTINE (IEDQAE) TO GET THE ADDRESS    * 01216020
*   OF THE OPTION FIELD.  IF THE FIELD IS NOT FOUND,  THE ERROR       * 01218020
*   HANDLING EXIT IS TAKEN.                                           * 01220020
*                                                                     * 01222020
*   IF THE FIELD IS FOUND,  PARAMETERS ARE BUILT FOR,  AND A LINK     * 01224020
*   TAKEN TO,  THE BINARY SEARCH ROUTINE (IEDQA1).  THIS IS ALSO      * 01226020
*   THE PROCEDURE TAKEN WHEN THE REDIRECT DESTINATION NAME IS         * 01228020
*   EXPLICITLY SPECIFIED BY THE MACRO.  ON RETURN,  IF THE NAME IS    * 01230020
*   NOT FOUND IN THE TERMINAL NAME TABLE,  THE ERROR HANDLING EXIT    * 01232020
*   IS TAKEN.                                                         * 01234020
*                                                                     * 01236020
*   IF THE NAME IS FOUND,  THE DESTINATION KEY RETURNED BY BINARY     * 01238020
*   SEARCH IS PASSED TO THE LOOK UP DESTINATION ROUTINE (IEDQAV).     * 01240020
*   THIS IS ALSO THE PROCEDURE TAKEN WHEN THE REDIRECT DESTINATION    * 01242020
*   IS THE ORIGIN OR THE ORIGINAL DESTINATION,  IN WHICH CASE THE     * 01244020
*   KEY PASSED IS ACCESSED FROM THE PREFIX FIELD PRFSRCE (ORIGIN)     * 01246020
*   OR PRFDEST (ORIGINAL DESTINATION).  ON RETURN,  IF THE DESTINA-   * 01248020
*   TION IS A TSO TERMINAL,  THE ERROR HANDLING EXIT IS TAKEN.        * 01250020
*                                                                     * 01252020
*   IF IT IS NOT,  THE MESSAGE IS POSTED TO THE DESTINATION VIA AN    * 01254020
*   EXIT TO THE DISPATCHER AT THE LABEL DSPCHAIN.                     * 01256020
*                                                                     * 01258020
*    ERRORMSG MACRO FUNCTION USES THE REDIRECT ROUTINE TO             * 01260051
*   DETERMINE THE ERROR MESSAGE DESTINATION.  WHEN THIS IS THE CASE   * 01262020
*   THE REDIRECT ROUTINE DOES NOT POST THE MESSAGE.  INSTEAD THE      * 01264020
*   FIELD SCBMACR IN THE SCB IS SET TO THE ADDRESS OF THE ERROR       * 01266020
*   MESSAGE PARAMETER LIST AND EXIT IS MADE TO THE ERROR MESSAGE      * 01268020
*   ROUTINE.                                                          * 01270020
*                                                                     * 01272020
*   ERROR HANDLING EXIT (TESTDEAD) --                                 * 01274020
*   IF A DEAD-LETTER QUEUE IS SPECIFIED,  ITS KEY IS ACCESSED AND     * 01276020
*   PASSED TO IEDQAV AND THE MESSAGE IS POSTED THERE.  IF NONE IS     * 01278020
*   SPECIFIED,  THE MESSAGE IS NOT REDIRECTED AND EXIT IS MADE TO     * 01280020
*   BUFFER DISPOSITION VIA THE DISPATCHER AT THE LABEL DSPCHAIN.      * 01282020
*                                                                     * 01284020
*ENTRY POINTS --                                                      * 01286020
*       'IEDQAZ01' TO REDIRECT A MESSAGE TO AN ADDITIONAL DESTINA-    * 01288020
*   TION.  THE ROUTINE IS ENTERED BY A BRANCH FROM BUFFER             * 01290020
*   DISPOSITION (IEDQBD).                                             * 01292020
*                                                                     * 01294020
*INPUT --                                                             * 01296020
*   REGISTER 1 - ADDRESS OF AN ADDITIONAL ELEMENT TO BE POSTED        * 01298020
*                                                                     * 01300020
*   REGISTER 3 - ADDRESS OF THE SCB                                   * 01302020
*                                                                     * 01304020
*   REGISTER 6 - ADDRESS OF THE BUFFER                                * 01306020
*                                                                     * 01308020
*   REGISTER 8 - ADDRESS OF A MACRO-GENERATED PARAMETER LIST.         * 01310020
*   PARAMETER LIST FORMAT IS:                                         * 01312020
*                                                                     * 01314020
*        *********************************                            * 01316020
*        *       * PARAM * NO OF *       *                            * 01318020
*        * INDEX * LIST  * BFRS  *       *                            * 01320020
*        *       * LNGTH *       *       *                            * 01322020
*        *************************       *                            * 01324020
*        *                               *                            * 01326020
*        *          ERROR MASK           *                            * 01328020
*        *                               *                            * 01330020
*        *********************************                            * 01332020
*        *       *     VARIABLE DATA     *                            * 01334020
*        *STATUS *      (SEE BELOW)      *                            * 01336020
*        *       *                       *                            * 01338020
*        *********************************                            * 01340020
*        * INDEX * PARAM * INDEX * INDEX *                            * 01342020
*        *  TO   * LIST  *  TO   *  TO   *                            * 01344020
*        *   AT  * LNGTH *   AF  *   AO  *                            * 01346020
*        *********************************                            * 01348020
*        *       *                       *                            * 01350020
*        *       *  ADDRESS OF MESSAGE   *                            * 01352020
*        *       *                       *                            * 01354020
*        *********************************                            * 01356020
*        *          ADDRESS OF           *                            * 01358020
*        *       USER EXIT ROUTINE       *                            * 01360020
*        *           (OPTIONAL)          *                            * 01362020
*        *********************************                            * 01364020
*                                                                     * 01366020
*        VARIABLE DATA:                                               * 01368020
*                                                                     * 01370020
*        *********************************                            * 01372020
*        *       *                       * TO BE SENT                 * 01374020
*        *  'S'  *     UNUSED (ZERO)     *   TO SOURCE                * 01376020
*        *       *                       *                            * 01378020
*        *********************************                            * 01380020
*                                                                     * 01382020
*        *********************************                            * 01384020
*        *       *                       * TO BE SENT                 * 01386020
*        *  'D'  *     UNUSED (ZERO)     *   TO DESTINATION           * 01388020
*        *       *                       *   SPECIFIED IN PREFIX      * 01390020
*        *********************************                            * 01392020
*                                                                     * 01394020
*        *********************************                            * 01396020
*        *       * INDEX *  OPT  *  RTN  * TO BE SENT                 * 01398020
*        *  'O'  *  TO   * FIELD *  REG  *   TO DESTINATION           * 01400020
*        *       *   AE  * OFFST * OFFST *   SPECIFIED IN OPTION FL   * 01402020
*        *********************************                            * 01404020
*                                                                     * 01406020
*        *********************************                            * 01408020
*        *       *                       * TO BE SENT                 * 01410020
*        *  'N'  *    ADDRESS OF NAME    *   TO DESTINATION           * 01412020
*        *       *                       *   SPECIFIED BY NAME        * 01414020
*        *********************************                            * 01416020
*                                                                     * 01418020
*   REGISTER 12 - ENTRY POINT ADDRESS AND BASE REGISTER FOR THIS      * 01420020
*   SUBTASK.                                                          * 01422020
*                                                                     * 01424020
*   REGISTER 13 - ADDRESS OF THE SAVE AREA AND BASE FOR AVT           * 01426020
*   ADDRESSABILITY                                                    * 01428020
*                                                                     * 01430020
*OUTPUT --                                                            * 01432020
*   IF A VALID DESTINATION IS FOUND,  THE KEY FOR THE DESTINATION     * 01434020
*   IS SET IN THE PREFIX (PRFDEST).  THE DESTINATION QCB ADDRESS IS   * 01436020
*   SET IN THE BUFFER (PRFQCBA) AND THE ADDRESS OF THE ADDITIONAL     * 01438020
*   ELEMENT IS SET IN THE BUFFER (PRFLINK).  IF A VALID DESTINATION   * 01440020
*   IS NOT FOUND,  THE ADDRESS OF THE DEAD-LETTER QCB OR,  IF THERE   * 01442020
*   IS NO DEAD-LETTER QUEUE,  THE ADDRESS OF THE BUFFER DISPOSITION   * 01444020
*   QCB IS SET IN THE BUFFER (PRFQCBA).                               * 01446020
*                                                                     * 01448020
*EXTERNAL REFERENCES --                                               * 01450020
*                                                                     * 01452020
*   AVT - ADDRESS VECTOR TABLE                                        * 01454020
*                                                                     * 01456020
*   RECALLED HEADER BUFFER                                            * 01458020
*                                                                     * 01460020
*   SCB - STATION CONTROL BLOCK                                       * 01462020
*                                                                     * 01464020
*EXITS,  NORMAL --                                                    * 01466020
*   A VALID DESTINATION HAS BEEN FOUND.  THE BUFFER IS POSTED TO      * 01468020
*   THE DESTINATION.                                                  * 01470020
*                                                                     * 01472020
*EXITS, ERROR --                                                      * 01474020
*   NO VALID DESTINATION HAS BEEN FOUND.  A DEAD-LETTER QUEUE IS      * 01476020
*   SPECIFIED.  THE BUFFER IS POSTED TO THE DEAD-LETTER QUEUE.        * 01478020
*                                                                     * 01480020
*   NO VALID DESTINATION HAS BEEN FOUND.  NO DEAD-LETTER QUEUE IS     * 01482020
*   SPECIFIED.  THE BUFFER IS POSTED TO BUFFER DISPOSITION.           * 01484020
*                                                                     * 01486020
*TABLES/WORK AREAS: N/A                                               * 01488020
*                                                                     * 01490020
*ATTRIBUTES -- SERIALLY REUSEABLE, REENTERANT,ENABLED,RESIDENT,       * 01492051
*   PROBLEM PROGRAM MODE.                                             * 01494020
*                                                                     * 01496020
*NOTE -- THE OPERATION OF THIS MODULE DEPENDS UPON AN INTERNAL        * 01498020
*   REPRESENTATION OF THE EXTERNAL CHARACTER SET WHICH IS             * 01500020
*   EQUIVALENT TO THE ONE USED AT ASSEMBLY TIME.  THE CODING HAS      * 01502020
*   BEEN ARRANGED SO THAT REDEFINITION OF ''CHARACTER'' CONSTANTS,    * 01504020
*   BY REASSEMBLY, WILL RESULT IN A CORRECT MODULE FOR THE NEW        * 01506020
*   DEFINITIONS.                                                      * 01508020
*                                                                     * 01510020
*********************************************************************** 01512020
         EJECT                                                          22000020
********* REGISTER EQUATES *********                                    22400020
         SPACE                                                          22800020
R0       EQU   0                        WORK REGISTER                   23200020
         SPACE                                                          23600020
R1       EQU   1                        PARAMETER LIST REGISTER         24000020
         SPACE                                                          24400020
RWORK2   EQU   2                        WORK REGISTER                   24800020
         SPACE                                                          25200020
RSCB3    EQU   3                        SCB ADDRESS                     25600020
         SPACE                                                          26000020
RLCB4     EQU   4                       LCB ADDRESS                     26100020
         SPACE                                                          26200020
RPREFIX  EQU   6                        ADDRESS OF BUFFER               26400020
         SPACE                                                          26800020
RELEM7   EQU   7                        ADDRESS OF ELEMENT              27200020
         SPACE                                                          27600020
RPARM8   EQU   8                        PARAMETER LIST ADDR             28000020
*                                         ON INITIAL ENTRY              28400020
         SPACE                                                          28800020
RGO9     EQU   9                        LINK REG AFTER DEST FOUND       29200020
         SPACE                                                          29600020
RDISP    EQU   11                       ADDRESS OF DISPATCHER           30000020
         SPACE                                                          30400020
RBASE    EQU   12                       BASE REGISTER                   30800020
         SPACE                                                          31200020
R13      EQU   13                       SAVE AREA ADDRESS               31600020
R14      EQU   14                       RETURN REGISTER                 32000020
R15      EQU   15                       BRANCH REGISTER AND             32400020
*                                         RETURN CODE REGISTER          32800020
         SPACE                                                          33200020
         EJECT                                                          33600020
********* OTHER EQUATES *********                                       34000020
         SPACE                                                          34400020
CHARS    EQU   C'S'                     SOURCE                          34800020
CHARD    EQU   C'D'                     ORIGINAL DESTINATION            35200020
CHARN    EQU   C'N'                     NAME                            35600020
         SPACE                                                          36000020
PARMAZ   EQU   0                        INDEX OF IEDQAZ                 36400020
PARMSTAT EQU   2                        STATUS BYTE                     37200020
PARMDTYP EQU   0                        DESTINATION TYPE CODE           37600020
PARMNAME EQU   1                        ADDRESS OF NAME                 38000020
PARMAE   EQU   1                        INDEX OF IEDQAE                 38400020
PARMOPT  EQU   2                        OPTION FIELD OFFSET             38800020
PARMAT   EQU   4                        IEDQAT PARAMETER LIST           39200020
         SPACE                                                          39600020
ONE      EQU   1                        INCREMENT FACTOR OF ONE         40000020
FOUR     EQU   4                        LENGTH OF A FULLWORD            40400020
NUMB     EQU   28                       COUNT OF 28 DECIMAL      S21903 40600005
         SPACE                                                          40800020
UNCOFLAG EQU   X'01'                    UNCONDITIONAL FLAG              41200020
ERMSFLAG EQU   X'01'                    ERROR MESSAGE FLAG              41600020
INDEXA1  EQU   X'08'                    INDEX OF IEDQA1                 42000005
INDEXAV  EQU   X'10'                    INDEX OF IEDQAV                 42600005
         SPACE                                                          43200020
ZERO     EQU   8                        CONDITION CODE: ZERO            43600020
         SPACE                                                          44000020
         EJECT                                                          45200020
         USING AVTSAVE2,R13                                      S22025 45600022
         USING IEDQSCB,RSCB3                                            46000020
         USING IEDQPRF,RPREFIX                                          46400020
         USING IEDQAZ,RBASE                                             46800020
         SPACE                                                          47200020
IEDQAZ01 EQU   *                                                        47600020
IEDQAZ   IEDHJN REDIRECT                ID AND DATE              S22025 47680022
         ST    RPREFIX,AVTADBUF         REINITIALIZE AVT BFR ADDR       48000020
         LR    RELEM7,R1                SAVE ELEMENT ADDRESS            48400020
         MVI   SCBPRI,AVTEZERO          CLEAR SCB PRIORITY              48800020
         NI    PRFSTAT1,PRFCNCLF        MAKE SURE CANCEL BIT IS OFF     49000020
         SPACE 1                                                OX00468 49060051
         MVC   AVTDOUBL+4(FOUR),0(RPARM8)  SAVE ENTRY FLAGS     SA63999 49120051
         TM    PARMSTAT(RPARM8),ERMSFLAG IS ERROR MSG REQUESTED         49200020
         LA    RGO9,ERRMSG              ANTICIPATE ERROR MSG            49600020
         BO    SETPARM                  YES, BRANCH                     50000020
         SPACE                                                          50400020
         LA    RGO9,SETQCB              NO, SET LINK TO POST            50500020
         L     RLCB4,PRFLCB-1           GET ADDRESS OF LCB              50600020
         TM    PRFSTAT1,PRFERMGN        IS THIS BFR AN ERRMSG    A42407 50620000
         BO    POSTDISP                 BRANCH YES - DO NOT      A42407 50640000
*                                       REDIRECT AN ERRMSG       A42407 50660000
*                                       POST TO BD INSTEAD       A42407 50680000
         USING IEDQLCB,RLCB4                                            50700020
         TM    LCBSTAT1,LCBINITN+LCBSENDN INIT MODE ON SEND SIDE        50800020
         BNO   SETPARM                  BR NOT SEND INITIATE     A51765 50900022
         TM    SCBERR4,SCBSLCTN+SCBTXTTN  LINE ERROR             A51765 50930022
         BNZ   POSTDISP                 YES,DON'T REDIRECT,POST  A51765 50960022
*                                         TO BFR DISP INSTEAD           51000020
         SPACE                                                          51200020
SETPARM  EQU   *                                                        51600020
         TM    PARMAZ(RPARM8),UNCOFLAG  TEST IF UNCONDITIONAL           52000020
         LA    RPARM8,FOUR(,RPARM8)     BUMP TO SECOND WORD             52400020
         BO    TESTSRCE                 YES, NOW AT DEST TYPE FIELD     52800020
         SPACE                                                          53200020
         LA    RPARM8,FOUR(,RPARM8)     NO, MUST BUMP ANOTHER WORD      53600020
         SPACE                                                          54000020
TESTSRCE EQU   *                                                        54400020
         CLI   PARMDTYP(RPARM8),CHARS   SEND TO ORIGIN                  54800020
         LH    R1,PRFSRCE               YES, PICK UP ORIGIN KEY         55200020
         BNE   TESTDEST                 BRANCH IF NONZERO       SA62385 55600005
         MVC   PRFDEST,PRFSRCE          SET UP DEST             SA62385 55700005
         B     LINKRET                  SET FOR REDIRECT        SA62385 55800005
         SPACE                                                          56000020
         SPACE                                                          56400020
TESTDEST EQU   *                                                        56800020
         CLI   PARMDTYP(RPARM8),CHARD   SEND TO ORIGINAL DEST           57200020
         BNE   TESTNAME                 NO, PROCEED                     57600020
         SPACE                                                          58000020
         LH    R1,PRFDEST               YES, PICK UP DEST KEY           58400020
         SPACE                                                          58800020
LINKRET  EQU   *                                                        59200020
         N     R1,AVTCLRHI              IS KEY ZEROES                   59600020
         BZ    TESTDEAD                 YES, GO TEST FOR DLQ            60000020
         SPACE                                                          60400020
         B     LINKAV                   NO, GO LINK TO IEDQAV           60800020
         SPACE                                                          61200020
TESTNAME EQU   *                                                        61600020
         CLI   PARMDTYP(RPARM8),CHARN   SEND TO DEST NAMED              62000020
         BNE   PROCOPT                  NO, MUST BE IN OPT FIELD        62400020
         SPACE                                                          62800020
         L     RWORK2,PARMNAME-1(,RPARM8) YES, GET ADDRESS OF NAME      63200020
         LA    R15,ONE(,RWORK2)         BUMP PAST LENGTH BYTE           63600020
         IC    RWORK2,AVTEZERO(,RWORK2) PICK UP LENGTH BYTE             64000020
         B     LINKA1                   GO LINK TO BINARY SEARCH        64400020
         SPACE                                                          64800020
PROCOPT  EQU   *                                                        65200020
         LH    RWORK2,PARMOPT(,RPARM8)  PICK UP AE PARM LIST DATA       65600020
         STH   RWORK2,AVTDOUBL+2        SET IN PARM LIST                66000020
         IC    RWORK2,PARMAE(,RPARM8)   PICK UP IEDQAE OFFSET           66400020
         STC   RWORK2,AVTDOUBL          SET IN PARM LIST                66800020
         LA    R1,AVTDOUBL              POINT TO PARM LIST              67200020
         L     R15,AVTUI                GET USER INETRFACE ADDR         67600020
         BALR  R14,R15                  LINK TO LOCATE OPTION FIELD     68000020
         SPACE                                                          68400020
         LTR   R15,R15                  IS OPTION FIELD FOUND           68800020
         BZ    TESTDEAD                 NO, GO TEST IF DLQ              69200020
         SPACE 1                                                OY00468 69400051
         SPACE                                                          69600020
         TM    AVTDOUBL+6,ERMSFLAG      ERRORMSG REQUESTED ?    SA63999 70000051
         BNO   NERRMSG                  BRANCH IF NOT ERRORMSG  SA63999 70020051
         SPACE 1                                                SA63999 70040051
         IC    RWORK2,0(,R15)           LOAD LENGTH             SA63999 70060051
         SLL   RWORK2,NUMB              SHIFT LEFT              SA55948 70100022
         SRL   RWORK2,NUMB              SHIFT RIGHT             SA55948 70200022
         LA    R15,ONE(,R15)            LOAD ADDRESS            SA63999 70300051
         B     LINKA1                                                   70360051
         SPACE 1                                                SA63999 70420051
NERRMSG  EQU   *                                                        70480051
         IC    RWORK2,AVTEZERO(,R1)     GET LENGTH              SA63999 70540051
         LA    RWORK2,ONE(,RWORK2)      LOAD PAST LENGTH        SA63999 70600051
         SPACE 3                                                 S21903 70700005
LINKA1   EQU   *                                                        71200020
         ST    R15,AVTDOUBL+4           SET ADDR OF CHAR STRING         71600020
         STC   RWORK2,AVTDOUBL+3          & COUNT IN PARM LIST          72000020
         MVI   AVTDOUBL+2,AVTEZERO      ZERO HIGH LENGTH BYTE           72400020
         MVI   AVTDOUBL,INDEXA1+ONE     SET BINARY SEARCH INDEX         72800020
         LA    R1,AVTDOUBL              POINT TO PARM LIST              73200020
         L     R15,AVTUI                GET USER INETRAFCE ADDR         73600020
         BALR  R14,R15                  LINK TO BINARY SEARCH           74000020
         SPACE                                                          74400020
         LTR   R1,R15                   IS NAME FOUND IN TNT            74800020
         BZ    TESTDEAD                 NO, GO TEST FOR DLQ             75200020
         SPACE                                                          75600020
LINKAV   EQU   *                                                        76000020
         L     R15,AVTMSGS-1            GET ADDR OF LOOKUP ROUTINE      76400020
         L     R15,INDEXAV(,R15)          FROM MH VCON TABLE            76800020
         LR    RWORK2,R13               SAVE ADDR OF AVTSAVE2           77200020
         LA    R13,AVTSAVE3             POINT TO AVTSAVE3               77600020
         BALR  R14,R15                  LINK TO LOOKUP ROUTINE          78000020
         SPACE                                                          78400020
         LR    R13,RWORK2               RESET ADDR OF AVTSAVE2          78800020
         LTR   R15,R15                  TEST IF TSO TERMINAL            79200020
         BCR   ZERO,RGO9                NO, PROCEED                     79600020
         SPACE                                                          80000020
TESTDEAD EQU   *                                                        80400020
         LH    R1,AVTDLQX               PICK UP DEAD-LETTER Q KEY       80800020
         N     R1,AVTCLRHI              IS THERE A DEAD-LETTER Q        81200020
         BNZ   LINKAV                   YES, GO LINK TO LOOKUP          81600020
         SPACE                                                          82000020
POSTDISP EQU   *                                                        82200020
         L     RWORK2,BDVCON            ADDR OF IEDQBD           A52511 82400022
         B     MOVEQCB                  GO POST BUFFER                  83200020
         SPACE                                                          83600020
ERRMSG   EQU   *                                                        84000020
         LR    R1,RELEM7                RESET ELEMENT ADDRESS           84400020
         LA    RPARM8,PARMAT(,RPARM8)   BUMP TO IEDQAT PARM LIST        84800020
         IC    R0,SCBMACR-1                                             85200020
         ST    RPARM8,SCBMACR-1         SET IT IN SCB                   85600020
         STC   R0,SCBMACR-1                                             86000020
         IC    R15,AVTEZERO(,RPARM8)    PICK UP IEDQAT OFFSET           86400020
         L     RBASE,AVTMSGS-1          GET MH VCON TABLE ADDRESS       86800020
         L     RBASE,AVTEZERO(R15,RBASE) GET IEDQAT ADDRESS             87200020
         BR    RBASE                    EXIT TO IEDQAT                  87600020
         SPACE                                                          88000020
SETQCB   EQU   *                                                        88400020
         L     RWORK2,SCBDESTQ-1        SET DEST QCB ADDRESS            88800020
         SPACE                                                          89200020
MOVEQCB  EQU   *                                                        89600020
         ST    RWORK2,PRFQCBA-1         SET QCB ADDR IN BUFFER          90000020
         ST    RELEM7,PRFLINK-1         LINK ELEMENT TO BUFFER          90400020
         MVI   PRFPRI,PRIDESTQ          SET BUFFER PRIORITY             90800020
         SPACE                                                          91200020
         LR    R1,RPREFIX               PASS BFR ADDR IN REG 1          91600020
         L     RDISP,AVTEA              GET ADDR OF DISPATCHER          92000020
         USING IEDQDISP,RDISP                                           92400020
         B     DSPCHAIN                 POST                            92800020
BDVCON   DC    V(IEDQBD)                ADDR OF BD               A52511 93000022
         EJECT                                                          93200020
********* DSECTS *********                                              93600020
         SPACE                                                          94000020
         TAVTD ,                                                 S22025 94400022
         EJECT                                                          94800020
         TDISPD                                                         95200020
         EJECT                                                          95600020
      TLCBD                                                             95700020
         EJECT                                                          95800020
         TPRFD                                                          96000020
         EJECT                                                          96400020
         TPRIOR                                                         96800020
         EJECT                                                          97200020
         TSCBD                                                          97600020
         SPACE                                                          98000020
         END                                                            98400020
