         TITLE 'IEDQB7 - MULTIPLE ROUTE CHECK ROUTINE'                  00400052
IEDQB7   CSECT                                                          00800052
         SPACE                                                          01200052
         ENTRY IEDQB701                                                 01600052
*********************************************************************** 02000052
*                                                                     * 02400052
* MODULE NAME = IEDQB7                                                * 02800052
*                                                                     * 03200052
* DESCRIPTIVE NAME = MULTIPLE ROUTE CHECK ROUTINE                     * 03600052
*                                                                     * 04000052
* COPYRIGHT = 'NONE'                                                  * 04400052
*                                                                     * 04800052
* STATUS -- CHANGE LEVEL 0                                            * 05200052
*                                                                     * 05600052
* FUNCTION -- THIS ROUTINE PROVIDES A TECHNIQUE TO ALERT THE USER     * 06000052
*    THAT A MULTIROUTE FUNCTION IS IN PROGRESS.  THIS MODULE GAINS    * 06400052
*    CONTROL WHEN A MRCHECK MACRO IS CODED IN THE INMSG SUBGROUP OF   * 06800052
*    THE MH.  THIS MODULE EXECUTES ONLY IF 1) CHECKPOINT IS IN THE    * 07200052
*    SYSTEM, AND 2) EITHER A MULTIROUTE OR DLIST FUNCTION HAS BEEN    * 07600052
*    REQUESTED.  THE USER MUST HAVE SPECIFIED AN OPTION FIELD FOR THE * 08000052
*    SOURCE TERMINAL.  UPON ENTRY TO MODULE FROM IEDQBD, THE PREVIOUS * 08400052
*    TWO CONDITIONS ARE CHECKED.  IF THE EOM BUFFER HAS ALREADY BEEN  * 08800052
*    QUEUED, THE OPTION FIELD IS FLAGGED WITH THE INPUT SEQUENCE NUMBER 09200052
*    AND A X'02' INDICATING A RECEIVE OPERATION.  AN INCIDENT         * 09600052
*    CHECKPOINT IS TAKEN OF THE OPTION FIELDS FOR CURRENT TERMINAL    * 10000052
*    ENTRY.  IF THE EOM BUFFER HAS NOT BEEN QUEUED THEN THE POST LIST * 10400052
*    IS POSTED TO AN INTERNAL QCB.  WHEN THE LCB IS POSTED BACK TO    * 10800052
*    AN INTERNAL QCB.  WHEN THE LCB IS POSTED BACK TO THIS MODULE     * 11200052
*    FROM CHECKPOINT, TWO FLAGS, SCBCKPT AND SCBPRER ARE TURNED.      * 11600052
*    SCBCKPT IS SET TO INDICATE TO BD THAT A CHECKPOINT IS TO BE TAKEN* 12000052
*    AFTER MULTIROUTE OR DLIST HAVE COMPLETED.  SCBPRER IS SET TO     * 12400052
*    INDICATE THAT THE MRCHECK FUNCTION IS EFFECT AND THAT THE        * 12800052
*    MULTIROUTE AND DLIST MODULES SHOULD CLEAR OUT THE OPTION FIELD   * 13200052
*    BEFORE THE CHECKPOINT IS TAKEN.                                  * 13600052
*                                                                     * 14000052
* ENTRY POINTS --                                                     * 14400052
*    IEDQB7 TO PROCESS A BUFFER FROM IEDQBD                           * 14800052
*    IEDQB701 TO PROCESS ELEMENTS                                     * 15200052
*                                                                     * 15600052
* INPUT --                                                            * 16000052
*    REGISTER 1 - ADDRESS OF A POST LIST                              * 16400052
*                 LCB FROM CHECKPOINT                                 * 16800052
*                 ERB WHEN WAITING FOR EOM BUFFER TO BE QUEUED        * 17200052
*    REGISTER 11 - ADDRESS OF DISPATCHER                              * 17600052
*    REGISTER 13 - ADDRESS OF AVTSAVE2                                * 18000052
*                                                                     * 18400052
* OUTPUT --                                                           * 18800052
*    OPTION FIELDS CHECKPOINTED AND SCBCKPT FLAG SET FOR ANOTHER      * 19200052
*    CHECKPOINT.                                                      * 19600052
*                                                                     * 20000052
* EXTERNAL REFERENCES -- NONE                                         * 20400052
*                                                                     * 20800052
* EXITS,NORMAL -- DISPATCHER AT ENTRY POINT DSPCHAIN                  * 21200052
*                                                                     * 21600052
* EXITS,ERROR -- NONE                                                 * 22000052
*                                                                     * 22400052
* TABLES/WORKAREAS -- AVT, LCB, SCB, TERMINAL TABLE, TERMNAME TABLE   * 22800052
*                                                                     * 23200052
* ATTRIBUTES -- REENTRANT, REFRESHABLE, ENABLED, RESIDENT, PROBLEM    * 23600052
*    PROGRAM MODE.                                                    * 24000052
*                                                                     * 24400052
* NOTES -- THE OPERATION OF THIS MODULE DOES NOT DEPEND UPON A        * 24800052
*    PARTICULAR INTERNAL REPRESENTATION OF THE EXTERNAL CHARACTER SET.* 25200052
*                                                                     * 25600052
*********************************************************************** 26000052
         EJECT                                                          26400052
************************* REGISTER EQUATES **************************** 26800052
         SPACE                                                          27200052
R0       EQU   0                                                        27600052
R1       EQU   1                        PARAMETER REG                   28000052
R2       EQU   2                                                        28400052
RSCB     EQU   3                        ADDRESS OF SCB                  28800052
RLCB     EQU   4                        ADDRESS OF LCB                  29200052
RTERM    EQU   5                        ADDRESS OF TERMINAL ENTRY       29600052
RPREFIX  EQU   6                        ADDRESS OF BUFFER               30000052
R7       EQU   7                        WORK REGISTER                   30400052
R8       EQU   8                        WORK REGISTER                   30800052
R9       EQU   9                        WORK REG                        31200052
R10      EQU   10                       WORK REGISTER                   31600052
R11      EQU   11                       ADDRESS OF DISPATCHER           32000052
R12      EQU   12                       BASE REGISTER                   32400052
R13      EQU   13                                                       32800052
R14      EQU   14                                                       33200052
R15      EQU   15                                                       33600052
         SPACE 3                                                        34000052
************************* OTHER EQUATES ******************************* 34400052
         SPACE                                                          34800052
THREE    EQU   3                                                        35200052
X08      EQU   X'08'                                                    35600052
FOUR     EQU   4                                                        36000052
TWO      EQU   2                                                        36400052
X02      EQU   X'02'                                                    36800052
ONE      EQU   1                                                        37200052
         SPACE                                                          37600052
         USING AVTSAVE2,R13                                             38000052
         USING IEDQDISP,R11             DISPATCHER BASE                 38400052
         USING IEDQLCB,RLCB             LCB BASE                        38800052
         USING IEDQSCB,RSCB             SCB BASE                        39200052
         USING IEDQPRF,RPREFIX          PREFIX BASE                     39600052
         SPACE                                                          40000052
         USING *,R12                                                    40400052
         SPACE                                                          40800052
IEDQB7   IEDHJN QB7VTO                                                  41200052
         ST    R1,LCBERBLK-ONE          POST LIST SET UP                41600052
         NC    AVTCKGET,AVTCKGET        IS CHECKPOINT IN SYSTEM         42000052
         BZ    RETURN1                  NO                              42400052
         SPACE                                                          42800052
CONTMH   EQU   *                                                        43200052
         SR    R7,R7                    CLEAR REGISTER                  43600052
         L     RSCB,LCBSCBA-ONE         SET UP LCB                      44000052
         C     R7,SCBMRFSD              IS MULTIROUTE OR DLIST          44400052
         BE    RETURN1                  NO                              44800052
         SPACE                                                          45200052
CKPSTLST EQU   *                                                        45600052
         LR    RPREFIX,R1               SET UP REG 6                    46000052
         LH    R1,LCBTTCIN              PICK UP SOURCE OFFSET           46400052
         N     R1,AVTCLRHI              CLEAR HIGH BYTES                46800052
         BZ    RETURN1                  NO SOURCE                       47200052
         L     R15,AVTRNMPT             ADDR OF TNT CODE                47600052
         BALR  R14,R15                  LINK TO TNT CODE                48000052
         SPACE                                                          48400052
         LR    RTERM,R1                 SET UP TERMINAL ENTRY           48800052
         USING IEDQTRM,RTERM                                            49200052
         SR    R8,R8                    CLEAR REG                       49600052
         CLI   TRMOPNO,AVTEZERO         ANY OPTIONS SPECIFIED           50000052
         BE    RETURN1                  NO                              50400052
         SPACE                                                          50800052
         L     R7,AVTOPTPT              ADDR OF OPTION TABLE            51200052
         LR    R10,R8                   INDEX TO OPTION TABLE           51600052
         IC    R10,TRMOPT(R10)          OFFSET                          52000052
         IC    R8,AVTHFF+ONE            TO COMPARE WITH OFFSET          52400052
         CR    R10,R8                   IS FIRST OPTION FIELD SPECIFIED 52800052
         BE    RETURN1                  NO                              53200052
         SPACE                                                          53600052
         L     R9,FOUR(R7)              OPTION FIELD LOOKUP             54000052
         CLI   AVTEZERO(R9),X02         IS OPTION FIELD 3 BYTES LONG    54400052
         BNE   RETURN1                  NO                              54800052
         SPACE                                                          55200052
         TM    SCBSTATE,SCBSEQIN        HAS SEQUENCE IN BEEN EXECUTED   55600052
         BZ    RETURN1                  NO                              56000052
         SPACE                                                          56400052
         LH    R9,TRMINSEQ              INPUT SEQUENCE NO               56800052
         BCTR  R9,AVTEZERO              DECREMENT SEQ NO                57200052
         LTR   R9,R9                    IS IT ZERO                      57600052
         BZ    RETURN1                  YES                             58000052
         SPACE                                                          58400052
         AH    R7,TRMOPTBL              OPTIONS FOR THIS TERMINAL ENTRY 58800052
         AR    R7,R10                   ADDR OF OPTION FIELD            59200052
         STH   R9,AVTDOUBL              STORE IN TEMPORARY AREA         59600052
         MVC   AVTEZERO(TWO,R7),AVTDOUBL PUT SEQ NO IN OPTION FIELD     60000052
         MVI   X02(R7),X02              SET RECEIVE STATUS              60400052
         LTR   RPREFIX,RPREFIX          ANY ELEMENTS IN LIST            60800052
         BZ    BFRTHERE                 NO                              61200052
         SPACE                                                          61600052
POSTLIST EQU   *                                                        62000052
         LA    R2,IEDQB701              SET QCB ADDRESS FOR 2ND ENTRY   62200000
         B     COMM1                    POST TO DISPATCHER              62400052
         SPACE                                                          62800052
CKNEXT   EQU   *                                                        63200052
SETLIST  EQU   *                                                        64000052
BFRTHERE EQU   *                                                        64400052
         OI    SCBSTATE,SCBCKPT         CHECKPOINT THIS                 64800052
         OI    SCBSTATE,SCBPRER         OPTION FIELD FIRST ONE          65200052
         MVC   LCBRCQCB,LCBQCBA         SAVE QCB ADDRESS                65600052
         LA    R8,IEDQB701              QCB ADDRESS                     66000052
         ST    R8,LCBQCBA-ONE           STORE IN LCB                    66400052
         MVI   LCBPRI,PRIDESTQ          SET UP LCB PRIORITY FOR POST    66800052
*                                       BACK FROM CHECKPOINT            67200052
         LA    R2,AVTCKPTB              CHECKPOINT QCB                  67600052
         MVI   LCBERBPY,PRICKPLN        CHECKPOINT PRIORITY             68000052
         B     COMM2                    POST TO DISPATCHER              68400052
         EJECT                                                          68800052
         DS    0F                                                       69200052
         ORG   *-8                                                      69600052
IEDQB701 EQU   *                                                        70000052
         ORG                                                            70400052
         DC    AL1(DSPMCPL4)            SUBTASK ENTRY CODE              70800052
         DC    AL3(*-1)                 STCB ADDRESS                    71200052
         SPACE 3                                                        71600052
         USING *,R15                                                    72000052
         L     R12,BASE                 SET UP BASE REGISTER            72400052
         DROP  R15                                                      72800052
         USING IEDQB7,R12                                               73200052
         LR    RLCB,R1                  SET UP LCB POINTER              73600052
         SR    R1,R1                    CLEAR REGISTER                  74000052
         CLI   LCBPRI,PRIRCQCB          PRIORITY FOR ERB                74400052
         BNE   CKLCB                    LCB BACK FROM CHECKPOINT        74800052
         SPACE                                                          75200052
         LA    RPREFIX,LCBERB-IEDQLCB   ERB OFFSET                      75600052
         SR    RLCB,RPREFIX             BACK UP TO LCB                  76000052
         B     QB7VTO                   START AGAIN                     76400052
         SPACE                                                          76800052
CKLCB    EQU   *                                                        77200052
RETURN   EQU   *                                                        77600052
         ST    R1,LCBERBLK-ONE          CLEAR LINK FIELD                78000052
         L     RSCB,LCBSCBA-ONE         SET UP SCB REGISTER             78400052
         MVC   LCBQCBA,LCBRCQCB         RESTORE LCB FIELD               78800052
         OI    SCBSTATE,SCBCKPT         SET CHECKPOINT FLAG FOR BD      79200052
RETURN1  EQU   *                                                        79600052
         L     R2,AVTMSGS-ONE                                           80000052
         L     R2,AVTEZERO(R2)          SET TO POST TO BD               80400052
COMM1    EQU   *                                                        80800052
         MVI   LCBERBPY,PRIRCQCB        SET PRIORITY                    81200052
COMM2    EQU   *                                                        81600052
         ST    R2,LCBERB                SET UP QCB                      82000052
         LA    R1,LCBERB                ERB ADDRESS TO POST TO BD       82400052
         B     DSPCHAIN                 EXIT TO DISPATCHER              82800052
         EJECT                                                          83200052
BASE     DC    A(IEDQB7)                BASE FOR MODULE                 83600052
         EJECT                                                          84000052
         TAVTD                                                          84400052
         EJECT                                                          84800052
         TDISPD                                                         85200052
         EJECT                                                          85600052
         DCBD  DSORG=TX                                                 86000052
         EJECT                                                          86400052
         TLCBD                                                          86800052
         EJECT                                                          87200052
         TPRFD                                                          87600052
         EJECT                                                          88000052
         TPRIOR                                                         88400052
         EJECT                                                          88800052
         TSCBD                                                          89200052
         TTRMD                                                          89600052
         EJECT                                                          90000052
         END                                                            90400052
