         TITLE '''IEDQCH'' - DISPLAY TERM'                              00300020
IEDQCH   CSECT                                                          00600020
*A237000,279000,564000,618000,714000,717000                       M6406 00670000
*C297000,450000-459000,477000-480000,513000-525000,723000         M6406 00740000
*C729000-732000,744000-747000,759000,765000,774000                M6406 00810000
*********************************************************************** 00900020
*                                                                     * 01200020
*TITLE 'IEDQCH' PROCESSOR OF DISPLAY TERM COMMANDS.                   * 01500020
*                                                                     * 01800020
*STATUS -- CHANGE LEVEL 0                                             * 02100020
*                                                                     * 02400020
*FUNCTION -- THIS ROUTINE PROCESSES OPERATOR CONTROL COMMANDS WHICH   * 02700020
*   REQUEST DISPLAY OF THE FIELDS IN A SPECIFIED TERMINAL ENTRY.      * 03000020
*                                                                     * 03300020
*   THE COPY TERMINAL INFORMATION ROUTINE OBTAINS THE TERMNAME        * 03600020
*   TABLE FROM THE AVT AND SERIALLY SEARCHES IT FOR AN ENTRY WHICH    * 03900020
*   MATCHES THAT SPECIFIED IN THE COMMON INPUT BLOCK.  IF A MATCH     * 04200020
*   CANNOT BE FOUND, THE ROUTINE PUTS THE REQUESTED NAME IN AN        * 04500020
*   ERROR MESSAGE AND RETURNS TO THE CONTROL MODULE.                  * 04800020
*                                                                     * 05100020
*   WHEN THE ENTRY IS FOUND, ITS NAME IS PLACED IN THE GOOD           * 05400020
*   RESPONSE, AND ITS ADDRESS OBTAINED.  ITS INPUT AND OUTPUT         * 05700020
*   SEQUENCE NUMBERS (TRMINSEQ AND TRMOUTSQ) ARE CONVERTED TO         * 06000020
*   PRINTABLE CHARACTERS AND PLACED IN THE RESPONSE.  IF THE ENTRY    * 06300020
*   IS NOT A PROCESS ENTRY (TRMSTATE DOES NOT HAVE X'20' BIT ON),     * 06600020
*   THE INTENSIVE MODE SEARCH TABLE IS OBTAINED AND THE SENSE DATA    * 06900020
*   AT TRMSENSE IS CONVERTED TO PRINTABLE INFORMATION AND PLACED IN   * 07200020
*   THE RESPONSE.                                                     * 07500020
*                                                                     * 07800020
*   THE STATUS BYTE (TRMSTATE) IS ACCESSED AND THE PRINTABLE          * 08100020
*   EQUIVALENTS OF ITS BIT VALUES PLACED IN THE RESPONSE MESSAGE.     * 08400020
*   CONTROL RETURNS TO THE CONTROL MODULE.                            * 08700020
*                                                                     * 09000020
*ENTRY POINTS --                                                      * 09300020
*        'IEDQCH' TO PROCESS DISPLAY TERM OPERATOR CONTROL            * 09600020
*   COMMANDS.  CALLING SEQUENCE IS                                    * 09900020
*                        LOAD EPLOC=LOADPRFX                          * 10200020
*                        LR   R1,ROPC                                 * 10500020
*                        LR   R15,R0                                  * 10800020
*                        BALR R14,R15                                 * 11100020
*                                                                     * 11400020
*INPUT -- REGISTER 1 - ADDRESS OF OPERATOR CONTROL AVT.  AT THE TAG   * 11700020
*   OPCTNME (IN THE CHECKPOINT ELEMENT) IS THE NAME OF THE            * 12000020
*   REQUESTED TERMINAL.                                               * 12300020
*                                                                     * 12600020
*   REGISTER 15 - ENTRY POINT ADDRESS.                                * 12900020
*                                                                     * 13200020
*OUTPUT -- REGISTER 1 - ADDRESS OF APPROPRIATE RESPONSE MESSAGE.      * 13500020
*                                                                     * 13800020
*   REGISTER 15 - RETURN CODE.  VALUES ARE                            * 14100020
*                   0    DISPLAY DONE                                 * 14400020
*                   4    TERMINAL NOT FOUND                           * 14700020
*                                                                     * 15000020
*EXTERNAL ROUTINES -- N/A.                                            * 15300020
*                                                                     * 15600020
*EXITS-NORMAL -- COMMAND IS PROCESSED.  A RESPONSE MESSAGE IS         * 15900020
*   CONSTRUCTED AND ITS ADDRESS RETURNED TO THE CALLER.               * 16200020
*                                                                     * 16500020
*EXITS-ERROR -- TERMINAL NAME COULD NOT BE FOUND.  A MESSAGE SO       * 16800020
*   INDICATING IS CONSTRUCTED AND ITS ADDRESS IS RETURNED TO THE      * 17100020
*   CALLING ROUTINE.                                                  * 17400020
*                                                                     * 17700020
*TABLES/WORK AREAS -- MESSAGES, STATUS BYTE TABLE, SENSE BYTE         * 18000020
*   CONVERSION TABLE, AVT, TERMNAME TABLE, TERMINAL ENTRY, OPERATOR   * 18300020
*   CONTROL AVT.                                                      * 18600020
*                                                                     * 18900020
*ATTRIBUTES -- SERIALLY REUSABLE, REFRESHABLE, ENABLED, TRANSIENT,    * 19200020
*   PROBLEM PROGRAM MODE.                                             * 19500020
*                                                                     * 19800020
*NOTES -- THE OPERATION OF THIS MODULE DEPENDS UPON AN INTERNAL       * 20100020
*   REPRESENTATION OF THE EXTERNAL CHARACTER SET WHICH IS             * 20400020
*   EQUIVALENT TO THE ONE USED AT ASSEMBLY TIME.  THE CODING HAS      * 20700020
*   BEEN ARRANGED SO THAT REDEFINITION OF ''CHARACTER'' CONSTANTS,    * 21000020
*   BY REASSEMBLY, WILL RESULT IN A CORRECT MODULE FOR THE NEW        * 21300020
*   DEFINITIONS.                                                      * 21600020
*                                                                     * 21900020
*   MESSAGES ISSUED BY THIS MODULE ARE                                * 22200020
*              IED016I, IED033I                                       * 22500020
*                                                                     * 22800020
*********************************************************************** 23100020
*                                                                       23400020
*                                                                       23700020
R0       EQU   0                       WORK REGISTER              M6406 23800000
R1       EQU   1                        PARAMETER                       24000020
ROPC     EQU   2                        OPERATOR CONTROL AVT BASE       24300020
RAVT     EQU   4                        AVT BASE                        24600020
RTNT     EQU   5                        TERMNAME TABLE BASE             24900020
RTERM    EQU   6                        TERMINAL ENTRY BASE             25200020
RWORK    EQU   7                        WORK                            25500020
RWORK2   EQU   8                        WORK                            25800020
RWORK3   EQU   9                        WORK                            26100020
RQCB     EQU   10                       QCB BASE                        26400020
RTBL     EQU   11                       WORK TABLE                      26700020
RBASE    EQU   12                       ROUTINE BASE                    27000020
R13      EQU   13                       SAVE AREA                       27300020
R14      EQU   14                       RETURN                          27600020
R15      EQU   15                       ENTRY POINT                     27900020
         USING IEDQQCB,RQCB             ADDRESSABILITY FOR QCB    M6406 28000000
         USING IEDQCH,RBASE             ADDRESSABILITY FOR ROUTINE      28200020
         USING IEDQAVTD,RAVT            ADDRESSABILITY FOR AVT          28500020
         USING IEDQOPC,ROPC             ADDRESSABILITY FOR OP CTL       28800020
         USING IEDQTNTD,RTNT            ADDRESSABILITY FOR TNT          29100020
         USING IEDQTRM,RTERM            ADDRESSABILITY FOR TERM         29400020
         SAVE  (14,12),,IEDQCH-05/17/71                           M6406 29700000
         LR    RBASE,R15                SET UP BASE                     30000020
         LR    ROPC,R1                  SET UP OP CTL AVT               30300020
         L     RAVT,OPCAVTAD            GET AVT                         30600020
         L     RTNT,AVTRNMPT            GET TERMINAL TABLE              30900020
         LA    RWORK2,OPCONE            SET UP COUNTER                  31200020
         LH    RWORK3,TNTLEN            GET NUMBER OF ENTRIES           31500020
         SR    RTERM,RTERM              CLEAR                           31800020
         IC    RTERM,TNTENLEN           GET ENTRY LENGTH                32100020
         BCTR  RTERM,0                  DECREMENT FOR EXECUTE           32400020
         CH    RTERM,AVTHA7           EIGHT BYTE TERMNAME               32440020
         BE    HTRMOK                   YES, VALID LENGTH               32480020
         LA    R15,OPCTNME+1(RTERM)     PTR TO FIRST BLANK              32520020
        CLI   OPCZERO(R15),AVTEBLNK     IS IT A BLANK                   32560020
         BNE   ERROR                    NO, ERROR                       32600020
HTRMOK   EQU   *                                                        32640020
         LA    RTNT,TNTFIRST            GET TO START OF ENTREIS         32700020
LOOP     EQU   *                                                        33000020
         CR    RWORK2,RWORK3            END OF TABLE                    33300020
         BH    ERROR                    YES - TAKE ERROR EXIT           33600020
*                                                                       33900020
         EX    RTERM,COMP               RIGHT ENTRY                     34200020
         BE    FOUND                    YES - PROCESS IT                34500020
*                                                                       34800020
         LA    RTNT,OPCFOUR(RTERM,RTNT) BUMP TO NEXT ENTRY              35100020
         LA    RWORK2,OPCONE(,RWORK2)   ADD ONE TO COUNTER              35400020
         B     LOOP                     GO PROCESS NEXT ENTRY           35700020
*                                                                       36000020
ERROR    EQU   *                                                        36300020
         MVC   BADMSG(OPCEIGHT),OPCTNME PUT NMME IN MSG                 36600020
         LA    RWORK,BAD                PICK UP MESSAGE ADDRESS         36900020
SETBAD   EQU   *                                                        37200020
         LA    R15,OPCFOUR              BAD RETURN CODE                 37500020
         B     PUT                                                      37800020
*                                                                       38100020
FOUND    EQU   *                                                        38400020
         MVC   GOOD+12(OPCEIGHT),OPCTNME PUT NAME IN MSG                38700020
         AR    RTNT,RTERM               BUMP PAST TERMNAME              39000020
         MVC   OPCWORK+1(OPCTHREE),OPCONE(RTNT) PUT ON BDRY             39300020
         L     RTERM,OPCWORK            GET TERMINAL ENTRY              39600020
         LH    RWORK,TRMINSEQ           GET INPUT SEQUENCE              39900020
         CVD   RWORK,OPCDOUBL           CONVERT IT TO PACKED DEC        40200020
         UNPK  OPCDOUBL(OPCFIVE),OPCDOUBL+5(OPCTHREE) MAKE ZONED        40500020
         OI    OPCDOUBL+4,ZONE          CHANGE ZONE FOR PRINTING        40800020
         MVC   SEQ+7(OPCFOUR),OPCDOUBL+1 PUT SEQ-IN IN MSG              41100020
         LH    RWORK,TRMOUTSQ           GET OUTPUT SEQUENCE             41400020
         CVD   RWORK,OPCDOUBL           CONVERT IT TO PACKED DEC        41700020
         UNPK  OPCDOUBL(OPCFIVE),OPCDOUBL+5(OPCTHREE) MAKE ZONED        42000020
         OI    OPCDOUBL+4,ZONE          CHANGE ZONE FOR PRINTING        42300020
         MVC   SEQ+21(OPCFOUR),OPCDOUBL+1 PUT SEQ-OUT IN MSG            42600020
         LH    RWORK,LMSG               GET MSG LENGTH                  42900020
         STH   RWORK,GOOD               PUT IN MSG                      43200020
         SR    RWORK,RWORK              CLEAR                           43500020
         TM    TRMSTATE,PROCESS         PROCESS ENTRY                   43800020
         BO    NOIMMSG                  YES - NO INTENSIVE MODE         44100020
*                                                                       44400020
         LA    RTBL,IMTBL               GET BIT VALUE TBL               44700020
         BAL   RWORK2,CKLCB             GET INTENSEIVE MODE VALUE M6406 45000000
         SRL   RWORK,OPCFOUR            CLEAR COUNT               M6406 45300000
         SLL   RWORK,OPCFOUR            RESTORE SENSE             M6406 45600000
         STC   RWORK,OPCDOUBL           PUT IN WORK AREA          M6406 45900000
ILOOP    EQU   *                                                        46200020
         CLI   OPCZERO(RTBL),AVTEFF     END OF TABLE                    46500020
         BE    NOIMMSG                  YES - NO SENSE BITS ON          46800020
*                                                                       47100020
         IC    RWORK,OPCZERO(RTBL)      GET BIT SETTING                 47400020
         EX    RWORK,CLI               THIS IT                    M6406 47700000
         BE    PUTIM                     YES                      M6406 48000000
*                                                                       48300020
         LA    RTBL,OPCTHREE(,RTBL)     BUMP TO NEXT BIT                48600020
         B     ILOOP                    TEST IT                         48900020
*                                                                       49200020
NOIMMSG  EQU   *                                                        49500020
         MVC   INTENSE(OPCTWO),NOIM     NO SENSE BITS ON                49800020
         B     TESTSTAT                                                 50100020
*                                                                       50400020
PUTIM    EQU   *                                                        50700020
         MVC   INTENSE(OPCTWO),OPCONE(RTBL) SET SENSE VALUE             51000020
         BAL   RWORK2,CKLCB             G%T INTENSIVE MODE VALUE  M6406 51300000
         SLL   RWORK,TWENTY8       CLEAR HIGHHALF                 M6406 51600000
         SRL   RWORK,TWENTY7        MULTIPLY BY TWO FOR HALFWORD  M6406 51900000
         LA    RWORK,COUNT(RWORK)       GET INDEX                 M6406 52200000
         MVC   INTENSE+3(OPCTWO),OPCZERO(RWORK) SET IN MSG        M6406 52500000
TESTSTAT EQU   *                                                        52800020
         TM    TRMSTATE,LINE            LINE ENTRY                      53100020
         BNO   ENTRIES                  NO - TEST OTHER TYPES           53400020
*                                                                       53700020
         MVC   GOODMSG(OPCSEVEN),BITTAGS PUT 'LINE' IN MSG              54000020
         B     OTHERS                   GO LOOK AT OTHER BITS           54300020
*                                                                       54600020
ENTRIES  EQU   *                                                        54900020
         TM    TRMSTATE,DISCAS          DISTLIST OR CASCADE             55200020
         BNO   SNGLPROC                 NO - SINGLE OR PROCESS          55500020
*                                                                       55800020
         LH    RWORK,SMSG               GET SHORT MSG LENGTH            56100020
         STH   RWORK,GOOD               STORE IN MSG                    56400020
         MVC   GOODMSG1(OPCFOUR),DESCR2 RESET DESCRIPTOR CODE     M6406 56500000
         L     RQCB,TRMDESTQ-1          GET QCB ADDRESS                 56700020
         CLI   OPCFIVE(RQCB),CASC       CASCADE LIST ENTRY              57000020
         BE    PUTCASC                  YES - PUT IN MSG                57300020
*                                                                       57600020
         MVC   GOODMSG(OPCSEVEN),BITTAGS+7 PUT 'DISLIST' IN MSG         57900020
         B     OTHERS                                                   58200020
*                                                                       58500020
PUTCASC  EQU   *                                                        58800020
         MVC   GOODMSG(OPCSEVEN),BITTAGS+14 PUT 'CASCADE' IN MSG        59100020
         B     OTHERS                                                   59400020
*                                                                       59700020
SNGLPROC EQU   *                                                        60000020
         TM    TRMSTATE,PROCESS         PROCESS ENTRY                   60300020
         BNO   PROC                     NO - SINGLE                     60600020
*                                                                       60900020
         MVC   GOODMSG(OPCSEVEN),BITTAGS+28 PUT 'PROCESS' IN MSG        61200020
         B     OTHERS                                                   61500020
*                                                                       61800020
CKLCB    EQU   *                                                        61808000
         TM    TRMSTATE,DISCAS          DISTLIST OR CASCADE       M6406 61816000
         BNZ   CKTRM                    YES, CAN'T BE IN LCB      M6406 61824000
         L     RQCB,TRMDESTQ-1          GET QCB ADDRESS           M6406 61832000
         IC    RWORK,QCBRELLN           GET RELATIVE LINE         M6406 61840000
         L     R1,QCBDCBAD-1            GET DCB ADDRESS           M6406 61848000
         USING IHADCB,R1                ADDRESSABILITY FOR DCB    M6406 61856000
         CLI   DCBTIOT,A                LINE OPEN                 M6406 61864000
         BNL   CKTRM                     NO, NOT IN LCB           M6406 61872000
         LR    R15,RWORK                RELATIVE LINE NUMBER      M6406 61880000
         SLL   R15,OPCTWO               X 2 FOR UCB INDEX         M6406 61888000
         L     R14,DCBDEBAD             GET DEB ADDRESS           M6406 61896000
         CLC   QCBRELLN(OPCONE),DEBNMEXT-DEBNMSUB(R14) EXTENT HIGHM6406 61904000
         BH    CKTRM                    YES, NOT IN LCB           M6406 61912000
         L     R15,DEBUCBAD-4-DEBNMSUB(R14,R15)  GET UCB ADDRESS  M6406 61920000
         LA    R15,OPCZERO(R15)          CLEAR HIGH BYTE          M6406 61928000
         LTR   R15,R15                   OPEN DD DUMMY            M6406 61936000
         BZ    CKTRM                     YES,  NOT LCB            M6406 61944000
         L     R15,DCBIOBAD             GET FIRST JOB ADDRESS     M6406 61952000
         LA    R15,OPCZERO(R15)         CLEAR HIGH BYTE           M6406 61960000
         SR    R0,R0                    CLEAR FOR INDEX           M6406 61968000
         IC    R0,DCBEIOBX              GET INDEX TO IOB          M6406 61976000
         DROP  R1                                                       61984000
         LR    R1,RWORK                 RELATIVE LINE NUMBER      M6406 61992000
         MR    R0,R0                    INDEX TO PROPER IOB       M6406 62000000
         AR    R15,R1                   ADDRESS OF PROPER IOB     M6406 62008000
         LA    R1,LCBFLAG1-IEDQLCB      GET LCB INDEX             M6406 62016000
         SR    R15,R1                   GET LCB ADDRESS           M6406 62024000
         IC    RWORK,LCBERMSK-IEDQLCB(R15)   INTENSIVE MODE VALUE M6406 62032000
         LTR   RWORK,RWORK              ANY IN LCB                M6406 62040000
         BCR   7,RWORK2                 YES, USE IT.              M6406 62048000
*                                                                       62056000
CKTRM    IC    RWORK,TRMSENSE           GET INTENSIVE MODE VALUE  M6406 62064000
         BR    RWORK2                                             M6406 62072000
PROC     EQU   *                                                        62100020
         MVC   GOODMSG(OPCSEVEN),BITTAGS+21 PUT 'SINGLE' IN MSG         62400020
OTHERS   EQU   *                                                        62700020
         LA    RWORK3,GOODMSG+8         GET START OF VARIABLE           63000020
         TM    TRMSTATE,TRMHELDN        INTERCEPT BIT ON                63300020
         BNO   OPTS                     NO                              63600020
*                                                                       63900020
         MVC   OPCZERO(OPCSEVEN,RWORK3),BITTAGS+42 PUT 'HOLD' IN MSG    64200020
         LA    RWORK3,OPCEIGHT(,RWORK3) BUMP MSG ADDR                   64500020
OPTS     EQU   *                                                        64800020
         TM    TRMSTATE,TRMOPTFN        OPTION FIELDS BIT ON            65100020
         BNO   SEC                      NO                              65400020
*                                                                       65700020
         MVC   OPCZERO(OPCSEVEN,RWORK3),BITTAGS+49 PUT 'OPTIONS'        66000020
         LA    RWORK3,OPCEIGHT(,RWORK3) BUMP MSG ADDR                   66300020
SEC      EQU   *                                                        66600020
         TM    TRMSTATE,TRMSCNYN        SECONDARY BIT ON                66900020
         BNO   END                      NO                              67200020
*                                                                       67500020
         MVC   OPCZERO(OPCSEVEN,RWORK3),BITTAGS+56 PUT 'SECONDARY'      67800020
         LA    RWORK3,OPCEIGHT(,RWORK3) BUMP MSG ADDR                   68100020
END      EQU   *                                                        68400020
         LA    RWORK,GOOD               PICK UP MESSAGE ADDRESS         68700020
         SR    R15,R15                  RETURN CODE                     69000020
PUT      EQU   *                                                        69300020
         ST    RWORK,OPCREG1(,R13)      PUT IN SAVE AREA                69600020
         RETURN (14,12),T,RC=(15)                                       69900020
*                                                                       70200020
PROCESS  EQU   X'20'                    EQUATE FOR PROCESS              70500020
ZONE     EQU   X'30'                    CONVERSION FACTOR FOR ZONE      70800020
DISCAS   EQU   X'40'                    EQUATE FOR DIST OR CASC         71100020
LINE     EQU   X'80'                    EQUATE FOR LINE ENTRY           71400020
COUNT    DC    C'00010203040506070809101112131415'                M6406 71500000
FIFTEEN  EQU   15                                                       71700020
TWENTY7  EQU   27                                                 M6406 71770000
TWENTY8  EQU   28                                                 M6406 71840000
A        EQU   C'A'                                               M6406 71910000
CASC     EQU   C'G'                                                     72000020
CLI      CLI   OPCDOUBL,OPCZERO                                   M6406 72300000
COMP     CLC   OPCZERO(OPCONE,RTNT),OPCTNME                             72600020
SMSG     DS    0H                                                 M6406 72700000
         DC    AL2(GOODMSG1-GOOD)                                 M6406 72800000
LMSG     DS    0H                                                 M6406 72900000
         DC    AL2(DESCR2-GOOD)                                   M6406 73000000
BAD      DS    0H                                                       73300020
         DC    AL2(DESCR1-*),X'6000'     LENGTH,MCSFLGS-INREG0-IMMRSP   73400020
         DC    C'IED016I STATION '                                      73500020
BADMSG   DC    8C' ',C' NOT FOUND'                                      73600020
DESCR1   DC    X'0800'                   DESCRIPTOR - IMMEDIATE RESP    73700020
         DC    X'0000'                   ROUTING - IN REG 0             73800020
GOOD     DS    0H                                                       73900020
         DC    AL2(DESCR2-*),X'6000'     LENGTH,MCSFLGS-INREG0-IMMRSP   74000020
         DC    C'IED033I ',8C' ',C' STATUS='                            74100020
GOODMSG  DC    47C' '                                             M6406 74200000
GOODMSG1 DC    C' INTENSE='                                       M6406 74300000
INTENSE  DC    6C' '                                              M6406 74400000
SEQ      DC    C'IN-SEQ=    , OUT-SEQ=    '                             74800020
DESCR2   DC    X'0800'                   DESCRIPTOR - IMMEDIATE RESP    74900020
         DC    X'0000'                   ROUTING - IN REG 0             75000020
BITTAGS  DC    C'LINEENTDISLISTCASLISTSNGLTRMPROCESS'                   75300020
         DC    C'ACPTINGINTCEPTOPTFLDSSCNDARY'                          75600020
IMTBL    DC    X'10',C'TO',X'20',C'LD',X'30',C'OR',X'40',C'DC'    M6406 75900000
         DC    X'50',C'EC',X'60',C'BO',X'70',C'IR',X'80',C'CR'          76200020
         DC    X'90',C'UE',X'A0',C'M2',X'F0',C'IM',X'FF'          M6406 76500000
NOIM     DC    C'NO'                                                    76800020
*                                                                       77100020
         TQCBD                                                          77200000
         TLCBD                                                          77300000
         DCBD  DSORG=TX                                                 77400000
         TDEBD                                                          77500000
         TOPCD                                                          77700020
         TAVTD                                                          78000020
         TTRMD                                                          78300020
         TTNTD                                                          78600020
*                                                                       78900020
         END                                                            79200020
