         TITLE 'IEDQBH -- CONCENTRATOR BUFFER DISPOSITION'              00200022
         SPACE 3                                                        00200122
IEDQBH   CSECT                                                          00400022
         SPACE 3                                                        00400122
******************** MICROFICHE FLAGS *********************** SUPT CODE 00400222
*D536100-537500,604600-605200,689000                            SA52971 00400322
*                                                                       00450322
         SPACE 3                                                        00500322
*********************************************************************** 00600022
*                                                                     * 00800022
* STATUS -- CHANGE LEVEL 0                                            * 01000022
*                                                                     * 01200022
* FUNCTION -- TO LOCATE THE PROPER SCB AND TO INTERFACE WITH IEDQBD   * 01400022
*    TO CONTROL THE EXECUTION OF OUTMSG FOR A CONCENTRATOR MH         * 01600022
*                                                                     * 01800022
* ENTRY POINTS --                                                     * 02000022
*         IEDQBH01                                                    * 02200022
*         IEDQBH02                                                    * 02400022
*                                                                     * 02600022
* INPUT --                                                            * 02800022
*    R1 ADDRESS OF A BUFFER, LCB OR ERB                               * 03000022
*    R3 ADDRESS OF STCB                                               * 03200022
*    R7 ADDRESS OF QCB                                                * 03400022
*    R11 DISPATCHER BASE                                              * 03600022
*    R13 ADDRESS OF AVTSAVE2                                          * 03800022
*    R15 ENTRY POINT ADDRESS                                          * 04000022
*                                                                     * 04200022
* OUTPUT --                                                           * 04400022
*    R1 ADDRESS OF A BUFFER, LCB OR ERB                               * 04600022
*    R3 ADDRESS OF STCB                                               * 04800022
*    R11 DISPATCHER BASE                                              @ 05000022
*    R13 ADDRESS OF AVTSAVE2                                          * 05200022
*                                                                     * 05400022
* EXTERNAL REFERENCES --                                              * 05600022
*         NONE                                                        * 05800022
*                                                                     * 06000022
* EXITS,NORMAL --                                                     * 06200022
*         DSPPOST                                                     * 06400022
*         DSPBYPAS                                                    * 06600022
*                                                                     * 06800022
* EXITS,ERROR --                                                      * 07000022
*         NONE                                                        * 07200022
*                                                                     * 07400022
* TABLES/WORK AREAS --                                                * 07600022
*    AVT                                                              * 07800022
*    LCB                                                              * 08000022
*    QCB                                                              * 08200022
*    SCB                                                              * 08400022
*    TERMINAL ENTRY                                                   * 08600022
*    DRQ                                                              * 08800022
*    QCBE                                                             * 09000022
*                                                                     * 09200022
* ATTRIBUTES --                                                       * 09400022
*    RE-ENTRANT, REFRESHABLE, PROBLEM PROGRAM MODE                    * 09600022
*                                                                     * 09800022
* CHARACTER CODE DEPENDENCY --                                        * 10000022
*    THE OPERATION OF THIS MODULE DOES NOT DEPEND UPON A PARTICULAR   * 10200022
*    INTERNAL REPRESENTATION OF THE EXTERNAL CHARACTER SET.           * 10400022
*                                                                     * 10600022
* NOTES --                                                            * 10800022
*    STANDARD TCAM LINKAGES AND DEVIATIONS FROM STANDARDS.            * 11000022
*                                                                     * 11200022
*********************************************************************** 11400022
         EJECT                                                          11600022
*********************************************************************** 11800022
*        SYMBOLIC REGISTERS                                           * 12000022
*********************************************************************** 12200022
         SPACE 1                                                        12400022
RZERO    EQU   0                        WORK REG                        12600022
RPARM    EQU   1                        PARAMETER REG                   12800022
RWORKA   EQU   2                        WORK REG                        13000022
RQCBE    EQU   3                        QCBE                            13200022
RSTCB    EQU   3                        STCB                            13400022
RLCB     EQU   4                        LCB                             13600022
RWORKB   EQU   5                        WORK REG                        13800022
RDRQ     EQU   6                        DRQ                             14000022
RQCB     EQU   7                        QCB                             14200022
RWORKC   EQU   8                        WORK REG                        14400022
RTERM    EQU   8                        TERMINAL ENTRY                  14600022
RSCB     EQU   9                        SCB                             14800022
RDCB     EQU   10                       DCB                             15000022
RDISP    EQU   11                       DISPATCHER BASE                 15200022
RBASE    EQU   12                       CSECT BASE                      15400022
RAVT     EQU   13                       AUT BASE                        15600022
RRETURN  EQU   14                       RETURN REG                      15800022
RENTRY   EQU   15                       ENTRY POINT REG                 16000022
         SPACE 1                                                        16200022
*********************************************************************** 16400022
*        ESTABLISH CSECT AND CONTROL BLOCK ADDRESSABILITY             * 16600022
*********************************************************************** 16800022
         SPACE 1                                                        17000022
         USING IEDQDISP,RDISP           DISP                            17200022
         USING AVTSAVE2,RAVT            AVT                             17400022
         USING IEDQQCB,RQCB             QCB                             17600022
         USING IEDQSCB,RSCB             SCB                             17800022
         USING IEDQLCB,RLCB             LCB                             18000022
         USING IEDQTRM,RTERM            TERMINAL ENTRY                  18200022
         USING IEDQDRQ,RDRQ             DRQ                             18400022
         USING IEDQQCBE,RQCBE           QCBE REG                        18500022
         SPACE 3                                                        18600022
IEDQBH   IEDHJN                                                         18900022
         DC    AL1(DSPMCPL4)            STCB                            19200022
         DC    AL3(*-1)                 STCB ADDR                       19400022
IEDQBH01 EQU   *                                                        19600022
         USING *,RBASE                                                  19800022
         LR    RBASE,RENTRY             SET BASE REG                    20000022
         CLI   LCBPRI-IEDQLCB(RPARM),PRIFSPCI-1                         20200022
*                                       ELEMENT A LCB                   20400022
         BE    LCB                      BRANCH IF YES                   20600022
         L     RLCB,PRFLCB-1-IEDQPRF(RPARM)                             20800022
*                                       ASSUME BUFFER                   21000022
         TM    PRFTIC-IEDQPRF(RPARM),CCWTIC                             21200022
*                                       ELEMENT A BUFFER                21400022
         BO    BUFFER                   BRANCH IF YES                   21600022
         SPACE 1                                                        21800022
*********************************************************************** 22000022
*        ELEMENT IS AN ERB                                            * 22200022
*********************************************************************** 22400022
         SPACE 1                                                        22600022
BDEXIT   EQU   *                                                        22800022
         L     RQCB,IEDQBD              BD ADDR                         23000022
BDEXIT2  EQU   *                                                        23200022
         L     RSTCB,QCBSTCHN-1-IEDQQCB(RQCB)                           23400022
*                                       STCB ADDR                       23600022
         B     DSPBYPAS                 BYPASS TO BD                    23800022
         SPACE 1                                                        24000022
*********************************************************************** 24200022
*        ELEMENT IS A LCB                                             * 24400022
*********************************************************************** 24600022
         SPACE 1                                                        24800022
LCB      EQU   *                                                        25000022
         LR    RLCB,RPARM               SET LCB REG                     25200022
         SPACE 1                                                        25400022
*********************************************************************** 25600022
*        ELEMENT IS A BUFFER                                          * 25800022
*********************************************************************** 26000022
         SPACE 1                                                        26200022
BUFFER   EQU   *                                                        26400022
         TM    LCBSTAT1,LCBSENDN        LCB SENDING                     26600022
         BNO   BDEXIT                   BRANCH IF NO                    26800022
         L     RSCB,LCBSCBA-1           SCB ADDR                        27000022
         TM    SCBQTYPE,SCBCONC         CONC                            27200022
         BNO   BDEXIT                   BRANCH IF NO                    27400022
         CLI   LCBPRI-IEDQLCB(RPARM),PRILCB                             27600022
*                                       ELEMENT A LCB                   27800022
         BNE   NOTLCB                   BRANCH IF NO                    28000022
         L     RPARM,LCBLSPCI-1         BUFFER ADDR                     28200022
NOTLCB   EQU   *                                                        28400022
         TM    LCBERBST,LCBERROR        LINE ERROR                      28408022
         BO    CHKERBWT                 BRANCH IF YES                   28416022
         TM    PRFTIC-IEDQPRF(RPARM),PRFEOMSG                           28424022
*                                       LOGICAL MID-MESSAGE             28432022
         BZ    DRQLP                    BRANCH IF NO                    28440022
         NI    PRFTIC-IEDQPRF(RPARM),255-PRFEOMSG                       28448022
*                                       RESET LOGICAL MID-MESSAGE       28456022
         OI    LCBERBST,LCBERROR        SIMULATE ERROR                  28464022
CHKERBWT EQU   *                                                        28472022
         TM    LCBERBST,LCBDLNKN+LCBEOMSG                               28480022
*                                       ERB AVAILABLE                   28488022
         BNZ   DRQLP                    BRANCH IF YES                   28496022
         LA    RWORKA,IEDQBH02          QCB ADDR                        28504022
         ST    RWORKA,LCBRCQCB          SET ERB RETURN ADDR             28512022
         CLI   LCBERBPY,PRIDSPLB-1      ERB ON RDY Q                    28520022
         BNE   DONTCHG                  BRANCH IF NO                    28528022
         ST    RWORKA,LCBERB            SET QCB ADDR                    28536022
DONTCHG  EQU   *                                                        28544022
         IC    RWORKA,LCBLSPCI-1        SAVE HI-ORDER BYTE              28552022
         ST    RPARM,LCBLSPCI-1         SAVE BUFFER ADDR                28560022
         STC   RWORKA,LCBLSPCI-1        RESTORE HI-ORDER BYTE           28568022
         B     DSPDISP                  WAIT FOR ERB                    28576022
DRQLP    EQU   *                                                        28584022
         L     RQCB,SCBDESTQ-1          DEST QUEUE                      28594022
         LR    RQCBE,RQCB               SET REG                         28604022
         AH    RQCBE,QCBEXTO            QCBE ADDR                       28614022
         L     RDRQ,QCBECONC-1          CONC TERM ADDR                  28624022
         L     RDRQ,TRMDESTQ-1-IEDQTRM(RDRQ)                            28634022
*                                       DRQ ADDR                        28644022
         L     RWORKA,LCBSCBDA-1        LINE SCB ADDR                   28654022
         IC    RWORKB,SCBSTATE-IEDQSCB(RWORKA)                          28664022
*                                       SAVE HI-ORDER BYTE              28674022
         ST    RDRQ,SCBDESTQ-1-IEDQSCB(RWORKA)                          28684022
*                                       SAVE DRQ ADDR                   28694022
         STC   RWORKB,SCBSTATE-IEDQSCB(RWORKA)                          28704022
*                                       RESTORE HI-ORDER BYTE           28714022
         LR    RQCB,RDRQ                DRQ ADDR                        28800022
         LA    RWORKA,DRQSLINK-IEDQDRQ-1                                29000022
*                                       SET REG                         29200022
         SR    RQCB,RWORKA              SET LOOP REG                    29400022
DRQLPA   EQU   *                                                        29600022
         L     RQCB,QCBSLINK-IEDQQCB-1(RQCB)                            29800022
*                                       FIRST/NEXT STCB                 30000022
         CLI   FOUR(RQCB),ZERO          LAST ENTRY                      30200022
         BNE   QCBSET                   BRANCH IF NO                    30400022
         NC    LCBLSPCI,LCBLSPCI        BUFFER TO FREE                  30600022
         BNZ   BUFFREE                  BRANCH IF YES                   30800022
         OI    LCBSTAT1,LCBRCLLN        SET RECALL FOR BD/2             31000022
BUFFREE  EQU   *                                                        31200022
         L     RQCB,IEDQBD2             BD/2 ADDR                       31400022
         ST    RQCB,LCBQCBA-1           SET QCB ADDR                    31600022
         XC    LCBLINK,LCBLINK          ZERO FIELD                      31800022
         MVI   LCBPRI,PRIDESTQ-1        SET PRTY                        32000022
         MVC   LCBSCBA,LCBSCBDA         SET SCB POINTER                 32200022
         LR    RPARM,RLCB               SET REG FOR POST                32400022
         L     RSCB,LCBSCBDA-1          LINE SCB ADDR                   32600022
         NI    SCBQTYPE,255-SCBCONC     RESET TEMP CONC FLAG            32800022
         B     BDEXIT2                  BYPASS TO BD/2                  33000022
QCBSET   EQU   *                                                        33200022
         LA    RZERO,DRQSTVTO-IEDQDRQ   STCB OFFSET                     33400022
         SR    RQCB,RZERO               QCB ADDR                        33600022
         LH    RQCBE,QCBEXTO            EXTENSION OFFSET                33800022
         AR    RQCBE,RQCB               QCBE ADDR                       34000022
         TM    QCBEFLG,QCBEDATA+QCBEOMSG                                34400022
*                                       OUTMSG POSSIBLE                 34600022
         BZ    DRQLPA                   BRANCH IF NO                    34800022
         L     RWORKA,LCBSCBDA-1        SCB ADDR                        35000022
*        USING RWORKA  LINE SCB                                         35200022
         TM    SCBERR4-IEDQSCB(RWORKA),ERROR4                           35400022
*                                       ANY ERRORS                      35600022
         BZ    NOERRA                   BRANCH IF NO                    35800022
         TM    QCBEFLG,QCBEDATA         DATA IN THIS MSG                36000022
         BO    EXOUTMSG                 BRANCH IF YES                   36200022
NOERRA   EQU   *                                                        36400022
         NI    QCBEFLG,255-QCBEDATA     RESET DATA IN MSG               36600022
         TM    QCBEFLG,QCBEOPL          LEVEL QUEUEING                  36800022
         BZ    NOTLVLQ                  BRANCH IF NO                    37000022
         SR    RWORKC,RWORKC            ZERO REG                        37200022
         IC    RWORKC,QCBENPLV          NUMBER OF LEVELS                37400022
         LR    RWORKB,RQCBE             SET REG                         37600022
         SR    RZERO,RZERO              ZERO REG                        37800022
QCBELPA  EQU   *                                                        38000022
         IC    RZERO,QCBELGTH-IEDQQCBE(RWORKB)                          38200022
*                                       GET EXT LENGTH                  38400022
         AR    RWORKB,RZERO             QCBE ADDR                       38600022
         NI    QCBEFLG-IEDQQCBE(RWORKB),255-QCBEDATA                    38800022
*                                       RESET DATA IN MSG               39000022
         BCT   RWORKC,QCBELPA           BRANCH IF MORE LEVELS           39200022
NOTLVLQ  EQU   *                                                        39400022
         TM    QCBEFLG,QCBEOMSG         OUTMSG PENDING                  39600022
         BZ    DRQLPA                   BRANCH IF NO                    39800022
         TM    QCBEFLG,QCBESTAT         STATUS SPECIFIED                40000022
         BO    DRQLPA                   BRANCH IF YES                   40200022
EXOUTMSG EQU   *                                                        40400022
         IC    RWORKB,DRQSCBOF          SAVE HI-ORDER BYTE              42200022
         ST    RQCB,DRQCURQ-1           SAVE LAST QCB                   42400022
         STC   RWORKB,DRQSCBOF          RESTORE HI-ORDER BYTE           42600022
         SR    RSCB,RSCB                ZERO REG                        42800022
         SR    RWORKB,RWORKB            ZERO REG                        43000022
         IC    RSCB,QCBSCBOF            SCB OFFSET                      43200022
         IC    RWORKB,AVTSCBSZ          SCB SIZE                        43400022
         MR    RSCB-1,RWORKB            COMPUTE                         43600022
         ALR   RSCB,RWORKA              SCB ADDR                        43800022
         OC    SCBERR1(FOUR),SCBERR1-IEDQSCB(RWORKA)                    44000022
*                                       SET SCB                         44200022
         MVC   SCBEOB,QCBEEOB           SET SAVED SCBEOB                44400022
         TM    QCBEFLG,QCBECNT          BYTE COUNT TERMINAL     SA52971 44460022
         BZ    CHKBUF                   BRANCH IF NO            SA52971 44520022
         MVC   SCBDEOB,QCBEDEOB         SET SAVED SCBDEOB               44600022
*        DROP  RWORKA  LINE SCB                                         44800022
CHKBUF   EQU   *                                                        45000022
         LTR   RPARM,RPARM              GOT A BUFFER ALREADY            45200022
         BNZ   BUFFSET                  BRANCH IF YES                   45400022
         L     RPARM,AVTBFREB           GET UNIT                        45600022
         LA    RPARM,ZERO(RPARM)        ZERO HI-ORDER BYTE              45800022
         LTR   RPARM,RPARM              BUFFER AVAILABLE                46000022
         BNZ   DLNKBUF                  BRANCH IF YES                   46200022
         LA    RWORKA,IEDQBH02          QCB ADDR FOR RETURN             46400022
         ST    RWORKA,LCBRCQCB          RETURN QUEUE                    46600022
         MVI   LCBERBPY,PRIACTIV        POST PRIORITY                   47400022
         LA    RWORKA,X'0101'           SET REG                         47600022
         STH   RWORKA,LCBERBCT          SET COUNT TO ONE                47800022
         OI    LCBERBST,LCBPRCPG        INDICATE POST BACK              48000022
         LA    RWORKA,AVTBFREB          AVAILABLE BUFFER QUEUE          48040022
ERBPOST  EQU   *                                                        48080022
         ST    RWORKA,LCBERB            QCB ADDR FOR POST               48120022
         XC    LCBERBLK,LCBERBLK        CLEAR LINK FIELD                48160022
         LA    RPARM,LCBERB             ADDR FOR POST                   48200022
         B     DSPPOST                  POST ERB                        48400022
DLNKBUF  EQU   *                                                        48600022
         USING IEDQPRF,RPARM                                            48800022
         MVC   AVTBFREB+1(THREE),PRFLINK                                49000022
*                                       DELINK BUFFER                   49200022
         LH    RWORKA,AVTAVFCT          BUFFER COUNT                    49400022
         N     RWORKA,AVTCLRHI          FORCE POSIFIVE                  49600022
         BCTR  RWORKA,ZERO              SUB ONE                         49800022
         STH   RWORKA,AVTAVFCT          RESTORE COUNT                   50000022
         MVI   PRFNBUNT,ONE             SET ONE UNIT                    50200022
         MVC   PRFTIC+ONE(THREE),BUFLINK                                50400022
*                                       CLEAR LINK.                     50600022
         MVI   PRFPRI,PRIMHBFR          SET PRIORITY                    50800022
BUFFSET  EQU   *                                                        51000022
         IC    RWORKA,LCBLSPCI-1        SAVE HI-ORDER BYTE              51200022
         ST    RPARM,LCBLSPCI-1         SET BUFFER ADDR                 51400022
         STC   RWORKA,LCBLSPCI-1        RESTORE HI-ORDER BYTE           51600022
         IC    RWORKA,PRFNBUNT          SAVE UNIT COUNT                 51800022
         ST    RLCB,PRFLCB-1            SET LCB ADDR                    52000022
         STC   RWORKA,PRFNBUNT          RESTORE UNIT COUNT              52200022
         MVI   PRFSTAT1,ONE             SET TEXT LAST                   52400022
         MVI   PRFTIC,CCWTIC            SET BUFFER FLAG                 52600022
         NI    QCBEFLG,255-QCBEDATA-QCBEOMSG-QCBEHELD                   52800022
*                                       RESET FLAGS                     53000022
         LR    RWORKC,RQCBE             SAVE MAIN EXT                   53200022
         TM    QCBEFLG,QCBEOPL          PRTY QUEUEING                   53400022
         BZ    NOPRTY                   BRANCH IF NO                    53600022
         SR    RZERO,RZERO              ZERO REG                        53800022
         SR    RWORKB,RWORKB            ZERO REG                        54000022
         SR    RWORKA,RWORKA            ZERO REG                        54200022
         IC    RWORKB,QCBENPLV          NUMBER OF PRTY LEVLES           54400022
QCBELP   EQU   *                                                        54600022
         AH    RZERO,HALFONE            ADD ONE                         54800022
         CR    RZERO,RWORKB             LAST LEVEL                      55000022
         BH    RESETSCB                 BRANCH IF YES                   55200022
         IC    RWORKA,QCBELGTH          ENTRY LENGTH                    55400022
         AR    RQCBE,RWORKA             ENTRY ADDR                      55600022
         TM    SCBERR4,ERROR4           ANY ERRORS                      55800022
         BZ    NOERRB                   BRANCH IF NO                    56000022
         TM    QCBEFLG,QCBEDATA         DATA IN THIS MESSAGE            56200022
         BO    FOMSG                    BRANCH IF YES                   56400022
NOERRB   EQU   *                                                        56600022
         TM    QCBEFLG,QCBEOMSG         OUTMSG PENDING                  56800022
         BZ    QCBELP                   BRANCH IF NO                    57000022
         TM    QCBEFLG,QCBESTAT         STATUS SPECIFIED                57200022
         BO    QCBELP                   BRANCH IF YES                   57400022
FOMSG    EQU   *                                                        57600022
         TM    SCBERR4,SCBSLCTN         INITIAL SELECTION ERROR         57800022
         BO    SCBSET                   BRANCH IF YES                   58000022
         MVC   SCBSCHDR,QCBEHDR         SET HDR ADDR                    58200022
         MVC   SCBFEFO,QCBEFEFO         SET FEFO POINTER                58400022
         MVC   SCBPRI,QCBEPRI           SET PRTY LEVEL                  58600022
         MVC   SCBOSEQ,QCBEOSEQ         SET SEQ NUMBER                  58800022
         MVZ   SCBQTYPE,QCBEQTYP        SET QTYPE                       59000022
         IC    RWORKB,SCBSTATE          SAVE HI-ORDER BYTE              59200022
         ST    RQCB,SCBDESTQ-1          SET DESTQ                       59400022
         STC   RWORKB,SCBSTATE          RESTORE HI-ORDER BYTE           59600022
SCBSET   EQU   *                                                        59800022
         NI    QCBEFLG,255-QCBEDATA-QCBEOMSG-QCBEHELD                   60000022
*                                       RESET FLAGS                     60200022
NOPRTY   EQU   *                                                        60400022
         MVC   PRFNHDR,SCBSCHDR         SET HDR ADDR                    60600022
         DROP  RPARM                                                    60800022
         TM    SCBERR4,SCBSLCTN         INITIAL SELECTION ERROR         61000022
         BO    TTCINSET                 BRANCH IF YES                   61200022
         MVC   LCBTTCIN,QCBETCIN        SET TTCIN                       61400022
         MVC   SCBMACR,QCBEMACR-IEDQQCBE(RWORKC)                        61600022
*                                       SET SCBMACR                     61800022
TTCINSET EQU   *                                                        62000022
         IC    RWORKB,LCBMSGFM          SAVE HI-ORDER BYTE              62200022
         ST    RSCB,LCBSCBA-1           SET SCB ADDR                    62400022
         STC   RWORKB,LCBMSGFM          RESTORE HI-ORDER BYTE           62600022
         NI    LCBSTAT1,255-LCBRCLLN    RESET RECALL                    62700022
         LA    RWORKA,IEDQBH02          QCB ADDR                        62800022
         IC    RWORKB,LCBKEY            SAVE HI-ORDER BYTE              63000022
         ST    RWORKA,LCBQCBA-1         SET RETURN                      63200022
         STC   RWORKB,LCBKEY            RESTORE HI-ORDER BYTE           63400022
         B     BDEXIT                   BYPASS TO BD                    63600022
         DS    0F                                                       63800022
         ORG   *-8                      ORG BACK TO CREATE DUMMY QCB    64000022
IEDQBH02 EQU   *                                                        64200022
         ORG                                                            64400022
         DC    AL1(DSPMCPL4)            STCB                            64600022
         DC    AL3(*-1)                 STCB ADDR                       64800022
         USING *,RENTRY                                                 65000022
         L     RBASE,BHBASE             SET BASE REG                    65200022
         DROP  RENTRY                                                   65400022
         LR    RLCB,RPARM               SET LCB REG                     65600022
         LR    RWORKB,RPARM             SAVE REG                        65800022
         SR    RPARM,RPARM              INDICATE NO BUFFER              66000022
         CLI   LCBRSKEY-IEDQLCB(RWORKB),RSVTO                           66200022
*                                       ELEMENT A LCB                   66400022
         BNE   ERB                      BRANCH IF NO                    66600022
         XC    LCBLSPCI,LCBLSPCI        INDICATE NO BUFFER              66800022
         NI    LCBSTAT1,255-LCBRCLLN    RESET RECALL                    67000022
         MVI   LCBERBST,ZERO            CLEAR ERB STATUS                67200022
         L     RSCB,LCBSCBA-1           SCB ADDR                        67400022
         L     RWORKA,LCBSCBDA-1        LINE SCB ADDR                   67500022
         L     RDRQ,SCBDESTQ-1-IEDQSCB(RWORKA)                          67600022
*                                       RESTORE DRQ ADDR                67700022
         L     RQCB,DRQCURQ-1           LAST QCB SERVICED               67800022
         LR    RQCBE,RQCB               SET REG                         68000022
         AH    RQCBE,QCBEXTO            QCBE ADDR                       68200022
         TM    SCBQTYPE,SCBBFMM         HOLD LEVEL=BLOCK                68400022
         BO    DRQLPA                   BRANCH IF YES                   68600022
         LA    RWORKA,AVTCKPTB          CHKPT QCB ADDR                  68620022
         MVI   LCBERBPY,PRICKPLN        SET ERB PRIORITY                68640022
         TM    SCBSTATE,SCBCKPT         CHKPT REQUESTED                 68660022
         BO    ERBPOST                  BRANCH IF YES                   68680022
         MVI   SCBHBFNO,ZERO            CLEAR SCBHBFNO                  68690022
         TM    QCBEFLG,QCBEOPL          LEVEL QUEUEING                  68700022
         BO    CHKBUF                   BRANCH IF YES                   68720022
RESETSCB EQU   *                                                        68800022
         SR    RZERO,RZERO              ZERO REG                        69000022
         ST    RZERO,SCBERRST           CLEAR ERROR BYTES               69200022
         ST    RZERO,SCBDEOB            CLEAR DEOB                      69400022
         STH   RZERO,SCBEOB             CLEAR EOB                       69600022
         ST    RZERO,SCBHBFNO           CLEAR HBFNO AND SCHDR   SA52971 69800022
         NI    SCBQTYPE,255-SCBNREUS-SCBREUS-SCBCOREQ-SCBNORCL-SCBBFMM  70000022
*                                       RESET QTYPE                     70200022
         LA    RWORKA,AVTBFRTB          BUFFER RETURN                   70400022
         IC    RWORKC,SCBSTATE          SAVE HI-ORDER BYTE              70600022
         ST    RWORKA,SCBDESTQ-1        SET TO BUFFER RETURN            70800022
         STC   RWORKC,SCBSTATE          RESTORE HI-ORDER BYTE           71000022
         B     DRQLPA                   BRANCH TO LOOP                  71200022
         SPACE 1                                                        71400022
*********************************************************************** 71600022
*        ELEMENT IS A ERB                                             * 71800022
*********************************************************************** 72000022
         SPACE 1                                                        72200022
ERB      EQU   *                                                        72400022
         LA    RWORKA,LCBERB-IEDQLCB     ERB OFFSET INTO LCB            72600022
         SR    RWORKB,RWORKA            COMPUTE LCB                     72800022
         LR    RLCB,RWORKB              LCB                             73000022
         L     RSCB,LCBSCBA-1           LOAD SCB ADDR                   73020022
         TM    LCBERBST,LCBPRCPG        ERB FROM BUFFER REQUEST         73040022
         BO    BUFRET                   BRANCH IF YES                   73060022
         OI    LCBERBST,LCBDLNKN        MARK ERB AVAILABLE              73080022
         L     RPARM,LCBLSPCI-1         RESTORE BUFFER ADDR             73100022
         B     DRQLP                    BRANCH TO PROCESS               73120022
BUFRET   EQU   *                                                        73140022
         NI    LCBERBST,255-LCBPRCPG    RESET REQUEST BIT               73200022
         L     RPARM,LCBERBCH-1         BUFFER ADDR                     73400022
         MVC   PRFTIC+ONE-IEDQPRF(THREE,RPARM),BUFLINK                  73420022
*                                       CLEAR LINK                      73440022
         L     RWORKA,LCBSCBDA-1        LINE SCB ADDR                   73460022
         L     RDRQ,SCBDESTQ-1-IEDQSCB(RWORKA)                          73520022
*                                       RESTORE DRQ ADDR                73580022
         L     RQCB,DRQCURQ-1           CURRENT QCB ADDR                73640022
         LR    RQCBE,RQCB               SET REG                         73680022
         AH    RQCBE,QCBEXTO            QCBE ADDR                       73720022
         B     EXOUTMSG                 BRANCH TO PROCESS               73760022
         SPACE 1                                                        73800022
         EJECT                                                          76400022
         SPACE 1                                                        76600022
*********************************************************************** 76800022
*        EQUATES                                                      * 77000022
*********************************************************************** 77200022
         SPACE 1                                                        77400022
RSVTO    EQU   X'0C'                    RCV VTO                         77600022
CSVTO    EQU   X'20'                    CONC VTO                        77800022
ZERO     EQU   0                        ZERO                            78000022
ONE      EQU   1                        ONE                             78200022
TWO      EQU   2                        TWO                             78400022
THREE    EQU   3                        THREE                           78600022
FOUR     EQU   4                        FOUR                            78800022
FIVE     EQU   5                        FIVE                            79000022
SIX      EQU   6                        SIX                             79200022
SEVEN    EQU   7                        SEVEN                           79400022
EIGHT    EQU   8                        EIGHT                           79600022
         EJECT                                                          79800022
*********************************************************************** 80000022
*        CONSTANTS                                                    * 80200022
*********************************************************************** 80400022
         SPACE 1                                                        80600022
BHBASE   DC    A(IEDQBH01)              BASE ADDR OF BH                 80800022
IEDQBD   DC    V(IEDQBD)                VCON FOR IEDQBD                 81000022
IEDQBD2  DC    V(IEDQBD02)              BD/2 VCON                       81200022
HALFONE  DC    H'1'                     ONE                             81400022
BUFLINK  DC    X'000002'                BUFFER LINK                     81600022
         EJECT                                                          81800022
         SPACE 1                                                        82000022
*********************************************************************** 82200022
*        DSECTS                                                       * 82400022
*********************************************************************** 82600022
         SPACE 1                                                        82800022
         TPRIOR                                                         83000022
         TAVTD                                                          83200022
         TQCBD                                                          83400022
         TLCBD                                                          83600022
         TSCBD                                                          83800022
ERROR4   EQU   SCBSLCTN+SCBCONNN+SCBTRMLN+SCBCTLUN+SCBCHANN+SCBUNDFN+SCX84000022
               BTXTTN                                                   84200022
         TDISPD                                                         84400022
         TTRMD                                                          84600022
         TPRFD                                                          84800022
         TCCWD                                                          85000022
         TDRQD                                                          85200022
         TQCBED                                                         85400022
         END                                                            85600022
