         TITLE '''IEDQC3'' - COPY LIST STATUS'                          00300020
IEDQC3   CSECT                                                          00600020
*********************************************************************** 00900020
*                                                                     * 01200020
*TITLE 'IEDQC3' PROCESSOR OF DISPLAY LIST COMMANDS                    * 01500020
*                                                                     * 01800020
*STATUS -- CHANGE LEVEL 0                                             * 02100020
*                                                                     * 02400020
*FUNCTION -- THIS MODULE PROCESSES OPERATOR CONTROL COMMANDS WHICH    * 02700020
*   REQUEST DISPLAY OF THE STATUS FIELD OF INVITATION LISTS.          * 03000020
*                                                                     * 03300020
*   THE COPY INVITATION LIST STATUS ROUTINE CHECKS THE COMMON INPUT   * 03600020
*   BLOCK TO DETERMINE IF THE LINE WAS SPECIFIED IN THE DDNAME/RLN    * 03900020
*   OR THE HARDWARE ADDRESS FORMAT.  IF DDNAME/RLN, THE RELATIVE      * 04200020
*   LINE IS TESTED FOR 'ALL'.  IF SO, THE COMMAND IS REJECTED, AS     * 04500020
*   ONLY STATUS FOR A SINGLE LINE MAY BE DISPLAYED.  THE ROUTINE      * 04800020
*   EXITS TO THE CONTROL MODULE.  OTHERWISE, THE RLN IS CONVERTED     * 05100020
*   TO HEXADECIMAL, AND TESTED FOR A VALUE OF ZERO OR GREATER THAN    * 05400020
*   255.  IF EITHER CASE, THE COMMAND IS REJECTED AND CONTROL EXITS   * 05700020
*   TO THE CONTROL MODULE.  IF THE RLN IS VALID, THE TCB IS           * 06000020
*   OBTAINED FROM THE AVT (AVTTCB) AND THE TIOT (AT TCB+12) IS        * 06300020
*   SERIALLY SEARCHED FOR A DDNAME MATCHING THAT SPECIFIED.  IF       * 06600020
*   NONE IS FOUND, AN ERROR MESSAGE IS BUILT AND CONTROL RETURNS TO   * 06900020
*   THE CONTROL MODULE.  WHEN A MATCHING ENTRY IS FOUND, ITS OFFSET   * 07200020
*   INTO THE TIOT IS SAVED.                                           * 07500020
*                                                                     * 07800020
*   FOR BOTH FORMATS, THE START OF THE DEB CHAIN IS OBTAINED FROM     * 08100020
*   TCB+8, AND EACH ASSOCIATED DCB (DEBDCBAD) IS TESTED FOR TCAM      * 08400020
*   LINE TYPE (DSORG OF X'40').  IF THE END OF THE DEB CHAIN IS       * 08700020
*   REACHED BEFORE A DCB IS FOUND, AN ERROR MESSAGE IS BUILT AND      * 09000020
*   CONTROL RETURNS TO THE CONTROL MODULE.                            * 09300020
*                                                                     * 09600020
*   FOR DDNAME/RLN FORMAT, ONCE THE DCB HAS BEEN FOUND, ITS OFFSET    * 09900020
*   INTO THE TIOT (DCBTIOT) IS COMPARED TO THAT COMPUTED ABOVE.  IF   * 10200020
*   IT DOES NOT MATCH, THE NEXT DEB IS LOCATED AND SEARCHING          * 10500020
*   CONTINUES AS ABOVE.  WHEN THE PROPER DCB IS FOUND, ITS UCB        * 10800020
*   ADDRESS IS TESTED FOR OPEN DD DUMMY.  IF YES, AN ERROR MESSAGE    * 11100020
*   IS BUILT AND CONTROL RETURNS TO THE CONTROL MODULE.               * 11400020
*                                                                     * 11700020
*   IF THE ADDRESS FORMAT IS USED, EACH UCB ASSOCIATED WITH THE DEB   * 12000020
*   IS TESTED FOR A MATCH TO THE ONE SPECIFIED.  THE DEB CHAIN IS     * 12300020
*   SEARCHED AS ABOVE UNTIL A MATCH IS FOUND.                         * 12600020
*                                                                     * 12900020
*   ONCE THE PROPER DCB HAS BEEN OBTAINED, THE RLN PROVIDED (OR       * 13200020
*   COMPUTED IF ADDRESS FORMAT) IS COMPARED TO THE NUMBER OF LINES    * 13500020
*   IN THE LINE GROUP.  IF THE RLN IS GREATER, AN ERROR MESSAGE IS    * 13800020
*   BUILT AND CONTROL RETURNS TO THE CONTROL MODULE.  THE LINE IS     * 14100020
*   THEN TESTED FOR OPEN STATUS, AND IF NOT OPEN THE ERROR MESSAGE    * 14400020
*   IS BUILT AND THE SAME EXIT TAKEN.  IF THE LINE IS OPEN, ITS       * 14700020
*   INVITATION LIST IS OBTAINED (DCBINVLI) AND THE STATUS BYTE        * 15000020
*   VALUES ARE CONVERTED TO THEIR PRINTABLE EQUIVALENTS AND PLACED    * 15300020
*   IN THE RESPONSE.  THE ROUTINE EXITS TO THE CONTROL MODULE.        * 15600020
*                                                                     * 15900020
*ENTRY POINTS --                                                      * 16200020
*        'IEDQC3' TO PROCESS DISPLAY LIST OPERATOR CONTROL            * 16500020
*   COMMANDS.  CALLING SEQUENCE IS                                    * 16800020
*                        LOAD EPLOC=LOADPRFX                          * 17100020
*                        LR   R1,ROPC                                 * 17400020
*                        LR   R15,R0                                  * 17700020
*                        BALR R14,R15                                 * 18000020
*                                                                     * 18300020
*INPUT -- REGISTER 1 - ADDRESS OF THE OPERATOR CONTROL AVT.  AT THE   * 18600020
*   TAG OPCCKELE IS THE COMMON INPUT BLOCK.  FIELDS USED BY THIS      * 18900020
*   ROUTINE ARE                                                       * 19200020
*                   +4   OPCLEN    0 IF RLN ALL                       * 19500020
*                                  X'80' IF HARDWARE ADDRESS          * 19800020
*                                  1 - 3 - LENGTH OF RLN              * 20100020
*                   +5   OPCRLN    RELATIVE LINE NUMBER               * 20400020
*                   +8   OPCTNME   DDNAME OR LINE ADDRESS             * 20700020
*                                                                     * 21000020
*    REGISTER 15 - ENTRY POINT ADDRESS.                               * 21300020
*                                                                     * 21600020
*OUTPUT -- REGISTER 1 - ADDRESS OF APPROPRIATE RESPONSE MESSAGE.      * 21900020
*                                                                     * 22200020
*   REGISTER 15 - RETURN CODE.  VALUES ARE                            * 22500020
*                   0    DISPLAY IS SUCCESSFUL                        * 22800020
*                   4    RLN IS ALL, ZERO, GREATER THAN 255, OR       * 23100020
*                        GREATER THAN NUMBER OF LINES, LINE IS NOT    * 23400020
*                        OPEN OR OPEN DD DUMMY.                       * 23700020
*                                                                     * 24000020
*EXITS-NORMAL -- A RESPONSE MESSAGE CONTAINING THE REQUESTED DATA     * 24300020
*   IS PREPARED AND ITS ADDRESS IS RETURNED TO THE CALLER.            * 24600020
*                                                                     * 24900020
*EXITS-ERROR -- RLN IS ALL, ZERO, OR GREATER THAN 255.  COMMAND       * 25200020
*   INVALID MESSAGE BUILT, X'04' RETURN CODE SET.                     * 25500020
*                                                                     * 25800020
*   LINE NOT FOUND SEARCHING DEB CHAIN, RLN NOT IN LINE GROUP, LINE   * 26100020
*   NOT OPEN OR OPEN DD DUMMY.  NOT OPEN MESSAGE BUILT, X'04'         * 26400020
*   RETURN CODE SET.                                                  * 26700020
*                                                                     * 27000020
*EXTERNAL ROUTINES -- N/A.                                            * 27300020
*                                                                     * 27600020
*TABLES/WORK AREAS -- MESSAGES, STATUS CONVERSION TABLE, AVT, DEB,    * 27900020
*   DCB, OPERATOR CONTROL AVT.                                        * 28200020
*                                                                     * 28500020
*ATTRUBUTES -- SERIALLY REUSABLE, REFRESHABLE, ENABLED, TRANSIENT,    * 28800020
*   RROBLEM PROGRAM MODE.                                             * 29100020
*                                                                     * 29400020
*NOTES -- THE OPERATON OF THIS MODULE DEPENDS UPON AN INTERNAL        * 29700020
*   REPRESENTATION OF THE EXTERNAL CHARACTER SET WHICH IS             * 30000020
*   EQUIVALENT TO THE ONE USED AT ASSEMBLY TIME.  THE CODING HAS      * 30300020
*   BEEN ARRANGED SO THAT REDEFINITION OF ''CHARACTER'' CONSTANTS,    * 30600020
*   BY REASSEMBLY, WILL RESULT IN A CORRECT MODULE FOR THE NEW        * 30900020
*   DEFINITIONS.                                                      * 31200020
*                                                                     * 31500020
*   MESSAGES ISSUED BY THIS MODULE ARE                                * 31800020
*              IED017I, IED018I, IED059I                              * 32100020
*                                                                     * 32400020
*********************************************************************** 32700020
*                                                                       33000020
*                                                                       33300020
R0       EQU   0                        WORK                            33600020
R1       EQU   1                        PARAMETER                       33900020
ROPC     EQU   2                        OPERATOR CONTROL AVT            34200020
RCIB     EQU   3                        INPUT UNIT BASE                 34500020
RAVT     EQU   4                        AVT BASE                        34800020
RTCB     EQU   5                        TCB BASE                        35100020
RDEB     EQU   5                        DEB BASE                        35400020
ROFF     EQU   6                        DDNAME OFFSET                   35700020
RRLN     EQU   6                        RLN SAVE                        36000020
RDCB     EQU   7                        DCB BASE                        36300020
RDD      EQU   8                        DDNAME                          36600020
RUCB     EQU   8                        UCB BASE                        36900020
RLIST    EQU   9                        INVITATION LIST BASE            37200020
RLCB     EQU   10                       LCB BASE                        37500020
RWORK    EQU   10                       WORK                            37800020
RCTR     EQU   11                       COUNTER                         38100020
RWORK2   EQU   11                       WORK                            38400020
RBASE    EQU   12                       ROUTINE BASE                    38700020
R13      EQU   13                       SAVE AREA                       39000020
R14      EQU   14                       RETURN                          39300020
R15      EQU   15                       ENTRY POINT                     39600020
RWORK3   EQU   15                       WORK                            39900020
         USING IEDQC3,RBASE             ADDRESSABILITY FOR ROUTINE      40200020
         USING IEDQOPC,ROPC             ADDRESSABILITY FOR OP CTL       40500020
         USING IEDQAVTD,RAVT            ADDRESSABILITY FOR AVT          40800020
         USING DEBNMSUB,RDEB            ADDRESSABILITY FOR DEB          41100020
         USING IHADCB,RDCB              ADDRESSABILITY FOR DCB          41400020
         USING IEDQLCB,RLCB             ADDRESSABILITY FOR LCB          41700020
         SAVE  (14,12),,IEDQC3-02/18/71                                 42000020
         LR    RBASE,R15                GIVE ROUTINE A BASE             42300020
         LR    ROPC,R1                  GET OP CONTROL AVT              42600020
         L     RCIB,OPCINPUT            GET INPUT INIT                  42900020
         L     RAVT,OPCAVTAD                                            43200020
         L     RTCB,AVTTCB                                              43500020
         TM    OPCLEN,ADCODE             DDOR ADDR                      43800020
         BO    GETLCB                    ADDR - SKIP RLN CODE           44100020
*                                                                       44400020
         CLI   OPCLEN,AVTEZERO          RLN 'ALL'                       44700020
         BE    COMINV                   YES - REJECT COMMAND            45000020
*                                                                       45300020
         MVC   OPCDOUBL(OPCTHREE),OPCRLN PUT RLN IN WORK AREA           45600020
         SR    R15,R15                  CLEAR                           45900020
         IC    R15,OPCLEN               GET LENGTH OR RLN               46200020
         BCTR  R15,R0                   DECREMENT FOR EXECUTE       620 46500020
         EX    R15,PACK                 CONVERT RLN TO PACKED       620 46800020
         XC    OPCDOUBL(OPCSIX),OPCDOUBL CLEAR FOR CVB              620 47100020
         CVB   RWORK,OPCDOUBL           CONVERT RLN TO HEX          619 47400020
         LTR   RWORK,RWORK              ZERO RLN SPECIFIED          619 47700020
         BZ    COMINV                   YES - REJECT COMMAND        619 48000020
*                                                                   619 48300020
         CH    RWORK,MAXVAL             RLN > 255 SPECIFIED         619 48600020
         BH    COMINV                   YES - REJECT COMMAND        619 48900020
*                                                                   619 49200020
         STC   RWORK,OPCDOUBL           SAVE HEX RLN                    49500020
GETDATA  EQU   *                                                        49800020
         L     RDD,TIOT(RTCB)           GET TIOT ADDR               619 50100020
         LA    ROFF,STARTOFF            OFFSET OF FISST DD              50400020
         SR    RWORK2,RWORK2            CLEAR                           50700020
         LA    RDD,STARTOFF(RDD)        ADDR OF FIRST DDNAME        619 51000020
DDLOOP   EQU   *                                                        51300020
         IC    RWORK2,OPCZERO(,RDD)     GET LENGTH OF DD ENTRY          51600020
         CLI   OPCZERO(RDD),OPCZERO     ANOTHER DD                      51900020
         BE    ERR                      NO - DDNAME NOT FOUND           52200020
*                                                                       52500020
         CLC   OPCFOUR(OPCEIGHT,RDD),OPCTNME SPECIFIED DD               52800020
         BE    GETLCB                   YES - CONTINUE PROCESSING       53100020
*                                                                       53400020
         AR    ROFF,RWORK2              BUMP OFFSET                     53700020
         AR    RDD,RWORK2               BUMP TO NEXT ENTRY              54000020
         B     DDLOOP                   LOOK AT NEXT DDNAME             54300020
*                                                                       54600020
GETLCB   EQU   *                                                        54900020
         L     RDEB,DEB(,RTCB)          GET FIRST DEB                   55200020
GETDCB   EQU   *                                                        55500020
         L     RDCB,DEBDCBAD            GET DCB ADDR                    55800020
         LA    RDCB,OPCZERO(,RDCB)      CLR HI BYTE FOR COMPARE         56100020
         TM    DCBDSORG+1,TX            TCAM LINE                       56400020
         BNO   NEXTDEB                  NO - GET NEXT DCB               56700020
*                                                                       57000020
         TM    OPCLEN,ADCODE             DD OR ADDR                     57300020
         BO    UCB                       ADDR - CHAIN THRU UCBS         57600020
*                                                                       57900020
         LH    RWORK2,DCBTIOT           GET OFFSET TO DD                58200020
         CR    RWORK2,ROFF              SAME AS CALCULATED              58500020
         BNE   NEXTDEB                  NO - GET NEXT DEB               58800020
*                                                                       59100020
         SR    R0,R0                    CLEAR                           59400020
         IC    R0,OPCDOUBL              GET RLN                         59700020
         LR    RWORK,R0                 SAVE RLN FOR TEST               60000020
         CLC   OPCDOUBL(OPCONE),DEBNMEXT  EXTENT NUMBER GREATER TOTAL   60100020
         BH    ERR                      YES, NOT OPENED                 60200020
         SLL   RWORK,OPCTWO             MULTIPLY BY FOUR                60300020
         L     RWORK,DEBUCBAD-4-DEBNMSUB(RWORK,RDEB) GET UCB ADDR       60600020
         LA    RWORK,OPCZERO(,RWORK)    CLEAR HIGH TYTE                 60900020
         LTR   RWORK,RWORK              OPENEDD DD DUMMY                61200020
         BZ    ERR                      YES - REJECT COMMAND            61500020
COUNTOK  EQU   *                                                        61800020
         B     PROCESS                  PROCESS COMMAND                 62100020
*                                                                       62400020
UCB      EQU   *                                                        62700020
         SR    RWORK,RWORK              CLEAR                           63000020
         IC    RWORK,DEBNMEXT           GET NUMBER OF LINES             63300020
         LA    RWORK3,DEBUCBAD          GET POINTER TO UCBS             63600020
         LA    RCTR,OPCONE              SET COUNTER                     63900020
UCBLOOP  EQU   *                                                        64200020
         L     RUCB,OPCZERO(,RWORK3)    GET UCB ADDR                    64500020
         CLC   ADDR(OPCTHREE,RUCB),OPCTNME RIGHT UCB                    64800020
         BE    FOUND                    YES                             65100020
*                                                                       65400020
         LA    RCTR,OPCONE(,RCTR)       INCREMENT COUNT                 65700020
         LA    RWORK3,OPCFOUR(,RWORK3)  GET TO NEXT UCB ADDR            66000020
         CR    RCTR,RWORK               ANY MORE EXTENTS                66300020
         BH    NEXTDEB                  NO - GET NEXT DEB               66600020
*                                                                       66900020
         B     UCBLOOP                  YES - LOOK AT NEXT UCB          67200020
*                                                                       67500020
FOUND    EQU   *                                                        67800020
         LR    R0,RCTR                  PUT RLN OFFSET FOR MULTIPLY     68100020
         STC   RCTR,OPCDOUBL            SAVE RLN                        68400020
         B     COUNTOK                  GO COMPUTE LCB ADDR             68700020
*                                                                       69000020
NEXTDEB  EQU   *                                                        69300020
         L     RDEB,OPCFOUR(,RDEB)      GET ADDR OF NEXT DEB            69600020
         LA    RDEB,OPCZERO(RDEB)       CLEAR HIGH BYTE                 69900020
         LTR   RDEB,RDEB                ANOTEHR DEB                     70200020
         BNZ   GETDCB                   YES - PROCESS IT            619 70500020
*                                                                       70800020
ERR      EQU   *                                                        71100020
         MVC   MSGE(OPCEIGHT),OPCTNME   PUT NAME IN MSG                 71400020
         CLI   OPCLEN,ADCODE            RLN SPECIFIED                   71700020
         BE    ERR1                     NO                              72000020
*                                                                       72300020
         MVC   MSGE+9(OPCTHREE),OPCRLN  PUT RLN IN MSG                  72600020
ERR1     EQU   *                                                        72900020
         LA    RWORK,EMSG               GET MG ADDR                     73200020
SETBAD   EQU   *                                                        73500020
         LA    R15,OPCFOUR              SET BAD RETURN                  73800020
         B     PUT                                                      74100020
*                                                                       74400020
PROCESS  EQU   *                                                        74700020
         SR    RRLN,RRLN                CLEAR FOR INDEXING              74800020
         IC    RRLN,OPCDOUBL           GET RLN                          75000020
         CLC   OPCDOUBL(OPCONE),DEBNMEXT RLN > NUMBER OF LINES          75300020
         BH    ERR                      YES - BUILD ERROR MSG       619 75600020
*                                                                   619 75900020
         CLI   DCBTIOT,A                LINE OPEN                   619 76200020
         BNL   ERR                      NO - BUILD ERROR MSG        619 76500020
*                                                                   619 76800020
         SLL   RRLN,OPCTWO                                              77100020
         LA    RLIST,DCBINVLI-4(RRLN)   GET LIST ADDR                   77400020
         L     RLIST,OPCZERO(,RLIST)    GET LIST                        77700020
         TM    OPCTHREE(RLIST),AUTO        AUTOPOLL BIT ON              78400020
         BNO   NODATA                      NO                           79100020
         MVC   MSGL+25(OPCSIX),AUTOW    PUT AUTOPOLL IN MESSAGE         79900020
*                                                                       80700020
         MVC   MSGL(OPCEIGHT),OPCTNME   PUT NAME IN MSG                 81000020
         CLI   OPCLEN,ADCODE            RLN SPECIFIED                   81300020
         BE    MSG1                     NO                              81600020
*                                                                       81900020
         MVC   MSGL+9(OPCTHREE),OPCRLN  PUT RLN IN MSG                  82200020
MSG1     EQU   *                                                        82500020
         LA    RWORK,LMSG               GET MSG LIST ADDR               82800020
         B     SETGOOD                                                  83100020
*                                                                       83400020
NODATA   EQU   *                                                        83700020
         MVC   MSGN(OPCEIGHT),OPCTNME   PUT NAME IN MSG                 84000020
         CLI   OPCLEN,ADCODE            RLN SPECIFIED                   84300020
         BE    NODATA1                  NO                              84600020
*                                                                       84900020
         MVC   MSGN+9(OPCTHREE),OPCRLN  PUT RLN IN MSG                  85200020
NODATA1  EQU   *                                                        85500020
         LA    RWORK,NMSG               GET NO ENTREIS MSG ADDR         85800020
SETGOOD  EQU   *                                                        86100020
         SR    R15,R15                  SET GOOD RETURN                 86400020
PUT      EQU   *                                                        86700020
         ST    RWORK,OPCREG1(,R13)      STORE ADDR IN SAVE AREA         87000020
         RETURN (14,12),T,RC=(15)                                       87300020
*                                                                       87600020
COMINV   EQU   *                                                    619 87900020
         LA    RWORK,OPCERMSG           GET MSG INVALID ADDR        619 88200020
         B     SETBAD                                                   88500020
*                                                                       88800020
DEB      EQU   8                                                        89100020
ELEVEN   EQU   11                                                       89400020
TWELVE   EQU   12                                                       89700020
TIOT     EQU   12                                                       90000020
ADDR     EQU   13                                                       90300020
STARTOFF EQU   24                                                       90600020
AUTO     EQU   X'01'                                                    90900020
TX       EQU   X'40'                                                    91200020
ADCODE   EQU   X'80'                                                    91500020
A        EQU   C'A'                                                 619 91800020
PACK     PACK  OPCDOUBL+6(OPCTWO),OPCDOUBL(OPCONE)                  620 92100020
AUTOW    DC    C'AUTOPL'                                                92400020
MAXVAL   DC    H'255'                                               619 92700020
LMSG     DS    0H                                                       92800020
         DC    AL2(DESCR1-*),X'6000'     LENGTH MCS FLAGS               92900020
         DC    C'IED059I '                                              93000020
MSGL     DC    12C' ',C' LIST STATUS=',13C' '                           93100020
DESCR1   DC    X'08000000'               DESCRIPTOR AND ROUTING         93200020
NMSG     DS    0H                                                       93300020
         DC    AL2(DESCR2-*),X'6000'     LENGTH MCS FLAGS               93400020
         DC    C'IED059I '                                              93500020
MSGN     DC    12C' ',C' LIST STATUS=NO BITS ON'                        93600020
DESCR2   DC    X'08000000'               DESCRIPTOR AND ROUTING         93700020
EMSG     DS    0H                                                       93800020
         DC    AL2(DESCR3-*),X'6000'     LENGTH MCS FLAGS               93900020
         DC    C'IED017I LINE '                                         94000020
MSGE     DC    12C' ',C' NOT OPEN'                                      94100020
DESCR3   DC    X'08000000'               DESCRIPTOR AND ROUTING         94200020
         PRINT NOGEN                                                    94800020
         TLCBD                                                          95100020
         TOPCD                                                          95400020
         TAVTD                                                          95700020
         TPRFD                                                      619 96000020
         TDEBD                                                          96300020
         DCBD  DSORG=TX                                                 96600020
         END                                                            96900020
