         TITLE '''IEDQCG'' - DISPLAY ADDR'                              00400020
IEDQCG   CSECT                                                          00800020
*********************************************************************** 01200020
*                                                                     * 01600020
*TITLE   'IEDQCG' PROCESSOR OF DISPLAY ADDR COMMANDS                  * 02000020
*                                                                     * 02400020
*STATUS -- CHANGE LEVEL 0                                             * 02800020
*                                                                     * 03200020
*FUNCTION -- THIS ROUTINE PROCESSES OPERATOR CONTROL COMMANDS WHICH   * 03600020
*   REQUEST DISPLAY OF THE LINE ADDRESS AND RELATIVE LINE NUMBER      * 04000020
*   FOR A SPECIFIED TERMINAL.                                         * 04400020
*                                                                     * 04800020
*   THE COPY LINE INFORMATION ROUTINE ACCESSES THE TERMNAME TABLE     * 05200020
*   THROUGH THE AVT AND SERIALLY SEARCHES IT FOR THE ENTRY WHICH      * 05600020
*   MATCHES THAT SPECIFIED IN THE COMMON INPUT ELEMENT.  IF AN        * 06000020
*   ENTRY WHICH MATCHES CANNOT BE FOUND, AN ERROR MESSAGE CONTAINING  * 06400020
*   THE NAME IS BUILT AND THE ROUTINE EXITS TO THE CONTROL MODULE.    * 06800020
*                                                                     * 07200020
*   WHEN A MATCHING ENTRY IS FOUND, ITS NAME IS PLACED IN THE GOOD    * 07600020
*   RESPONSE MESSAGE AND ITS ADDRESS IS OBTAINED.  IF THE ENTRY IS    * 08000020
*   A PROCESS ENTRY (X'20' ON IN TRMSTATE) THE ENTRY HAS NO LINE      * 08400020
*   INFORMATION.  A MESSAGE SO STATING IS BUILT AND THE ROUTINE       * 08800020
*   RETURNS TO THE CONTROL MODULE.                                    * 09200020
*                                                                     * 09600020
*   THE QCB ADDRESS IS OBTAINED FROM THE TERMINAL ENTRY (TRMDESTQ),   * 10000020
*   AND THE RELATIVE LINE NUMBER (QCBRELLN) IS OBTAINED, CONVERTED    * 10400020
*   TO PRINTABLE EBCDIC, AND STORED IN THE GOOD RESPONSE.  THE DCB    * 10800020
*   ADDRESS IS OBTAINED (QCBDCBAD) AND TESTED FOR A LINE OPEN         * 11200020
*   CONDITION.  IF THE LINE IS NOT OPEN, A NOT OPEN MESSAGE IS        * 11600020
*   BUILT AND CONTROL RETURNS TO THE CALLING ROUTINE.  THE LINE IS    * 12000020
*   THEN TESTED FOR OPEN DD DUMMY (DEBUCBAD IS ZERO, DEB OBTAINED     * 12400020
*   FROM DCBDEBAD).  IF SO, THE LINE NOT OPEN MESSAGE IS BUILT AND    * 12800020
*   THE ROUTINE EXITS TO THE CONTROL MODULE.                          * 13200020
*                                                                     * 13600020
*   IF THE LINE IS OPEN, THE UCB ADDRESS IS PLACED IN THE GOOD        * 14000020
*   RESPONSE, THE TCB ADDRESS IS OBTAINED FROM THE AVT (AVTTCB) AND   * 14400020
*   USED TO ACCESS THE TIOT ADDRESS AT TCB+12.  THE DCBTIOT VALUE     * 14800020
*   IS ADDED TO THE TIOT START AND THE DDNAME FIELD IS MOVED FROM     * 15200020
*   THE RESULTING LOCATION INTO THE RESPONSE.  THE ROUTINE EXITS TO   * 15600020
*   THE CONTROL MODULE.                                               * 16000020
*                                                                     * 16400020
*ENTRY POINTS --                                                      * 16800020
*        'IEDQCG' TO PROCESS DISPLAY ADDR OPERATOR CONTROL            * 17200020
*   COMMANDS.  CALLING SEQUENCE IS                                    * 17600020
*                        LOAD EPLOC=LOADPRFX                          * 18000020
*                        LR   R1,ROPC                                 * 18400020
*                        LR   R15,R0                                  * 18800020
*                        BALR R14,R15                                 * 19200020
*                                                                     * 19600020
*INPUT -- REGISTER 1 - ADDRESS OF THE OPERATOR CONTROL AVT.  AT THE   * 20000020
*   TAG OPCCKELE IS THE COMMON INPUT BLOCK.  THE DESIRED TERMINAL     * 20400020
*   NAME IS EIGHT BYTES BEYOND THIS AT THE TAG OPCTNME.               * 20800020
*                                                                     * 21200020
*   REGISTER 15 - ENTRY POINT ADDRESS.                                * 21600020
*                                                                     * 22000020
*OUTPUT -- REGISTER 1 - ADDRESS OF APPROPRIATE RESPONSE MESSAGE.      * 22400020
*                                                                     * 22800020
*   REGISTER 15 -                                                     * 23200020
*              0 IF REQUESTED INFORMATION IS DISPLAYED.               * 23600020
*              4 IF TERMINAL NOT FOUND, TERMINAL IS A PROCESS         * 24000020
*                ENTRY, OR LINE FOR TERMINAL IS NOT OPEN.             * 24400020
*                                                                     * 24800020
*EXTERNAL ROUTINES -- N/A.                                            * 25200020
*                                                                     * 25600020
*EXITS-NORMAL -- COMMAND IS PROCESSED.  A RESPONSE MESSAGE IS         * 26000020
*   CONSTRUCTED AND ITS ADDRESS RETURNED TO THE CALLING ROUTINE.      * 26400020
*                                                                     * 26800020
*EXITS-ERROR --  TERMINAL REQUESTED CANNOT BE FOUND.  NOT FOUND       * 27200020
*   MESSAGE BUILT, RETURN CODE OF X'04' SET.                          * 27600020
*                                                                     * 28000020
*   TERMINAL IS A PROCESS ENTRY AND THUS HAS NO LINE INFORMATION.     * 28400020
*   PROCESS ENTRY MESSAGE BUILT, RETURN CODE OF X'04' SET.            * 28800020
*                                                                     * 29200020
*   LINE FOR TERMINAL NOT OPEN OR OPENED DD DUMMY.  NOT OPEN          * 29600020
*   MESSAGE BUILT, RETURN CODE OF X'04' SET.                          * 30000020
*                                                                     * 30400020
*TABLES/WORK AREAS -- MESSAGES, AVT, DEB, DEB, QCB, TERMNAME TABLE,   * 30800020
*   TERMINAL ENTRY, OPERATOR CONTROL AVT.                             * 31200020
*                                                                     * 31600020
*ATTRIBUTES -- SERIALLY REUSABLE, REFRESHABLE, ENABLED, TRANSIENT,    * 32000020
*   PROBLEM PROGRAM MODE.                                             * 32400020
*                                                                     * 32800020
*NOTES -- THE OPERATION OF THIS MODULE DEPENDS UPON AN INTERNAL       * 33200020
*   REPRESENTATION OF THE EXTERNAL CHARACTER SET WHICH IS             * 33600020
*   EQUIVALENT TO THE ONE USED AT ASSEMBLY TIME.  THE CODING HAS      * 34000020
*   BEEN ARRANGED SO THAT REDEFINITION OF ''CHARACTER'' CONSTANTS,    * 34400020
*   BY REASSEMBLY, WILL RESULT IN A CORRECT MODULE FOR THE NEW        * 34800020
*   DEFINITIONS.                                                      * 35200020
*                                                                     * 35600020
*   MESSAGES ISSUED BY THIS MODULE ARE                                * 36000020
*              IED016I, IED038I, IED090I, IED091I                     * 36400020
*                                                                     * 36800020
*********************************************************************** 37200020
*                                                                       37600020
*                                                                       38000020
R1       EQU   1                        PARAMETER                       38400020
ROPC     EQU   2                        OPERATOR CONTROL AVT BASE       38800020
RAVT     EQU   4                        AVT BASE                        39200020
RTNT     EQU   5                        TERMNAME TABLE BASE             39600020
RTERM    EQU   6                        TERMINAL ENTRY BASE             40000020
RQCB     EQU   7                        QCB BASE                        40400020
RWORK2   EQU   7                        WORK                            40800020
RDCB     EQU   8                        DCB BASE                        41200020
RWORK3   EQU   8                        WORK                            41600020
RDEB     EQU   9                        DEB BASE                        42000020
RUCB     EQU   10                       UCB BASE                        42400020
RWORK    EQU   11                       WORK                            42800020
RBASE    EQU   12                       ROUTINE BASE                    43200020
R13      EQU   13                       SAVE AREA                       43600020
R14      EQU   14                       RETURN                          44000020
R15      EQU   15                       ENTRY                           44400020
         USING IEDQCG,RBASE             ADDRESSABILITY FOR ROUTINE      44800020
         USING IEDQOPC,ROPC             ADDRESSABILITY FOR OP CTL       45200020
         USING IEDQAVTD,RAVT            ADDRESSABILITY FOR AVT          45600020
         USING IEDQTNTD,RTNT            ADDRESSABILITY FOR TNT          46000020
         USING IEDQTRM,RTERM            ADDRESSABILITY FOR TERM         46400020
         USING IEDQQCB,RQCB             ADDRESSABILITY FOR QCB          46800020
         USING IHADCB,RDCB              ADDRESSABILITY FOR DCB          47200020
         USING DEBNMSUB,RDEB            ADDRESSABILITY FOR DEB          47600020
         SAVE  (14,12),,IEDQCG-02/18/71                                 48000020
         LR    RBASE,R15                SET UP ROUTINE BASE             48400020
         LR    ROPC,R1                  GET OP CTL AVT                  48800020
         L     RAVT,OPCAVTAD            GET AVT                         49200020
         L     RTNT,AVTRNMPT            GET TERMNAME TABLE              49600020
         LA    RWORK2,OPCONE            SET UP COUNTER                  50400020
         LH    RWORK3,TNTLEN            GET NUMBER OF ENTRIES           50800020
         SR    RTERM,RTERM              CLEAR                           51200020
         IC    RTERM,TNTENLEN           GET ENTRY LENGTH                51600020
         BCTR  RTERM,0                  DECREMENT FOR EXECUTE           52000020
         CH    RTERM,AVTHA7           EIGHT BYTE TERMNAME               52050020
         BE    HTRMOK                   YES, VALID LENGTH               52100020
         LA    R15,OPCTNME+1(RTERM)     PTR TO FIRST BLANK              52150020
        CLI   OPCZERO(R15),AVTEBLNK     IS IT A BLANK                   52200020
         BNE   ERROR                    NO, ERROR                       52250020
HTRMOK   EQU   *                                                        52300020
         LA    RTNT,TNTFIRST            GET TO START OF ENTRIES         52400020
LOOP     EQU   *                                                        52800020
         CR    RWORK2,RWORK3            END OF TABLE                    53200020
         BH    ERROR                    YES - TAKE ERROR EXIT           53600020
*                                                                       54000020
         EX    RTERM,COMP               RIGHT ENTRY                     54400020
         BE    FOUND                    YES - PROCESS IT                54800020
*                                                                       55200020
         LA    RTNT,OPCFOUR(RTERM,RTNT) BUMP TO NEXT ENTRY              55600020
         LA    RWORK2,OPCONE(,RWORK2)   ADD ONE TO COUNTER              56000020
         B     LOOP                     GO LOOK FOR NEXT ENTRY          56400020
*                                                                       56800020
PE       EQU   *                                                        57200020
         MVC   PEMSG(OPCEIGHT),OPCTNME  PUT NAME IN MSG                 57600020
         LA    RWORK,PEM                GET MSG ADDR                    58000020
         B     GOODEX                                                   58400020
*                                                                       58800020
ERROR    EQU   *                                                        59200020
         MVC   BADMSG(OPCEIGHT),OPCTNME PUT NAME IN MSG                 59600020
         LA    RWORK,BAD                GET ITS ADDRESS                 60000020
SETBAD   EQU   *                                                        60400020
         LA    R15,OPCFOUR              SET BAD RETURN                  60800020
EXIT     EQU   *                                                        61200020
         ST    RWORK,OPCREG1(,R13)      PUT IN SAVE AREA                61600020
         RETURN (14,12),T,RC=(15)                                       62000020
*                                                                       62400020
FOUND    EQU   *                                                        62800020
         MVC   GOODMSG+12(OPCEIGHT),OPCTNME  PUT NAME IN MSG            63200020
         AR    RTNT,RTERM               BUMP PAST TERMNAME              63600020
         MVC   OPCWORK+1(OPCTHREE),OPCONE(RTNT) PUT ON BDRT             64000020
         L     RTERM,OPCWORK            GET ADDR OF TERM ENTRY          64400020
         TM    TRMSTATE,PROC+DIST        PRECESS,DIST, OR CASCADE       64800020
         BNZ   PE                                                       65200020
*                                                                       65600020
         L     RQCB,TRMDESTQ-1          GET QCB ADDRESS                 66000020
         SR    RWORK,RWORK              CLEAR                           66400020
         IC    RWORK,QCBRELLN           GET RELATIVE LINE NUMBER        66800020
         CVD   RWORK,OPCDOUBL           COVERT RLN TO PACKED DEC        67200020
         UNPK  OPCDOUBL(OPCTHREE),OPCDOUBL+6(OPCTWO) MAKE ZONED         67600020
         MVC   MSG+9(OPCTHREE),OPCDOUBL PUT RLN IN MSG                  68000020
         OI    MSG+11,ZONE                                              68400020
         L     RDCB,QCBDCBAD-1          GET DCB ADDRESS                 68800020
         CLI   DCBTIOT,A                LINE OPEN                       69200020
         BNL   NOTOP                    NO - REJECT COMMAND             69600020
*                                                                       70000020
         L     RDEB,DCBDEBAD            GET DEB ADDRESS                 70400020
         SLL   RWORK,OPCTWO             MULTIPLY RLN BY FOUR            70800020
         L     RUCB,DEBUCBAD-4-DEBNMSUB(RWORK,RDEB) GET UCB ADDR        71200020
         LA    RUCB,OPCZERO(RUCB)       CLEAR HIGH BYTE                 71600020
         LTR   RUCB,RUCB                OPENED DD DUMMY                 72000020
         BZ    NOTOP                    YES - REJECT COMMAND            72400020
         CLC   QCBRELLN(OPCONE),DEBNMEXT  EXTERT HIGH                   72500020
         BH    NOTOP                    YES, OPENED DD DUMMY            72600020
*                                                                       72800020
         MVC   MSG+13(OPCTHREE),ADDR(RUCB) PUT UCB ADDR IN MSG          73200020
         LH    RWORK,DCBTIOT            GET DD OFFSET IN TIOT           73600020
         L     RWORK2,AVTTCB            GET TCB ADDRESS                 74000020
         L     RWORK2,TWELVE(,RWORK2)   GET TIOT ADDRESS                74400020
         AR    RWORK2,RWORK             GET TO DDNAME                   74800020
         MVC   MSG(OPCEIGHT),OPCFOUR(RWORK2) PUT IN MSG                 75200020
         LA    RWORK,GOODMSG            PICK UP MESSAGE ADDR            75600020
GOODEX   EQU   *                                                        76000020
         SR    R15,R15                  SET GOOD RETURN                 76400020
         B     EXIT                                                     76800020
*                                                                       77200020
NOTOP    EQU   *                                                        77600020
         MVC   NOB(OPCEIGHT),OPCTNME    PUT NAME IN MSG                 78000020
         LA    RWORK,NOA                GET MSG ADDR                    78400020
         B     SETBAD                                                   78800020
*                                                                       79200020
TWELVE   EQU   12                       TIOT OFFSET FROM TCB            79600020
ADDR     EQU   13                                                       80000020
PROC     EQU   X'20'                                                    80400020
ZONE     EQU   X'30'                                                    80800020
DIST     EQU   X'40'                                                    80900020
A        EQU   C'A'                                                     81200020
COMP     CLC   OPCZERO(OPCONE,RTNT),OPCTNME                             81600020
BAD      DS    0H                                                       81700020
         DC    AL2(DESCR1-*),X'6000'     LENGTH,MCSFLGS-INREG0-IMMRSP   81800020
         DC    C'IEDO16I STATION '                                      81900020
BADMSG   DC    8C' ',C' NOT FOUND'                                      82000020
DESCR1   DC    X'0800'                   DESCRIPTOR - IMMEDIATE RESP    82100020
         DC    X'0000'                   ROUTING - IN REG 0             82200020
GOODMSG  DS    0H                                                       82300020
         DC    AL2(DESCR2-*),X'6000'     LENGTH,MCSFLGS-INREG0-IMMRSP   82400020
         DC    C'IED038I ',8C' ',C' IS ON LINE '                        82500020
MSG      DC    16C' '                                                   82600020
DESCR2   DC    X'0800'                   DESCRIPTOR - IMMEDIATE RESP    82700020
         DC    X'0000'                   ROUTING - IN REG 0             82800020
PEM      DS    0H                                                       82900020
         DC    AL2(DESCR3-*),X'6000'     LENGTH,MCSFLGS-INREG0-IMMRSP   83000020
         DC    C'IED090I '                                              83100020
PEMSG    DC    8C' ',C' IS NOT SINGLE ENTRY'                            83200020
DESCR3   DC    X'0800'                   DESCRIPTOR - IMMEDIATE RESP    83300020
         DC    X'0000'                   ROUTING - IN REG 0             83400020
NOA      DS    0H                                                       83500020
         DC    AL2(DESCR4-*),X'6000'     LENGTH,MCSFLGS-INREG0-IMMRSP   83600020
         DC    C'IED091I LINE FOR '                                     83700020
NOB      DC    8C' ',C' NOT OPEN'                                       83800020
DESCR4   DC    X'0800'                   DESCRIPTOR - IMMEDIATE RESP    83900020
         DC    X'0000'                   ROUTING - IN REG 0             84000020
*                                                                       85200020
         PRINT NOGEN                                                    85600020
         TAVTD                                                          86000020
         TOPCD                                                          86400020
         TDEBD                                                          86800020
         DCBD  DSORG=TX                                                 87200020
         TQCBD                                                          87600020
         TTNTD                                                          88000020
         TTRMD                                                          88400020
         END                                                            88800020
