IEDQBU   TITLE '''IEDQBU'' - CANCEL BLOCK'                              00100022
IEDQBU   CSECT                                                          00200022
*********************************************************************** 00400022
*TITLE   'IEDQBU'  CANCEL BLOCK                                         00600022
*                                                                     * 00800022
*STATUS -- CHANGE LEVEL 0                                             * 01000022
*                                                                     * 01200022
*FUNCTION -- WHEN TEXT ERRORS OCCUR ON THOSE LINES WHICH HAVE         * 01280022
*   MID-BATCH CAPABILITY CANCEL BLOCK WILL PERFORM VARIOUS            * 01360022
*   FUNCTIONS DEPENDING UPON THE OCCURENCE OF A PREVIOUS              * 01440022
*   GOOD EOB IN THIS MESSAGE, THE LOCATION OF THE BAD EOB IN          * 01520022
*   THE BUFFER, AND THE AMOUNT OF DATA BETWEEN THE EOB'S.             * 01600022
*   FOR THOSE LINES WHICH HAVE NOT SPECIFIED MID-BATCH CANCEL         * 01680022
*   BLOCK WILL PERFORM ESSENTIALLY THE SAME FUNCTIONS AS              * 01760022
*                   CANCEL MESSAGE.                                   * 01840022
*                                                                     * 02000022
*ENTRY POINTS -- IEDQBU - CANCEL BLOCK                                * 02200022
*   CALLING SEQUENCE -   LA   R12,IEDQAR                              * 02400022
*                        BR   R12                                     * 02600022
*                                                                     * 02800022
*INPUT -- IEDQBU IS CALLED BY BUFFER DISPOSITION (IEDQBD)             * 03000022
*   WITH THE FOLLOWING REGISTERS INITIALIZED                          * 03200022
*   R4 HAS THE LCB ADDRESS                                            * 03400022
*   R3 HAS THE SCB ADDRESS                                            * 03600022
*   R11 HAS THE DISPATCHER ADDRESS                                    * 03800022
*   R12 HAS THE ENTRY POINT ADDRESS                                   * 04000022
*   R13 HAS THE AVT SAVE2 ADDRESS                                     * 04200022
*   R1 HAS THE ADDRESS OF A LIST OF ELEMENTS TO BE POSTED             * 04400022
*                                                                     * 04600022
*EXTERNAL ROUTINES -- DISPATCHER CHAIN FUNCTION - PLACES THE          * 04800022
*   CHAIN OF ELEMENTS ON THE READY QUEUE.                             * 05000022
*                                                                     * 05200022
*EXITS-NORMAL -- TO THE DISPATCHER AT CHAIN                           * 05400022
*                                                                     * 05600022
*EXITS-ERROR  --  NONE                                                * 05800022
*                                                                     * 06000022
*TABLES/WORKAREAS -- AVT,LCB,SCB                                      * 06200022
*                                                                     * 06400022
*ATTRIBUTES -- REUSABLE, REFRESHABLE, ENABLED, RESIDENT               * 06600022
*                                                                     * 06800022
*NOTES -- THE OPERATION OF THIS MODULE DOES NOT DEPEND UPON A         * 07000022
*   PARTICULAR INTERNAL REPRESENTATION OF THE EXTERNAL CHARACTER      * 07200022
*   SET.                                                              * 07400022
*CHANGE ACTIVITY = AS FOLLOWS:                                          07400156
******************** MICROFICHE FLAGS *********************** SUPT CODE 07400256
*C253200                                                        OY04395 07400356
         EJECT                                                          07600022
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *         07800022
*                                                             *         08000022
*                  REGISTER EQUATES                           *         08200022
*                                                             *         08400022
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *         08600022
R0       EQU   0                                                        08800022
R1       EQU   1                        PARAMETER REG                   09000022
R2       EQU   2                        WORK REGISTER                   09200022
RSCB     EQU   3                        SCB ADDRESS                     09400022
RLCB     EQU   4                        LCB ADDRESS                     09600022
RPRF     EQU   5                        POST LIST ADDRESS               09800022
R6       EQU   6                        WORK REGISTER                   10000022
RQCB     EQU   7                        QCB ADDRESS                     10200022
R8       EQU   8                        WORK REGISTER                   10400022
R9       EQU   9                        WORK REGISTER                   10600022
R10      EQU   10                       WORK REGISTER                   10800022
RDSP     EQU   11                       DISPATCHER BASE                 11000022
RBASE    EQU   12                       BASE REG                        11200022
RAVT     EQU   13                       AVT SAVE2 BASE                  11400022
R14      EQU   14                                                       11600022
R15      EQU   15                                                       11800022
         SPACE 1                                                        12000022
         USING IEDQLCB,RLCB             LCB DSECT                       12200022
         USING IEDQPRF,RPRF             PREFIX DSECT                    12400022
         USING IEDQSCB,RSCB                                             12600022
         USING IEDQAVTD,RAVT                                            12800022
         USING IEDQDISP,RDSP                                            13000022
         USING *,RBASE                                                  13200022
         SPACE 1                                                        13400022
START    EQU   *                                                        13600022
IEDQBU   IEDHJN TAG                     GENERATE MODULE ID AND DATE     14300022
         ST    R1,LCBERBLK-1            ADD THE ERB TO THE POST         15000022
*                                         LIST                          15200022
         LR    RPRF,R1                  COPY THE ADDRESS OF THE         15400022
*                                         POST LIST                     15600022
         SR    R10,R10                  CLEAR A REGISTER FOR THE        15800022
*                                         PREVIOUS ELEMENT              16000022
         ST    R10,AVTPARM              CLEAR THE LINK FIELD            16200022
         ST    R10,AVTDOUBL             CLEAR WORK AREA                 16400022
         SPACE 2                                                        16600022
CHECK    EQU     *                                                      16800022
         NC    PRFLINK(3),PRFLINK       LAST ELEM ON LIST               17000022
         BZ    MBCHECK                  YES, BRANCH                     17200022
         LR    R10,RPRF                 COPY THE ADDRESS OF THE         17400022
*                                         PREVIOUS ELEMENT              17600022
         L      RPRF,PRFLINK-1          OF MSG - NO - GET NEXT ON       17800022
         B     CHECK                    GO CHECK NEXT ELEMENT           18000022
         EJECT                                                          18200022
MBCHECK  EQU   *                                                        18400022
         TM    SCBERR4,SCBSLCTN         ERROR DURING SELECTION          18600022
         BO    HAVEBFR                  YES, CANCEL MESSAGE             18800022
         SPACE 2                                                        19000022
         TM    SCBERR4,SCBTXTTN         IS THIS A TEXT ERROR            19200022
         BZ    HAVEBFR                  NO, BRANCH               S22025 19400022
       SPACE 2                                                          19600022
CHKMID   EQU   *                                                        19800022
         TM    LCBSTAT1,LCBINITN        IS THIS AN INITIATE MODE        20000022
*                                         MESSAGE                       20200022
         BO    HAVEBFR                  YES, DEFAULT TO A NORMAL        20400022
*                                         CANCELMSG                     20600022
         L     R2,SCBDESTQ-1            GET THE ADDRESS OF THE          20700022
*                                         DESTINATION QUEUE             20800022
         LA    R9,AVTBFRTB              GET THE ADDRESS OF              20810022
*                                         BUFFER RETURN                 20820022
         LA    R2,ZERO(R2)              CLEAR HIGH ORDER BYTE           20830022
         CLR   R2,R9                    IS THE DESTINATION THE          20840022
*                                         BUFFER RETURN QUEUE           20850022
         BE    HAVEBFR                  YES, BRANCH                     20860022
         TM    QCBDSFLG-IEDQQCB(R2),QCBDISK   ANY DISK QUEUEING         20900022
         BZ    HAVEBFR                  NO, DEFAULT TO CANCELMG         21000022
*                                         PROCESSING                    21200022
         TM    LCBSTAT2,LCBDIAL         IS THIS A DIAL LINE             21280022
         BZ    MIDBTEST                 NO, BRANCH                      21360022
         TM    LCBSTAT2,LCBNEGRP       DO WE STILL HAVE A DIAL          21440022
*                                         CONNECTION                    21520022
         BO    HAVEBFR                  NO, BRANCH                      21600022
MIDBTEST EQU   *                                                        21680022
         TM    SCBQTYPE,SCBBBFTM        IS MID-BATCH POSSIBLE ON        21800022
*                                         THIS LINE                     22000022
         BZ    HAVEBFR                  NO, THEN DEFAULT TO             22200022
*                                         CANCELMG PROCESSING           22400022
         EJECT                                                          22600022
         EJECT                                                          24600022
         NC    SCBDEOB+1(THREE),SCBDEOB+1    HAS THERE BEEN A           24800022
*                                         PREVIOUS GOOD EOB             25000022
         BZ    HAVEBFR                  NO, BRANCH                      25200022
         LA    RPRF,ZERO(RPRF)          CLEAR HIGH ORDER BYTE           25202022
         L     R9,SCBDEOB               GET THE LAST GOOD EOB           25204022
         LA    R9,ZERO(R9)              CLEAR HIGH ORDER BYTE           25206022
         SR    R8,R8                    CLEAR A WORK REGISTER           25208022
         CH    R8,SCBEOB                IS THERE ANY DATA IN THE        25210022
*                                         BUFFER                        25212022
         BNE   SETEOB                   YES, BRANCH                     25214022
         CLR   R9,RPRF                  DOES THE ERROR BUFFER           25216022
*                                         HAVE THE LAST GOOD EOB        25218022
         BNE   CURNTHDR                 NO, BRANCH                      25220022
         TM    PRFSTAT1,PRFNHDRN        IS THIS A HEADER BUFFER         25222022
         BZ    HAVEBFR                  YES, BRANCH                     25224022
         B     SETEOB                                                   25226022
CURNTHDR EQU   *                                                        25228022
         CLC   SCBDEOB+1(THREE),SCBDCHDR  IS THE BUFFER WITH THE        25230022
*                                         LAST GOOD EOB THE SAME        25232022
*                                         AS THE CURRENT HEADER         25234022
         BE    HAVEBFR                  YES, BRANCH                     25236022
SETEOB   EQU   *                                                        25238022
         MVI   SCBERR4,ZERO             CLEAR THE FOURTH SCB            25250022
*                                         ERROR BYTE                    25300022
         NI    SCBERR3,X'FF'-SCBFORMN-SCBXCEPN TURN OFF THE     OY04395 25320056
*                                         FORMAT ERROR AND UNIT         25340022
*                                         EXCEPTION BITS                25360022
*                                         EXCEPTION BIT                 25400022
         MVI   LCBSENS0,ZERO            CLEAR THE FIRST LCB             25450022
*                                         SENSE BYTE                    25500022
         OI    SCBQTYPE,SCBBFMM         TURN ON THE MIDDLE OF           25600022
*                                         MESSAGE BIT                   25800022
         LA    R2,AVTINOUT              ADDRESS OF DUMMY INEND/         26000022
*                                         OUTEND                        26200022
         IC    R0,SCBMBHEN-1            SAVE THE HIGH ORDER BYTE        26400022
         ST    R2,SCBMBHEN-1            PREVENT A MULTIPLE -            26600022
*                                         BUFFERED HEADER               26800022
         STC   R0,SCBMBHEN-1            RESTORE HIGH ORDER BYTE         27000022
         CH    R8,SCBEOB                IS THERE ANY DATA IN THE        28000022
*                                         BUFFER                        28200022
         BNE   TESTSAME                 YES, BRANCH                     28400022
         CLR   RPRF,R9                  ERROR BUFFER CONTAIN EOB        28600022
         BNE   RESET                    NO, BRANCH                      28800022
         SPACE 1                                                        29000022
         LA    R2,AVTBFRTB              BUFFER RETURN                   29200022
         ST    R2,PRFQCBA-1             SET DESTINATION QCB             29400022
         B     DSPERB                   POST LIST                       29600022
         EJECT                                                          29800022
TESTSAME EQU   *                                                        30000022
         CLR   RPRF,R9                  IS THE START OF THE             30200022
*                                         ERROR BUFFER THE LAST         30400022
*                                         GOOD EOB                      30600022
         BNE   RESET                    NO, BRANCH                      30800022
         MVC   PRFSIZE,SCBEOB           POST THE GOOD DATA TO           31000022
*                                         THE DESTINATION QUEUE         31200022
         SR    R14,R14                  CLEAR FOR COMPARE               31210022
         IC    R14,PRFSCAN              PRFSCAN FOR COMPARE             31220022
         CH    R14,PRFSIZE              IS PRFSCAN LARGER THAN          31230022
*                                         PRFSIZE                       31240022
         BNH   CLREOB1                  NO, BRANCH                      31250022
         LH    R9,SCBEOB                GET THE NUMBER OF BYTES         31260022
*                                         OF GOOD DATA                  31270022
         LA    R9,ONE(R9)               INCREMENT BY ONE                31280022
         STC   R9,PRFSCAN               RESET THE SCAN POINTER          31290022
CLREOB1  EQU   *                                                        31300022
         XC    SCBEOB,SCBEOB            CLEAR EOB TO MAINTAIN           31310022
*                                         THE INTEGRITY OF THE          31320022
*                                         EOB OFFSET FOR LMD AND        31330022
*                                         CONCENTRATOR                  31340022
         OI    PRFSTAT1,PRFNLSTN        SET  BUFFER AS NOT LAST         31400022
         B     DSPERB                   POST ELEMETN LIST               31600022
         EJECT                                                          31800022
RESET    EQU   *                                                        32000022
         XC    LCBERBLK(THREE),LCBERBLK REMOVE THE ERROR BLOCK          32200022
*                                         FROM THE POST LIST            32400022
         LTR   R10,R10                  WAS THERE A PREVIOUS            32600022
*                                         ELEMENT                       32800022
         BZ    SAVERROR                 NO, BRANCH                      33000022
         ST    R1,LCBERBLK-1            CHAIN THE POST LIST OFF         33200022
*                                         THE ERB                       33400022
         XC    PRFLINK-IEDQPRF(THREE,R10),PRFLINK-IEDQPRF(R10)          33600022
*                                       CLEAR THE LINK FIELD OF         33800022
*                                         THE PREVIOUS ELEMENT          34000022
SAVERROR EQU   *                                                        34200022
         ST    RPRF,LCBERCCW            SAVE THE ADDRESS OF THE         34400022
*                                         ERROR BUFFER                  34600022
*                                         THE RECALL                    34800022
         MVC   PRFQCBA(SEVEN),SCBDNSEG  SAVE DNSEG AND CLSEG IN         35000022
*                                         THE ERROR BUFFER              35200022
         EJECT                                                          35400022
RECALL   EQU   *                                                        35600022
         XC    SCBNTXT,SCBNTXT          CLEAR NEXT TEXT ADDRESS         35800022
         XC    SCBXTRA,SCBXTRA          CLEAR NEXT UNIT ADDRESS         36000022
         MVI   SCBDEOB,AVTEZERO         CLEAR INSERT OFFSET             36200022
         OI    LCBSTAT1,LCBRCLLN        SET THE RECALL BIT              36400022
         MVI   LCBERBST,ZERO            CLEAR THE ERB STATE             36600022
         MVC   LCBLINK-1(FOUR),SCBDEOB  SAVE DEOB DURING THE            36800022
*                                         RECALL                        37000022
         MVI   LCBERBPY,PRIRECAL        SET THE RECALL PRIORITY         37200022
         LA    R2,D256                  REQUEST ONE BUFFER FOR          37400022
         STH   R2,LCBERBCT              SET THE ERB COUNT FIELD         37600022
         LA    R8,RECALQCB              ADDRESS OF THE QCB TO           37800022
*                                         WHICH THE RECALLED            38000022
*                                         BUFFER WILL BE POSTED         38200022
         ST    R8,LCBRCQCB              SET THE RECALL ADDRESS          38400022
         XC    LCBERBCH(THREE),LCBERBCH CLEAR FOR THE RECALLED          38600022
*                                         BUFFER ADDRESS                38800022
         LA    R2,AVTDSIOB              ADDRESS OF DISK I/O QCB         39000022
         B     POSTERB                  POST ERB AND BUFFERS            39200022
         EJECT                                                          39400022
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *         39430022
*                                                             *         39460022
*        THE RECALLED BUFFER WILL BE POSTED TO THIS QCB       *         39490022
*                                                             *         39520022
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *         39550022
         DS    0F                                                       39600022
RECALQCB EQU   *-8                                                      39800022
         DC    AL1(DSPMCPL4),AL3(*-1)   STCB THAT GETS CONTROL WHEN     39900022
*                                       BUFFER RECALLED                 40000022
         SPACE 2                                                        40200022
BUFPOST  EQU   *                                                        40400022
         USING *,R15                                                    40600022
         L     RBASE,BASE               SET ADDRESSABILITY              40800022
         DROP  R15                                                      41000022
         USING START,RBASE                                              41200022
         SPACE 2                                                        41400022
         LA    R0,LCBERB-IEDQLCB        GET THE ERB OFFSET              41600022
         SR    R1,R0                    COMPUTE THE LCB ADDRESS         41800022
         LR    RLCB,R1                  SET LCB BASE REGISTER           42000022
         L     RSCB,LCBSCBA-1           SET SCB BASE REGISTER           42200022
         MVC   SCBUNTCT,SCBDEOB         RESTORE THE UNIT COUNT          42400022
         MVC   SCBDEOB,LCBLINK-1        RESET SCBDEOB                   42600022
         L     RPRF,LCBERBCH-1          LOAD THE ADDRESS OF THE         42800022
*                                         RECALLED BUFFER               43000022
         TM    PRFSTAT1,PRFNHDRN        IS THIS A HEADER BUFFER         43020022
         BO    RESETLCB                 NO, BRANCH                      43040022
         SR    R8,R8                    CLEAR A WORK REGISTER           43060022
         CH    R8,SCBEOB                IS THERE ANY DATA IN THE        43080022
*                                         BUFFER                        43100022
         BE    HAVEBFR                  NO, BRANCH                      43120022
RESETLCB EQU   *                                                        43140022
         NI    LCBERBST,LCBEOMSG        RESET STATUS EXCEPT FOR         43200022
*                                         EOM                           43400022
         OI    LCBERBST,LCBDLNKN        MARK THE ERB POSTABLE           43600022
         NI    PRFSTAT1,AVTEFF-PRFDUPLN RESET THE DUPLICATE BIT         43800022
         NI    LCBSTAT1,AVTEFF-LCBRCLLN RESET THE RECALL FLAG           44000022
         XC    AVTPARM,AVTPARM          CLEAR POST LIST POINTER         44200022
         L     R2,SCBDESTQ-1            GET THE DESTINATION             44400022
*                                         QUEUE ADDRESS                 44600022
         MVZ   SCBQTYPE,QCBDSFLG-IEDQQCB(R2) RESTORE QTYPE              44800022
         TM    SCBQTYPE,SCBREUS+SCBNREUS     ANY IDSK QUEUEING          45000022
         BZ    NODISK                   NO, BRANCH                      45200022
         XI    SCBQTYPE,SCBREUS+SCBNREUS     BITS ARE REVERSED          45400022
NODISK   EQU   *                                                        45600022
         L     R15,LCBERCCW             GET THE ADDRESS OF THE          45700022
*                                         ERROR BLOCK                   45800022
         MVC   SCBDNSEG(SEVEN),PRFQCBA-IEDQPRF(R15)                     45900022
*                                       RESTORE DNSEG AND CLSEG         46000022
         MVI   PRFPRI,PRIDESTQ-1        SET THE POST PRIORITY           46200022
         TM    PRFSTAT1,PRFNHDRN        IS THE RECALLED BUFFER          46800022
*                                         A HEADER                      47000022
         BO    HDROK                    NO, BRANCH                      47200022
         MVC   PRFSIZE,SCBEOB           ADJUST PRFSIZE TO THE           47210022
*                                         LAST GOOD EOB                 47220022
         SR    R14,R14                  CLEAR FOR COMPARE               47230022
         IC    R14,PRFSCAN              PRFSCAN FOR COMPARE             47240022
         CH    R14,PRFSIZE              IS PRFSCAN LARGER THAN          47250022
*                                         PRFSIZE                       47260022
         BNH   CLREOB2                  NO, BRANCH                      47270022
         LH    R9,SCBEOB                GET THE NUMBER OF BYTES         47280022
*                                         OF GOOD DATA                  47290022
         LA    R9,ONE(R9)               INCREMENT BY ONE                47300022
         STC   R9,PRFSCAN               RESET THE SCAN POINTER          47310022
CLREOB2  EQU   *                                                        47320022
         XC    SCBEOB,SCBEOB            CLEAR EOB TO MAINTAIN           47330022
*                                         THE INTEGRITY OF THE          47340022
*                                         EOB OFFSET FOR LMD AND        47350022
*                                         CONCENTRATOR                  47360022
         BAL   R14,POSTLIST             BRANCH TO LIST ROUTINE          47400022
         EJECT                                                          47600022
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *         47800022
*                                                             *         48000022
*        THE LAST GOOD EOB WAS IN THE HEADER BUFFER           *         48200022
*        WE WANT TO CANCEL THE MESSAGE AND POST THE           *         48400022
*        RECALLED BUFFER BACK TO THE DESTINATION              *         48600022
*        QUEUE WITH PRFSIZE ADJUSTED TO REFLECT THE           *         48800022
*                       CHECKED DATA                          *         49000022
*                                                             *         49200022
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *         49400022
         LR    RPRF,R15                 COPY THE ADDRESS OF THE         49500022
*                                         HEADER BUFFER TO BE           49600022
*                                         CANCELED                      49700022
         MVI   PRFSTAT1,PRFCNCLN+PRFNHDRN    SET THE                    50000022
*                                         STATUS TO CANCEL THE          50200022
*                                         ERROR BLOCK                   50400022
         MVI   PRFPRI,PRIBFRTB          SET THE PRIORITY                50500022
         BAL   R14,POSTLIST             ADD TO POST LIST                50600022
POSTALL  EQU   *                                                        50800022
         ST    RPRF,LCBERBLK-1          ADD TO ERB                      51000022
         B     DSPERB                   EXIT TO POST ERB AND            51200022
*                                         BUFFERS                       51400022
         EJECT                                                          51600022
HDROK    EQU   *                                                        51800022
         MVI   AVTDOUBL,ZERO            CLEAR FOR LATER TEST            52000022
         L     R9,SCBCCHDR-1            LOAD THE ADDRESS OF THE         52200022
*                                         CURRENT CORE HEADER           52400022
         MVC   SCBDNSEG,PRFCRCD         SET DNSEG TO THE LAST           52600022
*                                         GOOD EOB                      52800022
         TM    SCBQTYPE,SCBCOREQ        CORE QUEUEING                   53000022
         BZ    ERRPOST                  NO, BRANCH                      53200022
         TM    PRFKEY-IEDQPRF(R9),COPYLOST   HAS THE CORE COPY          53400022
*                                         BEEN LOST                     53600022
         BO    ERRPOST                  YES, BRANCH                     53800022
         TM    SCBERR3,SCBLOSTN         LOST FROMCORE QUEUE             54000022
         BO    ERRPOST                  BRANCH IF YES                   54200022
*                                                                       54400022
NXTBFRA  EQU   *                                                        54600022
         CLC   PRFCRCD,PRFCRCD-IEDQPRF(R9)   IS THE CURRENT             54800022
*                                         RECORD POINTER OF THE         55000022
*                                         RECALLED BUFFER EQUAL         55200022
*                                         TO THE CURRENT RECORD         55400022
*                                         POINTER OF THE CURRENT        55600022
*                                         CORE HEADER                   55800022
         BE    NEXTBUFR                 YES, BRANCH                     56000022
         MVC   SCBCLSEG(THREE),PRFCORE-IEDQPRF(R9)    GET THE           56200022
*                                         LAST BUFFER ADDRESS           56400022
         MVC   AVTDOUBL+1(THREE),PRFNTXT-IEDQPRF(R9)  SET UP THE        56600022
*                                         NEXT BUFFER ADDRESS           56800022
         L     R9,AVTDOUBL              GET IT FROM THE SCRATCH         57000022
*                                         AREA                          57200022
         B     NXTBFRA                  DO THE COMPARE AGAIN            57400022
         SPACE 2                                                        57600022
NEXTBUFR EQU   *                                                        57800022
         L     R9,SCBCLSEG-1            GET THE ADDRESS OF THE          58000022
*                                         LAST BUFFER IN THE QUE        58200022
         MVC   AVTDOUBL+1(THREE),PRFNTXT-IEDQPRF(R9)  MOVE THE          58400022
*                                         ADDRESS OF THE NEXT           58600022
*                                         BUFR TO A WORD BOUNDRY        58800022
         L     R10,AVTDOUBL             ADDRESS OF THE NEXT BUFR        59000022
         XC    PRFNTXT-IEDQPRF(THREE,R9),PRFNTXT-IEDQPRF(R9)            59200022
*                                       CLEAR THE NEXT BUFFER           59400022
*                                       ADDRESS TO INDICATE THE         59600022
*                                       END OF THE POST LIST            59800022
         SR    R0,R0                    CLEAR A COUNT REGISTER          60000022
         LR    RPRF,R10                 SAVE THE BUFFER ADDRESS         60200022
NXTBUFER EQU   *                                                        60400022
         LR    R6,R10                   COPY THE BUFFER ADDRESS         60600022
         SR    R8,R8                    CLEAR A COUNT REGISTER          60800022
         IC    R8,PRFNBUNT-IEDQPRF(R10) NUMBER OF UNITS/BUFFER          61000022
         AR    R0,R8                    KEEP A TOTAL UNIT COUNT         61200022
         BAL   R14,NXTUNIT              DECREMENT THE UNIT COUNT        61400022
         SPACE 2                                                        61600022
         L     R10,PRFTIC-IEDQPRF(R10)  GET THE NEXT UNIT ADDR          61800022
NXTUNIT  EQU   *                                                        62000022
         BCTR  R8,R14                   LOOP THRU A BUFFER              62200022
         SPACE 2                                                        62400022
         MVC   AVTDOUBL+1(THREE),PRFNTXT-IEDQPRF(R6)                    62600022
*                                       MOVE NEXT BUFFER ADDRESS        62800022
*                                         FROM THIS BUFFER              63000022
         MVC   PRFTIC+1-IEDQPRF(THREE,R10),AVTDOUBL+1                   63200022
*                                       CHAIN THE NEXT BUFFER TO        63400022
*                                       THE LAST UNIT OF THE            63600022
*                                       PREVIOUS BUFFER                 63800022
         L     R10,AVTDOUBL             GET THE ADDRESS OF THE          64000022
*                                         NEXT BUFFER                   64200022
         LTR   R10,R10                  IS THIS THE END OF THE          64400022
*                                         BUFFER CHAIN                  64600022
         BNZ   NXTBUFER                 NO, BRANCH                      64800022
         EJECT                                                          65000022
         STC   R0,PRFNBUNT-IEDQPRF(RPRF)  TOTAL NUMBER OF UNITS         65200022
*                                         TO BE FREED                   65400022
         L     R2,AVTCADDR              GET THE COUNT OF         S22025 65500022
*                                         AVAILABLE MSUNITS      S22025 65600022
         SR    R2,R0                    SUBTRACT THE UNITS TO BE S22025 65700022
*                                         FREED                  S22025 65800022
         ST    R2,AVTCADDR              RESTORE THE COUNT OF     S22025 65900022
*                                         AVAILABLE MSUNITS      S22025 66000022
         LA    R2,AVTBFRTB              ADDRESS OF BUFFER RETURN S22025 66100022
         MVI   PRFPRI,PRIBFRTB          SET THE POST PRIORITY           66400022
         BAL   R14,POSTLIST             ADD THE BUFFERS TO THE          66600022
*                                         POST LIST                     66800022
ERRPOST  EQU   *                                                        67000022
         L     RPRF,LCBERBCH-1          GET THE ADDRESS OF THE          67200022
*                                         RECALLED BUFFER               67400022
         MVI   PRFPRI,PRIDESTQ          SET THE POST PRIORITY           67600022
         L     R2,SCBDESTQ-1            ADDRESS OF THE                  67800022
*                                         DESTINATION QUEUE             68000022
         MVC   PRFSIZE(TWO),SCBEOB      SET THE PRFSIZE TO              68200022
*                                         REFLECT THE GOOD DATA         68400022
         SR    R14,R14                  CLEAR FOR COMPARE               68410022
         IC    R14,PRFSCAN              PRFSCAN FOR COMPARE             68420022
         CH    R14,PRFSIZE              IS PRFSCAN LARGER THAN          68430022
*                                         PRFSIZE                       68440022
         BNH   CLREOB3                  NO, BRANCH                      68450022
         LH    R9,SCBEOB                GET THE NUMBER OF BYTES         68460022
*                                         OF GOOD DATA                  68470022
         LA    R9,ONE(R9)               INCREMENT BY ONE                68480022
         STC   R9,PRFSCAN               RESET THE SCAN POINTER          68490022
CLREOB3  EQU   *                                                        68500022
         SR    R8,R8                    CLEAR WORK REGISTER             68600022
         CH    R8,SCBEOB                IS THERE ANY DATA IN THE        68800022
*                                         BUFFER                        69000022
         STH   R8,SCBEOB                CLEAR EOB TO MAINTAIN           69040022
*                                         THE INTEGRITY OF THE          69080022
*                                         EOB OFFSET FOR LMD AND        69120022
*                                         CONCENTRATOR                  69160022
         BNE   POSTBUF                  YES, BRANCH                     69200022
SETBFRTB EQU   *                                                        69400022
         LA    R2,AVTBFRTB              GET THE ADDRESS OF              69600022
*                                         BUFFER RETURN                 69800022
POSTBUF  EQU   *                                                        70000022
         ST    R2,PRFQCBA-1             SET DESTINATION QCB             70200022
         MVI   PRFPRI,PRIDESTQ          SET PRIORITY                    70400022
         BAL   R14,POSTLIST             ADD TO POSTLIST                 70600022
         SPACE 1                                                        70800022
         L     RPRF,LCBERCCW            GET BUFER SAVED OVER            71000022
*                                         THE RECALL                    71200022
         LA    R2,AVTBFRTB              BUFFER RETURN                   71400022
         MVI   PRFPRI,PRIBFRTB          SET PRIORITY                    71600022
         BAL   R14,POSTLIST             ADD TO POSTLIST                 71800022
         SPACE 1                                                        72000022
         B     POSTALL                  COMMON EXIT                     72200022
         EJECT                                                          72400022
HAVEBFR  EQU  *                                                         72600022
         OI    PRFSTAT1,PRFCNCLN                                        72800022
         NI    SCBSTATE,X'FF'-SCBCKPT   STOP CHECKPOINT                 73000022
         ST    R0,SCBMRFSD              R0 HAS ZERO WHEN ENTERED,       73200022
         SPACE 2                                                        73280022
*        THIS STORE WILL STOP DISTRIBUTION LISTS              *         73360022
*                AND MULTIPLE ROUTES                          *         73440022
         SPACE 2                                                        73520022
RETURN   EQU   *                                                        73600022
         TM    SCBSTATE,SCBSEQIN        HAS SEQ NO BEEN DONE            73800022
         BNO   RETURNA                  BR NO                           74000022
         NI    SCBSTATE,X'FF'-SCBSEQIN  RESET                           74200022
         LH    R1,PRFSRCE               OFFSET TO SRCE TNT              74400022
         N     R1,AVTCLRHI              CLEAR HIGH HALF                 74600022
         L     R15,AVTRNMPT             ADDR OF CODE                    74800022
         BALR  R14,R15                  FIND TERMINAL ENTRY             75000022
         USING  IEDQTRM,R1                                              75200022
         LH    R14,TRMINSEQ             INPUT SEQ NO                    75400022
         BCT   R14,SETSEQ               ADJUST SEQUENCE NUMBER          75600022
         LH    R14,DC9999               SET WRAPPED VALUE               75800022
SETSEQ   EQU   *                                                        76000022
         STH   R14,TRMINSEQ             SET NEW VALUE                   76200022
RETURNA  EQU   *                                                        76400022
         TM    SCBSTATE,SCBLCK1N+SCBMSGLN   LOCK                        76600022
         BZ    POSTBACK                 NO, BRANCH               S22025 76800022
         BM    EXTLOCK                  BR IF EXTENDED LOCK             77000022
         NI    SCBSTATE,AVTEFF-(SCBMSGLN+SCBLCK1N)                      77200022
*       IF THIS IS MSG LOCK - RESET ALL LOCK FLAGS                      77400022
EXTLOCK EQU   *                                                         77600022
         MVI   LCBINSRC+2,AVTEZERO      RESET FLAGS FOR BD TO POS       77800022
         NI    LCBSTAT1,X'FF'-LCBRECVN  SET FOR SCH TO REPOLL           78000022
POSTBACK EQU   *                                                 S22025 78020022
         LR    R1,RPRF                  COPY THE POST LIST       S22025 78040022
         L     R2,AVTMSGS-1             GET VCON TABLE ADDRESS   S22025 78060022
         L     R2,0(,R2)                GET ADDRESS OF IEDQBD    S22025 78080022
         ST    R2,PRFQCBA-1             SET THE QCB ADDRESS      S22025 78100022
         MVI   PRFPRI,PRIRCQCB          SET THE POST PRIORITY    S22025 78120022
         B     DSPPOST                  EXIT TO THE DISPATCHER   S22025 78140022
         EJECT                                                          78200022
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *         78400022
*                                                             *         78600022
*        THIS SECTION OF CODE WILL INITIALIZE THE ERB         *         78800022
*        PRIOR TO POSTING IT BACK TO BUFFER DISPOSITION       *         79000022
*                                                             *         79200022
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *         79400022
DSPERB   EQU   *                                                        79600022
         MVI   LCBERBPY,PRIRCQCB        SET THE PRIORITY                79800022
         L     R2,AVTMSGS-1             GET THE ADDRESS OF THE          80000022
*                                         VCON LIST                     80200022
         L     R2,AVTEZERO(,R2)         GET THE ADDRESS OF THE          80400022
*                                         BUFFER DISPOSITION QCB        80600022
POSTERB  EQU   *                                                        80800022
         ST    R2,LCBERBQB-1            POST THE ERB                    81000022
         LA    R1,LCBERB                GET THE ERB ADDRESS             81200022
         B     DSPCHAIN                 EXIT TO THE DISPATCHER          81400022
         EJECT                                                          81600022
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *         81800022
*                                                             *         82000022
*        THIS SECTION OF CODE WILL CHAIN AN ELEMENT           *         82200022
*        INTO A LIST OF ELEMENTS THAT ARE TO BE POSTED        *         82400022
*                  TO THE READY QUEUE                         *         82600022
*                                                             *         82800022
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *         83000022
POSTLIST EQU   *                                                        83200022
         ST    R2,PRFQCBA-1             PUT DESTINATION QUEUE           83400022
*                                         ADDRESS IN THE ELEMENT        83600022
         MVC   PRFLINK(THREE),AVTPARM+1 LINK THE PREVIOUS               83800022
*                                         ELEMENT TO THE CURRENT        84000022
         ST    RPRF,AVTPARM             SAVE THE ELEMENT ADDRESS        84200022
         BR    R14                      RETURN                          84400022
         EJECT                                                          84600022
BASE     DC    A(START)                 MODULE BASE ADDR                84800022
DC9999   DC    H'9999'                  SEQ NUMBER WRAP                 85000022
ZERO     EQU   0                                                        85200022
ONE      EQU   1                                                        85300022
TWO      EQU   2                                                        85400022
THREE    EQU   3                                                        85600022
FOUR     EQU   4                                                        85800022
SEVEN    EQU   7                                                        86000022
D256     EQU   256                                                      86200022
COPYLOST EQU   X'10'                                                    86400022
DIAL     EQU   X'18'                                                    86600022
         EJECT                                                          86800022
         TAVTD  2                                                       87000022
         EJECT                                                          87200022
         TQCBD                                                          87400022
         TTRMD                                                          87600022
         TPRFD                                                          87800022
         TLCBD                                                          88000022
         TSCBD                                                          88200022
         TPRIOR                                                         88400022
         TDISPD                                                         88600022
         END                                                            88800022
