         TITLE 'IEDQBO - SETEOM MODULE'                                 00050022
IEDQBO   CSECT                                                          00100022
         SPACE 3                                                        00110022
*CHANGE ACTIVITY AS FOLLOWS:                                            00120022
******************** MICROFICHE FLAGS *********************** SUPT CODE 00130022
*A094500,208822-208825,503100-503950                             S22026 00150022
*A212000,301400                                                 SA53636 00150122
*C133900                                                        SA53636 00150222
*A089000,149070-149840                                           S99238 00150322
*C149000                                                         S99238 00150422
*C148800,524500-525000                                          SA54290 00150522
*A559450-559900                                                 SA54935 00150622
*D522000-526000                                                 SA54935 00150722
*A253380-253430                                                 SA59188 00150822
*C208860,253150,253250,253330,284500,344060                     SA59188 00150922
*D208867-208881,222040-222240,253410,291040-291804              SA59188 00151022
*A584770,584785-584787,584790                                   SA59189 00151122
*D584792                                                        SA59189 00151222
*C132000,562000                                                 SA65376 00171252
*C500700-501400                                                 SA68031 00173253
*A148760,148820,559400                                          SA68031 00175253
*D584770                                                        OX02192 00177253
*A208750,486420                                                 OY00508 00181253
*C150215,150535,164100                                          SA69659 00192055
*                                                                       00194022
         SPACE 3                                                        00196022
*********************************************************************** 00200022
*                                                                     * 00300022
* MODULE NAME - IEDQBO                                                * 00310022
*                                                                     * 00320022
* DESCRIPTIVE NAME - SETEOM MODULE                                    * 00330022
*                                                                     * 00340022
* COPYRIGHT - NONE                                                    * 00350022
*                                                                     * 00360022
* TITLE 'IEDQBO' - SETEOM MODULE                                      * 00400022
*                                                                     * 00500022
*STATUS - CHANGE LEVEL 5                                              * 00600052
*                                                                     * 00700022
* FUNCTION - BLOCKS OR DEBLOCKS PHYSICALS MESSAGES INTO LOGICAL       * 00800022
*    MESSAGES ON COUNT, ON EOB BUFFERS OR BY EOM CHARACTER STRING.      00900022
*                                                                     * 01000022
* ENTRY POINT - 'IEDQBO'                                              * 01100022
*    CALLING SEQUENCE -                                               * 01200022
*         L    R15,IEDUI                                              * 01300022
*         BALR R14,R15                                                * 01400022
*                                                                     * 01500022
* INPUT -                                                             * 01600022
*    EXPECTED REGISTER CONTENTS                                       * 01700022
*         USING R3,SCB ADDR                                           * 01800022
*         USING R4,LCB ADDR                                           * 01900022
*         USING R6,BUFFER DSECT                                       * 02000022
*         USING R9,AVT BASE                                           * 02100022
*         USING R11,DISP DSECT                                        * 02150022
*         USING R12,BASE REGISTER                                     * 02200022
*    ADDRESS OF BO PARAMETER LIST PASSED IN R1; GENERATED IN SETEOM   * 02300022
*    MACRO                                                            * 02400022
*                                                                     * 02500022
* OUTPUT - DEBLOCKED OR BLOCKED LOGICAL MESSAGES; RETURN CODE IN      * 02900022
*          PRFNHDR+1                                                  * 03300022
*                                                                     * 03900022
* EXTERNAL REFERENCES -                                               * 04000022
*    IEDQAE - LOCATE OPTION FIELDS FOR LENGTH AND/OR ENDCHAR          * 04100022
*    IEDQBN - REMOVE BUFFER FROM HOLD QUEUE AND ATTACH TO IT THE      * 04200022
*          CURRENT BUFFER                                             * 04300022
*    IEDQBR - COUNT DATA BYTES IN BUFFER WHEN BLOCKING OR DEBLOCKING  * 04360022
*          ON COUNT                                                   * 04420022
*    IEDQAF - CLOSE UP DATA IN BUFFER                                 * 04500022
*    IEDQAO - OBTAIN NEW UNIT FOR DATA AFTER EOM CHARACTER            * 04600022
*                                                                     * 05100022
* EXITS,NORMAL - BRANCHES TO DISPATCHER; RETURNS TO MH VIA UI         * 05180022
*                                                                     * 05260022
* EXITS,ERROR - N/A                                                   * 05340022
*                                                                     * 05420022
* TABLES/WORK AREAS -                                                 * 05500022
*    AVT - ADDRESS VECTOR TABLE                                       * 05580022
*    LCB - LINE CONTROL BLOCK                                         * 05660022
*    SCB - STATION CONTROL BLOCK                                      * 05740022
*                                                                     * 05820022
* ATTRIBUTES - REUSABLE,REENTRABLE                                    * 05900022
*                                                                     * 05980022
* CHARACTER CODE DEPENDENCY - THE OPERATION OF THIS MODULE DOES NOT   * 06060022
*    DEPEND UPON AN INTERNAL REPRESENTATION OF THE EXTERNAL CHARACTER * 06140022
*    SET.                                                             * 06220022
*                                                                     * 06300022
* NOTES - N/A                                                         * 06380022
*                                                                     * 06500022
*********************************************************************** 06600022
R0       EQU   0                        INPUT/OUTPUT REG FOR AXM        06700022
R1       EQU   1                        WORK REG                        06800022
R2       EQU   2                        INPUT REG FOR AXM; ALSO, OPFLD  06900022
*                                       FOR ENDCHAR                     07000022
RSCB3    EQU   3                        SCB                             07100022
RSTCB    EQU   3                        STCB FOR BYPASS                 07150022
RLCB4    EQU   4                        LCB                             07200022
R5       EQU   5                        WORK REG                        07300022
RPREFIX  EQU   6                        BUFFER                          07400022
R7       EQU   7                        WORK REG                        07500022
R8       EQU   8                        WORK REG                        07600022
RAVT     EQU   9                        AVT                             07700022
RPARM    EQU   10                       SETEOM PARM LIST                07800022
R11      EQU   11                       DISP DSECT                      07900022
RBASE    EQU   12                       BASE                            08000022
R13      EQU   13                       REG                             08100022
R14      EQU   14                       REG                             08200022
R15      EQU   15                       REG                             08300022
ENDCH    EQU   X'01'                    ENDCHAR OPERAND SPECIFIED       08400022
EDCHOPF  EQU   X'02'                    ENDCHAR IN OPT FIELD            08500022
LNGOP    EQU   X'04'                    LENGTH OPERAND SPECIFIED        08600022
PROCESS  EQU   X'10'                    PROCESS EQ YES SPECIFIED        08700022
REMOVE   EQU   X'20'                    REMOVE EQ YES SPECIFIED         08800022
EOMETB   EQU   X'40'                    EOM=ETB SPECIFIED        S99238 08900022
STATUS   EQU   2                        OFFSET IN PARM LIST TO STATUS   09000022
*                                       BYTE                            09100022
SAVOFF   EQU   2                        OFFSET IN BFR - AREA FOR SAVING 09140022
*                                       EOM OFFSET                      09150022
CONST    EQU   2                        CONSTANT VALUE                  09155022
UNEX     EQU   X'01'                    UNIT EXCEPTION                  09160022
AEOFF    EQU   3                        OFFSET IN PARM LIST TO AE INDEX 09200022
LINK     EQU   3                        LENGTH OF ADDR                  09300022
THREE    EQU   3                        LENGTH TO RESET SCB PTR  S22026 09450022
DISP4    EQU   4                        DISPLACEMENT VALUE              09500022
LINKOS   EQU   5                        LINK FIELD OFFSET IN PARM LIST  09600022
*                                       AND IN BFR                      09700022
HOLDQ    EQU   4                        HOLD Q OFFSET                   09800022
RG15OFF  EQU   16                       REG 15 OFFSET                   09900022
ENDLEN   EQU   16                       OFFSET TO ENDCHAR LENGTH        10000022
SETEOMQ  EQU   16                       SETEOM QCB OFFSET IN PARM LIST  10100022
EOBBFR   EQU   20                      OFFSET IN STCB TO EOB BFR        10150022
EOT      EQU   X'37'                    EOT                             10200022
AOOFF    EQU   7                        AO OFFSET                       10300022
TXTHDRDF EQU   7                        DIFFERENCE BETWEEN HDR AND      10330022
*                                       TEXT PREFIX SIZE                10360022
AFOFF    EQU   6                        AF OFFSET                       10400022
INOFF    EQU   4                        INSERT OFFSET                   10500022
DATOFF   EQU   6                        DATA OFFSET                     10600022
PARMLN   EQU   X'04'                    AE PARM LIST LENGTH             10900022
DISPA    EQU   1                        DISPLACEMENT                    11000022
ONE      EQU   1                        INCREMENT                       11100022
DISPB    EQU   11                       DISPLACEMENT                    11200022
LASTUT   EQU   X'02'                    INDICATES LAST UNIT IN BFR      11300022
UTCNTOFF EQU   12                       OFFSET                          11400022
EOMSTCB  EQU   16                       OFFSET TO SETEOM STCB (LCBCPA)  11500022
STCBPRI  EQU   X'C0'                    PRIORITY                        11600022
STCBVTO  EQU   X'0A'                    SETEOM STCB VTO                 11700022
DISP5    EQU   5                        DISPLACEMENT                    11800022
DISP8    EQU   8                        DISPLACEMENT                    11900022
FOUR     EQU   4                        SHIFT BUFIN TO LOW HALF BYTE    11920022
CLRHI    EQU   X'0F'                    CLEAR HI HALF OF THE FIRST      11940022
*                                       BYTE OF LCBERBCT                11960022
LINKFD   EQU   9                        DISPLACEMENT                    11980022
MODBIT   EQU   X'01'                    USED TO TURN ON LOW ORDER BIT   12000022
*                                       OF INDEX                        12100022
BROFF    EQU   X'05'                    OFFSET TO IEDQBR INDEX          13030022
CTOPOFF  EQU   X'0E'                    OFFSET TO CTR OPT FIELD         13060022
MAXOPT   EQU   X'08'                    FLAG- MAX COUNT IN OPT FIELD    13068022
MAXOFF   EQU   X'0D'                    OFFSET TO MAX COUNT OPT FIELD   13076022
INTEG    EQU   X'0C'                    MAX COUNT OFFSET IN PARM LIST   13084022
*                                       (WHEN INTEGER)                  13092022
RETOFF   EQU   X'26'                    RETURN TO MH OFFSET PASSED      13100022
*                                       SETEOM PARM LIST                13150022
PRIMH    EQU   0                        ALT MH QCB ADDRESS      SA65376 13200052
ALTMH    EQU   5                        ALT MH ADDRESS IN QCB   SA65376 13250052
PARMLEN  EQU   8                        STARTMH PARM LENGTH             13300022
*                                                                       13304022
*                  PRFTQBCK+2 -- FLAG BYTE                              13308022
*                                                                       13312022
DEBLKBFR EQU   X'80'                    DEBLOCKED BFR FLAG              13316022
NORDCON  EQU   X'40'                    NO READ CONT TO BE DONE IN THIS 13320022
*                                       BFR- NOT AN ORIGINAL BFR        13324022
EOBBUF   EQU   X'20'                    READ CONTINUE HAS BEEN DONE     13328022
*                                         IN THIS BUFFER                13332022
NOLNGOP  EQU   X'10'                    OPTION FIELD FOR LENGTH NOT     13333022
*                                       FOUND                           13334022
EOMXBFR  EQU   X'08'                    EOM STRING CROSS BFR BOUNDARY   13336022
BREOBBF  EQU   X'02'                    READ CONT NECESSARY  (FOR       13336822
*                                       PROCESS=NO CASE)                13337622
NOCHAROP EQU   X'01'                    OPTION FIELD FOR ENDCHAR NOT    13338422
*                                       FOUND                           13339222
*                                                                       13340022
*                  PRFNHDR+1  --  FIELD FOR RETURN CODE                 13344022
*                                                                       13348022
BOTHCD   EQU   X'0C'                    RETURN CODE- PROCESSED ON BOTH  13352022
*                                       CONDITIONS (PRFNHDR+1)          13356022
NOUNIT   EQU   X'10'                    RETURN CODE- NO AVAILABLE BFR   13360022
*                                       UNITS (PRFNHDR+1)               13364022
COUNTCD  EQU   X'08'                    RETURN CODE- PROCESSED ON       13368022
*                                       COUNT CONDITION (PRFNHDR+1)     13372022
STRINGCD EQU   X'04'                    RETURN CODE- PROCESSED ON EOM   13376022
*                                       STRING (PRFNHDR+1)              13380022
NOTPRO   EQU   X'14'                    BUFFER NOT PROCESSED    SA53636 13390022
         USING IEDQBO1,RBASE                                            13400022
         USING IEDQAVTD,RAVT                                            13500022
         USING IEDQLCB,RLCB4                                            13600022
         USING IEDQPRF,RPREFIX                                          13700022
         USING IEDQSCB,RSCB3                                            13800022
         USING IEDQDISP,R11                                             13900022
IEDQBO1  EQU   *                                                        14000022
IEDQBO   IEDHJN IDPASS                                                  14100022
         LR    RPARM,R1                 ADDR OF PARM LIST               14300022
         NI    PRFTQBCK+2,EOBBUF+NORDCON CLEAR ALL BUT TWO FLAGS        14400022
         MVC   PRFXTRA+1(2),AVTFZERO    INDICATE NO EOB IN BUFFER       14500022
         TM    PRFSTAT1,PRFCNCLN       IS THIS A RD CONT BUFFER         14530022
         BNO   SCANQ                    NO                              14560022
         NI    PRFSTAT1,X'FF'-PRFCNCLN    RESET CANCEL BIT              14590022
         MVC   PRFSCAN(2),PRFNHDR      RESET SCAN POINTER FROM SAVED    14620022
SCANQ    EQU   *                                                        14808022
         TM    PRFTIC,PRFEOMSG          TEMP END OF MSG?                14809022
         BNO   SKIP4                    BR NO                           14810022
         NI    PRFSTAT1,X'FF'-PRFNLSTN  SET AS LAST BFR                 14811022
         NI    PRFTIC,X'FF'-PRFEOMSG    TURN OFF FLAG                   14812022
SKIP4    EQU   *                                                        14813022
         LA    R1,DISP4(RPARM)          EXIT TO BN                      14816022
         OI    0(R1),MODBIT             TURN ON BIT FOR RETURN          14824022
         L     R15,AVTUI                EXIT TO                         14832022
         BALR  R14,R15                  SCAN HOLD Q                     14840022
         L     RPREFIX,AVTADBUF         SET UP BFR ADDR                 14848022
         MVC   PRFCRCD(1),LCBISZE       SAVE ISZE FOR BFR               14848522
         NI    PRFTQBCK+2,X'FF'-EOMXBFR-DEBLKBFR  TURN OFF FLAGS        14849522
         MVC   PRFCRCD+1(2),AVTFZERO    INITIALIZE FIELD (INDICATE      14849622
*                                       COUNT CONDITION NOT MET)        14850022
         CLC   PRFSIZE(2),AVTFZERO      ZERO LENGTH BUFFER              14851022
         BE    NOEOM                    CHECK FOR RD CONT NECESSARY     14852022
         TM    AVTAFE30,AVTEFF          IS DUMP REQUESTED?              14856022
         BZ    SKIPFE                   BR NO                           14864022
         L     R2,AVTAFE30              GET RTN ADDR                    14872022
         LR    R1,RPREFIX               BFR ADDR                        14876022
         LR    R8,R13                   SAVE AVTSAVE3 ADDR      SA68031 14877053
         LA    R13,AVTSAVE2             SAVE2 ADDRESS FOR RTNE  SA68031 14878053
         LR    R14,RPARM                SAVE PARAMETER REG      SA54290 14880022
         BALR  RPARM,R2                 LINK TO BUFFER TRACE    SA54290 14882022
         LR    R13,R8                   RESTORE SAVE3 ADDRESS   SA68031 14883053
         LR    RPARM,R14                RESTORE PARM REG        SA54290 14884022
SKIPFE   EQU   *                                                        14888022
         MVI   PRFNHDR+1,AVTEZERO       ZERO OUT RETURN CODE FIELD      14894022
         TM    STATUS(RPARM),EOMETB     EOM=ETB                  S99238 14900022
         BNO   NOTETB                   BRANCH NO                S99238 14907022
         SPACE                                                          14914022
         TM    PRFSTAT1,PRFNLSTN        EOB OR EOT BUFFER        S99238 14921022
         BO    CKCOUNT                  BRANCH NO                S99238 14928022
         SPACE                                                          14935022
         LH    R0,PRFSIZE               SET EOB OFFSET           S99238 14942022
         N     R0,AVTCLRHI              CLEAR HIGH ORDER BYTE    S99238 14949022
         MVI   PRFNHDR+1,STRINGCD       PROCESSED ON EOM INDICAT S99238 14956022
         B     CONP1                    BRANCH TO POST BUFFER    S99238 14963022
         SPACE                                                          14970022
NOTETB   EQU   *                                                 S99238 14977022
         TM    STATUS(RPARM),LNGOP      LENGTH OPERAND SPECIFIED S99238 14984022
         BZ    CKENDOPF                 BR NO                           15000022
         TM    PRFTQBCK+2,NOLNGOP       HAS OPTION FIELD BEEN FOUND     15000522
*                                       ON PREVIOUS PASS?               15001022
         BO    CKENDOPF                 BR IF NOT FOUND PREVIOUSLY      15001522
         MVC   AVTPARM(1),AEOFF(RPARM)  AE INDEX                        15002022
         MVI   AVTPARM+1,PARMLN         PARM LIST LNG                   15004022
         MVC   AVTPARM+2(1),CTOPOFF(RPARM)  COUNTER OPT FIELD OFFSET    15006022
         MVI   AVTPARM+3,RG15OFF        REG 15 OFFSET                   15008022
         LA    R1,AVTPARM               EXIT TO                         15010022
         L     R15,AVTUI                AE TO                           15012022
         BALR  R14,R15                  LOCATE OPT FIELD                15014022
         LTR   R15,R15                  OPT FIELD FOUND?                15016022
         BNZ   OPFLD2                   BR YES                          15018022
         OI    PRFTQBCK+2,NOLNGOP       SET FLAG FOR LENGTH OPERAND NOT 15018522
*                                       FOUND                           15019022
         TM    STATUS(RPARM),ENDCH      ENDCHAR SPECIFIED?              15019522
         BO    CKENDOPF                 BR YES                          15020022
         MVI   PRFNHDR+1,NOTPRO         SET RETURN CODE- OPTION FIELD   15020522
*                                       NOT FOUND- BFR NOT PROCESSED    15021022
         B     NOEOM                    BRANCH                  SA69659 15021555
OPFLD2   EQU   *                                                        15022022
         LR    R7,R15                   ADDR OF COUNTER OPT FIELD       15024022
         TM    STATUS(RPARM),MAXOPT     MAX COUNT IN OPT FIELD?         15026022
         BZ    NOOPT                    BR NO                           15028022
*                                       THEREFORE, MAX COUNT IS INTEGER 15030022
*                                       IN SETEOM PARM LIST             15032022
         MVC   AVTPARM(1),AEOFF(RPARM)  AE INDEX                        15034022
         MVI   AVTPARM+1,PARMLN         PARM LNG                        15036022
         MVC   AVTPARM+2(1),MAXOFF(RPARM) MAX COUNT OPT FIELD INDEX     15038022
         MVI   AVTPARM+3,RG15OFF        RG 15 OFFSET                    15040022
         LA    R1,AVTPARM               EXIT TO                         15042022
         L     R15,AVTUI                AE TO                           15044022
         BALR  R14,R15                  LOCATE MAXCOUNT OPT FIELD       15046022
         LTR   R15,R15                  OPT FIELD FOUND?                15048022
         BNZ   OPFLD1                   BR YES                          15050022
         OI    PRFTQBCK+2,NOLNGOP       SET FLAG FOR LENGTH OPERAND NOT 15050522
*                                       FOUND                           15051022
         TM    STATUS(RPARM),ENDCH      ENDCHAR SPECIFIED?              15051522
         BO    CKENDOPF                 BR YES                          15052022
         MVI   PRFNHDR+1,NOTPRO         SET RETURN CODE- OPTION FIELD   15052522
*                                       NOT FOUND- BFR NOT PROCESSED    15053022
         B     NOEOM                    BRANCH                  SA69659 15053555
OPFLD1   EQU   *                                                        15054022
         LR    R8,R15                   ADDR OF MAX COUNT OPT FIELD     15056022
         B     SKIP2                    BRANCH                          15058022
NOOPT    EQU   *                                                        15060022
         LA    R8,INTEG(RPARM)          ADDR OF MAX COUNT IN PARM LIST  15062022
*                                       (INTEGER)                       15064022
SKIP2    EQU   *                                                        15066022
         ST    RPARM,AVTPARM            ADDR OF SETEOM PARM LIST        15100022
         MVC   AVTPARM(1),BROFF(RPARM)  BR INDEX                        15107022
         LA    R1,AVTPARM               EXIT TO                         15114022
         L     R15,AVTUI                BR                              15121022
         BALR  R14,R15                  THRU UI                         15128022
         LTR   R15,R15                  EOM CONDITION ON COUNT MET?     15135022
         BNZ   CTEOM                    BR YES                          15142022
         TM    STATUS(RPARM),ENDCH      ENDCHAR SPECIFIED?              15149022
         BO    CKENDOPF                 BR YES                          15156022
         B     NOEOM                    BRANCH                          15163022
CTEOM    EQU   *                                                        15170022
         STH   R15,PRFCRCD+1            SAVE EOM POSITION               15177022
         TM    STATUS(RPARM),ENDCH      ENDCHAR SPECIFIED?              15184022
         BZ    LNGEOM                   BR NO                           15191022
CKENDOPF EQU   *                                                        15200022
         TM    STATUS(RPARM),EDCHOPF    ENDCHAR IN OPTFLD?              15300022
         BZ    FINDEOM1                 BR NO                           15400022
         MVC   AVTPARM(1),AEOFF(RPARM)  BUILD AE                        15500022
         MVI   AVTPARM+1,PARMLN         PARM LIST                       15600022
         MVC   AVTPARM+2(1),ENDLEN(RPARM)  TO LOCATE OPT FIELD          15700022
         MVI   AVTPARM+3,RG15OFF        FOR ENDCHAR                     15800022
         LA    R1,AVTPARM               EXIT TO                         15900022
         L     R15,AVTUI                AE VIA                          16000022
         BALR  R14,R15                  UI                              16100022
         LTR   R15,R15                  WAS OPT FIELD FOUND?            16200022
         BNZ   CONT1                    BR YES                          16300022
         OI    PRFTQBCK+2,NOCHAROP      SET FLAG FOR ENDCHAR OPERAND    16310022
*                                       NOT FOUND                       16320022
         TM    STATUS(RPARM),LNGOP      LENGTH OPERAND SPECIFIED?       16330022
         BNO   NOOPTFLD                 BR NO                           16340022
         TM    PRFTQBCK+2,NOLNGOP       LENGTH OPTION FIELDS FOUND?     16350022
         BNO   CKCOUNT                  BR YES                          16360022
NOOPTFLD EQU   *                                                        16370022
         MVI   PRFNHDR+1,NOTPRO         SET RETURN CODE- BFR NOT        16380022
*                                       PROCESSED DUE TO OPTION FIELDS  16390022
*                                       NOT FOUND                       16400022
         B     NOEOM                    BRANCH                  SA69659 16410055
CONT1    EQU   *                                                        16500022
         LR    R2,R15                   ADDR OF OPFLD (ENDCHAR)         16600022
         B     FINDEOM                  BRANCH TO EXIT TO AX            17600022
FINDEOM1 EQU   *                                                        18800022
         L     R2,ENDLEN(RPARM)         PUT ADDR OF ENDCHAR IN R1       18900022
FINDEOM  EQU   *                                                        18950022
         LR    R1,R2                    ADDR OF ENDCHAR                 19050022
         SR    R8,R8                    CLEAR REG                       19150022
         IC    R8,0(R2)                 LENGTH OF ENDCHAR STRING        19300022
         LNR   R2,R1                    MAKE R2 NEGATIVE                19400022
         LH    R0,PRFSCAN               POINT AT WHICH AX  STARTS SCAN  19500022
         N     R0,AVTCLRHI              CLEAR HIGH ORDER BYTES          19600022
         L     R15,AVTAX                EXIT TO AX TO                   19700022
         BALR  R14,R15                  SEARCH FOR EOM IN THIS BFR      19800022
         LTR   R15,R15                  EOM FOUND?                      19900022
         BNZ   CON                      BR YES                          20000022
CKCOUNT  EQU   *                                                        20050022
         CLC   PRFCRCD+1(2),AVTFZERO    EOM ON COUNT CONDITION MET?     20100022
         BNE   LNGEOM                   BR YES                          20200022
NOEOM    EQU   *                                                        20300022
         TM    STATUS(RPARM),PROCESS    PROCESS EQ YES?                 20500022
         BO    PROYES                   BR YES                          20600022
         TM    PRFSTAT1,PRFNLSTN        EOT BFR?                        20700022
         BO    CONT                     BR NO                           20800022
CKRDCON  EQU   *                                                        20810022
         TM    SCBQTYPE,SCBBBFTM        SCB FOR TERMINAL?               20820022
         BNO   CONT                     BR NO                           20830022
         TM    SCBERR4,SCBTXTTN+SCBSLCTN  TEXT ERROR OR ERROR           20865022
*                                       DURING SELECTION?               20870022
         BNZ   CONT                     BR YES                          20875022
         TM    SCBERR1,SCBCUTFN         EXECUTED                OY00508 20877053
         BO    CONT                     YES, BRANCH             OY00508 20879053
         TM    LCBCSW+3,UNEX            EOT RECEIVED                    20881022
         BO    MIDMSG                   YES, NO READ CONTINUE NEEDED    20882022
         SPACE                                                          20882122
         L     R5,LCBSTCBA-1            GET STCB ADDR           S22026  20882222
         CLI   AVTEZERO(R5),STCBVTO     PROC=YES ALREADY EXEC'D S22026  20882322
*                                       ON THIS BUFFER          S22026  20882422
         BE    MIDMSG                   YES, NO READ CONT       S22026  20882522
         SPACE                                                          20882622
         LH    R5,SCBEOB                GET EOB OFFSET                  20883022
         MVC   PRFOPCDE(8),LCBCPA+16    SET CCW FOR COMMON CODE         20884022
         TM    LCBSTAT2,LCBRESP         IS READ CONTINUE NECESSARY      20885022
         BO    ARDCONT                  BR YES                  SA59188 20886022
MIDMSG   EQU   *                                                        20889022
         SPACE                                                          20890022
         OI    PRFSTAT1,PRFNLSTN        TURN OFF EOT                    20900022
         OI    PRFTIC,PRFEOMSG          TURN ON FOR BD                  21000022
         OI    SCBQTYPE,SCBBFMM         TURN ON MID MSG BIT             21100022
CONT     EQU   *                                                        21200022
         SR    R1,R1                    CLEAR REGISTER          SA53636 21230022
         IC    R1,PRFNHDR+1             SET RETURN CODE         SA53636 21260022
         L     R14,AVTUI                EXIT                            21300022
         B     DISP4(R14)               THRU UI                         21400022
PROYES   EQU   *                                                        21500022
         TM    SCBERR4,SCBSLCTN         ERROR DURING SELECTION?         21530022
         BO    CONT                     BR YES                          21560022
         TM    PRFSTAT1,PRFNLSTN        EOT BFR?                        21600022
         BZ    FORCEOM                  BR YES                          21700022
         TM    PRFTQBCK+2,DEBLKBFR      IS THIS A DEBLOCKED BFR?        21800022
         BZ    QBFR                     BR NO TO LINK BFR ON SETEOM Q   21900022
*                                       ELSE, LINK BFR ON HOLD Q        22000022
COMP     EQU   *                                                        22004022
         TM    STATUS(RPARM),LNGOP      LENGTH OPERAND SPECIFIED?       22008022
         BZ    HOLDPRO                  BR NO                           22012022
         TM    PRFTQBCK+2,NOLNGOP       LENGTH OPTION FIELDS FOUND?     22013022
         BO    HOLDPRO                  BR NO                           22014022
         LH    R7,PRFSIZE               SIZE OF BFR                     22016022
         N     R7,AVTCLRHI              CLEAR HIGH ORDER BYTES          22020022
HOLDPRO2 EQU   *                                                        22024022
         SR    R2,R2                    CLEAR REG                       22028022
         L     R14,LCBDCBPT             DCB ADDR                        22032022
         TM    PRFSTAT1,PRFNHDRN        HDR BFR?                        22036022
         BO    TXTIDL1                  BR NO                           22040022
         TM    PRFTQBCK+2,DEBLKBFR      HDR BFR OF FIRST LOGICAL MSG?   22044022
         BO    HDRES                    BR NO                           22048022
         IC    R2,LCBISZE               NO. OF RESERVES CHARACTERS      22052022
         B     HDRES1                   BR                              22056022
HDRES    EQU   *                                                        22060022
         IC    R2,DCBRESER-IHADCB(R14)  NO. OF HDR RESERVES             22064022
HDRES1   EQU   *                                                        22068022
         LA    R2,AVTHDRSZ(R2)          HDR PREFIX SIZE                 22072022
         B     SK                       BR                              22076022
TXTIDL1  EQU   *                                                        22080022
         IC    R2,DCBRESER+1-IHADCB(R14)  NO. OF TEXT RESERVES          22084022
         LA    R2,AVTTXTSZ(R2)          TEXT PREFIX SIZE                22088022
SK       EQU   *                                                        22092022
         SR    R7,R2                    AMOUNT OF DATA BYTES GOING ON   22096022
*                                       HOLD Q (THAT IS, THE NO. TO BE  22100022
*                                       SUBTRACTED FROM CTR FIELD OF    22104022
*                                       LENGTH OPERAND)                 22108022
HOLDPRO1 EQU   *                                                        22112022
         MVC   AVTPARM(1),AEOFF(RPARM)  AE INDEX                        22116022
         MVI   AVTPARM+1,PARMLN         PARM LIST LNG                   22120022
         MVC   AVTPARM+2(1),CTOPOFF(RPARM)  CTR OPTION FIELD INDEX      22124022
         MVI   AVTPARM+3,RG15OFF        REG 15 OFFSET                   22128022
         LA    R1,AVTPARM               EXIT TO                         22132022
         L     R15,AVTUI                AE TO                           22136022
         BALR  R14,R15                  LOCATE OPTION FIELD             22140022
CONTN    EQU   *                                                        22156022
         LH    R8,0(R15)                VALUE IN COUNTER OPTION FIELD   22160022
         N     R8,AVTCLRHI              DECREMENT COUTN                 22164022
         SR    R8,R7                    IN THE                          22168022
         STH   R8,0(R15)                COUNTER OPTION FIELD            22172022
HOLDPRO  EQU   *                                                        22200022
         LA    R14,EXITDSP              SET RETURN TO DISPATCH          22230022
HOLDEOB  EQU   *                                                        22260022
         LR    R8,RPREFIX               ADDR OF FIRST UNIT OF BFR       22300022
         SR    R7,R7                    CLEAR REG                       22400022
         IC    R7,PRFNBUNT              NO. OF UNITS IN BFR             22500022
         B     FUNIT                    BRANCH                          22600022
LTUT     EQU   *                                                        22700022
         L     R8,PRFTIC-IEDQPRF(R8)    BUMP TO NEXT UNIT               22800022
FUNIT    EQU   *                                                        22900022
         BCT   R7,LTUT                  DECREMENT COUNT                 23000022
*                                       R8 NOW HAS ADDR OF LAST UNIT    23100022
         L     R0,PRFTIC-IEDQPRF(R8)    GET NEXT FUFFER ADDR            23150022
         MVC   PRFTIC+1-IEDQPRF(3,R8),AVTFZERO  SET AS LAST             23220022
         MVI   DISPB(R8),LASTUT         UNIT OF BFR                     23300022
         TM    PRFTQBCK+2,EOMXBFR       PARTIAL CHAR STRING BFR?        23330022
         BO    STRN                     BR YES                          23360022
         IC    R5,LCBISZE               SET ISZE IN                     23370022
         STC   R5,PRFSCAN               PRFSCAN FOR BN                  23380022
         LA    R5,HOLDQ(RPARM)          ADDR OF HOLD QCB                23400022
LP1      EQU   *                                                        23500022
         B     LOOP1                    PUT BUFFER ON HOLD Q            23600022
CON      EQU   *                                                        24300022
         CR    R15,R8                   ALL OF EOM STRING FOUND (STRING 24400022
*                                       NOT CROSS BFR BOUNDARY)         24500022
         BE    ALLFND                   BR YES                          24600022
         CLC   PRFCRCD+1(2),AVTFZERO    EOM ON COUNT CONDITION MET?     24630022
         BNE   LNGEOM                   BR YES                          24660022
         TM    PRFSTAT1,PRFNLSTN        EOT BFR?                        24700022
         BO    CONT4                    BR NO                           24800022
         TM    STATUS(RPARM),PROCESS    PROCESS EQ YES?                 24900022
         BO    FORCEOM                  BR YES                          25000022
         B     CKRDCON                  BRANCH                          25050022
CONT4    EQU   *                                                        25100022
         TM    PRFTQBCK+2,DEBLKBFR      DEBLOCKED BFR?                  25200022
         BZ    CONTP                    BR NO                           25250022
         TM    STATUS(RPARM),LNGOP      LENGTH OPERAND SPECIFIED?       25310022
         BZ    HOLDPRO                  BR NO                   SA59188 25315022
         TM    PRFTQBCK+2,NOLNGOP       LENTTH OPTION FIELDS FOUND?     25320022
         BO    HOLDPRO                  BR NO                   SA59188 25325022
         LH    R7,PRFSIZE               AMOUNT OF DATA IN BFR   SA59188 25333022
         N     R7,AVTCLRHI              CLEAR HI HALF           SA59188 25338022
         B     HOLDPRO2                 DECREMENT COUNT FIELD   SA59188 25343022
CONTP    EQU   *                                                        25350022
         SR    R0,R15                   BACK UP PTR TO FIRST BYTE OF    25400022
*                                       THE SETEOM STRING WHICH         25500022
*                                       CROSSES BFR BOUNDARIES          25600022
         OI    PRFTQBCK+2,EOMXBFR       INDICATE PARTIAL EOM STRING     25700022
*                                       FOUND IN BFR                    25800022
         B     CONP                     BR TO GET UNIT                  25900022
STRN     EQU   *                                                        26000022
         LR    R7,R5                    ADDR OF ORIGINAL BFR THAT HAD   27100022
*                                       PARTIAL EOM STRING IN IT        27200022
         LA    R5,HOLDQ(RPARM)          ADDR OF HOLD Q                  27300022
         BAL   R14,LOOP1                BR TO LINK BFR WITH PARTIAL     27400022
*                                       STRING IN IT ON HOLD Q          27500022
         LR    RPREFIX,R7               ORIGINAL BFR WITH STRING        27600022
*                                       REMOVED                         27700022
         ST    RPREFIX,AVTADBUF         SET ADBUF TO THIS BUFFER        27750022
         OI    PRFSTAT1,PRFNLSTN        SET AS NOT LAST BFR             27800022
         TM    STATUS(RPARM),PROCESS    PROCESS EQ YES?                 27900022
         BNO   CONT                     BR NO TO RETURN                 28000022
QBFR     EQU   *                                                        28050022
         LA    R5,SETEOMQ(RPARM)        ADDR OF SETEOM Q                28100022
         BAL   R14,SIZE                 BR TO CALC ISZE AND LINK BFR    28200022
*                                       ON SETEOM Q                     28220022
EXITDSP  EQU   *                                                        28230022
         L     R11,AVTEA                DISPATCHER                      28240022
         LA    R13,AVTSAVE2             ADDR OF SAVE2                   28260022
         B     DSPDISP                  BR TO DISPATCHER                28280022
ALLFND   EQU   *                                                        28300022
         CLC   PRFCRCD+1(2),AVTFZERO    EOM ON COUNT CONDITION MET?     28400022
         BE    CKCODE1                  BR NO                   SA59188 28450022
         CH    R0,PRFCRCD+1             EOM ON COUNT OCCUR FIRST?       28500022
         BE    CKCODE                   BR IF EOM ON COUNT CONDITION    28550022
*                                       COINCIDES WITH EOM STRING       28560022
         BL    CKCODE1                  BR IF EOM STRING OCCURS FIRST   28570022
*                                       ELSE, USE COUNT CONDITION       28600022
LNGEOM   EQU   *                                                        28650022
         LH    R0,PRFCRCD+1             SET R0 AS OFFSET IN BFR TO      28700022
         N     R0,AVTCLRHI              END OF COUNT CONDITION          28770022
         LR    R1,R0                    SET R1                          28850022
         LR    R7,RPREFIX               BFR ADDR                        28870022
         BAL   R14,ENTERLOP             BR TO FIND ENDING ADDR OF       28890022
*                                       EOM DELIMITER                   28910022
         MVI   PRFNHDR+1,COUNTCD        RETURN CODE- PROCESSED ON COUNT 28950022
*                                       CONDITION                       29020022
         B     CKPRO2                   BRANCH                          29060022
CKCODE   EQU   *                                                        29180822
         MVI   PRFNHDR+1,BOTHCD         RETURN CODE- COUNT AND EOM      29181222
*                                       STRING COINCIDE                 29181622
         B     CKPRO2                   BRANCH                          29182022
CKCODE1  EQU   *                                                        29182422
         MVI   PRFNHDR+1,STRINGCD       RETURN CODE- PROCESSED ON       29182822
*                                       EOM STRING                      29183222
CKPRO2   EQU   *                                                        29184022
         TM    STATUS(RPARM),PROCESS    PROCESS EQ YES?                 29200022
         BO    CKEOT2                   BR YES                          29300022
         TM    PRFSTAT1,PRFNLSTN        LAST BFR?                       29400022
         BZ    CONT5                    BR YES                          29420022
         STH   R0,PRFSIZE               ADJUST PRFSIZE                  29440022
         IC    R7,LCBISZE               SET ISZE IN                     29446022
         STC   R7,PRFSCAN               PRFSCAN FOR BN                  29452022
         B     COMP                     BR TO LINK BFR ON HOLD Q        29460022
CONT5    EQU   *                                                        29480022
         CLI   PRFNHDR+1,COUNTCD        DOES COUNT CONDITION PREVAIL?   29486022
         BE    SHORT                    BR YES                          29492022
         TM    STATUS(RPARM),REMOVE     REMOVE EOM STRING?              29500022
         BZ    SHORT                    BR NO                           29600022
         SR    R0,R8                    SHORTEN BFR BY EOM STRING       29700022
         BAL   R14,CHECK                CHECK FOR ZERO BFR CREATED      29800022
SHORT    EQU   *                                                        30000022
         STH   R0,PRFSIZE               SHORTEN BFR APPROPRIATELY       30100022
         CLC   SCBDEOB+1(3),AVTADBUF+1  EOB BFR                         30105022
         BNE   SETLAST                  BR NO                           30110022
         SPACE                                                          30115022
         CH    R0,SCBEOB                PRFSIZE GREATER THAN EOB        30120022
         BNL   SETLAST                  BR YES                          30125022
         SPACE                                                          30130022
         STH   R0,SCBEOB                SET EOB TO PRFSIZE              30135022
SETLAST  EQU   *                                                        30140022
         SR    R1,R1                    CLEAR REGISTER          SA53636 30143022
         IC    R1,PRFNHDR+1             SET RETURN CODE         SA53636 30146022
         NI    PRFSTAT1,PRFNLSTF        SET AS EOT BFR                  30150022
         L     R14,AVTUI                EXIT THRU                       30230022
         B     DISP4(R14)               UI+4                            30310022
CKEOT2   EQU   *                                                        30400022
         CLI   DISPA(R1),EOT            NEXT CHAR A X'37' ?             30500022
         BNE   CONP1                    BR NO                           30600022
         CLI   PRFNHDR+1,COUNTCD        DOES COUNT CONDITION PREVAIL?   30630022
         BE    FORCEOM                  BR YES                          30660022
         TM    STATUS(RPARM),REMOVE     REMOVE EOM STRING?              30700022
         BZ    FORCEOM                  BR NO                           30800022
         SR    R0,R8                    SHORTEN BFR BY                  30900022
         BAL   R14,CHECK                CHECK FOR ZERO BFR CREATED      30950022
         STH   R0,PRFSIZE               EOM STRING                      31000022
         B     FORCEOM                  BRANCH                          31100022
CONP1    EQU   *                                                        31207022
         CH    R0,PRFSIZE               EOM STRING LAST IN BFR?         31214022
         BNE   CONP2                    BR NO                           31221022
         TM    PRFSTAT1,PRFNLSTN        LAST BFR?                       31228022
         BO    CONP2                    BR NO                           31235022
         TM    LCBCSW+3,UNEX            EOT RECEIVED?                   31235622
         BNZ   SK1                      BR YES                          31235922
         CLC   SCBDEOB+1(3),AVTADBUF+1  EOB BFR?                        31236222
         BNE   SK1                      BR NO                           31236522
         CLC   SCBEOB(2),PRFSIZE        EOB LAST IN BFR?                31236822
         BNE   SK1                      BR NO                           31237122
         L     R2,AVTBFREB              AVAIL BFR Q                     31237422
         LA    R2,0(R2)                 ANY BFR UNITS                   31237722
         LTR   R2,R2                    AVAILABLE?                      31238022
         BNZ   UNIT                     BR YES                          31238222
         MVI   PRFNHDR+1,NOUNIT         SET RETURN CODE                 31238422
         OI    LCBCSW+3,UNEX            SET UNEX BIT                    31238622
         NI    LCBSTAT2,X'FF'-LCBRESP   TURN OFF RESP BIT               31238822
         B     PREPARE                  BRANCH                          31239022
UNIT     EQU   *                                                        31239222
         MVC   AVTBFREB+1(3),PRFLINK-IEDQPRF(R2)  DELINK BFR            31239522
         LH    R5,AVTAVFCT              ADJUST AVAIL COUNT              31239822
         BCTR  R5,0                     SET COUNTER                     31240122
         STH   R5,AVTAVFCT              STORE IT BACK                   31240422
         SR    R5,R5                    CLEAR REG                       31240722
         L     R14,LCBDCBPT             NO. OF                          31241022
         IC    R5,DCBRESER-IHADCB(R14)  HDR RESERVES                    31241322
         STC   R5,PRFCRCD               SAVE IT                         31241622
         LA    R5,AVTHDRSZ(R5)          ADD PREFIX SIZE                 31241922
         BCTR  R5,0                     DECREMENT FOR EX                31242222
         EX    R5,MVPRE                 MOVE PREFIX + RESERVES INTO     31242522
*                                       NEW BFR                         31242822
         LA    R5,ONE(R5)               RESET TOTAL                     31243122
         STH   R5,PRFSIZE-IEDQPRF(R2)   SET PFFRIZE                     31243422
         STH   R5,PRFSCAN-IEDQPRF(R2)   SET PRFSCAN                     31243722
         STH   R5,SCBEOB                UPDATE EOB OFFSET AND           31244022
         ST    R2,SCBDEOB               EOB BFR POINTER                 31244322
         NI    PRFSTAT1-IEDQPRF(R2),PRFNHDRF SET AS HDR BFR             31244622
         LR    R5,RPREFIX               ADDR OF FIRST UNIT OF BFR       31244922
         SR    R1,R1                    CLEAR REG                       31245222
         IC    R1,PRFNBUNT              NO. OF UNITS                    31245522
         B     FUNIT1                   BRANCH                          31245822
LTUT1    EQU   *                                                        31246122
         L     R5,PRFTIC-IEDQPRF(R5)    BUMP TO NEXT UNIT               31246422
FUNIT1   EQU   *                                                        31246722
         BCT   R1,LTUT1                 DECREMENT COUNT                 31247022
         MVC   PRFTIC-IEDQPRF(4,R2),PRFTIC-IEDQPRF(R5) MOVE NEXT BFR    31247322
*                                       ADDR INTO NEW BFR               31247622
         MVC   PRFTIC+1-IEDQPRF(3,R5),AVTFZERO  SET AS LAST             31247922
         MVI   DISPB(R5),LASTUT         UNIT OF BFR                     31248222
         LA    R1,ONE                   SET TO                          31248522
         STC   R1,PRFNBUNT-IEDQPRF(R2)  ONE UNIT BFR                    31248822
         MVI   PRFTQBCK+2-IEDQPRF(R2),AVTEZERO REINIT FLAG BYTE         31249122
         OI    PRFTQBCK+2-IEDQPRF(R2),DEBLKBFR+NORDCON SET FLAGS        31249422
         CLI   PRFNHDR+1,COUNTCD        DOES COUNT CONDITION PREVAIL?   31249722
         BE    SKIP5                    BR YES                          31250022
         TM    STATUS(RPARM),REMOVE     REMOVE EQ YES?                  31250322
         BZ    SKIP5                    BR NO                           31250622
         SR    R0,R8                    SUBTRACT LENGTH OF EOM STRING   31250922
         BAL   R14,CHECK                CHECK FOR ZERO BFR CREATED      31251222
         STH   R0,PRFSIZE               ADJUST PRFSIZE                  31251522
SKIP5    EQU   *                                                        31251822
         LA    R5,SETEOMQ(RPARM)        PUT ORIGINAL BFR ON             31252122
         BAL   R14,SIZE                 SETEOM Q                        31252422
         LR    RPREFIX,R2               SET NEW BFR                     31252722
         ST    RPREFIX,AVTADBUF         AS CURRENT BFR                  31253022
         XC    PRFLINK(3),PRFLINK       CLEAR FIELD                     31253322
         XC    PRFSTXT(PRFSHDR-PRFSTXT+ONE),PRFSTXT  ZERO BYTES         31253622
         B     FORCEOM                  BRANCH                          31253922
SK1      EQU   *                                                        31254222
         CLI   PRFNHDR+1,COUNTCD        COUNT CONDITION PREVAIL         31254522
         BE    FORCEOM                  BR YES                          31254822
         TM    STATUS(RPARM),REMOVE     REMOVE EQ YES                   31255122
         BZ    SKIP1                    BR NO                           31255422
         SR    R0,R8                    SHORTEN BFR BY                  31256022
         BAL   R14,CHECK                CHECK FOR ZERO BFR CREATED      31259022
         STH   R0,PRFSIZE               EOM STRING                      31263022
         OI    PRFTQBCK+2,NORDCON       INDICATE NO RD CONT IN THIS BFR 31266022
SKIP1    EQU   *                                                        31270022
         B     FORCEOM                  BRANCH TO CLEAN SETEOM Q        31277022
CONP2    EQU   *                                                        31284022
         CLI   PRFNHDR+1,COUNTCD        DOES COUNT CONDITION PREVAIL?   31286022
         BE    CONP                     BR YES                          31288022
         STH   R8,PRFCRCD+1             SAVE LENGTH OF EOM STRING       31291022
CONP     EQU   *                                                        31300022
         LA    R2,ONE                   CTR TO DETERMINE WHICH UNIT     31400022
*                                       EOM IN (PRFNBUNT FOR EOM BFR)   31500022
         STH   R0,SAVOFF(RPREFIX)       SAVE OFFSET INTO EOM BFR (NEW   31600022
*                                       PRFSIZE FOR EOM BFR)            31700022
         B     FNDUT                    BRANCH TO FIND UNIT WITH EOM    31800022
LP2      LA    R2,ONE(R2)               ADD TO CTR                      31900022
         SH    R0,AVTKEYLE              SUBTRACT KEYLEN                 32000022
FNDUT    CH    R0,AVTKEYLE              EOM IN THIS UNIT?               32100022
         BH    LP2                      BR NO                           32200022
*        R2 CONTAINS NO. OF UNITS IN SETEOM BFR                         32300022
*        R0 CONTAINS OFFSET TO END OF EOM STRING IN THE ACTUAL UNIT     32400022
*        THAT CONTAINS THE STRING                                       32500022
         LR    R7,R0                    SAVE OFFSET                     32600022
         LH    R5,AVTKEYLE              KEYLEN                          32700022
         SR    R5,R0                    R5 CONTAINS REMAINING BYTES IN  32800022
*                                       IN EOM UNIT                     32900022
         LH    R0,SAVOFF(RPREFIX)       RESTORE R0 - OFFSET IN EOM BFR  33000022
*                                       OF END OF EOM STRING            33100022
         N     R0,AVTCLRHI              CLEAR HIGH BYTES                33150022
         LA    R8,ONE                   INITIALIZE TO ONE               33220022
         AR    R0,R8                    ADD 1 FOR AO                    33300022
GETUNIT  EQU   *                                                        33400022
         MVC   AVTPARM(1),AOOFF(RPARM)  AO INDEX INTO AVTPARM           33500022
         OI    AVTPARM,MODBIT           TURN ON BIT IN AO INDEX SO      33600022
*                                       RETURN IS TO BO                 33700022
         MVC   INOFF(2,RPREFIX),AVTFZERO  INSERT OFFSET                 33800022
         STH   R0,DATOFF(RPREFIX)       DATA OFFSET                     33900022
         MVI   AVTPARM3,AVTEFF          SET FLAG IN PARM3               34000022
         LA    R1,AVTPARM               EXIT TO AO AND BACK TO BO       34100022
         L     R15,AVTUI                UI                              34200022
         BALR  R14,R15                  EXIT TO GET UNIT                34260022
         LTR   R15,R15                  DID I GET A UNIT                34320022
         BZ    AUNIT                    YES BRANCH                      34340022
         MVI   PRFNHDR+1,NOUNIT         SET RETURN CODE- NO UNITS       34360022
*                                       AVAILABLE                       34366022
         TM    PRFSTAT1,PRFNLSTN        LAST BFR?                       34376022
         BNO   CONT7                    BR YES                          34386022
         NI    PRFTQBCK+2,X'FF'-EOMXBFR  TURN OFF BIT                   34396022
         B     HOLDPRO                  PUT BFR ON HOLD QUEUE   SA59188 34406022
CONT7    EQU   *                                                        34416022
         OI    LCBCSW+3,UNEX            SET UNEX BIT                    34426022
         NI    LCBSTAT2,X'FF'-LCBRESP   TURN OFF RESP BIT               34436022
         B     PREPARE                  BRANCH                          34446022
AUNIT    EQU   *                                                        34456022
         SR    R1,R1                    CLEAR REG                       34466022
         L     R14,LCBDCBPT             DCB ADDR                        34476022
         TM    PRFTQBCK+2,EOMXBFR       PARTIAL CHAR STRING BFR?        34600022
         BO    PARTSTR                  BR YES                          34700022
         IC    R1,DCBRESER-IHADCB(R14)  NO. OF HDR RESERVES             34800022
         LA    R1,AVTHDRSZ(R1)          HDR PREFIX SIZE                 34900022
         B     COPR                     BR TO DETERMINE IF ANOTHER UNIT 34960022
*                                       NEEDED                          35020022
PARTSTR  EQU   *                                                        35100022
         IC    R1,DCBRESER+1-IHADCB(R14)  NO. OF TEXT RESERVES          35200022
         LA    R1,AVTTXTSZ(R1)          TEXT PREFIX SIZE                35300022
COPR     EQU   *                                                        35400022
         CR    R1,R7                    COMPARE PREFIX + RESERVES WITH  35500022
*                                       OFFSET IN UNIT(S) TO DETERMINE  35600022
*                                       IF SPACE AVAILABLE TO MOVE IN   35700022
*                                       PREFIX + RESERVES               35800022
         BNH   MVE                      BR IF SPACE AVAILABLE           35900022
         AH    R7,AVTKEYLE              OFFSET IN BFR AFTER GOT UNIT    36000022
         LH    R0,DATOFF(RPREFIX)       ELSE, GET NEW OFFSET IN BFR     36100022
         B     GETUNIT                  BR TO GET ANOTHER UNIT          36200022
MVE      EQU   *                                                        36300022
         SR    R1,R1                    CLEAR REG                       36400022
         IC    R1,PRFNBUNT              TOTAL NO. OF UNITS              36500022
         SR    R1,R2                    SUBTRACT NO. OF UNITS FOR EOM   36600022
*                                       BFR                             36700022
         STC   R2,PRFNBUNT              NO. OF UNITS IN EOM BFR AND     36800022
*                                       R1 CONTAINS NO. OF UNITS FOR    36900022
*                                       NEW BFR                         37000022
         LH    R8,PRFSIZE               TOTAL NO. OF BYTES IN ALL       37100022
         N     R8,AVTCLRHI             CLEAR HI ORDER BYTES             37200022
         MVC   PRFSIZE(2),SAVOFF(RPREFIX) MOVE PRFSIZE INTO EOM BFR     37300022
         LH    R2,PRFSIZE               PRFSIZE OF EOM BFR              37400022
         N     R2,AVTCLRHI              CLEAR HIGH ORDER BYTES          37500022
         SR    R8,R2                    PRFSIZE OF NEW BFR = TOTAL      37600022
         SR    R8,R5                    PRFSIZE - PRFSIZE OF SETEOM BFR 37700022
*                                       - REMAING BYTES IN EOM UNIT     37800022
         LR    R5,RPREFIX               BFR ADDR                        37900022
         SR    R2,R2                    CLEAR REG                       38000022
         IC    R2,PRFNBUNT              NO. OF BFR UNITS IN EOM BFR     38100022
         B     STCOMP                   BRANCH                          38200022
DELOOP   EQU   *                                                        38300022
         L     R5,PRFTIC-IEDQPRF(R5)    BUMP TO NEXT UNIT               38400022
STCOMP   EQU   *                                                        38500022
         BCT   R2,DELOOP                BR IF NOT LAST UNIT OF EO       38600022
*                                       BFR                             38700022
         L     R2,PRFTIC-IEDQPRF(R5)    ADDR OF NEW BFR                 38800022
         MVC   PRFTIC+1-IEDQPRF(3,R5),AVTFZERO SET AS LAST UNIT OF      38900022
         MVI   DISPB(R5),LASTUT         EOM BFR                         39000022
         SR    R5,R5                    CLEAR REG                       39100022
         L     R14,LCBDCBPT             ADDR OF DCB                     39200022
         TM    PRFTQBCK+2,EOMXBFR       PARTIAL CHAR STRING BFR?        39300022
         BO    PARTSTR1                 BR YES                          39400022
         IC    R5,DCBRESER-IHADCB(R14)  NO. OF HDR RESERVES             39500022
         LA    R5,AVTHDRSZ(R5)          HDR PREFIX SIZE                 39600022
         B     COPR1                    BRANCH                          39700022
PARTSTR1 EQU   *                                                        39800022
         IC    R5,DCBRESER+1-IHADCB(R14)  NO. OF TEXT RESERVES          39900022
         LA    R5,AVTTXTSZ(R5)          TEXT PREFIX SIZE                40000022
COPR1    EQU   *                                                        40100022
         BCTR  R5,0                     DECREMENT BY 1 FOR EX           40200022
         EX    R5,MVPRE                 MOVE PREFIX + RESERVES INTO     40300022
*                                       NEW BFR                         40400022
         STC   R1,PRFNBUNT-IEDQPRF(R2)  NO. OF UNITS IN NEW BFR         40500022
         STH   R8,PRFSIZE-IEDQPRF(R2)   PRFSIZE IN NEW BFR              40600022
*                                       TURN OFF EOB FLAG IN NEW BFR    40630022
         NI    PRFTQBCK+2-IEDQPRF(R2),X'FF'-EOBBUF                      40660022
         LH    R0,PRFSIZE               PRFSIZE OF EOM BFR              40670022
         N     R0,AVTCLRHI              CLEAR HI HALF                   40680022
         LR    R5,R0                    SAVE ORIGINAL PRFSIZE           40690022
         TM    PRFTQBCK+2,EOMXBFR       PARTIAL CHAR STRING BFR?        40700022
         BO    CONT6                    BR YES                          40800022
         NI    PRFSTAT1,PRFNLSTF        SET EOM BFR AS EOT BFR          40900022
         CLI   PRFNHDR+1,COUNTCD        DEBLOCKING ON COUNT?            40903022
         BE    CONT6                    BR YES                          40905022
         SPACE                                                          40907022
         TM    STATUS(RPARM),REMOVE     REMOVE EQ YES?                  40910022
         BZ    CONT6                    BR NO                           40918022
         SH    R0,PRFCRCD+1             SHORTEN BFR BY LENGTH OF STRING 40938022
         LR    R1,R7                    SAVE REG                        40944022
         BAL   R14,CHECK                CHECK FOR ZERO BFR CREATED      40950022
         LR    R7,R1                    RESTORE REG                     40956022
         STH   R0,PRFSIZE               SET SIZE                        40962022
CONT6    EQU   *                                                        41150022
         CLC   SCBDEOB+1(3),AVTADBUF+1  DOES SCBDEOB POINT TO EOM BFR?  41200022
         BNE   SKIP                     BR NO                           41210022
         SPACE                                                          41220022
         CH    R5,SCBEOB                EOB AFTER EOM STRING            41230022
         BL    UPDEOB                   YES, GO UPDATE DEOB             41240022
         SPACE                                                          41250022
         CH    R0,SCBEOB                EOB BEFORE EOM STRING           41260022
         BNL   SKIP                     BR YES                          41270022
         SPACE                                                          41280022
         STH   R0,SCBEOB                ADJUST EOB TO NEW PRFSIZE       41290022
         B     SKIP                     GO PUT BFR ON SETEOM Q          41300022
         SPACE                                                          41310022
UPDEOB   EQU   *                                                        41320022
         IC    R5,SCBDEOB               POINT SCBDEOB                   41400022
         ST    R2,SCBDEOB               TO THE                          41500022
         STC   R5,SCBDEOB               NEW BFR                         41600022
SKIP     EQU   *                                                        41620022
         TM    PRFTQBCK+2,EOMXBFR       PARTIAL CHAR STRING BFR         41640022
         BO    SWAPBFR                  BR YES                          41660022
         SPACE                                                          41680022
         LA    R5,SETEOMQ(RPARM)        BR TO LINK EOM BFR ON           41700022
         BAL   R14,SIZE                 SETEOM Q                        41720022
         SPACE                                                          41740022
SWAPBFR  EQU   *                                                        41760022
         LR    R5,RPREFIX               R5 CONTAINS ADDR OF ORIGINAL    41800022
*                                       BFR                             41900022
         LR    RPREFIX,R2               SET NEW BFR AS CURRENT BFR      42000022
         ST    RPREFIX,AVTADBUF         UPDATE AVTADBUF                 42100022
         SR    R2,R2                    CLEAR REG                       42200022
         L     R14,LCBDCBPT             ADDR OF DCB                     42300022
         TM    PRFTQBCK+2,EOMXBFR       PARTIAL CHAR STRING BFR?        42400022
         BO    PARTSTR2                 BR YES                          42500022
         IC    R2,DCBRESER-IHADCB(R14)  NO. OF HDR RESERVES             42600022
         STC   R2,LCBISZE               SET ISZE FOR NEW BFR            42650022
         STC   R2,PRFCRCD               SAVE ISZE BFR                   42670022
         LA    R2,AVTHDRSZ(R2)          HDR PREFIX SIZE                 42700022
         NI    PRFSTAT1,PRFNHDRF        SET AS HDR BFR                  42800022
         XC    PRFSTXT(PRFSHDR-PRFSTXT+ONE),PRFSTXT ZERO LAST SEVEN     42900022
*                                       BYTES OF PREFIX PLUS ONE EXTRA  43000022
         STH   R2,PRFSCAN               SET UP PRFSCAN                  43050022
         B     COPR2                    BRANCH                          43120022
PARTSTR2 EQU   *                                                        43200022
         IC    R2,DCBRESER+1-IHADCB(R14)  NO. OF TEXT RESERVES          43300022
         STC   R2,PRFSCAN               SET ISZE IN PRFSCAN FOR BN      43350022
         LA    R2,AVTTXTSZ(R2)          TEXT PREFIX SIZE                43400022
         STC   R2,PRFSCAN+1             SET UP PRFSCAN                  43450022
         OI    PRFSTAT1,PRFNHDRN        SET AS NOT HDR                  43500022
COPR2    EQU   *                                                        43600022
         CR    R2,R7                    IS SHIFT NECESSARY TO CLOSE     43800022
*                                       UP BFR?                         43900022
         BE    CONTPR                   BR NO                           44000022
         IC    R1,AFOFF(RPARM)          AF INDEX IN                     44100022
         LA    R1,ONE(R1)               AVTPARM WITH                    44200022
         STC   R1,AVTPARM               X'01' ON                        44300022
         STH   R7,DATOFF(RPREFIX)       DATA OFFSET                     44400022
         SR    R7,R2                    CALCULATE INSERT                44500022
         STH   R7,INOFF(RPREFIX)        OFFSET                          44600022
         LH    R8,PRFSIZE               PRFSIZE OF NEW BFR              44700022
         N     R8,AVTCLRHI              CLEAR HI ORDER BYTES            44800022
         SR    R8,R7                    PFRSIZE OF BFR AFTER SHIFT      44900022
         STH   R8,PRFSIZE               PRFSIZE                         45000022
         SR    R8,R2                    R8 CONTAINS AMOUNT OF           45900022
         LA    R8,ONE(R8)               DATA (NO. OF BYTES) TO BE       46000022
*                                       SHIFTED                         46100022
         LA    R1,AVTPARM               EXIT TO                         46180022
         L     R15,AVTUI                AF TO                           46260022
         BALR  R14,R15                  CLOSE UP                        46340022
         CLC   SCBDEOB+1(3),AVTADBUF+1  IS THIS THE EOB BFR?            46420022
         BNE   CONTPR                   BR NO                           46440022
         MVC   SCBEOB(2),PRFSIZE        SET EOB OFFSET                  46460022
CONTPR   EQU   *                                                        46500022
         OI    PRFTQBCK+2,DEBLKBFR+NORDCON INDICATE THAT THIS IS A      46520022
*                                       DEBLOCKED BFR AND NO READ CONT  46540022
*                                       CAN BE DONE INTO THIS BFR       46560022
         TM    PRFTQBCK+2,EOMXBFR       PARTIAL CHAR STRING BFR?        46600022
         BO    COMP                     BR YES                          46680022
         MVC   PRFCRCD+1(2),AVTFZERO    REINITIALIZE AREA FOR COUNT     46920022
*                                       DATA TO ZERO                    47001022
         B     SKIPFE                   BR BACK TO PROCESS THIS NEW BFR 47002022
         EJECT                                                          47003022
*********************************************************************** 47005022
*      CALCULATE AND SAVE ISZE BEFORE LINKING BUFFER ON SETEOM Q      * 47010022
*********************************************************************** 47015022
SIZE     EQU   *                                                        47020022
         TM    PRFSTAT1,PRFNHDRN        HDR BFR?                        47030022
         BO    TXTIDL                   BR NO                           47035022
         MVC   PRFNHDR+2(1),LCBSENS0    SAVE SENSE BYTE                 47043022
         MVC   PRFCRCD(4),SCBERRST      SAVE SCB ERROR BYTES            47051022
TXTIDL   EQU   *                                                        47060022
         IC    R8,LCBISZE               NO. OF RESERVES                 47080022
SAVESIZE EQU   *                                                        47085022
         MVC   PRFSCAN(1),PRFSCAN+1     SAVE SCAN PTR                   47090022
         STC   R8,PRFSCAN+1             SAVE ISZE                       47095022
*********************************************************************** 47100022
*        THIS RTN LINKS A BFR ON A Q                                    47200022
*********************************************************************** 47300022
LOOP1    EQU   *                                                        47400022
         CLC   LINKOS(LINK,R5),AVTFZERO NO MORE BFR'S ON Q?             47500022
         BE    FOUND                    BR IF NO MORE                   47600022
         L     R5,DISP4(R5)             INCREMENT TO NEXT BFR IN CHAIN  47700022
         B     LOOP1                    BRANCH TO CHECK AGAIN           47800022
FOUND    EQU   *                                                        47900022
         IC    R8,DISP4(R5)             LINK BFR                        48000022
         ST    RPREFIX,DISP4(R5)        LAST                            48100022
         STC   R8,DISP4(R5)             ON Q                            48200022
         MVC   PRFLCB-IEDQPRF(3,RPREFIX),LCBSCBA PUT SCB ADDR IN BFR    48300022
         MVC   PRFLINK(3),AVTFZERO      SET BFR AS LAST ON CHAIN        48400022
         BR    R14                      RETURN                          48450022
*********************************************************************** 48503022
*        ADDRESS FINDER ROUTINE                                       * 48506022
*********************************************************************** 48509022
ADDRLOOP EQU   *                                                        48512022
         L     R7,PRFTIC-IEDQPRF(,R7)   POINT TO NEXT UNIT              48515022
         SH    R1,AVTKEYLE              SUBTRACT UNIT LENGTH            48518022
ENTERLOP EQU   *                                                        48521022
         CH    R1,AVTKEYLE              IS ITEM IN THIS UNIT?           48524022
         BH    ADDRLOOP                 NO, TEST NEXT UNIT              48527022
         LA    R1,AVTUMALN-1(R1,R7)     YES, ITEM ADDR                  48530022
         BR    R14                      RETURN                          48533022
*********************************************************************** 48536022
*        ROUTINE TO PREVENT ZERO BFR IF REMOVE=YES                    * 48539022
*********************************************************************** 48542022
CHECK    EQU   *                                                        48545022
         SR    R7,R7                    CLEAR REG                       48548022
         IC    R7,LCBISZE               NO. OF RESERVES                 48551022
         LA    R7,AVTTXTSZ(R7)          PLUS PREFIX SIZE                48554022
         TM    PRFSTAT1,PRFNHDRN        HDR BFR?                        48557022
         BO    NOTHDR1                  BR NO                           48560022
         LA    R7,TXTHDRDF(R7)          ADD TO SIZE                     48563022
NOTHDR1  EQU   *                                                        48566022
         CR    R0,R7                    EOM FIRST IN BFR                48569022
         BNE   RET1                     BR NO                           48572022
         LA    R7,AVTUMALN(R7,RPREFIX)  FIRST DATA BYTE IN BFR          48575022
         MVI   0(R7),EOT                MOVE IN EOT                     48578022
         LR    R7,R0                    SHOW SIZE                       48581022
         LA    R7,ONE(R7)               AS ONE                          48584022
         LR    R0,R7                    BYTE OF DATA                    48587022
RET1     EQU   *                                                        48590022
         BR    R14                      RETURN                          48593022
         EJECT                                                          48596022
FORCEOM  EQU   *                                                        48600022
         CLC   SCBDEOB+1(3),AVTADBUF+1  IS THIS THE EOB FUFFER          48607022
         BNE   PREPARE                  NO, PUT STCB IN LCB             48614022
         SR    R5,R5                   CLEAR REGISTER                   48621022
         ST    R5,LCBCPA+EOMSTCB+EOBBFR  CLEAR BFR SAVE AREA            48628022
         TM    SCBERR4,SCBTXTTN        IS TEXT ERROR PRESENT            48635022
         BO    PREPARE                 YES, FORCE EOM CONDITION         48642022
         TM    SCBERR1,SCBCUTFN         CUTOFF EXECUTED         OY00508 48644053
         BO    PREPARE                  YES, BRANCH             OY00508 48646053
         TM    LCBCSW+3,UNEX            EOT RECEIVED?                   48649022
         BO    PREPARE                  BRANCH IF EOT RECEIVED          48656022
         MVC   PRFNHDR+1(1),SCBBSCFM    SAVE FLAG BYTE                  48659022
         MVC   PRFXTRA+1(2),PRFSIZE     SET EOB OFFSET AS FLAG          48663022
         MVC   LCBCPA+EOMSTCB+EOBBFR+1(3),SCBDEOB+1  SAVE AS EOB BFR    48670022
         MVC   PRFOPCDE(8),LCBCPA+16   SAVE READ CONTINUE CCW           48677022
         B     STCBSET                  SKIP LINKAGE ON Q               48684022
PREPARE  EQU   *                                                        48691022
         LA    R5,SETEOMQ(RPARM)        BR TO LINK BFR ON               48700022
         BAL   R14,SIZE                 SETEOM Q                        48800022
STCBSET  EQU   *                                                        48850022
         LA    R5,POSTQ                 STCB RTN ADDR                   48900022
         ST    R5,LCBCPA+EOMSTCB        BUILD SETEOM STCB IN LCB        49000022
         MVI   LCBCPA+EOMSTCB,STCBVTO   PUT VTO IN STCB                 49100022
         MVI   LCBCPA+EOMSTCB+DISP4,STCBPRI  PRIORITY                   49200022
         MVC   LCBCPA+EOMSTCB+DISP8(8),STCBCD                           49300022
         LA    R0,SETEOMQ(RPARM)                                        49400022
         ST    R0,LCBCPA+EOMSTCB+SETEOMQ                                49500022
         LA    R2,SETEOMQ(RPARM)        SETEOM Q                        49600022
         B     CONT3                    BRANCH TO BEGIN CLEANING OFF    49670022
*                                       SETEOM Q                        49740022
         EJECT                                                          49810022
*********************************************************************** 49820022
*                      ENTRY POINT -                                  * 49830022
*                  SUBTASK TO REMOVE BUFFERS FROM SETEOM QUEUE        * 49840022
*********************************************************************** 49850022
         SPACE 3                                                        49860022
POSTQ    EQU   *                                                        49900022
         USING *,R15                                                    50000022
         LR    RAVT,R13                 AVT ADDR                SA68031 50070053
         SH    RAVT,X48                 REAL AVT ADDR           SA68031 50140053
         LR    RLCB4,R7                 AND LCB ADDR                    50210022
         L     RBASE,BASEBO             RESET MODULE BASE REGISTER      50302022
         DROP  R15                                                      50306022
         LH    R1,LCBTTCIN              TERM ENTRY KEY           S22026 50310022
         N     R1,AVTCLRHI              CLEAR HI ORDER HALF      S22026 50315022
         LTR   R1,R1                    LCBTTCIN ZERO            S22026 50320022
         BZ    GETSCB                   YES, SKIP CONC TEST      S22026 50325022
         SPACE                                                          50330022
         L     R15,AVTRNMPT             TNT CODE                 S22026 50335022
         BALR  R14,R15                  GO GET TERM ENTRY ADDR   S22026 50340022
         SPACE                                                          50345022
         USING IEDQTRM,R1               ADDRABILITY FOR TRM ENT  S22026 50350022
         TM    TRMDEVFL+1,TRMCONC+TRMLMD CONC OR ATTACHED TO CONCS22026 50358022
*                                       AND LMD OR MB SPECIFIED? S22026 50366022
         BNO   GETSCB                   NO, SCB ADDR OK, BRANCH  S22026 50375022
         DROP  R1                                                       50377022
         SPACE                                                          50380022
         MVC   LCBSCBA(THREE),LCBSCBDA  RESET SCB TO LINE SCB    S22026 50385022
         SPACE                                                          50390022
GETSCB   EQU   *                                                 S22026 50395022
         L     RSCB3,LCBSCBA-1          SCB ADDR                        50400022
         MVC   LCBSTCBA(3),LCBCPA+EOMSTCB+DISP5   REMOVE SETEOM STCB    50500022
*                                       FROM LCB STCB CHAIN             50600022
         L     R2,LCBCPA+EOMSTCB+SETEOMQ ADDR OF SETEOM Q - 4           50700022
         LR    RPARM,R2                 ADDR OF SETEOMQ-4               50720022
         LA    R1,SETEOMQ               OFFSET IN PARM LIST OF          50740022
*                                       SETEOMQ-4                       50760022
         SR    RPARM,R1                 ADDR OF SETEOM PARM LIST        50780022
CONT3    EQU   *                                                        50800022
         CLC   LINKOS(3,R2),AVTFZERO    ANY BFR'S Q'ED?                 50900022
         BE    RDCONT                   BR NO                           51000022
         L     R5,DISP4(R2)             PREPARE TO                      51100022
         LR    R8,R2                    SCAN Q                          51200022
LOOP     EQU   *                                                        51300022
         CLC   PRFLCB-IEDQPRF(3,R5),LCBSCBA BFR ON Q FOR THIS SCB?      51400022
         BE    BFRDELNK                 BR YES                          51500022
         CLC   LINKOS(3,R5),AVTFZERO    LAST BFR ON Q?                  51600022
         BE    RDCONT                   BR YES                          51700022
         LR    R8,R5                    PUT ADDR OF BFR IN R8           51800022
         L     R5,DISP4(R5)             BUMP TO NEXT BFR IN CHAIN       51900022
         B     LOOP                     BRANCH TO CONTINUE SCAN         52000022
BFRDELNK EQU   *                                                        52100022
         MVC   LINKOS(3,R8),LINKOS(R5)  PULL BFR OFF Q                  53500022
         IC    R8,PRFNBUNT-IEDQPRF(R5)  PUT LCB ADDR                    53600022
         ST    RLCB4,PRFNBUNT-IEDQPRF(R5)  BACK                         53700022
         STC   R8,PRFNBUNT-IEDQPRF(R5)  IN BFR                          53800022
         LR    RPREFIX,R5               SET RPREFIX TO THIS BFR         53900022
         MVC   LCBISZE(1),PRFSCAN+1     SET UP LCBISZE                  53920022
         MVC   PRFSCAN+1(1),PRFSCAN     RESTORE SCAN                    53921022
         MVI   PRFSCAN,AVTEZERO         POINTER                         53922022
         TM    PRFSTAT1,PRFNHDRN+PRFNLSTN  HDR AND LAST?                53923022
         BNZ   TESTMM                   BR NO                           53924022
         SR    R2,R2                    CLEAR REG                       53925022
         IC    R2,LCBISZE               NO. OF RESERVES                 53926022
         LA    R2,AVTHDRSZ+ONE(R2)      ADD PREFIX SIZE + 1             53927022
         CH    R2,PRFSIZE               DATA IN BFR?                    53928022
         BL    TESTMM                   BR YES                          53929022
         IC    R5,LCBLSPCI-1            SET BFR                         53929222
         ST    RPREFIX,LCBLSPCI-1       ADDR IN                         53929422
         STC   R5,LCBLSPCI-1            LSPCI                           53929622
         MVC   LCBCPA+EOMSTCB+DISP5(3),LCBSTCBA  LINK SETEOM STCB       53930022
         LA    R5,LCBCPA+EOMSTCB        PUT SETEOM STCB                 53931022
         IC    R8,LCBSTCBA-1            FIRST                           53932022
         ST    R5,LCBSTCBA-1            IN                              53933022
         STC   R8,LCBSTCBA-1            CHAIN                           53934022
         L     R2,AVTMSGS-1             GET VCON TABLE ADDR             53935022
         MVC   PRFQCBA(3),ONE(R2)       PUT BFR DISP QCB IN PREFIX      53936022
         MVI   PRFPRI,PRIDSPLB          SET PRIORITY                    53937022
         LR    R1,RPREFIX               GET RECB ADDR IN R1             53938022
         LA    R13,AVTSAVE2             SAVE2 ADDR                      53939022
         L     R11,AVTEA                ADDR OF DISPATCHER              53940022
         B     DSPPOST                  EXIT TO POST RECB               53941022
TESTMM   EQU   *                                                        53942022
         TM    SCBQTYPE,SCBBFMM         MID MSG ON?                     53943022
         BNO   SKIP6                    BR NO                           53944022
FREEBF   EQU   *                                                        53945022
         LA    R2,AVTBFRTB              BFR RETURN QCB                  53961522
         MVI   PRFPRI,PRIBFRTB          PRIORITY                        53962022
         ST    R2,PRFQCBA-1             DEST Q ADDR IN ELEMENT          53962522
         LR    R1,RPREFIX               BUFFER TO BE FREED              53963022
         LA    R13,AVTSAVE2             ADDR OF SAVE2                   53963522
         L     R11,AVTEA                BRANCH TO                       53964022
         BAL   R14,DSPPOSTR             DISPATCHER AND RETURN           53964522
         LA    R13,AVTSAVE2             SAVE2                           53965022
         LA    R2,SETEOMQ(RPARM)        ADDR SETEOM Q - 4               53965522
         B     CONT3                    BRANCH                          53966022
SKIP6    EQU   *                                                        53966522
         L     R8,LCBSTCBA-1            ADDR OF FIRST STCB              53968022
         CLI   0(R8),STCBVTO            IS SETEOM STCB ALREADY IN       53976022
*                                       CHAIN?                          53984022
         BE    SKIP3                    BR YES                          53992022
         MVC   LCBCPA+EOMSTCB+DISP5(3),LCBSTCBA  LINK SETEOM STCB       54000022
         LA    R5,LCBCPA+EOMSTCB        PUT SETEOM STCB                 54080022
         IC    R8,LCBSTCBA-1            FIRST                           54160022
         ST    R5,LCBSTCBA-1            IN                              54240022
         STC   R8,LCBSTCBA-1            CHAIN                           54320022
SKIP3    EQU   *                                                        54400022
         ST    RPREFIX,AVTADBUF         SET ADBUF TO THIS BFR           54500022
         TM    PRFSTAT1,PRFNHDRN        HDR BFR                         54510022
         BO    NOTHDR                   BR NO                           54520022
         SPACE                                                          54530022
         MVC   LCBSENS0(1),PRFNHDR+2    RESTORE SENSE BYTE              54537022
         MVC   SCBERRST(4),PRFCRCD      RESTORE BYTES                   54544022
         MVC   LCBTTCIN(2),PRFSRCE      RESET ORIGINIAL TTCIN           54553022
         B     PROCHDR                  SKIP TEXT MOVE                  54556022
         SPACE                                                          54560022
NOTHDR   EQU   *                                                        54570022
         TM    PRFTQBCK+2,EOBBUF        SRCE SAVED IN TQBCK             54572022
         BNO   SETSRCE                  BR NO                           54574022
         SPACE                                                          54576022
         MVC   LCBTTCIN(2),PRFTQBCK     RESTORE LAST TTCIN              54578022
SETSRCE  EQU   *                                                        54580022
         MVC   PRFSRCE(2),LCBTTCIN      SET TO SRCE OF LAST HDR         54582022
         SPACE                                                          54584022
PROCHDR  EQU   *                                                        54591022
         TM    PRFSTAT1,PRFNLSTN        EOT BFR?                        54600022
         BZ    RET                      BR YES                          54700022
         ST    RLCB4,0(RLCB4)           POINT LCB TO SELF FOR POSTING   55000022
         LR    R1,RLCB4                 ADDR OF LCB TO BE PLACED ON     55100022
*                                       READY Q                         55200022
         MVI   LCBPRI,PRIDESTQ-1        PRIORITY                        55300022
         L     R11,AVTEA                PREPARE                         55400022
         LA    R13,AVTSAVE2             TO                              55500022
         BAL   R14,DSPPOSTR             POST LCB TO SELF WITH SETEOM    55600022
*                                       STCB FIRST IN CHAIN             55700022
         B     RET2                     BRANCH                          55740022
RET      EQU   *                                                        55780022
         IC    R14,LCBLSPCI-1           SET BFR                         55820022
         ST    RPREFIX,LCBLSPCI-1       ADDR IN                         55860022
         STC   R14,LCBLSPCI-1           LSPCI                           55900022
RET2     EQU   *                                                        55940022
         LA    R13,AVTSAVE2             SAVE2 ADDRESS FOR RTNE  SA68031 55942053
         TM    AVTAFE30,AVTEFF          IS DUMP REQUESTED?      SA54935 55945022
         BZ    SKIPFE1                  BR IF NO                SA54935 55950022
         SPACE                                                          55955022
         L     R2,AVTAFE30              GET RTN ADDRESS         SA54935 55960022
         LR    R1,RPREFIX               SET BUFFER ADDRESS      SA54935 55965022
         LR    R14,RPARM                SAVE PARAMETER REG      SA54935 55970022
         BALR  RPARM,R2                 LINK TO BUFFER TRACE    SA54935 55975022
         SPACE                                                          55980022
         LR    RPARM,R14                RESTORE PARM REG        SA54935 55985022
SKIPFE1  EQU   *                                                SA54935 55990022
         L     R7,LCBDCBPT              DCB ADDR                        56100022
         L     R8,DCBMH-1-IHADCB(,R7)   MH ADDRESS              SA65376 56200052
         NC    ALTMH(3,R8),ALTMH(R8)    ALT MH SPECIFIED        SA65376 56206052
         BZ    SKIPFE2                  BRANCH IF NO            SA65376 56212052
         NC    LCBTTCIN(2),LCBTTCIN     TTCIN ZERO?             SA65376 56218052
         BZ    SKIPFE2                  BRANCH IF NO            SA65376 56224052
         LH    R1,LCBTTCIN              TNT OFFSET              SA65376 56230052
         N     R1,AVTCLRHI              CLEAR HIGH-ORDER HALF   SA65376 56236052
         L     R15,AVTRNMPT             CONVERSION LOGIC        SA65376 56242052
         BALR  R14,R15                  COMPUTE TERM ENTRY ADDR SA65376 56248052
         L     R1,TRMDESTQ-1-IEDQTRM(,R1) QCB ADDRESS           SA65376 56254052
         TM    QCBDSFLG-IEDQQCB(R1),QCBALTMH IS TERMINAL        SA65376 56260052
*                                       CONNECTED TO ALTERNATE  SA65376 56266052
*                                       MESSAGE HANDLER         SA65376 56272052
         BNO   SKIPFE2                  BRANCH IF NO            SA65376 56278052
         L     R8,PRIMH(,R8)            GET ALTMH QCB ADDRESS   SA65376 56284052
SKIPFE2  EQU   *                                                SA65376 56290052
         SR    R2,R2                    CLEAR REG2                      56300022
         IC    R2,PARMLEN(R8)           PICK UP LENGTH OF STARTMH       56400022
*                                       PARM LIST                       56500022
         LA    R8,AVTEZERO(R2,R8)       GET FIRST INSTRUCTION ADDR      56600022
         LH    R2,CONBASE               SET INCR VALUE IF MULT BASE     56700022
         LA    R15,RETOFF(RPARM)        RETURN ADDR TO MH PASSED        56710022
*                                       SETEOM PARM LIST                56720022
         SR    R1,R1                    SET                             56730022
         IC    R1,PRFNHDR+1             RETURN CODE                     56760022
         LR    RBASE,R8                 SET BASE                        56780022
         LNR   R0,R2                    SET MINUS CONDITION CODE        56800022
         BR    RBASE                    RETURN TO MH                    57000022
RDCONT   EQU   *                                                        57100022
         TM    LCBSTAT2,LCBRESP         READ CONT NECESSARY?            57200022
         BO    POSTBFR                 YES,  POST BUFFER OR ERB         57250022
         SPACE                                                          57300022
NOBFR    EQU   *                                                        57350022
         SPACE                                                          57400022
         LR    R1,RLCB4                 LCB FOR BD/2 FOR CLEANUP        57470022
         MVI   LCBPRI,PRIDESTQ-1        SET PRTY                        57540022
         OI    LCBSTAT1,LCBRCLLN       SET FLAG TO INDICATE BFRS FREED  57610022
         L     R7,IEDQBD2               BD/2 ADDR                       57680022
*                                       STCB ADDR                       57750022
         L     RSTCB,QCBSTCHN-1-IEDQQCB(R7)                             57820022
         L     R11,AVTEA                DISP ADDR                       57890022
         LA    R13,AVTSAVE2             ADDR OF SAVE AREA               57960022
         B     DSPBYPAS                 BYPASS TO BD/2                  58030022
         SPACE                                                          58100022
POSTBFR  EQU   *                                                        58200022
         L     RPREFIX,LCBCPA+EOMSTCB+EOBBFR   SET BFR FOR POST         58210022
         LTR   RPREFIX,RPREFIX         IS THERE AN EOB BFR              58220022
         BZ    NOBFR                   NO, POST LCB TO CLEANUP          58230022
         MVC   SCBBSCFM(1),PRFNHDR+1    RESTORE FLAG BYTE               58235022
         LH    R5,PRFXTRA+1             GET EOB OFFSET                  58240022
ARDCONT  EQU   *                                                        58242022
         MVC   LCBISZE,PRFCRCD          RESET LCBISZE                   58242122
         TM    PRFTQBCK+2,EOBBUF        SUBSEQUENT RD CONT IN THIS BFR  58242222
         BO    BRDCONT                  YES, TTCIN CORRECTLY SET        58242322
         SPACE                                                          58242422
         TM    PRFSTAT1,PRFNHDRN        HDR                             58242522
         BNO   HDR                      BR YES                          58242622
         SPACE                                                          58242722
         MVC   PRFTQBCK(2),LCBTTCIN     SAVE CURRENT TTCIN              58242822
         OI    PRFTQBCK+2,EOBBUF        INDICATE TTCIN SAVED IN BFR     58242922
HDR      EQU   *                                                        58243022
         MVC   LCBTTCIN(2),PRFSRCE      RESET TO ORIGINAL TTCIN         58243122
BRDCONT  EQU   *                                                        58243222
         CLI   LCBFLAG1,AVTEZERO        PLCB                     S22024 58245222
         BE    HAVEPLCB                 YES, BRANCH              S22024 58247222
         TM    PRFTQBCK+2,NORDCON       CAN THIS BFR BE POSTED FOR      58250022
*                                       READ CONT?                      58255022
         BZ    POSTHIS                  BR YES                          58260022
HAVEPLCB EQU   *                                                 S22024 58265022
         BAL   R14,HOLDEOB              NO, PUT ON HOLD Q               58270022
         SR    R5,R5                   CLEAR EOB OFFSET                 58280022
         N     R0,CLRBITS               CLEAR HIGH AND LOW BITS         58290022
         ST    R0,LCBCPA+12            RESET UNIT ADDRESS FOR KA        58310022
         LTR   RPREFIX,R0               IS THE NEXT BFR AVAILABLE       58330022
         BNZ   POSTOK                   POST NEXT BFR FOR READ CONT     58335022
         LA    R1,LCBERB                ERB ADDR                        58340422
         TM    LCBERBST,LCBDLNKN        IS DELINK SWITCH SET?           58340822
         BO    ERBFRE                   BRANCH NOT IN CHAIN             58341222
         LA    R8,AVTBFRTB-4            BFR RETURN QCB                  58341622
         LA    R2,CONST                 LOOP TWICE FOR BOTH BFR         58342022
*                                       RETURN Q AND READY Q            58342422
NEXT     EQU   *                                                        58342822
         LR    R7,R8                    SET TO NEXT ELEMENT             58343222
         L     R8,DISP4(,R7)            FIRST/NEXT ELEMENT IN CHAIN     58343622
         LA    R8,0(,R8)                CLEAR HIGH ORDER BYTE           58344022
         CLR   R8,R1                    IS THIS THE ERB?                58344422
         BE    REMOVERB                 BR IF ERB FOUND                 58344822
         C     R8,AVTDELAD              IS THIS THE DUMMY END           58345222
*                                       ELEMENT?                        58345622
         BNE   NEXT                     BR NO                           58346022
         LA    R8,AVTREADY-4            ADDR OF READY Q FOR LOOP        58346422
         BCT   R2,NEXT                  LOOP THRU THE READY Q           58346822
REMOVERB EQU   *                                                        58347222
         MVC   DISP5(3,R7),DISP5(R8)    REMOVE ERB FROM CHAIN           58347622
ERBFRE   EQU   *                                                        58348022
         MVI   LCBERBPY,PRIINTRQ        SET PRIORITY             S22024 58348500
         CLI   LCBFLAG1,AVTEZERO        PLCB                     S22024 58349022
         BE    PLCB                     YES, BRANCH              S22024 58349522
         L     R2,LCBDCBPT             GET DCB ADDRESS                  58350022
         IC    R2,DCBBUFIN-IHADCB(R2)   GET BFR COUNT FOR BUFIN         58360022
         SRL   R2,FOUR                  SHIFT OUT BUFOUT                58365022
         STC   R2,LCBERBCT             SET IN ERB BFR COUNT FOR GA      58370022
         NI    LCBERBCT,CLRHI           CLEAR HI HALF-BYTE              58375022
         MVI   LCBERBCT+1,AVTEZERO      ZERO DISABLED COUNT             58380022
         LA    R2,AVTBFREB             SET AVAIL BFR QCB  ADDR          58390022
         B     POSTERB                  BRANCH TO POST ERB              58410022
         SPACE 2                                                        58420022
PLCB     EQU   *                                                 S22024 58421000
         L     R2,AVTSAVTP              ADDR OF SECONDARY AVT    S22024 58422000
         L     R2,SAVTPLCB-IEDNSVTD(R2) ADDR OF PLCB REQUEST     S22024 58423000
         B     POSTERB                  POST ERB                 S22024 58424000
         SPACE                                                          58425000
POSTHIS  EQU   *                                                        58430022
         CLC   PRFSIZE(2),AVTFZERO      ZERO BFR?                       58433022
         BE    POSTOK                   BR YES                          58436022
         MVC   PRFNHDR(2),PRFSCAN      SAVE ORIGINAL SCAN POINTER       58440022
         MVC   PRFSCAN(2),PRFSIZE      RESET TO PREVENT TRANSLATE       58450022
         OI    PRFSTAT1,PRFCNCLN       PREVENT PROCESS OF FIRST BLOCK   58460022
POSTOK   EQU   *                                                        58470022
         SR    R7,R7                    CLEAR REG                       58470422
         LR    R8,RPREFIX               BFR ADDR                        58470822
         B     LOOP3                    BRANCH                          58471222
INLOOP   EQU   *                                                        58471622
         L     R8,PRFTIC-IEDQPRF(R8)    BUMP TO NEXT UNIT               58472022
DECRE    EQU   *                                                        58472422
         BCT   R1,INLOOP                FIND LAST UNIT                  58472822
         CLC   PRFTIC+1-IEDQPRF(2,R8),AVTFZERO  ANY MORE BFRS?          58473222
         BE    OUTCT                    BR NO                           58473622
         L     R8,PRFTIC-IEDQPRF(R8)    BUMP TO FIRST UNIT OF BFR       58474022
LOOP3    EQU   *                                                        58474422
         LA    R7,ONE(R7)               COUNT NO. OF BFRS IN CHAIN      58474822
         SR    R1,R1                    CLEAR REG                       58475222
         IC    R1,PRFNBUNT-IEDQPRF(R8)  NO. OF UNITS IN BFR             58475622
         B     DECRE                    BRANCH                          58476022
OUTCT    EQU   *                                                        58476422
         SR    R2,R2                    CLEAR REG                       58476822
         L     R8,LCBDCBPT              DCB ADDR                        58477222
         IC    R2,DCBBUFMA-IHADCB(R8)   BUFMAX                          58477622
         SR    R2,R7                    BUFMAX-NO. OF BFRS ON           58478022
*                                       LSPCI CHAIN                     58478422
         LTR   R2,R2                    BUFMAX OR MORE IN CHAIN SA59189 58478522
         BNP   NOMORE                   BR YES                  SA59189 58478622
         SPACE                                                          58478722
         STC   R2,LCBERBCT              PUT DIFFERENCE IN COUNT FIELD   58478822
NOMORE   EQU   *                                                SA59189 58479022
         OI    PRFSTAT1,PRFNLSTN        SET AS NOT LAST BUFFER          58480022
         MVC   LCBCPA+16(8),PRFOPCDE      RESET RD CONT CCW             58490022
         LA    R2,AVTACTIB             SET TO POST BUFFER TO            58500022
         LR    R1,RPREFIX                ACTIVATE QCB FOR RD CONT       58510022
         MVI   PRFPRI-IEDQPRF(R1),PRIACTIV  SET ELEMENT PRIORITY        58515022
         SPACE                                                          58520022
POSTERB  EQU   *                                                        58530022
         MVC   LCBTTBIN,LCBTTCIN        SET TTBIN FOR READ CONT  S22024 58535000
         IC    R0,LCBLSPCI-1            SET THIS                        58540022
         ST    RPREFIX,LCBLSPCI-1       BUFFER AS                       58550022
         STC   R0,LCBLSPCI-1            LSPCI                           58560022
         IC    R0,SCBDEOB               RESET                           58570022
         ST    RPREFIX,SCBDEOB          EOB BUFFER                      58580022
         STC   R0,SCBDEOB               ADDR                            58590022
         STH   R5,SCBEOB                RESET OFFSET TO EOB             58600022
         OI    LCBSTAT1,LCBCONT         TURN ON READ CONT BIT           58610022
         ST    R2,PRFKEY-IEDQPRF(R1)    SET TO POST ERB OR BFR          58660022
         L     R11,AVTEA                PREPARE                         58720022
         LA    R13,AVTSAVE2             TO                              58810022
         B     DSPPOST                  POST BFR FOR READ CONT          58900022
*                                       THRU MH                         58950022
**********************************************************************  59000022
MVPRE    MVC   UTCNTOFF(1,R2),UTCNTOFF(RPREFIX) MOVE             S22024 59100000
         DS    0F                                                       59200022
STCBCD   L     R15,LCBCPA-IEDQLCB+EOMSTCB(,R7) CODE TO PICK UP ADDR     59300022
*                                       OF 'POSTQ' FROM SETEOM STCB     59400022
*                                       IN THE LCB AND                  59500022
         BR    R15                      BRANCH                          59600022
         DS    0H                                                       59700022
X48      DC    X'0048'                  LENGTH OF SAVE AREA IN AVT      59800022
CONBASE  DC    H'4096'                  INCREMENT VALUE FOR MULTIPLE    59900022
*                                       BASE REGISTERS                  60000022
BASEBO   DC    A(IEDQBO)                ADDR OF IEDQBO                  60020022
IEDQBD2  DC    V(IEDQBD02)              BD/2 VCON                       60040022
CLRBITS  DC    X'00FFFFFC'              CLEAR HIGH AND LOW BITS         60046022
*                                       A READ CONT?                    60052022
         TAVTD                                                          60100022
         TLCBD                                                          60200022
         TPRFD                                                          60300022
         TQCBD                                                          60350022
         TSCBD                                                          60400022
         TTRMD                                                          60450022
         TDISPD                                                         60500022
         TPRIOR                                                         60600022
         DCBD  DSORG=TX                                                 60650022
         END                                                            60700022
