         TITLE '''IEDQCI'' - DISPLAY LINE'                              00200020
IEDQCI   CSECT                                                          00400020
*********************************************************************** 00600020
*                                                                     * 00800020
*TITLE 'IEDQCI' PROCESSOR OF COPY LINE COMMANDS                       * 01000020
*                                                                     * 01200020
*STATUS -- CHANGE LEVEL 0                                             * 01400020
*                                                                     * 01600020
*FUNCTION -- THIS ROUTINE PROCESSES OPERATOR CONTROL COMMANDS WHICH   * 01800020
*   REQUEST DISPLAY OF THE LCB FIELDS FOR A SPECIFIED LINE.           * 02000020
*                                                                     * 02200020
*   THE COPY LCB INFORMATION ROUTINE DETERMINES IF THE LINE IS        * 02400020
*   SPECIFIED IN THE DDNAME/RLN OR HARDWARE ADDRESS FORMAT BY         * 02600020
*   CHECKING THE COMMON INPUT BLOCK.  IF IT IS DDNAME/RLN, AND THE    * 02800020
*   RELATIVE LINE IS SPECIFIED AS 'ALL' THE COMMAND IS REJECTED, AS   * 03000020
*   ONLY INFORMATION FOR A SINGLE LINE MAY BE PROVIDED.  IF IT IS     * 03200020
*   NOT RLN ALL, THE RELATIVE LINE NUMBER IS CONVERTED TO HEXA-       * 03400020
*   DECIMAL FORMAT FOR INTERNAL USE, AND TESTED FOR A VALUE OF ZERO   * 03600020
*   OR GREATER THAN THE MAXIMUM PERMITTED RLN VALUE OF 255.  IF       * 03800020
*   EITHER OF THESE, THE COMMAND IS REJECTED AND CONTROL RETURNS TO   * 04000020
*   THE CONTROL MODULE.  IF THE RLN IS VALID, THE TCB ADDRESS IS      * 04200020
*   OBTAINED FROM THE AVT (AVTTCB), THE TIOT ACCESSED FROM TCB+12,    * 04400020
*   AND THE OFFSET INTO THE TIOT FOR THE DDNAME IS DETERMINED.        * 04600020
*                                                                     * 04800020
*   FOR BOTH DDNAME AND ADDRESS FORMATS, THE START OF THE DEB CHAIN   * 05000020
*   IS OBTAINED (TCB+8), AND THE FIRST DCB ACCESSED FROM DEBDCBAD.    * 05200020
*   IF THE DCB IS NOT FOR A TCAM LINE (DSORG NOT EQUAL X'40') THE     * 05400020
*   NEXT DEB IS OBTAINED (DEBDEBAD) AND ITS DCB EXAMINED.  IF THERE   * 05600020
*   ARE NO DEBS WITH TCAM DCBS ASSOCIATED, A LINE NOT OPEN MESSAGE    * 05800020
*   IS BUILT AND CONTROL RETURNS TO THE CALLING ROUTINE.              * 06000020
*                                                                     * 06200020
*   IF THE INPUT FORMAT IS DDNAME/RLN, THE TIOT OFFSET IN THE DCB     * 06400020
*   (DCBTIOT) IS COMPARED TO THAT CALCULATED IN SEARCHING THE TIOT.   * 06600020
*   IF THE OFFSETS ARE NOT IDENTICAL, THE NEXT DEB IS OBTAINED AND    * 06800020
*   PROCESSED AS ABOVE.  WHEN THE CORRECT DCB HAS BEEN LOCATED, ITS   * 07000020
*   UCB IS TESTED (DEBUCBAD) FOR ZERO, IMPLYING THE LINE WAS OPENED   * 07200020
*   DD DUMMY.  IF SO, THE COMMAND IS REJECTED AND CONTROL RETURNS     * 07400020
*   TO THE CONTROL MODULE.  IF THE LINE IS OPEN, BUT ITS RELATIVE     * 07600020
*   LINE IS GREATER THAN THE NUMBER OF LINES IN THE LINE GROUP, THE   * 07800020
*   COMMAND IS REJECTED AND THE ROUTINE EXITS TO THE CONTROL          * 08000020
*   MODULE.                                                           * 08200020
*                                                                     * 08400020
*   IF A HARDWARE ADDRESS WAS SPECIFIED, THE UCB IS OBTAINED FROM     * 08600020
*   DEBUCBAD AND COMPARED TO THE SPECIFIED ADDRESS.  IF THE UCB       * 08800020
*   IS NOT ASSOCIATED WITH THIS DEB, THE NEXT DEB IS ACCESSED AND     * 09000020
*   PROCESSED AS ABOVE.                                               * 09200020
*                                                                     * 09400020
*   FOR BOTH FORMATS, ONCE WE HAVE VERIFIED THE DCB ADDRESS, THE      * 09600020
*   LINE IS TESTED FOR OPEN CONDITION.  IF IT IS NOT OPEN, A LINE     * 09800020
*   NOT OPEN MESSAGE IS BUILT AND THE ROUTINE EXITS TO THE CONTROL    * 10000020
*   MODULE.  IF IT IS OPEN, THE LCB ADDRESS IS DETERMINED FROM        * 10200020
*   DCBIOBAD+(DCBEIOBX*RELATIVE LINE)-LENGTH OF AN IOB.  THE LCB      * 10400020
*   STATUS BYTE IS OBTAINED AND IF ANY BITS ARE ON THE STATUS         * 10600020
*   CONVERSION TABLE IS USED TO CONVERT THEIR VALUES TO PRINTABLE     * 10800020
*   DATA AND PLACE THESE EQUIVALENTS IN THE RESPONSE.  OTHERWISE      * 11000020
*   'NO BITS ON' IS PLACED IN THE RESPONSE.                           * 11200020
*                                                                     * 11400020
*   THE SCB IS THEN OBTAINED FROM THE LCB AND THE ERROR WORD IS       * 11600020
*   CONVERTED BY USE OF AN ERROR CONVERSION TABLE AND PRINTABLE       * 11800020
*   EQUIVALENTS ARE PLACED IN THE RESPONSE.  IF NO BITS ARE ON,       * 12000020
*   THIS INDICATOR IS PLACED IN THE MESSAGE.  THE ROUTINE RETURNS     * 12200020
*   TO THE CONTROL MODULE.                                            * 12400020
*                                                                     * 12600020
*ENTRY POINTS --                                                      * 12800020
*        'IEDQCI' TO PROCESS DISPLAY LINE OPERATOR CONTROL COMMANDS   * 13000020
*   CALLING SEQUENCE IS                                               * 13200020
*                        LOAD EPLOC=LOADPRFX                          * 13400020
*                        LR   R1,ROPC                                 * 13600020
*                        LR   R15,R0                                  * 13800020
*                        BALR R14,R15                                 * 14000020
*                                                                     * 14200020
*INPUT -- REGISTER 1 - ADDRESS OF THE OPERATOR CONTROL AVT.  THIS     * 14400020
*   CONTAINS (AT THE TAG OPCCKELE) THE COMMON INPUT BLOCK.  THE       * 14600020
*   FIRST SIXTEEN BYTES OF THIS ELEMENT ARE THE INPUT USED BY THIS    * 14800020
*   MODULE.  THE FORMAT IS                                            * 15000020
*                   +4   (OPCLEN)  LENGTH OF RLN (0 - 3)              * 15200020
*                                  IF 0 - ALL                         * 15400020
*                                  IF X'80' - NO RLN (ADDR FORM)      * 15600020
*                   +5   (OPCRLN)  THE EBCDIC RLN IF ANY              * 15800020
*                   +8   (OPCTNME) THE DDNAME OR HARDWARE ADDRESS     * 16000020
*                                                                     * 16200020
*                                                                     * 16400020
*   REGISTER 15 - ENTRY POINT ADDRESS.                                * 16600020
*                                                                     * 16800020
*OUTPUT -- REGISTER 1 - ADDRESS OF APPROPRIATE RESPONSE MESSAGE.      * 17000020
*                                                                     * 17200020
*   REGISTER 15 - RETURN CODE.                                        * 17400020
*                   0 IF SUCCESSFUL                                   * 17600020
*                   4 IF LINE NOT OPEN, OR OPENED DD DUMMY, OR IF     * 17800020
*                     RELATIVE LINE SPECIFIED IS INVALID              * 18000020
*                                                                     * 18200020
*EXTERNAL ROUTINES -- N/A                                             * 18400020
*                                                                     * 18600020
*EXITS-NORMAL -- COMMAND IS PROCESSED.  A RESPONSE MESSAGE SO         * 18800020
*   INDICATING IS CONSTRUCTED AND ITS ADDRESS RETURNED TO THE         * 19000020
*   CALLING ROUTINE.                                                  * 19200020
*                                                                     * 19400020
*EXITS-ERROR -- RLN SPECIFIED ALL.  COMMAND INVALID MESSAGE BUILT,    * 19600020
*   X'04' RETURN CODE SET.                                            * 19800020
*                                                                     * 20000020
*   RLN IS ZERO OR IS GREATER THAN 255.  COMMAND INVALID MESSAGE      * 20200020
*   BUILT, X'04' RETURN CODE SET.                                     * 20400020
*                                                                     * 20600020
*   RLN SPECIFIED IS GREATER THAN NUMBER OF LINES IN LINE GROUP.      * 20800020
*   COMMAND INVALID MESSAGE BUILT, X'04' RETURN CODE SET.             * 21000020
*                                                                     * 21200020
*   LINE NAME NOT FOUND THROUGH DEB CHAIN, IS NOT OPEN, OR IS OPEN    * 21400020
*   DD DUMMY.  LINE NOT OPEN MESSAGE BUILT, RETURN CODE X'04' SET.    * 21600020
*                                                                     * 21800020
*TABLES/WORK AREAS -- MESSAGES, STATUS CONVERSION TABLE, ERROR WORD   * 22000020
*   CONVERSION TABLE, AVT, LCB, DCB, DEB, SCB, QCB, OPERATOR          * 22200020
*   CONTROL AVT.                                                      * 22400020
*                                                                     * 22600020
*ATTRIBUTES -- SERIALLY REUSABLE, REFRESHABLE, ENABLED, TRANSIENT,    * 22800020
*   PROBLEM PROGRAM MODE.                                             * 23000020
*                                                                     * 23200020
*NOTES -- THE OPERATION OF THIS MODULE DEPENDS UPON AN INTERNAL       * 23400020
*   REPRESENTATION OF THE EXTERNAL CHARACTER SET WHICH IS             * 23600020
*   EQUIVALENT TO THE ONE USED AT ASSEMBLY TIME.  THE CODING HAS      * 23800020
*   BEEN ARRANGED SO THAT REDEFINITION OF ''CHARACTER'' CONSTANTS,    * 24000020
*   BY REASSEMBLY, WILL RESULT IN A CORRECT MODULE FOR THE NEW        * 24200020
*   DEFINITIONS.                                                      * 24400020
*                                                                     * 24600020
*   MESSAGES ISSUED BY THIS MODULE ARE                                * 24800020
*              IED017I, IED018I, IED032I                              * 25000020
*                                                                     * 25200020
*********************************************************************** 25400020
*                                                                       25600020
*                                                                       25800020
R0       EQU   0                        WORK                            26000020
R1       EQU   1                        PARAMETER                       26200020
ROPC     EQU   2                        OPERATOR CONTROL AVT BASE       26400020
RAVT     EQU   4                        AVT BASE                        26600020
RWORK    EQU   5                        WORK                            26800020
RTCB     EQU   6                        TCB BASE                        27000020
RDEB     EQU   6                        DEB BASE                        27200020
RDCB     EQU   7                        DCB BASE                        27400020
RWORK3   EQU   8                        WORK                            27600020
RLCB     EQU   9                        LCB BASE                        27800020
ROFF     EQU   10                       OFFSET TO DDNAME                28000020
RCTR     EQU   10                       COUNTER                         28200020
RTBL     EQU   10                       WORK TABLE                      28400020
RDD      EQU   11                       DDNAME                          28600020
RUCB     EQU   11                       UCB BASE                        28800020
RBASE    EQU   12                       ROUTINE BASE                    29000020
R13      EQU   13                       SAVE AREA                       29200020
R14      EQU   14                       RETURN                          29400020
R15      EQU   15                       ENTRY POINT                     29600020
RWORK2   EQU   15                       WORK                            29800020
         USING IEDQCI,RBASE             ADDRESSABILITY FOR ROUTINE      30000020
         USING IEDQAVTD,RAVT            ADDRESSABILITY FOR AVT          30200020
         USING IEDQLCB,RLCB             ADDRESSABILITY FOR LCB          30400020
         USING IHADCB,RDCB              ADDRESSABILITY FOR DCB          30600020
         USING DEBNMSUB,RDEB            ADDRESSABILITY FOR DEB          30800020
         USING IEDQOPC,ROPC             ADDRESSABILITY FOR OP CTL       31000020
         SAVE  (14,12),,IEDQCI-03/05/71                                 31200020
         LR    RBASE,R15                SET UP BASE                     31400020
         LR    ROPC,R1                                                  31600020
         L     RAVT,OPCAVTAD            GET AVT ADDRESS                 31800020
         L     RTCB,AVTTCB              GET TCB ADDR                    32000020
         CLI   OPCLEN,ADCODE            DD OR ADDR                      32200020
         BE    GETLCB                   ADDR - SKIP RLN CODE            32400020
*                                                                       32600020
         CLI   OPCLEN,AVTEZERO          RLN 'SLL' SPECIFIED             32800020
         BE    COMINV                   YES - REJECT COMMAND            33000020
*                                                                       33200020
         MVC   OPCDOUBL(OPCTHREE),OPCRLN MOVE RLN TO WORK AREA          33400020
         SR    R15,R15                  CLEAR                           33600020
         IC    R15,OPCLEN               GET LENGTH OF RLN               33800020
         BCTR  R15,R0                   DECREMENT FOR EXECUTE           34000020
         EX    R15,PACK                 PACK                            34200020
         XC    OPCDOUBL(OPCSIX),OPCDOUBL CLEAR FOR CONRERT              34400020
         CVB   RWORK,OPCDOUBL           CONVERT TO HEX                  34600020
         LTR   RWORK,RWORK              RLN ZERO                        34800020
         BZ    COMINV                   YES - REJECT COMMAND            35000020
*                                                                       35200020
         CH    RWORK,MAXVAL             RLN > 255                       35400020
         BH    COMINV                   YES - REJECT COMMAND            35600020
*                                                                       35800020
         STC   RWORK,OPCDOUBL           SAVE HEX RLN                    36000020
         L     RDD,TIOT(RTCB)           GET TIOT ADDR                   36200020
         LA    ROFF,STARTOFF            OFFSET TO FIRST DD              36400020
         SR    RWORK2,RWORK2            CLEAR                           36600020
         LA    RDD,STARTOFF(RDD)        ADDR OF FIRST DD                36800020
LOOP     EQU   *                                                        37000020
         IC    RWORK2,OPCZERO(,RDD)     GET LENGTH BYTE                 37200020
         CLI   OPCZERO(RDD),OPCZERO     ANOTHER DD                      37400020
         BE    ERR                      NO - DDNAME NOT FOUND           37600020
*                                                                       37800020
         CLC   OPCFOUR(OPCEIGHT,RDD),OPCTNME SPECIFIED DD               38000020
         BE    GETLCB                   YES - WE HAVE FOUND DD          38200020
*                                                                       38400020
         AR    ROFF,RWORK2              BUMP OFFSET TO NEXT DD          38600020
         AR    RDD,RWORK2               BUMP TO NEXT ENTRY              38800020
         B     LOOP                     GET NEXT DD                     39000020
*                                                                       39200020
GETLCB   EQU   *                                                        39400020
         L     RDEB,DEB(,RTCB)          GET FIRST DEB                   39600020
GETDCB   EQU   *                                                        39800020
         L     RDCB,DEBDCBAD            GET DCB                         40000020
         TM    DCBDSORG+1,TX            TCAM LINE                       40200020
         BNO   NEXTDEB                  NO - WORNG DCB                  40400020
*                                                                       40600020
         CLI   OPCLEN,ADCODE            DD OR ADDR                      40800020
         BE    UCB                      ADDR - GO PROCESS UCBS          41000020
*                                                                       41200020
         LH    RWORK2,DCBTIOT           GET OFFSET INTO TIOT            41400020
         CR    RWORK2,ROFF              SAME AS FOR DD                  41600020
         BNE   NEXTDEB                  NO - WRONG DCB                  41800020
*                                                                       42000020
         SR    R0,R0                    CLEAR                           42200020
         IC    R0,OPCDOUBL              GET RLN                         42400020
         LR    RWORK,R0                 SAVE FOR TEST                   42600020
         SLL   RWORK,OPCTWO             MULTIPLY BY OFUR                42800020
         L     RWORK,DEBUCBAD-4-DEBNMSUB(RWORK,RDEB) GET UCB ADDR       43000020
         LA    RWORK,OPCZERO(RWORK)     CLEAR HIGH BYTE                 43200020
         LTR   RWORK,RWORK              OPENED DD DUMMY                 43400020
         BZ    ERR                      YES - REJECT COMMAND            43600020
*                                                                   622 43800020
         CLC   OPCDOUBL(OPCONE),DEBNMEXT RLN > NUMBER OF EXTENTS        44000020
         BH    ERR                      YES - REJECT COMMAND            44200020
*                                                                   622 44400020
COUNTOK  EQU   *                                                        44600020
         CLI   DCBTIOT,A                LINE OPEN                       44800020
         BNL   ERR                      NO - REJECT COMMAND             45000020
*                                                                       45200020
         LA    RWORK3,DEBUCBAD          GET FIRST UCBA DDR              45400020
         L     RLCB,DCBIOBAD            GET IOB                         45600020
         LA    RLCB,OPCZERO(RLCB)       CLEAR HIGH BYTE                 45800020
         SR    R1,R1                    CLEAR                           46000020
         IC    R1,DCBEIOBX              GET IOB LENGTH                  46200020
         MR    R0,R0                    MULTIPLY IOB BY RLN             46400020
         AR    RLCB,R1                  ADD RESULT TO IOB ADDR          46600020
         LA    RWORK3,LCBFLAG1-IEDQLCB  GET LENGTH OF IOB               46800020
         SR    RLCB,RWORK3              GET TO LCB START                47000020
         B     PROCESS1                                                 47200020
*                                                                       47400020
UCB      EQU   *                                                        47600020
         SR    RWORK,RWORK              CLEAR                           47800020
         IC    RWORK,DEBNMEXT           GET NUMBER OF RLNS              48000020
         LA    RWORK3,DEBUCBAD          GET ADDR OF UCB                 48200020
         LA    RCTR,OPCONE              SET COUNT TO ONE                48400020
UCBLOOP  EQU   *                                                        48600020
         L     RUCB,OPCZERO(,RWORK3)    GET UCB ADDR                    48800020
         CLC   ADDR(OPCTHREE,RUCB),OPCTNME SPECIFIED ADDR               49000020
         BE    FOUND                    YES                             49200020
*                                                                       49400020
         LA    RCTR,OPCONE(,RCTR)       ADD 1 TO COUNT                  49600020
         LA    RWORK3,OPCFOUR(,RWORK3)  GET TO NEXT UCB ADDR            49800020
         CR    RCTR,RWORK               ANY MORE EXTENTS                50000020
         BH    NEXTDEB                  NO - GET NEXT DEB               50200020
*                                                                       50400020
         B     UCBLOOP                                                  50600020
*                                                                       50800020
FOUND    EQU   *                                                        51000020
         LR    R0,RCTR                  PUT RLN OFFSET IN R0            51200020
         B     COUNTOK                  GO GET LCB                      51400020
*                                                                       51600020
NEXTDEB  EQU   *                                                        51800020
         L     RDEB,OPCFOUR(,RDEB)      PICK UP POINTER TO NEXT         52000020
         LA    RDEB,OPCZERO(RDEB)       CLEAR HIGH BYTE                 52200020
         LTR   RDEB,RDEB                ANOTEHR DEB                     52400020
         BNZ   GETDCB                   YES - PROCESS IT                52600020
*                                                                       52800020
ERR      EQU   *                                                        53000020
         MVC   ERMGTXT(OPCEIGHT),OPCTNME PUT NAME IN MSG                53200020
         CLI   OPCLEN,ADCODE            RLN SPECIFIED                   53400020
         BE    MOVETWO                  NO                              53600020
*                                                                       53800020
         MVC   ERMGTXT+9(OPCTHREE),OPCRLN PUT RLN IN MSG                54000020
MOVETWO  EQU   *                                                        54200020
         LA    R1,ERMG                  PICK UP ERROR MESSAGE           54400020
SETRET   EQU   *                                                        54600020
         LA    R15,OPCFOUR              SET ERROR RETURN CODE           54800020
PUT      EQU   *                                                        55000020
         ST    R1,OPCREG1(,R13)         SAVE ITS ADDRESS                55200020
         RETURN (14,12),T,RC=(15)                                       55400020
*                                                                       55600020
COMINV   EQU   *                                                        55800020
         LA    R1,OPCERMSG              GET MSG ADDR                    56000020
         B     SETRET                                                   56200020
*                                                                       56400020
PROCESS1 EQU   *                                                        56600020
         LH    RWORK,LCBSTATE           GET STATUS BYTES                56800020
         STH   RWORK,OPCWORK            SAVE FOR ACCESS                 57000020
         LTR   RWORK,RWORK              ANY BITS ON                     57200020
         BNZ   GETBYTE                  YES - PROCESS THEM              57400020
*                                                                       57600020
SETNO    EQU   *                                                        57800020
         MVC   GOOD(OPCTEN),NOBITS      SET 'NOEN ON' IN MSG            58000020
         B     PROC                                                     58200020
*                                                                       58400020
GETBYTE  EQU   *                                                        58600020
         LA    RWORK,OPCWORK            GET ADDR OF STATUS              58800020
         LA    RWORK2,OPCTWO                                            59000020
         LA    RWORK3,BYTE1             GET BIT TBL ADDR                59200020
         LA    RTBL,GOOD                GET MSG ADDR                    59400020
         SR    R1,R1                    CLEAR                           59600020
STATCLI  EQU   *                                                        59800020
         CLI   OPCZERO(RWORK3),AVTEFF   END OF TABLE                    60000020
         BE    NEXTST                   GO GET TABLE                    60200020
*                                                                       60400020
         IC    R1,OPCZERO(RWORK3)       GET BIT VALUE                   60600020
         EX    R1,TM                    IS THIS BIT ON                  60800020
         BO    PUTST                    YES - PUT ITS TAG IN MSG        61000020
*                                                                       61200020
         LA    RWORK3,OPCTHREE(RWORK3)  BUMP TO NEXT BIT VALUE          61400020
         B     STATCLI                                                  61600020
*                                                                       61800020
NEXTST   EQU   *                                                        62000020
         LA    RWORK,OPCONE(RWORK)                                      62200020
         BCT   RWORK2,NEXT              ANOTER TBL                      62400020
*                                                                       62600020
         B     PROCESS2                                                 62800020
*                                                                       63000020
NEXT     EQU   *                                                        63200020
         LA    RWORK3,BYTE2             GET NEXT TBL ADDR               63400020
         B     STATCLI                                                  63600020
*                                                                       63800020
PUTST    EQU   *                                                        64000020
         MVC   OPCZERO(OPCTWO,RTBL),OPCONE(RWORK3) PUT VALUEIN MSG      64200020
         LA    RTBL,OPCTHREE(,RTBL)     BUMP TO NEXT BIT                64400020
         LA    RWORK3,OPCTHREE(,RWORK3) BUMP MSG ADDR                   64600020
         B     STATCLI                                                  64800020
*                                                                       65000020
PROCESS2 EQU   *                                                        65200020
         LA    RWORK,GOOD               RESET MSG ADDR                  65400020
         CR    RTBL,RWORK               ANY BITS FOUND                  65600020
         BE    SETNO                    NO                              65800020
*                                                                       66000020
PROC     EQU   *                                                        66200020
         L     RLCB,LCBSCBA-1           GET SCB ADDR                    66400020
         LA    RLCB,SCBERRST-IEDQSCB(RLCB) GET SCB ERROR WORD ADDR      66600020
         L     RWORK,OPCZERO(RLCB)      GET STATUS WORD                 66800020
         ST    RWORK,OPCWORK            SAVE FOR COMPARES               67000020
         LTR   RWORK,RWORK              ANY BITS ON                     67200020
         BNZ   ERLOOP                   YES - PROCESS THEM              67400020
*                                                                       67600020
SETNOE   EQU   *                                                        67700020
         MVC   GOODE(OPCTEN),NOBITS     SET NO INDICATOR                67800020
SETGOOD  EQU   *                                                        68000020
         MVC   MSGN(OPCEIGHT),OPCTNME   PUT NAME IN MSG                 68200020
         CLI   OPCLEN,ADCODE            RLN SPECIFIED                   68400020
         BE    PROC1                    NO                              68600020
*                                                                       68800020
         MVC   MSGN+9(OPCTHREE),OPCRLN  PUT RLN NN MSG                  69000020
PROC1    EQU   *                                                        69200020
         LA    R1,MSG                   GET MSG ADDR                    69400020
         SR    R15,R15                  SET GOOD RETURN                 69600020
         B     PUT                                                      69800020
*                                                                       70000020
ERLOOP   EQU   *                                                        70200020
         LA    RWORK,OPCWORK            GET ADDR OF STATUS              70400020
         LA    RWORK2,OPCFOUR           SET LOOP CONTROL                70600020
         LA    RWORK3,BIT1              GET FIRST TABLE ADDR            70800020
         LA    RTBL,GOODE               GET MSG ADDR                    71000020
         SR    R1,R1                    CLEAR FOR IC                    71100020
CLI      EQU   *                                                        71200020
         CLI   OPCZERO(RWORK3),AVTEFF   END OF TABLE                    71400020
         BE    NEXTBYTE                 YES                             71600020
*                                                                       71800020
         IC    R1,OPCZERO(RWORK3)        GET BIT                        72000020
         EX    R1,TM                     BIT ON                         72200020
         BO    PUTFLD              YES - PUT DESCRIPTION                72600020
*                                                                       72800020
         LA    RWORK3,OPCFOUR(RWORK3)   BUMP TO NEXT BIT SETTING        73000020
         B     CLI                      TEST IT                         73200020
*                                                                       73400020
NEXTBYTE EQU   *                                                        73600020
         LA    RWORK,OPCONE(RWORK)                                      73800020
         BCT   RWORK2,END               END OF PROCESSING               74000020
*                                                                       74200020
         LA    RWORK,GOODE              RESET MSG ADDR                  74250020
         CR    RTBL,RWORK               ANY BITS ON                     74300020
         BE    SETNOE                   NO, GO SET INDICATOR            74350020
         B     SETGOOD                                                  74400020
*                                                                       74600020
END      EQU   *                                                        74800020
         STC   RWORK2,COMP                                              74900020
         CLI   COMP,OPCTHREE       THREE TABLES TO GO                   75000020
         BE    SBIT                     YES - GET SECOND TBL            75200020
*                                                                       75400020
         CLI   COMP,OPCTWO         TWO TABLES TO GO                     75600020
         BE    TBIT                     YES - GET THIRD TBL             75800020
*                                                                       76000020
         LA    RWORK3,BIT4              GET FOURTH TBL ADDR             76200020
         B     CLI                                                      76400020
*                                                                       76600020
SBIT     EQU   *                                                        76800020
         LA    RWORK3,BIT2              GET SECOND TBL ADDR             77000020
         B     CLI                                                      77200020
*                                                                       77400020
TBIT     EQU   *                                                        77600020
         LA    RWORK3,BIT3              GET THRD TBL ADDR               77800020
         B     CLI                                                      78000020
*                                                                       78200020
PUTFLD   EQU   *                                                        78400020
         MVC   OPCZERO(OPCTHREE,RTBL),OPCONE(RWORK3)                    78600020
         LA    RTBL,OPCFOUR(,RTBL)      INCREMENT MSG ADDR              78800020
         LA    RWORK3,OPCFOUR(,RWORK3)  BUMP TO NEXT BIT                79000020
         B     CLI                      GO PROCESS IT                   79200020
*                                                                       79400020
DEB      EQU   8                        OFFSET INTO TCB OF DEB          79600020
TIOT     EQU   12                       OFFSET INTO TCB OF TIOT         79800020
ADDR     EQU   13                                                       80000020
STARTOFF EQU   24                                                       80200020
TX       EQU   X'40'                                                    80400020
ADCODE   EQU   X'80'                                                    80600020
A        EQU   C'A'                                                     80800020
COMP     DC    X'00'                                                    80900020
NOBITS   DC    C'NO BITS ON'                                            81000020
MAXVAL   DC    H'255'                                                   81200020
*                                                                       81400020
TM       TM    OPCZERO(RWORK),OPCZERO                                   81600020
ERMG     DS    0H                                                       81680020
         DC    AL2(DESCR1-*),X'6000'     LENGTH,MCSFLGS-INREG0-IMMRSP   81760020
         DC    C'IED017I LINE '                                         81840020
ERMGTXT  DC    12C' ',C' NOT OPEN'                                      81920020
DESCR1   DC    X'0800'                   DESCRIPTOR - IMMEDIATE RESP    82000020
         DC    X'0000'                   ROUTING - IN REG 0             82080020
MSG      DS    0H                                                       82160020
         DC    AL2(DESCR2-*),X'6000'     LENGTH,MCSFLGS-INREG0-IMMRSP   82240020
         DC    C'IED032I '                                              82320020
MSGN     DC    12C' ',C' LNSTAT='                                       82400020
GOOD     DC    32C' ',C' ERR='                                          82600020
GOODE    DC    62C' '                                                   82700020
DESCR2   DC    X'0800'                   DESCRIPTOR - IMMEDIATE RESP    82800020
         DC    X'0000'                   ROUTING - IN REG 0             82900020
PACK     PACK  OPCDOUBL+6(OPCTWO),OPCDOUBL(OPCONE)                  622 83000020
BIT1     DC    X'80',C'HDR',X'40',C'ORG',X'20',C'NTS',X'10',C'SQH'      83200020
         DC    X'08',C'SQL',X'04',C'MNS',X'02',C'ISB',X'01',C'CUT'      83400020
         DC    X'FF'                                                    83600020
BIT2     DC    X'80',C'MIN',X'40',C'MAX'                                83700020
         DC    X'08',C'OLT',X'04',C'ABR',X'02',C'FWD'                   83800020
         DC    X'FF'                                                    83900020
BIT3     DC    X'80',C'LST'                                             83950020
         DC    X'40',C'INV'                                             84000020
         DC    X'20',C'NOP'                                             84050020
         DC    X'08',C'USE',X'04',C'FMT',X'02',C'HDW',X'01',C'UNX'      84100020
         DC    X'FF'                                                    84200020
BIT4     DC    X'80',C'SEL',X'40',C'TXT',X'20',C'CDC',X'10',C'TER'      84400020
         DC    X'08',C'LER',X'04',C'CUR',X'02',C'CHR',X'01',C'UNR'      84600020
         DC    X'FF'                                                    84800020
BYTE1    DC    X'80',C'RC',X'40',C'CM',X'20',C'OC',X'10',C'IM'          85000020
         DC    X'08',C'CR',X'04',C'LF',X'02',C'RV',X'01',C'SD'          85200020
         DC    X'FF'                                                    85400020
BYTE2    DC    X'80',C'TR',X'40',C'MS',X'20',C'TB'                      85500020
         DC    X'08',C'NR',X'04',C'BS',X'02',C'DL'                      85600020
         DC    X'FF'                                                    85700020
*                                                                       86000020
         PRINT NOGEN                                                    86200020
         TOPCD                                                          86400020
         TDEBD                                                          86600020
         DCBD  DSORG=TX                                                 86800020
         TLCBD                                                          87000020
         TSCBD                                                          87200020
         TQCBD                                                          87400020
         TAVTD                                                          87600020
         END                                                            87800020
