 TITLE 'IEDQC6 - FEROUTER '                                             00200020
IEDQC6   CSECT                                                          00400020
*********************************************************************** 00600020
*                                                                     * 00800020
*MODULE NAME--IEDQC6 FEROUTER                                         * 01000020
*                                                                     * 01100020
*STATUS--CHANGE LEVEL 1                                               * 01200020
*                                                                     * 01300020
*FUNCTION--  THIS MODULE PROCESSES OPERATOR CONTROL COMMANDS WHICH      01500020
*   REQUEST LOADING OR DELETING A SERVICE AID. IF THE COMMAND IS VALID  01800020
*   THE SERVICE AID ROUTINE IS EXECUTED AND A RESPONSE MESSAGE RETURNED 02100020
*                                                                       02400020
*   ADDRESSABILITY IS ESTABLISHED AND THE DESIRED SERVICE AID NAME IS   02700020
*   ACCESSED THROUGH IEDQCA02. THE LOAD OR DELETE FUNCTION IS CHECKED,  03000020
*   IF EITHER FUNCTION IS NOT FOUND AN ERROR MESSAGE IS PREPARED AND    03300020
*   CONTROL RETURNS TO THE CALLING ROUTINE. THE SERVICE AID IS ACCESSED 03600020
*   FROM THE OPERATOR CONTROL AVT.  A BLDL IS PERFORMED TO DETERMINE IF 03800020
*   THE NAME PROVIDED IS A SERVICE AID ROUTINE (IEDQFE**) AND WHETHER   04000020
*   OR NOT THE MODULE EXISTS ON SYS1.LINKLIB OR JOB/STEPLIB.  IF        04200020
*   NEITHER OF THE TWO CONDITIONS ABOVE EXIST, MESSAGE IED102I INVALID  04400020
*   OPERAND IS ISSUED.                                                  04600020
*                                                                       04800020
*   IF THE COMMAND REQUESTS A LOADING OF A SERVICE AID THE LOAD LIST IS 05100020
*   CHECKED FOR THE SERVICE AID BEING ACTIVE. FINDING THE ROUTINE       05400020
*   ACTIVE A MESSAGE IS PREPARED AND CONTROL RETURNS TO THE CALLING     05700020
*   ROUTINE.                                                            06000020
*   IF THE SERVICE IS NOT ACTIVE A GETMAIN IS ISSUED TO DETERMINE       06300020
*   IF THERE IS ENOUGH CORE AVAILABLE TO LOAD IT. IF CORE IS AVAILABLE  06600020
*   THE SERVICE AID IS LOADED AND GIVEN CONTROL.                        06900020
*   UPON RETURN FROM THE SERVICE AID THE RETURN CODE IS                 07200020
*   CHECKED AND FOR GOOD INITIALIZATION A MESSAGE IS PREPARED AND       07500020
*   CONTROL RETURNS TO THE CALLING ROUTINE. UPON RETURN FROM THE        07800020
*   SERVICE AID WITH A BAD RETURN CODE A MESSAGE IS PREPARED AND THE    08100020
*   SERVICE AID IS DELETED AND CONTROL RETURNED TO THE CALLING          08400020
*   ROUTINE.                                                            08700020
*   IF CORE IS NOT AVAILABLE A TEST IS MADE TO SEE HOW MUCH MORE CORE   09000020
*   IS NEEDED IN ORDER TO LOAD THE SERVICE AID AND A MESSAGE IS         09300020
*   PREPARED TO INFORM THE REQUESTOR.                                 * 09600020
*                                                                       09900020
*   IF THE COMMAND REQUESTS A DELETING OF A SERVICE AID THE LOAD        10200020
*   LIST IS CHECKED FOR THE SERVICE AID BEING ACTIVE. FINDING THE       10500020
*   SERVICE AID NOT ACTIVE A MESSAGE IS PREPARED AND CONTROL IS         10800020
*   RETURNED TO THE CALLING ROUTINE. THE SERVICE AID, BEING ACTIVE      11100020
*   IS GIVEN CONTROL. UPON RETURN THE RETURN CODE IS CHECKED.           11400020
*   FOR A GOOD RETURN CODE A DEACTIVATION MESSAGE IS PREPARED,          11700020
*   THE SERVICE AID IS DELETED AND CONTROL IS RETURNED TO THE CALLING   12000020
*   ROUTINE. UPON RETURN FROM THE SERVICE AID WITH A BAD RETURN         12300020
*   CODE A MESSAGE IS PREPARED AND CONTROL IS RETURNED TO THE CALLING   12600020
*   ROUTINE.                                                            12900020
*                                                                       13200020
*ENTRY POINTS--                                                         13500020
*   'IEDQC6' TO PROCESSES DEBUG OPERATOR CONTROL COMMANDS.              13800020
*                                                                       14100020
*INPUT-- REGISTER 1 - ADDRESS OF PARAMETER(WHICH IS ADDRESS OF          14400020
*   OPERATOR CONTROL AVT)                                               14700020
*   REGISTER 15 - ENTRY POINT ADDRESS.                                  15000020
*                                                                       15300020
*OUTPUT-- REGISTER 1 - ADDRESS OF APPROPRIATE RESPONSE MESSAGE.         15600020
*                                                                       15900020
*EXTERNAL ROUTINES--                                                    16200020
*   'IEDQCA02' TO ACCESS SERVICE AID NAME.                              16500020
*   SERVICE AID ROUTINE.                                                16800020
*        ***************************************************            17100020
*        EXIT TO SERVICE AID-                                         * 17400020
*             REGISTER 0 INDICATES LOAD OR DELETE FUNCTION              17700020
*             REGISTER 15 ENTRY POINT                                   18000020
*             REGISTER 14 RETURN REGISTER                               18300020
*        RETURN FROM SERVICE AID-                                     * 18600020
*             REGISTER 15 RETURN CODE:                                  18900020
*                  0 = GOOD RETURN                                      19200020
*                  4 = MULTIPLE REQUEST                               * 19500020
*                  8 OR HIGHER NOT DEFINED                              19800020
*                  NEGITIVE = COMPLIMENT OF ADDRESS WHICH POINTS TO     20100020
*                             A MESSAGE.                                20400020
*                                                                       20700020
*EXITS-NORMAL-- COMMAND IS PROCESSED. A RESPONSE MESSAGE IS CONSTRUCTED 21000020
*   AND ITS ADDRESS RETURNED TO THE CALLING ROUTINE.                    21300020
*   THE NORMAL EXIT MESSAGES ARE-                                       21600020
*   IED099I  ROUTINE LOADED                                           * 21900020
*   IED100I  ROUTINE DEACTIVATED                                      * 22200020
*                                                                       22500020
*EXITS-ERROR--                                                          22800020
*   IED101I  RESTART IN PROGRESS                                        23700020
*   IED102I  INVALID OPERAND                                            24000020
*   IED103I  RTN ALREADY ACTIVE                                         24300020
*   IED104I  ROUTINE NOT ACTIVE                                         24600020
*   IED105I  RETURN CODE=0000                                           24900020
*   IED106I  MULTIPLE REQUEST                                           25200020
*   IED107I  COMWRITE NOT ACTIVE                                        25500020
*   IED109I  ROUTINE NOT DELETED                                        25800020
*   IED125I  0000 BYTES NEEDED                                          26100020
*                                                                       26400020
*TABLES/WORK AREAS-- WORK AREAS CONTAINING THE FIXED PORTION OF         26700020
*   EACH RESPONSE MESSAGE AND SPACE FOR INSERTION OF VARIABLE DATA;     27000020
*   DSECTS OF AVT, OPERATOR CONTROL AVT                                 27300020
*                                                                       27600020
*ATTRIBUTES PROBLEM PROGRAM MODE                                      * 27900020
*                                                                     * 28200020
* NOTE-  THE OPERATION OF THIS MODULE DEPENDS UPON AN INTERNAL          28500020
*        REPRESENTATION OF THE EXTERNAL CHARACTER SET WHICH IS          28800020
*        EQUIVALENT TO THE ONE USED AT ASSEMBLY TIME. REDEFINITION OF   29100020
*        CHARACTER CONSTANTS BY REASSEMBLY WILL RESULT IN A CORRECT     29400020
*        MODULE FOR THE NEW DEFINITIONS. THIS MODULE IS ALSO            29700020
*        DEPENDENT ON DISPLACEMENTS IN SOME OS CONTROL BLOCKS. THESE    30000020
*        DISPLACEMENTS ARE DEFINED IN THE EQUATES PRECEEDING THE        30300020
*        CODING. REDEFINITION OF THESE EQUATES & REASSEMBLY WILL        30600020
*        RESULT IN A CORRECT MODULE FOR THE NEW DISPLACEMENTS.          30900020
*********************************************************************** 31200020
* CONTROL CHARACTERS       COMMAND             OPERAND                  31500020
*   ************************************************************        31800020
*   CONTROL CHARS *    **      **        *           ** **              32100020
*                 *    * MODIFY *  IDENT,* DEBUG   = * L *  ,NAME       32400020
*                 *   *          *       *          *     *             32700020
*                 *    *   F    *        *           * D *              33000020
*                 *    **      **        *           **  *              33300020
*                                                                       33600020
*                                                                       33900020
*      SERVICE AID JOB NAME                                             34200020
*       ***      ***                                                    34500020
*       * IEDQFE10 *                                                    34800020
*       * IEDQFE20 *                                                    35100020
* NAME=*  IEDQFE30  *                                                   35400020
*       * IEDQFE** *                                                    35700020
*       * IEDQFE** *                                                    36000020
*       ***      ***                                                    36300020
*   ************************************************************        36600020
*                                                                       36900020
*********************************************************************** 37200020
         EJECT                                                          37500020
         USING IEDQC6,RBASE        ROUTINE BASE                         37800020
         USING IEDQAVTD,RAVT       AVT BASE REG                         38100020
         USING IEDQOPC,ROPC        OP CTL AVT BASE                      38400020
R0       EQU   0                                                        38700020
R1       EQU   1                   PARAMETER                            39000020
ROPC     EQU   2                   OPER CTRL AVT BASE                   39300020
RCIB     EQU   3                   INPUT BASE (BFR UNIT)                39600020
RAVT     EQU   4                   AVT BASE                             39900020
RWRK2    EQU   5                   WORK REGISTER                        40200020
RETREG   EQU   6                   LOCAL RETURN REG                     40500020
RWRK1    EQU   7                   WORK REGISTER                        40800020
RINDX    EQU   8                   INDEX REGISTER                       41100020
RBASE    EQU   12                  ROUTINE BASE                         41400020
R13      EQU   13                  SAVE AREA                            41700020
R14      EQU   14                  RETURN                               42000020
R15      EQU   15                  ENTRY POINT                          42300020
CDEEPAD  EQU   X'10'               CDE DISPL TO EP                      42600020
CVTTCBP  EQU   0                   CVT DISPL-ADDR NEW/OLD POINTERS      42900020
TCBOLD   EQU   4                   DISPL  IN NEW/OLD TO OLD TCB         43200020
TCBLLS   EQU   X'24'               TCB DISPL TO LOAD LIST POINTER       43500020
LLECDEAD EQU   X'04'               LOAD LIST ELEM DISP TO CDE ADDR      43800020
MODNAME  EQU   X'08'               CDE DISPL TO MODULE NAME             44100020
LLENXT   EQU   X'00'               LOAD LIST ELEM DISP TO NEXT LLE      44400020
ACTIVET  EQU   X'80'               COMWRITE ACTIVE BIT IN AVTCWFL2      44700020
EIGHT    EQU   8                   LENGTH OF OPERAND                    45600020
         SAVE  (14,12),,IEDQC6--5-6-70 SAVE REGS                        45900020
         LR    RBASE,R15           SET BASE                             46200020
         LA    RWRK1,REGSAVE                                            46500020
         ST    R13,4(,RWRK1)                                            46800020
         ST    RWRK1,8(R13)                                             47100020
         LR    R13,RWRK1                                                47400020
         LR    ROPC,R1             LOAD OP CTL AVT BASE                 47700020
         L     RCIB,OPCINPUT       GET INPUT ADDR (BFR UNIT)            48000020
         L     RAVT,OPCAVTAD       GET AVT ADDR                         48300020
         TM    AVTCWFL2,ACTIVET    IS COMWRITE IN CORE                  48600020
         BZ    ERR10               NO BRANCH                            48900020
         TM    OPCCKBIT,OPCRSTN    RESTART IN PROGRESS                  49200020
         BO    ERR1                YES-RETURN                           49500020
         LA    R1,EIGHT            LENGTH OF OPERAND                    49800020
         L     R15,OPCSCAN         GET FIRST OPERAND                    50100020
         BALR  R14,R15             OPERAND                              50400020
*     ******** ON RETURN OPCDOUBL CONTAINS 8 BYTE OPERAND ********      50700020
         MVC   TYPOPER(1),OPCDOUBL SAVE OPERATION TYPE                  51000020
         CLI   OPCDOUBL,C'D'       CHECK FOR DELETE FUNCTION            51300020
         BNE   CHKLD               NO                                   51600020
         LA    RETREG,DELETE       YES                                  51900020
         B     SEARCH                                                   52200020
CHKLD    CLI   OPCDOUBL,C'L'       CHECK FOR LOAD FUNCTION              52500020
         BNE   ERR2                NO                                   52800020
         LA    RETREG,LOAD         RETURN POINT FOR LOAD FUNCTION       53100020
SEARCH   L     R15,OPCSCAN         GO GET ROUTINE NAME                  53400020
         LA    R1,EIGHT            LENGTH OF OPERAND                    53700020
         BALR  R14,R15             AND PUT IN OPCDOUBL                  54000020
         CLC   OPCDOUBL(6),NAME    VALID SERVICE NAME- IEDQFE**         54400020
         BNE   ERR2                IF NO, ISSUE IED102I MESSAGE         54800020
         MVC   NAME+6(2),OPCDOUBL+6 MOVE IN LAST 2 CHARS TO BLDL LIST   55200020
         BLDL  0,BLDLLIST          SEE IF MODULE EXISTS                 55600020
         LTR   R15,R15             CHECK RETURN CODE FROM BLDL          56000020
         BNZ   ERR2                IF CANT FIND OR I/O ERR..IED102I     56400020
         L     R15,16              GET CVT ADDRESS                      56900020
         L     RWRK1,CVTTCBP(,R15) GET ADDR OF                          57400020
         L     RWRK1,TCBOLD(RWRK1) ACTIVE TCB                           57900020
         L     RWRK1,TCBLLS(RWRK1) AND LOAD LIST                        58200020
CDELOOP  LTR   RWRK2,RWRK1         END OF LIST                          58500020
         BZ    INACTIVE            YES                                  58800020
         TM    116(R15),X'20'      IS THIS AN MFT SYSTEM                58900020
         BO    LLSLOOP             IF YES,CHECK LOAD LIST               59000020
         L     RWRK2,LLECDEAD(RWRK1) GET CDE ADDR                       59100020
LLSLOOP  CLC   MODNAME(8,RWRK2),NAME  FOR THIS ROUTINE                  59400020
         BE    ACTIVE              YES                                  59700020
         L     RWRK1,LLENXT(RWRK1) NO                                   60000020
         B     CDELOOP             CONTINUE SEARCH                      60300020
INACTIVE SR    R15,R15             ZERO REG 15                          60600020
         B     4(RETREG)           RETURN INACTIVE                      60900020
ACTIVE   TM    116(R15),X'20'      IS THIS AN MFT SYSTEM                61000020
         BZ    ACTIVE1             IF NO,GO GET EPA FROM CDE            61100020
         LA    RWRK2,4(,RWRK2)     ELSE INCREMENT TO EPA IN MFT LLE     61200020
ACTIVE1  L     R15,CDEEPAD(,RWRK2) GET EPA                              61300020
         BR    RETREG              RETURN ACTIVE                        61500020
EXIT     MVC   MESSAGE+4(29),0(RWRK1) BUILD MESSAGE                     61800020
EXIT1    LA    RWRK1,MESSAGE                                            62100020
         L     R13,REGSAVE+4       RESTORE                              62700020
         ST    RWRK1,24(R13)       RETURN MESSAGE                       63000020
         LM    14,12,12(R13)       RESTORE REGS                         63300020
         SR    R15,R15             ZERO R15                             63600020
         BR    R14                                                      63900020
LOAD     B     ERR3                ALREADY ACTIVE                       64200020
         MVC   STORAMT+5(3),NAME+24 GET MODULE SIZE                     64250020
         L     R1,STORAMT+4        GET SIZE INTO REGISTER               64300020
         ST    R1,STORAMT+4        STORE BACK INTO GETMAIN PARAM LIST   64450020
         GETMAIN VC,LA=STORAMT,A=STORALOC TEST FOR ENOUGH CORE          64500020
         LTR   R15,R15                                                  64800020
         BNZ   TESTCORE            BRANCH IF NOT ENOUGH                 65100020
         FREEMAIN V,A=STORALOC     FREE GOTTEN CORE                     65400020
         LOAD  DE=NAME             LOAD SERVICE AID                     65700020
         LR    R15,R0              LOAD RTNE ENTRY POINT                66000020
         LA    R0,0                INDICATE LOAD FUNCTION               66300020
         BALR  R14,R15             GO INITIALIZE                        66600020
*                                  GO TO ROUTINE AND RETURN HERE        66900020
         LTR   R15,R15             INITIALIZED OK ?                     67200020
         BNZ   ERRCODE             NO                                   67500020
         LA    RWRK1,LOADMSG       ISSUE LOAD MSG                       67800020
         B     EXIT                                                     68100020
DELETE   B     DELACT              ACTIVE-DELETE                        68400020
         B     ERR4                NOT ACTIVE                           68700020
DELACT   LA    R0,255              INDICATE DELETE FUNCTION             69000020
         BALR  14,15               GO DEACTIVATE                        69300020
         LTR   R15,R15             DEACTIVATED OK                       69600020
         BNZ   ERRCODE             NO                                   69900020
         LA    RWRK1,DLTDMSG       SET DELETE MESSAGE                   70200020
         MVC   MESSAGE+4(29),0(RWRK1) BUILD MESSAGE                     70500020
         BAL   RETREG,SCRATCH                                           70800020
         B     EXIT1                                                    71100020
SCRATCH DELETE DE=NAME             DELETE SERVICE AID                   71400020
         LTR   R15,R15             CHECK RETURN CODE                    71700020
         BNZ   MODIFY              IF BAD,WRITE ERROR MESSAGE           72100020
         BR    RETREG              ELSE GO INITIALIZE                   72500020
ERRCODE  BNP   USER                USER MESSAGE SUPPLIED                72900020
         C     R15,FOUR            RTN CODE EQUAL TO FOUR               73200020
         BE    ERR8                YES MULTIPLE REQUEST                 73500020
         STH   R15,WORK1           GENERATE USER                        73800020
         UNPK  WORK2(5),WORK1(3)   COMPLETION                           74100020
         TR    WORK2(4),TRTABLE-240 CODE AND                            74400020
         MVC   ERRMSG5+21(4),WORK2 MOVE INTO MESSAGE                    74700020
         LA    RWRK1,ERRMSG5                                            75000020
         B     MOVEMSG                                                  75300020
USER     LCR   R15,R15             RECOMPLIMENT                         75600020
         LR    RWRK1,R15           SET POINTER TO USER MSG              75900020
MOVEMSG  MVC   MESSAGE+4(29),0(RWRK1) MOVE INDICATED MESSAGE            76200020
*                                  INTO BLANK MESSAGE                   76500020
         BAL   RETREG,VERDEL                                            76800020
         B     EXIT1               DELETED OKAY                         77100020
MODIFY   LA    RWRK1,ERRMSG11                                           77400020
         B     EXIT                                                     77700020
VERDEL   CLI   TYPOPER,C'D'        COMPARE OPERATION                    78000020
         BNE   SCRATCH                                                  78300020
         B     4(RETREG)                                                78600020
ERR1     LA    RWRK1,ERRMSG1                                            78900020
         B     EXIT                                                     79200020
ERR2     LA    RWRK1,ERRMSG2                                            79500020
         B     EXIT                                                     79800020
ERR3     LA    RWRK1,ERRMSG3                                            80100020
         B     EXIT                                                     80400020
ERR4     LA    RWRK1,ERRMSG4                                            80700020
         B     EXIT                                                     81000020
ERR8     LA    RWRK1,ERRMSG8                                            81300020
         B     MOVEMSG                                                  81600020
ERR10    LA    RWRK1,ERRMSG10                                           81900020
         B     EXIT                                                     82200020
TESTCORE L     RWRK2,STORAMT+4     GET AMOUNT OF CORE REQUESTED         82700020
         S     RWRK2,STORALOC+4    SUBTRACT AMOUNT OF CORE OBTAINED     83200020
         FREEMAIN V,A=STORALOC     FREE GOTTEN CORE                     83700020
         ST    RWRK2,WORK3         SAVE DIFFERENCE                      84000020
         UNPK  WORK2(9),WORK3(5)                                        84300020
         TR    COREMSG+9(4),TRTABLE-240                                 84600020
         MVI   COREMSG+14,X'40'                                         84900020
         LA    RWRK1,COREMSG                                            85200020
         B     EXIT                                                     85500020
BLDLLIST DC    AL2(1),AL2(58)      PREFIX FOR BLDL                      85900020
NAME     DC    CL8'IEDQFE',XL50'00'    BLDL ENTRY FOR SERVICE AID LOAD  86300020
MESSAGE  DC    H'32',X'1000',29C' '                                     86700020
LOADMSG  DC    CL29'IED099I  ROUTINE LOADED      '                      87000020
DLTDMSG  DC    CL29'IED100I  ROUTINE DEACTIVATED '                      87300020
ERRMSG1  DC    CL29'IED101I  RESTART IN PROGRESS '                      87600020
ERRMSG2  DC    CL29'IED102I  INVALID OPERAND     '                      87900020
ERRMSG3  DC    CL29'IED103I  RTN ALREADY ACTIVE  '                      88200020
ERRMSG4  DC    CL29'IED104I  ROUTINE NOT ACTIVE  '                      88500020
ERRMSG5  DC    CL29'IED105I  RETURN CODE=0000    '                      88800020
ERRMSG8  DC    CL29'IED106I  MULTIPLE REQUEST'                          89100020
ERRMSG10 DC    CL29'IED107I  COMWRITE NOT ACTIVE '                      89400020
ERRMSG11 DC    CL29'IED109I  ROUTINE NOT DELETED '                      89700020
COREMSG  DC    CL29'IED125I  0000 BYTES NEEDED   '                      90000020
         DS    0F                                                       90300020
REGSAVE  DS    18F                 REGISTER SAVE AREA                   90600020
FOUR     DC    X'00000004'                                              90900020
WORK1    DC    H'0'                                                     91500020
         DC    X'0F'                                                    91800020
WORK2    DS    5X                                                       92100020
WORK3    DC    F'0'                                                     92400020
TYPOPER  DC    CL1' '              SAVE TYPE OF OPERATION               92700020
TRTABLE  EQU   *                   THIS IS THE TRANSLATE TABLE          93000020
         DC    C'0123456789ABCDEF'                                      93600020
STORALOC DC    2F'0'               PARMS FOR GETMAIN                    93900020
STORAMT  DC    F'0'                PARMS FOR                            94200020
         DC    F'4095'             GETMAIN                              94500020
         TOPCD                                                          97500020
         TAVTD                                                          97800020
         END                                                            98100020
