         TITLE '''IEDQCN'' - MODIFY PRIMARY'                            00400020
IEDQCN   CSECT                                                          00800020
*********************************************************************** 01200020
*                                                                     * 01600020
*TITLE 'IEDQCN' PROCESSOR OF MODIFY OPERATOR COMMANDS                 * 02000020
*                                                                     * 02400020
*STATUS -- CHANGE LEVEL 0                                             * 02800020
*                                                                     * 03200020
*FUNCTION -- THIS ROUTINE PROCESSES OPERATOR CONTROL COMMANDS WHICH   * 03600020
*   REQUEST THE PRIMARY OPERATOR CONTROL TERMINAL BE CHANGED FROM     * 04000020
*   ITS CURRENT MEMBER TO THE ONE SPECIFIED IN THE COMMAND.           * 04400020
*                                                                     * 04800020
*   THE CHANGE CONTROL TERMINAL ROUTINE CHECKS THE COMMON INPUT       * 05200020
*   BLOCK TO SEE IF THE REQUESTED PRIMARY TERMINAL IS THE SYSTEM      * 05600020
*   CONSOLE.  IF IT IS, THE PRIMARY OFFSET IN THE AVT (AVTOPCON) IS   * 06000020
*   COMPARED TO ZERO.  IF ZERO, THE CONSOLE IS ALREADY PRIMARY.  A    * 06400020
*   RESPONSE IS BUILT AND THE ROUTINE EXITS TO THE CONTROL MODULE.    * 06800020
*                                                                     * 07200020
*   IF THE SYSTEM CONSOLE IS NOT ALREADY PRIMARY, AVTOPCON IS SET     * 07600020
*   TO ZERO.  IF THE OPERATOR AWARENESS WRITER MODULE IS IN THE       * 08000020
*   SYSTEM (AVTNX IS NOT ZERO) THE IEDQNX ROUTINE IS DELETED AND      * 08400020
*   AVTNX IS SET TO ZERO.  A RESPONSE MESSAGE IS BUILT AND THE        * 08800020
*   ROUTINE EXITS TO THE CONTROL MODULE.                              * 09200020
*                                                                     * 09600020
*   IF THE PRIMARY REQUESTED IS NOT ZERO, THE TERMNAME TABLE IS       * 10000020
*   ACCESSED FROM THE AVT AND SERIALLY SEARCHED FOR A MATCH WITH      * 10400020
*   THE ONE SPECIFIED IN THE COMMON INPUT BLOCK.  IF NO MATCH IS      * 10800020
*   FOUND, AN ERROR MESSAGE IS BUILT AND CONTROL RETURNS TO THE       * 11200020
*   CONTROL MODULE.  WHEN A MATCH IS FOUND, ITS ENTRY IS TESTED TO    * 11600020
*   SEE IF IT IS A VALID SECONDARY TERMINAL (TRMSCNYN ON IN           * 12000020
*   TRMSTATE).  IF NOT, AN ERROR MESSAGE IS BUILT AND THE ROUTINE     * 12400020
*   EXITS TO THE CONTROL MODULE.                                      * 12800020
*                                                                     * 13200020
*   ONCE THE ENTRY IS LOCATED, ITS OFFSET FROM THE START OF THE       * 13600020
*   TERMNAME TABLE IS COMPARED TO AVTOPCON.  IF THEY ARE THE SAME,    * 14000020
*   THE TERMINAL IS ALREADY PRIMARY.  A RESPONSE IS BUILT AND THE     * 14400020
*   ROUTINE EXITS TO THE CONTROL MODULE.  OTHERWISE, THE NEW OFFSET   * 14800020
*   IS PLACED IN AVTOPCON, AND AVTNX IS TESTED FOR THE PRESENCE OF    * 15200020
*   THE IEDQNX ROUTINE.  IF IT IS NOT IN THE SYSTEM, THE IEDQNX       * 15600020
*   ROUTINE IS LOADED AND ITS ADDRESS STORED IN AVTNX.  A RESPONSE    * 16000020
*   IS BUILT AND CONTROL RETURNS TO THE CONTROL MODULE.               * 16400020
*                                                                     * 16800020
*ENTRY POINTS --                                                      * 17200020
*        'IEDQCN' TO PROCESS MODIFY OPERATOR OPERATOR CONTROL         * 17600020
*   COMMANDS.  CALLING SEQUENCE IS                                    * 18000020
*                        LOAD EPLOC=LOADPRFX                          * 18400020
*                        LR   R1,ROPC                                 * 18800020
*                        LR   R15,R0                                  * 19200020
*                        BALR R14,R15                                 * 19600020
*                                                                     * 20000020
*INPUT -- REGISTER 1 - ADDRESS OF THE OPERATOR CONTROL AVT.  AT THE   * 20400020
*   LOCATION OPCTNME IS THE NAME OF THE TERMINAL TO BE MADE           * 20800020
*   PRIMARY.                                                          * 21200020
*                                                                     * 21600020
*   REGISTER 15 - ENTRY POINT ADDRESS.                                * 22000020
*                                                                     * 22400020
*OUTPUT -- REGISTER 1 - ADDRESS OF APPROPRIATE RESPONSE MESSAGE.      * 22800020
*                                                                     * 23200020
*   REGISTER 15 - RETURN CODE.  VALUE IS                              * 23600020
*                   0    TERMINAL MADE PRIMARY OR ALREADY PRIMARY.    * 24000020
*                   4    TERMINAL NOT FOUND OR NOT CAPABLE OF BEING   * 24400020
*                        PRIMARY.                                     * 24800020
*                                                                     * 25200020
*EXTERNAL ROUTINES --                                                 * 25600020
*        'LOAD' MACRO - SVC 8 - TO LOAD IEDQNX                        * 26000020
*                                                                     * 26400020
*        'DELETE' MACRO - SVC 9 - TO DELETE IEDQNX                    * 26800020
*                                                                     * 27200020
*EXITS-NORMAL -- TERMINAL MADE PRIMARY.  RESPONSE BUILT, X'00'        * 27600020
*   RETURN CODE SET.                                                  * 28000020
*                                                                     * 28400020
*   TERMINAL WAS ALREADY PRIMARY.  ALREADY MESSAGE BUILT, X'00'       * 28800020
*   RETURN CODE SET.                                                  * 29200020
*                                                                     * 29600020
*EXITS-ERROR -- TERMINAL NOT FOUND.  NOT FOUND MESSAGE BUILT, X'04'   * 30000020
*   RETURN CODE SET.                                                  * 30400020
*                                                                     * 30800020
*   TERMINAL NOT SECONDARY.  NOT CAPABLE MESSAGE BUILT, X'04'         * 31200020
*   RETURN CODE SET.                                                  * 31600020
*                                                                     * 32000020
*TABLES/WORK AREAS -- MESSAGES, AVT, TERMNAME TABLE, TERMINAL         * 32400020
*   ENTRY, OPERATOR CONTROL AVT.                                      * 32800020
*                                                                     * 33200020
*ATTRIBUTES -- SERIALLY REUSABLE, REFRESHABLE, ENABLED, TRANSIENT,    * 33600020
*   PROBLEM PROGRAM MODE.                                             * 34000020
*                                                                     * 34400020
*NOTES -- THE OPERATION OF THIS MODULE DEPENDS UPON AN INTERNAL       * 34800020
*   REPRESENTATION OF THE EXTERNAL CHARACTER SET WHICH IS             * 35200020
*   EQUIVALENT TO THE ONE USED AT ASSEMBLY TIME.  THE CODING HAS      * 35600020
*   BEEN ARRANGED SO THAT REDEFINITION OF ''CHARACTER'' CONSTANTS,    * 36000020
*   BY REASSEMBLY, WILL RESULT IN A CORRECT MODULE FOR THE NEW        * 36400020
*   DEFINITIONS.                                                      * 36800020
*                                                                     * 37200020
*   MESSAGES ISSUED BY THIS MODULE ARE                                * 37600020
*              IED016I, IED018I, IED041I, IED042I, IED044I            * 38000020
*                                                                     * 38400020
*********************************************************************** 38800020
*                                                                       39200020
*                                                                       39600020
R0       EQU   0                        WORK                            40000020
R1       EQU   1                        PARAMETER                       40400020
ROPC     EQU   2                        OPERATOR CONTROL AVT BASE       40800020
RAVT     EQU   4                        AVT BASE                        41200020
RTNT     EQU   5                        TERMNAME TABLE BASE             41600020
RTERM    EQU   6                        TERMINAL ENTRY BASE             42000020
RWORK    EQU   7                        WORK                            42400020
RWORK2   EQU   8                        WORK                            42800020
RWORK3   EQU   9                        WORK                            43200020
RBASE    EQU   12                       ROUTINE BASE                    43600020
R13      EQU   13                       SAVE AREA                       44000020
R14      EQU   14                       RETURN                          44400020
R15      EQU   15                       ENTRY                           44800020
         USING IEDQCN,RBASE             ADDRESSABILITY FOR ROUTINE      45200020
         USING IEDQAVTD,RAVT            ADDRESSABILITY FOR AVT          45600020
         USING IEDQOPC,ROPC             ADDRESSABILITY FOR OP CTL       46000020
         USING IEDQTNTD,RTNT            ADDRESSABILITY FOR TNT          46400020
         USING IEDQTRM,RTERM            ADDRESSABILITY FOR TERM         46800020
*                                                                       47200020
         SAVE  (14,12),,IEDQCN-03/06/71                                 47600020
         LR    RBASE,R15                SET BASE                        48000020
         LR    ROPC,R1                  SET OP CTL AVT BASE             48400020
         L     RAVT,OPCAVTAD            GET AVT ADDRESS                 48800020
         CLC   OPCTNME(OPCSEVEN),SYSCON  CHANGE TO CONSOLE              49200020
         BNE   GETTRM                   NO - FIND TERM ENTRY            49600020
*                                                                       50000020
         SR    RWORK,RWORK              CLEAR                           50400020
         CH    RWORK,AVTOPCON           ALREADY CONSOLE                 50800020
         BE    ALR                      YES - PUT PROPER MSG            51200020
*                                                                       51600020
         STH   RWORK,AVTOPCON           CLEAR AVT FIELD - DEFAULT       52000020
         CLC   AVTNX(OPCFOUR),AVTFZERO  IEDQNX IN SYSTEM                52400020
         BE    MESSAGE                  NO - EXIT                       52800020
*                                                                       53200020
         LA    RWORK,EPNX               GET ENTRY POINT                 53600020
         DELETE EPLOC=(RWORK)           DELETE IEDQNX                   54000020
*                                                                       54400020
         MVC   AVTNX(OPCFOUR),AVTFZERO  CLEAR AVTNX FIELD               54800020
         B     MESSAGE                  PREPARE MESSAGE                 55200020
*                                                                       55600020
GETTRM   EQU   *                                                        56000020
          L    RTNT,AVTRNMPT            GET TERMNAME TABLE              56400020
         LA    RWORK,OPCONE             SET COUNTER                     56800020
         LH    RWORK2,TNTLEN            GET NUMBER OF ENTRIES           57200020
         SR    RWORK3,RWORK3            CLEAR                           57600020
         IC    RWORK3,TNTENLEN          GET ENTRY LENGTH                58000020
         BCTR  RWORK3,R0                DECREMENT FOR EXECUTE           58400020
         CH    RWORK3,AVTHA7            EIGHT BYTES                     58450020
         BE    HTRMOK                   YES, VALID LENGTH               58500020
         LA    R15,OPCTNME+1(RWORK3)  PTR TO FIRST BLANK                58550020
        CLI   OPCZERO(R15),AVTEBLNK     IS IT A BLANK                   58600020
         BNE   NOTFOUND                 NO, ERROR                       58650020
HTRMOK   EQU   *                                                        58700020
         LA    RTNT,TNTFIRST            GET FIRST ENTRY ADDR            58800020
LOOPTNT  EQU   *                                                        59200020
         CR    RWORK,RWORK2             END OF TABLE                    59600020
         BH    NOTFOUND                 YES - ERROR EXIT                60000020
*                                                                       60400020
         EX    RWORK3,CLC               RIGHT ENTRY                     60800020
         BE    SECTEST                  YES - PROCESS IT                61200020
*                                                                       61600020
         LA    RWORK,OPCONE(,RWORK)     BUMP COUNTER BY ONE             62000020
         LA    RTNT,OPCFOUR(RWORK3,RTNT) BUMP TO NEXT ENTYR             62400020
         B     LOOPTNT                  LOOK AT NEXT ENTRY              62800020
*                                                                       63200020
NOTFOUND EQU   *                                                        63600020
         MVC   NFA(OPCEIGHT),OPCTNME    PUT NAME IN MSG                 64000020
         LA    RWORK,NFB                GET MSG ADDR                    64400020
         B     SETBAD                                                   64800020
*                                                                       65200020
SECTEST  EQU   *                                                        65600020
         LR    RTERM,RTNT                                               66000020
         AR    RTERM,RWORK3             GET TERM ENTRY ADDR             66400020
         MVC   OPCWORK+1(OPCTHREE),OPCONE(RTERM) PUT ON BDRY            66800020
         L     RTERM,OPCWORK            PUT ADDR IN REG                 67200020
         TM    TRMSTATE,TRMSCNYN        VALID SECONDARY                 67600020
         BO    SET                      YES - STORE OFFSET IN AVT       68000020
*                                                                       68400020
ERROR    EQU   *                                                        68800020
         MVC   BADVAR(OPCEIGHT),OPCTNME PUT NAME IN MSG                 69200020
         LA    RWORK,BADMSG             GET MSG ADDR                    69600020
SETBAD   EQU   *                                                        70000020
         LA    R15,OPCFOUR              SET BAD RETURN                  70400020
EXIT     EQU   *                                                        70800020
         ST    RWORK,OPCREG1(,R13)                                      71200020
         RETURN (14,12),T,RC=(15)                                       71600020
*                                                                       72000020
SET      EQU   *                                                        72400020
         LA    RTNT,OPCZERO(RTNT)       CLEAR HIGH BYTE                 72800020
         L     RWORK,AVTRNMPT           GET START OF TABLE              73200020
         LA    RWORK,OPCZERO(RWORK)     CLEAR HIGH BYTE                 73600020
         SR    RTNT,RWORK               GET OFFSET FROM START           74000020
         CH    RTNT,AVTOPCON            ALREADY THIS TERMINAL           74400020
         BE    ALR                      YES - PUT ALREADY MSG           74800020
*                                                                       75200020
         CLC   AVTNX(OPCFOUR),AVTFZERO  IEDQNX IN SYSTEM                76000020
         BNE   MESSAGE1                 YES, SET OFFSET AND EXIT        76400020
*                                                                       76800020
         LA    RWORK,EPNX               GET ENTRY POINT                 77200020
         LOAD  EPLOC=(RWORK)            LOAD IEDQNX                     77600020
*                                                                       78000020
         ST    R0,AVTNX                 PUT ITS ADDR IN AVT             78400020
MESSAGE1 EQU   *                                                        78500020
         STH   RTNT,AVTOPCON            PUT NEW OFFSET IN AVT           78600020
MESSAGE  EQU   *                                                        78800020
         MVC   GOODVAR(OPCEIGHT),OPCTNME PUT NAME IN MSG                79200020
         LA    RWORK,GOOD               GET MSG ADDR                    79600020
         OI    OPCCKBIT,OPCCKPTN        TURN ON CHECKPOINT BIT          80000020
SETGOOD  EQU   *                                                        80400020
         SR    R15,R15                  SET GOOD RETURN                 80800020
         B     EXIT                                                     81200020
*                                                                       81600020
ALR      EQU   *                                                        82000020
         MVC   ALRM(OPCEIGHT),OPCTNME   PUT NAME IN MSG                 82400020
         LA    RWORK,AL                 GET MSG ADDR                    82800020
         B     SETGOOD                                                  83200020
*                                                                       83600020
COMINV   EQU   *                                                        84000020
         LA    RWORK,OPCERMSG           GET MSG ADDR                    84400020
         B     SETBAD                                                   84800020
*                                                                       85200020
BITSOFF  EQU   X'E0'                                                    85600020
CLC      CLC   OPCZERO(OPCONE,RTNT),OPCTNME                             86000020
SYSCON   DC    C'SYSCON '                                               86400020
EPNX     DC    C'IEDQNX  '                                              86800020
BADMSG   DS    0H                                                       86900020
         DC    AL2(DESCR1-*),X'6000'     LENGTH,MCSFLGS-INREG0-IMMRSP   87000020
         DC    C'IED044I '                                              87100020
BADVAR   DC    8C' ',C' NOT ELIGIBLE FOR PRIMARY'                       87200020
DESCR1   DC    X'0800'                   DESCRIPTOR - IMMEDIATE RESP    87300020
         DC    X'0000'                   ROUTING - IN REG 0             87400020
NFB      DS    0H                                                       87500020
         DC    AL2(DESCR2-*),X'6000'     LENGTH,MCSFLGS-INREG0-IMMRSP   87600020
         DC    C'IED016I STATION '                                      87700020
NFA      DC    8C' ',C' NOT FOUND'                                      87800020
DESCR2   DC    X'0800'                   DESCRIPTOR - IMMEDIATE RESP    87900020
         DC    X'0000'                   ROUTING - IN REG 0             88000020
GOOD     DS    0H                                                       88100020
         DC    AL2(DESCR3-*),X'6000'     LENGTH,MCSFLGS-INREG0-IMMRSP   88200020
         DC    C'IED041I PRIMARY='                                      88300020
GOODVAR  DC    8C' '                                                    88400020
DESCR3   DC    X'0800'                   DESCRIPTOR - IMMEDIATE RESP    88500020
         DC    X'0000'                   ROUTING - IN REG 0             88600020
AL       DS    0H                                                       88700020
         DC    AL2(DESCR4-*),X'6000'     LENGTH,MCSFLGS-INREG0-IMMRSP   88800020
         DC    C'IED042I '                                              88900020
ALRM     DC    8C' ',C' ALREADY PRIMARY'                                89000020
DESCR4   DC    X'0800'                   DESCRIPTOR - IMMEDIATE RESP    89100020
         DC    X'0000'                   ROUTING - IN REG 0             89200020
         PRINT NOGEN                                                    90400020
         TOPCD                                                          90800020
         TTNTD                                                          91200020
         TTRMD                                                          91600020
         TAVTD                                                          92000020
         END                                                            92400020
