         TITLE 'IEDQB3 - AUTOMATIC DATE/TIME INSERTION ROUTINE'         00100022
IEDQB3   CSECT                                                          00300022
* CHANGE ACTIVITY = AS FOLLOWS:                                         00300122
*D213400-214600,705000-726000                                   SA56226 00300222
*C215400                                                        SA56226 00300322
*********************************************************************** 00600022
*                                                                     * 00900022
* MODULE-NAME = IEDQB3                                                * 00920022
*                                                                     * 00940022
* DESCRIPTIVE-NAME = AUTOMATIC DATE/TIME INSERTION ROUTINE            * 00960022
*                                                                     * 00980022
* COPYRIGHT = 'NONE'                                                  * 01000022
*                                                                     * 01020022
* STATUS - CHANGE LEVEL=00                                            * 01100022
*                                                                     * 01300022
*                                                                     * 01500022
* FUNCTION - THIS ROUTINE EXPANDS A HEADER BUFFER AND INSERTS THE     * 01700022
*    DATE AND TIME.  THIS FUNCTION IS PERFORMED ONLY FOR TPROCESS     * 01900022
*    ENTRIES THAT SPECIFY DATE=YES.  IT ALSO REQUIRES THAT DATE=YES   * 02100022
*    BE CODED ON THE ASSOCIATED PCB MACRO.                            * 02300022
*                                                                     * 02500022
*                                                                     * 02700022
* ENTRY POINTS - IEDQB3                                               * 02900022
*                                                                     * 03100022
*                                                                     * 03300022
* INPUT - REGISTER  3 HAS THE SCB ADDRESS                             * 03500022
*         REGISTER  4 HAS THE LCB ADDRESS                             * 03700022
*         REGISTER  9 HAS THE AVT ADDRESS                             * 03900022
*         REGISTER  6 HAS THE BUFFER ADDRESS                          * 04100022
*         REGISTER 13 HAS A SAVEAREA ADDRESS                          * 04300022
*         REGISTER 14 HAS A RETURN ADDRESS                            * 04500022
*         REGISTER 15 HAS THE ENTRY POINT ADDRESS                     * 04700022
*                                                                     * 04900022
*                                                                     * 05100022
* OUTPUT - NONE                                                       * 05300022
*                                                                     * 05500022
*                                                                     * 05700022
* EXTERNAL REFERENCES - AVT,SCB,LCB,BUFFER,BUFFER POOL                * 05900022
*                                                                     * 06100022
*                                                                     * 06300022
* EXITS,NORMAL - RETURN TO ADDRESS IN REGISTER 14                     * 06500022
*                                                                     * 06700022
* EXITS,ERROR - NONE                                                  * 06900022
*                                                                     * 07100022
*                                                                     * 07300022
* TABLES/WORKAREAS - AVTDOUBL                                         * 07500022
*                                                                     * 07700022
*                                                                     * 07900022
* ATTRIBUTES - SERIALLY REUSABLE, REFRESHABLE, ENABLED, RESIDENT,     * 08100022
*    PROBLEM PROBLEM MODE                                             * 08300022
*                                                                     * 08500022
*                                                                     * 08700022
* CHARACTER CODE DEPENDENCIES - THE OPERATION OF THIS MODULE HAS      * 08900022
*    NO CHARACTER CODE DEPENDENCIES.                                  * 09100022
*                                                                     * 09300022
* NOTES - NONE                                                        * 09500022
*                                                                     * 11100022
*********************************************************************** 11400022
         EJECT                                                          11600022
R0       EQU   0                        WORK REGISTER                   11800022
R1       EQU   1                        INPUT REGISTER                  12000022
RWORK2   EQU   2                        WORK REGISTER                   12200022
RSCB     EQU   3                        SCB BASE                        12400022
RLCB     EQU   4                        LCB BASE                        12600022
RWORK3   EQU   5                        WORK REGISTER                   12800022
RPREFIX  EQU   6                        BUFFER BASE REGISTER            13000022
RWORK4   EQU   7                        WORK REGISTER                   13200022
RBUF     EQU   8                        BUFFER POINTER                  13400022
RAVT     EQU   9                        AVT BASE REGISTER               13600022
RWORK    EQU   10                       WORK REGISTER                   13800022
RWORK1   EQU   11                       WORK REGISTER                   14000022
RBASE    EQU   12                       MODULE BASE REGISTER            14200022
RSAVE    EQU   13                       SAVEAREA BASE REGISTER          14400022
RETURN   EQU   14                       RETURN REGISTER                 14600022
RTO      EQU   14                       WORK REGISTER                   14800022
RENTRY   EQU   15                       ENTRY POINT REGISTER            15000022
RFROM    EQU   15                       WORK REGISTER                   15200022
OFF1     EQU   1                        OFFSET OF 1                     15400022
OFF5     EQU   5                        OFFSET OF 5                     15600022
OFF8     EQU   8                        OFFSET OF 8                     15800022
ROFF     EQU   12                       OFFSET OF 12                    16000022
         EJECT                                                          16200022
         USING IEDQB3,RBASE             ADDRESSABILITY                  16400022
         USING IEDQSCB,RSCB             SCB ADDRESSABILITY              16600022
         USING IEDQLCB,RLCB             LCB ADDRESSABILITY              16800022
         USING IEDQPRF,RPREFIX          BUFFER ADDRESSABILITY           17000022
         USING IEDQAVTD,RAVT            AVT ADDRESSABILITY              17200022
         STM   RETURN,RBASE,ROFF(RSAVE) SAVE REGISTERS                  17400022
         LR    RBASE,RENTRY             GET ENTRY ADDRESS               17600022
         B     START                    BEGIN                           17800022
IEDQB3   IEDHJN                                                         19900022
START    DS    0H                                                       20300022
BEGIN    EQU   *                                                        21500022
         OI    SCBBSCFM,SCBDATEN        SET DATE INSERTED       SA56226 21540022
         SR    RBUF,RBUF                CLEAR REG                       21600022
         SR    RWORK,RWORK              CLEAR FOR DIVIDE                21900022
         SPACE 2                                                        22000022
*********************************************************************** 22100022
* THIS SECTION DIVIDES PRFSIZE BY KEYLENGTH TO DETERMINE THE NUMBER     22200022
* OF FULL UNOTS AND THE AMOUNT OF DATA IN THE PARTIALLY FILLED UNIT,    22500022
* IF THERE IS ONE.                                                      22800022
*********************************************************************** 22900022
         SPACE 2                                                        23000022
         LH    RWORK1,PRFSIZE           GET AMOUNT OF DATA              23100022
         N     RWORK1,AVTCLRHI          ASSURE POSITIVE VLAUE           23400022
         LH   RWORK2,AVTKEYLE           GET UNIT SIZE                   23700022
         N     RWORK2,AVTCLRHI         AASSURE POSITIVE                 24000022
         DR    RWORK,RWORK2             DIVIDE PRFSIZE BY INIT          24300022
         ST    RWORK1,AVTDOUBL          SAVE NO UNITS FILLED            24600022
         ST    RWORK,AVTDOUBL+4         SAVE NO BYTES IN PARTIAL       -24900022
                                         UNIT, IF ANY                   25200022
         SR    RWORK2,RWORK2            CLEAR FOR COMPARE               25500022
         IC    RWORK2,PRFNBUNT          GET NO UNITS IN BUFFER          25800022
         LTR  RWORK,RWORK               IS THERE A PARTIAL UNIT         26100022
         BZ    UNITFULL                 NO,ALL FULL                     26400022
         SPACE                                                          26700022
         LA    RWORK,OFF8(RWORK)        ADD FOR DATE/TIME               27000022
         CH    RWORK,AVTKEYLE           WILL DATE/TIME FIT IN           27300022
         BNH   WILLFIT                  YES, GO GET DATE/TIME           27600022
         SPACE                                                          27900022
         LA    RWORK1,OFF1(RWORK1)      GET TOTAL NO UNITS THAT        -28200022
                                         CONTAIN DATA                   28500022
         SPACE 2                                                        28600022
*********************************************************************** 28700022
* AT THIS POINT, THERE IS NOT A PARTIALLY FILLED UNIT THAT WILL         28800022
* CONTAIN THE 8 BYTES OF DATE/TIME.  THIS SECTION CHECKS TO SEE IF      29100022
* THERE ARE UNUSED UNITS AT THE END OF THE BUFFER.                      29400022
*********************************************************************** 29500022
         SPACE 2                                                        29600022
UNITFULL EQU   *                                                        29700022
         CR    RWORK1,RWORK2            IS THERE AN EMPTY UNIT         -30000022
                                         ALREADY IN THE BUFFER          30300022
         BL    WILLFIT                  YES, DON'T GET ANOTHER          30600022
         SPACE 2                                                        30700022
*********************************************************************** 30800022
         SPACE                                                          30900022
* THIS SECTION GETS A UNIT FROM TCAM'S BUFFER POLL (IF AVAILABLE).      31200022
*********************************************************************** 31300022
         SPACE 2                                                        31400022
         L     RBUF,AVTBFREB            FIRST UNIT IN POOL              31500022
         LA    RBUF,AVTEZERO(RBUF)      CLEAR GARBAGE                   31800022
         LTR   RBUF,RBUF                POOL EMPTY                      32100022
         BZ    ALLDONE                 YES, CAN'T DO FUNCTION           32400022
         SPACE                                                          32700022
         MVC   AVTBFREB+1(3),OFF5(RBUF) DELINK UNIT                     33000022
         XC    OFF5(3,RBUF),OFF5(RBUF)  CLEAR LINK FIELD                33300022
         LH    RWORK1,AVTAVFCT          GET AVAILABLE UNIT COUNT        33600022
         BCTR  RWORK1,AVTEZERO          SUBTRACT ONE                    33900022
         STH   RWORK1,AVTAVFCT          RESTORE UNIT COUNT              34200022
         SPACE 2                                                        34300022
*********************************************************************** 34400022
* AT THIS POINT, WE KNOW WE HAVE ENOUGH SPACE IN THE BUFFER.  A BACK    34500022
* CHAIN IS SETUP SO THAT EACH UNIT POINTS TO THE PREVIOUS ONE AS        34800022
* WELL AS THE NEXT ONE.  IF A NEW UNIT WAS GOTTEN, IT IS CHAINED IN     35100022
* AND PRFNBUNT IS BUMPED.                                               35400022
*********************************************************************** 35500022
         SPACE 2                                                        35600022
WILLFIT  EQU  *                                                         35700022
         LR    RFROM,RPREFIX            POINT TO FIRST UNIT             36000022
         BCTR  RWORK2,AVTEZERO          SUBTRACT ONE FROM UNITS         36300022
         CLI   PRFNBUNT,OFF1            IS THERE ONLY ONE UNIT          36600022
         BE    ONEUNIT                  YES, NO CHAINING NEEDED         36900022
         SPACE                                                          37200022
LOOP     EQU   *                                                        37500022
         L     RTO,PRFTIC-IEDQPRF(,RFROM) GET ADDRESS OF NEST UNIT      37800022
         ST    RFROM,PRFLINK-1-IEDQPRF(,RTO) SET BACK CHAIN             38100022
         LR    RFROM,RTO                GO TO NEXT UNIT                 38400022
         BCT   RWORK2,LOOP              CONTINE CHAIN                   38700022
ONEUNIT  EQU   *                                                        39000022
         LTR   RBUF,RBUF                DID I GET A UNIT                39300022
         BZ    SHIFT                    NO, READY TO SHIFT DATA         39600022
         SPACE                                                          39900022
         ST    RBUF,PRFTIC-IEDQPRF(RFROM) POINT TO LAST TO NEW          40200022
         OI    PRFTIC-IEDQPRF(RFROM),OFF8 SET ON THE TIC                40500022
         ST    RFROM,PRFLINK-1-IEDQPRF(,RBUF)  SET BACK CHAIN           40800022
         LA    RWORK2,2                                                 41100022
         ST    RWORK2,PRFTIC-IEDQPRF(,RBUF)                             41400022
         OI    PRFTIC-IEDQPRF(RBUF),OFF8                                41700022
         IC    RWORK2,PRFNBUNT          GET ORIGINAL COUNT              42000022
         LA    RWORK2,OFF1(RWORK2)     ADD FOR NEW UNIT                 42300022
         STC   RWORK2,PRFNBUNT          STORE NEW COUNT                 42600022
         SPACE 2                                                        42700022
*********************************************************************** 42800022
* NOW WE MUST FIND THE LENGTH TO BE MOVED AND THE TO AND FROM POINTS.   42900022
*********************************************************************** 43000022
         SPACE 2                                                        43100022
SHIFT    EQU   *                                                        43200022
         LR    RFROM,RPREFIX           GET FIRST UNIT                   43500022
         LH    RWORK,PRFSIZE            GET TOTAL SIZE                  43800022
         N     RWORK,AVTCLRHI           CLEAR  HALF                     44100022
LOOP1    EQU   *                                                        44400022
         CH    RWORK,AVTKEYLE           LESS THAN A UNIT                44700022
         BNH   GOTFROM                  YES, THIS IS FROM UNIT          45000022
         SPACE                                                          45300022
         L     RFROM,PRFTIC-IEDQPRF(,RFROM) GET NEXT UNIT               45600022
         SH    RWORK,AVTKEYLE           ADJUST SIZE                     45900022
         B     LOOP1                    TRY NEXT                        46200022
         SPACE                                                          46500022
GOTFROM  EQU   *                                                        46800022
         LR    RWORK1,RFROM             RWORK=ADDRESS OF 'FROM' UNIT    47100022
         LA    RBUF,ROFF(,RWORK1)       RBUF=ADDRESS OF DATA            47400022
         CR    RWORK1,RPREFIX           FIRST UNIT                      47700022
         BNE   NOTFIRST                 NO, IGNORE HEADER FOR NOW       48000022
         SPACE                                                          48300022
         LA    RBUF,AVTHDRSZ(,RBUF)     BUMP PAST HDR PREFIX            48600022
NOTFIRST EQU   *                                                        48900022
         LA    RFROM,ROFF(RWORK,RWORK1) BUMP TO END OF DATA             49200022
         LA    RWORK,OFF8(,RWORK)       BUMP LENGTH FOR INSERT          49500022
         CH    RWORK,AVTKEYLE           WILL UNIT HOLD INSERTION        49800022
         BNH   THISONE                  YES, 'TO' AND 'FROM' SAME       50100022
         SPACE                                                          50400022
         SH    RWORK,AVTKEYLE           GET OFFSET INTO NEW UNIT        50700022
         L     RWORK2,PRFTIC-IEDQPRF(,RWORK1) GET NEW UNIT              51000022
         LA    RWORK4,ROFF(,RWORK2)     BUMP TO START OF DATA           51300022
         LA    RTO,ROFF(RWORK,RWORK2)   GET TARGET ADDRESS+1            51600022
         B     GOTTO                    PREPARE TO MOVE DATA            51900022
         SPACE                                                          52200022
THISONE EQU    *                                                        52500022
         LR    RWORK2,RWORK1            TARGET IN SAME UNIT             52800022
         LR    RWORK4,RBUF                                              53100022
         LA    RTO,OFF8(,RFROM)         BUMP 8 PAST 'FROM' BYTE         53400022
GOTTO    EQU   *                                                        53700022
         LH    RWORK,PRFSIZE            GET TOTAL LENGTH                54000022
         N     RWORK,AVTCLRHI           CLEAR GARBAGE                   54300022
         LA    RWORK3,AVTHDRSZ          GET PREFIX SIZE                 54600022
         SR    RWORK,RWORK3             ADJUST DATA SIZE                54900022
         LTR   RWORK,RWORK              ZERO LENGTH                     55200022
         BZ    ALLDONE                  NO DATA                         55500022
         SPACE                                                          55800022
MOVEL    EQU   *                                                        56100022
         BCTR  RFROM,AVTEZERO           BACK UP TO BYTE                 56400022
         BCTR RTO,AVTEZERO              BACK UP TO TARGET               56700022
         MVC   0(1,RTO),0(RFROM)        MOVE DATA                       57000022
         CR    RFROM,RBUF               END OF 'FROM' UNIT              57300022
         BNE   FROMOK                   NO, CONTINUE                    57600022
         SPACE                                                          57900022
         CR    RWORK1,RPREFIX           FIRST UNIT                      58200022
         BE    SHIFTED                  YES, THAT'S ALL                 58500022
         SPACE                                                          58800022
         L     RWORK1,PRFLINK-1-IEDQPRF(,RWORK1)                        59100022
         LA    RBUF,ROFF(,RWORK1)       GET DATA START                  59400022
         CR    RWORK1,RPREFIX           FIRST UNIT                      59700022
         BNE   NOPRF                    NO, IGNORE PREFIX               60000022
         SPACE                                                          60300022
         LA    RBUF,AVTHDRSZ(,RBUF)     BUMP PAST HDR                   60600022
NOPRF    EQU   *                                                        60900022
         LH    RFROM,AVTKEYLE           GET UNIT SIZE                   61200022
         N     RFROM,AVTCLRHI           CLEAR HALF                      61500022
         LA    RFROM,ROFF(RWORK1,RFROM) GO TO END OF UNIT               61800022
FROMOK   EQU   *                                                        62100022
         CR    RTO,RWORK4               END OF TARGET UNIT              62400022
         BNE   TOOK                     NO, CONTINUE                    62700022
         SPACE                                                          63000022
         L     RWORK2,PRFLINK-1-IEDQPRF(,RWORK2) GET PREVIOUS           63300022
         LA    RWORK4,ROFF(,RWORK2)     START OF DATA                   63600022
* IF THIS IS THE FIRST UNIT, RFROM SHOULD TERMINATE THE LOOP            63900022
         LH    RTO,AVTKEYLE             GET UNIT SIZE                   64200022
         N     RTO,AVTCLRHI             CLEAR                           64500022
         LA    RTO,ROFF(RWORK2,RTO)     GO TO END OF NEW UNIT           64800022
TOOK     EQU   *                                                        65100022
         BCT   RWORK,MOVEL              GET NEXT BYTE                   65400022
         SPACE                                                          65700022
SHIFTED  EQU   *                                                        66000022
         TIME  DEC                                                      66300022
         ST    R1,AVTDOUBL              SAVE DATE                       66600022
         ST    R0,AVTDOUBL+4            SAVE TIME                       66900022
         LR    RTO,RPREFIX              GET BUFFER                      67200022
         LA    RTO,ROFF(,RTO)          BUMP PAST  CCW                   67500022
         LA    RTO,AVTHDRSZ(,RTO)      BUMP PAST HDR                    67800022
         LH    RWORK,PRFSCAN            GET SCAN                        68100022
         N     RWORK,AVTCLRHI           CLEAR                           68400022
         LA    RWORK,OFF8(RWORK)        ADD FOR DATE/TIME               68700022
         STH   RWORK,PRFSCAN            STORE NEW SCAN PTR              69000022
         LH    RWORK,PRFSIZE            GET AMOUNT OF DATA              69300022
         N     RWORK,AVTCLRHI           CLEAR                           69600022
         LA    RWORK,OFF8(RWORK)        ADJUST FOR DATE/TIME            69900022
         STH   RWORK,PRFSIZE            STORE NEW SIZE                  70200022
COPY     EQU   *                                                        72700022
         L     RWORK,SCBDEOB            GET EOB BUFFER ADDRESS          72900022
         LA    RWORK,AVTEZERO(,RWORK)   CLEAR                           73200022
         CR    RWORK,RPREFIX            THIS ONE                        73500022
         BNE   NOTDEOB                  NO, IGNORE OFFSET               73800022
         SPACE                                                          74100022
         LH    RWORK,SCBEOB             GET EOB OFFSET                  74400022
         N     RWORK,AVTCLRHI           CLEAR                           74700022
         LA    RWORK,OFF8(RWORK)        ADJUST FOR DATE/TIME            75000022
         STH   RWORK,SCBEOB             STORE NEW EOB OFFSET            75300022
NOTDEOB  EQU   *                                                        75600022
         SR    RWORK,RWORK              CLEAR                           75900022
         IC    RWORK,LCBISZE            GET NO RESERVES                 76200022
         AR    RTO,RWORK                BUMP PAST                       76500022
         MVC   0(8,RTO),AVTDOUBL        INSERT DATE/TIME                76800022
ALLDONE EQU    *                                                        77100022
         LM    RETURN,RBASE,ROFF(RSAVE) RESTORE GEGISTERS               77400022
         BR    RETURN                   RETURN TO CALLER                77600022
         EJECT                                                          77800022
         TSCBD                                                          78000022
         TLCBD                                                          78300022
         TPRFD                                                          78600022
         TAVTD                                                          78900022
         END                                                            79200022
