  TITLE  'IEDQCF MODIFY OPITIONS'                                       00100020
IEDQCF   CSECT                                                          00200020
*********************************************************************** 00300020
*                                                                     * 00400020
*TITLE 'IEDQCF' PROCESSOR OF MODIFY OPTION COMMANDS                   * 00500020
*                                                                     * 00600020
*STATUS -- CHANGE LEVEL 0                                             * 00700020
*                                                                     * 00800020
*FUNCTION -- THIS ROUTINE PROCESSES OPERATOR CONTROL COMMANDS WHICH   * 00900020
*   REQUEST MODIFICATION OF TERMINAL OPTION FIELDS.                   * 01000020
*                                                                     * 01100020
*   THE MODIFY OPTIONS ROUTINE LOADS ITS WORK AREA (IEDQC5) AND       * 01200020
*   SERIALLY SEARCHES THE TERMNAME TABLE FOR AN ENTRY MATCHING THAT   * 01300020
*   SPECIFIED IN THE COMMON INPUT BLOCK.  IF THE END OF THE TABLE     * 01400020
*   IS REACHED BEFORE A MATCH IS FOUND, AN ERROR MESSAGE IS BUILT     * 01500020
*   AND CONTROL RETURNS TO THE CONTROL MODULE.  WHEN THE ENTRY IS     * 01600020
*   FOUND, THE OPTION NAMES TABLE IS SERIALLY SEARCHED FOR THE        * 01700020
*   SPECIFIED OPTION FIELD.  IF NO ENTRY IS FOUND, AN ERROR MESSAGE   * 01800020
*   IS BUILT AND CONTROL EXITS TO THE CONTROL MODULE.  IF THERE ARE   * 01900020
*   NO OPTIONS FOR THE TERMINAL ENTRY (TRMOPTFN OFF IN TRMSTATE) AN   * 02000020
*   ERROR RESPONSE IS BUILT AND THE ROUTINE RETURNS TO THE CONTROL    * 02100020
*   MODULE.  IF THE SPECIFIED OPTION FIELD IS NOT DEFINED FOR THE     * 02200020
*   TERMINAL, AN ERROR MESSAGE IS BUILT AND CONTROL EXITS TO THE      * 02300020
*   CONTROL MODULE.  OTHERWISE THE ADDRESS OF THE OPTION FIELD IS     * 02400020
*   OBTAINED AND PROCESSING CONTINUES.                                * 02500020
*                                                                     * 02600020
*   IF MODIFY, THE IEDQCA02 SCAN ROUTINE (AT OPCSCAN) IS GIVEN        * 02700020
*   CONTROL TO OBTAIN THE REPLACEMENT DATA.  IF THERE IS NO DATA OR   * 02800020
*   IF END-OF-MESSAGE WAS FOUND BEFORE THE END OF THE FIELD, AN       * 02900020
*   ERROR MESSAGE IS BUILT AND CONTROL RETURNS TO THE CONTROL         * 03000020
*   MODULE.  THE DATA IS MOVED INTO THE WORK AREA.  IF THE OPTION     * 03100020
*   FIELD TYPE DEFINITION DOES NOT MATCH THE DATA (FIELD IS DECIMAL   * 03200020
*   BUT DATA IS CHARACTER, FOR EXAMPLE) AN ERROR RESPONSE IS BUILT    * 03300020
*   AND CONTROL RETURNS TO THE CONTROL MODULE.  IF A HEXADECIMAL      * 03400020
*   DATA FIELD CONTAINS INVALID CHARACTERS AN ERROR MESSAGE IS        * 03500020
*   BUILT AND CONTROL RETURNS TO THE CONTROL MODULE.  CHARACTER       * 03600020
*   DATA IS PLACED IN THE OPTION FIELD, DECIMAL AND HEXADECIMAL       * 03700020
*   FIELDS ARE CONVERTED FROM EBCDIC NUMBERS TO THE CORRECT FORMAT    * 03800020
*   AND THE NEW VALUES STORED.  IF THE NEW FIELDS ARE LARGER THAN     * 03900020
*   THE OPTION FIELD THEY ARE NOT STORED AND AN ERROR MESSAGE IS      * 04000020
*   BUILT AND CONTROL RETURNS TO THE CONTROL MODULE.  ONCE THE NEW    * 04100020
*   DATA HAS BEEN PLACED IN THE OPTION FIELD A RESPONSE MESSAGE IS    * 04200020
*   BUILT AND CONTROL RETURNS TO THE CONTROL MODULE.                  * 04300020
*                                                                     * 04400020
*ENTRY POINTS --                                                      * 04500020
*        'IEDQCF' TO PROCESS MODIFY OPTION OPERATOR                   * 04600020
*   CONTROL COMMANDS.  CALLING SEQUENCE IS                            * 04700020
*                        LOAD EPLOC=LOADPRFX                          * 04800020
*                        LR   R1,ROPC                                 * 04900020
*                        LR   R15,R0                                  * 05000020
*                        BALR R14,R15                                 * 05100020
*                                                                     * 05200020
*INPUT -- REGISTER 1 - ADDRESS OF OPERATOR CONTROL AVT.  AT THE TAG   * 05300020
*   OPCCKELE IS THE COMMON INPUT BLOCK.  FIELDS RELEVANT TO THIS      * 05400020
*   ROUTINE ARE                                                       * 05500020
*                   +8   OPCTNME   NAME OF THE TERMINAL               * 05600020
*                   +24  OPCOPFLD  NAME OF THE OPTION FIELD           * 05700020
*                                                                     * 05800020
*   REGISTER 15 - ENTRY POINT ADDRESS.                                * 05900020
*                                                                     * 06000020
*OUTPUT -- REGISTER 1 - ADDRESS OF APPROPRIATE RESPONSE MESSAGE.      * 06100020
*                                                                     * 06200020
*   REGISTER 15 - RETURN CODE.  VALUES ARE                            * 06300020
*                   0    IF EXECUTION SUCCESSFUL                      * 06400020
*                   4    IF TERMINAL OR OPTION NOT FOUND, THE         * 06500020
*                        OPTION DOES NOT EXIST FOR THE TERMINAL,      * 06600020
*                        OR THE MODIFY DATA WAS INVALID OR WAS        * 06700020
*                        LARGER THAN THE OPTION FIELD.                * 06800020
*                                                                     * 06900020
*EXTERNAL ROUTINES --                                                 * 07000020
*       'IEDQCA02'  TO ACCESS THE MODIFY DATA                         * 07100020
*                                                                     * 07200020
*       'LOAD' (SVC 8) TO ACCESS THE WORK AREA                        * 07300020
*                                                                     * 07400020
*EXITS-NORMAL -- COMMAND IS PROCESSED.  A RESPONSE MESSAGE IS         * 07500020
*   CONSTRUCTED AND ITS ADDRESS IS RETURNED TO THE CALLER.            * 07600020
*                                                                     * 07700020
*EXITS-ERROR -- TERMINAL OR OPTION NOT FOUND, OR OPTION DOES NOT      * 07800020
*   EXIST FOR THE TERMINAL.  ERROR MESSAGE BUILT, X'04' RETURN CODE   * 07900020
*   SET.                                                              * 08000020
*                                                                     * 08100020
*   MODIFY DATA WRONG FORMAT, CONTAINS INVALID CHARACTERS, OR IS      * 08200020
*   LARGER THAN THE OPTION FIELD.  ERROR RESPONSE BUILT, X'04'        * 08300020
*   RETURN CODE SET.                                                  * 08400020
*                                                                     * 08500020
*TABLES/WORK AREAS -- MESSAGES, TRANSLATE TABLES, OPERATOR CONTROL    * 08600020
*   AVT, AVT, TERMNAME TABLE, TERMINAL ENTRY, BUFFER.                 * 08700020
*                                                                     * 08800020
*ATTRIBUTES -- SERIALLY REUSABLE, REFRESHABLE, ENABLED, TRANSIENT,    * 08900020
*   PROBLEM PROGRAM MODE.                                             * 09000020
*                                                                     * 09100020
*NOTES -- THE OPERATION OF THIS MODULE DEPENDS UPON AN INTERNAL       * 09200020
*   REPRESENTATION OF THE EXTERNAL CHARACTER SET WHICH IS             * 09300020
*   EQUIVALENT TO THE ONE USED AT ASSEMBLY TIME.  THE CODING HAS      * 09400020
*   BEEN ARRANGED SO THAT REDEFINITION OF ''CHARACTER'' CONSTANTS,    * 09500020
*   BY REASSEMBLY, WILL RESULT IN A CORRECT MODULE FOR THE NEW        * 09600020
*   DEFINITIONS.                                                      * 09700020
*                                                                     * 09800020
*   MESSAGES ISSUED BY THIS MODULE ARE                                * 09900020
*              IED016I, IED034I, IED035I, IED050I, IED056I, IED062I   * 10000020
*              IED077I                                                * 10100020
*                                                                     * 10200020
*********************************************************************** 10300020
*                                                                       10400020
*                                                                       10500020
R0       EQU   0                                                        10600020
R1       EQU   1                        PARAMETER                       10700020
ROPC     EQU   2                        OPERATOR CONTROL AVT BASE       10800020
RCIB     EQU   3                        BUFFER OR CIB BASE              10900020
RAVT     EQU   4                        AVT BASE                        11000020
ROPT     EQU   5                        OPTION CSECT BASE               11100020
RTNT     EQU   6                        TERMNAME TABLE BASE             11200020
RTERM    EQU   7                        TERMINAL ENTRY BASE             11300020
RWORK    EQU   8                        WORK                            11400020
RWORK2   EQU   9                        WORK                            11500020
RWORK3   EQU   10                       WORK                            11600020
RWORK4   EQU   11                                                       11700020
RBASE    EQU   12                       ROUTINE BASE                    11800020
R13      EQU   13                       SAVE AREA                       11900020
R14      EQU   14                       RETURN                          12000020
R15      EQU   15                        ENTRY POINT                    12100020
ZERO     EQU   0                                                        12200020
ONE      EQU   1                                                        12300020
TWO      EQU   2                                                        12400020
THREE    EQU   3                                                        12500020
FOUR     EQU   4                                                        12600020
FIVE     EQU   5                                                        12700020
SIX      EQU   6                                                        12800020
EIGHT    EQU   8                                                        12900020
TWELVE   EQU   12                                                       13000020
THIRTEEN EQU   13                                                       13100020
TWOONE   EQU   21                                                       13200020
TWOEIGHT EQU   28                                                       13300020
TWONINE  EQU   29                                                       13400020
THRSEVEN EQU   37                                                       13500020
THREIGHT EQU   38                                                       13600020
MAX      EQU   508                                                      13700020
PACK     EQU   X'40'                                                    13800020
NOTFRST  EQU   3                                                        13850020
RETDELIM EQU   X'02'                                                    13900020
COMRETDM EQU   X'FD'                                                    14000020
C5BIT    EQU   X'10'                                                    14100020
         USING IEDQCF,RBASE             ADDRESSABILITY FOR RTN          14200020
         USING IEDQAVTD,RAVT            ADDRESSABILITY FOR AVT          14300020
         USING IEDQOPC,ROPC             ADDRESSABILITY FOR OP CTL       14400020
         USING IEDQTNTD,RTNT            ADDRESSABILITY FOR TNT          14500020
         USING IEDQTRM,RTERM            ADDRESSABILITY FOR TERM         14600020
         USING IEDQPRF,RWORK3           ADDRESSABILITY FOR BUFFER       14650020
         SAVE  (14,12),,IEDQCF-03/08/71                                 14720020
         LR    RBASE,R15                SET UP BASE                     14800020
         LR    ROPC,R1                  GET OP CTL AVT BASE             14900020
         L     RCIB,OPCINPUT            SET UP CIB                      15000020
         L     RAVT,OPCAVTAD            GET AVT BASE                    15100020
         L     RTNT,AVTRNMPT            GET TNT ADDRESS                 15200020
         LOAD  EPLOC=TAG                                                15300020
         LR    RWORK3,R0                MOVE TO WORK ON                 15350020
         LA    RWORK3,ZERO(RWORK3)      CLEAR HIGH ORDER BYTE           15400020
         ST    RWORK3,OPCWORK           SAVE THE WORKAREA ADDRESS       15450020
         OI    OPCCKBIT,C5BIT           INDICATE MODULE C5 LOADED       15500020
         LA    RWORK3,OPCONE            SET COUNTER TO ONE              15600020
         LH    RWORK2,TNTLEN            GET NUMBER OF ENTRIES           15700020
         SR    RTERM,RTERM              CLEAR                           15800020
         IC    RTERM,TNTENLEN           GET ENTRY LENGTH                15900020
         BCTR  RTERM,R0                                                 16000020
         CH    RTERM,AVTHA7           EIGHT BYTE TERMNAME               16010020
         BE    HTRMOK                   YES, VALID LENGTH               16020020
         LA    R15,OPCTNME+1(RTERM)     PTR TO FIRST BLANK              16030020
        CLI   OPCZERO(R15),AVTEBLNK     IS IT A BLANK                   16040020
         BNE   ERROR                    NO, ERROR                       16050020
HTRMOK   EQU   *                                                        16060020
         LA    RTNT,TNTFIRST            GET TO FIRST ENTRY              16100020
TESTTRM  EQU   *                                                        16200020
         CR    RWORK3,RWORK2            END OF TABLE                    16300020
         BH    ERROR                    YES - ERROR EXIT                16400020
*                                                                       16500020
         EX    RTERM,COMP               TERM ENTRY FOUND                16600020
         BE    GETOP                                                    16700020
*                                                                       16800020
         LA    RWORK3,OPCONE(,RWORK3)   BUMP COUNTER                    16900020
         LA    RTNT,OPCFOUR(RTERM,RTNT) BUMP TNT ADDRESS                17000020
         B     TESTTRM                  GO TEST NEXT ENTRY              17100020
*                                                                       17200020
ERROR    EQU   *                                                        17300020
         MVC   ERMG(OPCEIGHT),OPCTNME   PUT NAME IN MSG                 17400020
         LA    RWORK,ERR                                                17500020
         B     ERROPRET                                                 17600020
*                                                                       17700020
GETOP    EQU   *                                                        17800020
         AR    RTNT,RTERM               BUMP TO ADDR                    17900020
         MVC   OPCSAVE2+1(THREE),ONE(RTNT) TERM ADR. TO FULL WORD       18000020
         L     RTERM,OPCSAVE2           ADDRESS OF TERMINAL ENTRY       18100020
         L     ROPT,AVTOPTPT            GET ADDR OPTION TBLS            18200020
         L     ROPT,OPCFOUR(,ROPT)      GET ADDR OPT NAMES              18300020
         LA    RWORK3,OPCONE            SET COUNTER FOR OPT OFFSET      18400020
         TM    TRMSTATE,TRMOPTFN        OPTION FIELDS PRESENT           18500020
         BNO   ERROP                    NO - ERROR EXIT                 18600020
*                                                                       18700020
COMPOP   EQU   *                                                        18800020
         CLI   OPCZERO(ROPT),AVTEFF     END OF OPTIONS                  18900020
         BE    ERROP                    YES- ERROREXIT                  19000020
*                                                                       19100020
         CLC   OPCTWO(OPCEIGHT,ROPT),OPCOPFLD OPTION FOUND              19200020
         BE    PROCESS                  YES - PROCESS IT                19300020
*                                                                       19400020
         LA    ROPT,OPCTEN(,ROPT)       BUMP TO NEXT ENTRY              19500020
         LA    RWORK3,OPCONE(,RWORK3)   BUMP COUNTER                    19600020
         B     COMPOP                   CHECK NEXT FIELD                19700020
*                                                                       19800020
PROCESS  EQU   *                                                        19900020
         SR    RWORK,RWORK                                              20000020
         IC    RWORK,TRMOPNO            PICK UP NUMBER OF OPTIONS       20100020
         CR    RWORK,RWORK3             OFFSET GREATER                  20200020
         BL    ERROP                    YES - ERROR EXIT                20300020
*                                                                       20400020
         AR    RWORK3,RTERM             ADD TERM BASE                   20500020
         CLI   TRMOPT-1-IEDQTRM(RWORK3),AVTEFF OFFSET THERE             20600020
         BE    ERROP                    NO - ERROR EXIT                 20700020
*                                                                       20800020
         SR    RWORK4,RWORK4                                            20900020
         IC    RWORK4,TRMOPT-1-IEDQTRM(RWORK3)                          21000020
         SR    RWORK3,RTERM                                             21100020
         L     RTNT,AVTOPTPT            GET OPTION DATA CSECT           21200020
         AH    RTNT,TRMOPTBL            ADD OFFSET TO THIS TERM         21300020
         AR    RTNT,RWORK4              ADD OFFSET TO THIS OPTION       21400020
         TM    OPCED,HEX80               IS THIS RESTART                21500020
         BO    RSTRMOV                   YES MOVE THE FIELD             21600020
         L     RWORK4,OPCWORK           ADDRESS OF THE WORK AREA        21640020
         SR    RWORK2,RWORK2            CLEAR FOR COUNT                 21680020
         LA    R14,CON1                 ADDR OF FIRST PLACE TO GO       21720020
*                                       IF NEED TO GET BUFFER UNIT      21760020
         TM    OPCBITSW,OPCMCPN         CIB(CONSOLE) OR BUFFER          21800020
         BZ    CON                      CIB                             21840020
*                                                                       21880020
*                                                                       21920020
*                                                                       21960020
NOCON    EQU   *                                                        22000020
*                                                                       22040020
*                                                                       22080020
*    GET MESSAGE FROM BUFFER UNITS                                      22120020
*                                                                       22160020
*                                                                       22200020
*              REGISTER USEAGE                                          22240020
*                                                                       22280020
*        RWORK2    LENGTH OF DATA                                       22320020
*        RWORK     BEGINNING OF INPUT DATA                              22360020
*        R14       RETURN ADDRESS                                       22400020
*        R15       ADDRESS CCAN BALR'S TO                               22440020
*        R1        COUNT OF BYTES LEFT IN THIS UNIT                     22480020
*        RWORK4    FIRST BYTE IN THE WORK AREA                          22520020
*        R0        TEMPORARY INDEX                                      22560020
*        RWORK     TEMPORARY INDEX                                      22600020
*                                                                       22640020
*                                                                       22680020
         LR    RWORK3,RCIB              GET ADDR OF FIRST BUFFER UNIT   22720020
         LH    R1,PRFSIZE               TOTAL BYTES IN FUFFER           22760020
         LH    RWORK,PRFSCAN            INDEX TO FIRST BYTE OF OPTION   22800020
*                                         TO BE PROCESSED               22840020
         N     RWORK,AVTCLRHI           CLEAR HIGH HALFWORK             22880020
LAB1     EQU   *                                                        22920020
         CH    RWORK,AVTKEYLE           IS THE FIRST BYTE IN THIS UNIT  22960020
         BNL   FIX                      NO, SET UP FOR NEXT UNIT        23000020
         LR    R0,RWORK                 SAVE LENGTH, NO INDEX NEEDED    23040020
         LA    RWORK,AVTUMALN(RWORK,RWORK3)    ADDRESS OF FIRST BYTE    23080020
*                                         TO BE PROCESSED               23120020
         CH    R1,AVTKEYLE              IS ALL DATA TO BE PROCESSED IN  23160020
*                                         THIS UNIT                     23200020
         BH    FIX1                     NO, SPECIAL CONSIDERATION       23240020
         SR    R1,R0                    SET UP TOTAL TO BE PROCESSED    23280020
*                                                                       23320020
*                                                                       23360020
LABA     EQU   *                                                        23400020
*                                                                       23440020
         LA    R1,ONE(R1)               SET TO LENGTH + 1 FOR SCANRTN   23480020
         BR    R14                      GO TO OR RETURN TO REQUESTOR    23520020
*                                                                       23560020
*                                                                       23600020
*                                                                       23640020
FIX1     EQU   *                                                        23680020
         SH    R0,AVTKEYLE             GET 2S COMPLEMENT OF BYTES TO    23720020
*                                         TO PROCESS IN THIS UNIT       23760020
         LCR   R0,R0                    GET THE LENGTH                  23800020
         LR    R1,R0                    SAVE LENGHT TO BE PRECESSED     23840020
         AH    R0,PRFSCAN              RESET THE CSAN                   23880020
         STH   R0,PRFSCAN                TO END OF THIS UNIT            23920020
         B     LABA                     PROCESS THESE BYTES             23960020
*                                                                       24000020
*                                                                       24040020
FIX      EQU   *                                                        24080020
*                                                                       24120020
         L     RWORK3,PRFTIC            GET ADDRESS OF NEXT UNIT        24160020
         SH    RWORK,AVTKEYLE           RESET SCAN TO REFECT NEXT UNIT  24200020
         SH    R1,AVTKEYLE              SAME FOR LENGTH                 24240020
         B     LAB1                     RETURN                          24280020
*                                                                       24320020
*                                                                       24360020
*                                                                       24400020
*                                                                       24440020
*                                                                       24480020
*                                                                       24520020
*      GET MESSAGE FROM CIB                                             24560020
*                                                                       24600020
*        RWORK2     LENGTH OF DATA                                      24640020
*        RWORK      BEGINNING OF INPUT DATA                             24680020
*        R14        RETURN REG                                          24720020
*        R15        ADDRESS  SCAN  BALRS  TO                            24760020
*        R1         COUNT OF BYTES LEFT IN THIS UNNIT(CIB)              24800020
*        RWORK4     FIRST BYTE IN WORKAREA                              24840020
*                                                                       24880020
*                                                                       24920020
CON      EQU   *                                                        24960020
         LH    R1,CIBDLEN(RCIB)         LENGTH OF DATA AREA             25000020
         SH    R1,OPCCOUNT-1            MINUS THAT SCANED               25040020
         LA    R1,ONE(R1)               SET COUNT 1 GREATER THAN ACT    25080020
         LA    RWORK,VARDATA(RCIB)      BEGINNING OF CIB DATA           25120020
         AH    RWORK,OPCCOUNT-1         BEGINNING OF OPTION DATA        25160020
CON1     EQU   *                                                        25200020
         MVC   ZERO(TWO,RWORK4),ZERO(RWORK)  PUT FORST 2 CHAR IN WORK   25240020
*                                         AREA                          25280020
         LA    RWORK,TWO(RWORK)         SET INPUT PAST C'OR X'          25320020
         SH    R1,AVTHA2                 GET PROPER INPUT COUNT         25360020
         LTR   R1,R1                    AT LEAST 2 BYTES                25400020
         BP    DATATYP                  YES, GO CHECK C' AND X'         25440020
         TM    OPCBITSW,OPCMCPN         FOOM CONSOL                     25480020
         BZ    HDECFCKA                 YES, DATA STRING FOOM CONSOLE   25520020
         BAL   R14,NOCON                GO GET ANOTHER UNIT - C AND '   25560020
*                                       OR X AND ' ARE SPLIT BETWEEN 2  25600020
         MVC   ONE(ONE,RWORK4),ZERO(RWORK) PUT IN WITH FIRST CHAR       25640020
         LA    RWORK,ONE(RWORK)         SET INPUT PAST THE CHAR         25680020
         BCT   R1,DATATYP               DECREMENT INPUT COUNT AND CK    25720020
         B     HDECFCKA                 ONLY ONE CHARACTER, GET OUT     25760020
*                                                                       25800020
*                                                                       25840020
*                                                                       25880020
*                                                                       25920020
*        CK  DATA  TYPE                                                 25960020
*            ON  INPUT                                                  26000020
*                 R1  COUNT OF BYTES IN BUFFER UNIT - (CIB)             26040020
*                RWORK PTR TO FIRST CHARACTER INPUT                     26080020
*                RWORK4   PTR TO FIRST SLOT IN WORK AREA.               26120020
*                RWORK2      LENGTH OF DATA FOR THIS FIELD              26160020
*                                                                       26200020
*                                                                       26240020
DATATYP  EQU   *                                                        26280020
         LA    R14,SCANRTN              SET UP TO SCAN WHEN DONE CKING  26320020
         LA    R15,HCHARCK              SET UP FOR C'                   26360020
         CLC   ZERO(TWO,RWORK4),CHARS    IS IT C'                       26400020
         BCR   8,R14                    YES. GO SCAN                    26440020
         LA    R15,HHEXCK               SETUP FOR HEX'                  26480020
         CLC   ZERO(TWO,RWORK4),HEX      IS IT HEX '                    26520020
         BCR   8,R14                    YES. GO SCAN                    26560020
DATATYP1 EQU   *                                                        26600020
         LA    R15,HDECFCK              SET UP FOR CHAR (DEC)           26640020
         CLI   ONE(RWORK4),C' '         IS SECOND CHARACTRR A BLANK     26680020
         BE    HDECFCKA                 YES, DONE WITH THE SCAN         26720020
         LA    RWORK4,TWO(RWORK4)       DEC STRING - HAVE SCANED TWO    26760020
         LA    RWORK2,TWO(RWORK2)       INCRE MENT THE COUNT ALSO       26800020
         BR    R14                      GO SCAN TBE REST                26840020
*                                                                       26880020
*                                                                       26920020
*                                                                       26960020
*        ENTRY TO  SCAN                                                 27000020
*                                                                       27040020
*        R1      TOTAL+1 BYTES LEFT IN INPUT  UNIT-CIB.                 27080020
*        RWORK4  THIS BYTE IN WORK AREA                                 27120020
*        RWORK   PTR TO THIS BYTE IN BUFFER                             27160020
*        RWORK2  COUNT OF BYTES MOVED                                   27200020
*        R15     ADDRESS OF DATA TYPE ROUTINE                           27240020
*                                                                       27280020
*     SCAN  WILL      B       0(R15) IF  END OF CIB AND NOT '           27320020
*          OR         B       4(R15) IF  BLANK FOUND.                   27360020
*                     B       8(R15) IF  QUOTE FOUND                    27400020
*                                                                       27440020
*        R14     RETURN REG                                             27480020
*                                                                       27520020
SCANRTN  EQU   *                                                        27560020
*                                         HERE                          27600020
         LA    R14,SCAN2                SET UP RETURN REG               27640020
         BCT   R1,SCAN                  DECREMENT AVAILABLE BYTES       27680020
         TM    OPCBITSW,OPCMCPN         NO MORE - CIB?                  27720020
         BCR   14,R15                   YES  PROCESS END                27760020
GETBUF   EQU   *                                                        27800020
         LA    R14,SCANRTN              SET UP TO RECEIVE NEXT BURRER   27840020
         B     NOCON                    GO GET ANOTHER UNIT             27880020
SCAN     MVC   ZERO(ONE,RWORK4),ZERO(RWORK)  MOVE CHARACTER INTO WORK A 27920020
         LA    RWORK2,ONE(RWORK2)       INCREASE COUNT                  27960020
         CLI   ZERO(RWORK4),C' '        IS CHARACTER A BLANK            28000020
         BE    FOUR(R15)                  YES, LET DATA ROUTINE LOOK    28040020
         CLI   ZERO(RWORK4),C''''       IS IT A QUOTE                   28080020
         BE    EIGHT(R15)                 YES, LET DATA ROUTINE LOOK    28120020
SCAN2    EQU   *                                                        28160020
         LA    RWORK4,ONE(RWORK4)       RESET WORK AREA PTR.            28200020
         LA    RWORK,ONE(RWORK)         NEX BYTE                        28240020
         CH    RWORK2,H514              FIELD TOO LONG.                 28280020
         BNL   GENM62                     YES, ERROR CONDITION          28320020
         B     SCANRTN                  GET NEXT BYTE                   28360020
*                                                                       28400020
*                                                                       28440020
*         EXIT  FROM  SCAN.                                             28480020
*             SEE ENTRY TO SCAN  FOR REGISTERS                          28520020
*                                                                       28560020
*                                                                       28600020
HCHARCK  EQU   *                                                        28640020
         B     GENM62                   ERROR GET OUT                   28680020
         BR    R14                      BLANK, CK - GO ON               28720020
         BCR   ZERO,R0                  FILLER                          28760020
*                                                                       28800020
HCHARCK2 EQU   *                                                        28840020
         BCT   R1,HCHARCK1              IS THIS LAST CHAR IN UNIT-CIB   28880020
         B     SPEC1                    YES, HANDLE SPECIAL             28920020
HCHARCK1 EQU   *                        ASSUME '' LEFT LESS ONE.        28960020
         LA    RWORK,ONE(RWORK)         INPUT SKIP PAST NEXT            29000020
         CLI   ZERO(RWORK),C''''        IS NEXT CHAR '                  29040020
         BCR   8,R14                    YES, GO ON -                    29080020
HCHARCKA BCTR  RWORK4,R0                DECREASE ADDR TO NON '          29120020
         BCTR  RWORK2,R0                COUNT ALSO                      29160020
         B     CHARCK1                  HANDLE THE CHARACTERS           29200020
SPEC1    TM    OPCBITSW,OPCMCPN         FROM THE CONSOL                 29240020
         BNO   HCHARCKA                 YES, LAST ' DONE                29280020
*                                                                       29320020
         BAL   R14,NOCON                NEXT CHAR IN NEXT UNIT GO GET   29360020
         LA  R14,SCAN2                  RESET THE LINK REGESTER         29400020
         BCT   RWORK,HCHARCK2           BACK UP AS IF LAST CHAR IN THIS 29440020
*                                       UNIT AND CHECK FOR '            29480020
*                                                                       29520020
*                                                                       29560020
*              TEST AND PERFORM ON DECIMAL EQUIVALENT OF HESICECIMAL    29600020
*                                                                       29640020
HDECFCK  EQU   *                                                        29680020
         BCT   RWORK4,HDECFCK1    END   RESET WRKAREA AND PROCESS       29720020
         BCT   RWORK2,HDECFCK2   BLNK   GET OUT                         29760020
         B     GENM62             QUOTE BAD CHAR GENERATE ERROR MSG -   29800020
HDECFCK2 EQU   *                                                        29840020
         BCTR  RWORK4,0                 ADJUST FOR BLANK                29880020
         B     HDECFCK1                                                 29920020
*                                                                       30600020
HDECFCKA EQU   *                                                        30610020
         LA    RWORK2,ONE(RWORK2)       THERE WAS ONLY ONE CHAR --      30620020
*                                       GET THE COUNT RIGHT             30630020
HDECFCK1 EQU   *                                                        30640020
         LR    R1,RWORK4                ADDRESS OF CURRENT BYTE         30650020
         LR    R0,RWORK2                COUNT OF BYTES                  30660020
         CLI   ONE(ROPT),ZERO           CHAR THPE PPT FLD               30663020
         BE    GENM56                   YES, CANNOT PROCEWS             30666020
LOOPDF   EQU   *                                                        30670020
         CLI   0(R1),CZERO              LESS THAN ZERO - NOT NUMERIC    30680020
         BL    GENM77                   YES, REJECT COMMAND             30690020
         CLI   0(R1),CNINE              GREATER TNAN NINE - NOT NUMERIC 30700020
         BH    GENM77                   YES, REJECT COMMAND             30710020
         BCTR  R1,R0                     BACK ADDR ONE BYTE             30720020
         BCT   R0,LOOPDF                CHECK NEXT CHAR IF ANY          30730020
         LR    RWORK,RWORK2             SAVE COUNT OF BYTES             30780020
         SR    R15,R15                  CLEAR FOR OPTION COUNT          30830020
         IC    R15,ZERO(ROPT)           COUNT -1 OF BYTES IN OPTION FLD 30880020
         LA    R15,ONE(R15)             GET TRUE COUNT                  30930020
         LR    R14,RWORK4               SAVE PTR TO LAST CHARACTER MOVD 30980020
         L     RWORK4,OPCWORK           GET BEGINNING OF WORK AREA      31030020
         LA    RWORK4,ZERO(RWORK4)      CLEAR HIGH BYTE                 31080020
         BCTR  RWORK4,R0                WORK AREA -1                    31130020
DFCK1    EQU   *                                                        31180020
         BCTR  RWORK,R0                 DECREMENT FOR CONVERT           31230020
         CH    RWORK,H9                GREATER TNAB TEN CHARACTERS      31280020
         BH    GENM62                   YES REJECT COMMAND              31330020
         MVZ   ZERO(ONE,R14),ZONEC0     PLUS SIGN IN ZONE OF LAST "'    31380020
         EX    RWORK,PACKDF             PACK THE NUMBER                 31430020
         CLC   OPCDOUBL(EIGHT),DOUBLMAX GREATER THAN ALLOWABLE VAL1)    31480020
         BH    GENM62                   YES, REJECT                     31530020
         CVB   R1,OPCDOUBL         CHANGE IT TH BINALY                  31580020
         ST    R1,OPCDOUBL              SET UP FOR SIZE COMP            31630020
         LA    R14,FOUR            FOUR BYEES ALLOWED                   31680020
         LA    RWORK,OPCDOUBL           PTER TH THE FIRST CHARACTER     31730020
LNTLOOP  EQU   *                                                        31780020
         CLI   ZERO(RWORK),ZERO         IS THIS BYTE USED               31830020
         BNE   LNTGOT                   YES, HAVE LENGTH                31880020
         LA    RWORK,ONE(RWORK)         INDES FOR NEXT                  31930020
         BCT   R14,LNTLOOP              REDUCE LENGTH AND TRY AGAI(     31980020
LNTGOT   EQU   *                                                        32030020
         CR    R14,R15                  LENGTH TOO BIG                  32080020
         BH    GENM62                   YES REJECT THE COMMAND          32130020
         LR    RWORK3,R15               GET LENGTH FOR CLEAR            32180020
         BCTR  RWORK3,R0                DECREMENT FOR EXECUTE           32230020
         EX    RWORK3,CLEARDF           CLEAR THE FIELD                 32280020
         LA    RWORK3,ZERO(R15,RTNT)    PTR TO END OF OPTION FIELD + 1  32330020
         SR    RWORK3,R14               LESS LENGTH  OF FIELD TO MOVE   32380020
         LTR   R14,R14                   WAS LENGTH ZERO                32430020
        BZ    GENM50                   YES FIELD CLEAR, GET OUT         32480020
         BCTR  R14,R0                  DECREMENT FRR EXECUTE            32530020
         EX    R14,MOVEDF               MOVE INTO INTO OPTION FIELD     32580020
         B     GENM50                   GENERATE GOOD MESSAGE           32630020
*                                                                       33000020
*              AT THIS POINT THE FOLLOWING REGISTERS ARE SET            33100020
*                                                                       33200020
*                  RWORK     TOTOL NUMBER OF INPUT CHARACTERS           33300020
*                  R15       LENGTH OF THE OPTION FIELD                 33400020
*                  RWORK4    START OF INPUT DATA MINUS ONE              33500020
*                  R14       ADDRESS OF LAST INPUT CHARACTER            33600020
*                                                                       33700020
*                                                                       33900020
*              PROCESS CHARACTER QUOTE TYPE DATA                        34000020
*                                                                       34100020
*                                                                       36000020
*              PROCESS HEX DATA                                         36100020
*                                                                       36200020
HEXCK1   EQU   *                                                        36300020
HHEXCK   EQU   *                                                        36320020
         B     GENM62             END   ERROR GET OUT                   36340020
         B     GENM62             BLANK BADCHAR, GENERATE ERROR MSG     36360020
         BCTR  RWORK4,R0          QUOTE DECREASE WORK AREA ADDR TO NON  36380020
         BCTR  RWORK2,R0                COUNT ALSO                      36400020
HHEXCK1  EQU   *                                                        36420020
         LR    RWORK,RWORK2             COUNT IN RWORK                  36440020
         L     RWORK4,OPCWORK           BEGINNING OF WORK AREA          36460020
         LR    RWORK2,RWORK4            COPY START OF DATA              36480020
         SH    RWORK4,AVTHA3            BACK UP VOR MERGE               36500020
         SR    R15,R15                  CLEAR FOR COUUT                 36520020
         IC    R15,ZERO(ROPT)           GET LENGTH OF OPTION -1         36540020
         LA    R15,ONE(R15)             LENGTH OF THE OPTION            36560020
         SR    R14,R14                                                  36600020
         STH   RWORK,OPCSAVE2           STORE LENGTH OF DATA            36700020
         TM    OPCSAVE2+1,ONE           WAS DATA COUNT ODD OR EVEN      36800020
         BZ    HEXEVEN                  BRANCH IF EVEN                  36900020
         LA    RWORK,ONE(RWORK)         ODD ADD ONE BEFORE THE DIVIDE   37000020
         SRL   RWORK,ONE                DIVIDE BY TWO                   37100020
         BAL   RWORK3,HEXSUBCK          GO TEST IF VALID HEX CHARACTER  37200020
         SR    R0,R0                                                    37300020
         BAL   RWORK3,MERSUB1           GO MERGE FIRST DATA BYTE WITH   37400020
*                                       DUMMY ZERO BYTE IN R0           37500020
         B     CKENDHEX                 GO TEST FOR MORE TO MERGE       37600020
HEXEVEN  EQU   *                                                        37700020
         SRL   RWORK,ONE                DIVIDE BY TWO                   37800020
LOOPHEX  EQU   *                                                        37900020
         BAL   RWORK3,HEXSUBCK          GO TEST IF VALID HEX CHARACTER  38000020
         LA    RWORK4,ONE(RWORK4)       STEP DATA POINTER BY ONE        38100020
         BAL   RWORK3,HEXSUBCK          GO TEST IF VALID HEX CHARACTER  38200020
         BAL   RWORK3,MERSUB            GO MERGE THE TWO BYTES          38300020
CKENDHEX EQU   *                                                        38400020
         CR    R14,RWORK                ALL CHARACTERS MERGED           38500020
         BNE   LOOPHEX                  BRANCH NO FOR NEXT MERGE        38600020
*              SUB ROUTINE TO MOVE DATA TO THE OPTION FIELD AND ZERO    38605020
*              LEADING BYTES OF THE HEX OR DECIMAL FIELD                38610020
*                                                                       38615020
MOVESUB  EQU   *                                                        38620020
         L     RWORK4,OPCWORK           RESTORE START OF WORK AREA      38625020
         BCTR  RWORK4,R0                BACK UP ONE                     38630020
NEXTBYTE CR    RWORK,R15                ALL DTA MOVED                   38635020
         BH    GENM62                   IF HIGH DATA LARGER THEN        38640020
*                                       THE OPTION FIELD                38645020
         BE    EXMOVES                  EQUAL ALL HIGH ORDER BYTES      38650020
*                                       HAVE BEEN ZEROED                38655020
         MVI   ZERO(RTNT),X'00'         ZERO NEXT BYTE                  38660020
         LA    RTNT,ONE(RTNT)           INCREMENT OPTION FIELD POINTER  38665020
         BCT   R15,NEXTBYTE             RETURN AND DECREASE SIZE OF     38670020
*                                       THE OPTION FIELD                38675020
EXMOVES  BCTR  R15,R0                   SUB ONE FOR THE MOVE            38680020
         EX    R15,MOVETOOP             MOVE THE DATA                   38685020
         B     GENM50                   GO GENERATE COMPLETE MESSAGE    38690020
*                                                                       39200020
*                                                                       46200020
*              PROCESS PLAIN CHARACTER TYPE DATA                        46300020
*                                                                       46400020
CHARCK1  EQU   *                                                        46500020
         CLI   ONE(ROPT),ZERO           CHARACTER TYPE FOELD            46580020
         BNE   GENM56                   NO, CANNOT PROCESS              46660020
         LR    RWORK,RWORK2             COUNT IN RWORK                  46740020
         BCTR  RWORK,R0                 SUB ONE FOR MOVE                46820020
         LR    R14,RWORK4               LAST CHARACTER IN RWOR          46900020
         L     RWORK4,OPCWORK           BEGINNING OF WORK AREA          46980020
         BCTR  RWORK4,R0                WORK AREA -1                    47060020
         SR    R15,R15                  CLEAR FOR COUUT                 47140020
         IC    R15,ZERO(ROPT)           GET LENGTH OF OPTION -1         47220020
         CR    RWORK,R15                COMPARE OPTION FIELD LENGTH TO  47300020
*                                       INPUT DATA LENGTH               47400020
         BH    GENM62                   BRANCH INPUT TOO LARGE          47500020
         LTR   RWORK,RWORK              IS THERE ANY LENGTH             47530020
         BM    GENM62                   NO, C'' - ERRPR                 47560020
         EX    RWORK,MOVETOOP           MOVE DATA TO THE OPTION FIELD   47700020
NEXTBLNK CR    RWORK,R15                PADDING NEEDED                  47900020
         BE    GENM50                   GO GENERATE COMPLETE MESSAGE    48000020
         LA    RWORK2,ZERO(R15,RTNT)    ADDR. OF CHAR. TO BE BLANKED    48100020
         MVI   ZERO(RWORK2),C' '        BLANK OUT CHARACTER             48200020
         BCT   R15,NEXTBLNK                                             48300020
*                                                                       48400020
*              GENERATE MODIFY COMPLETED MESSAGE                        48500020
*                                                                       48600020
GENM50   EQU   *                                                        48700020
*        CHECLPOINTING THE OPTIONS                                      48800020
*              DUE THE THE LENGTH OF OPTIONS FIELDS - DONE IN BITS      48900020
*  RTNT        PTR TO OPTION FIELD                                      49000020
*  R15         LENGTH OF OPTION -1                                      49100020
*  RWORK       ABSOLUTE OOSITIONT   OF NEXT MOVE                        49200020
*  RWORK4      NUMBER OF CHARACTERS YET OT MOVE                         49300020
*  RWORK2      LINK REGISTER                                            49400020
*  RWORK3      RELATIVE POSITION OF NEXT MOVE                           49500020
         SPACE 2                                                        49600020
*        IN THE CHECK POINT ELEMENT THE DATA WILL BE AS FOLLOWS         49700020
*        -  UP TO EIGHT BYTES OF DATA / INCIDENT RECORD                 49800020
         SPACE 2                                                        49900020
*  OPCBIT1,OPCBIT2  RELATIVE POSITION OF THE CHECK POINT ELEMENT        50000020
*  OPCINFO    NUMBER OF BYTES OF DATA IN THIS ELEMENT                   50100020
*   OPCLEN   FIRST FOUR BYTES OF DATA                                   50200020
*  OPCSNSE    SECOND FORR BYTES OF DATA                                 50300020
         SPACE 3                                                        50400020
         L     RWORK3,AVTCKGET           IS CHECK POINT IN THE SYSTEM   50500020
         LTR   RWORK3,RWORK3             NO                             50600020
         BZ    GENM50A                        DONT CHECK POINT UT       50700020
         CLI   ONE(ROPT),X'C1'          ADDRESS FORM                    50710020
        BL    CKELEA1                  NO, CHECK PT IT                  50720020
         CLI   ONE(ROPT),X'D0'          2ND CK - ADDR FORM              50730020
         BL    GENM50A                  YES, DON'T CK PT IT             50740020
CKELEA1  EQU   *                                                        50750020
         SR    R15,R15                  CLEAR FOR LENGTH                50760020
         IC    R15,ZERO(ROPT)           GET LENGTH - 1                  50770020
         SR    RWORK3,RWORK3             SERO REAOATIVE POSITION        50800020
         LR    RWORK,RTNT                GET BEGINNING OF OPT FOELD     50900020
         LA    RWORK4,ONE(R15)           LENGTH OF OPT FIELD            51000020
CKELE1   CH    RWORK4,H8                 MOVE THAN EIGHT BYTES          51100020
         BNH   CKMOV1B                   NO, LAST VOVE                  51200020
         MVC   OPCLEN(FOUR),ZERO(RWORK)      FOUR INTO OPCLEN           51300020
         MVC   OPCSNSE(FOUR),FOUR(RWORK)   FOUR INTO OPCSNSE            51400020
         MVI   OPCINFO,HEX08             CK POINT THE LENGTH            51500020
         STH   RWORK3,OPCBIT1            CK POINT THE RELATIVE OOSITION 51600020
         SH    RWORK4,H8                 DECREMENT 6O9 55   4 55        51700020
         LA    RWORK,EIGHT(RWORK)        INCREMENT ADDRESS              51800020
         LA    RWORK3,EIGHT(RWORK3)      RESER RELATIVE POSITION        51900020
         BAL   RWORK2,CKPTIT             CHECK POINT IT                 52000020
         B     CKELE1                    GO FOR NEXT PASS               52100020
CKMOV1B  EQU   *                                                        52200020
         STH   RWORK3,OPCBIT1            SAVE RELATIVE POSITION         52300020
         STC   RWORK4,OPCINFO            SAVE LENGTH                    52400020
         CH    RWORK4,H4                 MOVE THAT FOUR BYTES           52500020
         BNH   CKMOV1C                   NO, REALLY LAST                52600020
         MVC   OPCLEN(FOUR),ZERO(RWORK)   MOVE FIRST FOUR BYTES         52700020
         LA    RWORK,FOUR(RWORK)         SET FOR LAST PASS              52800020
         SH    RWORK4,H4                 RESET COUNT                    52900020
         SPACE 2                                                        53000020
CKMOV1C  BCTR  RWORK4,ZERO               DECREMENT FOR EX               53100020
         EX    RWORK4,CKPTMOV           MOVE LAST CHARACTER             53200020
         BAL   RWORK2,CKPTIT             CHECK POINT IT                 53300020
         NI    OPCED,HEXFF-HEX80          CLEAR CK POINT                53400020
         SPACE 2                                                        53500020
GENM50A  EQU   *                                                        53600020
         LA    R14,MSG50                ADDRESS OF GOOD MESSAGE         53700020
         SR    R15,R15                  ZERO THE RETURN CODE            53800020
         B     LEAVE                                                    53900020
         SPACE 2                                                        54000020
RSTRMOV  LR    RWORK,RTNT                GET OPT ADDRESS                54100020
         LA    RWORK,ZERO(RWORK)         CLEAR HIGH BYTE                54200020
         SR    RWORK4,RWORK4             CERO FOR LENGTH                54300020
         IC    RWORK4,OPCINFO            GET LENGHH                     54400020
         AH    RWORK,OPCBIT1             GET RELATIVE POSITION          54500020
         CH    RWORK4,H4                 MORE THAN FOUR BYTES           54600020
         BNH   RSTRMOV1                  NO - NEED ONLY ONE MOVE        54700020
         MVC   ZERO(FOUR,RWORK),OPCLEN      MOVE FIRST 4 BYTES          54800020
         LA    RWORK,FOUR(RWORK)         SET UP FOR NEXT MOVE           54900020
         SH    RWORK4,H4                 DECREMENT                      55000020
RSTRMOV1 EQU   *                                                        55100020
         BCTR  RWORK4,ZERO               SET OU COUNT FOR ES            55200020
         EX    RWORK4,MOVRSTR            MOVE LAST BYTES                55300020
         B     PUT                        GET OUT                       55400020
         SPACE 3                                                        55500020
CKPTIT   EQU   *                                                        55600020
         OI    OPCED,HEX80               SET TO ALLOW CHECKPOINTING     55700020
         XC    AVTCCELE+4(OPCFOUR),AVTCCELE+4                           55800020
         LA    R1,AVTCKPTB              PLACE CK PT                     55830020
         ST    R1,AVTCCELE                  QCB IN THE ELEMENT          55860020
         MVI   AVTCCELE,AVTEBLNK                                        55900020
         MVI   AVTCCELE+4,PRIOPCKP                                      56000020
         LA    R1,AVTCCELE                                              56100020
         ST    R1,OPCPPLA-1                                             56200020
         ST    R1,OPCPPL2                                               56300020
         MVI   OPCPPL1,ECB                                              56400020
         MVI   OPCPPL2,AVTE80                                           56500020
         LA    R1,OPCPPL1                                               56600020
         MVI   AVTOPCOB+4,ZERO                                          56700020
         AQCTL                                                          56800020
POSTCK1  EQU   *                                                        56900020
         SPACE 2                                                        57000020
         WAIT  ECB=AVTOPCOB+4                                           57100020
         MVI   AVTOPCOB+4,ZERO           RESET THE ECB                  57200020
         L     R1,AVTOPCOB               GET LIST PTR                   57300020
         CLI   4(R1),PRIOPCKP            IS IT THE CK PT ELEMENT        57400020
         BNE   POSTCK1                   NO WAIT AGAIN                  57500020
TSTMP65  CLI   AVTCPUST,AVTEZERO         MP65 IN SYSTEM                 57600020
         BNE   NOTS                      NO - PROCEED                   57700020
         TS    AVTOPCOB+8                ANY ONE QUEUI                  57800020
         BC    4,TSTMP65                 YES, WAIT UNTIL HE IS DONE     57900020
NOTS     EQU   *                                                        58000020
         MVC   AVTOPCOB+1(3),5(R1)       DEQUEUE THE ELEMENT            58100020
         MVI   AVTOPCOB+8,AVTEZERO       DONE, CLEAR TS SWITCH          58200020
         BR    RWORK2                                                   58300020
         SPACE 2                                                        58400020
*                                                                       58500020
*              GENERATE ERROR MESSAGE IED056I                           58600020
*                                                                       58700020
GENM56   EQU   *                                                        58800020
         LA    R14,MSG56                ADDRESS OF ERROR MESSAGE        58900020
         B     SETRET04                 GO SET ERROR RETURN CODE        59000020
*                                                                       59100020
*              GENERATE ERROR MESSAGE IED062I                           59200020
*                                                                       59300020
GENM62   EQU   *                                                        59400020
         LA    R14,MSG62                ADDRESS OF THE ERROR MESSAGE    59500020
         B     SETRET04                 GO SET ERROR RETURN CODE        59600020
*                                                                       59700020
*              GENERATE ERROR MESSAGE IED077I                           59800020
*                                                                       59900020
GENM77   EQU   *                                                        60000020
         LA    R14,MSG77                ADDRESS OF THE ERROR MESSAGE    60100020
SETRET04 EQU   *                                                        60200020
         LA    R15,FOUR                 SET RETURN CODE                 60300020
*                                                                       60400020
*              GENERATE FIXED PORTION OF MESSAGE SUBROUTINE             60500020
*                                                                       60600020
LEAVE    EQU   *                                                        60700020
         L     RWORK4,OPCWORK           RESTORE IEDQC5 ADDRESS          60800020
         BCTR  RWORK4,R0                BACK UP ONE                     60900020
         MVC   ONE(TWO,RWORK4),ZERO(R14) MESSAGE LENGTH                 61000020
         MVC   THREE(FIVE,RWORK4),X1000IED IED PORTION OF MESSAGE       61100020
         MVC   EIGHT(FOUR,RWORK4),TWO(R14) MESSAGE NUMBER               61200020
         MVI   TWELVE(RWORK4),C' '      BLANK OUT NEXT BYTE             61300020
         MVC   THIRTEEN(EIGHT,RWORK4),OPCTNME TERMINAL NAME             61400020
         MVC   TWOONE(EIGHT,RWORK4),OPTION BLANK 'OPTION' BLANK         61500020
         MVC   TWONINE(EIGHT,RWORK4),OPCOPFLD OPTION FLD NAME           61600020
         MVI   THRSEVEN(RWORK4),C' '    BLANK OUT NEXT CHARACTER        61700020
         MVC   THREIGHT(TWOEIGHT,RWORK4),SIX(R14) MESSAGE TEXT          61800020
         LA    RWORK,ONE(RWORK4)        ADDRESS OF THE WORK AREA        61900020
         LH    R14,ZERO(RWORK)          LENGTH OF THE MESSAGE           62000020
         LA    R14,ONE(R14,RWORK4)      END OF MESSAGE PLUS ONE         62100020
         MVC   ZERO(FOUR,R14),ROUTE     ROUTING INFORMATION             62200020
         B     PUT                                                      62300020
*                                                                       62400020
ERROP    EQU   *                                                        62500020
         MVC   EROM(OPCEIGHT),OPCTNME   TERMINAL NAME                   62600020
         MVC   EROOM(OPCEIGHT),OPCOPFLD                                 62700020
         LA    RWORK,ERO                                                62800020
         B     ERROPRET                                                 62900020
*                                                                       63000020
ERREX    EQU   *                                                        63100020
         LA    RWORK,OPCERMSG           INVALID COMMAND MESSAGE ADR.    63200020
ERROPRET  EQU  *                                                        63300020
         LA    R15,OPCFOUR                                              63400020
PUT      EQU   *                                                        63500020
         ST    RWORK,OPCREG1(,R13)                                      63600020
         NI    OPCBITSW,COMRETDM        TURN OFF RETURN DELIMITOR SW.   63700020
         RETURN (14,12),T,RC=(15)                                       63800020
*                                                                       64600020
*              SUB ROUTINE TO VALITY CHECK HEX CHARACTERS               64700020
*                                                                       64800020
HEXSUBCK EQU   *                                                        64900020
         CLI   THREE(RWORK4),X'F0'      COMPARE FOR ZERO                65000020
         BL    TRYALPHA                 NOT NUM. TRY FOR ALPHA CHAR.    65100020
         CLI   THREE(RWORK4),X'F9'      COMPARE FOR NINE                65200020
         BH    GENM77                   INVALID IF GREATER THEN NINE    65300020
         TR    THREE(ONE,RWORK4),TRANNUM-240   TRANSLATE THE BYTE       65400020
         BR    RWORK3                   RETURN TO CALLER                65500020
TRYALPHA CLI   THREE(RWORK4),C'A'       TRY CHARACTER A                 65600020
         BL    GENM77                   LESS THEN A INVALID CHARACTER   65700020
         CLI   THREE(RWORK4),C'F'       TRY CHARACTER F                 65800020
         BH    GENM77                   GREATER THEN F INVALID          65900020
         TR    THREE(ONE,RWORK4),TRANCHAR-193  TRANSLATE THE BYTE       66000020
         BR    RWORK3                   RETURN TO CALLER                66100020
*                                                                       67100020
*              SUB ROUTINE TO MERGE TWO BYTES INTO ONE                  67200020
*                                                                       67300020
MERSUB   EQU   *                                                        67400020
         IC    R0,TWO(RWORK4)           PICK UP FIRST CHARACTER         67500020
MERSUB1  EQU   *                                                        67600020
         NI    THREE(RWORK4),X'0F'      CLEAR HIGH ORDER HALF BYTE      67700020
         IC    R1,THREE(RWORK4)         PICK UP SECOND CHARACTER        67800020
         SLL   R0,FOUR                  POSITION FIRST BYTE             67900020
         OR    R0,R1                    MERGE TWO BYTES                 68000020
         STC   R0,ZERO(RWORK2)           KTORE THE MERGED BYTE          68100020
         LA    RWORK4,ONE(RWORK4)       INCREMENT THE DATA POINTER      68200020
         LA    RWORK2,ONE(RWORK2)       INCREMENT NEW DATA POINTER      68300020
         LA    R14,ONE(R14)             INCREMENT INDEX                 68400020
         BR    RWORK3                   RETURN TO CALLER                68500020
ERR      DC    H'38',X'6000',C'IED016I STATION '                        68600020
ERMG     DC    8C' ',C' NOT FOUND',X'08000000'                          68700020
*                                                                       68800020
*                                                                       68900020
*                                                                       69000020
*              IF THIS MESSAGE IS MOVED THE TWO DC'S FOLLOWING IT       69100020
*              MUST ALSO BE MOVED                                       69200020
*                                                                       69300020
ERO      DC    H'44',X'6000',C'IED034I '                                69400020
EROM     DC    CL8' ',C' HAS NO '                                       69500020
EROOM    DC    CL8' '                                                   69600020
*                                                                       69700020
*              THESE NEXT TWO DC'S CANNOT BE MOVED. THEY ARE PART       69800020
*              OF MESSAGE ERO AND ARE USED BY OTHER CODE                69900020
*                                                                       70000020
OPTION   DC    C' OPTION '                                              70100020
ROUTE    DC    X'08000000'                                              70200020
*                                                                       70300020
*                                                                       70400020
*                                                                       70500020
MSG50    DC    H'45',C'050I'                                            71400020
MODIFIED DC    C'MODIFIED'                                              71500020
MSG56    DC    H'56',C'056I'                                            71600020
TXTM56   DC    C'DATA FORMAT INVALID'                                   71700020
MSG62    DC    H'65',C'062I'                                            71800020
TXTM62   DC    C'CANNOT ACCEPT SPECIFIED DATA'                          71900020
MSG77    DC    H'59',C'077I'                                            72000020
TXTM77   DC    C'DATA CHARACTER INVALID'                                72100020
TRANNUM  DC    X'00112233445566778899'                                  72200020
TRANCHAR DC    X'AABBCCDDEEFF'                                          72300020
MOVEDATA MVC   ONE(ZERO,RWORK),OPCDOUBL                                 72400020
MOVETOOP MVC   ZERO(ONE,RTNT),ONE(RWORK4)                               72500020
COMP     CLC   OPCZERO(OPCONE,RTNT),OPCTNME                             72600020
PACKDF   PACK  OPCDOUBL(EIGHT),ONE(ZERO,RWORK4)                         72607020
MOVEDF   MVC   ZERO(ONE,RWORK3),ZERO(RWORK)                             72614020
CLEARDF  XC    ZERO(ONE,RTNT),ZERO(RTNT)                                72621020
CZERO    EQU   C'0'                                                     72628020
CNINE    EQU   C'9'                                                     72635020
DOUBLMAX DC    X'000002147483647C'                                      72642020
H9       DC    H'9'                                                     72649020
ZONEC0   DC    X'C0'                                                    72656020
VARDATA  EQU   X'10'                                                    72663020
CIBDLEN  EQU   VARDATA-2                                                72670020
H514     DC    H'514'                                                   72677020
QUOTEBIT EQU   1                                                        72684020
H8       DC    H'8'                                                     72700020
HEX08    EQU   8                                                        72800020
HEX80    EQU   X'80'                                                    72900020
HEXFF    EQU   X'FF'                                                    73000020
H4       DC    H'4'                                                     73100020
CKPTMOV  MVC   OPCSNSE(ONE),ZERO(RWORK)                                 73200020
MOVRSTR  MVC   ZERO(ONE,RWORK),OPCSNSE                                  73300020
ECB      EQU   12                                                       73400020
HEX      DC    C'X'''                                                   73500020
TAG      DC    CL8'IEDQC5'                                              73700020
CHARS    DC    C'C'''                                                   73800020
X1000IED DC    X'6000',C'IED'                                           73900020
         TOPCD                                                          74100020
OPCPPL1  EQU   OPCSCAN-8                                                74200020
OPCPPLA  EQU   OPCSCAN-7                                                74300020
OPCPPL2  EQU   OPCSCAN-4                                                74400020
         TAVTD                                                          74500020
         TTNTD                                                          74600020
         TTRMD                                                          74700020
         TPRFD                                                          74800020
         TPRIOR                                                         74900020
         END                                                            75000020
