DQBY TITLE '''IEDQBY''   LOG MESSAGE'                                   01000020
IEDQBY   CSECT                                                          02000020
*A740000                                                         A42407 02300000
*C860000                                                         A42407 02600000
*A750000,830000                                                  A51765 02700022
*D800000                                                         A51765 02800022
*********************************************************************** 03000020
*                                                                     * 04000020
*TITLE 'IEDQBY' LOG MESSAGE                                           * 05000020
*                                                                     * 06000020
*STATUS -- CHANGE LEVEL 0                                             * 07000020
*                                                                     * 08000020
*FUNCTION -- LOG MESSAGE WILL POST A RECALLED HEADER TO THE           * 09000020
*   DESTINATION QCB SPECIFIED BY THE USED FOR LOGGING THIS MESSAGE    * 10000020
*   THIS POST WILL ACTIVATE THE LOG SCHEDULER WHO WILL LOG THE        * 11000020
*   MESSAGE.                                                          * 12000020
*                                                                     * 13000020
*ENTRY POINTS -- 'IEDQBY, TO LOG A MESSAGE                           * 14000020
*   CALLING SEQUENCE -       LA R12,IEDQBY                            * 15000020
*                            BR  R12                                  * 16000020
*                                                                     * 17000020
*INPUT -- IEDQBY IS CALLED BY BUFFER DISPOSITION AS A RESULT OF THE   * 18000020
*   LOG MACRO BEING SPECIFIED IN THE INMSG OR OUTMSG SUBGROUP         * 19000020
*   R8 - THE ADDRESS OF THE MACRO PAR LIST                            * 20000020
*   R6 - THE ADDRESS OF THE RECALLED HEADER                           * 21000020
*   R1 - THE ADDRESS OF THE FIRST OF A CHAIN OF ELEMENTS              * 22000020
*        TO BE POSTED OR 0 IF THERE ARE NONE.                         * 23000020
*   R11-  THE DISPATCHER BASE                                         * 24000020
*   R12- THE ENTRY POINT ADDRESS                                      * 25000020
*   THE MACRO PARLIST HAS THE ADDRESS FO THE TERMINAL TABLE ENTRY       26000020
*   FOR THE LOGTYPE MACRO.                                            * 27000020
*                                                                     * 28000020
*OUTPUT -- THE RECALLED HEADER WILL EBE POSTED TO THE DESTINATION     * 29000020
*   QCB SPECIFIED IN THE MACRO.                                       * 30000020
*                                                                     * 31000020
*EXTERNAL ROUTINES -- DISPATCHER TO POST A CHAIN OF ELEMENTS.         * 32000020
*                                                                     * 33000020
*EXITS-NORMAL -- EXIT IS TO DSPCHAIN TO POST A CHAIN OF ELEMENTS,     * 34000020
*   THE FIRST OF WHICH WILL BE THE RECALLED HEADER.                   * 35000020
*                                                                     * 36000020
*EXITS-ERROR  --  NONE                                                * 37000020
*                                                                     * 38000020
*TABLES/WORK AREAS -- TDISPD, TSCBD, TPRFD                            * 39000020
*                                                                     * 40000020
*                        REGISTER EQUATES                             * 41000020
*                                                                     * 42000020
*                         USING STATEMENTS                            * 43000020
*                                                                     * 44000020
*ATTRIBUTES -- REUSABLE,REFRESHABLE, RESIDENT, ENABLED                * 45000020
*                                                                     * 46000020
*NOTES -- THE OPERATION OF THIS MADULE DOES NOT DEPEND UPON A         * 47000020
*   PARTICULAR INTERNAL REPRESENTATION OF THE EXTERNAL CHARACTER      * 48000020
*   SET.                                                              * 49000020
*                                                                     * 50000020
*********************************************************************** 51000020
*NOTES -- THE DCB OPENED MUST BE A BSAM DCB.                          * 52000020
*                                                                     * 53000020
R1       EQU   1                        PARAMETER COR CHAIN             54000020
RSCB     EQU   3                        SCB ADDRESS                     55000020
RLCB     EQU   4                                                        56000020
RPREFIX  EQU   6                        BUFFER ADDRESS                  57000020
RQCB     EQU   7                        DEST Q ADDR                     58000020
R8       EQU   8                        ADDRESS OF PARM LIST            59000020
RDISP    EQU   11                       DISPATCHER ADDR                 60000020
RBASE    EQU   12                       ENTRY POINT ADDRESS             61000020
         USING IEDQDISP,RDISP                                           62000020
         USING IEDQSCB,RSCB                                             63000020
         USING IEDQPRF,RPREFIX                                          64000020
         USING IEDQQCB,RQCB                                             65000020
         USING IEDQLCB,RLCB                                             66000020
         USING *,RBASE                                                  67000020
IEDQBY   IEDHJN IDPASS                  ID AND DATE              S22025 68000022
         L     RQCB,4(R8)               SECOND WORD OF THE PARLASST     69000020
*                                       CONTAINS THE RTTABLE ADDR       70000020
         L     RQCB,0(RQCB)             ADDR OF DEST QCB                71000020
         ST    R1,PRFLINK-1             LINK BFR INTO CHAIN OF ELEMENTS 72000020
*                                       TO POST                         73000020
         MVI   PRFPRI,PRIDESTQ          SET PRTY                        74000020
         NI    PRFSTAT1,PRFERMGF        RESET ERRMSG FLAG        A42407 74500000
         LR    R1,RPREFIX               SET FIRST IN CHAIN ADDR         75000020
         TM    LCBSTAT1,LCBINITN+LCBSENDN SND INIT MODE MSG?     A51765 75100022
         BNO   NOTINIT                  BR NO                    A51765 75200022
         TM    SCBERR4,SCBSLCTN+SCBTXTTN ID LINE ERR OCCUR?      A51765 75300022
         BZ    NOTINIT                  BR NO                    A51765 75400022
         L     RQCB,LCBRCQCB            SET TO POST BFR TO BD AS A51765 75500022
*                                       IF THE DUPLICATE HDR HAS A51765 75600022
*                                       BEEN PROCESSED           A51765 75700022
         B     INITIATE                 GO SET INITIATE          A51765 75800022
NOTINIT  EQU   *                                                 A51765 75900022
         IC    R8,SCBDESTQ-1            SAVE HI BYTE                    76000020
         ST    RQCB,SCBDESTQ-1          INITIALIZE SCB DESTQ            77000020
         STC   R8,SCBDESTQ-1            RESTORE HI BYTE                 78000020
         MVI     SCBPRI,X'00'           SET PRTY QCB T/ 0               79000020
         L     RLCB,QCBDCBAD-1          GET LCB ADDR                    81000020
         LH    RLCB,LCBTTCIN            OFFSET INTO TNT                 82000020
         STH   RLCB,PRFDEST             INTO BFR PREFIX                 83000020
INITIATE EQU   *                                                 A51765 83300022
         ST    RQCB,PRFQCBA-1           SET QCB ADDR             A51765 83600022
         B     DSPCHAIN                 EXIT                            84000020
         TPRIOR                                                         85000022
         TSCBD                                                          87000020
         TLCBD                                                          88000020
         TQCBD                                                          89000020
         TDISPD                                                         90000020
         TPRFD                                                          91000020
         END                                                            92000020
