         TITLE '''IEDQC1'' - ICHNG PROCESSOR'                           00200020
IEDQC1   CSECT                                                          00400020
*A676000,684000,744000                                           A49232 00420022
*C196000,654000,670000,724000                                    A49232 00440022
*A373000,713300,752000                                           A42413 00460021
*C196000,373000,713300,810000                                    A42413 00520021
*********************************************************************** 00600020
*                                                                     * 00800020
*TITLE 'IEDQC1' PROCESSOR OF ICHNG MPP COMMANDS'                      * 01000020
*                                                                     * 01200020
*STATUS -- CHANGE LEVEL 0                                             * 01400020
*                                                                     * 01600020
*FUNCTION -- THE PURPOSE OF THIS MODULE IS TO CHANGE AN               * 01800020
*   INVITATION LIST ENTRY AS REQUESTED BY A PROCESSING PROGRAM.       * 02000020
*                                                                     * 02200020
*   THE ROUTINE IS GIVEN CONTROL WHEN STOPLINE HAS BEEN COMPLETED     * 02400020
*   AND THE LCB IS ON THE OPERATOR CONTROL QUEUE.  THE DCB ADDRESS    * 02600020
*   IS OBTAINED FROM THE LCB (LCBDCBAD) AND THE INVITATION LIST       * 02800020
*   FROM DCBINVLI+4*LCBUCBX.  THE COMMON INPUT BLOCK IS USED TO       * 03000020
*   DETERMINE THE TYPE OF ICHANGE TO BE DONE.  IF IT IS AN ICHANGE    * 03200020
*   MOVE, THE LIST SIZE IS CALCULATED AND THE DATA AT THE MOVE WORK   * 03400020
*   AREA IS MOVED TO OVERLAY THE LIST.  THE LCB IS REMOVED FROM THE   * 03600020
*   OPERATOR CONTROL QUEUE AND POSTED TO ITSELF TO START THE LINE     * 03800020
*   VIA THE AQCTL MACRO (SVC 102).  A GOOD RETURN CODE IS SET AND     * 04000020
*   THE ROUTINE RETURNS TO THE CONTROL MODULE.                        * 04200020
*                                                                     * 04400020
*   IF THE COMMAND IS ICHANGE DEACT AND ALL ENTRIES ARE ALREADY       * 04600020
*   INACTIVE, THE LCB IS DEQUEUED AND THE LINE STARTED AS ABOVE.  A   * 04800020
*   COUNT OF THE NUMBER OF ACTIVE ENTRIES IS SET UP.  EACH ACTIVE     * 05000020
*   ENTRY IS SWAPPED FROM THE ACTIVE TO THE INACTIVE SIDE OF THE      * 05200020
*   LIST AND THE ACTIVE COUNT IS DECREMENTED.  WHEN ALL ENTRIES ARE   * 05400020
*   INACTIVE, THE NUMBER OF ACTIVE ENTRIES IS SET TO ZERO, THE LCB    * 05600020
*   IS DEQUEUED AND THE LINE STARTED AS ABOVE.                        * 05800020
*                                                                     * 06000020
*   IF THE COMMAND IS ICHANGE ACT AND ALL ENTRIES ARE ALREADY         * 06200020
*   ACTIVE, THE LCB IS DEQUEUED AND THE LINE STARTED AS ABOVE.  A     * 06400020
*   COUNT OF THE NUMBER OF INACTIVE ENTRIES IS SET UP.  EACH ENTRY    * 06600020
*   IS SWAPPED FROM THE INACTIVE TO THE ACTIVE SIDE OF THE LIST,      * 06800020
*   AND THEN SWAPPED WITH OTHER ACTIVE ENTRIES UNTIL IT IS IN ITS     * 07000020
*   PROPER PLACE IN THE LIST.  THE COUNT IS DECREMENTED.  WHEN ALL    * 07200020
*   ENTRIES HAVE BEEN MADE ACTIVE, THE NUMBER OF ACTIVE ENTRIES IS    * 07400020
*   SET TO EQUAL THE TOTAL ENTRY COUNT.  THE LCB IS DEQUEUED AND      * 07600020
*   THE LINE STARTED AS ABOVE.                                        * 07800020
*                                                                     * 08000020
*ENTRY POINTS --                                                      * 08200020
*        'IEDQC1' TO CHANGE THE INVITATION LIST.  CALLING SEQUENCE    * 08400020
*   IS                        LOAD EPLOC=(10)                         * 08600020
*                             LR   R15,R0                             * 08800020
*                             BALR R14,R15                            * 09000020
*                                                                     * 09200020
*INPUT -- REGISTER 1 - ADDRESS OF THE OPERATOR CONTROL AVT.           * 09400020
*                                                                     * 09600020
*   REGISTER 15 - ENTRY POINT ADDRESS.                                * 09800020
*                                                                     * 10000020
*OUTPUT -- REGISTER 15 - SET TO ZERO.                                 * 10200020
*                                                                     * 10400020
*EXTERNAL ROUTINES -- N/A.                                            * 10600020
*                                                                     * 10800020
*EXITS-NORMAL -- THE LIST IS CHANGED AS REQUESTED.  REGISTER 15 IS    * 11000020
*   SET TO ZERO TO INDICATE COMPLETION.                               * 11200020
*                                                                     * 11400020
*EXITS-ERROR -- N/A.                                                  * 11600020
*                                                                     * 11800020
*TABLES/WORK AREAS -- AVT, DCB, LCB, OPERATOR CONTROL AVT.            * 12000020
*                                                                     * 12200020
*ATTRIBUTES -- SERIALLLY REUSABLE, REFRESHABLE, ENABLES, TRANSIENT,   * 12400020
*   PROBLEM PROGRAM MODE.                                             * 12600020
*                                                                     * 12800020
*NOTES -- THE OPERATION OF THIS MODULE DOES NOT DEPEND UPON AN        * 13000020
*   INTERNAL REPRESENTATION OF THE EXTERNAL CHARACTER SET.            * 13200020
*                                                                     * 13400020
*********************************************************************** 13600020
*                                                                       13800020
*                                                                       14000020
R0       EQU   0                                                        14200020
R1       EQU   1                                                        14400020
ROPC     EQU   2                                                        14600020
RCIB     EQU   3                                                        14800020
RAVT     EQU   4                                                        15000020
RTCB     EQU   5                                                        15200020
RDCB     EQU   6                                                        15400020
RWORK2   EQU   7                                                        15600020
RDD      EQU   8                                                        15800020
RWORK3   EQU   8                                                        16000020
RLIST    EQU   9                                                        16200020
RWORK    EQU   10                                                       16400020
RMOVE    EQU   11                                                       16600020
RBASE    EQU   12                                                       16800020
R13      EQU   13                                                       17000020
R14      EQU   14                                                       17200020
R15      EQU   15                                                       17400020
RLENGTH  EQU   RWORK2                   ENTRY LENGTH                    17600020
RLTH1    EQU   RWORK3                   ENTRY LENGTH - 1                17800020
RSWAP    EQU   RWORK                                                    18000020
RENTRYX  EQU   R1                                                       18200020
ROFF     EQU   R15                                                      18400020
         USING IEDQC1,RBASE                                             18600020
         USING IEDQOPC,ROPC                                             18800020
         USING IEDQLCB,RCIB                                             19000020
         USING IEDQAVTD,RAVT                                            19200020
         USING IHADCB,RDCB                                              19400020
         SAVE  (14,12)                                                  19600022
         LR    RBASE,R15                                                19800020
IEDQC1   IEDHJN IDDATE                                           S22025 19900022
         LR    ROPC,R1                                                  20000020
         TM    OPCED,HEX80               CHECK POINT RESTART            20200020
         BO    ARND                     LINE NOT OPENED                 20400020
         CLI   OPCBITSW+1,AVTEZERO      WAS STOPLINE SUCCESSFUL         20600020
         BNE   BADEX                    NO - DO NOT PROCESS             20800020
ARND     EQU   *                                                        21000020
         L     RAVT,OPCAVTAD            GET AVT ADDR                    21200020
         L     RCIB,OPCSAVE2+16         GET LCB OFF +                   21400020
         L     RDCB,LCBDCBPT                                            21600020
         LA    RLIST,DCBINVLI           GET LIST ADDR                   21800020
         SR    RWORK,RWORK              CLEAR                           22000020
         IC    RWORK,LCBUCBX                                            22200020
         SLL   RWORK,OPCTWO             MULTIPLY BY OOUR                22400020
         AR    RLIST,RWORK              GET TO PROPER LIST ADDR         22600020
         L     RLIST,OPCZERO(RLIST)     GET LIST                        22800020
         TM    OPCED,OPCTWO              RESTART FOR MODIFY             23000020
         BO    RSTRMOV                   YES HANDLE SPECIAL             23200020
         CLC   OPCOPFLD(OPCTHREE),FZERO    MOVE TYPE ICHNG              23400020
         BNE   MOVELIST                 YES                             23600020
*                                                                       23800020
         CLI   OPCOPFLD+3,ZERO           ACT OR DEACT                   24000020
         BE    ACT                      ACTIVATE                        24200020
*                                                                       24400020
CTSTART  EQU   *                                                        24600020
         SR    ROFF,ROFF                SET UP FIRST ENTRY              24800020
         STH   ROFF,OPCDATA+2           SAVE FOR INDEXING               25000020
         SR    RLENGTH,RLENGTH          HOUSEKEEP                       25200020
         SR    RLTH1,RLTH1              HOUSEKEEP                       25400020
         IC    RLENGTH,OPCTWO(RLIST)   LENGTH OF ENTRY                  25600020
         LR    RLTH1,RLENGTH            LENGTH OF ENTRY                 25800020
         BCTR  RLTH1,OPCZERO            DECREMENT FOR EXECUTE           26000020
GTENTRY  LH    ROFF,OPCDATA+2           GET NEXT ENTRY                  26200020
         CLI   OPCONE(RLIST),OPCZERO    ALLENTRIES INACTIVE             26400020
         BE    EXIT                     YES                             26600020
         LA    ROFF,OPCONE(ROFF)        BUMP ONE                        26800020
         STH   ROFF,OPCDATA+2                                           27000020
         CLC   OPCDATA+3(OPCONE),OPCZERO(RLIST)  OUT OF ENTRIES         27200020
         BH    EXIT                                                     27400020
ACTALL   LA    RENTRYX,OPCSEVEN(RLIST)  PTR TO FIRST ENTRY INDEX        27600020
         OI    OPCBITSW,OPCTEMPN       AT LESST ONE ENTRY IN LIST       27800020
         SR    R14,R14                  HOUSEKEEP                       28000020
         IC    R14,OPCONE(RLIST)        NUMBER OF ACTIVE ENTRIES        28200020
CKNEXT   AR    RENTRYX,RLENGTH             GO TO NEXT ENTRY'S INDEX     28400020
         CLC   OPCZERO(OPCONE,RENTRYX),OPCDATA+3  IS THIS AN ENTRY?     28600020
         BE    DACTIV                    YES, ITS ACTIVE, DEACTIVZTE    28800020
         BCT   R14,CKNEXT               IF NOT END OF ACTIVE, GO BACK   29000020
         B     GTENTRY                 GET THE NEXT --DONEWITH THIS     29200020
DACTIV   LR    RSWAP,RENTRYX              HOUSEKEEP                     29400020
         SR    RENTRYX,RLENGTH          SET TO ENTRY-LENGTH-1           29600020
         BCT   R14,SWAPLOOP                                             29800020
         B     LOOPOUT                                                  30000020
         SPACE 2                                                        30200020
SWAPLOOP EX    RLTH1,SWAP1              SWAP                            30400020
         EX    RLTH1,SWAP2                 THIS ENTRY                   30600020
         EX    RLTH1,SWAP3                AND NEXT ENTRY                30800020
         AR    RENTRYX,RLENGTH          GO TO NEXT ENTRY                31000020
         AR    RSWAP,RLENGTH              GET TO THIS ENTRY             31200020
         BCT   R14,SWAPLOOP             NOT DINE, RRTURN                31400020
         SPACE 2                                                        31600020
LOOPOUT  IC    R14,OPCTWO(RLIST)        DONE, GET ENTRY LENGTH          31800020
         LA    R15,OPCONE               GET'ONE'FOR USEAGE              32000020
         TM    OPCTHREE(RLIST),EOTENT   IS THIS EOT-FE  (BSC)           32200020
         BO    SFTEOT                     YES, SPECIAL TREATMENT        32400020
         SPACE 2                                                        32600020
SFTLOOP  MVC   OPCONE(OPCONE,RSWAP),OPCZERO(RSWAP)  MOVE ONE CHARACTER  32800020
         SR    RSWAP,R15                  AT A  TIME, STARTING          33000020
         BCT   R14,SFTLOOP                WITH THE LAST CHARACTER       33200020
         MVI   OPCONE(RSWAP),ACTEND     INSERT ACTIVE END CHACTER       33400020
RSETACT  IC    R14,OPCONE(RLIST)        COUNT OF ACTIVE ENTRIES         33600020
         SR    R14,R15                    ONE LESS                      33800020
         STC   R14,OPCONE(RLIST)        RESET                           34000020
         B     GTENTRY                  TRY NEXT                        34200020
         SPACE 2                                                        34400020
SFTEOT   MVC   OPCDATA+8(OPCTWO),OPCONE(RSWAP)  SAVE EOT-FE             34600020
SFTEOT1 MVC OPCTWO(OPCONE,RSWAP),OPCZERO(RSWAP)  MOVE  ONE CHARACTER    34800020
         SR    RSWAP,R15                   AT A TIME                    35000020
         BCT   R14,SFTEOT1                 STARTING WITH THE LASTP      35200020
         SPACE 2                                                        35400020
         MVC   OPCONE(OPCTWO,RSWAP),OPCDATA+8   RESET EOT-FE            35600020
         B     RSETACT                  SET ACTIVE COUNT                35800020
EXIT     EQU   *                                                        36000020
         TM    OPCED,HEX80              IS THIS CHECK PT ELEMENT        36060020
         BO    OUT1                     YES, DON'T CKPT AND DON'T REST  36120020
         TM    AVTBIT3,AVTSTAIN          CHECK POINT THIS               36200020
         BZ    EXIT1           NO                                       36400020
         OI    OPCCKBIT,OPCCKPTN+OPCINVN   SET CKPT BITS                36600020
EXIT1    EQU   *                                                        36800020
         LA    R14,OPCEIGHT(RLIST)       PTR TO BEGINNING OF LIST       36820020
         ST    R14,LCBINVPT-1                FOR RECEIVE SCHEDULAR      36840020
         TM    OPCINFO,OPCONE            WAS THE LINE STARTED BEFOR     36860020
         BZ    OUT1                        NO, DON'T START IT           36920020
         L     RWORK3,CVTPTR            LOAD CVT ADDR            A42413 37010021
         CLC   AVTCVTMP+1(3,RWORK3),AVTFZERO MP GEN'ED IN SYSTEM A42413 37100021
         BE    NOTS                     NO, CONTINUE             A42413 37190021
TSTMP65  CLI   CPUSTAT-IEAQFX00,AVTEZERO MP ACTIVE IN SYSTEM     A42413 37280021
         BNE   NOTS                      NO - PROCEED                   37400020
         TS    AVTOPCOB+8                ANY ONE QUEUING                37500020
         BC    4,TSTMP65                 YES, WAIT UNTIL HE IS DONE     37600020
NOTS     EQU   *                                                        37700020
         MVC   AVTOPCOB+1(3),LCBLINK     DEQUEUE THE ELEMENT            37800020
         MVI   AVTOPCOB+8,AVTEZERO       DONE, CLEAR TS SWITCH          38000020
         OI    LCBSTAT1,LCBRECVN        SET STATUS FOR START            38200020
         ST    RCIB,OPCZERO(RCIB)       MAKE LCB POINT TO ITSELF        38400020
         ST    RCIB,OPCPPL                                              38600020
         ST    RCIB,OPCPPL+4                                            38800020
         MVI   OPCPPL,POST                                              39000020
         XC    LCBLINK(OPCTHREE),LCBLINK                                39200020
         MVI   LCBPRI,PRILNFRE                                          39400020
         MVI   OPCPPL+4,TJID                                            39600020
         LA    R1,OPCPPL                                                39800020
         AQCTL                                                          40000020
*                                                                       40200020
OUT1     EQU   *                                                        40400020
         LA    R15,OPCZERO                                              40600020
OUT      EQU   *                                                        40800020
*                                                                       41000020
         RETURN (14,12),T,RC=(15)                                       41200020
*                                                                       41400020
BADEX    EQU   *                                                        41600020
         LA    R15,OPCFOUR                                              41800020
         B     OUT                                                      42000020
         EJECT                                                          42200020
ACT      EQU   *                                                        42400020
CSSTART  SR    ROFF,ROFF                SET UP FIRST ENTRY              42600020
         STH   ROFF,OPCDATA+2           SAVE FOR INDEXING               42800020
         SR    RLENGTH,RLENGTH          HOUSEKEEP                       43000020
         SR    RLTH1,RLTH1              HOUSEKEEP                       43200020
         IC    RLENGTH,OPCTWO(RLIST)   LENGTH OF ENTRY                  43400020
         LR    RLTH1,RLENGTH            LENGTH OF ENTRY                 43600020
         BCTR  RLTH1,OPCZERO            DECREMENT FOR EXECUTE           43800020
GTENTRY1 LH    ROFF,OPCDATA+2           GET NEXT ENTRY                  44000020
         LA    ROFF,OPCONE(ROFF)        BUMP ONE                        44200020
         STH   ROFF,OPCDATA+2                                           44400020
         CLC   OPCZERO(OPCONE,RLIST),OPCONE(RLIST) ALLENTRIES ACTIVE    44600020
         BE    EXIT                     YES                             44800020
         CLC   OPCDATA+3(OPCONE),OPCZERO(RLIST)  OUT OF ENTRIES         45000020
         BH    EXIT                                                     45200020
         LA    RENTRYX,OPCSEVEN(RLIST)  PTR TO FIRST ENTRY INDEX        45400020
         SR    R14,R14                  HOUSEKEEP                       45600020
         IC    R14,OPCONE(RLIST)        NUMBER OF ACTIVE ENTRIES        45800020
         LTR   R14,R14                  ARE THERE ANY ACTIVE ENTRIES    46000020
         BZ    CKINACT                    NO  CK THE INACTIVE           46200020
CKNEXT1  AR    RENTRYX,RLENGTH             GO TO NEXT ENTRY'S INDEX     46400020
         CLC   OPCZERO(OPCONE,RENTRYX),OPCDATA+3  IS THIS AN ENTRY?     46600020
         BE    GTENTRY1                  YES, ITS ACTIVE, GET ANOTHER   46800020
         BCT   R14,CKNEXT1              IF NOT END OF ACTIVE, GO BACK   47000020
CKINACT  LA    RENTRYX,OPCONE(RENTRYX)  GET BY ACTIVE FLAG              47200020
         TM    OPCTHREE(RLIST),EOTENT    'EOT' ENTRY PRESENT            47400020
         BZ    CKINACT1                 NO, GO ON                       47600020
         LA    RENTRYX,OPCONE(RENTRYX)  SKIP IT, TOO                    47800020
CKINACT1 AR    RENTRYX,RLENGTH          GET TO NEXT INDEX               48000020
         CLC   OPCZERO(OPCONE,RENTRYX),OPCDATA+3  IS THIS AN ENTRY      48200020
         BNE   CKINACT1                   NO, GET ANOTHER               48400020
         SR    RENTRYX,RLENGTH            YES, SET UP FOR SWAP          48600020
         LR    RSWAP,RENTRYX            ONE BYTE SHY OF                 48800020
         SR    RSWAP,RLENGTH              ENTRY AND PREVIOUS ENTRY      49000020
ACTIVATE CLI   OPCZERO(RENTRYX),ACTEND  FIRST INACTIVE ENTRY?           49200020
         BE    MACTIVE                  YES, MAKE IT ACTIVE             49400020
         EX    RLTH1,SWAP1              SWAP                            49600020
         EX    RLTH1,SWAP2                 THIS ENTRY                   49800020
         EX    RLTH1,SWAP3                    AND PRECEDING ENTRY       50000020
         SR    RENTRYX,RLENGTH          BACK UP ONE ENTRY               50200020
         SR    RSWAP,RLENGTH            BACK PREVIOUS ENTRY, ONE ENTRY  50400020
         B     ACTIVATE                                                 50600020
MACTIVE  TM    OPCTHREE(RLIST),EOTENT    EOT ENTRY PRESENT              50800020
         BO    MACTIVE1                 YES, SPECIAL CARE               51000020
         EX    RLTH1,MOVACT             PLACE ENTRY ON ACTIVE SIDE      51200020
         LA    R14,OPCZERO(RLENGTH,RENTRYX) POINT TO NEW END OF ACTIVE  51400020
         BCTR  RENTRYX,OPCZERO         GET TO ONE SYY                   51600020
         BCTR  RSWAP,OPCZERO           GET TO ONE SHY                   51800020
         MVI   OPCZERO(R14),ACTEND      RESET ACTIVE POINTER            52000020
MACTIVE2 SR    R14,R14                  CLEAR REGISTER                  52200020
         IC    R14,OPCONE(RLIST)        GET NUMBER OF ACTIVE ENTRIES    52400020
         LA    R14,OPCONE(R14)          INCREMENT FOR BCT               52600020
ACTLOOP  BCT   R14,ACTPOS               IF NOT LAST POSITION COMPARE    52800020
RETURNA  IC    R14,OPCONE(RLIST)        GET                             53000020
         LA    R14,OPCONE(R14)          AND INCREMENT                   53200020
         STC   R14,OPCONE(RLIST)           NUMBER OF ACTIVE ENTRIES     53400020
         B     GTENTRY1                 RETURN FOR ANOTHER              53600020
ACTPOS   CLC   OPCZERO(OPCONE,RENTRYX),OPCDATA+3 ENTRY IN POSITION      53800020
         BL    RETURNA                  PREVIOUS ENTRY LOWER, DONE      54000020
         EX    RLTH1,SWAP1              SWAP THIS ENTRY                 54200020
         EX    RLTH1,SWAP2                 AND                          54400020
         EX    RLTH1,SWAP3                    PRECEDING ENTRY           54600020
         SPACE 2                                                        54800020
         SR    RENTRYX,RLENGTH          BACK UP                         55000020
         SR    RSWAP,RLENGTH               ONE ENTRY                    55200020
         B     ACTLOOP                                                  55400020
*                                                                       55600020
MOVELIST EQU   *                                                        55800020
         L     RMOVE,OPCOPFLD                                           56000020
         SR    R1,R1                    CLEAR                           56200020
         LR    R0,R1                    CLEAR                           56400020
         IC    R0,OPCZERO(RLIST)        GET NUMBER OF ENTRIES           56600020
         IC    R1,OPCTWO(RLIST)         GET ETNRY WIDTH                 56800020
         MR    R0,R0                    GET LIST SIZE - 1               57000020
         LA    R1,OPCNINE(R1)            ADD STATUS AND FE              57200020
         TM    OPCTHREE(RLIST),EOTENT    BSC?                           57400020
         BZ    MOVE1A1                   NO, GO ON                      57600020
         LA    R1,OPCONE(R1)             YES, ADD ONE FOR EOT           57800020
MOVE1A1  LR    R14,RLIST                 SAVE LIST PTR                  58200020
         LR    RTCB,R1                   KEEP THE LENGTH                58210020
         MVC   ZERO(FOUR,RLIST),ZERO(RMOVE)  RESET FIRST CONTROL WORD   58220020
         CLI   LCBRSKEY,X1A              IS THIS FOR BUFFERED TERMS     58230020
         BE    MOVE1A2                   YES,  SAVE ONLY ONE BYTE       58240020
         MVC   FOUR(FOUR,RLIST),FOUR(RMOVE)  SET SECOND CONTRL WORD     58250020
MOVE1A2  EQU   *                                                        58260020
         MVC   FIVE(ONE,RLIST),FIVE(RMOVE)      SET BUFFERED BYTE       58270020
         LA    RLIST,EIGHT(RLIST)        RESET  PTR                     58280020
         LA    RMOVE,EIGHT(RMOVE)        RESET ALSO                     58290020
         SH    R1,H8                     RESET COUNT                    58300020
MOVE1A   CH    R1,H256                   WILL ONE MOVE DO IT            58400020
         BNH    MOVE1B                   YES                            58600020
         MVC   0(256,RLIST),0(RMOVE)     MOVE  256  CHARACTERS          58800020
         LA    RLIST,256(RLIST)          SET UP                         59000020
         LA    RMOVE,256(RMOVE)            FOR                          59200020
         SH    R1,H256                       NEXT MOVE                  59400020
         B     MOVE1A                    GO AGAIN                       59600020
MOVE1B   BCTR  R1,OPCZERO                DECREMENT FOR EXECUTE          59800020
         EX    R1,MVC                      MOVE CHAR.                   60000020
         LR    RLIST,R14                 GET LIST BACK                  60200020
*   REGISTER USAGE FOR THE CK PT RESTART                                60400020
*  RLIST   LIST ADDRESS                                                 60600020
*  RMOVE   ADDRESS OF NEXT MOVE                                         60800020
*  RWORK   RELATIVE POSITION OF NEXT MOVE                               61000020
*  RWORK2   LINK REGISTER                                               61200020
*  RTCB    CHAR                                                         61400020
*   RTCB   NUMBER OF CHARACTRES TO BE CHECK POINTED                     61600020
*   IN  THE CHECK POINT ELEMENT                                         61800020
*  BIT1,BIT2   THE RELATIVE POSITION FROM BEGINNING OF LIST             62000020
*   RLN     LENGTH FO THIS FIELD                                        62200020
*    SENSE                                                              62400020
*   OPCSNSE   UP TO 12  BYTES OF DATA                                   62600020
         L     RWORK,AVTCKGET             IS CHECKPOINT IN              62800020
         LTR   RWORK,RWORK                   IN THE SYSTEM              63000020
         BZ    EXIT1                     NO DONT CHECK POINT IT         63200020
         TM    AVTBIT3,AVTSTAIN          NEED A CHECH POINT             63400020
         BZ    EXIT1                     NO, THEN DONE                  63600020
         SR    RWORK,RWORK               HOUSEKEEP                      63800020
         LR    RMOVE,RLIST               GET BEGINNING OF LIST          64000020
CKELE1   EQU   *                                                        64200020
         CH    RTCB,H12                  WILL THIS MOVE DO IT           64400020
         BNH   CKMOV1B                   YES,  SET UP FOR LIST          64600020
         MVC   OPCSNSE(TWELVE),ZERO(RMOVE)    MOVE TO CK PT             64800020
         SH    RTCB,H12                  DECREMENT COUNT OT MOVE        65000020
         STH   RWORK,OPCBIT1             SAVE RELATIVE POSITION         65200020
         MVI   OPCRLN+1,ELEVEN         NUMBER OF BYTES-1         A49232 65400022
         LA    RWORK,TWELVE(RWORK)       SET FOR NEXT RELATIVE POSITIO  65600020
         LA    RMOVE,TWELVE(RMOVE)       SET FOR NEXT ADDRESS           65800020
         BAL   RWORK2,CKPTIT             GO CHECK POINT IT              66000020
         B     CKELE1                    THR AGAIN                      66200020
         SPACE 2                                                        66400020
CKMOV1B  BCTR  RTCB,ZERO                 DECREMENT FOR EXECUTE          66600020
         EX    RTCB,MOVCKPT              MOVE THE LAST BYTES            66800020
         STC   RTCB,OPCRLN+1           SAVE IN CKPOINT           A49232 67000022
         STH   RWORK,OPCBIT1              SAVE RELATIVE OOSITION        67200020
         BAL   RWORK2,CKPTIT             GO CHECK POINT IT              67400020
         MVI   OPCED,ZERO                CLEAR                          67600020
         OI    OPCINFO,NFSTFLG         RESET FLAG FOR 110D       A49232 67700022
         B     EXIT1                     VINISHED GET OUT               67800020
         SPACE 2                                                        68000020
CKPTIT   EQU   *                                                        68200020
         OI    OPCED,HEX82               SET TO ALLOW CHECKPOINTING     68400020
         NI    OPCINFO,X7F             CLEAR NOT FIRST SWITCH    A49232 68500022
         XC    AVTCCELE+4(OPCFOUR),AVTCCELE+4                           68600020
         LA    R1,AVTCKPTB              PLACE CK PT                     68660020
         ST    R1,AVTCCELE                  QCB IN THE ELEMENT          68720020
         MVI   AVTCCELE,AVTEBLNK                                        68800020
         MVI   AVTCCELE+4,PRIOPCKP                                      69000020
         LA    R1,AVTCCELE                                              69200020
         ST    R1,OPCPPLA-1                                             69400020
         ST    R1,OPCPPL2                                               69600020
         MVI   OPCPPL1,ECB                                              69800020
         MVI   OPCPPL2,AVTE80                                           70000020
         LA    R1,OPCPPL1                                               70200020
         MVI   AVTOPCOB+4,ZERO                                          70400020
         AQCTL                                                          70600020
POSTCK1  EQU   *                                                        70700020
         SPACE 2                                                        70800020
         LA    R1,AVTOPCOB+4                                            71000020
         WAIT  ECB=(1)                                                  71200020
         MVI   AVTOPCOB+4,ZERO           RESET THE ECB                  71230020
         L     R1,AVTOPCOB               GET LIST PTR                   71260020
         CLI   4(R1),PRIOPCKP            IS IT THE CK PT ELEMENT        71290020
         BNE   POSTCK1                   NO WAIT AGAIN                  71320020
         L     RWORK3,CVTPTR            LOAD CVT ADDR            A42413 71324021
         CLC   AVTCVTMP+1(3,RWORK3),AVTFZERO MP GEN'ED IN SYSTEM A42413 71328021
         BE    NOTS1                    NO, CONTINUE             A42413 71332021
TSTMP651 CLI   CPUSTAT-IEAQFX00,AVTEZERO MP ACTIVE IN SYSTEM     A42413 71336021
         BNE   NOTS1                     NO - PROCEED                   71340020
         TS    AVTOPCOB+8                ANY ONE QUEUI                  71350020
         BC    4,TSTMP651                YES, WAIT UNTIL HE IS DONE     71360020
NOTS1    EQU   *                                                        71370020
         MVC   AVTOPCOB+1(3),5(R1)       DEQUEUE THE ELEMENT            71380020
         MVI   AVTOPCOB+8,AVTEZERO       DONE, CLEAR TS SWITCH          71390020
         BR    RWORK2                                                   71400020
         SPACE 2                                                        71600020
RSTRMOV  LR    RMOVE,RLIST               GET BEGINNING                  71800020
         LA    RMOVE,ZERO(RMOVE)         CLEAR HIGH BYTE                72000020
         SR    RTCB,RTCB                CLEAR FOR LENGHH                72200020
         IC    RTCB,OPCRLN+1           GET LENGTH                A49232 72400022
         AH    RMOVE,OPCBIT1             GET ABSOLUTE POSITION          72600020
         CLC   OPCBIT1(TWO),FZERO        ISTHIS FOR CONTROL WORDS       72610020
         BNE   RSTRMOV2                  NO, PROCEED NORMALLY           72620020
         MVC   ZERO(FOUR,RMOVE),OPCSNSE                                 72630020
         MVC   ZERO(FOUR,RMOVE),OPCSNSE    RESTORE  FIRST CONTRL WRD    72640020
         CLI   LCBRSKEY,X1A              IS THIS FOR BUFFERED TERMS     72650020
         BNE   RSTRMOV1                  NO, PROCEED                    72660020
         MVC   FIVE(ONE,RMOVE),OPCSNSE+5    RESTORE AUTOPOLL BIT        72670020
RSTRMOV1 EQU   *                                                        72680020
         SH    RTCB,H8                    SET TO RESTORE REST           72690020
         EX    RTCB,MOVRSTR1             RESTORE THE REST               72700020
         B     OUT1                      DONE GET OUT                   72710020
RSTRMOV2 EQU   *                                                        72720020
         EX    RTCB,MOVRSTR              MOVE INTO THE LIST             72800020
         B     OUT1                      DONE GET OUT                   73000020
*                                                                       73200020
MOVE     EQU   X'14'                                                    73400020
POST     EQU   X'0C'                                                    73600020
TJID     EQU   X'80'                                                    73800020
TX       EQU   X'40'                                                    74000020
ELEVEN   EQU   11                                                       74200020
TWELVE   EQU   12                                                       74400020
NFSTFLG  EQU   X'80'                                             A49232 74406022
X7F      EQU   X'7F'                                                    74412022
X1A      EQU   X'1A'                                                    74420020
ONE      EQU   1                                                        74440020
TWO      EQU   2                                                        74460020
FOUR     EQU   4                                                        74480020
FIVE     EQU   5                                                        74500020
EIGHT    EQU   8                                                        74520020
HEX80    EQU   X'80'                                                    74600020
HEX82    EQU   X'82'                                                    74800020
CU       EQU   X'18'                                                    75000020
EOL      EQU   X'FE'                                                    75200020
CVTPTR   EQU   16                       POINTER TO CVT           A42413 75300021
H12      DC    H'12'                                                    75400020
MOVRSTR  MVC   ZERO(ZERO,RMOVE),OPCSNSE                                 75600020
MOVRSTR1 MVC   EIGHT(ZERO,RMOVE),OPCSNSE+8                              75700020
MOVCKPT  MVC   OPCSNSE(OPCONE),ZERO(RMOVE)                              75800020
         SPACE 2                                                        76000020
MOVEA    MVC   OPCSAVE2(OPCONE),OPCONE(R1)                              76200020
MOVEB    MVC   OPCZERO(OPCONE,R1),OPCSAVE2                              76400020
MVC      MVC   OPCZERO(OPCONE,RLIST),OPCZERO(RMOVE)                     76600020
         SPACE 3                                                        76800020
MACTIVE1 LA    R14,OPCTWO               HOUSEKEEP                       77000020
         SR    RENTRYX,R14              BACK UP TWO FOR EOTFE           77200020
         SR    RSWAP,R14                  SAME                          77400020
         MVC   OPCDATA+8(OPCTWO),OPCONE(RENTRYX)  SAVE EOTFE            77600020
         EX    RLTH1,MOVEACT1           MOVE TO ACTIVE                  77800020
         LA    R14,OPCONE(RLENGTH,RENTRYX)  ADDRESSING FOR EOTFE        78000020
         MVC   OPCZERO(OPCTWO,R14),OPCDATA+8     RESET EOTFE            78200020
         B     MACTIVE2                 CARRY ON                        78400020
         EJECT                                                          78600020
H256     DC    H'256'                                                   78800020
H8       DC    H'8'                                                     78900020
FZERO    DC    F'0'                                                     79000020
ZERO     EQU   0                                                        79200020
ECB      EQU   12                                                       79400020
ACTEND   EQU   X'FE'                                                    79600020
EOTENT   EQU   X'80'     EOT(BSC)   IN STATUS BYTE                      79800020
SWAP1    XC    OPCONE(OPCZERO,RSWAP),OPCONE(RENTRYX)                    80000020
SWAP2    XC    OPCONE(OPCZERO,RENTRYX),OPCONE(RSWAP)                    80200020
SWAP3    XC    OPCONE(OPCZERO,RSWAP),OPCONE(RENTRYX)                    80400020
MOVACT   MVC   OPCZERO(OPCZERO,RENTRYX),OPCONE(RENTRYX)                 80600020
MOVEACT1 MVC   OPCONE(OPCZERO,RENTRYX),OPCTHREE(RENTRYX)                80800020
         IEAQFX 65,MCH,M65MP                                     A42413 81000021
         TOPCD                                                          81200020
OPCPPL1  EQU   OPCSCAN-8                                                81400020
OPCPPLA  EQU   OPCSCAN-7                                                81600020
OPCPPL2  EQU   OPCSCAN-4                                                81800020
         TAVTD                                                          82000020
         TDEBD                                                          82200020
         DCBD  DSORG=TX                                                 82400020
         TPRIOR                                                         82600020
         TLCBD                                                          82800020
         END                                                            83000020
