         TITLE '''IEDQCJ'' - DISPLAY QUEUE'                             00300020
IEDQCJ   CSECT                                                          00600020
*A450000-468000,485000                                           S22026 00700022
*C336000                                                         S22026 00800022
*C420000,610430,610460,683000,685000,705080-705640,706220-706920 S22025 00830022
*C710700,713700,714700,725700,726700                             S22025 00860022
*********************************************************************** 00900020
*                                                                     * 01200020
*TITLE 'IEDQCJ' PROCESSOR OF DISPLAY QUEUE COMMANDS                   * 01500020
*                                                                     * 01800020
*STATUS -- CHANGE LEVEL 0                                             * 02100020
*                                                                     * 02400020
*FUNCTION -- THIS ROUTINE PROCESSES OPERATOR CONTROL COMMANDS WHICH   * 02700020
*   REQUEST DISPLAY OF THE QCB FIELDS FOR A SPECIFIED TERMINAL.       * 03000020
*                                                                     * 03300020
*   THE COPY QCB INFORMATION ROUTINE ACCESSES THE TERMINAL NAME       * 03600020
*   TABLE FROM THE AVT AND SERIALLY SEARCHES IT FOR AN ENTRY WHICH    * 03900020
*   MATCHES THAT SPECIFIED IN THE COMMON INPUT BLOCK.  IF A MATCH     * 04200020
*   CANNOT BE FOUND, AN ERROR MESSAGE IS PREPARED AND THE ROUTINE     * 04500020
*   EXITS TO THE CONTROL MODULE.                                      * 04800020
*                                                                     * 05100020
*   WHEN THE ENTRY IS FOUND ITS ADDRESS IS USED TO OBTAIN THE QCB     * 05400020
*   ADDRESS (AT TRMDESTQ) AND THE DCB ADDRESS (AT QCBDCBAD).  IF      * 05700020
*   THE DCB IS NOT OPEN, THE COMMAND IS REJECTED, AS THERE IS NO      * 06000020
*   QUEUE STATUS.  CONTROL RETURNS TO THE CONTROL MODULE.  IF THE     * 06300020
*   LINE IS OPEN, ITS DEB ADDRESS (AT DCBDEBAD) IS USED TO TEST THE   * 06600020
*   UCB ADDRESS AT DEBUCBAD.  IF THE ADDRESS IS ZERO, THE LINE IS     * 06900020
*   OPENED DD DUMMY AND IS EFFECTIVELY NOT OPEN.  THE COMMAND IS      * 07200020
*   REJECTED AND THE ROUTINE EXITS TO THE CONTROL MODULE.             * 07500020
*                                                                     * 07800020
*   IF THE LINE IS OPEN, THE NUMBER OF MESSAGES ON THE QUEUE          * 08100020
*   (QCBMSGCT) IS OBTAINED, CONVERTED TO A PRINTABLE NUMBER, AND      * 08400020
*   PLACED IN A RESPONSE MESSAGE ALONG WITH THE TERMINAL NAME.  THE   * 08700020
*   STATUS FIELD (QCBSTAT) IS ACCESSED AND ITS VALUES CONVERTED TO    * 09000020
*   THEIR PRINTABLE EQUIVALENTS AND PLACED IN THE RESPONSE.  IF NO    * 09300020
*   BITS ARE ON, THIS INDICATION IS PLACED IN THE MESSAGE.            * 09600020
*                                                                     * 09900020
*   THE FIRST PRIORITY QCB ASSOCIATED WITH THE MASTER QCB IS          * 10200020
*   OBTAINED AND ITS PRIORITY CONVERTED TO A PRINTABLE NUMBER.  IF    * 10500020
*   THERE ARE MORE PRIORITY QCBS, EACH PRIORITY IS PLACED IN THE      * 10800020
*   RESPONSE.  THE ROUTINE THEN EXITS TO THE CONTROL MODULE.          * 11100020
*                                                                     * 11400020
*ENTRY POINTS --                                                      * 11700020
*        'IEDQCJ' TO PROCESS DISPLAY QUEUE OPERATOR CONTROL           * 12000020
*   COMMANDS.  CALLING SEQUENCE IS                                    * 12300020
*                        LOAD EPLOC=LOADPRFX                          * 12600020
*                        LR   R1,ROPC                                 * 12900020
*                        LR   R15,R0                                  * 13200020
*                        BALR R14,R15                                 * 13500020
*                                                                     * 13800020
*INPUT -- REGISTER 1 - ADDRESS OF THE OPERATOR CONTROL AVT.  IN       * 14100020
*   THIS BLOCK AT THE TAG OPCTNME IS THE NAME OF THE TERMINAL WHOSE   * 14400020
*   QCB VALUES ARE TO BE DISPLAYED.                                   * 14700020
*                                                                     * 15000020
*   REGISTER 15 - ENTRY POINT ADDRESS.                                * 15300020
*                                                                     * 15600020
*OUTPUT -- REGISTER 1 - ADDRESS OF APPROPRIATE RESPONSE MESSAGE.      * 15900020
*                                                                     * 16200020
*   REGISTER 15 - RETURN CODE.  VALUES ARE                            * 16500020
*                   0    IF FIELDS DISPLAYED.                         * 16800020
*                   4    IF TERMINAL CANNOT BE FOUND, LINE IS NOT     * 17100020
*                        OPEN, OR LINE IS OPENED DD DUMMY.            * 17400020
*                                                                     * 17700020
*EXTERNAL ROUTINES -- N/A.                                            * 18000020
*                                                                     * 18300020
*EXITS-NORMAL -- COMMAND IS PROCESSED.  A RESPONSE MESSAGE IS         * 18600020
*   CONSTRUCTED AND ITS ADDRESS IS RETURNED TO THE CALLER.            * 18900020
*                                                                     * 19200020
*EXITS-ERROR -- TERMINAL REQUESTED NOT IN TERMNAME TABLE.  NOT        * 19500020
*   FOUND MESSAGE BUILT, X'04' RETURN CODE SET.                       * 19800020
*                                                                     * 20100020
*   LINE FOR TERMINAL NOT OPEN OR OPENED DD DUMMY.  NOT OPEN          * 20400020
*   MESSAGE BUILT, X'04' RETURN CODE SET.                             * 20700020
*                                                                     * 21000020
*TABLES/WORK AREAS -- MESSAGES, STATUS CONVERSION TABLE, QCB, AVT,    * 21300020
*   DCB, DEB, TERMNAME TABLE, TERMINAL ENTRY, OPERATOR CONTROL AVT.   * 21600020
*                                                                     * 21900020
*ATTRIBUTES -- SERIALLY REUSABLE, REFRESHABLE, ENABLED, TRANSIENT,    * 22200020
*   PROBLEM PROGRAM MODE.                                             * 22500020
*                                                                     * 22800020
*NOTES -- THE OPERATION OF THIS MODULE DEPENDS UPON AN INTERNAL       * 23100020
*   REPRESENTATION OF THE EXTERNAL CHARACTER SET WHICH IS             * 23400020
*   EQUIVALENT TO THE ONE USED AT ASSEMBLY TIME.  THE CODING HAS      * 23700020
*   BEEN ARRANGED SO THAT REDEFINITION OF ''CHARACTER'' CONSTANTS,    * 24000020
*   BY REASSEMBLY, WILL RESULT IN A CORRECT MODULE FOR THE NEW        * 24300020
*   DEFINITIONS.                                                      * 24600020
*                                                                     * 24900020
*   MESSAGES ISSUED BY THIS MODULE ARE                                * 25200020
*              IED016I, IED031I, IED091I                              * 25500020
*                                                                     * 25800020
*********************************************************************** 26100020
*                                                                       26400020
*                                                                       26700020
R1       EQU   1                        PARAMETER                       27000020
ROPC     EQU   2                        OPERATOR CONTROL AVT BASE       27300020
RCIB     EQU   3                        INPUT UNIT BASE                 27600020
RAVT     EQU   4                        AVT BASE                        27900020
RTNT     EQU   5                        TERMNAME TABLE BASE             28200020
RTERM    EQU   6                        TERMINAL ENTRY BASE             28500020
RQCB     EQU   7                        QCB BASE                        28800020
RWORK    EQU   8                        WORK                            29100020
RWORK2   EQU   9                        WORK                            29400020
RWORK3   EQU   10                       WORK                            29700020
RDCB     EQU   11                       DCB BASE                        30000020
RBASE    EQU   12                       ROUTINE BASE                    30300020
R13      EQU   13                       SAVE AREA                       30600020
R14      EQU   14                       RETURN                          30900020
R15      EQU   15                       ENTRY                           31200020
         USING IEDQCJ,RBASE             ADDRESSABILITY FOR RTN          31500020
         USING IEDQAVTD,RAVT            ADDRESSABILITY FOR AVT          31800020
         USING IEDQOPC,ROPC             ADDRESSABILITY FOR OP CTL       32100020
         USING IEDQTNTD,RTNT            ADDRESSABILITY FOR TNT          32400020
         USING IEDQTRM,RTERM            ADDRESSABILITY FOR TERM         32700020
         USING IEDQQCB,RQCB             ADDRESSABILITY FOR QCB          33000020
         USING IHADCB,RDCB              ADDRESSABILITY FOR DCB          33300020
         SAVE  (14,12),,IEDQCJ-01/21/72                          S22026 33600022
         LR    RBASE,R15                GET BASE                        33900020
         LR    ROPC,R1                  GET OP CTL AVT                  34200020
         L     RAVT,OPCAVTAD            ACCESS AVT                      34500020
         L     RCIB,OPCINPUT            ACCESS BUFFER OR CIB            34800020
         L     RTNT,AVTRNMPT            GET TNT ADDRESS                 35100020
         LA    RWORK2,OPCONE            SET OFFSET COUNTER              35400020
         LH    RWORK3,TNTLEN            GET NUMBER OF ENTRIES           35700020
         SR    RTERM,RTERM              CLEAR                           36000020
         IC    RTERM,TNTENLEN           GET COMPARE LENGTH              36300020
         BCTR  RTERM,0                  DECREMENT FOR EXECUTE           36600020
         CH    RTERM,AVTHA7           EIGHT BYTE TERMNAME               36640020
         BE    HTRMOK                   YES, VALID LENGTH               36680020
         LA    R15,OPCTNME+1(RTERM)     PTR TO FIRST BLANK              36720020
        CLI   OPCZERO(R15),AVTEBLNK     IS IT A BLANK                   36760020
         BNE   ERROR                    NO, ERROR                       36800020
HTRMOK   EQU   *                                                        36840020
         LA    RTNT,TNTFIRST            ADDR FIRST TERMNAME             36900020
LOOPTNT  EQU   *                                                        37200020
         CR    RWORK2,RWORK3            END OF TABLE                    37500020
         BH    ERROR                    YES - ERROR                     37800020
*                                                                       38100020
         EX    RTERM,COMP               ENTRY FOUND                     38400020
         BE    FOUND                    YES - PROCESS IT                38700020
*                                                                       39000020
         LA    RTNT,OPCFOUR(RTERM,RTNT) BUMP TO NEXT ENTRY              39300020
         LA    RWORK2,OPCONE(,RWORK2)   BUMP COUNTER                    39600020
         B     LOOPTNT                  CHECK NEXT ENTRY                39900020
*                                                                       40200020
ERROR    EQU   *                                                        40500020
         MVC   BADMSG(OPCEIGHT),OPCTNME PUT NAME IN MSG                 40800020
         LA    RWORK,BAD                GET MSG ADDR                    41100020
SETRET   EQU   *                                                        41400020
         LA    R15,OPCFOUR              BAD RETURN CODE                 41700020
         B     EXIT                     RETURN IN ERROR          S22025 42000022
*                                                                       42300020
FOUND    EQU   *                                                        42600020
         AR    RTNT,RTERM               BUMP PAST DATA                  42900020
         MVC   OPCWORK+1(OPCTHREE),OPCONE(RTNT) PUT ON BDRY             43200020
         L     RTERM,OPCWORK            GET TERMINAL ENTRY              43500020
         MVC   GOOD+12(OPCEIGHT),OPCTNME PUT NAME IN MSG                43800020
         TM    TRMSTATE,DIST             DISTRIBUTION OR CASCADE        43900020
         BNZ   PE                        YES, REJECT COMMAND            44000020
         L     RQCB,TRMDESTQ-1          GET QCB ADDR                    44100020
         SR    RWORK,RWORK              SET MSGCNT TO ZERO       S22026 45000022
         TM    QCBDSFLG,QCBDRQQ         DATA READY QUEUE         S22026 45900022
         BO    DRQ                      YES, BRANCH              S22026 46800022
TQ0      EQU   *                                                        47800020
*                                                                       48000020
         LH    RWORK,QCBMSGCT           GET NUMBER OF MSGS ON Q         48300020
         N     RWORK,AVTCLRHI            CLEAR HIGH HALF                48400020
DRQ      EQU   *                                                 S22026 48500022
         CVD   RWORK,OPCDOUBL           CONVERT IT TO PACKED DEC        48600020
        UNPK  OPCDOUBL(OPCFIVE),OPCDOUBL+5(OPCTHREE)  MAKE ZONED        48900020
         OI    OPCDOUBL+4,ZONE          SET ZONE FOR PRINTING           49200020
         MVC   SIZE(OPCFIVE),OPCDOUBL   STORE ON MESSAGE                49400020
         TM    QCBFLAG,QCBTSSES          TSO IN SESSION                 49420020
         BO    NOFLG                     YES, NO TCAM QUEUING           49440020
         TM    QCBDSFLG,HEX70            ANY Q TYPE FLAGS               49460020
         BZ    NOFLG                     NO, SAY SO                     49520020
         TM    QCBDSFLG,QCBREUS         REUSABLE DISK - OR BACKUP       49600020
         BZ    TQ1                      NO                              49800020
         MVI   BUFFTYP+1,R              YES, SET FOR REUSEABLE OR BACE  50000020
TQ1      EQU   *                                                        50200020
         TM    QCBDSFLG,QCBNREUS        NON REUSEABLE DISK              50400020
         BZ    TQ2                      NO                              50600020
         MVI   BUFFTYP+1,N              YES, SET REUSABLE               50800020
TQ2      EQU   *                                                        51000020
         TM    QCBDSFLG,QCBCORE         CORE                            51200020
         BO    TQ3                      YES                             51400020
         MVI   BUFFTYP,D                DISK QUEUING                    51600020
TQ3      EQU   *                                                        51800020
**********                                                              52000020
*          REG  USAGE                                                   52200020
*   R14        LINK                                                     52400020
*   RWORK      ADDRESS OFF ENTRY IN MESSAGE                             52600020
*   RWORK2     ADDRESS OF ENTRY                                         52800020
*   RWORK3     LENGTH OF MESSAGE                                        53000020
***********                                                             53200020
         MVC   OPCDOUBL+6(OPCONE),QCBSTAT  SAVE STAT BYTE               53400020
         MVC   OPCDOUBL+7(OPCONE),QCBFLAG   >AVE FLAG BYTE              53600020
         LH    RWORK3,GOOD              LENGTH OF MESSAGE TO HERE       53800020
         LA    RWORK,GOODMSG             GET AT FIRST ENTRY - LENGTH    53870020
         LA    RWORK2,DELAY-6            SET FOR FORST ENTRY            53940020
         TM    OPCDOUBL+6,QCBDELAY      IN DELAY QUEUE                  54400020
         BAL   R14,MOVENT               IF SO, MOVE IN MESSAGE          54600020
         TM    OPCDOUBL+6,QCBBUFRD       IS A BUFFERED TERMINAL         54800020
         BAL   R14,MOVENT               IF SO, MOVE IN MESSAGE          55000020
         TM    OPCDOUBL+6,QCBSEND        BUFFERED - SENDING             55200020
         BAL   R14,MOVENT               IF SO, MOVE IN MESSAGE          55400020
         TM    OPCDOUBL+6,QCBTIME        DELAY GREATER THAN 12 HR       55600020
         BAL   R14,MOVENT               IF SO, MOVE IN MESSAGE          55800020
         TM    OPCDOUBL+7,QCBTSSES        TSO IN SESSION                56000020
         BAL   R14,MOVENT               IF SO, MOVE IN MESSAGE          56200020
         TM    OPCDOUBL+7,QCBREAD        READ HAS PRIORITY              56400020
         BAL   R14,MOVENT               IF SO, MOVE IN MESSAGE          56600020
         CLI   GOODMSG,N                 ANY BITS ON                    56630020
         BNE   MVC1                      YES, GO ON                     56660020
         LA    RWORK,OPCSEVEN(RWORK)     GET TO END OF 'NONEON'         56690020
         LA    RWORK3,OPCSEVEN(RWORK3)    RESET LENGTH                  56720020
MVC1     EQU   *                                                        56750020
         MVC   OPCZERO(OPCTEN,RWORK),PRIORITY  SET UP FOR PRIORITY      56800020
         LA    RWORK,10(RWORK)           PAST PRIORITY                  57000020
         LA    RWORK3,10(RWORK3)         INCREASE LENTH                 57200020
         SPACE 2                                                        57400020
         SR    R14,R14                   HOUSEKEEP                      57600020
         LA    RWORK2,PRISIZE           SIZE OF PRIORITY QCB            57800020
         LA    R1,IEDQPQCB              ADDR OF 1ST PRIORITY QCB        58000020
         SPACE 2                                                        58200020
PRILOOP  EQU   *                                                        58400020
         IC    R14,PRILEV(R1)            GET PRIORITY LEVEL             58600020
         CVD   R14,OPCDOUBL             CONVERT TO DECIMAL              58800020
         UNPK  OPCDOUBL(OPCTHREE),OPCDOUBL+6(OPCTWO)    MAKE ZONED      59000020
         MVC   OPCZERO(OPCTHREE,RWORK),OPCDOUBL  PUT IN MESSAGE         59200020
         OI    OPCTWO(RWORK),ZONE       ZONE FOR PRINTING               59400020
         LA    RWORK,OPCFOUR(RWORK)     BUMP MESSAGE ADDR               59600020
         LA    RWORK3,OPCFOUR(RWORK3)   BUMP MESSAGE LENGTH             59800020
         CLI   PRILEV(R1),OPCZERO        LAST PRIORITY QCB              60000020
         BE    PEND                     YES, EXIT                       60200020
         AR    R1,RWORK2                NO, SET NEXT QCB                60400020
         CH    RWORK3,MAXMSG            OPT OF MESSAGE SPAS             60600020
         BH    PEND                     YES, QUIT                       60800020
         B     PRILOOP                  GET NEXT                        61000020
NOFLG    MVI   BUFFTYP,N                SET 'NO' IN MESSAGE FOR  S22025 61010022
         B     TQ3                      QUEUE TYPE. BRANCH BACK  S22025 61020022
MOVENT   EQU   *                                                        61050020
         LA    RWORK2,OPCSIX(RWORK2)  NEXT ENTRY TO PUT                 61060020
         BCR   8,R14                      BIT NOT ON REUTRN             61070020
         MVC   OPCZERO(OPCSIX,RWORK),OPCZERO(RWORK2) MOVE ENTRY IN MSG  61080020
         LA    RWORK,OPCSEVEN(RWORK)     GET OO NEXT ENTRY              61090020
         LA    RWORK3,OPCSEVEN(RWORK3)    BUMP MSG LENGTH               61100020
         BR    R14                       RETURN                         61110020
PEND     EQU   *                                                        61200020
         MVC   OPCZERO(OPCFOUR,RWORK),DESCR4 MOVE IN DESCR,ROUT CODES   61300020
         LA    RWORK,GOOD               GET M%SSAGE ADDRESS             61400020
         STH   RWORK3,GOOD              RESET LENGTH                    61600020
GOODRET  EQU   *                                                        67500020
         SR    R15,R15                  GOOD RETURN CODE                67800020
EXIT     EQU   *                                                        68100020
         ST    RWORK,OPCREG1(,R13)      PUT ADDRESS OF MESSAGE   S22025 68300022
*                                       IN USERS REG 1           S22025 68500022
         RETURN (14,12),T,RC=(15)                                       68700020
*                                                                       69000020
PE       EQU   *                                                        69060020
         MVC   PEMSG(OPCEIGHT),OPCTNME   SET UP NAME                    69120020
         LA    RWORK,PEM                 GET ERROR MESSAGE ADDRESS      69180020
         B     SETRET                    SET BAD RETURN CODE            69240020
A        EQU   C'A'                                                     69300020
PRILEV   EQU   X'18'                                                    69600020
PRISIZE  EQU   X'1C'                                                    69900020
ZONE     EQU   X'30'                                                    70200020
COMP     CLC   OPCZERO(OPCONE,RTNT),OPCTNME                             70500020
*                                       WORDS PLACED IN GOOD MSG S22025 70508022
DELAY    DC    C'DELAY '                IN DELAY QUEUE           S22025 70516022
         DC    C'BUFFRD'                BUFFERED TERMINAL        S22025 70524022
         DC    C'SNDBUF'                BUFFERED-SENDING         S22025 70532022
         DC    C'TWELVE'                DELAY > 12 HOURS         S22025 70540022
         DC    C'TSOSES'                TSO IN SESSION           S22025 70548022
         DC    C'RDPRIO'                READ HAS PRIORITY        S22025 70556022
PRIORITY DC    C' PRIORITY='            PRIORITY OF QCB          S22025 70564022
R        EQU   C'R'                                                     70580020
N        EQU   C'N'                                                     70590020
HEX70    EQU   X'70'                                                    70595020
D        EQU   C'D'                                                     70600020
PROC     EQU   X'20'                                                    70603020
DIST     EQU   X'40'                                                    70606020
GOOD     DS    0H                                                       70609020
         DC    AL2(DESCR5-*),X'6000'     LENGTH,MCSFLGS-INREG0-IMMRSP   70612020
         DC    C'IED031I ',9C' ',C'SIZE='  MSG NO. AND TERMNAME  S22025 70622022
SIZE     DC    5C' '                    NO. OF MESSAGES ON QUEUE S22025 70632022
         DC    C' QUEUETYP='            POSSIBILITIES ARE DR,DN, S22025 70642022
BUFFTYP  DC    C'MO'                    MO,MR,MN, OR NO FOR QTYPES22025 70652022
         DC    C' STATUS='              POSSIBILITIES FOR STATUS S22025 70662022
DESCR5   EQU   *                        ARE LISTED UNDER 'DELAY' S22025 70672022
GOODMSG  DC    C'NONEON '               PLUS NO STATUS BITS ON.  S22025 70682022
         DC    400C' '                  MSG OF PRIORITY QCBS     S22025 70692022
DESCR1   DC    X'0800'                   DESCRIPTOR - IMMEDIATE RESP    70770020
         DC    X'0000'                   ROUTING - IN REG 0             70870020
MAXMSG   DS    0H                                                       70970020
         DC    AL2(DESCR1-GOOD)         LENGTH OF MESSAGE        S22025 71070022
BAD      DS    0H                                                       71170020
         DC    AL2(DESCR2-*),X'6000'     LENGTH,MCSFLGS-INREG0-IMMRSP   71270020
         DC    C'IED016I STATION '      ERROR MESSAGE CONTAINING S22025 71370022
BADMSG   DC    8C' ',C' NOT FOUND'      TERMNAME SPECIFIED       S22025 71470022
DESCR2   DC    X'0800'                   DESCRIPTOR - IMMEDIATE RESP    71570020
         DC    X'0000'                   ROUTING - IN REG 0             71670020
PEM      DS    0H                                                       72370020
         DC    AL2(DESCR4-*),X'6000'     LENGTH,MCSFLGS-INREG0-IMMRSP   72470020
         DC    C'IED090I '              ERROR MESSAGE CONTAINING S22025 72570022
PEMSG    DC    8C' ',C' IS NOT SINGLE ENTRY'  TERMNAME           S22025 72670022
DESCR4   DC    X'0800'                   DESCRIPTOR - IMMEDIATE RESP    72770020
         DC    X'0000'                   ROUTING - IN REG 0             72870020
         TOPCD                                                          73800020
         TQCBD                                                          74100020
         TAVTD                                                          74400020
         TTNTD                                                          74700020
         TTRMD                                                          75000020
         DCBD  DSORG=TX                                                 75300020
         TDEBD                                                          75600020
         END                                                            75900020
