         TITLE 'IEDQBQ - QACTION MODULE'                                00100022
IEDQBQ   CSECT                                                          00200022
*A406300-406600                                                 SA59012 00210022
*A444100-444500                                                  S22027 00230022
*D000500                                                         S22027 00260022
*A681100-681500                                                  S99228 00270022
*C681000                                                         S99228 00280022
         ENTRY IEDQBQ02                                                 00300022
*********************************************************************** 00400022
*                                                                     * 00500022
* STATUS -- CHANGE LEVEL 0                                            * 00600022
*                                                                     * 00700022
* FUNCTION --                                                         * 00800022
*    THIS MODULE PERFORMS ANY OF THE FOLLOWING OPERATIONS BASED       * 00900022
*    UPON A USER PARAMETER LIST :                                     * 01000022
*    1- SET USER ERROR BIT IN USER ERROR WORD                         * 01100022
*    2- EXECUTION OF INMSG                                            * 01200022
*    3- EXECUTION OF OUTMSG                                           * 01300022
*    4- PREVENTION OF FURTHER OUTPUT (PENDING OPERATIONS NOT EXECUTED)* 01400022
*    5- CONTINUATION OF SENDING (PENDING OPERATIONS ARE EXECUTED)     * 01500022
*                                                                     * 01600022
* ENTRY POINTS --                                                     * 01700022
*                                                                     * 01800022
*         IEDQBQ -- WHEN ENTERED FROM QACTION                         * 01900022
*                                                                     * 02000022
*         BAL   1,*+12               POINT TO PARAMETER LIST          * 02100022
*         PARAMETER LIST                                              * 02200022
*         L     15,IEDQUI            USER INTERFACE ROUTINE           * 02300022
*         BALR  14,15                EXIT TO USER INTERFACE ROUTINE   * 02400022
*                                                                     * 02500022
*         IEDQBQ02 -- WHEN DUMMY LCB IS RETURNED                      * 02600022
*                                                                     * 02700022
* INPUT --                                                            * 02800022
*    WHEN ENTERED FROM QACTION MACRO VIA IEDQUI  :                    * 02900022
*                                                                     * 03000022
*    REGISTER 1 - POINTS TO A MACRO GENERATED PARAMETER LIST          * 03100022
*                                                                     * 03200022
*    ***************************************                          * 03300022
*    * INDEX  * LENGTH  *                  *                          * 03400022
*    *  TO    * OF PARM *    RESERVED      *                          * 03500022
*    * IEDQBQ * LIST    *                  *                          * 03600022
*    ***************************************                          * 03700022
*    *        *  ADDRESS OF USER WRITTEN   *                          * 03800022
*    * UNUSED *  STATUS ANALYSIS ROUTINE   *                          * 03900022
*    *        *                            *                          * 04000022
*    ***************************************                          * 04100022
*    <---------- 4 BYTES ------------------>                          * 04200022
*                                                                     * 04300022
*    REGISTER 3 - SCB ADDRESS                                         * 04400022
*    REGISTER 4 - LCB ADDRESS                                         * 04500022
*    REGISTER 6 - CURRENT BUFFER ADDRESS                              * 04600022
*    REGISTER 9 - AVT ADDRESS                                         * 04700022
*    REGISTER 12 - ADDRESS OF FIRST EXECUTABLE INSTRUCTION            * 04800022
*                                                                     * 04900022
*    WHEN ENTERED AT IEDQBQ02                                         * 05000022
*    REGISTER 1 - ADDRESS OF THE DUMMY LCB                            * 05100022
*    REGISTER 15 - THE ENTRY POINT ADDRESS                            * 05200022
*                                                                     * 05300022
* OUTPUT --                                                           * 05400022
*    N/A                                                              * 05500022
*                                                                     * 05600022
* EXTERNAL REFERENCES --                                              * 05700022
*         IEDQBD -- BUFFER DISPOSITION                                * 05800022
*                                                                     * 05900022
* EXITS,NORMAL --                                                     * 06000022
*                                                                     * 06100022
*         TO THE USER ROUTINE WHOSE ADDRESS IS PASSED IN THE MACRO    * 06200022
*         EXPANDED PARAMETER LIST. THIS USER ROUTINE ANALYZES THE     * 06300022
*         STATUS RETURNED BY THE TERMINAL AND RETURNS TO IEDQBQ WITH  * 06400022
*         REGISTER 1 POINTING TO A PARAMETER LIST WHICH INDICATES THE * 06500022
*         ACTION TO BE TAKEN FOR EACH TERMINAL IN THE LIST.           * 06600022
*                                                                     * 06700022
*         REGISTER 1 --                                               * 06800022
*                                                                     * 06900022
*         ****************************************************        * 07000022
*         * NUMBER  * FLAGS   *  ACTION *  TERMINAL NAME     *        * 07100022
*         *   OF    * AND     *   BYTE  *       OR           *        * 07200022
*         * ENTRIES * ENTRY   *         *  DEVICE I. D.      *        * 07300022
*         *         * LENGTH  *         *                    *        * 07400022
*         ****************************************************        * 07500022
*                    <--------- FORMAT OF EACH ENTRY ------->         * 07600022
*                                                                     * 07700022
*         NUMBER OF ENTRIES -- ONE BYTE FIELD APPEARING ONLY ONCE     * 07800022
*         AS THE FIRST BYTE OF THE PARAMETER LIST. IT CONTAINS        * 07900022
*         A COUNT OF THE NUMBER OF ENTRIES IN THE PARAMETER           * 08000022
*         LIST.                                                       * 08100022
*                                                                     * 08200022
*         FLAGS AND ENTRY LENGTH -- ONE BYTE FIELD                    * 08300022
*                                                                     * 08400022
*         FLAGS -- 4 BITS DEFINED AS FOLLOWS :                        * 08500022
*         BIT 0 - 0, DEVICE I. D. SPECIFIED                           * 08600022
*         BIT 0 - 1, TERMINAL NAME SPECIFIED                          * 08700022
*         BIT 1 - RESERVED                                            * 08800022
*         BIT 2 - RESERVED                                            * 08900022
*         BIT 3 - RESERVED                                            * 09000022
*                                                                     * 09100022
*         ENTRY LENGTH 4 BITS                                         * 09200022
*         BITS 4 THRU 7 -- LENGTH OF THIS ENTRY.                      * 09300022
*                                                                     * 09400022
*         ACTION BYTE -- INDICATES THE ACTION TO BE TAKEN FOR         * 09500022
*         THIS TERMINAL.                                              * 09600022
*                                                                     * 09700022
*         BIT 0 -- SET USER ERROR BIT IN USER ERROR WORD              * 09800022
*         BIT 1 -- RESERVED                                           * 09900022
*         BIT 2 -- RESERVED                                           * 10000022
*         BIT 3 -- RESERVED                                           * 10100022
*         BIT 4 -- TEMPORARY HOLD                                     * 10200022
*         BIT 5 -- FORCE OUTMSG                                       * 10300022
*         BIT 6 -- FORCE INMSG                                        * 10400022
*         BIT 7 -- CONTINUE SENDING ( PENDING OPERATIONS ARE EXEC. )  * 10500022
*                                                                     * 10600022
*         TERMINAL NAME OR DEVICE I. D. --                            * 10700022
*                                                                     * 10800022
*         TERMINAL NAME - 1 TO 8 BYTE EBCIDIC REPRESENTATION          * 10900022
*         DEVICE I. D.  - 1 TO 8 BYTES HEX. REPRESENTATION            * 11000022
*                                                                     * 11100022
*         TO THE DISPATCHER TO :                                      * 11200022
*         1 - POST A BUFFER TO IEDQBD FOR OUTMSG EXECUTION            * 11300022
*         2 - TO POST A BUFFER TO THE HOLD QCB (IEDQBQ03)             * 11400022
*         3 - TO DISPATCH THE NEXT SUBTASK                            * 11500022
*                                                                     * 11600022
*         REGISTER 1 -- THE ELEMENT ADDRESS (IF NEEDED)               * 11700022
*         REGISTER 7 -- THE ACB ADDRESS (IF NEEDED)                   * 11800022
*         REGISTER 11 - THE DISPATCHER'S ADDRESS                      * 11900022
*         REGISTER 13 - THE DISPATCHER'S SAVE AREA ( AVTSAVE2 )       * 12000022
*                                                                     * 12100022
*         TO THE NEXT SEQUENTIAL INSTRUCTION IS THE MESSAGE HANDLER   * 12200022
*         REGISTER 15 -- 0 TO INDICATE SUCCESSFULL EXECUTION          * 12300022
*                                                                     * 12400022
*                                                                     * 12500022
*         TO IGG019Q9 TO PUT THE CONC. SEND SCHED. IN THE LCB         * 12600022
*         REGISTER 7 -- DATA READY QUEUE ADDRESS                      * 12700022
*         REGISTER 11 - DISPATCHER'S ADDRESS                          * 12800022
*         REGISTER 13 - AVTSAVE2                                      * 12900022
*         REGISTER 14 - RETURN ADDRESS                                * 13000022
*         REGISTER 15 - ENTRY POINT IN IEDQBH                         * 13100022
*                                                                     * 13200022
* EXITS,ERROR --                                                      * 13300022
*                                                                     * 13400022
*         TO THE NEXT SEQUENTIAL INSTRUCTION IN THE MESSAGE HANDLER   * 13500022
*         REGISTER 1 -- ADDRESS OF THE INVALID ENTRY                  * 13600022
*         REGISTER 15 - X'04' TO INDICATE UNSUCCESSFUL EXECUTION.     * 13700022
*         NO ACTION WAS TAKEN FOR ANY ENTRY AFTER THE INVALID ENTRY.  * 13800022
*                                                                     * 13900022
*         TO THE NEXT INSTRUCTION IN THE MH                           * 14000022
*         REGISTER 1 -- ADDRESS OF THE CURRENT ENTRY IN PARM LIST     * 14100022
*         REGISTER 15 - X'08', NO BUFFERS, NO FURTHER ACTION TAKEN    * 14200022
*                                                                     * 14300022
* TABLES/WORK AREAS --                                                * 14400022
*    AVT                                                              * 14500022
*    BUFFER PREFIX                                                    * 14600022
*    DCB                                                              * 14700022
*    DEB                                                              * 14800022
*    DEVICE ID TABLE                                                  * 14900022
*    DRQ                                                              * 15000022
*    LCB                                                              * 15100022
*    QCB                                                              * 15200022
*    QCBE                                                             * 15300022
*    SCB                                                              * 15400022
*    TERMINAL ENTRY                                                   * 15500022
*                                                                     * 15600022
* ATTRIBUTES --                                                       * 15700022
*    SERIALLY REUSABLE, ENABLED, PROBLEM PROGRAM MODE                 * 15800022
*                                                                     * 15900022
* CHARACTER CODE DEPENDENCIES --                                      * 16000022
*                                                                     * 16100022
*    THE EXECUTION OF THIS MODULE DOES NOT DEPEND UPON ANY INTERNAL   * 16200022
*    REPRESENTATION OF THE EXTERNAL CHARACTER SET .                   * 16300022
*                                                                     * 16400022
* NOTES --                                                            * 16500022
*                                                                     * 16600022
*    THE BUFFER PREFIX IS USED AS A SAVE AREA TO SAVE THE DATA        * 16700022
*    NECESSARY TO SET UP FOR OUTMSG EXECUTION. THE DATA SAVED IS      * 16800022
*    1- ACTION BYTE FROM THE CURRENT ENTRY IN THE PARAMET5R LIST      * 16900022
*    2 - TNT INDEX FOR THIS TERMINAL                                  * 17000022
*    3 - SCB ADDRESS                                                  * 17100022
*    4 - QCB EXTENSION ADDRESS                                        * 17200022
*    5 - LCBSTAT2                                                     * 17300022
*    6 - QCB ADDRESS                                                  * 17400022
*    THIS DATA IS USED TO SET UP THE LCB, SCB, AND BUFFER PREFIX WITH * 17500022
*    THE FIELDS NECESSARY FOR OUTMSG EXECUTION                        * 17600022
*                                                                     * 17700022
*********************************************************************** 17800022
         EJECT                                                          17900022
*********************************************************************** 18000022
*        REGISTER EQUATES                                             * 18100022
*********************************************************************** 18200022
R0       EQU   0                        WORK REG                        18300022
RZERO    EQU   0                                                        18400022
RPARM    EQU   1                        PARAMETER LIST ADDRESS          18500022
R1       EQU   1                        WORK REG                        18600022
R2       EQU   2                        WORK REG                        18700022
RSCB     EQU   3                        SCB ADDRESS                     18800022
RLCB     EQU   4                        LCB ADDRESS                     18900022
RCURR    EQU   5                        CURRENT ENTRY IN PARM LIST      19000022
RPREFIX  EQU   6                        BUFFER ADDRESS                  19100022
RQCB     EQU   7                        QCB ADDRESS                     19200022
RTERM    EQU   8                        TERMINAL ENTRY ADDRESS          19300022
RAVT     EQU   9                        AVT ADDRESS                     19400022
R10      EQU   10                       WORK REG                        19500022
RQCBE    EQU   11                       QCB EXTENSION ADDRESS           19600022
RDISP    EQU   11                       DISPATCHER ADDRESSABILITY       19700022
RBASE    EQU   12                       BASE REG                        19800022
RSAVE    EQU   13                       SAVE AREA ADDRESS               19900022
RLINK    EQU   14                       LINKAGE REGISTER                20000022
R14      EQU   14                       WORK REG                        20100022
R15      EQU   15                       WORK REG                        20200022
*********************************************************************** 20300022
*        DSECT ADDRESSABILITY                                         * 20400022
*********************************************************************** 20500022
         USING *,RBASE                  MODULE BASE                     20600022
         USING IEDQSCB,RSCB             SCB BASE                        20700022
         USING IEDQLCB,RLCB             LCB BASE                        20800022
         USING IEDQPRF,RPREFIX                                          20900022
         USING IEDQQCB,RQCB             QCB BASE                        21000022
         USING IEDQTRM,RTERM                                            21100022
         USING IEDQAVTD,RAVT            AVT BASE                        21200022
         USING IEDQQCBE,RQCBE           QCBE BASE                       21300022
IEDQBQ   IEDHJN IEDQBQ01                                                21500022
         OC    PRFSIZE,PRFSIZE          ZERO LENGTH BUFFER              21800022
         BZ    RETURN                   YES, RETURN                     21900022
*********************************************************************** 22000022
*        EXIT TO USER WRITTEN STATUS ANALYSIS ROUTINE                 * 22100022
*********************************************************************** 22200022
         USING PARMLST,RPARM                                            22300022
         L     R15,PARMEXIT-1           USER EXIT ADDRESS               22400022
         STM   RLINK,RBASE,D12(RSAVE)   SAVE REGISTERS                  22500022
         BALR  RLINK,R15                EXIT TO USER ROUTINE            22600022
         LM    R2,RBASE,D28(RSAVE)      RESTORE REGISTERS               22700022
         DROP  RPARM                    RELEASE PARM REG                22800022
         USING ACTLST,RPARM             DECLARE ACTLST REG              22900022
         CLI   TRMNO,AVTEZERO           ANY TERMINALS IN LIST           23000022
         BE    RETURN                   NO, RETURN TO NSI IN MH         23100022
         MVC   NOENT,TRMNO              INITIALIZE COUNT                23200022
         DROP  RPARM                    RELEASE ACTLST REG              23300022
         LA    RCURR,ONE(RPARM)         ADDRESS OF FIRST ENTRY          23400022
         USING ACTLST,RCURR             GET NEW ACTLST REG              23500022
ANYACT   EQU   *                                                        23600022
         CLI   ACTBYTE,AVTEZERO         ANY ACTION THIS ENTRY           23700022
         BNE   CHKVAL                   YES, CHECK VALIDITY             23800022
*********************************************************************** 23900022
*        INDEX TO NEXT ENTRY IN PARAMETER LIST OR EXIT IF ALL ENTRIES * 24000022
*        HAVE BEEN PROCESSED.                                         * 24100022
*********************************************************************** 24200022
NXTENTRY EQU   *                        TRY NEXT ENTRY                  24300022
         SR    R0,R0                    ZERO INDEX REG                  24400022
         IC    R0,NOENT                 NO OF ENTRIES REMAINING         24500022
         BCTR  R0,AVTEZERO              SUBTRACT ONE                    24600022
         LTR   R0,R0                    ANY ENTRIES LEFT                24700022
         BZ    RETURN                   NO, EXIT                        24800022
         STC   R0,NOENT                 SAVE NO OF ENTRIES LEFT         24900022
         IC    R0,FLGLEN                GET ENTRY LENGTH                25000022
         N     R0,ELENMSK               ISOLATE LEN FROM FLAGS          25100022
         AR    RCURR,R0                 INDEX TO NEXT ENTRY             25200022
         B     ANYACT                   CHECK ACTION BYTE               25300022
CHKVAL   EQU   *                        CHECK ACTION BYTE               25400022
         TM    ACTBYTE,THLD+TRLSE       VALID ACTION BYTE               25500022
         BNO   SPEC                     YES, BRANCH                     25600022
*********************************************************************** 25700022
*        INVALID ENTRY                                                * 25800022
*********************************************************************** 25900022
INVENT   EQU   *                                                        26000022
         LR    RPARM,RCURR              POINT TO INVALID ENTRY          26100022
         LA    R15,AVTECD4              SET RETURN CODE                 26200022
         B     BADRTN                   EXIT                            26300022
*********************************************************************** 26400022
*        VALID ACTION BYTE                                            * 26500022
*********************************************************************** 26600022
SPEC     EQU   *                        CHECK LENGTH                    26700022
         SR    R2,R2                    ZERO LENGTH REG                 26800022
         IC    R2,FLGLEN                GET ENTRY LENGTH                26900022
         N     R2,ELENMSK               ISOLATE LENGTH                  27000022
         CH    R2,AVTHA3                ENTRY LENGTH LESS THAN MIN.     27100022
         BL    INVENT                   YES, INVALID ENTRY              27200022
         TM    FLGLEN,TRMNME            TERMINAL NAME SPECIFIED         27300022
         BZ    IDSPEC                   NO, DVC ID SPECIFIED            27400022
*********************************************************************** 27500022
*        TERMINAL NAME SPECIFIED                                      * 27600022
*********************************************************************** 27700022
         SH    R2,AVTHA2                CALC LENGTH OF TRM NAME         27800022
         STC   R2,CHARLEN               SAVE LENGTH IN PARM LIST        27900022
         LA    R2,TRMNAME               POINT TO TERMINAL NAME          28000022
         ST    R2,CHARADDR              SAVE ADDR IN PARM LIST          28100022
         LA    RPARM,BSLST              POINT TO PARAMETER LIST         28200022
         L     R15,AVTUI                ADDR USER INTERFACE RTN         28300022
         BALR  RLINK,R15                LINK TO IEDQUI                  28400022
         LTR   R1,R15                   TRM NAME FOUND                  28500022
         BZ    INVENT                   NO, EXIT ON ERROR               28600022
         STH   R1,TTCIN                 SAVE TNT INDEX                  28700022
         B     TENTRY                   TRM ENTRY ADDR FOUND            28800022
*********************************************************************** 28900022
*        DEVICE ID SPECIFIED                                          * 29000022
*********************************************************************** 29100022
IDSPEC   EQU   *                                                        29200022
         CH    R2,AVTHA3                DVCID ONE BYTE LONG             29300022
         BH    NOTFF                    NO, BRANCH                      29400022
         CLI   DVCID,AVTEFF             DVC ID EQUAL TO X'FF'           29500022
         BE    NXTENTRY                 YES, IGNORE ENTRY               29600022
NOTFF    EQU   *                                                        29700022
         LR    RPREFIX,R2               SAVE ID LENGTH                  29800022
         SH    RPREFIX,AVTHA2                                           29900022
         LH    RPARM,LCBTTCIN           GET TTCIN                       30000022
         N     RPARM,AVTCLRHI           CLEAR HI-ORDER                  30100022
         L     R15,AVTRNMPT             ADDR OF TNT CODE                30200022
         BALR  RLINK,R15                GET TERMINAL ENTRY ADDR         30300022
         LR    RTERM,R1                 SAVE TRM ENTRY ADDR             30400022
         TM    TRMDEVFL+ONE,TRMCONC     CONC OR ATTACHED TRM            30500022
         BZ    INVENT                   NO, INVALID ENTRY               30600022
         L     RQCB,TRMDESTQ-1          QCB ADDR                        30700022
         TM    QCBDSFLG,QCBDRQQ         DATA READY QUEUE                30800022
         BO    TBLADDR                  YES, EXTRACT DVC ID ADDR        30900022
         LR    RQCBE,RQCB               CALC QCB EXT ADDR               31000022
         AH    RQCBE,QCBEXTO                                            31100022
         L     RTERM,QCBECONC-1         CONC TRM ENTRY ADDR             31200022
TBLADDR  EQU   *                                                        31300022
         LA    RPARM,TRMOPNO            DVC DEP FLDS IF NO OPTION FLDS  31400022
         TM    TRMSTATE,TRMOPTFN        OPTION FIELDS USED              31500022
         BZ    NOOPT                    NO, BRANCH                      31600022
         SR    R2,R2                                                    31700022
         IC    R2,TRMOPNO               NO. OF OPTION FIELDS            31800022
         LA    RPARM,THREE(R2,RPARM)    ADDR OF DEV DEP FLDS            31900022
NOOPT    EQU   *                                                        32000022
         LH    R0,TRMDEVFL              DEVICE DEPENDENT FLAGS          32100022
         SLL   R0,HIORDER               SHIFT TO HIGH ORDER             32200022
         LA    R2,DIDTBLB               LOCATE PTR TO DVC ID TBL        32300022
         SR    R14,R14                                                  32400022
NXTFLD   EQU   *                                                        32500022
         SLL   R0,ONE                   SHIFT TO TEXT FOR FIELD         32600022
         LTR   R0,R0                    FIELD PRESENT                   32700022
         BNM   LPEND                    NO, BRANCH                      32800022
         IC    R14,AVTEZERO(RPARM)      GET LENGTH OF THIS FLD          32900022
         LA    RPARM,ONE(R14,RPARM)     INDEX TO NEXT FIELD             33000022
LPEND    EQU   *                                                        33100022
         BCT   R2,NXTFLD                LOOP TIL PROPER FLD LOCATED     33200022
         MVC   AVTDOUBL(L4),ONE(RPARM)  GET PTR TO DVC ID TABLE         33300022
         L     R2,AVTDOUBL              DVC ID TABLE ADDR               33400022
         USING IEDQDVCT,R2                                              33500022
         IC    R14,DVCENLTH             LENGTH OF EACH ENTRY            33600022
         SR    R0,R0                    ZERO INDEX REG                  33700022
         IC    R0,DVCNO                 NO OF ENTRIES IN DVC ID TBL     33800022
         LA    R2,DVCECW                POINT TO FIRST ENTRY            33900022
         SR    RPARM,RPARM              ZERO LENGTH REG                 34000022
NEXTID   EQU   *                                                        34100022
         IC    RPARM,DVCIDLTH           LENGTH OF THIS ID               34200022
         CR    RPARM,RPREFIX            ARE ID LENGTHS EQUAL            34300022
         BNE   NEXTONE                  NO, BRANCH                      34400022
         BCTR  RPARM,AVTEZERO           DECREMENT LENGTH BY ONE         34500022
         EX    RPARM,IDCLC              COMPARE DVC ID                  34600022
         BE    IDOK                     BRANCH EQUAL                    34700022
NEXTONE  EQU   *                                                        34800022
         LA    R2,AVTEZERO(R14,R2)      INDEX TO NEXT ENTRY             34900022
         BCT   R0,NEXTID                COMPARE NEXT DVC ID             35000022
         B     INVENT                   ID NOT FOUND, INVALID ENTRY     35100022
IDOK     EQU   *                                                        35200022
         LA    R14,TWO(RPARM,R2)        POINT TO TNT OFFSET             35300022
         MVC   TTCIN(TWO),AVTEZERO(R14) SAVE TNT OFFSET                 35400022
         LH    RPARM,TTCIN              PARM FOR TNT CODE               35500022
         N     RPARM,AVTCLRHI           CLEAR HIGH HALF WORD            35600022
TENTRY   EQU   *                                                        35700022
         L     R15,AVTRNMPT             ADDR OF TNT CODE                35800022
         BALR  RLINK,R15                GET TRM ENTRY ADDRESS           35900022
         DROP  RTERM                                                    36000022
         USING IEDQTRM,RPARM                                            36100022
*********************************************************************** 36200022
*        CAN QACTION BE EXECUTED FOR THIS TERMINAL                    * 36300022
*********************************************************************** 36400022
         TM    TRMDEVFL+ONE,TRMCONC     CONC OR ATTACHED TRM            36500022
         BZ    INVENT                   NO, INVALID ENTRY               36600022
         L     RQCB,TRMDESTQ-1          QCB ADDRESS                     36700022
         TM    QCBDSFLG,QCBDRQQ         DATA READY QUEUE                36800022
         BO    INVENT                   YES, INVALID ENTRY              36900022
         LR    RQCBE,RQCB                                               37000022
         AH    RQCBE,QCBEXTO            CALC QCB EXTENSION ADDR         37100022
         TM    QCBEFLG,QCBESTAT         STATUS ANALYSIS SPECIFIED       37200022
         BZ    INVENT                   NO, INVALID ENTRY               37300022
         DROP  RPARM                                                    37400022
         L     R15,QCBDCBAD-1           DCB ADDRESS                     37500022
         USING IHADCB,R15                                               37600022
         TM    DCBOFLGS,OPEN            DCB OPEN                        37700022
         BZ    NXTENTRY                 NO, BRANCH                      37800022
         L     R1,DCBDEBAD              DEB ADDRESS                     37900022
         TM    DEBOPATB-DEBNMSUB(R1),OUTPUT OPEN FOR OUTPUT             38000022
         BZ    NXTENTRY                 NO, BRANCH                      38100022
         USING IEDQTRM,RTERM                                            38200022
*********************************************************************** 38300022
*        LOCATE PROPER PRIORITY QCB EXTENSION IF QUEUEING BY PRIORITY * 38400022
*        LEVEL                                                        * 38500022
*********************************************************************** 38600022
         TM    QCBEFLG,QCBEOPL          QUEUEING BY PRTY LEVEL          38700022
         BZ    LFND                     NO, BRANCH                      38800022
         SR    R2,R2                    ZERO WORK REG                   38900022
         IC    R2,QCBENPLV              NO OF PRTY LEVEL EXTENSIONS     39000022
         SR    R0,R0                    ZERO LENGTH REG                 39100022
NXTPL    EQU   *                                                        39200022
         IC    R0,QCBELGTH              QCB EXTENSION LENGTH            39300022
         AR    RQCBE,R0                 FIRST/NEXT QCB EXT              39400022
         CLC   QCBETCIN(TWO),TTCIN      PROPER QCB EXT PRTY LEVEL       39500022
         BE    LFND                     YES, BRANCH                     39600022
         BCT   R2,NXTPL                 SEARCH ALL LEVELS               39700022
         B     NXTENTRY                 PROCESS NEXT ENTRY              39800022
LFND     EQU   *                                                        39900022
*********************************************************************** 40000022
*        INMSG EXECUTION                                              * 40100022
*********************************************************************** 40200022
EIMSG    EQU   *                                                        40300022
         TM    ACTBYTE,IMSG             EXECUTE INMSG                   40400022
         BZ    IMSGEXIT                 NO, BRANCH                      40500022
         L     RPREFIX,AVTADBUF         CURRENT BUFFER                  40600022
         TM    SCBQTYPE,SCBBFMM         IS MIDDLE MSG SET       SA59012 40630022
         BZ    IMSGEXIT                 NO, DO NOT SET EOM      SA59012 40660022
         NI    PRFSTAT1,PRFNLSTF        SET LAST BUFFER                 40700022
         NI    SCBQTYPE,AVTEFF-SCBBFMM  TURN OFF MIDDLE OF MSG          40730022
         NI    PRFTIC,AVTEFF-PRFEOMSG   RESET EOM                       40760022
         TM    ACTBYTE,UERR             SET USER ERROR BIT              40800022
         BZ    IMSGEXIT                 NO, BRANCH                      40900022
         OI    SCBERR3,SCBUSERN         SET USER ERROR BIT              41000022
IMSGEXIT EQU   *                                                        41100022
         TM    QCBEFLG,QCBEPEND         QACTION OPERATION IN PROCESS    41200022
         BO    NXTENTRY                 YES, SKIP ENTRY                 41300022
*********************************************************************** 41400022
*        LOCATE PROPER LCB IF TERMINAL NAME WAS SPECIFIED             * 41500022
*********************************************************************** 41600022
         TM    FLGLEN,TRMNME            TRM NAME SPECIFIED              41700022
         BZ    LCBFND                   NO, BRANCH                      41800022
         SR    R1,R1                    ZERO WORK REG                   41900022
         IC    R1,QCBRELLN              QCB STARTING RLN                42000022
         SR    R0,R0                    ZERO WORK REG                   42100022
         IC    R0,DCBEIOBX              LCB SIZE                        42200022
         MR    R0,R0                    STARTING LCB OFFSET             42300022
         AL    R1,DCBIOBAD              POINT TO IOB                    42400022
         LA    R2,LCBFLAG1-IEDQLCB      IOB OFFSET                      42500022
         SR    R1,R2                    BACK UP TO START OF LCB         42600022
         LR    RLCB,R1                  LCB ADDRESS                     42700022
         DROP  R15                                                      42800022
LCBFND   EQU   *                                                        42900022
*********************************************************************** 43000022
*        OUTMSG EXECUTION                                             * 43100022
*********************************************************************** 43200022
EOMSG    EQU   *                                                        43300022
         TM    ACTBYTE,OMSG             FORCE OUTMSG EXECUTION          43400022
         BZ    EOMEXIT                  NO, BRANCH                      43500022
         TM    QCBEFLG,QCBEHELD         HAS A CTB BEEN SENT             43600022
         BZ    EOMEXIT                  NO, CAN'T FORCE OUTMSG          43700022
EOMSG2   EQU   *                                                        43800022
         SR    RSCB,RSCB                                                43900022
         IC    RSCB,QCBSCBOF            SCB OFFSET                      44000022
         SR    R0,R0                                                    44100022
         IC    R0,AVTSCBSZ              SCB SIZE                        44200022
         MR    RSCB-ONE,R0              DISP OF PROPER SCB              44300022
         AL    RSCB,LCBSCBDA-1          SCB ADDRESS                     44400022
         TM    SCBQTYPE,SCBBFMM         MIDDLE OF MESSAGE        S22027 44410022
         BO    GETUNIT                  YES, OUTMSG CAN BE EXEC  S22027 44420022
         TM    QCBEFLG,QCBEOMSG         OUTMSG PENDING           S22027 44430022
         BZ    EOMEXIT                  NO, DONT EXECUTE OUTMSG  S22027 44440022
GETUNIT  EQU   *                                                 S22027 44450022
         L     RPREFIX,AVTBFREB         GET BUFFER UNIT                 44500022
         LA    RPREFIX,AVTEZERO(RPREFIX) CLEAR HI-ORDER                 44600022
         LTR   RPREFIX,RPREFIX          UNIT AVAILABLE                  44700022
         BNZ   DLNKBUF                  YES, BRANCH                     44800022
         LA    R15,AVTECD8              SET RETURN CODE                 44900022
         LR    RPARM,RCURR              CURRENT ENTRY IN PARM LIST      45000022
         B     BADRTN                   RETURN, NO BUFFERS AVAIL.       45100022
DLNKBUF  EQU   *                                                        45200022
         MVC   AVTBFREB+ONE(L3),PRFLINK DELINK BUFFER                   45300022
         LH    R2,AVTAVFCT              BUFFER COUNT                    45400022
         N     R2,AVTCLRHI              FORCE POSITIVE                  45500022
         BCTR  R2,AVTEZERO              SUBTRACT ONE                    45600022
         STH   R2,AVTAVFCT              RESTORE COUNT                   45700022
         MVC   PRFTIC(L4),CHAIN         SET INVALID TIC IN LINK FLD     45800022
         MVI   PRFPRI,PRIDSPLB          SET BUFFER PRTY                 45900022
         ST    RSCB,PRFSRCE             SAVE CURRENT SCB ADDR           46000022
         MVC   PRFDEST(TWO),TTCIN       SET TNT INDEX                   46100022
         ST    RQCBE,PRFSTAT1           SAVE PROPER QCB EXT ADDR        46200022
         ST    RQCB,PRFSCAN             SAVE QCB ADDRESS                46300022
         MVC   PRFISEQ(ONE),ACTBYTE     SAVE ENTRY IN BUFFER PREFIX     46400022
         MVC   PRFSTXT,LCBSTAT2         SAVE LCBSTAT2                   46500022
         OI    QCBEFLG,QCBEPEND         SET PENDING OPERATION           46600022
         NI    QCBEFLG,AVTEFF-QCBEOMSG-QCBEDATA RESET OUTMSG PENDING    46700022
         LA    RLINK,NXTENTRY           SET RETURN ADDRESS              46800022
         LA    R2,DLCB                  USE DUMMY LCB                   47000022
         ST    R2,PRFLCB-1              SET LCB ADDRESS IN BUFFER       47100022
         LR    R1,RQCB                  COMPUTE PRIMARY         SA52971 47120022
         AH    R1,QCBEXTO               EXTENSION               SA52971 47140022
         MVC   QCBEDEOB-IEDQQCBE(3,R1),PRFLCB SAVE LCB ADDR     SA52971 47160022
         MVI   PRFNBUNT,ONE             SET ONE UNIT                    47200022
         DROP  RLCB                                                     47300022
         USING IEDQLCB,R2               DECLARE LCB REG                 47400022
         LR    R1,RPREFIX               ELEMENT TO POST                 47450022
         TM    LCBTSTSW,LCBCONCT        DUMMY LCB BUSY                  47500022
         BZ    BDPOST                   NO, BRANCH                      47600022
         DROP  R2                       RELEASE LCB REG                 47700022
         USING IEDQLCB,RLCB             DECLARE LCB REG                 47800022
         LA    RQCB,IEDQBQ03            QCB ADDRESS                     47900022
*********************************************************************** 48000022
*        PLACE ELEMENT ON QUEUE.                                      * 48100022
*********************************************************************** 48200022
ENQUE    EQU   *                                                        48300022
         DROP  RQCBE                                                    48400022
         USING IEDQDISP,RDISP                                           48500022
         STM   R2,R14,SAVE+D8           SAVE REGISTERS                  48600022
         L     RDISP,AVTEA              DISPATCHER ADDRESS              48700022
         LA    RSAVE,AVTSAVE2           DISPATCHER'S SAVE AREA          48800022
         BAL   RLINK,DSPPRIOR           ENQUE ELEMENT                   48900022
         LM    R2,R14,SAVE+D8           RESTORE REGISTERS               49000022
         BR    RLINK                    PROCESS NEXT ENTRY              49100022
         DROP  RDISP                                                    49200022
         USING IEDQQCBE,RQCBE           DECLARE QCBE REG                49300022
EOMEXIT  EQU   *                                                        49400022
         LA    RLINK,NXTENTRY           SET RETURN ADDRESS              49500022
*********************************************************************** 49600022
*        HOLD FUNCTION                                                * 49700022
*********************************************************************** 49800022
EHLD     EQU   *                                                        49900022
         TM    ACTBYTE,THLD             HOLD TERMINAL                   50000022
         BZ    HLDEXIT                  NO, BRANCH                      50100022
         OI    QCBEFLG,QCBEHELD         MARK TERMINAL HELD              50200022
         BR    RLINK                    RETURN                          50300022
HLDEXIT  EQU   *                                                        50400022
*********************************************************************** 50500022
*        RELEASE FUNCTION                                             * 50600022
*********************************************************************** 50700022
ERLSE    EQU   *                                                        50800022
         TM    ACTBYTE,TRLSE            RELEASE TERMINAL                50900022
         BZ    RLSEEXIT                 NO, BRANCH                      51000022
         TM    QCBEFLG,QCBEDATA         DATA CURRENTLY BEING SENT       51100022
*                                       FROM THIS QUEUE                 51200022
         BO    RLSEEXIT                 YES, DON'T RELEASE              51300022
         TM    QCBEFLG,QCBEOMSG         OUTMSG PENDING                  51400022
         BO    EOMSG2                   YES, BRANCH                     51500022
         TM    QCBEFLG,QCBEHELD         TERMINAL HELD                   51530022
         BZ    RLSEEXIT                 NO, DONT RELEASE                51560022
         NI    QCBEFLG,AVTEFF-QCBEHELD  SET TERMINAL NOT HELD           51600022
         TM    QCBEFLG,QCBEOPL          QUEUEING BY PRIORITY LEV        51700022
         BZ    NOTBPL                   NO, BRANCH                      51800022
         XC    QCBETCIN,QCBETCIN        RESET QCB EXT TTCIN OFFSET      51900022
NOTBPL   EQU   *                                                        52000022
         STM   R0,RLINK,SAVE            SAVE REGISTERS                  52050022
         LR    RQCBE,RQCB                                               52100022
         AH    RQCBE,QCBEXTO            QCB EXTENSION ADDRESS           52200022
         L     RTERM,QCBECONC-1         CONC TRM ENTRY                  52300022
         L     RQCB,TRMDESTQ-1          DRQ ADDRESS                     52400022
         L     R15,AVTCSCH              CONCENTRATED SCHEDULER          52500022
         LA    R15,AVTEZERO(R15)        CLEAR HI-ORDER                  52600022
         SH    R15,AVTHA2               CAL BRANCH ENTRY ADDRESS        52700022
         AH    R15,AVTEZERO(R15)                                        52800022
         LA    RSAVE,AVTSAVE2           DISPATCHER'S SAVE AREA          53000022
         L     RDISP,AVTEA              DISPATCHER'S ADDRESS            53100022
         BALR  RLINK,R15                EFFECT TEMPORARY RELEASE        53200022
         LM    R0,RLINK,SAVE            RESTORE REGISTERS               53300022
RLSEEXIT EQU   *                                                        53400022
         BR    RLINK                    RETURN                          53500022
*********************************************************************** 53600022
*        POST BUFFERS TO BUFFER DISPOSITION FOR OUTMSG EXECUTION.     * 53700022
*********************************************************************** 53800022
BDPOST1  EQU   *                                                        53900022
         LA    RLINK,DSPEXIT            SET RETURN ADDRESS              54000022
         DROP  RPREFIX                                                  54100022
         USING IEDQPRF,RPARM                                            54200022
         L     R2,PRFLCB-1              LCB ADDRESS                     54300022
         L     RQCB,PRFSCAN             QCB ADDRESS                     54400022
         L     RQCBE,PRFSTAT1           QCB EXT ADDRESS                 54500022
BDPOST   EQU   *                                                        54600022
         DROP  RLCB                                                     54700022
         USING IEDQLCB,R2                                               54800022
         OI    LCBTSTSW,LCBCONCT        SET DUMMY LCB BUSY              54900022
         MVI   LCBSTAT1,LCBSENDN        SET SENDING                     55000022
         MVC   LCBSTAT2,PRFSTXT         RESET LCBSTAT2                  55100022
         MVC   LCBTTCIN(TWO),PRFDEST    SET LCBTTCIN                    55200022
         MVC   LCBSCBA(L11),PRFSRCE+ONE SET SCB, QCB, QCB EXT ADDR      55300022
         MVI   LCBERBST,LCBEOMSG+LCBDLNKN SET ERB AVAILABLE             55400022
         ST    RPARM,LCBLSPCI-1         SET BUFFER ADDRESS              55500022
         MVI   PRFSTAT1,ONE             SET TEXT LAST                   55600022
         L     RSCB,LCBSCBA-1           CURRENT SCB ADDRESS             55700022
         TM    QCBEFLG,QCBEOPL          QUEUEING BY PRTY LEVEL          55800022
         BZ    NOTPLQ                   NO BRANCH                       55900022
         MVC   DSCB+(SCBERRST-IEDQSCB)(L4),SCBERRST SET ERROR BITS      56000022
         LA    RSCB,DSCB                DUMMY SCB ADDRESS               56100022
         ST    RSCB,LCBSCBA-1           SET PSEUDO SCB ADDRESS          56200022
         LA    RQCB,AVTEZERO(RQCB)                                      56300022
         ST    RQCB,SCBDESTQ-1          SET QCB ADDRESS                 56400022
         MVC   SCBSCHDR,QCBEHDR         SET HDR ADDRESS                 56500022
         MVC   SCBFEFO,QCBEFEFO         SET FEFO POINTER                56600022
         MVC   SCBPRI,QCBEPRI           SET PRTY                        56700022
         MVC   SCBOSEQ,QCBEOSEQ         SET SEQUENCE NUMBER             56800022
         MVZ   SCBQTYPE,QCBEQTYP        SET QUEUE TYPE                  56900022
         NI    QCBEQTYP,AVTEFF-QCBEMM   RESET MIDDLE OF MSG             57000022
NOTPLQ   EQU   *                                                        57100022
         MVC   PRFCHDR,SCBSCHDR         SET PREFIX HDR ADDRESS          57200022
         LR    R15,RQCB                 CALC ADDR OF FIRST EXT          57300022
         AH    R15,QCBEXTO              FROM QCB INFO                   57400022
         MVC   SCBMACR,QCBEMACR-IEDQQCBE(R15) SET SCBMACR               57500022
         MVC   ACTBSAVE+ONE(ONE),PRFISEQ RESTORE ACTION BYTE            57550022
         TM    ACTBYTE,OMSG             FORCING OUTMSG                  57600022
         BZ    NOFORCE                  NO, BRANCH                      57700022
         OI    SCBERR4,SCBTRMLN         INDICATE TERMINAL ERROR         57800022
NOFORCE  EQU   *                                                        57900022
         TM    ACTBYTE,UERR             SET USER ERROR BIT              58000022
         BZ    NOTUSER                  NO, BRANCH                      58100022
         OI    SCBERR3,SCBUSERN         SET USER ERROR BIT              58200022
NOTUSER  EQU   *                                                        58300022
         DROP  R2                                                       58400022
         USING IEDQLCB,RLCB                                             58500022
         MVC   PRFRCB(L4),BDBASE        SET QCB ADDRESS FOR POST        58700022
         DROP  RPARM                                                    58800022
         USING IEDQPRF,RPREFIX                                          58900022
*********************************************************************** 59000022
*        PUT BUFFER ON READY QUEUE                                    * 59100022
*********************************************************************** 59200022
         STM   R0,R15,SAVE              SAVE REG.                       59300022
         LA    RSAVE,AVTSAVE2           DISPATCHERS SAVE AREA           59400022
         DROP  RQCBE                                                    59500022
         USING IEDQDISP,RDISP                                           59600022
         L     RDISP,AVTEA              DISPATCHER                      59700022
         BAL   RLINK,DSPPOSTR           ENQUE ELEMENT                   59800022
         DROP  RDISP                                                    59900022
         USING IEDQQCBE,RQCBE           DECLARE QCB REG                 60000022
         LM    R0,R15,SAVE              RESTORE REGS                    60100022
         BR    RLINK                    RETURN                          60200022
*********************************************************************** 60300022
*        LCB RETURNED AFTER OUTMSG EXECUTION                          * 60400022
*********************************************************************** 60500022
         DS    0F                       ALIGNMENT                       60600022
         ORG   *-8                      ORG BACK                        60700022
IEDQBQ02 EQU   *                        ENTRY                           60800022
         ORG                                                            60900022
         DC    AL1(DSPMCPL4)            SUBTASK ENTRY CODE              61000022
         DC    AL3(*-1)                 STCB ADDRESS                    61100022
         USING *,R15                                                    61200022
         L     RBASE,BQBASE             SET ADDRESSABILITY              61300022
         DROP  R15                                                      61400022
         LR    RAVT,RSAVE               RESET AVT ADDRESSABILITY        61500022
         SH    RAVT,SAVESZ              SUBTRACT                        61600022
         DROP  RLCB                                                     61700022
         USING IEDQLCB,RPARM            DECLARE LCB REG                 61800022
         MVI   LCBTSTSW,AVTEZERO        SET DUMMY LCB NOT BUSY          61900022
         MVI   LCBSENS0,AVTEZERO        CLEAN UP LCB                    62000022
         MVI   LCBCHAIN,AVTEZERO        ZERO CHAIN FIELD                62100022
         L     RSCB,LCBSCBA-1           CURRENT SCB ADDR                62200022
         SR    RZERO,RZERO              ZERO REG                        62300022
         ST    RZERO,SCBDEOB            CLEAR DEOB                      62400022
         STH   RZERO,SCBEOB             CLEAR EOB                       62500022
         STC   RZERO,SCBHBFNO           CLEAR HBFNO                     62600022
         NI    SCBQTYPE,255-SCBNREUS-SCBREUS-SCBCOREQ-SCBNORCL-SCBBFMM  62700022
*                                       RESET QTYPE                     62800022
         L     RQCBE,LCBINVPT-1         RESTORE QCB EXT ADDR            62900022
         L     RQCB,LCBTPCD             QCB ADDRESS                     63000022
         TM    QCBEFLG,QCBEOPL          PRIORITY LVL QUEUEING           63100022
         BO    NOCLEAR                  YES BRANCH                      63200022
         XC    QCBEDEOB(4),QCBEDEOB     CLEAR LCB ADDR          SA52971 63250022
         ST    RZERO,SCBERRST           CLEAR ERROR BYTES               63300022
NOCLEAR  EQU   *                                                        63400022
         DROP  RPARM                                                    63500022
         USING IEDQLCB,RLCB             DECLARE LCB REG                 63600022
         LA    RCURR,ACTBSAVE           ADDRESSABILITY                  63700022
         BAL   RLINK,EHLD               EXECUTE REMAINING FUNCTIONS     63800022
         NI    QCBEFLG,AVTEFF-QCBEPEND  RESET PENDING OPERATION         63900022
         L     RPARM,IEDQBQ03           NEXT ELEMENT                    64000022
         DROP  RPREFIX                                                  64100022
         USING IEDQPRF,RPARM                                            64200022
         MVC   IEDQBQ03+ONE(L3),PRFLINK DELINK ELEMENT                  64300022
         CLI   PRFPRI,AVTEZERO          ANY ELEMENTS ON QUEUE           64400022
         BNE   BDPOST1                  YES, BRANCH                     64500022
         DROP  RPARM                                                    64600022
         USING IEDQPRF,RPREFIX                                          64700022
DSPEXIT  EQU   *                                                        64800022
         LA    RSAVE,AVTSAVE2           DISPATCHERS SAVE AREA           64900022
         L     RDISP,AVTEA              DISP ADDRESS                    65000022
         DROP  RQCBE                    RELEASE QCB REG                 65100022
         USING IEDQDISP,RDISP                                           65200022
         B     DSPDISP                  DISPATCH NEXT TASK              65300022
*********************************************************************** 65400022
*        RETURN TO MH WITH RETURN CODE                                * 65500022
*********************************************************************** 65600022
RETURN   EQU   *                                                        65700022
         SR    R15,R15                  SET GOOD RETURN CODE            65800022
BADRTN   EQU   *                                                        65900022
         L     RLINK,AVTUI              USER INTERFACE MODULE           66000022
         B     D4(RLINK)                RETURN TO MSG HANDLER           66100022
*********************************************************************** 66200022
*        EXECUTED INSTRUCTIONS                                        * 66300022
*********************************************************************** 66400022
         USING IEDQDVCT,R2              DECLARE DVC TABLE REG           66500022
IDCLC    CLC   DVCCHAR(AVTEZERO),DVCID  COMPARE DVC ID'S                66600022
         DROP  R2                       RELEASE DVC TABLE REG           66700022
*********************************************************************** 66800022
*        BUFFERS GOTTEN TO EXECUTE OUTMSG ARE POSTED TO THIS QCB      * 66900022
*********************************************************************** 67000022
         DS    0F                       ALLIGNMENT                      67100022
IEDQBQ03 EQU   *                                                        67200022
         DC    AL1(2)                   QCB IDENTIFIER                  67300022
         DC    AL3(IEDDELEM)            ELEMENT CHAIN                   67400022
*********************************************************************** 67500022
*        PSEUDO LCB USED FOR OUTMSG EXECUTION                         * 67600022
*********************************************************************** 67700022
         DS    0F                                                       67800022
DLCB     EQU   *                                                        67900022
         DC    AL4(IEDQBQ02)            ADDRESS OF QCB                  68000022
         DC    XL48'00'                 FILLER                   S99228 68100022
         DC    AL4(DLCBX-DCBEIOBX+IHADCB) DUMMY DCB PTR          S99228 68110022
         DC    XL96'00'                 FILLER                   S99228 68120022
         DC    XL8'00'                  DUMMY LCB EXTENSION      S99228 68130022
DLCBX    EQU   *                                                 S99228 68140022
         DC    AL1(DLCBX-DLCB)          DUMMY LCB LENGTH         S99228 68150022
*********************************************************************** 68200022
*        PSEUDO SCB USED FOR OUTMSG EXECUTION WHEN QUEUEING BY        * 68300022
*        PRIORITY LEVEL IS BEING USED                                 * 68400022
*********************************************************************** 68500022
         DS    0F                                                       68600022
DSCB     EQU   *                        PSEUDO SCB                      68700022
         DC    3F'0'                    FILLER                          68800022
         DC    BL1'00001000'            CONC. SCB                       68900022
         DC    AL3(0)                   FILLER                          69000022
         DC    17F'0'                   FILLER                          69100022
*********************************************************************** 69200022
*        CONSTANTS AND EQUATES                                        * 69300022
*********************************************************************** 69400022
         DS    0F                                                       69500022
         ORG   *-4                      ELIMINATE UN-NEEDED SPACE       69600022
IEDDELEM EQU   *                                                        69700022
         ORG                                                            69800022
         DC    AL1(0)                   QCB IDENTIFIER                  69900022
         DC    AL3(IEDDELEM)            ELEMENT CHAIN                   70000022
BDBASE   DC    V(IEDQBD)                BUFFER DISPOSITION              70100022
ELENMSK  DC    F'15'                    TO ISOLATE LENGTH               70200022
SAVE     DC    16F'0'                   INTERNAL SAVE AREA              70300022
BSLST    DS    0F                       PARM LIST FOR BINARY SEARCH     70400022
         DC    AL1(9)                   INDEX TO IEDQA1                 70500022
         DC    AL1(8)                   LENGTH OF PARAMETER LIST        70600022
         DC    AL1(0)                   RESERVED                        70700022
CHARLEN  DC    AL1(0)                   LENGTH OF TERMINAL NAME         70800022
CHARADDR DC    AL4(0)                   ADDR OF TERMINAL NAME           70900022
BQBASE   DC    AL4(IEDQBQ)              MODULE BASE                     71000022
TTCIN    DC    H'0'                     TNT INDEX                       71100022
SAVESZ   DC    AL2(AVTSVSIZ)            REQUIRES HWRD ALIGNMENT         71200022
CHAIN    DC    X'08000002'              INVALID TIC                     71300022
NOENT    DC    AL1(0)                   NUMBER OF ENTRIES               71400022
         ORG   *-1                      BACK ONE BYTE                   71500022
ACTBSAVE EQU   *                                                        71600022
         ORG                                                            71700022
         DC    X'00'                    ACTION BYTE SAVE AREA           71800022
L11      EQU   11                       ELEVEN                          71900022
D4       EQU   4                        FOUR                            72000022
L3       EQU   3                        THREE                           72100022
L4       EQU   4                        FOUR                            72200022
D12      EQU   12                       TWELVE                          72300022
OPEN     EQU   X'10'                    TEST FOR OPEN DCB               72400022
OUTPUT   EQU   X'01'                    TO TEST DEB FOR OPEN FOR OUTPUT 72500022
D28      EQU   28                       TWENTY EIGHT                    72600022
ONE      EQU   1                        ONE                             72700022
RTNCDE4  EQU   4                        RETURN OF FOUR                  72800022
TWO      EQU   2                        TWO                             72900022
D8       EQU   8                        EIGHT                           73000022
THREE    EQU   3                        THREE                           73100022
DIDTBLB  EQU   8                        EIGHT                           73200022
HIORDER  EQU   15                       SHIFT FACTOR                    73300022
*********************************************************************** 73400022
*        DSECTS                                                       * 73500022
*********************************************************************** 73600022
         TAVTD                                                          73700022
         DCBD  DSORG=TX                                                 73800022
         TDEBD                                                          73900022
         TDISPD                                                         74000022
         TDRQD                                                          74100022
         TDVCIDTD                                                       74200022
         TLCBD                                                          74300022
         TPRFD                                                          74400022
         TPRIOR                                                         74500022
         TQCBD                                                          74600022
         TQCBED                                                         74700022
         TSCBD                                                          74800022
         TTRMD                                                          74900022
PARMLST  DSECT                          MACRO GENERATED PARM LIST       75000022
         DS    AL1                      VCON TABLE INDEX                75100022
PARMLEN  DS    AL1                      LENGTH OF LIST                  75200022
         DS    AL2                      RESERVED                        75300022
         DS    AL1                      RESERVED                        75400022
PARMEXIT DS    AL3                      USER EXIT ADDRESS               75500022
ACTLST   DSECT                          USER RETURNED PARM LIST         75600022
TRMNO    DS    0AL1                     LENGTH OF PARAMETER LIST        75700022
ENTRY    EQU   *                        START OF AN ENTRY               75800022
FLGLEN   DS    AL1                      FLAGS AND LENGTH OF ENTRY       75900022
TRMNME   EQU   X'80'                    TERMINAL NAME SPECIFIED         76000022
ACTBYTE  DS    BL1                      ACTION BYTE                     76100022
UERR     EQU   X'80'                    SET USFR ERROR BIT              76200022
THLD     EQU   X'08'                    STOP SENDING TO THIS TRM        76300022
OMSG     EQU   X'04'                    FORCE OUTMSG EXECUTION          76400022
IMSG     EQU   X'02'                    EXECUTE INMSG                   76500022
TRLSE    EQU   X'01'                    CONTINUE SENDING THIS TRM       76600022
TRMNAME  EQU   *                                                        76700022
DVCID    EQU   *                        DEVICE ID                       76800022
         END                                                            76900022
