         TITLE 'IEDQCA - RESIDENT OPERATOR CONTROL MODULE'              00100022
IEDQCA   CSECT                                                          00200022
         SPACE 3                                                        00200122
* CHANGE-ACTIVITY = AS FOLLOWS:                                         00200222
********************* MICROFICHE FLAGS ********************** SUPT CODE 00200322
*A065500,069300,075500,077200,081500,086500,108200,140000        S22024 00220022
*A142100,190000,320000,327007,3340000,398000,541200,710200       S22024 00220122
*A710340,710420,710640,71900                                     S22024 00220222
*C007000                                                         S22024 00220322
*A675000                                                        SA62344 00220422
*A710340,710420,710640,71900,297000,327385,327392                S22024 00220522
*C532000,534000,536000,540000                                   SA63617 00220652
*A568000,589000                                                 SA67103 00220755
*C694000                                                        SA69063 00220855
*C199000-201000                                                 OX03954 00220955
         SPACE 3                                                        00250655
*********************************************************************** 00300022
*                                                                     * 00400022
*TITLE - IEDQCA - TCAM OPERATOR CONTROL RESIDENT MODULE               * 00500022
*                                                                     * 00600022
* MODULE NAME=IEDQCA                                                  * 00700022
*                                                                     * 00710022
* DESCRIPTIVE NAME=TCAM OPERATOR CONTROL RESIDENT MODULE              * 00720022
*                                                                     * 00730022
* COPYRIGHT='NONE'                                                    * 00740022
*                                                                     * 00750022
* STATUS: CHANGE LEVEL 5                                              * 00760022
*                                                                     * 00800022
*FUNCTION - THIS MODULE SAVES REGISTERS, SETS UP A WAIT LIST, THEN    * 00900022
*        GIVES CONTROL TO THE INITIAL OP CONTROL TRANSIENT VIA SVC 104* 01000022
*        IT CONTAINS THE OPERATOR CONTROL AVT AND SEVERAL SUBROUTINES * 01100022
*        INCLUDING AN OUTPUT SUBTASK ACCESSED DIRECTLY BY TCAM.       * 01200022
*                                                                     * 01300022
*ENTRY POINTS - IEDQCA IS PASSED CONTROL BY OS WHEN OPERATOR CONTROL  * 01400022
*        IS ATTACHED.                                                 * 01500022
*               SUBROUTINES LISTED BELOW ARE LINKED TO BY VARIOUS     * 01600022
*        TRANSIENTS.                                                  * 01700022
*                   TRMOFLOC                                          * 01800022
*                   DCBLOCAT                                          * 01900022
*                   ALLOCBUF                                          * 02000022
*                   LCBSETUP                                          * 02100022
*               THE SUBROUTINE OSTCB IS ENTERED DIRECTLY BY THE TCAM  * 02200022
*        DISPATCHER WHEN THE DUMMY LCB IS POSTED TO ITSELF TO BE FREED* 02300022
*                                                                     * 02400022
*INPUT - TO IEDQCA                                                    * 02500022
*              REGISTER 1 CONTAINS THE ADDRESS OF THE AVT             * 02600022
*              REGISTER 14 CONTAINS THE RETURN ADDRESS                * 02700022
*        TO THE VARIOUS SUBROUTINES                                   * 02800022
*              A PROLOGUE FOR EACH SUBROUTINE DOCUMENTS ITS INPUT     * 02900022
*                                                                     * 03000022
*OUTPUT - FROM IDEQCA                                                 * 03100022
*              NONE                                                   * 03200022
*         FROM SUBROUTINES                                            * 03300022
*              OUTPUT IS DOCUMENTED IN EACH SUBROUTINE PROLOGUE       * 03400022
*                                                                     * 03500022
*EXTERNAL REFERENCES - IGC0010D, CALLING ROUTINE                      * 03600022
*                                                                     * 03700022
*EXITS,NORMAL                                                         * 03800022
*   TO TCAM OPERATOR CONTROL VIA SVC 104                              * 03900022
*   TO OS IF CLOSEDOWN IN PROGRESS                                    * 04000022
*                                                                     * 04100022
*EXITS,ERROR - N/A                                                    * 04200022
*                                                                     * 04300022
*TABLES/WORK AREAS - TCAM AVT, OPC AVT, OPCE                          * 04400022
*                                                                     * 04500022
*ATTRIBUTES - ATTACHED,RESIDENT,ENABLED,REUSABLE                      * 04600022
*                                                                     * 04700022
*CHARACTER CODE DEPENDENCY                                            * 04800022
*        THE OPERATION OF THIS MODULE DEPENDS UPON AN INTERNAL        * 04900022
*        REPRESENTATION OF THE EXTERNAL CHARACTER SET WHICH IS        * 05000022
*        EQUIVALENT TO THE ONE USED AT ASSEMBLY TIME.  THE CODING     * 05100022
*        HAS BEEN ARRANGED SO THAT REDEFINITION OF CHARACTER          * 05200022
*        CONSTANTS, BY REASSEMBLY WILL RESULT IN A CORRECT MODULE     * 05300022
*        FOR THE NEW DEFINITION.                                      * 05400022
*                                                                     * 05500022
*NOTES - COMMUNICATIONS BETWEEN THE VARIOUS TRANSIENT MODULES IS      * 05600022
*        PRIMARILY THROUGH THE OPERATOR CONTROL AVT.                  * 05700022
*                                                                     * 05800022
*********************************************************************** 05900022
         EJECT                                                          06000022
         SPACE                                                          06100022
*              E Q U A T E S                                            06200022
         SPACE                                                          06300022
RZERO    EQU   0                       REGISTER 0 - BRANCH PARAMETER    06400022
RPARM    EQU   1                       OPC AVT ADDRESS                  06500022
RLGBAD   EQU   1                        LGB ADDRESS              S22024 06550022
ROPCAVT  EQU   2                       POINTER TO OPC AVT               06600022
ROPCE    EQU   3                       POINTER TO CURRENT OPCE          06700022
RAVT     EQU   4                       POINTER TO TCAM AVT              06800022
RWORKA   EQU   5                       POINTER TO RESIDENT WORKAREA     06900022
RTRMLK   EQU   5                        RETURN ADDR OF GROUP LK  S22024 06930022
RTNTAD   EQU   5                        TERM NAME TABLE ADDR     S22024 06960022
ROFF     EQU   6                       TIOT OFFSET                      07000022
RTERM    EQU   6                       TERMINAL ENTRY POINTER           07100022
RTNT     EQU   7                       TERM NAME TABLE POINTER          07200022
RTIOT    EQU   7                       TIOT POINTER                     07300022
RUCB     EQU   7                       POINTER TO UCB                   07400022
RWORK    EQU   8                       WORK REGISTER                    07500022
RTRMENTA EQU   8                        TERM ENTRY ADDR          S22024 07550022
RDEB     EQU   9                       POINTER TO DEB                   07600022
RWORK1   EQU   9                       WORK REGISTER                    07700022
RQCBPTR  EQU   9                        QCB ADDRESS              S22024 07720022
RLCBAD   EQU   9                        LCB ADDRESS              S22024 07740022
RTNTOFF  EQU   9                        TNT OFFSET               S22024 07760022
RPREFIX  EQU   10                      POINTER TO BUFFER                07800022
RWORK2   EQU   10                      WORK REGISTER                    07900022
RLEN     EQU   10                      RELATIVE LINE NO.                08000022
RDCB     EQU   11                      DCB POINTER                      08100022
RRSID    EQU   11                       RESOURCE ID              S22024 08150022
RCIB     EQU   11                      POINTER TO INPUT CIB             08200022
RBASE    EQU   12                      BASE REGISTER                    08300022
RSAVE    EQU   13                      POINTER TO SAVEAREA              08400022
RRET     EQU   14                      RETURN FROM SUBROUTINES          08500022
RBRNCH   EQU   15                      SUBROUTINE ENTRY AND BASE        08600022
RBRANCH  EQU   15                       BRANCH REG AND BASE REG  S22024 08650022
         SPACE 2                                                        08700022
ALL      EQU   255                 ALL ONES                             08800022
ALTDEST  EQU   X'80'               INDICATE PROCESSING ALTERNATE DEST   08900022
AL0      EQU   0                       LENGTH USED IN EXECUTED INSTRUCT 09000022
AL1      EQU   1                       MOVE LENGTH OF ONE               09100022
AL2      EQU   2                   LENGTH OF 2                          09200022
AL3      EQU   3                       MOVE LENGTH OF THREE             09300022
AL4      EQU   4                       MOVE LENGTH OF 4                 09400022
AL8      EQU   8                       COMPARE LENGTH                   09500022
BACKCHN  EQU   4                       BACKWARD SAVEAREA CHAINING       09600022
BADDD    EQU   X'20'                    DDNAME NOT IN TIOT              09700022
INVALRLN EQU   8                        INDICATE INVALID RLN            09800022
BUFFERB  EQU   X'E4'                    BUFFER ERB PRIORITY             09900022
BUSY     EQU   4                       ROUTINE BEING USED BY MP         10000022
CLRFLAG  EQU   X'07'               CLEARS FLAGS OF UCB                  10100022
CVTPTR   EQU   16                       LOW CORE ADDRESS OF CVT         10200022
DDOFF    EQU   24                      OFFSET TO FIRST DD IN TIOT       10300022
DEB      EQU   4                       OFFSET TO DEB                    10400022
ECB      EQU   4                   OFFSET TO OP CONTROL ECB             10500022
EIGHT    EQU   8                       ADD EIGHT TO REGISTER            10600022
ERBBUFF  EQU   8                        OFFSET TO BUFFER ADDRESS        10700022
ERBSTATE EQU   X'41'                   STATE OF ERB TO BD               10800022
OPENED   EQU   X'10'                    DCB IS OPENED MASK       S22024 10820022
NOERRTN  EQU   X'0C'                    NO SYSTEM ERROR RTNS     S22024 10840022
MSG166   EQU   166                      ERROR MSG FOR DCB OPEN   S22024 10860022
*                                       FAILED                   S22024 10880022
FOUR     EQU   4                       ADD FOUR TO REGISTER             10900022
FORCHAIN EQU   8                       FORWARD CAHIN SAVEAREAS          11000022
LINK     EQU   4                        OFFSET TO QUEUE LINKAGE FIELDS  11100022
MPPREQ   EQU   2                   BUFFER REQ FROM MPP                  11200022
OFF00    EQU   0                       ZERO OFFSET FOR LOAD             11300022
OFF01    EQU   1                       ONE OFFSET FOR MOVE              11400022
OFF02    EQU   2                       TWO OFFSET                       11500022
OFF04    EQU   4                       FOUR OFFSET FOR LOAD             11600022
OFF05    EQU   5                   OFFSET OF 5 FOR ERB SETUP            11700022
OFF08    EQU   8                       EIGHT OFFSET FOR MOVE            11800022
OFF09    EQU   9                   OFFSET OF 9 FOR ERB SETUP            11900022
OFF0B    EQU   11                  OFFSET TO TIC ADDR OF 2              12000022
OFF0C    EQU   12                       12 OFFSET                       12100022
OFF0D    EQU   13                      MOVE OFFSET OF 13                12200022
ONE      EQU   1                       VALUE OF 1                       12300022
ONEBUFF  EQU   1                   INDICATE ONE BUFFER                  12400022
OPEN     EQU   X'10'                   INDICATES OPEN DCB               12500022
OPENERR  EQU   1                        DCB NOT OPEN                    12600022
OUTPRI   EQU   X'F9'                   OUTPUT MESSAGE PRIORITY          12700022
PARTREQ  EQU   64                  PARTIAL UNIT REQUEST                 12800022
POST     EQU   X'0C'                   CROSS PARTITION POST             12900022
PRIOFF   EQU   4                        OFFSET TO INPUT PRIORITIES      13000022
PROCESS  EQU   X'20'               INDICATES PROCESS ENTRY              13100022
REST     EQU   36                  LENGTH OF LAST OF OPCE               13200022
SAVEOFF  EQU   0                        OFFSET FOR SUBROUTINES   S22024 13300022
SAVE12   EQU   12                      OFFSET 12 INTO SAVE AREA LINKAGE 13400022
TEN      EQU   10                      ADD 10 TO REGISTER               13500022
THREE    EQU   3                       ADD THREE                        13600022
TIC      EQU   8                        OFFSET TO TIC FIELD IN UNIT     13700022
TIOT     EQU   12                      TIOT OFFSET IN TCB               13800022
TWO      EQU   2                        TWO                      S22024 13900022
TXTRDCB  EQU   X'44'                    INDICATES TCAM DCB FOR A S22024 14000022
*                                       270X                     S22024 14030022
*                                       LINE OR A 3705 CONTROL UNIT     14060022
UNITCNT  EQU   13                  OFFSET TO COUNT GOTTEN               14100022
ZERO     EQU   0                        ZERO                     S22024 14200022
BADNAME  EQU   4                        RETURN CODE INVALID NAME S22024 14210022
SEVEN    EQU   7                        MASK                     S22024 14220022
HEXZERO  EQU   X'00'                    NULL TNT OFFSET ENTRY    S22024 14230022
ISOPEN   EQU   X'10'                    OFLGS MASK               S22024 14240022
LINENT   EQU   X'80'                    LINE ENTRY MASK          S22024 14250022
OPCFRMCA EQU   X'10'                    ENTRY FROM IEDQCA        S22024 14260022
         EJECT                                                          14300022
*        BASE REGISTERS FOR TCAM CONTROL BLOCKS USED                    14400022
*                                                                       14500022
         USING IEDQAVTD,RAVT           TCAM AVT ADDRESSABILITY          14600022
         USING IEDQOPCE,ROPCE          OPC ELEMENT ADDRESSABILITY       14700022
         USING IEDQPRF,RPREFIX     BUFFER PREFIX BASE                   14800022
         USING IEDQTRM,RTERM       TERM ENTRY ADDRESSABILITY            14900022
         USING IEDQTNTD,RTNT           TNT ADDRESSABILITY               15000022
         SPACE                                                          15100022
         STM   RRET,RBASE,SAVE12(RSAVE) SAVE CALLER'S REGISTERS         15200022
         BALR  RBASE,0             SET BASE REGISTER                    15300022
         USING *,RBASE             ADDRESSABILITY                       15400022
IEDQCA   IEDHJN  SKIPID                                                 15500022
         LR    RAVT,RPARM          SAVE AVT POINTER                     16000022
         LA    ROPCAVT,OPCAVT      PICK UP OP CONTROL AVT ADDRESS       16100022
         USING OPCAVT,ROPCAVT          OPC AVT ADDRESSABILITY           16200022
         ST    RAVT,OPCAVTPT       SAVE TCAM AVT ADDRESS                16300022
         LA    RWORK,AVTINOUT      PICK UP ADDRESS OF DUMMY IN/OUT      16400022
         ST    RWORK,OSCBINOT      PLACE ADDRESS ON LCB/SCB             16500022
         LA    RWORK,AVTOPCOB      GET OPC QCB ADDRESS                  16600022
         ST    RWORK,OPCQCBAD      PLACE IT IN OPC AVT                  16700022
         ST    ROPCAVT,AVTOCGET    PLACE OUR AVT ADDRESS IN TCAM AVT    16800022
         SPACE                                                          16900022
WAIT     EQU   *                                                        17000022
         LA    RWORK,AVTOPCOB+OFF04 GET ECB ADDRESS (TERM INPUT)        17100022
         ST    RWORK,OPCWAIT+OFF04 PLACE ADDRESS IN WAIT LIST           17200022
         L     RWORK,AVTCOMPT      GET CSCB ADDRESS (CONSOLE INPUT ECB) 17300022
         L     RWORK1,OFF00(RWORK) GET CONSOLE ECB ADDRESS              17400022
         ST    RWORK1,OPCWAIT+OFF08 PLACE ECB ADDR IN WAIT LIST         17500022
         MVI   OPCWAIT+OFF08,AVTE80 SET END OF LIST INDICATOR           17600022
         LTR   RWORK1,RWORK1       CIB'S SPECIFIED?                     17700022
         BNZ   CHKINPUT            YES, CHECK FOR INPUT                 17800022
         SPACE                                                          17900022
         MVI   OPCWAIT+OFF04,AVTE80 SET END OF LIST AFTER TERM ECB      18000022
CHKINPUT EQU   *                                                        18100022
         L     RWORK,OFF04(RWORK)  PICK UP CIB ADDRESS                  18200022
         LA    RWORK,ZERO(RWORK)   CLEAR HIGH BYTE                      18300022
         LTR   RWORK,RWORK         ANY CIB'S?                           18400022
         BNZ   XCTL                YES, START COMMAND SERVICING         18500022
         CLC   AVTOPCOB+ONE(THREE),AVTDELAD+ONE ANYTHING QUEUED         18530022
         BNE   XCTL                     YES, SERVICE COMMAND            18560022
         SPACE                                                          18600022
         WAIT  1,ECBLIST=OPCWAIT   WAIT FOR INPUT                       18700022
         MVI   AVTOPCOB+OFF04,AVTEZERO  RESET COMPLETE BIT              18750022
         SPACE                                                          18800022
XCTL     EQU   *                                                        18900022
         OI    OPCSPEC,OPCFRMCA         SET ENTRY FLAG FOR 00    S22024 19000022
         SR    RZERO,RZERO              CLEAR PARAMETER REGISTER S22024 19050022
         LR    RPARM,ROPCAVT       POINT REG 1 TO OPC AVT               19100022
         TOPCTL                    FIRST LOAD OF SVC 104                19200022
         SPACE                                                          19300022
         TM    AVTBIT1,AVTCLOSN    CLOSEDOWN IN EFFECT?                 19400022
         BNO   WAIT                NO, WAIT FOR NEXT INPUT              19500022
         SPACE                                                          19600022
         CLC   OPCWAITO(AL4),AVTFZERO ALL OUTPUT DONE?                  19700022
         BNE   WAIT                NO, WAIT FOR COMPLETION              19800022
         TM    AVTCKELF,AVTCMCPN+AVTCCLCN  MCP CLOSE FINISHED   OX03954 19900055
*                                          AND CHKPT REQUESTED  OX03954 20000055
         BZ    WAIT                     NO                      OX03954 20100055
         SPACE                                                          20200022
         RETURN (14,12),T          RESTORE REGS, RETURN TO OS           20300022
         DROP  RBASE               CHANGE BASE REGISTERS                20400022
         TITLE 'IEDQCA - TERM NAME OFFSET CALCULATING ROUTINE'          20500022
*********************************************************************** 20600022
*                                                                     * 20700022
*        ENTRY TO THIS CODE IS VIA A 'BALR' FROM VARIOUS SVC          * 20800022
*        TRANSIENT MODULES.  THE INPUT IS AS FOLLOWS -                * 20900022
*                   REGISTER 2 - POINTER TO OP CONTROL AVT            * 21000022
*                   REGISTER 3 - POINTER TO THE CURRENT OPCE          * 21100022
*                   REGISTER 4 - POINTER TO THE TCAM AVT              * 21200022
*                   REGISTER 13 - POINTS TO OP CONTROL SAVE AREA      * 21300022
*                   REGISTER 14 - CONTAINS RETURN ADDRESS             * 21400022
*                   REGISTER 15 - CONTAINS ROUTINE ENTRY POINT ADDRESS* 21500022
*                   OPCDOUBL CONTAINS TERMNAME TO BE CHECKED          * 21600022
*                           (LEFT JUSTIFIED PADDED WITH BLANKS)       * 21700022
*        RETURN IS - NORMAL - REGISTER 14 PLUS 0 -                    * 21800022
*                           REGISTER 1 HAS THE TERM ENTRY ADDRESS     * 21900022
*                           OPCE CONTAINS TNT OFFSET                  * 22000022
*                   ABNORMAL - REGISTER 14 PLUS 4 -                   * 22100022
*                           INVALID TERMINAL NAME                     * 22200022
*                                                                     * 22300022
*********************************************************************** 22400022
         USING TRMOFLOC,RBRNCH     BASE FOR THIS CODE                   22500022
TRMOFLOC EQU   *                                                        22600022
         STM   RTERM,RWORK1,SAVEOFF(RSAVE) SAVE REGISTERS               22700022
         L     RTNT,AVTRNMPT       TNT ADDRESSABILITY                   22800022
         SR    RWORK,RWORK         CLEAR COUNTER OFFSET                 22900022
         LH    RWORK1,TNTLEN       GET NUMBER OF TNT ENTRIES            23000022
         N     RWORK1,AVTCLRHI     CLEAR LEFT HALF OF REGISTER          23100022
         SR    RTERM,RTERM         CLEAR REG FOR NAME LENGTH            23200022
         IC    RTERM,TNTENLEN      PICK UP MAXIMUM TERMNAME LENGTH      23300022
         BCTR  RTERM,RZERO         DECREMENT LENGTH FOR EXECUTE         23400022
         LA    RTNT,TNTFIRST       GET FIRST ENTRY ADDRESS              23500022
TESTTRM  EQU   *                                                        23600022
         LA    RWORK,ONE(RWORK)    UPDATE OFFSET COUNTER                23700022
         CR    RWORK,RWORK1        END OF TNT?                          23800022
         BH    TRMERROR            YES, RETURN WITH ERROR               23900022
         SPACE                                                          24000022
         EX    RTERM,COMPNAME      COMPARE NAME                         24100022
         BE    NAMEMAT             CORRECT NAME, CHECK LENGTH           24200022
         SPACE                                                          24300022
         LA    RTNT,FOUR(RTERM,RTNT) POINT TO NEXT ENTRY                24400022
         B     TESTTRM             CHECK FOR END OF TABLE OF NEXT ENTRY 24500022
         SPACE                                                          24600022
COMPNAME CLC   OPCDOUBL(AL0),OFF00(RTNT) COMPARE TERM NAMES             24700022
         SPACE 2                                                        24800022
NAMEMAT  EQU   *                                                        24900022
         CH    RTERM,AVTHA7        SEVEN LENGTH?                        25000022
         BE    ENTRYOK             CORRECT NAME, RETURN INFO TO TRANS   25100022
         SPACE                                                          25200022
         LA    RPARM,OPCDOUBL      POINT TO NAME START                  25300022
         AR    RPARM,RTERM         ADD NAME LENGTH TO GET LAST BYTE     25400022
         CLI   ONE(RPARM),AVTEBLNK  BLANK PAST LAST CHARACTER           25500022
         BNE   TRMERROR            NO, ERROR IN NAME                    25600022
         SPACE                                                          25700022
ENTRYOK  EQU   *                                                        25800022
         STH   RWORK,OCTRMTBL      STORE TNT OFFSET IN OPCE             25900022
         LA    RTNT,ZERO(RTNT,RTERM)    ADD LENGTH TO GET ADDRESS       26000022
         MVC   OPCTRMWA(AL4),OFF00(RTNT) MOVE ADDRESS TO WORD FOR LOAD  26100022
         L     RPARM,OPCTRMWA      PICK UP TERM ENTRY ADDRESS           26200022
         B     TRMRETUN            RETURN WITHOUT ERROR                 26300022
         SPACE                                                          26400022
TRMERROR EQU   *                                                        26500022
         LA    RRET,FOUR(RRET)     RETURN AT ERROR POINT                26600022
TRMRETUN EQU   *                                                        26700022
         LM    RTERM,RWORK1,SAVEOFF(RSAVE) RESTORE REGISTERS            26800022
         BR    RRET                RETURN TO CALLING TRANSIENT          26900022
         TITLE 'IEDQCA - DCB LOOK-UP ROUTINE'                           27000022
*********************************************************************** 27100022
*                                                                     * 27200022
*        ENTRY TO THIS CODE IS VIA A 'BALR' FROM VARIOUS SVC          * 27300022
*        TRANSIENT MODULES.  THE INPUT IS AS FOLLOWS -                * 27400022
*                   REGISTER 1 IS ZERO                                * 27500022
*                           OPCDOUBL CONTAINS EBCDIC LINE NUMBER      * 27600022
*                           (LEFT JUSTIFIED)                          * 27700022
*                   REGISTER 1 - CONTAINS RLN                         * 27800022
*                           OPCDOUBL CONTAINS DDNAME                  * 27900022
*                           (LEFT JUSTIFIED PADDED WITH BLANKS)       * 28000022
*                   REGISTER 2 - POINTER TO THE OP CONTROL AVT        * 28100022
*                   REGISTER 3 - POINTER TO THE CURRENT OPCE          * 28200022
*                   REGISTER 4 - POINTER TO THE TCAM AVT              * 28300022
*                   REGISTER 13 - POINTS TO OP CONTROL SAVE AREA      * 28400022
*                   REGISTER 14 - CONTAINS RETURN ADDRESS             * 28500022
*                   REGISTER 15 - CONTAINS ROUTINE ENTRY POINT ADDRESS* 28600022
*        RETURN IS - NORMAL - REGISTER 14 PLUS 0 -                    * 28700022
*                           REGISTER 0 HAS THE UCB ADDRESS            * 28800022
*                           REGISTER 1 HAS THE DCB ADDRESS            * 28900022
*                           OPCE CONTAINS THE RLN                     * 29000022
*                       IF GROUPNAME,RLN LOOKUP THEN:                 * 29020022
*                           REGISTER 0 HAS THE LINE ENTRY ADDRESS     * 29040022
*                           REGISTER 1 HAS THE LGB ADDRESS            * 29060022
*                   ABNORMAL - REGISTER 14 PLUS 4 -                   * 29100022
*                           DDNAME NOT FOUND                          * 29200022
*                              REGISTER 0 CONTAINS X'20'              * 29300022
*                           INVALID RELATIVE LINE NUMBER              * 29400022
*                              REGISTER 0 CONTAINS X'08'              * 29500022
*                           DCB NOT OPEN                              * 29600022
*                              REGISTER 0 CONTAINS X'01'              * 29700022
*                            3705 NOT ACTIVE                    S22024* 29720022
*                               REGISTER 0 CONTAINS X'01'       S22024* 29740022
*                            3705 IS BEING IPLED OR DUMPED      S22024* 29760022
*                               REGISTER 0 CONTAINS X'01'       S22024* 29780022
*                                                                     * 29800022
*********************************************************************** 29900022
         USING IHADCB,RDCB             DCB ADDRESSABILITY               30000022
         USING DEBNMSUB,RDEB       DEB ADDRESSABILITY                   30100022
         USING DCBLOCAT,RBRNCH                                          30200022
DCBLOCAT EQU   *                                                        30300022
         STM   RWORKA,RDCB,AVTEZERO(RSAVE) SAVE REGISTERS        S22024 30400022
         L     RWORKA,AVTTCB       GET TCAM TCB ADDRESS                 30500022
         STC   RPARM,OCRLN         PLACE RLN IN OPCE                    30600022
         OI    OCFLAG,OCLINE       INDICATE LINE NO. PROCESSED          30700022
         LTR   RPARM,RPARM         RLN EQUAL ZERO                       30800022
         BE    GETUCB              YES, ADDRESS IN COMMAND              30900022
         SPACE                                                          31000022
         NI    OCFLAG,ALL-OCLINE   CLEAR LINE NO. FLAG                  31100022
         L     RTIOT,TIOT(RWORKA)  GET TIOT ADDRESS                     31200022
         LA    ROFF,DDOFF          POINT TO FIRST DD ENTRY              31300022
         AR    RTIOT,ROFF          ADD START OFFSET TO BASE             31400022
         SR    RLEN,RLEN           CLEAR REGISTER                       31500022
         LA    RZERO,BADDD         SET POSSIBLE ERROR CODE              31600022
DDLOOP   EQU   *                                                        31700022
         IC    RLEN,OFF00(RTIOT)   GET LENGTH OF DD ENTRY               31800022
         CLI   OFF00(RTIOT),ZERO   OUT OF ENTRIES                       31900022
         BE    GRPRLNLK                 LOOK FOR GROUP ENTRY     S22024 32000022
         SPACE                                                          32100022
         CLC   OFF04(EIGHT,RTIOT),OPCDOUBL IS THIS THE DDNAME?          32200022
         BE    DDFOUND             YES, GET INFO                        32300022
         SPACE                                                          32400022
         AR    RTIOT,RLEN          BUMP TO NEXT DD ENTRY                32500022
         AR    ROFF,RLEN           UPDATE OFFSET                        32600022
         B     DDLOOP                   TRY NEXT ENTRY                  32700022
GRPRLNLK EQU   *                                                 S22024 32700722
         LTR   RPARM,RPARM              IS RLN IN REG. 1         S22024 32701422
         BZ    TRMERR                   IF NOT THEN GOTO ERROR   S22024 32702122
         SPACE                                                          32702822
         STC   RPARM,PARMRLN            STORE RLN                S22024 32703522
         L     RTNT,AVTRNMPT            TNT ADDRESSABILITY       S22024 32704222
         SR    RWORK,RWORK              CLEAR COUNTER OFFSET     S22024 32704922
         LH    RWORK1,TNTLEN            GET NUMBER OF TNT ENTRIE S22024 32705622
         N     RWORK1,AVTCLRHI          CLEAR LFT HALF OF REG    S22024 32706322
         SR    RTERM,RTERM              CLEAR REG FOR NM LEN     S22024 32707022
         IC    RTERM,TNTENLEN           PICK UP MAX TERM LEN     S22024 32707722
         BCTR  RTERM,RZERO              DEC LENGTH FOR EXECUTE   S22024 32708422
         LA    RTNT,TNTFIRST            GET FIRST ENTRY ADDR     S22024 32709122
TESTTRM2 EQU   *                                                 S22024 32709822
         LA    RWORK,ONE(RWORK)         UPDATE OFFSET COUNTER    S22024 32710522
         CR    RWORK,RWORK1             END OF TNT?              S22024 32711222
         BH    TRMERR                   YES, RETURN WITH ERROR   S22024 32711922
         EX    RTERM,COMPNAM            COMPARE NAME             S22024 32712622
         BE    NAMEMA                   CORRECT NAME, CHECK LEN  S22024 32713322
         LA    RTNT,FOUR(RTERM,RTNT)    POINT TO NEXT ENTRY      S22024 32714022
         B     TESTTRM2                 CHECK FOR END OF TABLE   S22024 32714722
COMPNAM  CLC   OPCDOUBL(AL0),OFF00(RTNT) COMPARE TERM NAMES      S22024 32715422
NAMEMA   EQU   *                                                 S22024 32716122
         CH    RTERM,AVTHA7             SEVEN LENGTH?            S22024 32716822
         BE    ENTRYO                   CORRECT NAME, RET INFO   S22024 32717522
         LA RPARM,OPCDOUBL              POINT TO NAME START      S22024 32718222
         AR    RPARM,RTERM              ADD NAME LEN TO GET LST  S22024 32718922
         CLI   ONE(RPARM),AVTEBLNK      BLANK PAST LAST CHAR     S22024 32719622
         BNE   TRMERR                   NO, ERROR IN NAME        S22024 32720322
*                                                                     * 32720622
ENTRYO   EQU   *                                                 S22024 32721022
         STH   RWORK,OCTRMTBL           STORE TNT OFFSET IN OPCE S22024 32721722
         LA    RTNT,ZERO(RTNT,RTERM)    ADD LENGTH TO GET ADDR   S22024 32722422
         MVC   OPCTRMWA(AL4),OFF00(RTNT) MOVE ADDRESS TO WORD    S22024 32723122
         DROP  RDEB                     DROP DCB ADDRESSABILITY  S22024 32723822
         L     RLGBAD,OPCTRMWA          PICKUP TERM ENTRY ADDR   S22024 32724522
         LR    RTERM,RLGBAD             SAVE TERM ENTRY ADDR     S22024 32725222
         TM    TRMDSORG,TRMLGB          CK FOR LGB               S22024 32725922
         BNO   CKRN                     NO - CK FOR RN LINE      S22024 32726622
         SH    RLGBAD,TWENTY            GET ADDRESS OF LGB       S22024 32727322
         ST    RLGBAD,ADDRLGB           SAVE LGB ADDRESS         S22024 32728022
         DROP  RDCB                     DROP DCB ADDRESSABILITY  S22024 32728722
         USING IHADCB,RLGBAD            LGB ADDRESSABILITY       S22024 32729422
         TM    DCBOFLGS,ISOPEN          IS DCB OPEN              S22024 32730122
         BZ    BADOPEN                  OPEN ERROR               S22024 32730822
         SPACE                                                          32731522
         DROP  RLGBAD                   DROP LGB ADDRESSABILITY  S22024 32732222
         USING IHADCB,RDCB              DCB ADDRESSABILITY       S22024 32732922
         USING IEDNLGB,RLGBAD           LGB ADDRESSABILITY       S22024 32733622
         L     RDCB,LGBRNDCB-ONE        GET ADDRESS OF DCB       S22024 32734322
         SR    RLCBAD,RLCBAD            ZERO REGISTER            S22024 32735022
         IC    RLCBAD,DCBEIOBX          PICK UP IOB INDEX        S22024 32735722
         A     RLCBAD,DCBIOBAD          ADD IOB ADDRESS          S22024 32736422
         SH    RLCBAD,THIRTY2           GETTING ADDRESS OF LCB   S22024 32737122
         USING IEDQLCB,RLCBAD           LCB ADDRESSABILITY       S22024 32737822
         DROP  RDCB                     DROP DCB ADDRESSABILITY  S22024 32738522
         TM    LCBSTAT1,LCBIPLPG        IS 3705 IPL/DUMP IN PROG.S22024 32738722
         BO    BADOPEN                  YES - PREPARE TO EXIT    S22024 32738922
         L     RRSID,LCBRSIDT           GET ADDRESS OF RESORSE   S22024 32739222
         LTR   RRSID,RRSID              IS THERE A 3705 RESOURCE S22024 32739322
*                                       ID TABLE ADDRESS         S22024 32739422
         BZ    BADOPEN                  NO - PREPARE TO EXIT     S22024 32739522
         DROP  RLCBAD                   DROP LCB ADDRESSABILITY  S22024 32739922
         L     RTNT,AVTRNMPT            ADDR OF TNT              S22024 32740622
         LH    RLEN,ZERO(RRSID)         GET LENGTH OF REG ID TAB S22024 32741322
         SLL   RLEN,TWO                 FIND NUMBER OF ENTRIES   S22024 32742022
*                                                                     * 32742322
RSIDLOOP EQU   *                                                 S22024 32742722
         BCT   RLEN,GRPSRCH             REDUSE LENGTH BY 1       S22024 32743422
*                                                                     * 32743722
         SPACE                                                          32744122
TBLEND   EQU   *                                                 S22024 32744822
         LA    RZERO,AL8                SET ERROR RETURN CODE    S22024 32745522
         B     ERROR                    RETURN ERROR TO CALLER   S22024 32746222
*                                                                     * 32746522
         SPACE                                                          32746922
TRMERR   EQU   *                                                 S22024 32747622
         LA    RZERO,BADNAME            LOAD ERROR RETURN CODE   S22024 32748322
         B     ERROR                    RETURN ERROR TO CALLER   S22024 32749022
*                                                                     * 32749322
         SPACE                                                          32749722
GRPSRCH  EQU   *                                                 S22024 32750422
         LA    RRSID,TWO(RRSID)         UPDATE RSID POINTER      S22024 32751122
         LH    RTNTOFF,ZERO(RRSID)      LOAD TNT OFFSET          S22024 32751822
         LTR   RTNTOFF,RTNTOFF          IS TNT OFFSET ZERO       S22024 32752522
         BZ    RSIDLOOP                 IF YES, GET TNT OFFSET   S22024 32753222
         BNP   TBLEND                   BRANCH END OF TABLE      S22024 32753922
*                                                                     * 32754222
         SPACE                                                          32754622
         BAL   RTERM,TNTDCODE-IEDQTNTD(RTNT)  TO TNT LOOK-UP     S22024 32755322
         LR    RTERM,RTRMENTA           TERMENTRY ADDRESSABILITY S22024 32756022
         TM    TRMSTATE,LINENT          IS THIS A LINE ENTRY     S22024 32756722
         BNO   RSIDLOOP                 IF NO, GET TNT OFFSET    S22024 32757422
*                                                                     * 32757722
         SPACE                                                          32758122
         L     RQCBPTR,TRMDESTQ-ONE     LOAD ADDRESS OF DEST QCB S22024 32758822
*                                                                     * 32759122
         USING IEDQQCB,RQCBPTR          QCB ADDRESSABILITY       S22024 32759522
         CLC   ADDRLGB+ONE(THREE),QCBDCBAD   RIGHT GROUP?        S22024 32760222
         BNE   RSIDLOOP                 IF NOT =, GET NEW OFFSET S22024 32760922
*                                                                     * 32761222
         SPACE                                                          32761622
         L     ROPCE,OPCCOPCE           LOAD ADDRESS OF ELEMENT  S22024 32762322
         CLC   QCBRELLN(ONE),PARMRLN    ARE THE RLNS THE SAME    S22024 32763022
         BNE   RSIDLOOP                 IF NOT =, GET OFFSET     S22024 32763722
         SPACE                                                          32764422
         LA    RTERM,TRMPRFSZ           TERM ENTRY PREFIX SIZE   S22024 32765122
         LNR   RTERM,RTERM              NEGATE IT                S22024 32765822
         AR    RTERM,RTRMENTA           CALC TRM PREFIX ADDR     S22024 32766522
         DROP  RTERM                                                    32767222
         USING IEDNTRM,RTERM                                            32767922
         MVC   OCRSID(TWO),TRMRSID      GET RESORCE ID           S22024 32768622
         SR    RRSID,RRSID              ZERO REG                 S22024 32769322
         ICM   RRSID,SEVEN,QCBDCBAD     LOAD ADDR GROUP ENTRY    S22024 32770022
         LR    RZERO,RTRMENTA           LOAD ADDR OF TRM ENTRY   S22024 32770722
         USING IHADCB,RDCB              REESTABLISH DCB BASE     S22024 32771422
         USING DEBNMSUB,RDEB            REESTABLISH DEB BASE     S22024 32772122
         B     DCBRETUN                 RETURN TO CALLER         S22024 32772822
         DROP  RTERM                                                    32773522
         USING IEDQTRM,RTERM                                            32774222
         SPACE                                                          32774922
CKRN     EQU   *                                                 S22024 32775622
         TM    TRMSTATE,LINENT          IS IT A LINE ENTRY       S22024 32776322
         BNO   BAD                      NO - ERROR               S22024 32777022
         TM    TRMDEVFL+1,TRMRNTRM      YES - IS IT RN LINE      S05331 32777752
         BNO   BAD                      NO - ERROR               S22024 32778422
         L     RPARM,TRMDESTQ-ONE       GET QCB ADDRESS          S22024 32779122
         USING IEDQQCB,RPARM                                     S22024 32779822
         L     RPARM,QCBLGBAD-ONE       GET LGB ADDR FROM QCB    S22024 32780522
         USING IEDNLGB,RPARM                                     S22024 32781222
         TM    LGBOFLGS,ISOPEN          IS LGB OPEN              S22024 32781922
         BNO   BADOPEN                  NO - OPEN ERROR          S22024 32782622
         L     RZERO,OPCTRMWA           YES - SET TERM ENTRY R0  S22024 32783322
         B     DCBRETUN                 RETURN                   S22024 32784022
BAD      EQU   *                                                 S22024 32784722
         LA    RZERO,BADDD              SET ERROR                S22024 32785422
         B     ERROR                    RETURN                   S22024 32786122
PARMRLN  DC    X'00'                    SAVE AREA FOR RLN        S22024 32786822
ADDRLGB  DC    F'0'                     SAVE AREA FOR LGB ADDR   S22024 32787522
TWENTY   DC    H'20'                    USED IN OBTAINING LCB    S22024 32788222
*                                       ADDRESS                  S22024 32790222
THIRTY2  DC    H'32'                    USED IN OBTAINING LCB    S22024 32792222
*                                       ADDRESS                  S22024 32794222
         SPACE                                                          32800022
DDFOUND  EQU   *                                                        32900022
         STH   ROFF,OCTIOT         SAVE OFFSET IN TIOT TO DDENTRY       33000022
GETUCB   EQU   *                                                        33100022
         LA    RDEB,DEB(RWORKA)    POINT BEFORE FIRST DEB ADDRESS       33200022
NEXTDEB  EQU   *                                                        33300022
         SR    RDCB,RDCB                ZERO DCB REG IN CASE DDNAME     33330022
*                                         NOT FOUND                     33360022
         L     RDEB,OFF04(RDEB)    GET ADDRESS OF NEXT DEB              33400022
         LA    RDEB,ZERO(RDEB)     CLEAR HIGH BYTE                      33500022
         LTR   RDEB,RDEB           ANOTHER DEB                          33600022
         BZ    BADOPEN             NO, ERROR-DCB NOT OPEN               33700022
         SPACE                                                          33800022
         L     RDCB,DEBDCBAD       GET DCB ADDRESS                      33900022
         TM    DCBDSORG+OFF01,TXTRDCB   DCB FOR 270X OR 3705 ?   S22024 34000022
         BZ    NEXTDEB                  NO, TRY ANOTHER DEB      S22024 34100022
         SPACE                                                          34200022
         TM    OCFLAG,OCLINE       PROCESSING LINE NUMBER?              34300022
         BNO   GETDCB              NO, PROCESS DDNAME                   34400022
         SPACE                                                          34500022
         SR    RWORKA,RWORKA       CLEAR FOR NO OF EXTENTS              34600022
         IC    RWORKA,DEBNMEXT     GET NUMBER OF RLNS                   34700022
         LA    RWORK,DEBUCBAD      GET UCB ADDRESS POINTER              34800022
         LA    RLEN,ONE            SET COUNT TO ONE                     34900022
NEXTUCB  EQU   *                                                        35000022
         L     RUCB,OFF00(RWORK)   GET UCB ADDRESS                      35100022
         CLC   OFF0D(THREE,RUCB),OPCDOUBL THIS THE UCB?                 35200022
         BE    GOTUCB              YES, RETURN INFO                     35300022
         SPACE                                                          35400022
         LA    RLEN,ONE(RLEN)      ADD ONE TO COUNT                     35500022
         LA    RWORK,FOUR(RWORK)        GET NEXT UCB ADDRESS            35600022
         CR    RLEN,RWORKA         ANY MORE EXTENTS?                    35700022
         BNH   NEXTUCB             YES, LOOK AT NEXT UCB                35800022
         SPACE                                                          35900022
         B     NEXTDEB             NO, TRY NEXT DEB                     36000022
         SPACE                                                          36100022
GOTUCB   EQU   *                                                        36200022
         STC   RLEN,OCRLN          SAVE RLN                             36300022
         LR    RWORKA,RUCB         SET PASS FOR UCB ADDRESS             36400022
         MVC   OCLINENO(AL2),OFF04(RWORKA) PLACE LINE NO. IN ELEMENT    36500022
         NI    OCLINENO,CLRFLAG    CLEAR UCB FLAGS                      36600022
         B     UCBRET              RETURN DCB ADDR TO CALLER            36700022
         SPACE                                                          36800022
GETDCB   EQU   *                                                        36900022
         LH    RLEN,DCBTIOT        GET OFFSET TO TIOT                   37000022
         N     RLEN,AVTCLRHI       CLEAR HIGH TWO BYTES                 37100022
         CR    RLEN,ROFF           RIGHT DCB?                           37200022
         BNE   NEXTDEB             NO, TRY NEXT DEB AND DCB             37300022
         SPACE                                                          37400022
         TM    DCBOFLGS,OPEN       DCB OPENED                           37500022
         BNO   BADOPEN             NO, RETURN ERROR INDICATION          37600022
         SPACE                                                          37700022
         LA    RZERO,INVALRLN           SET POSSIBLE ERROR              37800022
         CLC   OCRLN(AL1),DEBNMEXT RLN MORE THAN NO OF EXTENTS          37900022
         BH    ERROR               YES, RETURN ERROR                    38000022
         SPACE                                                          38100022
         LR    RWORKA,RPARM        PICK UP RELATIVE LINE NUMBER         38200022
         SLL   RWORKA,TWO          MULTIPLY BY FOUR                     38300022
         L     RWORKA,DEBUCBAD-OFF04-DEBNMSUB(RWORKA,RDEB) UCB ADDRESS  38400022
         LA    RWORKA,ZERO(RWORKA) CLEAR HIGH BYTE                      38500022
UCBRET   EQU   *                                                        38600022
         LR    RZERO,RWORKA        RETURN UCB ADDRESS                   38700022
         LTR   RWORKA,RWORKA       OPENED DUMMY?                        38800022
         BNZ   DCBRETUN            NO, RETURN GOOD INFORMATION          38900022
         SPACE                                                          39000022
*                  R E T U R N   T O   C A L L E R                      39100022
*                                                                       39200022
BADOPEN  EQU   *                                                        39300022
         LA    RZERO,OPENERR       SET NOT OPEN RETURN CODE             39400022
ERROR    EQU   *                                                        39500022
         LA    RRET,FOUR(RRET)     RETURN TO ERROR ROUTINE              39600022
DCBRETUN EQU   *                                                        39700022
         LA    RPARM,AVTEZERO(RDCB)     ZERO HIGH ORDER BYTE AND S22024 39800022
*                                        RETURN DCB ADDRESS      S22024 39850022
         LM    RWORKA,RDCB,AVTEZERO(RSAVE) RESTORE REGISTERS     S22024 39900022
         BR    RRET                RETURN INFORMATION                   40000022
         TITLE 'IEDQCA - BUFFER ALLOCATION ROUTINE'                     40100022
*********************************************************************** 40200022
*                                                                     * 40300022
*        ENTRY TO THIS CODE IS VIA A 'BALR' FROM VARIOUS SVC          * 40400022
*        TRANSIENT MODULES.  THE INPUT IS AS FOLLOWS -                * 40500022
*                   REGISTER 1 - CONTAINS NUMBER OF UNITS REQUESTED   * 40600022
*                   REGISTER 2 - POINTER TO THE OP CONTROL AVT        * 40700022
*                   REGISTER 4 - POINTER TO THE TCAM AVT              * 40800022
*                   REGISTER 13 - POINTS TO OP CONTROL SAVE AREA      * 40900022
*                   REGISTER 14 - CONTAINS RETURN ADDRESS             * 41000022
*                   REGISTER 15 - CONTAINS ROUTINE ENTRY POINT ADDRESS* 41100022
*        RETURN IS - NORMAL - REGISTER 14 PLUS 0 -                    * 41200022
*                           REGISTER 0 CONTAINS UNIT COUNT            * 41300022
*                           REGISTER 1 POINTS TO THE FIRST NEW UNIT   * 41400022
*                                                                     * 41500022
*********************************************************************** 41600022
         USING ALLOCBUF,RBRNCH                                          41700022
ALLOCBUF EQU   *                                                        41800022
         STM   RWORK,RWORK2,SAVEOFF(RSAVE) SAVE REGISTERS               41900022
         LH    RWORK1,OPCAVBUF     PICK UP NO. AVAILABLE                42000022
         N     RWORK1,AVTCLRHI     CLEAR HIGH TWO BYTES                 42100022
         SR    RWORK1,RPARM             ALLOCATE NUMBER NEEDED          42200022
         BNM   AVAIL                    POSITIVE MEANS WE HAVE THEM     42300022
         SPACE                                                          42400022
         LCR   RWORK1,RWORK1            GET NUMBER NEEDED FROM TCAM     42500022
         STC   RWORK1,OPCBFERB+UNITCNT SET ERB COUNT                    42600022
         SR    RPARM,RWORK1             FIND NUMBER GOTTEN FROM POOL    42700022
         BZ    REQBUFF             NO, REQUEST ALL                      42800022
         SPACE                                                          42900022
         OI    OPCSPEC,PARTREQ     PARTIAL UNIT REQUEST                 43000022
         SR    RWORK1,RWORK1            CLEAR NUMBER LEFT IN POOL       43100022
AVAIL    EQU   *                                                        43200022
         LR    RZERO,RPARM         SAVE NUMBER                          43300022
         STH   RWORK1,OPCAVBUF     STORE NEW COUNT                      43400022
         L     RWORK2,OPCBFIRS          PICK UP ADDR OF FIRST UNIT      43500022
         LR    RWORK,RWORK2             SAVE FIRST UNIT ADDRESS         43600022
ALLOCATE EQU   *                                                        43700022
         LR    RWORK1,RWORK2       SAVE POINTER TO PREVIOUS UNIT        43800022
         L     RWORK2,OFF08(RWORK1) GET BUFF UNIT LINK FIELD            43900022
         BCT   RPARM,ALLOCATE      LOOP UNTIL NEEDED COUNT IS ZERO      44000022
         SPACE                                                          44100022
         LR    RPARM,RWORK              SET FIRST UNIT POINTER          44200022
         ST    RWORK2,OPCBFIRS     PLACE NEW FIRST UNIT POINTER IN QCW  44300022
         MVI   OFF00(RPARM),AVTEZERO CLEAR ASSIGNED COUNT               44400022
         TM    OPCSPEC,PARTREQ     PARTIAL REQUEST?                     44500022
         BO    SAVCNT                   BRANCH ON YES            S22024 44600022
         LR    RWORK,RWORK1             SAVE POINTER TO LAST UNITS22024 44640022
         B     ALRETURN                 RETURN UNITS             S22024 44680022
         SPACE 1                                                        44720022
SAVCNT   EQU   *                                                 S22024 44760022
         LR    RWORK2,RZERO        SAVE COUNT                           44800022
         STM   RWORK,RWORK2,OFF0C(RSAVE) SAVE REGS FOR LATER            44900022
         SPACE                                                          45000022
REQBUFF  EQU   *                                                        45100022
         XC    OPCBFERB+OFF05(AL8),OPCBFERB+OFF05 CLEAR FIELDS          45200022
         MVI   OPCBFERB+OFF08,MPPREQ INDICATE MPP UNIT REQ              45300022
         MVI   OPCBFERB+OFF0C,ONEBUFF REQUEST ONE BUFFER                45400022
         LA    RWORK,AVTBFREB      GET BUFFER REQUEST QCB ADDRESS       45500022
         ST    RWORK,OPCBFERB      PLACE THAT ADDRESS IN THE ERB        45600022
         LA    RWORK,OPCBFERB      PICK UP ERB ADDRESS                  45700022
         LR    RWORK1,RWORK        SET ERB ADDRESS                      45800022
         STM   RWORK,RWORK1,OPCAQCTL PUT ADDRESS IN AQCTL LIST          45900022
         MVI   OPCAQCTL,POST       SET POST FLAGS                       46000022
         MVI   OPCAQCTL+OFF04,AVTE80 SET END OF LIST                    46100022
         LA    RPARM,OPCAQCTL      POINT TO 102 PARAMETER LIST          46200022
         LR    RWORK,RBRNCH        SAVE BASE REGISTER                   46300022
         SPACE 2                                                        46400022
         AQCTL                     CROSS PARTITION POST                 46500022
         SPACE 2                                                        46600022
*                  WAIT FOR ANOTHER CALL TO DUTY                        46700022
*                                                                       46800022
         LR    RBRNCH,RWORK             RESTORE BASE REGISTER           46850022
WAITBUFF EQU   *                                                        46900022
         LR    RWORK,RBRNCH             SAVE BASE REGISTER              46950022
         WAIT  ECB=AVTOPCOB+4           WAIT FOR ERB RETURN             47000022
         SPACE 2                                                        47100022
         LR    RBRNCH,RWORK        RESTORE BASE REGISTER                47200022
         MVI   AVTOPCOB+ECB,ZERO        CLEAR COMPLETION BIT            47300022
         LA    RWORK,AVTOPCOB-ECB       PICK UP QCB POINTER             47400022
WAITLOOP EQU   *                                                        47500022
         L     RWORK1,LINK(RWORK)       GET NEXT ELEMENT POINTER        47600022
         LA    RWORK1,ZERO(RWORK1)      CLEAR HIGH BYTES                47700022
         C     RWORK1,AVTDELAD     DUMMY LAST ELEMENT                   47800022
         BE    WAITBUFF            YES, WAIT FOR RETURN OF ERB          47900022
         SPACE                                                          48000022
         CLI   PRIOFF(RWORK1),BUFFERB   PRIORITY FOR BUFFER ERB         48100022
         BL    WAITBUFF                 LESS THEN WAIT AGAIN            48200022
         SPACE                                                          48300022
         BE    CORRPRI                  YES, CORRECT PRIORITY           48400022
         SPACE                                                          48500022
CONTLOOP EQU   *                                                        48600022
         LR    RWORK,RWORK1             UPDATE BACKUP POINTER           48700022
         B     WAITLOOP                 CONTINUE CHECKING               48800022
         SPACE                                                          48900022
CORRPRI  EQU   *                                                        49000022
         TM    TIC(RWORK1),TIC          TIC COMMAND SET                 49100022
         BO    CONTLOOP                 YES, INPUT MESSAGE, CONTINUE    49200022
         SPACE                                                          49300022
TESTMPS  EQU   *                                                        49400022
         L     RPARM,CVTPTR        GET CVT ADDRESS                      49500022
         NC    AVTCVTMP+ONE(THREE,RPARM),AVTCVTMP+ONE(RPARM) MP GEN'ED? 49600022
         BZ    NOTEST                   NO, MP NOT GEN'ED IN SYSTEM     49700022
         SPACE                                                          49800022
         CLI   CPUSTAT-IEAQFX00,AVTEZERO MP65 IN SYSTEM?                49900022
         BNE   NOTEST              NO, CONTINUE                         50000022
         SPACE                                                          50100022
         TS    AVTOPCOB+EIGHT           QUEUING IN PROGRESS?            50200022
         BC    BUSY,TESTMPS        YES, LOOP UNTIL THROUGH              50300022
         SPACE                                                          50400022
NOTEST   EQU   *                                                        50500022
         MVC   LINK+1(AL3,RWORK),LINK+1(RWORK1) DEQUEUE ERB             50600022
         MVI   AVTOPCOB+EIGHT,ZERO  CLEAR TS SWITCH                     50700022
         L     RPARM,ERBBUFF(RWORK1)    GET NEW BUFFER POINTER          50800022
         IC    RZERO,PRFNBUNT-IEDQPRF(RPARM) GET COUNT RETURNED         50900022
         MVI   OCUNTCNT-IEDQOPCE(RPARM),ONE SET ASSIGNED COUNT TO 1     51000022
         L     RWORK1,OPCCOPCE     GET CURRENT UNIT ADDRESS             51100022
         LTR   RWORK1,RWORK1       ELEMENT ADDRESS?                     51200022
         BZ    NOELEMNT            NO, ASSIGNED COUNT IS CORRECT        51300022
         SPACE                                                          51400022
         SR    RWORK,RWORK              CLEAR FOR INSERT                51500022
         IC    RWORK,OCUNTCNT-IEDQOPCE(RWORK1) GET ASSIGNED COUNT       51600022
         AR    RWORK,RZERO         ADD UNITS GOTTEN                     51700022
         STC   RWORK,OCUNTCNT-IEDQOPCE(RWORK1) NEW ASSIGNED COUNT BACK  51800022
NOELEMNT EQU   *                                                        51900022
         LR    RWORK,RZERO              SAVE COUNT                      52000022
         AH    RWORK,OPCASBUF           ADD IN ASSIGNED UNIT COUNT      52100022
         STH   RWORK,OPCASBUF           STORE NEW ASSIGNED COUNT        52200022
         TM    OPCSPEC,PARTREQ     PARTIAL REQUEST?                     52300022
         BNO   TOTREQ              NO, TOTAL                            52400022
         SPACE                                                          52500022
         LM    RWORK,RWORK2,OFF0C(RSAVE) RESTORE REGS                   52600022
         ST    RPARM,PRFTIC-IEDQPRF(RWORK1) LINK NEW UNITS              52700022
         AR    RZERO,RWORK2        GET TOTAL COUNT                      52800022
         LR    RPARM,RWORK              GET FIRST UNIT POINTER          52900022
TOTREQ   EQU   *                                                        53000022
         LR    RPREFIX,RPARM       GET FIRST UNIT ADDRESS               53100022
         LR    RWORK,RZERO              GET COUNT RECEIVED      SA63617 53200052
GETEND   EQU   *                                                        53300022
         LR    RWORK1,RPREFIX           SAVE LAST POINTER       SA63617 53400052
         L     RPREFIX,PRFTIC      PICK UP TIC FIELD                    53500022
         BCT   RWORK,GETEND             FIND LAST UNIT          SA63617 53600052
         SPACE                                                          53700022
         NI    OPCSPEC,ALL-PARTREQ TURN OFF FLAG                        53800022
ALRETURN EQU   *                                                        53900022
         SPACE                                                          53960022
         MVI   OFF0B(RWORK1),TWO        SET END OF CHAIN        SA63617 54000052
         XC    OFF0C(REST,RPARM),OFF0C(RPARM) CLEAR FIRST UNIT          54100022
         MVI   PRFPRI-IEDQPRF(RPARM),PRIBFRTB   SET PRIORITY TO  S22024 54120022
*                                       NON-X'D8' VALUE TO AVOID S22024 54140022
*                                       CONFUSION IN IGC0210D    S22024 54160022
         LM    RWORK,RWORK2,SAVEOFF(RSAVE) RESTORE REGISTERS            54200022
         BR    RRET                RETURN WITH NEW UNIT ADDR IN REG 1   54300022
         SPACE                                                          54400022
         TITLE 'IEDQCA - ROUTINE TO PLACE FREE UNITS IN UNIT POOL'      54500022
*********************************************************************** 54600022
*                                                                     * 54700022
*        ENTRY TO THIS CODE IS VIA A 'BALR' FROM VARIOUS SVC          * 54800022
*        TRANSIENT MODULES.  THE INPUT IS AS FOLLOWS -                * 54900022
*                   REGISTER 1 - ADDRESS OF FIRST UNIT IN CHAIN TO BE * 55000022
*                      FREED                                          * 55100022
*                   REGISTER 2 - POINTER TO THE OP CONTROL AVT        * 55200022
*                   REGISTER 4 - POINTER TO THE TCAM AVT              * 55300022
*                   REGISTER 13 - POINTS TO OP CONTROL SAVE AREA      * 55400022
*                   REGISTER 14 - CONTAINS RETURN ADDRESS             * 55500022
*                   REGISTER 15 - CONTAINS ROUTINE ENTRY POINT ADDRESS* 55600022
*        RETURN IS - NORMAL - REGISTER 14 PLUS 0 -                    * 55700022
*                                                                     * 55800022
*********************************************************************** 55900022
         USING FREEBUFF,RBRNCH                                          56000022
FREEBUFF EQU   *                                                        56100022
         STM   RWORK,RPREFIX,SAVEOFF(RSAVE) SAVE REGISTERS              56200022
         LR    RPREFIX,RPARM       GET FIRST UNIT ADDRESS               56300022
         SR    RWORK,RWORK         CLEAR COUNTER REGISTER               56400022
NEXTUNIT EQU   *                                                        56500022
         EX    RPREFIX,OPCHNEND    END OF CHAIN?                        56600022
         BNZ   FREEEND             YES, PLACE UNITS IN POOL             56700022
         SPACE                                                          56800022
         MVI   PRFTIC,TIC               SET TIC CODE IN UNIT    SA67103 56850053
         L     RPREFIX,PRFTIC      PICK UP NEXT UNIT ADDRESS            56900022
         BCT   RWORK,NEXTUNIT      KEEP COUNT OF UNITS                  57000022
         SPACE                                                          57100022
FREEEND  EQU   *                                                        57200022
         LPR   RWORK,RWORK         UNITS FREED MADE NON-NEGATIVE        57300022
         LR    RWORK1,RWORK        SAVE NUMBER OF UNITS FREED           57400022
         AH    RWORK,OPCAVBUF      ADD NEW UNITS TO COUNT               57500022
         STH   RWORK,OPCAVBUF      STORE NEW COUNT IN AVAILABLE AREA    57600022
         LA    RPREFIX,OPCBFIRS-(PRFTIC-IEDQPRF) POINT BEFORE QCW       57700022
         LR    RWORK,RPREFIX       SAVE BEGINNING POINTER               57800022
LOOPQUE  EQU   *                                                        57900022
         L     RPREFIX,PRFTIC      GET NEXT UNIT ADDR                   58000022
         EX    RPREFIX,OPCHNEND    END OF CHAIN?                        58100022
         BNZ   QUEEND              YES, PLACE NEW UNITS IN CHAIN        58200022
         SPACE                                                          58300022
         LR    RWORK,RPREFIX       POINT TO NEXT UNIT                   58400022
         B     LOOPQUE             CONTINUE SEARCH                      58500022
         SPACE                                                          58600022
QUEEND   EQU   *                                                        58700022
         ST    RPARM,PRFTIC-IEDQPRF(RWORK) PLACE NEW UNITS IN POOL      58800022
         MVI   PRFTIC-IEDQPRF(RWORK),TIC PLACE TIC COMMAND              58900022
         L     RPREFIX,OPCBFIRS         1ST BFR IN POOL         SA67103 58905053
         LA    RWORK,AVTBFRTB           ADDR OF BFR-RETURN QCB  SA67103 58910053
         ST    RWORK,PRFQCBA-ONE        ADDR FOR QPOST          SA67103 58915053
         MVI   PRFPRI,PRIBFRTB          PRIORITY                SA67103 58920053
         LH    RWORK,OPCAVBUF           AVAILABLE-BFR COUNT     SA67103 58925053
         STC   RWORK,PRFNBUNT           UNIT COUNT IN BFR       SA67103 58930053
         ST    RPREFIX,OPCAQCTL         BFR ADDR IN PARM LIST   SA67103 58935053
         ST    RPREFIX,OPCAQCTL+FOUR    BFR ADDR IN PARM LIST   SA67103 58940053
         MVI   OPCAQCTL,POST            SET FLAG FOR POST       SA67103 58945053
         MVI   OPCAQCTL+FOUR,AVTE80     SET END-OF-LIST         SA67103 58950053
         LA    RPARM,OPCAQCTL           POINT TO PARM LIST      SA67103 58955053
         LR    RWORK,RBRNCH             SAVE BASE REG           SA67103 58960053
         AQCTL                          CROSS-PARTITION POST    SA67103 58965053
         LR    RBRNCH,RWORK             RESTORE BASE REG        SA67103 58970053
         LA    RWORK,TWO                CLEAR THE OP CTL ...    SA67103 58975053
         ST    RWORK,OPCBFIRS           ... BFR POOL            SA67103 58980053
         SR    RWORK,RWORK              SET AVAILABLE-BFR ...   SA67103 58985053
         STH   RWORK,OPCAVBUF           ... COUNT TO ZERO       SA67103 58990053
         LR    RPARM,RWORK1        RETURN NUMBER OF UNITS FREED         59000022
         LM    RWORK,RPREFIX,SAVEOFF(RSAVE) RESTORE REGISTERS           59100022
         BR    RRET                RETURN TO CALLER                     59200022
         TITLE 'IEDQCA - OPERATOR CONTROL OUTPUT SUBTASK'               59300022
*********************************************************************** 59400022
*                                                                     * 59500022
*        ENTRY IS FROM TCAM DISPATCHER TO 2 BYTES BEYOND OSTCB        * 59600022
*        THIS ROUTINE CHECKS THE OUTPUT QUEUE.  IF IT IS NOT EMPTY,   * 59700022
*        THE DUMMY LCB/SCB IS RE-INITIALIZED AND TPOSTED BACK TO      * 59800022
*        IEDQBD.  IF THE QUEUE IS EMPTY, RETURN IS TO THE DISPATCHER. * 59900022
*        BEFORE RETURN, THE TCAM AVT IS CHECKED FOR CLOSEDOWN.        * 60000022
*        IF CLOSEDOWN IS IN PROGRESS, OP CONTROL ECB IS               * 60100022
*        POSTED COMPLETE TO ALLOW OP CONTROL TO CLEAN UP ITS QUEUES.  * 60200022
*                                                                     * 60300022
*********************************************************************** 60400022
         DROP  RBRNCH                                                   60500022
         USING OSTCB,RPARM         BASE FOR STCB                        60600022
         USING IEDQDISP,RCIB       BASE FOR DISPATCHER                  60700022
OSTCB    DC    X'04',X'00'         STCB FOR OUTPUT                      60800022
         LR    RPARM,ROPCE         SET BASE REGISTER                    60900022
         DROP  ROPCAVT                                                  61000022
         LA    ROPCAVT,OPCAVT      PICK UP OPC AVT ADDRESS              61100022
         USING OPCAVT,ROPCAVT                                           61200022
         L     RAVT,OPCAVTPT       GET ADDRESS OF TCAM AVT              61300022
         LA    RBRNCH,LCBSETUP     BASE FOR SETUP CODE                  61400022
         LA    RRET,DSPPOST             SET RETURN ADDRESS              61500022
MPTEST   EQU   *                                                        61600022
         L     ROPCE,CVTPTR        GET CVT ADDRESS                      61700022
         CLC   AVTCVTMP+ONE(THREE,ROPCE),AVTFZERO MP GEN'ED?            61800022
         BZ    NOTMPS                   NO, MP NOT GEN'ED IN SYSTEM     61900022
         SPACE                                                          62000022
         CLI   CPUSTAT-IEAQFX00,AVTEZERO MP65 IN SYSTEM?                62100022
         BNE   NOTMPS              NO, ACCESS QUEUE                     62200022
         SPACE                                                          62300022
         TS    OPCOQSW             OTHER QUEUEING GOING ON              62400022
         BC    BUSY,MPTEST         YES, WAIT FOR ITS COMPLETION         62500022
         SPACE                                                          62600022
NOTMPS   EQU   *                                                        62700022
         L     ROPCE,OPCWAITO      PICK UP FIRST ELEMENT ON OUTPUT QUE  62800022
         LA    ROPCE,ZERO(ROPCE)   CLEAR HIGH BYTE                      62900022
         LTR   ROPCE,ROPCE         QUEUE EMPTY?                         63000022
         BNZ   GETADDR             PICK BUFFER OFF OF QUEUE             63100022
         SPACE                                                          63200022
         MVI   OPCOQSW,ZERO        CLEAR TS SWITCH                      63300022
         LA    RPARM,OLCBECB       PICK UP ECB ADDRESS                  63400022
         MVI   OPCSTCBS,ZERO       CLEAR TEST SWITCH                    63500022
         TM    AVTBIT1,AVTCLOSN    CLOSEDOWN IN PROGRESS?               63600022
         BNO   DSPDISP             NO, RETURN TO THE DISPATCHER         63700022
         SPACE                                                          63800022
         POST  (1)                 POST OP CONTROL COMPLETE             63900022
         B     DSPDISP             GIVE CONTROL TO THE DISPATCHER       64000022
         SPACE                                                          64100022
GETADDR  EQU   *                                                        64200022
         L     RWORK,OFF00(ROPCE)  GET ELEMENT LINK FIELD               64300022
         LA    RWORK,ZERO(RWORK)   CLEAR HIGH BYTE                      64400022
         ST    RWORK,OPCWAITO      PLACE NEXT ELEMENT AT TOP OF QUEUE   64500022
         MVI   OPCOQSW,ZERO        CLEAR TS SWITCH                      64600022
         TITLE 'IEDQCA - LCB/SCB INITIALIZATION'                        64700022
*********************************************************************** 64800022
*                                                                     * 64900022
*        THIS ROUTINE SETS UP ALL FIELDS IN THE LCB/SCB NECESSARY     * 65000022
*        TO GET THE OPERATOR CONTROL OUTPUT MESSAGE ON THE CORRECT    * 65100022
*        OUTPUT QUEUE.  INPUT IS AS FOLLOWS:                          * 65200022
*                   REGISTER 2 - POINTER TO OP CONTROL AVT            * 65300022
*                   REGISTER 3 - POINTER TO THE CURRENT OPCE(BUFFER)  * 65400022
*                   REGISTER 4 - POINTER TO THE TCAM AVT              * 65500022
*                   REGISTER 14 - CONTAINS RETURN ADDRESS             * 65600022
*                   REGISTER 15 - CONTAINS ROUTINE ENTRY POINT ADDRESS* 65700022
*                                                                     * 65800022
*********************************************************************** 65900022
         DROP  RPARM                                                    66000022
         USING LCBSETUP,RBRNCH                                          66100022
LCBSETUP EQU   *                                                        66200022
         L     RWORK,AVTMSGS-OFF01 PICK UP VCON POINTER                 66300022
         MVC   OCLINK+OFF01(AL3),OFF01(RWORK) PLACE BD QCB ADDR IN BUFF 66400022
         MVI   OCELEM,PRIDESTQ          SET PRIORITY                    66500022
         ST    ROPCE,OLCBBUFF      SET LCB BUFFER POINTER               66600022
         MVI   OSCBPRI,OUTPRI      RESET OUTPUT PRIORITY                66700022
         MVI   OLCBERB,ERBSTATE    RESET ERB BITS                       66800022
         LH    RWORK,OCDEST             GET DESTINATION OFFSET          66900022
FINDTRM  EQU   *                                                        67000022
         N     RWORK,AVTCLRHI           CLEAR HIGH BYTES                67100022
         STH   RWORK,PRFDEST-IEDQPRF(ROPCE) SET DESTINATION OFFSET      67200022
         L     RTNT,AVTRNMPT            GET TERM NAME TABLE ADDRESS     67300022
         LA    RPARM,TNTFIRST           GET FIRST ENTRY ADDRESS         67400022
         SR    RWORK1,RWORK1            CLEAR FOR ENTRY LENGTH          67500022
         STH   RWORK1,PRFISEQ-IEDQPRF(ROPCE) CLEAR SEQ FIELD    SA62344 67550022
         IC    RWORK1,TNTENLEN          GET NAME LENGTH                 67600022
         AR    RPARM,RWORK1             ADD LENGTH TO FIRST TO GET ADDR 67700022
         LA    RWORK1,THREE(RWORK1)     ALLOW FOR ADDRESS FIELDS        67800022
         BCTR  RWORK,RZERO              DECREMENT OFFSET                67900022
         MR    RWORK,RWORK              CALCULATE OFFSET TO TNT ENTRY   68000022
         AR    RPARM,RWORK1             ADD OFFSET                      68100022
         MVC   OLCBZ2+OFF01(AL3),OFF00(RPARM)   MOVE ADDR FOR LOAD      68200022
         L     RTERM,OLCBZ2        TERM ENTRY ADDRESS TO REG            68300022
         L     RWORK,TRMDESTQ-1    PICK UP DESTINATION QCB ADDR         68400022
         TM    OPCSPEC,ALTDEST     PROCESSING ALTDEST?                  68500022
         BO    GETDEST             YES, THIS IS WHERE IT GOES           68600022
         SPACE                                                          68700022
         TM    TRMSTATE,PROCESS    PROCESS ENTRY?                       68800022
         BNO   GETDEST             NO, SEND MESSAGE TO DESTINATION      68900022
         SPACE                                                          69000022
         OI    OPCSPEC,ALTDEST     INDICATE ALTERNATE DEST              69100022
         LH    RWORK,TRMALTD            PICK UP ALT DEST TNT OFFSET     69200022
         CH    RWORK,AVTFZERO           ALTDEST SPECIFIED?              69300022
         BE    FINDTRM1                 NO, CHECK DLQ           SA69063 69400055
         N     RWORK,AVTCLRHI           CLEAR TOP HALF          SA69063 69420055
         STH   RWORK,PRFSRCE-IEDQPRF(,ROPCE)  SET SOURCE        SA69063 69440055
         B     FINDTRM                                          SA69063 69460055
FINDTRM1 EQU   *                                                SA69063 69480055
         SPACE                                                          69500022
         LH    RWORK,AVTDLQX            GET DLQ OFFSET                  69600022
         CH    RWORK,AVTFZERO           DLQ SPECIFIED?                  69700022
         BNE   FINDTRM             YES, IT WILL BE DESTINATION          69800022
         SPACE                                                          69900022
         LA    RWORK,AVTBFRTB      GET BUFFER RETURN ADDRESS            70000022
GETDEST  EQU   *                                                        70100022
         LA    RWORK,ZERO(RWORK)   CLEAR HIGH BYTE                      70200022
         NI    OPCSPEC,ALL-ALTDEST CLEAR ALTDEST FLAG                   70300022
         ST    RWORK,OSCBQCB       STORE QCB ADDRESS IN SCB             70400022
         LA    RPARM,OLCBQCBA           POINT TO LCB                    70500022
         MVI   LCBSTAT1-IEDQLCB(RPARM),LCBRECVN SET SEND                70600022
         IC    RWORK,PRFNBUNT-IEDQPRF(ROPCE) SAVE NUMBER OF UNITS       70700022
         ST    RPARM,PRFLCB-IEDQPRF-1(ROPCE) PLACE LCB ADDRESS IN BUFF  70800022
         STC   RWORK,PRFNBUNT-IEDQPRF(ROPCE) RESTORE UNIT COUNT         70900022
         BR    RRET                GO TO RETURN ADDRESS                 71000022
         EJECT                                                          71002022
*********************************************************************** 71004022
*        THIS ROUTINE DETERMINES IF THE DCB USED IN IPLING A 3705     * 71006022
*        NEEDS TO BE OPENED. IF NO HE BRANCHES TO THE ROUTINE POINTED * 71008022
*        TO BY REGISTER 14. IF NOT OPEN HE ISSUES AN OPEN FOR IT      * 71010022
*        AND IF UNSUCCESSFUL LOADS AN ERROR MSG NUMBER AND XCTLS TO   * 71012022
*        IGC0310D TO WRITE OUT THE MESSAGE. IF SUCCESSFUL HE BRANCHES * 71014022
*        ON REGISTER 14. BACK TO IGCMD10D TO CONTINUE IPLING          * 71016022
*********************************************************************** 71018022
         USING IHADCB,RWORK2            DCB ADDRESSABILITY       S22024 71020022
         USING OPENCODE,RBRNCH          ESTABLISH ADDRESSABILITY S22024 71022022
OPENCODE EQU   *                                                 S22024 71024022
         LR    RDCB,RBRNCH              SAVE BASE REGISTER       S22024 71026022
         TM    DCBOFLGS,OPENED          ALREADY OPENED ?         S22024 71028022
         BNO   NOTOPEN                  NO                       S22024 71030022
         CLOSE ((RWORK2))               CLOSE THE DCB            S22024 71032022
         LR    RBRNCH,RDCB              SET UP BASE              S22024 71034022
         L     RWORK2,DDOFF(RWORKA)     GET DCB ADDRESS          S22024 71036022
NOTOPEN  EQU   *                                                 S22024 71038022
         OPEN  ((RWORK2))               ISSUE AN OPEN SVC        S22024 71040022
         LR    RBRNCH,RDCB             RESTORE BASE REGISTER     S22024 71042022
         TM    DCBOFLGS,OPENED          OPEN SUCCESSFUL ?        S22024 71044022
         BNO   OPENFAIL                 NO                       S22024 71046022
         LR    RPARM,RWORK2             INSERT DCB ADDR IN REG 1 S22024 71048022
         BR    RRET                     YES- RETURN TO IGCMD10D  S22024 71050022
OPENFAIL EQU   *                                                 S22024 71052022
         LA    RZERO,MSG166             ERROR MSG NUMBER         S22024 71054022
         MVC   OPCLDNME+THREE(AL2),XCTLMH  ID OF IGCMH10D        S22024 71056022
         L     R3,OPCCOPCE              GET CURRENT ELEMENT ADDRESS     71056222
         CLI   FOUR(R3),AUTOIPL         IS THIS AN AUTO IPL REQUEST     71056422
         BE    XCTLTOMH                 YES, SKIP PRIORITY RESET        71056622
         MVI   FOUR(R3),CLNUPPRI        RESET PRIORITY FOR MH           71056822
XCTLTOMH EQU   *                                                        71057022
R3       EQU   3                        REG USED BY XCTL CODE           71057222
AUTOIPL  EQU   X'DF'                    AUTO IPL ELEMENT PRIORITY       71057422
CLNUPPRI EQU   X'88'                    CLEANUP PRIORITY FOR MH         71057622
         LR    RPARM,ROPCAVT            SET UP PARAMETER REG     S22024 71058022
         XCTL  SF=(E,OPCXCTL)           XCTL TO IGC0310D         S22024 71060022
         SPACE 3                                                        71062022
XCTLMH   DC    C'MH'                    ID OF COMMON LOAD OF IPL S22024 71064022
*                                       AND DUMP FOR THE 3705    S22024 71066022
         EJECT                                                          71068022
         TITLE 'IEDQCA-OPERATOR CONTROL ADDRESS VECTOR TABLE'           71100022
OPCAVT   DS    0D                  AVT ON DOUBLE WORD BOUNDARY          71200022
OPCDOUBL DC    D'0'                WORK SPACE FOR ACROSS UNIT CHECKING  71300022
OPCAVTPT DC    A(0)                ADDRESS OF TCAM AVT                  71400022
OPCCOPCE DC    A(0)                ADDRESS OF CURRENT OPCE              71500022
OPCDCBLK DC    A(DCBLOCAT)         ADDRESS OF DCB, RLN, ADDRESS LOOK-UP 71600022
OPCGTBLD DC    A(GETBLDL)               GETMAIN AND BLDL LIST AREAS     71700022
OPCTOFLK DC    A(TRMOFLOC)         ADDRESS TO GET TNT OFFSET,TERM ENTRY 71800022
OPCTRMLK DC    A(ADDRDCB)               ADDR OF DCB FOR 3705 IPL S22024 71900022
OPCLCB   DC    A(LCBSETUP)         ADDRESS OF LCB SET UP ROUTINE        72000022
OPCTRMWA DC    F'0'                WORKAREA FOR PICKING UP TNT ADDRESS  72100022
OPCSAVE  DC    7F'0'               OP CONTROL SAVE AREA                 72200022
*   DO NOT INSERT CARDS OR MOVE CARDS BETWEEN THESE COMMENTS          * 72300022
OPCQCBAD DC    A(0)                ADDRESS OF OPC QCB                   72400022
OPCRSAVE DC    2F'0'               BASE AND RETURN SAVEAREA (IGC0010D)  72500022
OPCWORK  DC    A(CMDWORKA)         ADDRESS OF RESIDENT WORKAREA         72600022
OPCWRKSZ DC    H'540'              SIZE OF RESIDENT WORKAREA            72700022
OPCFLAG1 DC    X'00'               FLAG BYTE FOR TRANSIENT USE          72800022
OPCFLAG2 DC    X'00'               FLAG BYTE FOR TRANSIENT USE          72900022
OPCBFERB DC    F'0'                BUFFER                               73000022
         DC    X'E4',AL3(0)              REQUEST                        73100022
         DC    X'02',AL3(0),X'0100',H'0'        ERB                     73200022
*   DO NOT INSERT CARDS OR MOVE CARDS BETWEEN THESE COMMENTS          * 73300022
OPCCKERB DC    X'40',AL3(0)        CHECKPOINT                           73400022
         DC    X'EC',AL3(0)                  REQUEST                    73500022
         DC    X'00',AL3(0),H'0',H'0'               ERB                 73600022
OPCAQCTL DC    3F'0'               SVC 102 PARAMETER LIST               73700022
OPCWAIT  DC    A(OLCBECB)          OP CONTROL WAIT LIST                 73800022
         DC    2F'0'               WAIT LIST (CONT)                     73900022
OPCXCTL  XCTL  EPLOC=OPCLDNME,SF=L                                      74000022
OPCLDNME DC    C'IGC0010D'         USED FOR MODULE NAME FOR XCTL        74100022
OPCWAITC DC    F'0'                QCW FOR CHECKPOINT WAIT QUEUE        74200022
OPCWAITL DC    F'0'                QCW FOR LCB WAIT QUEUE               74300022
OPCWAITN DC    F'0'                QCW FOR RESPONSE BCH WAIT QUEUE      74400022
OPCWAITO DC    F'0'                OUTPUT QUEUE QCW                     74500022
OPCWAITR DC    F'0'                QCW FOR RESOURSE WAIT QUEUE          74600022
OPCNEXT  DC    A(0)                ADDRESS OF ELEMENT FREED BY PREVIOUS 74700022
OPCGETBF DC    A(ALLOCBUF)         ADDRESS OF BUFFER REQUEST ROUTINE    74800022
OPCFREBF DC    A(FREEBUFF)         ADDRESS OF BUFFER UNIT FREE ROUTINE  74900022
OPCBFREQ DC    H'0'                NO. OF BUFFERS NEEDED BY WAIT LIST   75000022
OPCHA8   DC    H'8'                HALF WORD SET TO 8                   75100022
OPCASBUF DC    H'0'                NO. OF BUFFERS ASSIGNED TO OPC       75200022
OPCAVBUF DC    H'0'                NO, OF BUFFERS IN OPC FREE POOL      75300022
OPCBFIRS DC    F'2'                ADDRESS OF FIRST UNIT IN FREE POOL   75400022
OPCBFEND DC    F'0'                CURRENT UNIT END (IGC0110D)          75500022
OPCSPEC  DC    X'00'               SPECIAL FLAGS USED BY IEDQCA         75600022
OPCOQSW  DC    X'00'               SWITCH THAT INDICATES OUTPUT BUSY    75700022
OPCHNEND TM    OPCEND,ZERO         EXECUTED TO FIND END OF BUFFER UNITS 75800022
OPCSTCBS DC    X'00'               SWITCH TO INDICATE STCB BUSY         75900022
OPCEND   DC    X'03'               TESTED BYTE TO DECTECT UNIT END      76000022
CMDWORKA DC    140F'0'                  RESIDENT WORKAREA               76100022
         TITLE 'IEDQCA-DUMMY LCB/SCB FOR OUTPUT'                        76200022
OLCBQCBA DC    A(0)                ADDRESS OF IEDQBD QCB                76300022
OLCBPRI  DC    X'E7',AL3(0)        PRIORITY FOR OUTPUT                  76400022
OLCBSTCB DC    A(OSTCB)            ADDRESS OF OUR STCB FOR OUTPUT       76500022
OLCBZ1   DC    6F'0'               FIELDS ZEROED BY BD                  76600022
OLCBECB  DC    F'0'                ECB FOR THIS LCB                     76700022
OLCBZ2   DC    6F'0'               SOME FIELDS USED BY BD               76800022
OLCBBUFF DC    A(0)                ADDRESS OF OUTPUT BUFFER             76900022
OLCBZ3   DC    H'0'                RESERVED BYTES                       77000022
OLCBSEND DC    2X'00'              RECIEVE OPERATION                    77100022
OLCBZ4   DC    3F'0'               FIELDS USED BY BD                    77200022
OLCBERB  DC    X'41',AL3(0)        ERB STATUS FLAGS                     77300022
OLCBZ5   DC    F'0'                RESERVED FIELD                       77400022
OLCBSCBA DC    A(OSCBQCB)          ADDRESS OF OUR STCB                  77500022
OSCBQCB  DC    A(0)                ADDRESS OF DESTINATION QCB           77600022
OSCBINOT DC    A(0)                ADDRESS OF DUMMY IN/OUT IN AVT       77700022
OSCBPRI  DC    X'F9',AL3(0)        HIGHEST PRIORITY FOR OUTPUT          77800022
         DC    18F'0'                   DEBUG WORK AREA                 77900022
GETBLDL  EQU   *                                                        78000022
         DC    A(0)                     LA OR LU                        78100022
         DC    AL1(0)                   HIARCHY FILL                    78200022
         DC    AL3(0)                   ADDR. OF ADDFR. LIST            78300022
         DC    X'20'                    EC MODE                         78400022
         DC    AL1(0)                   SUBPOOL VALUE                   78500022
BLDLLIST DC    AL2(1),AL2(58)           PREFIX FOR BLDL                 78600022
NAME     DC    CL8'IEDQFE',XL50'00'        BLDL ENTRY FOR SERVICE AID L 78700022
*                                       LOAD                            78800022
ADDROPEN DC    A(OPENCODE)              ADDR OF CODE TO OPEN DCB S22024 78810022
*                                       FOR IPL                  S22024 78820022
ADDRDCB  DCB   DDNAME=DDIPL,BLKSIZE=1028,BUFL=1028,DEVD=DA,DSORG=PO,   X78830022
               MACRF=R,RECFM=U                                          78840022
ADDRDCB2 DCB   DDNAME=DDITEST,BLKSIZE=1028,BUFL=1028,DEVD=DA,DSORG=PO, X78850022
               MACRF=R,RECFM=U                                          78860022
         TITLE 'IEDQCA - DSECTS REFERENCED BY THIS MODULE'              78900022
         TAVTD                                                          79000022
         EJECT                                                          79100022
         DCBD  DSORG=TX                                                 79200022
         EJECT                                                          79300022
         TDEBD                                                          79400022
         EJECT                                                          79500022
         TDISPD                                                         79600022
         EJECT                                                          79700022
         IEAQFX 65,MCH,M65MP                                            79800022
         EJECT                                                          79900022
         TLCBD                                                          80000022
         TLGBD                                                   S22024 80050022
         EJECT                                                          80100022
         TOPCED                                                         80200022
         EJECT                                                          80300022
         TPRFD                                                          80400022
         EJECT                                                          80500022
         TPRIOR                                                         80600022
         EJECT                                                          80700022
         TQCBD                                                          80800022
         EJECT                                                          80900022
         TSCBD                                                          81000022
         EJECT                                                          81100022
         TTNTD                                                          81200022
         EJECT                                                          81300022
         TTRMD                                                          81400022
         END                                                            81500022
