         TITLE '''IEDQCK'' - DISPLAY INTERCEPTED'                       00500020
IEDQCK   CSECT                                                          01000020
*********************************************************************** 01500020
*                                                                     * 02000020
*TITLE 'IEDQCK' TO PROCESS DISPLAY INTER OPERATOR CONTROL COMMANDS    * 02500020
*                                                                     * 03000020
*STATUS -- CHANGE LEVEL 0                                             * 03500020
*                                                                     * 04000020
*FUNCTION -- THIS ROUTINE PROCESSES OPERATOR CONTROL COMMANDS WHICH   * 04500020
*   REQUEST DISPLAY OF THE LIST OF TERMINALS WHICH ARE CURRENTLY      * 05000020
*   BEING HELD.                                                       * 05500020
*                                                                     * 06000020
*   THE COPY HELD TERMINALS ROUTINE GETS THE ADDRESS OF THE           * 06500020
*   TERMINAL NAME TABLE FROM THE AVT AND STEPS THROUGH IT TO TEST     * 07000020
*   EACH ENTRY TO DETERMINE WHETHER IT IS BEING HELD (INTERCEPTED).   * 07500020
*   IF IT IS A PROCESS ENTRY (X'20' ON IN TRMSTATE) IT CANNOT BE      * 08000020
*   HELD.  IF AN ENTRY IS BEING HELD, THE ROUTINE SETS A BIT TO       * 08500020
*   INDICATE AN ENTRY FOUND AND PLACES THE NAME OF THE ENTRY IN THE   * 09000020
*   RESPONSE MESSAGE.  WHEN THE END OF THE TERMNAME TABLE IS          * 09500020
*   REACHED, THE BIT IS TESTED TO DETERMINE WHETHER ANY ENTRIES       * 10000020
*   WERE HELD.  IF NO ENTRIES ARE HELD, THE ROUTINE RETURNS A         * 10500020
*   RESPONSE MESSAGE INDICATING THIS TO THE CONTROL MODULE.  IF THE   * 11000020
*   BIT IS ON, IT IS TURNED OFF AND THE GOOD RESPONSE MESSAGE IS      * 11500020
*   RETURNED TO THE CONTROL MODULE.                                   * 12000020
*                                                                     * 12500020
*ENTRY POINTS --                                                      * 13000020
*        'IEDQCK' TO PROCESS DISPLAY INTER COMMANDS.  CALLING         * 13500020
*   SEQUENCE IS                                                       * 14000020
*                        LOAD EPLOC=LOADPRFX                          * 14500020
*                        LR   R1,ROPC                                 * 15000020
*                        LR   R15,R0                                  * 15500020
*                        BALR R14,R15                                 * 16000020
*                                                                     * 16500020
*INPUT -- REGISTER 1 - ADDRESS OF OPERATOR CONTROL AVT.               * 17000020
*                                                                     * 17500020
*   REGISTER 15 - ENTRY POINT ADDRESS.                                * 18000020
*                                                                     * 18500020
*OUTPUT -- REGISTER 1 - ADDRESS OF APPROPRIATE RESPONSE MESSAGE.      * 19000020
*                                                                     * 19500020
*EXTERNAL ROUTINES -- N/A.                                            * 20000020
*                                                                     * 20500020
*EXITS-NORMAL -- COMMAND IS PROCESSED.  A RESPONSE MESSAGE EITHER     * 21000020
*   INDICATING NO HELD ENTRIES OR CONTAINING A LIST OF HELD ENTRIES   * 21500020
*   IS CONSTRUCTED AND ITS ADDRESS RETURNED TO THE CALLING ROUTINE.   * 22000020
*                                                                     * 22500020
*EXITS-ERROR -- N/A.                                                  * 23000020
*                                                                     * 23500020
*TABLES/WORK AREAS -- MESSAGES, AVT, TERMNAME TABLE, TERMINAL         * 24000020
*   ENTRY, OPERATOR CONTROL AVT.                                      * 24500020
*                                                                     * 25000020
*ATTRIBUTES -- SERIALLY REUSABLE, REFRESHABLE, ENABLED, TRANSIENT,    * 25500020
*   PROBLEM PROGRAM MODE.                                             * 26000020
*                                                                     * 26500020
*NOTES -- THE OPERATION OF THIS MODULE DEPENDS UPON AN INTERNAL       * 27000020
*   REPRESENTATION OF THE EXTERNAL CHARACTER SET WHICH IS             * 27500020
*   EQUIVALENT TO THE ONE USED AT ASSEMBLY TIME.  THE CODING HAS      * 28000020
*   BEEN ARRANGED SO THAT REDEFINITION OF ''CHARACTER'' CONSTANTS,    * 28500020
*   BY REASSEMBLY, WILL RESULT IN A CORRECT MODULE FOR THE NEW        * 29000020
*   DEFINITIONS.                                                      * 29500020
*                                                                     * 30000020
*   MESSAGES ISSUED BY THIS MODULE ARE                                * 30500020
*              IED039I, IED040I                                       * 31000020
*                                                                     * 31500020
*********************************************************************** 32000020
*                                                                       32500020
*                                                                       33000020
R0       EQU   0                                                        33500020
R1       EQU   1                        PARAMETER                       34000020
ROPC     EQU   2                        OPERATOR CONTROL AVT BASE       34500020
RADDR    EQU   3                        WORK                            35000020
RAVT     EQU   4                        AVT BASE                        35500020
RTNT     EQU   5                        TERMNAME TABLE BASE             36000020
RMSG     EQU   6                        MESSAGE BUILDING BASE           36500020
RWORK    EQU   7                        WORK                            37000020
RWORK2   EQU   8                        WORK                            37500020
RWORK3   EQU   9                        WORK                            38000020
RTERM    EQU   10                       TERM ENTRY BASE                 38500020
RCTR     EQU   11                       COUNTER                         39000020
RBASE    EQU   12                       ROUTINE BASE                    39500020
R13      EQU   13                       SAVE AREA                       40000020
R14      EQU   14                       RETURN                          40500020
R15      EQU   15                       ENTRY POINT                     41000020
         USING IEDQCK,RBASE             ADDRESSABILITY FOR ROUTINE      41500020
         USING IEDQAVTD,RAVT            ADDRESSABILITY FOR AVT          42000020
         USING IEDQOPC,ROPC             ADDRESSABILITY FOR OP CTL       42500020
         USING IEDQTNTD,RTNT            ADDRESSABILITY FOR TNT          43000020
         USING IEDQTRM,RTERM            ADDRESSABILTIY FOR TERM         43500020
         SAVE  (14,12),,IEDQCK-12/13/70                                 44000020
         LR    RBASE,R15                SET UP ROUTINE BASE             44500020
         LR    ROPC,R1                  GET OPERATOR CONTROL AVT        45000020
         L     RAVT,OPCAVTAD            GET AVT                         45500020
         LA    R1,T9                    SET COMPARE VALUE               46000020
         LA    RCTR,MSGE                SET MSG END                     46500020
         L     RTNT,AVTRNMPT            GET TERMNAME TABLE              47000020
         LA    RMSG,MSG                 GET MSG START                   47500020
         LA    RWORK,OPCONE             SET UP COUNTER                  48000020
         LH    RWORK2,TNTLEN            GET NUMBER OF TERMINALS         48500020
         SR    RWORK3,RWORK3            CLEAR                           49000020
         IC    RWORK3,TNTENLEN          GET ENTRY LENGTH                49500020
         BCTR  RWORK3,R0                DECREMENT FOR EXECUTE           50000020
         LA    RTNT,TNTFIRST            GET TO FIRST ENTRY              50500020
         LA    RADDR,OPCTWO             SET COUNTER                     51000020
LOOP     EQU   *                                                        51500020
         CR    RWORK,RWORK2             END OF TABLE                    52000020
         BH    EXITCODE                YES - COMPLETE MESSAGE           52500020
*                                                                       53000020
         LR    RTERM,RTNT               SET WORK REG                    53500020
         AR    RTERM,RWORK3             GET TO ADDRESS                  54000020
         MVC   OPCWORK+1(OPCTHREE),OPCONE(RTERM) PUT ON BDRY            54500020
         L     RTERM,OPCWORK            GET TERM ADDR                   55000020
         TM    TRMSTATE,PROCN           PROCESS ENTRY                   55500020
         BO    BUMP                     YES - CANNOT BE HELD            56000020
*                                                                       56500020
         TM    TRMSTATE,TRMHELDN        TERMINAL INTERCEPTED            57000020
         BNO   BUMP                     NO - BUMP TO NEXT ENTRY         57500020
*                                                                       58000020
         OI    OPCBITSW,OPCTEMPN        TURN ON ENTRY-FOUND SWITCH      58500020
         EX    RWORK3,MOVE              MOVE NAME TO MSG                59000020
         CR    RMSG,RCTR                ENC OF MSG                      59500020
         BNL   FULLMSG                   YES SEND OUT WHAT HAVE         60000020
*                                                                       60500020
         LA    RWORK3,OPCTWO(RWORK3)    INCREMENT FOR BLANK             61000020
         AR    RMSG,RWORK3              ADD TO MSG OFFSET               61500020
         AR    R1,RWORK3                ADD TO MSG LENGTH               62000020
         SR    RWORK3,RADDR             DECREMENT BACK FOR LOOP         62500020
BUMP     EQU   *                                                        63000020
         LA    RTNT,OPCFOUR(,RTNT)      BUMP PAST ADDRESS               63500020
         AR    RTNT,RWORK3              BUMP PAST ENTRY                 64000020
         LA    RWORK,OPCONE(,RWORK)     INCREMENT COUNTER               64500020
         B     LOOP                                                     65000020
*                                                                       65500020
EXITCODE EQU   *                                                        66000020
         TM    OPCBITSW,OPCTEMPN        ANY ENTRIES                     66500020
         BO    FULLMSG                  YES                             67000020
*                                                                       67500020
         LA    RWORK,NOMSG              PICK UP NO ENTRY MSG ADDR       68000020
EXIT     EQU   *                                                        68500020
         SR    R15,R15                  SET GOOD RETURN                 69000020
         ST    RWORK,OPCREG1(,R13)      PUT IN SAVE AREA                69500020
         RETURN (14,12),T,RC=(15)                                       70000020
*                                                                       70500020
*                                                                       73000020
FULLMSG  EQU   *                                                        73500020
         MVC   OPCZERO(OPCFOUR,RMSG),ROUTE    SET UP ROUTE CODE         74500020
         NI    OPCBITSW,OPCTEMPF        TURN OFF TEMPORARY BIT          76000020
         STH   R1,GOODMSG               PUT LENGTH IN MSG               76500020
         LA    RWORK,GOODMSG            PICK UP MSG ADDRESS             77000020
         B     EXIT                                                     77500020
*                                                                       78000020
T9       EQU   33                                                       87500020
PROCN    EQU   X'20'                                                    88500020
MOVE     MVC   OPCZERO(OPCONE,RMSG),OPCZERO(RTNT)                       89500020
NOMSG    DS    0H                                                       89600020
         DC    AL2(DESCR1-*),X'6000'     LENGTH,MCSFLGS-INREG0-IMMRSP   89700020
         DC    C'IED039I NO STATIONS INTERCEPTED'                       89800020
ROUTE    EQU   *                                                        89900020
DESCR1   DC    X'0800'                   DESCRIPTOR - IMMEDIATE RESP    90000020
         DC    X'0000'                   ROUTING - IN REG 0             90100020
GOODMSG  DS    0H                                                       90200020
         DC    AL2(DESCR2-*),X'6000'     LENGTH,MCSFLGS-INREG0-IMMRSP   90300020
         DC    C'IED040I INTERCEPTED STATIONS='                         90400020
MSG      DC    97C' '                                                   90500020
         DC    500C' '                                                  90600020
DESCR2   DC    X'0800'                   DESCRIPTOR - IMMEDIATE RESP    90700020
         DC    X'0000'                   ROUTING - IN REG 0             90800020
MSGE     EQU   *-5                                                      92000020
         DC    10C' '                                                   93000020
         PRINT NOGEN                                                    94000020
         TOPCD                                                          94500020
         TTNTD                                                          95000020
         TTRMD                                                          95500020
         TAVTD                                                          96000020
*                                                                       96500020
         END                                                            97000020
