         TITLE '''IEDQCL'' - DISPLAY LIST ENTRIES'                      00200020
IEDQCL   CSECT                                                          00400020
*********************************************************************** 00600020
*                                                                     * 00800020
*TITLE 'IEDQCL' PROCESSOR OF DISPLAY ACT AND DISPLAY INACT COMMANDS   * 01000020
*                                                                     * 01200020
*STATUS -- CHANGE LEVEL 0                                             * 01400020
*                                                                     * 01600020
*FUNCTION -- THIS ROUTINE PROCESSES OPERATOR CONTROL COMMANDS WHICH   * 01800020
*   REQUEST DISPLAY OF A LIST OF EITHER ACTIVE OR INACTIVE            * 02000020
*   TERMINALS FOR A GIVEN LINE.                                       * 02200020
*                                                                     * 02400020
*   THE COPY INVITATION LIST ENTRY ROUTINE DETERMINES WHETHER THE     * 02600020
*   DDNAME/RLN FORMAT OR THE HARDWARE ADDRESS FORMAT IS SPECIFIED     * 02800020
*   IN THE COMMON INPUT BLOCK.  IF IT IS DDNAME/RLN AND THE RLN       * 03000020
*   SPECIFIED IS 'ALL' THE COMMAND IS REJECTED SINCE THIS ROUTINE     * 03200020
*   DISPLAYS DATA ONLY FOR A SINGLE LINE.  IF THE RLN IS NOT ALL,     * 03400020
*   IT IS CONVERTED TO A HEXADECIMAL VALUE.  IF THIS RESULTING        * 03600020
*   VALUE IS ZERO OR IS GREATER THAN 255, THE COMMAND IS REJECTED     * 03800020
*   DUE TO INCORRECTLY SPECIFIED RLN AND THE ROUTINE EXITS TO THE     * 04000020
*   CONTROL MODULE.  IF THE RLN IS VALID, THE TCB ADDRESS IS          * 04200020
*   OBTAINED FROM THE AVT AND THE TIOT (AT TCB+12) IS SERIALLY        * 04400020
*   SEARCHED FOR A DDNAME MATCHING THAT SPECIFIED.  IF NO MATCH IS    * 04600020
*   FOUND, AN ERROR MESSAGE IS BUILT AND CONTROL RETURNS TO THE       * 04800020
*   CONTROL MODULE.  WHEN THE DDNAME IS FOUND, ITS OFFSET INTO THE    * 05000020
*   TIOT IS SAVED.                                                    * 05200020
*                                                                     * 05400020
*   FOR BOTH INPUT FORMATS, THE START OF THE DEB CHAIN IS OBTAINED    * 05600020
*   FROM THE TCB (TCB+8).  THE DCB FOR EACH DEB IS TESTED TO SEE IF   * 05800020
*   IT IS A TCAM LINE DCB (DSORG OF X'40') AND IF NOT THE NEXT DEB    * 06000020
*   IS ACCESSED FROM DEBDEBAD.  IF THE END OF THE DEB CHAIN IS        * 06200020
*   REACHED BEFORE A VALID DCB IS FOUND, AN ERROR MESSAGE IS BUILT    * 06400020
*   AND CONTROL RETURNS TO THE CONTROL MODULE.                        * 06600020
*                                                                     * 06800020
*   IF THE COMMAND WAS SPECIFIED IN DDNAME/RLN FORMAT, THE OFFSET     * 07000020
*   INTO THE TIOT (DCBTIOT) IS COMPARED TO THAT COMPUTED ABOVE. IF    * 07200020
*   THEY ARE NOT EQUAL, THE NEXT DEB IS OBTAINED AND TESTED AS        * 07400020
*   ABOVE.  WHEN THE PROPER DCB IS OBTAINED, THE UCB ADDRESS IN THE   * 07600020
*   DEB (DEBUCBAD) IS TESTED FOR ZERO, IMPLYING LINE OPENED DD        * 07800020
*   DUMMY.  IF SO, AN ERROR MESSAGE IS BUILT AND CONTROL RETURNS TO   * 08000020
*   THE CONTROL MODULE.  IF THE COMPUTED RLN IS GREATER THAN THE      * 08200020
*   NUMBER OF LINES IN THE LINE GROUP (DEBNMEXT) THE COMMAND IS       * 08400020
*   REJECTED AND CONTROL EXITS TO THE CONTROL MODULE.                 * 08600020
*                                                                     * 08800020
*   IF THE HARDWARE ADDRESS FORMAT IS SPECIFIED, THE UCBS             * 09000020
*   ASSOCIATED WITH THE DEB ARE COMPARED TO THE INPUT ADDRESS.  THE   * 09200020
*   DEB CHAIN IS TESTED AS ABOVE UNTIL A MATCH IS FOUND.              * 09400020
*                                                                     * 09600020
*   WHEN THE PROPER DCB HAS BEEN OBTAINED FOR EITHER FORMAT, IT IS    * 09800020
*   TESTED FOR AN OPEN CONDITION.  IF IT IS NOT OPEN, AN ERROR        * 10000020
*   MESSAGE IS BUILT AND THE ROUTINE EXITS TO THE CONTROL MODULE.     * 10200020
*   OTHERWISE THE INVITATION LIST ADDRESS IS OBTAINED FROM DCBINVLI   * 10400020
*   AND IS SERIALLY SEARCHED FOR EACH ACTIVE OR INACTIVE ENTRY IN     * 10600020
*   THE LIST.  THE TERMNAME FOR EACH APPROPRIATE ENTRY IS OBTAINED    * 10800020
*   FROM THE TERMNAME TABLE AND PLACED IN A RESPONSE MESSAGE.  WHEN   * 11000020
*   THE END OF THE LIST IS REACHED, THE LINE NAME IS PLACED IN THE    * 11200020
*   RESPONSE AND THE ROUTINE EXITS TO THE CONTROL MODULE.             * 11400020
*                                                                     * 11600020
*ENTRY POINTS --                                                      * 11800020
*        'IEDQCL' TO PROCESS DISPLAY ACT-INACT COMMANDS.  CALLING     * 12000020
*   SEQUENCE IS                                                       * 12200020
*                        LOAD EPLOC=LOADPRFX                          * 12400020
*                        LR   R1,ROPC                                 * 12600020
*                        LR   R15,R0                                  * 12800020
*                        BALR R14,R15                                 * 13000020
*                                                                     * 13200020
*INPUT -- REGISTER 1 - ADDRESS OF OPERATOR CONTROL AVT.  THE COMMON   * 13400020
*   INPUT BLOCK IS AT THE TAG OPCCKELE.  THE FIELDS USED BY THIS      * 13600020
*   ROUTINE ARE IN THE BLOCK AT                                       * 13800020
*                   +4   OPCLEN    0 IF ALL                           * 14000020
*                                  X'80' IF HARDWARE ADDRESS          * 14200020
*                                  1 - 3 LENGTH OF RLN                * 14400020
*                   +5   OPCRLN    EBCDIC RELATIVE LINE NUMBER        * 14600020
*                   +8   OPCTNME   DDNAME OR LINE ADDRESS             * 14800020
*                   +18  OPCFLG    X'80' IF DISPLAY ACTIVE            * 15000020
*                                  X'40' IF DISPLAY INACTIVE          * 15200020
*                                                                     * 15400020
*   REGISTER 15 - ENTRY POINT ADDRESS.                                * 15600020
*                                                                     * 15800020
*OUTPUT -- REGISTER 1 - ADDRESS OF APPROPRIATE RESPONSE MESSAGE.      * 16000020
*                                                                     * 16200020
*   REGISTER 15 - RETURN CODE.                                        * 16400020
*                   0    IF DISPLAY SUCCESSFUL                        * 16600020
*                   4    IF RLN IS ALL, ZERO OR GREATER THAN 255,     * 16800020
*                        IF RLN IS GREATER THAN NUMBER OF LINES IN    * 17000020
*                        THE GROUP, IF THE LINE IS NOT OPEN OR        * 17200020
*                        OPEN DD DUMMY.                               * 17400020
*                                                                     * 17600020
*EXTERNAL ROUTINES -- N/A.                                            * 17800020
*                                                                     * 18000020
*EXITS-NORMAL -- COMMAND IS PROCESSED.   A RESPONSE MESSAGE IS        * 18200020
*   CONSTRUCTED AND ITS ADDRESS RETURNED TO THE CALLER.               * 18400020
*                                                                     * 18600020
*EXITS-ERROR -- RELATIVE LINE SPECIFIED IS ALL, ZERO, OR GREATER      * 18800020
*   THAN 255.  COMMAND INVALID MESSAGE BUILT, X'04' RETURN CODE       * 19000020
*   SET.                                                              * 19200020
*                                                                     * 19400020
*   RLN IS GREATER THAN THE NUMBER OF LINES IN THE GROUP, LINE IS     * 19600020
*   NOT FOUND SEARCHING THE DEB CHAIN, LINE IS NOT OPEN OR IS OPEN    * 19800020
*   DD DUMMY.  LINE NOT OPEN MESSAGE BUILT, X'04' RETURN CODE SET.    * 20000020
*                                                                     * 20200020
*TABLES/WORK AREAS -- MESSAGES, DEB, DCB, AVT, TERMNAME TABLE,        * 20400020
*   OPERATOR CONTROL AVT.                                             * 20600020
*                                                                     * 20800020
*ATTRIBUTES -- SERIALLY REUSABLE, REFRESHABLE, ENABLED, TRANSIENT,    * 21000020
*   PROBLEM PROGRAM MODE.                                             * 21200020
*                                                                     * 21400020
*NOTES -- THE OPERATION OF THIS MODULE DEPENDS UPON AN INTERNAL       * 21600020
*   REPRESENTATION OF THE EXTERNAL CHARACTER SET WHICH IS             * 21800020
*   EQUIVALENT TO THE ONE USED AT ASSEMBLY TIME.  THE CODING HAS      * 22000020
*   BEEN ARRANGED SO THAT REDEFINITION OF ''CHARACTER'' CONSTANTS,    * 22200020
*   BY REASSEMBLY, WILL RESULT IN A CORRECT MODULE FOR THE NEW        * 22400020
*   DEFINITIONS.                                                      * 22600020
*                                                                     * 22800020
*   MESSAGES ISSUED BY THIS MODULE ARE                                * 23000020
*              IED017I, IED018I, IED036I, IED037I                     * 23200020
*                                                                     * 23400020
**********************************************************************  23600020
*                                                                       23800020
*                                                                       24000020
R0       EQU   0                        WORK                            24200020
R1       EQU   1                        PARAMETER                       24400020
RMSG     EQU   1                        MESSAGE BASE                    24600020
ROPC     EQU   2                        OPERATOR CONTROL AVT BASE       24800020
RWORK2   EQU   3                        WORK                            25000020
RAVT     EQU   4                        AVT BASE                        25200020
RTNT     EQU   4                        TERMNAME TABLE BASE             25400020
RTCB     EQU   5                        TCB BASE                        25600020
RDEB     EQU   5                        DEB BASE                        25800020
RWORK6   EQU   5                        WORK                            26000020
ROFF     EQU   6                        DDNAME OFFSET                   26200020
RRLN     EQU   6                        RLN WORK                        26400020
RDCB     EQU   7                        DCB BASE                        26600020
RDD      EQU   8                        DDNAME                          26800020
RUCB     EQU   8                        UCB BASE                        27000020
RACT     EQU   8                        ACTIVE LIST ENTRIES             27200020
RLIST    EQU   9                        INVITATION LIST WORK START      27400020
RINV     EQU   10                       INVITATION LIST START           27600020
RWORK    EQU   11                       WORK                            27800020
RBASE    EQU   12                       ROUTINE BASE                    28000020
R13      EQU   13                       SAVE AREA                       28200020
RWORK5   EQU   14                       WORK                            28400020
R15      EQU   15                       ENTRY POINT                     28600020
RWORK3   EQU   15                       WORK                            28800020
         USING IEDQOPC,ROPC             ADDRESSABILITY FOR OP CTL       29000020
         USING DEBNMSUB,RDEB            ADDRESSABILITY FOR DEB          29200020
         USING IHADCB,RDCB              ADDRESSABILITY FOR DCB          29400020
         USING IEDQCL,RBASE             ADDRESSABILITY FOR ROUTINE      29600020
         USING IEDQAVTD,RAVT            ADDRESSABILITY FOR AVT          29800020
         SAVE  (14,12),,IEDQCL-03/09/71                                 30000020
         LR    RBASE,R15                SET UP ROUTINE BASE             30200020
         LR    ROPC,R1                  GET OP CTL AVT                  30400020
         L     RAVT,OPCAVTAD            GET AVT                         30600020
         L     RTCB,AVTTCB              GET TCB                         30800020
         TM    OPCLEN,ADCODE             DD OR ADDR                     31000020
         BO    GETLIST                   ADDR GET DCB                   31200020
*                                                                       31400020
         CLI   OPCLEN,AVTEZERO          RLN 'ALL' SPECIFIED             31600020
         BE    COMINV                   YES - REJECT COMMAND            31800020
*                                                                       32000020
         MVC   OPCDOUBL(OPCTHREE),OPCRLN PUT RLN IN WORK RREA           32200020
         SR    R15,R15                  CLEAR                           32400020
         IC    R15,OPCLEN               GET LENGTH OF LEN               32600020
         BCTR  R15,R0                   DECREMENT FOR EXECUTE           32800020
         EX    R15,PACK                 PACK                            33000020
         XC    OPCDOUBL(OPCSIX),OPCDOUBL CLEAR FOR CONVERT              33200020
         CVB   RWORK,OPCDOUBL           CONVERT                         33400020
         CH    RWORK,MAXVAL             RLN > 255                       33600020
         BH    COMINV                   YES - REJECT COMMAND            33800020
*                                                                       34000020
         LTR   RWORK,RWORK              RLN ZERO                        34200020
         BZ    COMINV                   YES - REJECT COMMAND            34400020
*                                                                       34600020
         STC   RWORK,OPCDOUBL           SAVE HEX RLN                    34800020
         L     RDD,TIOT(RTCB)           GET TIOT ADDR                   35000020
         LA    ROFF,STARTOFF            OFFSET TO FIRST DD              35200020
         SR    RWORK,RWORK              CLEAR                           35400020
         LA    RDD,STARTOFF(RDD)        ADDR OF FIRST DD                35600020
LOOP     EQU   *                                                        35800020
         IC    RWORK,OPCZERO(,RDD)      GET LENGTH BYTE                 36000020
         CLI   OPCZERO(RDD),OPCZERO     ANOTHER DD                      36200020
         BE    ERR                      NO -- DDNAME NOT FOUND          36400020
*                                                                       36600020
         CLC   OPCFOUR(OPCEIGHT,RDD),OPCTNME RIGHT DD                   36800020
         BE    GETLIST                  YES - GO GET LIST               37000020
*                                                                       37200020
         AR    ROFF,RWORK               BUMP OFFSET TO NEXT DD          37400020
         AR    RDD,RWORK                BUMP TO NEXT ENTRY              37600020
         B     LOOP                                                     37800020
*                                                                       38000020
COMINV   EQU   *                                                        38200020
         LA    R1,OPCERMSG              GET MSG ADDR                    38400020
SETBAD   EQU   *                                                        38600020
         LA    R15,OPCFOUR              SET BAD RETURN                  38800020
         B     PUTMSG                                                   39000020
*                                                                       39200020
GETLIST  EQU   *                                                        39400020
         L     RDEB,DEB(,RTCB)          GET FIRST DEB                   39600020
GETDCB   EQU   *                                                        39800020
         L     RDCB,DEBDCBAD            GET ITS DCB                     40000020
         TM    DCBDSORG+1,TX            TCAM LINE                       40200020
         BNO   NEXTDEB                  NO - GET NEXT DEB               40400020
*                                                                       40600020
         TM    OPCLEN,ADCODE             DD NAME OR ADDR                40800020
         BO    UCB                       ADDR GO GET UCB                41000020
*                                                                       41200020
         LH    RWORK2,DCBTIOT           GET DDNAME OFFSET               41400020
         CR    RWORK2,ROFF              SAME AS FOR DD                  41600020
         BNE   NEXTDEB                  NO - GET NEXT DEB               41800020
*                                                                       42000020
         SR    RRLN,RRLN                CLEAR                           42200020
         IC    RRLN,OPCDOUBL            GET RLN                         42400020
         LR    RWORK,RRLN               RESET FOR TEST                  42600020
         SLL   RWORK,OPCTWO             MULTIPLY BY FOUR                42800020
         L     RWORK,DEBUCBAD-4-DEBNMSUB(RWORK,RDEB) GET UCB            43000020
         LA    RWORK,OPCZERO(RWORK)     CLEAR HIGH BYTE                 43200020
         LTR   RWORK,RWORK              OPENED DD DUMMY                 43400020
         BZ    ERR                      YES - REJECT COMMAND            43600020
*                                                                       43800020
         CLC   OPCDOUBL(OPCONE),DEBNMEXT RLN GREATER THAN EXTENTS       44000020
         BH    ERR                                                      44200020
*                                                                       44400020
LINEOP   EQU   *                                                        44600020
         CLI   DCBTIOT,A                LINE OPEN                       44800020
         BNL   ERR                      NO - REJECT COMMAND             45000020
*                                                                       45200020
         B     LIST                     GO GET INVITATION LIST          45400020
*                                                                       45600020
UCB      EQU   *                                                        45800020
         SR    RWORK,RWORK              CLEAR                           46000020
         IC    RWORK,DEBNMEXT           GET NUMBER OF LINES             46200020
         LA    RWORK3,DEBUCBAD          GET FIRST UCB ADDR              46400020
         LA    RRLN,OPCONE              SET RLN COUNT TO ONE            46600020
UCBLOOP  EQU   *                                                        46800020
         L     RUCB,OPCZERO(,RWORK3)    GET UCB                         47000020
         CLC   ADDR(OPCTHREE,RUCB),OPCTNME SPECIFIED ADDR               47200020
         BE    LINEOP                   YES - GO PROCESS                47400020
*                                                                       47600020
         LA    RRLN,OPCONE(,RRLN)       BUMP RLN COUNT BY ONE           47800020
         LA    RWORK3,OPCFOUR(,RWORK3)  GET TO NEXT                     48000020
         CR    RRLN,RWORK               ANY MORE EXTENTS                48200020
         BH    NEXTDEB                  NO - GET NEXT DEB               48400020
*                                                                       48600020
         B     UCBLOOP                  YES - GO LOOK AT ITS UCB        48800020
*                                                                       49000020
NEXTDEB  EQU   *                                                        49200020
         L     RDEB,OPCFOUR(,RDEB)      GET NEXT DEB ADDR               49400020
         LA    RDEB,OPCZERO(RDEB)       CLEAR HIGH BYTE                 49600020
         LTR   RDEB,RDEB                ANOTHER DEB                     49800020
         BNZ   GETDCB                   YES - GO PROCESS IT             50000020
*                                                                       50200020
ERR      EQU   *                                                        50400020
         MVC   ERMGTXT(OPCEIGHT),OPCTNME PUT NAME IN MSG                50600020
         CLI   OPCLEN,ADCODE            RLN SPECIFIED                   50800020
         BE    ERR1                     NO                              51000020
*                                                                       51200020
         MVC   ERMGTXT+9(OPCTHREE),OPCRLN PUT RLN IN MSG                51400020
ERR1     EQU   *                                                        51600020
         LA    R1,ERMG                  GET MSG ADDR                    51800020
         B     SETBAD                                                   52000020
*                                                                       52200020
LIST     EQU   *                                                        52400020
         SLL   RRLN,OPCTWO              MULTIPLY RLN BY FOUR            52600020
         L     RINV,DCBINVLI-4(RRLN)    GET LIST ADDR                   52800020
         LA    RLIST,OPCSEVEN(,RINV)     GET LIST Q CONTROL FIELDS      53000020
         SR    RACT,RACT                CLEAR                           53200020
         IC    RACT,OPCONE(RINV)        GET ACTIVE                      53400020
         CLI   OPCFLG,ACTIND            DISPLAY ACT OR INACT            53600020
         BE    ACT                      ACT                             53800020
*                                                                       54000020
         SR    R1,R1                    CLEAR                           54200020
         LR    R0,RACT                  GET NUMBER ACTIVE               54400020
         IC    R1,OPCTWO(RINV)          GET ENTRY WIDTH                 54600020
         MR    R0,R0                    DETRMINE END OF ACT             54800020
         AR    RLIST,R1                 GET INACT INDICATOR             55000020
         LA    RLIST,OPCONE(,RLIST)     GET TO FIRST INACT              55200020
         TM    OPCTHREE(RINV),EOTENTRY    BSC LIST                      55400020
         BZ    CKINACT                  NO - PROCEED                    55600020
*                                                                       55800020
         LA    RLIST,OPCONE(RLIST)       GET PAST EOT                   56000020
CKINACT  EQU   *                                                        56200020
         SR    RWORK,RWORK              CLEAR                           56400020
         IC    RWORK,OPCZERO(,RINV)     GET TOTAL ENTRIES               56600020
         SR    RWORK,RACT               SUBTRACT ACTIVE                 56800020
         BNZ   GETENTRY                 INACTIVE ENTREIS - GO PROC      57000020
*                                                                       57200020
         MVC   NOINA1(OPCEIGHT),OPCTNME PUT NAME IN MSG                 57400020
         CLI   OPCLEN,ADCODE            RLN SPECIFIED                   57600020
         BE    CKINACT1                 NO                              57800020
*                                                                       58000020
         MVC   NOINA1+9(OPCTHREE),OPCRLN PUT RLN IN MSG                 58200020
CKINACT1 EQU   *                                                        58400020
         LA    R1,NOINA                 GET MSG ADDR                    58600020
         B     SETGOOD                                                  58800020
*                                                                       59000020
ACT      EQU   *                                                        59200020
         MVC   AMSG1(OPCEIGHT),OPCTNME  PUT NAME IN MSG                 59400020
         CLI   OPCLEN,ADCODE            RLN SPECIFIED                   59600020
         BE    ACT1                     NO                              59800020
*                                                                       60000020
         MVC   AMSG1+9(OPCTHREE),OPCRLN PUT RLN IN MSG                  60200020
ACT1     EQU   *                                                        60400020
         LA    RMSG,AMSG2               GET MSG ADDDR                   60600020
         ST    RMSG,OPCWORK             SAVE IT                         60800020
         LA    RMSG,AMSG3              GET ADDR OF END OF MSG           61000020
         ST    RMSG,OPCDOUBL            SAVE IT                         61200020
         LTR   RACT,RACT                ANY ACTIVE                      61400020
         BNZ   TESTACT                                                  61600020
*                                                                       61800020
         MVC   NOACT1(OPCEIGHT),OPCTNME PUT NAME IN MSG                 62000020
         CLI   OPCLEN,ADCODE            RLN SPECIFIED                   62200020
         BE    ACT2                     NO                              62400020
*                                                                       62600020
         MVC   NOACT1+9(OPCTHREE),OPCRLN PUT RLN IN MSG                 62800020
ACT2     EQU   *                                                        63000020
         LA    R1,NOACT                 GET MSG ADDR                    63200020
         B     SETGOOD                                                  63400020
*                                                                       63600020
GETENTRY EQU   *                                                        63800020
         IC    RACT,OPCZERO(,RINV)      GET TOTAL ENTRIES               64000020
         SR    R0,R0                    CLEAR                           64200020
         IC    R0,OPCONE(,RINV)         GET NUMBER ACTIVE               64400020
         SR    RACT,R0                  SUBTRACT ACTIVE                 64600020
         MVI   AMSGL6,CSEVEN           CHANGE MSG ID                    64700020
         MVC   AMSG1A(NINE),INACTIVE   CHANGE TO INACTIVE               64800020
        MVC   AMSG1(OPCEIGHT),OPCTNME  PUT NAME IN MSG                  64900020
         CLI   OPCLEN,ADCODE            RLN SPECIFIED                   65000020
         BE    GTENTRY1                 NO                              65200020
*                                                                       65400020
         MVC   AMSG1+9(OPCTHREE),OPCRLN  PUT RLN IN MSG                 65600020
GTENTRY1 EQU   *                                                        65800020
         LA    RMSG,AMSG2                GET MSG ADDR                   66000020
         ST    RMSG,OPCWORK             SAVE IT                         66200020
         LA    RMSG,AMSG3              GET ADDR OF END OF MSG           66400020
         ST    RMSG,OPCDOUBL            SAVE IT                         66600020
TESTACT  EQU   *                                                        66800020
         L     RTNT,AVTRNMPT            GET TERMNAME TABLE              67200020
PROCLOOP EQU   *                                                        67300020
         SR    R0,R0                     CLEAR                          67500020
         IC    R0,OPCTWO(RINV)           GET ENTRY WIDTH                67800020
         USING IEDQTNTD,RTNT            ADDRESSABILITY FOR TNT          68400020
COMCD    EQU   *                                                        70200020
         AR    RLIST,R0                 ADD WIDTH TO START              70400020
         SR    RWORK3,RWORK3            CLEAR                           70600020
         IC    RWORK3,OPCZERO(RLIST)    PICK UP K                       70800020
         SLL   RWORK3,OPCONE            MULTIPLY BY 2                   71000020
         LR    RWORK2,RINV              PUT LIST START IN WORK          71200020
         SR    RWORK2,RWORK3            DECREMENT TO TNT OFFSET         71400020
         LH    RWORK2,OPCZERO(,RWORK2)  PICK UP TNT OFFSET              71600020
         LR    RWORK3,RWORK2            SAVE                            71800020
         SR    RWORK5,RWORK5            CLEAR                           72000020
         IC    RWORK5,TNTENLEN          PICK UP TNT ENTRY LENGTH        72200020
         LA    RWORK5,OPCTHREE(RWORK5)  PAST ADDR                       72400020
         LA    RWORK6,TNTFIRST          TO FIRST ENTRY ADDR             72600020
         SR    RWORK6,RWORK5            DECREMENT TO ENTRY-1            72800020
         MR    RWORK5,RWORK5            MULT TNT BY OFFSET              73000020
         AR    RWORK6,RWORK3            GET TERM NAME                   73200020
         L     RWORK,OPCWORK            GET MSG ENTRY                   73400020
         SR    RWORK5,RWORK5            CLEAR                           73600020
         IC    RWORK5,TNTENLEN          LENGTH OF ENTRY                 73800020
         BCTR  RWORK5,R0                DECREMENT FOR EXECUTE           74000020
         EX    RWORK5,MVC               MOVE ENTRY TO MSG               74200020
         LA    RWORK,OPCNINE(RWORK)     BUMP MSG ADDR                   74400020
         ST    RWORK,OPCWORK            SAVE                            74600020
         SPACE                                                          74602020
* THE CODE FROM THIS POINT TO THE LABEL TESTEND IS USED TO              74604020
* DETERMINE WHETHER OR NOT A TSO SESSION IS IN PROGRESS , AND           74606020
* IF SO TO DISPLAY THE USERID.                                          74608020
         SPACE                                                          74610020
* BECAUSE OF THEIR USE IN THE NEXT FOUR INSTRUCTIONS, R1, RWORK5,       74612020
* AND RWORK3 MUST ALWAYS REMAIN EQUATED TO REGISTERS 1, 14, AND         74614020
* 15 RESPECTIVELY.                                                      74616020
         SPACE                                                          74618020
         LR    R1,RWORK2                PASS TNT OFFSET AS PARAM        74620020
         LR    RWORK3,RTNT              GET TERMNAME TABLE ADDR         74622020
         BALR  RWORK5,RWORK3            GO GET TERMINAL TABLE ADDR      74624020
         SPACE                                                          74626020
         USING IEDQTRM,R1               ADDRESSABILITY FOR TERM TAB     74628020
         L     RWORK3,TRMDESTQ-1        GET DESTINATION QCB ADDR        74630020
         USING IEDQQCB,RWORK3           ADDRESSABILITY FOR QCB          74632020
         TM    QCBFLAG,QCBTSSES         IS TSO SESSION IN PROGRESS?     74634020
         BZ    TESTEND                  NO, GO TEST FOR END OF MSG      74636020
         SPACE                                                          74638020
* TESTS FOR VALID TSCVT ADDRESS                                         74640020
         SPACE                                                          74642020
         L     RWORK5,CVTPTR            GET CVT ADDR                    74644020
         USING CVT,RWORK5               ADDRESSABILITY FOR CVT          74646020
         CLC   CVTTSCVT+1(TSTHREE),CVTMZ00+1  LT HIGHEST STG ADDR?      74648020
         BNL   TESTEND                  NO, GO TEST FOR END OF MSG      74650020
         SPACE                                                          74652020
         TM    CVTTSCVT+3,TSHEX3        ON A FULLWORD BOUNDARY?         74654020
         BNZ   TESTEND                  NO, GO TEST FOR END MSG         74656020
         SPACE                                                          74658020
         L     RWORK2,CVTTSCVT          LOAD TSO CVT ADDR               74660020
         LA    RWORK2,TSZERO(,RWORK2)   CLEAR HIGH ORDER BYTE           74662020
         LTR   RWORK2,RWORK2            IS TSCVT ADDR ZERO?             74664020
         BZ    TESTEND                  YES, GO TEST FOR END OF MSG     74666020
         SPACE                                                          74668020
* COMPUTE POINTER TO PROPER TJB AND TEST ITS VALIDITY                   74670020
         SPACE                                                          74672020
         USING TSCVT,RWORK2             ADDRESSABILITY FOR TSCVT        74674020
         TM    QCBTSOF1,QCBDELAY        IS QCB ON TIME DELAY QUEUE?     74676020
         BO    ONDELAYQ                 YES GET TJID FROM OTHER LOC     74678020
         SPACE                                                          74680020
         LH    RWORK3,QCBTJID           GET TJID                        74682020
         B     HAVETJID                 BRANCH AROUND DELAY Q CODE      74684020
         SPACE                                                          74686020
ONDELAYQ EQU   *                                                        74688020
         LH    RWORK3,QCBLINK+1         GET TJID FROM OTHER LOC         74690020
HAVETJID EQU   *                                                        74692020
         MH    RWORK3,TSCVTSZU          TJBSIZE * TJID = OFFSET         74694020
         A     RWORK3,TSCVTTJB          OFFSET+PTR TO TJB'S=TJBADDR     74696020
         LA    RWORK3,TSZERO(,RWORK3)   CLEAR HIGH ORDER BYTE           74698020
         LTR   RWORK3,RWORK3            IS THIS TJB ADDR ZERO?          74700020
         BZ    TESTEND                  YES, GO TEST FOR END OF MSG     74702020
         SPACE                                                          74704020
         ST    RWORK3,TS16(,R13)        STORE TJB ADDR FOR COMPARES     74706020
         CLC   TS16+1(TSTHREE,R13),CVTMZ00+1  LT HIGHEST STG ADDR?      74708020
         BNL   TESTEND                  NO, GO TEST FOR END OF MSG      74710020
         SPACE                                                          74712020
         TM    TS16+3(R13),TSHEX3       ON A FULLWORD BOUNDARY?         74714020
         BNZ   TESTEND                  NO, GO TEST FOR END OF MSG      74716020
         SPACE                                                          74718020
* EXTRACT USERID FOR DISPLAY FIRST, THEN MAKE SURE THIS TJB IS          74720020
* IN USE. THIS ORDER OF FLOW AVOIDS AN INTERRUPT DESTROYING USERID.     74722020
         SPACE                                                          74724020
         USING TJB,RWORK3               ADDRESSABILITY FOR TJB          74726020
         MVI   TSZERO(RWORK),LPAREN     PAREN TO INDICATE TSO USER      74728020
         MVC   TSONE(TSEIGHT,RWORK),TJBUSER    MOVE USERID TO MSG       74730020
         MVI   TSNINE(RWORK),RPAREN     INDICATE END OF USERID          74732020
         TM    TJBSTAT,TJBNJB           IS TJB IN USE?                  74734020
         BZ    INUSE                    YES, BRANCH PAST ERASE CODE     74736020
         SPACE                                                          74738020
         BCTR  RWORK,R0                 GET ADDR OF THE BLANK           74740020
*                                       PRECEDING THE MSG ENTRY         74742020
         MVC   TSONE(TSTEN,RWORK),TSZERO(RWORK)   BLANK OUT USERID      74744020
         LA    RWORK,TSONE(RWORK)       RESET MSG ADDR                  74746020
         B     TESTEND                  GO TEST FOR END OF MESSAGE      74748020
         SPACE                                                          74750020
INUSE    EQU   *                                                        74752020
         LA    RWORK,TSELEVEN(RWORK)    YES, BUMP MSG ADDR              74754020
         ST    RWORK,OPCWORK            SAVE MSG ADDR                   74756020
TESTEND  EQU   *                                                        74758020
         L     RWORK5,OPCDOUBL          GET END OF MSG                  74800020
         CR    RWORK,RWORK5             AT END                          75000020
         BNL   NXT                                                      75200020
*                                                                       75400020
         BCT   RACT,PROCLOOP                                            75800020
*                                                                       76000020
NXT      EQU   *                                                        76200020
         MVC   0(FOUR,RWORK),DESCR5      SET UP ROUTING CODE            76500020
         LA    RWORK5,FULLAMSG           BEGINNING OF MSG               76800020
         SR    RWORK,RWORK5             GET LENGTH                      77100020
         STH   RWORK,FULLAMSG           STORE FOR OUTPUT                77400020
         LA    R1,FULLAMSG              GET MSG ADDR                    77800020
SETGOOD  EQU   *                                                        78000020
         SR    R15,R15                  SET GOOD RETURN                 78200020
PUTMSG   EQU   *                                                        78400020
         ST    R1,OPCREG1(,R13)         STORE IN SAVE AREA              78600020
         RETURN (14,12),T,RC=(15)                                       78800020
*                                                                       79000020
TSZERO   EQU   0                        DISPL TO MOVE LPAREN INTO       79010020
*                                       MSG AND TO CLEAR HI ORDER       79020020
*                                       BYTE IN LOAD ADDR INST          79030020
TSONE    EQU   1                        DISPL TO MOVE USERID AND TO     79040020
*                                       RESET MSG PTR IN ERASE CODE     79050020
TSTHREE  EQU   3                        LENGTH USED IN ADDR COMPARE     79060020
TSEIGHT  EQU   8                        LENGTH TO MOVE USERID           79070020
TSNINE   EQU   9                        DISPL TO MOVE RPAREN            79080020
TSTEN    EQU   10                       LENGTH USED TO ERASE USERID     79090020
TSELEVEN EQU   11                       DISPL TO BUMP MSG ADDR          79100020
TS16     EQU   16                       DISPL INTO SAVE AREA FOR        79110020
*                                       WORD CONTAINING REGISTER 15     79120020
*                                       WHICH IS NOT RESTORED UPON      79130020
*                                       RETURN.                         79140020
TSHEX3   EQU   X'03'                    TO TEST FOR FULLWORD BDY        79150020
LPAREN   EQU   C'('                     INDICATES TSO USERID            79160020
RPAREN   EQU   C')'                     INDICATES END OF TSO USERID     79170020
*                                                                       79180020
DEB      EQU   8                                                        79200020
TIOT      EQU  12                                                       79400020
ADDR     EQU   13                                                       79600020
STARTOFF EQU   24                                                       79800020
ACTIND   EQU   X'80'                                                    80000020
ADCODE   EQU   X'80'                                                    80200020
TX       EQU   X'40'                                                    80400020
EOTENTRY  EQU   X'80'                                                   80600020
FOUR     EQU   4                                                        80640020
NINE     EQU   9                                                        80680020
CSEVEN   EQU   C'7'                                                     80720020
INACTIVE DC    C'INACTIVE='                                             80760020
A        EQU   C'A'                                                     80800020
MAXVAL   DC    H'255'                                                   81000020
MVC      MVC   OPCZERO(OPCONE,RWORK),OPCZERO(RWORK6)                    81200020
PACK     PACK  OPCDOUBL+6(OPCTWO),OPCDOUBL(OPCONE)                      81400020
ERMG     DS    0H                                                       81470020
         DC    AL2(DESCR1-*),X'6000'     LENGTH,MCSFLGS-INREG0-IMMRSP   81540020
         DC    C'IED017I LINE '                                         81610020
ERMGTXT  DC    12C' ',C' NOT OPEN'                                      81680020
DESCR1   DC    X'0800'                   DESCRIPTOR - IMMEDIATE RESP    81750020
         DC    X'0000'                   ROUTING - IN REG 0             81820020
NOINA    DS    0H                                                       81890020
         DC    AL2(DESCR2-*),X'6000'     LENGTH,MCSFLGS-INREG0-IMMRSP   81960020
         DC    C'IED037I '                                              82030020
NOINA1   DC    12C' ',C' INACTIVE=NONE'                                 82100020
DESCR2   DC    X'0800'                   DESCRIPTOR - IMMEDIATE RESP    82170020
         DC    X'0000'                   ROUTING - IN REG 0             82240020
NOACT    DS    0H                                                       82310020
         DC    AL2(DESCR3-*),X'6000'     LENGTH,MCSFLGS-INREG0-IMMRSP   82380020
         DC    C'IED036I '                                              82450020
NOACT1   DC    12C' ',C' ACTIVE=NONE'                                   82520020
DESCR3   DC    X'0800'                   DESCRIPTOR - IMMEDIATE RESP    82590020
         DC    X'0000'                   ROUTING - IN REG 0             82660020
FULLAMSG DS    0H                                                       83320020
         DC    AL2(DESCR5-*),X'6000'     LENGTH,MCSFLGS-INREG0-IMMRSP   83400020
         DC    C'IED03'                                                 83450020
AMSGL6   DC    C'6I '                                                   83500020
AMSG1    DC    12C' ',C' '                                              83550020
AMSG1A   DC    C'  ACTIVE='                                             83600020
AMSG2    DC    320C' '                                                  83650020
AMSG3    EQU   *                                                        83700020
         DC    25C' '                   EXTRA BYTES AT END OF MSG       83730020
*                                       TO HOLD LAST ENTRY IF NEEDED    83760020
DESCR5   DC    X'0800'                   DESCRIPTOR - IMMEDIATE RESP    83800020
         DC    X'0000'                   ROUTING - IN REG 0             83900020
         PRINT NOGEN                                                    84000020
         TOPCD                                                          84200020
         TDEBD                                                          84400020
         DCBD  DSORG=TX                                                 84600020
         TTNTD                                                          84800020
         TAVTD                                                          85000020
CVT      DSECT                                                          85020020
         CVT                                                            85040020
         TQCBD                                                          85060020
         IKJTJB                                                         85080020
         TTRMD                                                          85100020
         IKJTSCVT                                                       85120020
         END                                                            85200020
