         TITLE 'IEDQB2 -- TPDATE ROUTINE'                               00050000
IEDQB2   CSECT                                                   S22025 00100022
*A037700                                                         S22025 00110022
*C025500,037000,0395000                                          S22025 00120022
*A026100                                                        SA52997 00125022
*****************************************************************S22025 00130022
*                                                                     * 00150000
* TITLE: 'IEDQB2 -- TPDATE ROUTINE'                                   * 00200000
*                                                                     * 00250000
* STATUS: CHANGE LEVEL 0                                              * 00300000
*                                                                     * 00350000
* FUNCTION: THIS ROUTINE GETS CONTROL WHEN A TPDATE MACRO IS ISSUED   * 00400000
*         IN AN APPLICATION PROGRAM.  IF DELETE=YES WAS SPECIFIED,    * 00450022
*         BIT 1 OF GWAOPT2 IS TURNED ON.  IF DELETE=NO WAS SPECIFIED, * 00470022
*         BIT 1 OF GWAOPT2 IS TURNED OFF.  IF DTSAREA WAS SPECIFIED,  * 00490022
*         THE ADDRESS IS SAVED IN GWADTSA.  IF RECDEL=YES WAS         * 00510022
*         SPECIFIED, THE RECORD DELIMITER IS RETURNED TO THE          * 00530022
*         APPLICATION PROGRAM.                                        * 00550022
*                                                                     * 00570022
*                                                                     * 00600000
* ENTRY POINTS - IEDQB2                                               * 00650022
*                                                                     * 00670022
*                                                                     * 00700000
* INPUT - REGISTER 0 CONTAINS AN OPTION BYTE (X'04', INDICATION       * 00750022
*         THAT DELETE=WAS WAS SPECIFIED, X'20', INDICATING THAT       * 00760022
*         DTSAREA WAS SPECIFIED, X'80', INDICATING THAT RECDEL=YES    * 00770022
*         WAS SPECIFIED) AND THE ADDRESS OF THE DCB.                  * 00780022
*                                                                     * 00790022
*           THAT DELETE=YES WAS SPECIFIED AND THE ADDRESS OF THE DCB. * 00800000
*                                                                     * 00850000
* OUTPUT: REGISTER 15 CONTAINS A RETURN CODE.                         * 00900000
*           X'00' SUCCESSFUL COMPLETION                               * 00950000
*           X'04' AVT NOT ACTIVE                                      * 01000000
*           X'08' THE DEB POINTED TO BY THE DCB IS NOT A TCAM DEB     * 01050000
*                                                                     * 01100000
*         REGISTER 1 CONTAINS THE RECORD DELIMITER                    * 01110022
*                                                                     * 01120022
* EXTERNAL REFERENCES - CVT,AVT,DEB,DCB,AMWA(ACCESS METHOD WORKAREA)  * 01150022
*                                                                     * 01170022
*                                                                     * 01200000
* EXITS,NORMAL - RETURN TO ADDRESS IN REGISTER 14.                    * 01250022
*                                                                     * 01270022
*                                                                     * 01290022
* EXITS,ERROR -  RETURN TO ADDRESS IN REGISTER 14.                    * 01310022
*                                                                     * 01330022
*                                                                     * 01350000
* TABLES/WORKAREAS - AMWA (ACCESS METHOD WORKAREA)                    * 01400022
*                                                                     * 01420022
*                                                                     * 01450000
* ATTRIBUTES: REENTRANT, REFRESHABLE, PROBLEM PROGRAM MODE            * 01500000
* CHARACTER CODE DEPENDENCY - NONE                                    * 01504022
*                                                                     * 01508022
*                                                                     * 01512022
* NOTES - NONE                                                        * 01516022
*                                                                     * 01520022
*                                                                     * 01524022
* CHARACTER CODE DEPENDENCY -- THE OPERATION OF THIS MODULE DOES NOT  * 01528022
*    DEPEND UPON AN INTERNAL REPRESENTATION OF THE EXTERNAL CHARACTER * 01532022
*    SET.                                                             * 01536022
*                                                                     * 01540022
*********************************************************************** 01550000
         EJECT                                                          01600022
RPARM0   EQU   0                        PARAMETER REGISTER              01650022
RPARM1   EQU   1                        PARAMETER REGISTER              01690022
RWORK    EQU   2                        WORK REGISTER                   01730022
RWORK1   EQU   3                        WORK REGISTER                   01770022
RLCB     EQU   4                        LCB BASE REGISTER               01810022
RAVT     EQU   5                        AVT BASE REGISTER               01850022
RTERM    EQU   6                        PROCESS ENTRY BASE              01890022
RAMWA    EQU   8                        ACCESS METHOD WORKAREA BASE     01930022
RDEB     EQU   9                        DEB BASE REGISTER               01970022
RDCB     EQU   10                       DCB BASE REGISTER               02010022
RBASE    EQU   12                       MODULE BASE REGISTER            02050022
RSAVE    EQU   13                       SAVEAREA BASE REGISTER          02090022
RETURN   EQU   14                       RETURN ADDRESS                  02130022
RENTRY   EQU   15                       ENTRY POINT ADDRESS             02170022
NODEB    EQU   8                        DCB NOT OPEN FOR TCAM           02210022
NOTACT   EQU   4                        AVT NOT ACTIVE                  02250022
RECDEL   EQU   X'80'                    RECDEL=YES                      02290022
DTS      EQU   X'20'                    DTSAREA SPECIFIED               02330022
ID       EQU   X'C0'                    TCAM DEB INDICATOR              02370022
CVTPTR   EQU   16                       CVT ADDRESS                     02410022
         EJECT                                                          02450022
         USING IEDQB2,RBASE             MODULE ADDRESSABILITY           02490022
         USING IEDQDEB,RDEB             DEB    ADDRESSABILITY           02530022
         USING IHADCB,RDCB              DCB    ADDRESSABILITY           02570022
         USING IEDQWRKA,RAMWA           AMWA   ADDRESSABILITY           02610022
         SAVE  (2,12)                   SAVE CALLER'S REGISTERS SA52997 02630022
         LR    RBASE,RENTRY             GET ENTRY ADDRESS               02650022
IEDQB2   IEDHJN   IDPASS                ID,DATE                         02690022
         LR    RWORK,RPARM0            GET OPTIONS                      02800000
         LR    RDCB,RPARM0             GET DCB ADDRESS                  02850000
         LA    RDCB,0(RDCB)            CLEAR HIGH ORDER BYTE            02900000
         SRL   RWORK,24                OPTIONS ONLY                     02950000
         L     RDEB,DCBDEBAD           GET DEB ADDRESS                  03000000
         L     RAMWA,DEBTAMWA-1        GET ACCESSM METHOD WORKAREA      03050000
         L     RWORK1,CVTPTR           GET CVT ADDRESS                  03100000
         L     RAVT,AVTCVTPT(RWORK1)   GET PTR TO AVT ADDRESS           03150000
         LTR   RAVT,RAVT               AVT ACTIVE                       03200000
         BZ    ERR1                    NO,GET OUT                       03250000
         SPACE 2                                                        03300000
         TM    DEBTAMID,ID             TCAM DEB                         03350000
         BNO   ERR2                    NO, GET OUT                      03400000
         SPACE 2                                                        03450000
         STC   RWORK,GWASAVA           SAVE OPTION                      03500000
         TM    GWASAVA,DTS              DTSAREA SPECIFIED               03550000
         BZ    NODTSARE                 NO                              03600022
         SPACE 2                                                        03650000
         ST    RPARM1,GWADTSA-1         SAVE DTSAREA             S22025 03700022
NODTSARE EQU   *                        DTSAREA SET                     03750022
         NI    GWAOPT2,X'FF'-GWADLTE    RESET DELETE             S22025 03770022
         TM    GWASAVA,GWADLTE         DELETE=YES SPECIFIED      S21101 03800000
         BZ    NODEL                   NO                               03850000
         SPACE 2                                                        03900000
         OI    GWAOPT2,GWADLTE          INDICATE DELETE SPEC     S22025 03950022
NODEL    EQU   *                        DELETE SET                      04000022
         SR    RPARM1,RPARM1            CLEAR                           04050022
         TM    GWASAVA,RECDEL          RECDEL=YES SPECIFIED             04100000
         BZ    NOREC                   NO                               04150000
         SPACE 2                                                        04200000
         L     RTERM,PWAPEWA            GET PROCESS ENTRY WORK AREA     04250000
         L     RTERM,PEWAPROC-IEDQPEWA(0,RTERM) PROCESS ENTRY           04300000
         IC    RPARM1,TRMCHCIN-IEDQTRM(0,RTERM) GET RECORD DELIMITER    04350000
NOREC    SR    RENTRY,RENTRY           ZERO RETURN CODE                 04400000
DONE     EQU   *                        PROCESSING COMPLETE             04450022
         RETURN  (2,12),T,RC=(15)                                       04500000
ERR1     LA    RENTRY,NOTACT           AVT NOT ACTIVE                   04550000
         B     DONE                     GET OUT                         04600022
ERR2     LA    RENTRY,NODEB            NOT TCAM DEB                     04650000
         B     DONE                     GET OUT                         04700022
         EJECT                                                          04800022
         TAVTD                                                          05100000
         DCBD  DSORG=TX                                                 05150022
         TACSMD                                                         05200000
         TDEBAPD                                                        05250000
         TTRMD                                                          05300000
         TPEWAD                                                         05350000
         END                                                            05400000
