         TITLE '''IEDQCM'' - DISPLAY CONTROL TERMINAL'                  00400020
IEDQCM   CSECT                                                          00800020
*********************************************************************** 01200020
*                                                                     * 01600020
*TITLE 'IEDQCM' PROCESSOR OF DISPLAY PRITERM/SECTERM COMMANDS         * 02000020
*                                                                     * 02400020
*STATUS -- CHANGE LEVEL 0                                             * 02800020
*                                                                     * 03200020
*FUNCTION -- THIS MODULE PROCESSES OPERATOR CONTROL COMMANDS WHICH    * 03600020
*   REQUEST DISPLAY OF THE PRIMARY OPERATOR CONTROL TERMINAL OR THE   * 04000020
*   LIST OF SECONDARY OPERATOR CONTROL TERMINALS.                     * 04400020
*                                                                     * 04800020
*   THE COPY OPERATOR CONTROL TERMINAL ROUTINE ACCESSES THE           * 05200020
*   TERMNAME TABLE FROM THE AVT AND CHECKS THE COMMON INPUT BLOCK     * 05600020
*   TO DETERMINE THE TYPE OF COMMAND (OPCFLG IS X'80' IF PRITERM,     * 06000020
*   X'40' IF SECTERM).  IF PRITERM, THE OFFSET TO THE PRIMARY         * 06400020
*   CONTROL TERMINAL IS OBTAINED FROM THE AVT (AVTOPCON) AND TESTED   * 06800020
*   FOR ZERO.  IF ZERO, THE PRIMARY TERMINAL IS THE SYSTEM CONSOLE.   * 07200020
*   SYSCON IS PLACED IN THE RESPONSE AND CONTROL EXITS TO THE         * 07600020
*   CONTROL MODULE.  IF IT IS NOT ZERO, THE OFFSET IS ADDED TO THE    * 08000020
*   START OF THE TERMNAME TABLE, AND THE TERMNAME AT THAT LOCATION    * 08400020
*   IS MOVED INTO THE RESPONSE.  THE ROUTINE RETURNS TO THE CONTROL   * 08800020
*   MODULE.                                                           * 09200020
*                                                                     * 09600020
*   IF THE SECONDARY OPERATOR CONTROL TERMINALS ARE TO BE DISPLAYED   * 10000020
*   EACH ENTRY IN THE TERMNAME TABLE IS EXAMINED.  IF AN ENTRY IS A   * 10400020
*   SECONDARY TERMINAL (TRMSCNYN ON IN TRMSTATE) ITS NAME IS PLACED   * 10800020
*   IN THE RESPONSE MESSAGE.  WHEN THE END OF THE TABLE IS REACHED,   * 11200020
*   CONTROL RETURNS TO THE CONTROL MODULE.                            * 11600020
*                                                                     * 12000020
*ENTRY POINTS --                                                      * 12400020
*        'IEDQCM' TO PROCESS DISPLAY PRITERM AND DISPLAY SECTERM      * 12800020
*   OPERATOR CONTROL COMMANDS.  CALLING SEQUENCE IS                   * 13200020
*                        LOAD EPLOC=LOADPRFX                          * 13600020
*                        LR   R1,ROPC                                 * 14000020
*                        LR   R15,R0                                  * 14400020
*                        BALR R14,R15                                 * 14800020
*                                                                     * 15200020
*INPUT -- REGISTER 1 - ADDRESS OF OPERATOR CONTROL AVT, WHICH         * 15600020
*   CONTAINS THE COMMON INPUT BLOCK.                                  * 16000020
*                                                                     * 16400020
*   REGISTER 15 - ENTRY POINT ADDRESS.                                * 16800020
*                                                                     * 17200020
*OUTPUT -- REGISTER 1 - ADDRESS OF APPROPRIATE RESPONSE MESSAGE.      * 17600020
*                                                                     * 18000020
*EXTERNAL ROUTINES -- N/A.                                            * 18400020
*                                                                     * 18800020
*EXITS-NORMAL -- A MESSAGE CONTAINING THE REQUESTED INFORMATION IS    * 19200020
*   PREPARED AND ITS ADDRESS IS RETURNED TO THE CALLING ROUTINE.      * 19600020
*                                                                     * 20000020
*EXITS-ERROR -- N/A.                                                  * 20400020
*                                                                     * 20800020
*TABLES/WORK AREAS -- MESSAGES, AVT, TERMNAME TABLE, TERMINAL         * 21200020
*   ENTRY, OPERATOR CONTROL AVT.                                      * 21600020
*                                                                     * 22000020
*ATTRIBUTES -- SERIALLY REUSABLE, REFRESHABLE, ENABLED, TRANSIENT,    * 22400020
*   PROBLEM PROGRAM MODE.                                             * 22800020
*                                                                     * 23200020
*NOTES -- THE OPERATION OF THIS MODULE DEPENDS UPON AN INTERNAL       * 23600020
*   REPRESENTATION OF THE EXTERNAL CHARACTER SET WHICH IS             * 24000020
*   EQUIVALENT TO THE ONE USED AT ASSEMBLY TIME.  THE CODING HAS      * 24400020
*   BEEN ARRANGED SO THAT REDEFINITION OF ''CHARACTER'' CONSTANTS,    * 24800020
*   BY REASSEMBLY, WILL RESULT IN A CORRECT MODULE FOR THE NEW        * 25200020
*   DEFINITIONS.                                                      * 25600020
*                                                                     * 26000020
*   MESSAGES ISSUED BY THIS MODULE ARE                                * 26400020
*              IED041I, IED043I                                       * 26800020
*                                                                     * 27200020
*********************************************************************** 27600020
*                                                                       28000020
*                                                                       28400020
R0       EQU   0                        WORK                            28800020
R1       EQU   1                        PARAMETER                       29200020
ROPC     EQU   2                        OPERATOR CONTROL AVT BASE       29600020
RAVT     EQU   4                        AVT BASE                        30000020
RTNT     EQU   5                        TERMNAME TABLE BASE             30400020
RTERM    EQU   6                        TERMINAL ENTRY BASE             30800020
RWORK1   EQU   7                        WORK                            31200020
RWORK2    EQU  8                        WORK                            31600020
RWORK3   EQU   9                        WORK                            32000020
RLIST    EQU   10                       TERMNAME LIST BASE              32400020
RCTR     EQU   11                       COUNTER FOR MSG ENTRIES         32800020
RBASE    EQU   12                       ROUTINE BASE                    33200020
R13      EQU   13                       SAVE AREA                       33600020
R14      EQU   14                       RETURN                          34000020
R15      EQU   15                       ENTRY POINT                     34400020
         USING IEDQOPC,ROPC             ADDRESSABILITY FOR OP CTL       34800020
         USING IEDQAVTD,RAVT            ADDRESSABILITY FOR AVT          35200020
         USING IEDQTNTD,RTNT            ADDRESSABILITY FOR TNT          35600020
         USING IEDQTRM,RTERM            ADDRESSABILITY FOR TERM         36000020
         USING IEDQCM,RBASE             ADDRESSABILITY FOR ROUTINE      36400020
         SAVE  (14,12),,IEDQCM-02/26/71                                 36800020
         LR    RBASE,R15                GIVE ROUTINE A BASE             37200020
         LR    ROPC,R1                  GET OP CTL AVT                  37600020
         L     RAVT,OPCAVTAD            GET AVT                         38000020
         LA    R1,LEN                                                   38400020
         LA    RCTR,MSGLE                                               38800020
         L     RTNT,AVTRNMPT            GET TERMNAME TABLE              39200020
         SR    RWORK3,RWORK3                                            39600020
         IC    RWORK3,TNTENLEN          GET ENTRY LENGTH                40000020
         CLI   OPCFLG,SEC               DISPLAY SECONDARY TERMS         40400020
         BE    SECTERM                  YES                             40800020
*                                                                       41200020
         LH    RWORK2,AVTOPCON          GET PRIMARY OFFSET              41600020
         LTR   RWORK2,RWORK2            PRIMARY A TERMINAL              42000020
         BNZ   SETTRM                   YES - GET ITS NAME              42400020
*                                                                       42800020
         MVC   MSGN(OPCSIX),SYS         PUT 'SYSCON' IN MSG             43200020
         B     PRIMSG                   GO COMPLETE MESSAGE             43600020
*                                                                       44000020
SETTRM   EQU   *                                                        44400020
         AR    RTNT,RWORK2              ADD OFFSET INTO TNT             44800020
         BCTR  RWORK3,R0                DECREMENT FOR EXECUTE           45200020
         EX    RWORK3,MVC               PUT NAME IN MSG                 45600020
PRIMSG   EQU   *                                                        46000020
         LA    RWORK1,PMSG              PICK UP MSG ADDRESS             46400020
EXIT     EQU   *                                                        46800020
         SR    R15,R15                  SET GOOD RETURN                 47200020
OUT      EQU   *                                                        47600020
         NI    OPCBITSW,BITSOFF         TURN OFF WORK BITS              48000020
         ST    RWORK1,OPCREG1(,R13)     STORE IN SAVE AREA              48400020
         RETURN (14,12),T,RC=(15)                                       48800020
*                                                                       49200020
SECTERM   EQU  *                                                        49600020
         LA    RLIST,MSGL               GET ADDRESS OF LIST             50000020
         LA    RWORK2,OPCONE            SET COUNTER                     50400020
         LH    RWORK3,TNTLEN            GET NUMBER OF ENTRIES           50800020
         SR    RWORK1,RWORK1            CLEAR                           51200020
         IC    RWORK1,TNTENLEN          GET ENTRY LENGTH                51600020
         LA    RTNT,TNTFIRST            GET FIRST ENTRY                 52000020
LOOP     EQU   *                                                        52400020
         CR    RWORK2,RWORK3            END OF TABLE                    52800020
         BH    PUTMSG                   YES - PUT OUT MESSAGE           53200020
*                                                                       53600020
         CR    RLIST,RCTR               END OFMMSG                      54000020
         BNL   PUTMSG                    PUT OUT THE MESSAGE            54400020
*                                                                       54800020
NEXT     EQU   *                                                        55200020
         LR    RTERM,RTNT               ADD OFFSET TO FIRST             55600020
         AR    RTERM,RWORK1             ADD ENTRY LENGTH                56000020
         MVC   OPCWORK+1(OPCTHREE),OPCZERO(RTERM) PUT ON BDRY           56400020
         L     RTERM,OPCWORK            GET TERM ADDR                   56800020
         TM    TRMSTATE,TRMSCNYN        SECONDARY TERMINAL              57200020
         BO    LIST                     YES - PUT NAME IN LIST          57600020
*                                                                       58000020
INCR     EQU   *                                                        58400020
         LA    RTNT,OPCTHREE(RWORK1,RTNT) BUMP TO NEXT ENTRY            58800020
         LA    RWORK2,OPCONE(,RWORK2)   INCREMENT COUNTER               59200020
         B     LOOP                     PROCESS NEXT ENTRY              59600020
*                                                                       60000020
LIST     EQU   *                                                        60400020
         OI    OPCBITSW,OPCFRSTN        TURN ON FOUND BIT               60800020
         BCTR  RWORK1,R0                DECREMENT FOR EXECUTE           61200020
         EX    RWORK1,MVL               PUT NAME IN LIST                61600020
         LA    RWORK1,OPCTWO(,RWORK1)   BUMP PAST BLANK                 62000020
         AR    RLIST,RWORK1             ADD TO MSG                      62400020
         AR    R1,RWORK1                ADD TO MSG LENGTH               62800020
         BCTR  RWORK1,R0                DECREMENT FOR PROCESS           63200020
         B     INCR                     GET NEXT ENTRY                  63600020
*                                                                       64000020
*                                                                       64400020
PUTMSG   EQU   *                                                        64800020
         TM    OPCBITSW,OPCFRSTN        ANY ENTRIES FOUND               65200020
         BNO   SETCON                   NO - PUT CONSOLE IN MSG         65600020
         MVC   RLIST(OPCFOUR),ROUTE       GET ROUTING INFO              65800020
*                                                                       66000020
TESTC5   EQU   *                                                        66400020
*                                                                       67600020
         STH   R1,LMSG                  PUT LENGTH IN MSG               68000020
LA       EQU   *                                                        68400020
         LA    RWORK1,LMSG              GET MESSAGE ADDRESS             68800020
         B     EXIT                                                     69200020
*                                                                       69600020
*                                                                       71600020
SETCON   EQU   *                                                        72000020
         MVC   MSGL(11),SYS             PUT  'SYSCON' IN MSG            72300020
         LA    R1,OPCSEVEN(R1)           INCREASE CLUNT FOR SYSCON      72600020
         B     TESTC5                                                   72800020
*                                                                       73200020
*                                                                       80400020
LEN      EQU   22                                                       80800020
C5N      EQU   X'10'                                                    81200020
BITSOFF  EQU   X'E0'                                                    81600020
SEC      EQU   X'40'                                                    82000020
SYS      DC    C'SYSCON ',X'0800',X'0000'                               82600020
MVC      MVC   MSGN(OPCZERO),OPCZERO(RTNT)                              83200020
MVL      MVC   OPCZERO(OPCZERO,RLIST),OPCZERO(RTNT)                     83600020
PMSG     DS    0H                                                       83800020
         DC    AL2(DESCR1-*),X'6000'     LENGTH,MCSFLGS-INREG0-IMMRSP   84000020
         DC    C'IED041I PRIMARY='                                      84200020
MSGN     DC    8C' '                                                    84400020
ROUTE    EQU   *                                                        84600020
DESCR1   DC    X'0800'                   DESCRIPTOR - IMMEDIATE RESP    84800020
         DC    X'0000'                   ROUTING - IN REG 0             85000020
LMSG     DS    0H                                                       85200020
         DC    AL2(DESCR2-*),X'6000'     LENGTH,MCSFLGS-INREG0-IMMRSP   85400020
         DC    C'IED043I SECONDARY='                                    85600020
MSGL     DC    320C' '                                                  85800020
         DC    320C' '                                                  86000020
MSGLE    EQU   *-5                                                      86200020
DESCR2   DC    X'0800'                   DESCRIPTOR - IMMEDIATE RESP    86400020
         DC    X'0000'                   ROUTING - IN REG 0             86600020
ENDC5    EQU   *                                                        87200020
         TOPCD                                                          87600020
         PRINT NOGEN                                                    88000020
         TAVTD                                                          88400020
         TTNTD                                                          88800020
         TTRMD                                                          89200020
         END                                                            89600020
