BA01     TITLE '''IEDQBA'' -- MULTIPLE ROUTINE SUBTASK'                 00300022
IEDQBA   CSECT                                                          00370022
         SPACE 3                                                        00380052
*CHANGE ACTIVITY=AS FOLLOWS:                                            00390052
******************** MICROFICHE FLAGS *********************** SUPT CODE 00400052
*A5941000                                                        S21903 00440052
*C167000-174000,725400                                           S21903 00440152
*A064000-065000,112000,139000                                   SA61724 00440252
*C555000-556800                                                 SA61724 00440352
         SPACE                                                          00602020
*******************************************************************   * 00604020
*                                                                     * 00606052
* MODULE NAME=IEDQBA                                                  * 00606152
*                                                                     * 00606252
* DESCRIPTIVE NAME=MULTIPLE ROUTINE SUBTASK                           * 00606352
*                                                                     * 00606452
* COPYRIGHT='NONE'                                                    * 00606552
*                                                                     * 00606652
* STATUS: CHANGE LEVEL 5                                              * 00606752
*                                                                     * 00606852
*FUNCTION --                                                          * 00610020
*   THE MULTIPLE ROUTING SUBTASK IDENTIFIES ADDITIONAL DESTINATIONS   * 00612020
*   SPECIFIED IN A BUFFER AND POSTS THE MESSAGE TO EACH OF THEM IN    * 00614020
*   ORDER.                                                            * 00616020
*                                                                     * 00618020
*   ON INITIAL ENTRY, THE ERB WITHIN THE LCB IS POSTED TO THE         * 00620020
*   MULTIPLE ROUTING SUBTASK WITH THE ADDRESS OF A RECALLED HEADER,   * 00622020
*   FIRST BUFFER ONLY, IN THE ERB CHAIN FIELD (LCBERBCH).  THE        * 00624020
*   SUBTASK COUNTS THE NUMBER OF BUFFERS PASSED (IN THIS CASE, ONE)   * 00626020
*   AND KEEPS BOTH THE ADDRESS OF THE HEADER BUFFER AND THE CURRENT   * 00628020
*   BUFFER (WHICH IN THIS CASE IS THE HEADER).  THE CURRENT BUFFER    * 00630020
*   ADDRESS IS SAVED IN THE LCB,  AND THE CURRENT COUNT IS SAVED IN   * 00632020
*   THE CURRENT BUFFER.                                               * 00634020
*                                                                     * 00636020
*   THE SUBTASK    SETS THE SCAN POINTER FROM THE FIRST-SECONDARY-    * 00638020
*   DESTINATION FIELD IN THE SCB (SCBMRFSD).  THE ADDRESS OF THE      * 00640020
*   FORWARD PARAMETER LIST IS LOADED FROM THE SCB AND THE SUBTASK     * 00642020
*   LINKS TO THE FORWARD ROUTINE.  IF A VALID DESTINATION IS          * 00644020
*   FOUND,  THE SUBTASK    TESTS IF IT IS A DISTRIBUTION LIST. IF     * 00646020
*   IT IS,  THE LCB IS SET TO POST THE MESSAGE TO EACH MEMBER OF      * 00648020
*   THE LIST BEFORE RE-ENTRY TO MULTIPLE ROUTING SUBTASK.  THE        * 00650020
*   SUBTASK THEN POSTS THE RECALLED HEADER TO THE APPROPRIATE QCB     * 00652020
*   (DISTRIBUTION LIST OR SINGLE ENTRY).                              * 00654020
*                                                                     * 00656020
*   IF AN INVALID DESTINATION HAS BEEN FOUND,  THE SUBTASK LINKS      * 00658020
*   AGAIN TO THE FORWARD ROUTINE TO FIND THE NEXT DESTINATION.        * 00660020
*                                                                     * 00662020
*   AFTER THE FIRST SECONDARY DESTINATION HAS BEEN FOUND AND A        * 00664020
*   RECALLED HEADER POSTED TO IT,  THE SUBTASK IS REENTERED WITH      * 00666020
*   ANOTHER RECALLED HEADER. THE CURRENT BUFFER ADDRESS, SAVED IN     * 00668020
*   THE LCB BEFORE THE PREVIOUS POST, IS RECOVERED.  IF THE CURRENT   * 00670020
*   BUFFER IS ITSELF A HEADER,  THE COUNT IS SET TO ONE AND THE       * 00672020
*   HEADER JUST POSTED TO THE SUBTASK IS SET AS THE CURRENT BUFFER.   * 00674020
*   OTHERWISE THE BUFFER ADDRESS RECOVERED FROM THE LCB REMAINS AS    * 00676020
*   THE CURRENT BUFFER AND THE COUNT IS RECOVERED FROM IT. THE SCAN   * 00678020
*   POINTER IS AGAIN SET FROM SCBMRFSD AND THE SUBTASK AGAIN LINKS    * 00680020
*   TO THE FORWARD ROUTINE.                                           * 00682020
*                                                                     * 00684020
*   IF RETURN FROM THE FORWARD ROUTINE INDICATES A DESTINATION        * 00686020
*   FIELD IS INCOMPLETE IN THE CURRENT BUFFER (MULTIPLE-BUFFER        * 00688020
*   HEADER), THE NEXT BUFFER MUST BE RECALLED.  AFTER THE DATA        * 00690020
*   FOUND IN THE CURRENT BUFFER IS SAVED, THE ADDRESS OF THE          * 00692020
*   HEADER, WITH ALL OTHER BUFFERS IN THE MESSAGE THAT HAVE BEEN      * 00694020
*   PASSED LINKED TO IT, IS STORED IN THE ERB.  THE CURRENT COUNT     * 00696020
*   IS INCREMENTED BY ONE AND SET IN THE ERB, AND THE ERB IS POSTED   * 00698020
*   TO THE DISK I/O QCB TO RECALL ANOTHER BUFFER.                     * 00700020
*                                                                     * 00702020
*   THE ERB IS POSTED TO THE SUBTASK WHEN ANOTHER BUFFER IS           * 00704020
*   ACCESSED.  THE SUBTASK DETERMINES THAT TWO OR MORE BUFFERS ARE    * 00706020
*   BEING PASSED (TO DISTINGUISH FROM INITIAL ENTRY),   COUNTS THE    * 00708020
*   NUMBER BEING PASSED, AND SAVES THE ADDRESS OF THE LAST BUFFER     * 00710020
*   IN THE CHAIN (WHICH IS THE NEW CURRENT BUFFER) IN THE LCB WITH    * 00712020
*   THE COUNT SAVED IN IT.  THE ADDRESS OF THE SECOND BUFFER, WITH    * 00714020
*   ANY SUBSEQUENT BUFFERS LINKED TO IT, IS ALSO SAVED IN THE LCB.    * 00716020
*   THE FIELD SCBMRFSD IS SET TO THE OFFSET TO THE FIRST DATA BYTE    * 00718020
*   IN THE CURRENT BUFFER.  THE SUBTASK THEN SETS THE SCAN POINTER    * 00720020
*   FROM SCBMRFSD AND LINKS AGAIN TO THE FORWARD ROUTINE.             * 00722020
*                                                                     * 00724020
*   IF RETURN FROM THE FORWARD ROUTINE INDICATES THAT THE EOA         * 00726020
*   STRING HAS BEEN FOUND, NO MORE DESTINATIONS ARE PRESENT. THE      * 00728020
*   LAST RECALLED HEADER IS SET TO POINT TO ANY RECALLED TEXT         * 00730020
*   BUFFERS, AND ALL BUFFERS ARE SET WITH THE ADDRESS OF THE BUFFER   * 00732020
*   RETURN QCB.  THE LCB ITSELF IS LINKED TO THE LAST BUFFER AND      * 00734020
*   SET WITH THE ADDRESS OF THE BUFFER DISPOSITION QCB. THE FIELD     * 00736020
*   SCBMRFSD IS CLEARED TO ZEROES AND THE BUFFERS AND LCB ARE         * 00738020
*   POSTED VIA AN EXIT TO THE DISPATCHER.                             * 00740020
*                                                                     * 00742020
*ENTRY POINTS --                                                      * 00744020
*       'IEDQBA01' TO POST A MESSAGE TO ADDITIONAL DESTINATIONS.      * 00746020
*   THE MULTIPLE ROUTING SUBTASK IS DISPATCHED BY THE POSTING OF      * 00748020
*   AN ERB OR A BUFFER TO THE MULTIPLE ROUTING QCB.                   * 00750020
*                                                                     * 00752020
*INPUT --                                                             * 00754020
*   REGISTER 1 -- THE ADDRESS OF THE ELEMENT POSTED.                  * 00756020
*                                                                     * 00758020
*   REGISTER 7 -- THE ADDRESS OF THE MULTIPLE ROUTING QCB.            * 00760020
*                                                                     * 00762020
*   REGISTER 11 -- THE ADDRESS OF THE DISPATCHER.                     * 00764020
*                                                                     * 00766020
*   REGISTER 13 -- THE ADDRESS OF THE SAVE AREA.                      * 00768020
*                                                                     * 00770020
*   SCB MULTIPLE ROUTING FIRST SECONDARY DESTINATION FIELD            * 00772020
*   (SCBMRFSD) -- THE OFFSET IN THE BUFFER TO THE FIRST SECONDARY     * 00774020
*   DESTINATION.                                                      * 00776020
*                                                                     * 00778020
*   SCB MULTIPLE ROUTING FORWARD PARAMETER LIST FIELD (SCBMRFPL) --   * 00780020
*   THE ADDRESS OF THE FORWARD PARAMETER LIST.                        * 00782020
*                                                                     * 00784020
*OUTPUT --                                                            * 00786020
*   SCBMRFSD -- RESET TO ZEROES                                       * 00788020
*                                                                     * 00790020
*EXTERNAL REFERENCES --                                               * 00792020
*   'IEDQA5' - FORWARD ROUTINE                                        * 00794020
*                                                                     * 00796020
*   AVT - ADDRESS VECTOR TABLE                                        * 00798020
*                                                                     * 00800020
*   BUFFERS IN THE MULTIPLY-ROUTED MESSAGE                            * 00802020
*                                                                     * 00804020
*   SCB - STATION CONTROL BLOCK                                       * 00806020
*                                                                     * 00808020
*   LCB - LINE CONTROL BLOCK                                          * 00810020
*                                                                     * 00812020
*EXITS, NORMAL -- THE MESSAGE HAS BEEN POSTED TO ALL VALID SUBSE-     * 00814020
*   QUENT DESTINATIONS.  THE SCB MULTIPLE ROUTING FIRST SECONDARY     * 00816020
*   DESTINATION FIELD (SCBMRFSD) HAS BEEN RESET TO ZEROES.            * 00818020
*                                                                     * 00820020
*EXITS, ERROR -- N/A                                                  * 00822020
*                                                                     * 00824020
*TABLES/WORK AREAS -- N/A                                             * 00826020
*                                                                     * 00828020
*ATTRIBUTES -- SERIALLY REUSABLE, REFRESHABLE, ENABLED, RESIDENT,     * 00830020
*   PROBLEM PROGRAM MODE.                                             * 00832020
*                                                                     * 00834020
*NOTES -- THE OPERATION OF THIS MODULE DOES NOT DEPEND UPON AN        * 00836020
*   INTERNAL REPRESENTATION OF THE EXTERNAL CHARACTER SET.            * 00838020
*                                                                     * 00840020
*******************************************************************   * 00842020
         EJECT                                                          00844020
********* REGISTER EQUATES *********                                    00900020
         SPACE                                                          01200020
R0       EQU   0                        WORK REGISTER                   01500020
         SPACE                                                          01800020
R1       EQU   1                        ELEMENT ADDRESS                 02100020
         SPACE                                                          02400020
RWORK2   EQU   2                        WORK REGISTER                   02700020
         SPACE                                                          03000020
RSCB3    EQU   3                        SCB ADDRESS                     03300020
         SPACE                                                          03600020
RLCB4    EQU   4                        LCB ADDRESS                     03900020
         SPACE                                                          04200020
RCT5     EQU   5                        COUNT OF BUFFERS RECALLED       04500020
RGO5     EQU   5                        INITIAL BRANCH REGISTER         04600020
         SPACE                                                          04800020
RPREFIX  EQU   6                        BUFFER ADDRESS                  05100020
         SPACE                                                          05400020
RQCB7    EQU   7                        QCB ADDRESS                     05700020
         SPACE                                                          06000020
RHDR8    EQU   8                        ADDRESS OF HEADER BUFFER        06300020
R9       EQU   9                        WORK REG                SA61724 06400052
R10      EQU   10                       WORK REG                SA61724 06500052
         SPACE                                                          06600020
RDISP11  EQU   11                       DISPATCHER ADDRESS              06900020
         SPACE                                                          07200020
RBASE    EQU   12                       BASE REGISTER                   07500020
         SPACE                                                          07800020
R13      EQU   13                       ADDRESS OF SAVE AREA            08100020
R14      EQU   14                       RETURN REGISTER                 08400020
R15      EQU   15                       LINK REGISTER                   08700020
         SPACE                                                          09000020
********* OTHER EQUATES *********                                       09300020
         SPACE                                                          09600020
ONE      EQU   1                        INCREMENT VALUE OF ONE          09900020
FOUR     EQU   4                        FULL-WORD OFFSET                10200020
SIXTH    EQU   5                        OFFSET TO SIXTH BYTE            10500020
SEVEN    EQU   7                        LENGTH OF SCB SAVE AREA         10800020
EIGHT    EQU   8                        BFR ADDR IN LCB ERB             11100020
OPLNGTH  EQU   3                        LENGTH OF OPTION FIELD  SA61724 11200052
         SPACE                                                          11400020
CHARC    EQU   C'C'                     CHARACTER 'C'                   11700020
         SPACE                                                          12000020
MBHFLAG  EQU   X'01'                    MULTIPLE-BFR-HEADER FLAG        12300020
MLTRFLAG EQU   X'02'                    MULTIPLE-ROUTE FLAG             12600020
TICOP    EQU   X'08'                    TIC OP CODE                     12900020
DISTLIST EQU   X'40'                    DISTRIBUTION LIST FLAGS         13200020
TYPEMASK EQU   X'E0'                    CLEAR FLAG FOR TRM TYPE         13500020
CLERDSET EQU   X'0F'                    CLEAR MASK FOR SCBQTYPE         13800020
X02      EQU   2                        DISPLACEMENT            SA61724 13900052
         EJECT                                                          14100020
         USING AVTSAVE2,R13                                             14400020
         USING IEDQLCB,RLCB4                                            14700020
         USING IEDQSCB,RSCB3                                            15000020
         USING IEDQPRF,RHDR8                                            15300020
         USING IEDQDISP,RDISP11                                         15600020
         USING IEDQBA01,RBASE                                           15900020
         SPACE                                                          16200020
IEDQBA01 EQU   *                                                        16500020
         DC    CL6'IEDQBA'              CONSTANT                 S21903 16700022
         DC    X'1078'                  CONSTANT                 S21903 16900022
         DC    AL1(DSPMCPL4)            CONSTANT                 S21903 17100022
         DC    AL3(*-1)                 CONSTANT                 S21903 17400022
         SPACE                                                          17700020
         LR    RBASE,RQCB7              RESET BASE                      18000020
         SPACE                                                          18300020
         LR    RHDR8,R1                 GET ELEMENT ADDRESS             18600020
         LA    RGO5,BUFFER              SET BRANCH ADDR FOR BUFFER      18700020
         L     RLCB4,PRFLCB-1           SET LCB ADDR AS IF BUFFER       18800020
         TM    PRFTIC,TICOP             BUFFER OR ERB                   18900020
         BO    SETREGS                  BUFFER, BRANCH                  19200020
         SPACE                                                          19500020
         L     RHDR8,EIGHT(,RHDR8)      NO, GET HEADER ADDRESS          19800020
         LA    RGO5,ERB                 SET BRANCH ADDR FOR ERB         19870020
         LA    RLCB4,AVTEZERO(,R1)      SET LCB ADDRESS                 19940020
         SH    RLCB4,BACKUP               FROM ERB ADDRESS              20010020
         SPACE                                                          20100020
SETREGS  EQU   *                                                        20400020
         LA    RHDR8,AVTEZERO(,RHDR8)   CLEAR HI-ORDER BYTE             20700020
         L     RSCB3,LCBSCBA-1          GET SCB ADDRESS                 20800020
         LA    R14,POSTERB              SET ERROR EXIT ADDRESS          20900020
         LTR   RHDR8,RHDR8              IS THERE A BUFFER               21000020
         BZ    CLRMRFSD                 NO, LOGICAL READ ERROR, BR      21100020
         SPACE                                                          21200020
         ST    RQCB7,LCBRCQCB           POINT LCB TO OUR QCB            21300020
         LR    RPREFIX,RHDR8            ASSUME FIRST BUFFER             21900020
         BR    RGO5                     ENTER APPROPRIATE CODE          22300020
         EJECT                                                          22800020
ERB      EQU   *                                                        23100020
         SR    RCT5,RCT5                INITIALIZE COUNT TO ZERO        23400020
         B     ERBENTER                 ENTER ERB LOOP                  23700020
         SPACE                                                          24000020
ERBLOOP  EQU   *                                                        24300020
         LR    RPREFIX,RWORK2           GET NEXT BUFFER ADDRESS         24600020
         SPACE                                                          24900020
ERBENTER EQU   *                                                        25200020
         LA    RCT5,ONE(,RCT5)          COUNT FIRST/NEXT BUFFER         25500020
         L     RWORK2,PRFLINK-1-IEDQPRF(,RPREFIX) LOAD LINK             25800020
         LA    RWORK2,AVTEZERO(,RWORK2)   FIELD OF FIRST/NEXT BFR       26100020
         LTR   RWORK2,RWORK2            IS IT ZEROES                    26400020
         BNZ   ERBLOOP                  NO, GET NEXT BUFFER ADDRESS     26700020
         SPACE                                                          27000020
         CR    RHDR8,RPREFIX            YES, IS THIS FIRST BUFFER       27300020
         BNE   NOTFIRST                 IT IS NOT, BRANCH               27380020
         SPACE                                                          27460020
         NI    SCBERR2,AVTEFF-SCBFRWDN  IT IS, RESET FORWARD FLAG       27540020
         B     SETAVTAD                 GO SET BUFFER ADDR IN AVT       27620020
         SPACE                                                          27700020
NOTFIRST EQU   *                                                        27780020
         SPACE                                                          27900020
         STC   RCT5,PRFKEY-IEDQPRF(,RPREFIX) IT ISN'T, SAVE COUNT       28200020
         IC    R0,LCBERBCH-1            INITIALIZE ERB FIELD            28500020
         ST    RPREFIX,LCBERBCH-1         TO                            28800020
         STC   R0,LCBERBCH-1              BFR ADDR ON NOT-FIRST         29100020
         OI    PRFSTAT1-IEDQPRF(RPREFIX),PRFDUPLN SET DUPL HDR BIT      29400020
         LH    RWORK2,PRFSCAN-IEDQPRF(,RPREFIX) PICK UP RESERVE CT      29700020
         LA    RWORK2,AVTTXTSZ(,RWORK2)   SET SCB TO START              30000020
         STH   RWORK2,SCBMRFSD            START OF CURRENT BUFFER       30300020
         L     RWORK2,PRFLINK-1         SAVE SECOND BUFFER'S            30600020
         ST    RWORK2,LCBRCB              ADDRESS IN LCB                30900020
         OI    SCBMBHEN+2,MBHFLAG+MLTRFLAG SET FLAGS IN SCB             31200020
         B     SETAVTAD                 GO SET NEXT BFR ADDR IN AVT     31500020
         SPACE 3                                                        31800020
BUFFER   EQU   *                                                        32100020
         L     RPREFIX,LCBERBCH-1       PICK UP CURRENT BUFFER          32400020
         LA    RPREFIX,AVTEZERO(,RPREFIX) ADDRESS FROM LCB              32700020
         SPACE                                                          33000020
         TM    PRFSTAT1-IEDQPRF(RPREFIX),PRFNHDRN CURRENT BFR FIRST     33300020
         LA    RCT5,ONE                 ASSUME YES                      33600020
         BNO   SETAVTAD                 YES, SET CURRENT BFR REG        33900020
         SPACE                                                          34200020
         IC    RCT5,PRFKEY-IEDQPRF(,RPREFIX) NO, GET CT FROM BUFFER     34500020
*        B     SETAVTAD                 GO SET BFR ADDR IN AVT          34800020
         EJECT                                                          35100020
SETAVTAD EQU   *                                                        35400020
         ST    RPREFIX,AVTADBUF         SET BUFFER ADDR IN AVT          35700020
         MVI   SCBPRI,AVTEZERO          CLEAR SCB PRIORITY              36000020
         NI    PRFSTAT1,AVTEFF-PRFLOCK  MAKE SURE LOCK BIT IS OFF       36100020
         SPACE                                                          36300020
NEXTDEST EQU   *                                                        36600020
         LH    RWORK2,PRFSCAN-IEDQPRF(,RPREFIX) SAVE IDLES COUNT        36900020
         LH    R0,SCBMRFSD              GET SECONDARY DEST OFFSET       37200020
         STH   R0,PRFSCAN-IEDQPRF(,RPREFIX) SET TO START SCAN THERE     37500020
         L     R1,SCBMRFPL-1            GET FORWARD PARM LIST ADDR      37800020
         LA    R15,AVTECD4              CLEAR FLAGS                     37870020
         LNR   R15,R15                    IN LOW-ORDER                  37940020
         NR    R1,R15                     TWO BITS                      38010020
         L     R15,AVTUI                GET USER INTERFACE ADDRESS      38100020
         BALR  R14,R15                  LINK TO FORWARD ROUTINE         38400020
         SPACE                                                          38700020
         STH   RWORK2,PRFSCAN-IEDQPRF(,RPREFIX) RESTORE IDLES CT        39000020
         LTR   R15,R15                  TEST RETURN                     39300020
         BM    MBHEXIT                  MBH RETURN, BRANCH              39600020
         BNZ   VALTEST-4(R15)           NOT VALID DEST, SELECT EXIT     39900020
         SPACE                                                          40200020
         TM    PRFSTAT1-IEDQPRF(RPREFIX),PRFNHDRN IS CURRENT FIRST      40500020
         BNO   TSTDLIST                 YES, GO TEST FOR DLIST          40800020
         SPACE                                                          41100020
         LH    RWORK2,AVTPARM3          NO, RETRIEVE KEY FROM AVT       41400020
         STH   RWORK2,PRFDEST           SET IN HEADER PREFIX            41700020
         SPACE                                                          42000020
TSTDLIST EQU   *                                                        42300020
         L     RQCB7,SCBDESTQ-1         PICK UP DEST QCB ADDRESS        42600020
         L     RWORK2,AVTPARM           GET TERM ENTRY ADDRESS          42900020
         USING IEDQTRM,RWORK2                                           43200020
         IC    R0,TRMSTATE              PICK UP STATUS BYTE             43500020
         NI    TRMSTATE,TYPEMASK        CLEAR ALL BUT TYPE FLAGS        43800020
         CLI   TRMSTATE,DISTLIST        TEST IF DISTRIBUTION LIST       44100020
         STC   R0,TRMSTATE              RESET STATUS BYTE               44400020
         BNE   POSTBFR                  NO, POST NOW                    44700020
         SPACE                                                          45000020
         CLI   SIXTH(RQCB7),CHARC       YES, IS 6TH BYTE A 'C'          45300020
         BNE   POSTBFR                  NO, POST NOW                    45600020
         SPACE                                                          45900020
         ST    RWORK2,LCBLINK-1         YES, STORE TERM ENTRY ADDR      46200020
         LA    R0,ONE                   SET VALUE OF ONE                46500020
         STH   R0,SCBDLPTR                IN DIST LIST POINTER          46800020
         ST    RQCB7,LCBRCQCB           PASS DLIST QCB ADDR IN LCB      47100020
         SPACE                                                          47400020
POSTBFR  EQU   *                                                        47700020
         ST    RQCB7,PRFQCBA-1          SET DEST QCB ADDR IN BFR        48000020
         MVI   PRFPRI,PRIDESTQ          SET PRIORITY                    48300020
         LR    R1,RHDR8                 SET HEADER ADDR IN REG 1        48600020
         B     DSPPOST                  EXIT TO POST BUFFER             48900020
         EJECT                                                          49200020
VALTEST  EQU   *                                                        49500020
         B     NEXTDEST                 GET NEXT DESTINATION            49800020
         SPACE                                                          50100020
EOA      EQU   *                                                        50400020
         LA    R0,AVTBFRTB              GET BUFFER RTN QCB ADDR         50700020
         CR    RPREFIX,RHDR8            ONLY ONE BUFFER TO RETURN       51000020
         LR    RPREFIX,RHDR8            (START WITH HEADER BUFFER)      51300020
         BE    EOAENTER                 ONLY ONE, ENTER LOOP            51600020
         SPACE                                                          51900020
         L     RWORK2,LCBRCB            MORE THAN ONE, LINK             52200020
         ST    RWORK2,PRFLINK-1           SECOND BUFFER TO FIRST        52500020
         B     EOAENTER                 ENTER LOOP                      52800020
         SPACE                                                          53100020
EOALOOP  EQU   *                                                        53400020
         L     RPREFIX,PRFLINK-1-IEDQPRF(,RPREFIX) GET NEXT BFR         53700020
         SPACE                                                          54000020
EOAENTER EQU   *                                                        54300020
         ST    R0,PRFQCBA-1-IEDQPRF(,RPREFIX) SET QCB ADDR IN BFR       54600020
         MVI   PRFPRI-IEDQPRF(RPREFIX),PRIBFRTB SET PRIORITY            54900020
         BCT   RCT5,EOALOOP             LOOP TILL ALL BUFFERS SET       55100020
         SPACE                                                          55300020
         SR    RWORK2,RWORK2            YES,CLEAR SECONDARY DESTSA61724 55500052
         SR    R10,R10                  CLEAR REGISTER          SA61724 55510052
         TM    SCBSTATE,SCBPRER         IS OPTION FIELD FIRST   SA61724 55520052
         BZ    NORESET                  NO                      SA61724 55530052
         LH    R1,LCBTTCIN              TNT OFFSET              SA61724 55540052
         N     R1,AVTCLRHI              CLEAR HIGH BYTES        SA61724 55550052
         BZ    NORESET                  NO SOURCE               SA61724 55560052
         L     R15,AVTRNMPT             TNT ROUTINE             SA61724 55570052
         BALR  R14,R15                  LINK TO TNT ROUTINE     SA61724 55580052
         DROP  RWORK2                                           SA61724 55590052
         USING IEDQTRM,R1                                       SA61724 55600052
         L     R9,AVTOPTPT              ADDR OF OPTION TABLE    SA61724 55610052
         IC    R10,TRMOPT(R10)          OFFSET                  SA61724 55620052
         AH    R9,TRMOPTBL              OPTIONS FOR THIS TERM ENTRY     55630052
         AR    R9,R10                   ADDR OF OPTION FIELD    SA61724 55640052
         MVC   AVTEZERO(OPLNGTH,R9),AVTFZERO CLEAR OPTION FIELD SA61724 55650052
         NI    SCBSTATE,AVTEFF-SCBPRER  TURN OFF FLAG           SA61724 55660052
NORESET  EQU   *                                                SA61724 55670052
         LR    R1,RHDR8                 SET ELEMENT ADDR FOR POSSA61724 55680052
         LA    RWORK2,LCBERB            GET ERB ADDRESS                 55700020
         ST    RWORK2,PRFLINK-1-IEDQPRF(,RPREFIX) SET IN LAST BFR       55900020
         MVI   PRFPRI-IEDQPRF(RPREFIX),PRIBFRTB RESET PRIORITY          56100020
         SPACE                                                          56300020
POSTERB  EQU   *                                                        56500020
         L     RWORK2,AVTMSGS-1         GET MH VCON TABLE ADDRESS       56700020
         L     RWORK2,AVTEZERO(,RWORK2) GET ADDR OF BFR DISP QCB        57000020
         ST    RWORK2,LCBERBQB-1        SET IT IN ERB QCB FIELD         57300020
         SR    R0,R0                    CLEAR LINK FIELD                57600020
         ST    R0,LCBERBLK-1              IN ERB'S ECB                  57900020
         MVI   LCBERBPY,PRIRCQCB        SET ECB PRIORITY                57980020
         MVC   LCBERBCH,AVTFZERO        CLEAR CHAIN FIELD TO ZEROES     58060020
         NI    LCBSTAT1,LCBRCLLF        TURN OFF RECALL BIT             58140020
         SPACE                                                          58540020
         B     DSPCHAIN                 EXIT TO POST ELEMENTS           59100020
         EJECT                                                          59400020
*                                                                       59410022
MBHEXIT  EQU   *                                                        59700020
         TM    PRFSTAT1-IEDQPRF(RPREFIX),PRFNLSTN MBH ON LAST BFR       60000020
         BO    MBHSAVE                  NO, GO SAVE DATA FOUND          60300020
         SPACE                                                          60600020
         LA    R14,EOA                  SET BRANCH ADDRESS              60670020
         SPACE                                                          60740020
CLRMRFSD EQU   *                                                        60810020
         SR    RWORK2,RWORK2            YES, CLEAR SECONDARY DEST       60900020
         STH   RWORK2,SCBMRFSD            FIELD IN SCB TO ZEROES        61200020
         BR    R14                      EXIT FROM FUNCTION              61500020
         SPACE                                                          61800020
MBHSAVE  EQU   *                                                        62100020
         MVC   LCBCPA(SEVEN),AVTDOUBL   NO, SAVE DATA FOUND IN LCB      62400020
         IC    RWORK2,AVTPARM+1         PICK UP LNG OF DATA FOUND       62700020
         SLL   RWORK2,FOUR              SHIFT LEFT                      63000020
         EX    RWORK2,OIX               SET IN SCB                      63300020
         SPACE                                                          63600020
         BAL   R14,CLRMRFSD             LINK TO CLEAR FIELD             64000020
         SPACE                                                          64500020
         CR    RPREFIX,RHDR8            IS CURRENT BUFFER FIRST BFR     64800020
         BE    MBHLINK                  YES, MAKE ITS LINK FLD ZERO     65100020
         SPACE                                                          65400020
         L     RWORK2,LCBRCB            NO, GET SECOND BFR'S ADDR       65700020
         SPACE                                                          66000020
MBHLINK  EQU   *                                                        66300020
         ST    RWORK2,PRFLINK-1         SET FIRST BUFFER'S LINK FLD     66600020
         SPACE                                                          66900020
         IC    R0,LCBERBCH-1                                            67200020
         ST    RHDR8,LCBERBCH-1         SET 1ST BFR'S ADDR IN ERB       67500020
         STC   R0,LCBERBCH-1                                            67800020
         SPACE                                                          68100020
         NI    SCBQTYPE,CLERDSET        CLEAR OLD DATA-SET FLAGS        68400020
         SPACE                                                          68700020
         LA    RCT5,ONE                 REQUEST 1 MORE BUFFER           69000020
         STH   RCT5,LCBERBCT            STORE REQUEST IN LCB            69300020
         SPACE                                                          69600020
         LA    RWORK2,AVTDSIOB          SET ADDRESS OF DISK I/O         69900020
         ST    RWORK2,LCBERBQB-1          QCB IN LCB                    70200020
         MVI   LCBERBPY,PRIRECAL        SET RECALL PRIORITY             70500020
         LA    R1,LCBERB                PUT ELEMENT ADDR IN R1          70800020
         B     DSPPOST                  POST TO GET NEXT BUFFER         71100020
         SPACE                                                          71400020
********* EXECUTED INSTRUCTION *********                                71700020
         SPACE                                                          72000020
OIX      OI    SCBDESTL,AVTEZERO                                        72300020
         SPACE 3                                                        72360020
********* CONSTANTS *********                                           72420020
         SPACE                                                          72480020
BACKUP   DC    AL2(LCBERB-IEDQLCB)      CONSTANT                 S21903 72540022
         EJECT                                                          72600020
********* DSECTS *********                                              72900020
         SPACE                                                          73200020
         TAVTD                                                          73500020
         EJECT                                                          73800020
         TDISPD                                                         74100020
         EJECT                                                          74400020
         TLCBD                                                          74700020
         EJECT                                                          75000020
         TPRFD                                                          75300020
         EJECT                                                          75600020
         TPRIOR                                                         75900020
         EJECT                                                          76200020
         TTRMD                                                          76500020
         EJECT                                                          76800020
         TSCBD                                                          77100020
         SPACE                                                          77400020
         END                                                            77700020
