         TITLE '''IEDQCO'' - PREPROCESSOR OF START/STOP TERM'           00100020
IEDQCO   CSECT                                                          00200020
         TITLE '''IEDQCO'' - VARY TERMINAL'                             00300020
*********************************************************************** 00400020
*                                                                     * 00500020
*TITLE 'IEDQCO' PROCESSOR OF VARY TERMINAL COMMANDS                   * 00600020
*                                                                     * 00700020
*STATUS -- CHANGE LEVEL 0                                             * 00800020
*                                                                     * 00900020
*FUNCTION -- THIS ROUTINE PROCESSES OPERATOR CONTROL COMMANDS WHICH   * 01000020
*   REQUEST THAT A SPECIFIED TERMINAL BE ACTIVATED OR DEACTIVATED     * 01100020
*   FOR ENTERING, OR FOR BOTH ENTERING AND ACCEPTING.                 * 01200020
*                                                                     * 01300020
*   THE ROUTINE SEARCHES THE TERMNAME TABLE SERIALLY FOR AN ENTRY     * 01400020
*   MATCHING THAT SPECIFIED IN THE COMMON INPUT BLOCK.  IF NO MATCH   * 01500020
*   IS FOUND, AN ERROR MESSAGE IS BUILT AND CONTROL RETURNS TO THE    * 01600020
*   CONTROL MODULE.  WHEN THE ENTRY IS FOUND IT IS TESTED FOR A       * 01700020
*   PROCESS ENTRY (X'20' IN TRMSTATE).  IF IT IS, SINCE PROCESS       * 01800020
*   ENTRIES HAVE NO INVITATION LISTS, AN ERROR MESSAGE IS BUILT AND   * 01900020
*   CONTROL RETURNS TO THE CONTROL MODULE.  THE QCB AT TRMDESTQ IS    * 02000020
*   USED TO OBTAIN THE RLN (QCBRELLN) AND THE DCB (QCBDCBAD).  THE    * 02100020
*   DCB IS TESTED FOR OPEN STATUS, AND IF NOT AN ERROR MESSAGE IS     * 02200020
*   BUILT AND THE ROUTINE RETURNS TO THE CONTROL MODULE.  THE DEB     * 02300020
*   IS ACCESSED FROM DCBDEBAD AND ITS UCB AT DEBUCBAD IS TESTED FOR   * 02400020
*   ZERO.  IF ZERO, THE LINE HAS BEEN OPENED DD DUMMY, SO AN ERROR    * 02500020
*   RESPONSE IS BUILT AND CONTROL EXITS TO THE CONTROL MODULE.  THE   * 02600020
*   LCB ADDRESS IS DETERMINED FROM DCBIOBAD AND THE LCB TESTED FOR    * 02700020
*   DIAL (LCBDIAL ON IN LCBSTAT2).  IF IT IS DIAL, AN ERROR MESSAGE   * 02800020
*   IS BUILT AND THE ROUTINE RETURNS TO THE CONTROL MODULE.  THE      * 02900020
*   LINE IS TESTED FOR STOPPED AND IF NOT THE COMMAND REJECTED.  THE  * 03000020
*   INVITATION LIST IS ACCESSED FROM DCBINVLI.                        * 03100020
*                                                                     * 03200020
*   THE INPUT BLOCK IS TESTED TO SEE IF THIS IS A VARY ON OR OFF.     * 03300020
*   IF ON, THE LIST IS TESTED TO SEE IF ALL ENTRIES ARE ACTIVE.  IF   * 03400020
*   THEY ARE, A RESPONSE MESSAGE IS BUILT AND CONTROL EXITS TO THE    * 03500020
*   CONTROL MODULE.  EACH ENTRY IS TESTED TO SEE IF IT IS THE ENTRY   * 03600020
*   FOR THE TERMINAL.  IF IT IS AND IS NOT ALREADY ACTIVE, IT IS      * 03700020
*   SWAPPED FROM THE INACTIVE TO THE ACTIVE PART OF THE LIST AND      * 03800020
*   SWAPPED FORWARD IF NECESSARY UNTIL IT REACHES ITS PROPER          * 03900020
*   LOCATION IN THE LIST, AND A BIT IS SET TO INDICATE THAT THE       * 04000020
*   LIST WAS CHANGED.  WHEN THE END OF THE LIST IS REACHED, THE BIT   * 04100020
*   IS TESTED.  IF NOT ON, THE TERMINAL WAS ALREADY ACTIVE, SO AN     * 04200020
*   ALREADY ACTIVE MESSAGE IS BUILT AND THE ROUTINE EXITS TO THE      * 04300020
*   CONTROL MODULE.  OTHERWISE AN ACTIVATED MESSAGE IS BUILT AND      * 04400020
*   CONTROL RETURNS TO THE CONTROL MODULE.                            * 04500020
*                                                                     * 04600020
*   IF THE COMMAND IS A VARY OFF, THE LIST IS TESTED FOR ACTIVE       * 04700020
*   STATUS.  IF ALL ENTRIES ARE INACTIVE, A RESPONSE IS BUILT AND     * 04800020
*   CONTROL EXITS TO THE CONTROL MODULE.  EACH ENTRY IS TESTED TO     * 04900020
*   SEE IF IT IS AN ENTRY FOR THE TERMINAL.  IF IT IS AND IT IS       * 05000020
*   ACTIVE, IT IS SWAPPED FROM THE ACTIVE TO THE INACTIVE SIDE OF     * 05100020
*   THE LIST, THE ACTIVE COUNT IS DECREMENTED, AND A BIT IS SET TO    * 05200020
*   INDICATE THAT THE LIST WAS CHANGED.  WHEN ALL ENTRIES IN THE      * 05300020
*   LIST HAVE BEEN EXAMINED, THE BIT IS TESTED.  IF OFF, THE          * 05400020
*   TERMINAL WAS ALREADY INACTIVE SO THE APPROPRIATE RESPONSE IS      * 05500020
*   BUILT AND CONTROL RETURNS TO THE CONTROL MODULE.  OTHERWISE, A    * 05600020
*   TERMINAL STOPPED MESSAGE IS BUILT AND CONTROL RETURNS TO THE      * 05700020
*   CONTROL MODULE.                                                   * 05800020
*                                                                     * 05900020
*ENTRY POINTS --                                                      * 06000020
*        'IEDQCO' TO PROCESS VARY TERMINAL OPERATOR CONTROL           * 06100020
*   COMMANDS.  CALLING SEQUENCE IS                                    * 06200020
*                        LOAD EPLOC=LOADPRFX                          * 06300020
*                        LR   R1,ROPC                                 * 06400020
*                        LR   R15,R0                                  * 06500020
*                        BALR R14,R15                                 * 06600020
*                                                                     * 06700020
*INPUT -- REGISTER 1 - ADDRESS OF OPERATOR CONTROL AVT.  AT THE       * 06800020
*   LOCATION OPCTNME (IN THE COMMON INPUT BLOCK) IS THE NAME OF THE   * 06900020
*   TERMINAL TO BE VARIED, AND AT OPCFLG, X'80' INDICATES A VARY ON   * 07000020
*   COMMAND, X'40' A VARY OFF.                                        * 07100020
*                                                                     * 07200020
*   REGISTER 15 - ENTRY POINT ADDRESS.                                * 07300020
*                                                                     * 07400020
*OUTPUT -- REGISTER 1 - ADDRESS OF APPROPRIATE RESPONSE MESSAGE.      * 07500020
*                                                                     * 07600020
*   REGISTER 15 - RETURN CODE.  VALUES ARE                            * 07700020
*                   0    TERMINAL VARIED OR WAS ALREADY IN THE        * 07800020
*                        STATUS REQUESTED.                            * 07900020
*                   4    TERMINAL COULD NOT BE FOUND OR COULD NOT     * 08000020
*                        BE VARIED.                                   * 08100020
*                                                                     * 08200020
*EXTERNAL ROUTINES -- N/A.                                            * 08300020
*                                                                     * 08400020
*EXITS-NORMAL -- TERMINAL WAS VARIED AS REQUESTED.  RESPONSE BUILT,   * 08500020
*   X'00' RETURN CODE SET.                                            * 08600020
*                                                                     * 08700020
*   TERMINAL WAS ALREADY IN DESIRED STATUS.  RESPONSE BUILT, X'00'    * 08800020
*   RETURN CODE SET.                                                  * 08900020
*                                                                     * 09000020
*EXITS-ERROR -- TERMINAL COULD NOT BE FOUND OR IS A PROCESS ENTRY.    * 09100020
*   ERROR RESPONSE BUILT, X'04' RETURN CODE SET.                      * 09200020
*                                                                     * 09300020
*   LINE IS NOT OPEN, OPEN DD DUMMY, NOT STOPPED, OR DIAL.  ERROR     * 09400020
*   RESPONSE BUILT, X'04' RETURN CODE SET.                            * 09500020
*                                                                     * 09600020
*TABLES/WORK AREAS -- TERMNAME TABLE, OPERATOR CONTROL AVT, AVT,      * 09700020
*   DCB, TERMINAL ENTRY, QCB, LCB, DEB, MESSAGES.                     * 09800020
*                                                                     * 09900020
*ATTRIBUTES -- SERIALLY REUSABLE, REFRESHABLE, ENABLED, TRANSIENT,    * 10000020
*   PROBLEM PROGRAM MODE.                                             * 10100020
*                                                                     * 10200020
*NOTES -- THE OPERATION OF THIS MODULE DEPENDS UPON AN INTERNAL       * 10300020
*   REPRESENTATION OF THE EXTERNAL CHARACTER SET WHICH IS             * 10400020
*   EQUIVALENT TO THE ONE USED AT ASSEMBLY TIME.  THE CODING HAS      * 10500020
*   BEEN ARRANGED SO THAT REDEFINITION OF ''CHARACTER'' CONSTANTS,    * 10600020
*   BY REASSEMBLY, WILL RESULT IN A CORRECT MODULE FOR THE NEW        * 10700020
*   DEFINITIONS.                                                      * 10800020
*                                                                     * 10900020
*   MESSAGES ISSUED BY THIS MODULE ARE                                * 11000020
*              IED016I, IED019I, IED020I, IED025I, IED026I, IED088I   * 11100020
*              IED089I, IED090I, IED091I                              * 11200020
*                                                                     * 11300020
*********************************************************************** 11400020
*                                                                       11500020
*                                                                       11600020
R0       EQU   0                                                        11700020
R1       EQU   1                        PARAMETER                       11800020
ROPC     EQU   2                        OPERATOR CONTROL AVT BASE       11900020
RAVT     EQU   4                        AVT BASE                        12000020
RTNT     EQU   5                        TERMNAME TABLE BASE             12100020
RTERM    EQU   6                        TERMINAL ENTRY BASE             12200020
RQCB     EQU   7                        QCB BASE                        12300020
RLIST    EQU   7                        INVLIST BASE                    12400020
RLCB     EQU   8                        LCB BASE                        12500020
RDCB     EQU   9                        DCB BASE                        12600020
RWORK1   EQU   9                        WORK                            12700020
RWORK2   EQU   10                       WORK                            12800020
RWORK3   EQU   11                       WORK                            12900020
RBASE    EQU   12                       ROUTINE BASE                    13000020
R13      EQU   13                       SAVE AREA                       13100020
R14      EQU   14                       RETURN                          13200020
R15      EQU   15                       ENTRY POINT                     13300020
RLENGTH  EQU   RWORK2                   ENTRY LENGTH                    13400020
RLTH1    EQU   RWORK3                   ENTRY LENGTH - 1                13500020
RSWAP    EQU   RWORK1                   PTR TO ENTRY - 1 - ENTRY LENGTH 13600020
RENTRYX  EQU   RTERM                    PTR TO ENTRY - 1                13700020
ROFF     EQU   RLCB                                                     13800020
RSTART   EQU   RTNT                                                     13900020
         USING IEDQCO,RBASE             ADDRESSABILITY FOR ROUTINE      14000020
         USING IEDQOPC,ROPC             ADDRESSABILITY FOR OP CTL       14100020
         USING IEDQAVTD,RAVT            ADDRESSABILITY FOR AVT          14200020
         USING IEDQTNTD,RTNT            ADDRESSABILITY FOR TNT          14300020
         USING IEDQTRM,RTERM            ADDRESSABILITY FOR TERM         14400020
         USING IEDQQCB,RQCB             ADDRESSABILITY FOR QCB          14500020
         USING IEDQLCB,RLCB             ADDRESSABILITY FOR LCB          14600020
         USING IHADCB,RDCB              ADDRESSABILITY FOR DCB          14700020
         SAVE  (14,12),,IEDQCO-02/18/71                                 14800020
         LR    RBASE,R15                GIVE ROUTINE BASE               14900020
         LR    ROPC,R1                  GET OP CTL AVT ADDRESS          15000020
         L     RAVT,OPCAVTAD            ACCESS AVT                      15100020
         L     RTNT,AVTRNMPT            GET TERMNAME TABLE ADDR         15200020
         LA    RWORK2,OPCONE            SET UP COUNTER                  15300020
         LH    RWORK3,TNTLEN            GET NUMBER OF ENTRIES           15400020
         SR    RTERM,RTERM              CLEAR                           15500020
         IC    RTERM,TNTENLEN           GET ENTRY LENGTH                15600020
         BCTR  RTERM,R0                                                 15700020
         CH    RTERM,AVTHA7           EIGHT BYTE TERMNAME               15710020
         BE    HTRMOK                   YES, VALID LENGTH               15720020
         LA    R15,OPCTNME+1(RTERM)     PTR TO FIRST BLANK              15730020
        CLI   OPCZERO(R15),AVTEBLNK     IS IT A BLANK                   15740020
         BNE   ERROR                    NO, ERROR                       15750020
HTRMOK   EQU   *                                                        15760020
         LA    RTNT,TNTFIRST            GET TO START OF ENTRIES         15800020
LOOP     EQU   *                                                        15900020
         CR    RWORK2,RWORK3            END OF TABLE                    16000020
         BH    ERROR                    YES - TAKE ERROR EXIT           16100020
*                                                                       16200020
         EX    RTERM,COMP               RIGHT ENTRY                     16300020
         BE    FOUND                    YES - PROCESS IT                16400020
*                                                                       16500020
         LA    RTNT,OPCFOUR(RTERM,RTNT) BUMP TO NEXT                    16600020
         LA    RWORK2,OPCONE(,RWORK2)   ADD ONE TO COUNTER              16700020
         B     LOOP                     LOOK AT NEXT ENTRY              16800020
*                                                                       16900020
ERROR    EQU   *                                                        17000020
         MVC   BADMSG(OPCEIGHT),OPCTNME PUT NAME IN ERROR MSG           17100020
         LA    R1,BAD                   GET MSG ADDR                    17200020
SETBAD   EQU   *                                                        17300020
         LA    R15,OPCFOUR              SET BAD RETURN                  17400020
         B     EXIT                                                     17500020
*                                                                       17600020
FOUND    EQU   *                                                        17700020
         STH   RWORK2,OPCDATA           SAVE TNT OFFSET                 17800020
         AR    RTNT,RTERM               BUMP PAST TERMNAME              17900020
         MVC   OPCWORK+1(OPCTHREE),OPCONE(RTNT) PUT ON BDRY             18000020
         L     RTERM,OPCWORK            GET TERM ADDR                   18100020
         TM    TRMSTATE,PROC+DIST        DISTRIBUTION,PROCESS,OR CASCDE 18200020
         BNZ   PROCM                     YES, REJECT COMMAND            18300020
         L     RQCB,TRMDESTQ-1          GET QCB ADDR                    18500020
         SR    RWORK2,RWORK2            CLEAR                           18600020
         IC    RWORK2,QCBRELLN          GET RELATIVEL INE               18700020
         LR    R0,RWORK2                                                18800020
         L     RDCB,QCBDCBAD-1          GET DCB ADDR                    18900020
         LR    R0,RWORK2                SAVE FOR MULTIPLY               19000020
*                                                                       19100020
         CLI   DCBTIOT,A                LINE OPEN                       19200020
         BNL   NOM                      NO - REJECT COMMAND             19300020
*                                                                       19400020
         LR    R15,RWORK2               GET RLN                         19500020
         SLL   R15,OPCTWO               MULTIPLY BY FOUR                19600020
         L     R14,DCBDEBAD             GET DEB ADDR                    19700020
         CLC   QCBRELLN(OPCONE),DEBNMEXT-DEBNMSUB(R14)     EXTENT HIGH  19730020
         BH    NOM                      YES, OPENED DD DUMMY            19760020
         L     R15,DEBUCBAD-4-DEBNMSUB(R14,R15) GET UCB ADDR            19800020
         LA    R15,OPCZERO(R15)         CLEAR HIGH BYTE                 19900020
         LTR   R15,R15                  OPENED DD DUMMY                 20000020
         BZ    NOM                      YES - REJECT COMMAND            20100020
         CLI   DEBOPATB-DEBNMSUB(R14),OPCTHREE      FOR PUTPUT ONLY     20200020
         BE    OUTPO                     YES, ERROR                     20300020
*                                                                       20400020
         SR    R1,R1                    CLEAR                           20500020
         IC    R1,DCBEIOBX              GET INDEX TO IOB                20600020
         MR    R0,R0                    GET INDEX TO PROPER IOB         20700020
         L     RLCB,DCBIOBAD            GET FIRST IOB ADDR              20800020
         LA    RLCB,OPCZERO(RLCB)       CLEAR HIGH BYTE                 20900020
         AR    RLCB,R1                  GET ADDR OF PROPER IOB          21000020
         LA    R1,LCBFLAG1-IEDQLCB      GET LCB INDEX                   21100020
         SR    RLCB,R1                  GET LCB ADDR                    21200020
         TM    OPCED,HEX80               IS THE RESTART                 21300020
         BZ    FOUND2                    NO PROCEED                     21400020
         TM    AVTBIT3,AVTSTAIN          SHOULD RESTART THES ELEMENT    21500020
         BZ    SETGOOD                   NO, GET OUT                    21600020
         B     FOUND3                    BYPASS CKING LCB OTOPED        21700020
FOUND2   EQU   *                                                        21800020
         CLI   LCBSTAT1,AVTEZERO        LINE STOPPED                    21900020
         BNE   NEWERR                   NO - REJDCT COMMAND             22000020
*                                                                       22100020
FOUND3   EQU   *                                                        22200020
         TM    LCBSTAT2,LCBDIAL         DIAL LCB                        22300020
         BO    NOWAY                    YES - REJECT COMMAND            22400020
*                                                                       22500020
         LA    RLIST,DCBINVLI-4         GET TO LIST START               22600020
         SLL   RWORK2,OPCTWO            MULTIPLY RLN BY FOUR            22700020
         L     RLIST,OPCZERO(RWORK2,RLIST) GET LIST ADDR                22800020
         LA    RLIST,OPCZERO(RLIST)         CLEAR HIGH BYTE             22900020
         CLI   OPCZERO(RLIST),OPCZERO                                   23000020
         BE    OUTPO                                                    23100020
         LA    R1,8(RLIST)               POINTER TO BEGINNING OF LIST   23200020
         ST    R1,LCBINVPT-1             SAVE FOR LINE ACTIVATE         23300020
         CLI   OPCFLG,OFF               VARY ON OR OFF                  23400020
         BE    INACT                    OFF - GO PROCESS                23500020
*                                                                       23600020
         MVC   S(OPCEIGHT),OPCTNME      PUT NAME IN MSG                 23700020
         LA    R1,SMSG                  GET MSG ADDR                    23800020
         ST    R1,OPCWORK               SAVE IT                         23900020
         B     CSSTART                    ACTIVATE                      24000020
*                                                                       24100020
RTNCO    EQU   *                                                        24200020
         TM    OPCBITSW,OPCTEMPN        ANY ENTRIES MOVED               24300020
         BNO   ALREADY                  NO - ALREADY VARIED             24400020
*                                                                       24500020
         L     R1,OPCWORK                                               24600020
SETBIT   EQU   *                                                        24700020
         OI    OPCCKBIT,OPCCKPTN+OPCINVN TURN ON CKPT BITS              24800020
SETGOOD  EQU   *                                                        24900020
         SR    R15,R15                  SET GOOD RETURN                 25000020
EXIT     EQU   *                                                        25100020
         ST    R1,OPCREG1(,R13)                                         25200020
         RETURN (14,12),T,RC=(15)                                       25300020
*                                                                       25400020
OUTPO    MVC   OU(OPCEIGHT),OPCTNME                                     25500020
         LA    R1,OUTO                                                  25600020
         CLI   OPCVBCD2,AVTEZERO         VARY BOTH!                     25630020
         BE    SETBAD                    NO, REALLY BAD                 25660020
         CLI   OPCFLG,OFF                STOP OR START                  25690020
         BE    STOPPED                   STOP                           25720020
         B     STARTED                   START                          25750020
PROCM    EQU   *                                                        25800020
         MVC   PE(OPCEIGHT),OPCTNME     PUT NAME IN MSG                 25900020
         LA    R1,PEM                   GET MSG ADDR                    26000020
         B     SETBAD                                                   26100020
*                                                                       26200020
NOM      EQU   *                                                        26300020
         MVC   NO(OPCEIGHT),OPCTNME     PUT NAME IN MSG                 26400020
         LA    R1,NOP                   GETMMSG ADDR                    26500020
         B     SETBAD                                                   26600020
*                                                                       26700020
NOWAY    EQU   *                                                        26800020
         MVC   D(OPCEIGHT),OPCTNME      PUT NAME IN MSG                 26900020
         LA    R1,DMSG                  GET MSG ADDR                    27000020
         B     SETBAD                                                   27100020
*                                                                       27200020
INACT    EQU   *                                                        27300020
         MVC   P(OPCEIGHT),OPCTNME      PUT NAME IN MSG                 27400020
         LA    R1,PMSG                  GET MSG ADDR                    27500020
         ST    R1,OPCWORK               SAVE IT                         27600020
         B     CTSTART                                                  27700020
*                                                                       27800020
NEWERR   EQU   *                                                        27900020
         LA    R1,ERMSG                 GET MSG ADDR                    28000020
         B     SETBAD                                                   28100020
*                                                                       28200020
STARTED  EQU   *                                                        28300020
         MVC   AS(OPCEIGHT),OPCTNME     PUT NAME IN MSG                 28400020
         LA    R1,ASMSG                 GET MSG ADDR                    28500020
         B     SETGOOD                                                  28600020
*                                                                       28700020
STOPPED  EQU   *                                                        28800020
         MVC   AP(OPCEIGHT),OPCTNME     PUT NAME IN MSG                 28900020
         LA    R1,APMSG                 GET MSG ADDR                    29000020
         B     SETGOOD                                                  29100020
*                                                                       29200020
ALREADY  EQU   *                                                        29300020
         CLI   OPCFLG,OFF               VARY ON OR OFF                  29400020
         BE    ALOF                     OFF                             29500020
*                                                                       29600020
         B     ALON                                                     29700020
*                                                                       29800020
ALON     EQU   *                                                        29900020
         CLI   OPCVBCD2,AVTEZERO         VARY ON BOTH                   30000020
         BE    STARTED                  YES                             30100020
*                                                                       30200020
         B     SETBIT                                                   30300020
*                                                                       30400020
ALOF     EQU   *                                                        30500020
         CLI   OPCVBCD2,AVTEZERO         VARY OFF BOTH                  30600020
         BE    STOPPED                  YES                             30700020
*                                                                       30800020
         B     SETBIT                                                   30900020
*                                                                       31000020
         EJECT                                                          31100020
         TITLE '''IEDQCS'' - START TERMINAL'                            31200020
CSSTART  SR    ROFF,ROFF                SET UP FIRST ENTRY              31300020
         STH   ROFF,OPCDATA+2           SAVE FOR INDEXING               31400020
         SR    RLENGTH,RLENGTH          HOUSEKEEP                       31500020
         SR    RLTH1,RLTH1              HOUSEKEEP                       31600020
         IC    RLENGTH,OPCTWO(RLIST)   LENGTH OF ENTRY                  31700020
         LR    RLTH1,RLENGTH            LENGTH OF ENTRY                 31800020
         BCTR  RLTH1,OPCZERO            DECREMENT FOR EXECUTE           31900020
GTENTRY1 LH    ROFF,OPCDATA+2           GET NEXT ENTRY                  32000020
         LA    ROFF,OPCONE(ROFF)        BUMP ONE                        32100020
         STH   ROFF,OPCDATA+2                                           32200020
         CLC   OPCZERO(OPCONE,RLIST),OPCONE(RLIST) ALLENTRIES ACTIVE    32300020
         BE    RTNCO                    YES                             32400020
*                                                                       32500020
         CLC   OPCDATA+3(OPCONE),OPCZERO(RLIST)  OUT OF ENTRIES         32600020
         BH    RTNCO                    YES                             32700020
*                                                                       32800020
         SLL   ROFF,OPCONE              MULTIPLY BY TWO FOR LENGTH      32900020
         LR    RENTRYX,RLIST               BEGINNING                    33000020
         SR    RENTRYX,ROFF                BACK TO ENTRY                33100020
         CLC   OPCZERO(OPCTWO,RENTRYX),OPCDATA TO BE ACTIVATED          33200020
         BNE   GTENTRY1                 NO GET NEXT                     33300020
*                                                                       33400020
         LA    RENTRYX,OPCSEVEN(RLIST)  PTR TO FIRST ENTRY INDEX        33500020
         SR    R14,R14                  HOUSEKEEP                       33600020
         IC    R14,OPCONE(RLIST)        NUMBER OF ACTIVE ENTRIES        33700020
         LTR   R14,R14                  ARE THERE ANY ACTIVE ENTRIES    33800020
         BZ    CKINACT                    NO  CK THE INACTIVE           33900020
CKNEXT1  AR    RENTRYX,RLENGTH             GO TO NEXT ENTRY'S INDEX     34000020
         CLC   OPCZERO(OPCONE,RENTRYX),OPCDATA+3  IS THIS AN ENTRY?     34100020
         BE    GTENTRY1                  YES, ITS ACTIVE, GET ANOTHER   34200020
         BCT   R14,CKNEXT1              IF NOT END OF ACTIVE, GO BACK   34300020
CKINACT  LA    RENTRYX,OPCONE(RENTRYX)  GET BY ACTIVE FLAG              34400020
         TM    OPCTHREE(RLIST),EOTENT    'EOT' ENTRY PRESENT            34500020
         BZ    CKINACT1                 NO, GO ON                       34600020
         LA    RENTRYX,OPCONE(RENTRYX)  SKIP IT, TOO                    34700020
CKINACT1 AR    RENTRYX,RLENGTH          GET TO NEXT INDEX               34800020
         CLC   OPCZERO(OPCONE,RENTRYX),OPCDATA+3  IS THIS AN ENTRY      34900020
         BNE   CKINACT1                   NO, GET ANOTHER               35000020
         OI    OPCBITSW,OPCTEMPN        SET 'MOVED' INDICATOR           35100020
         SR    RENTRYX,RLENGTH            YES, SET UP FOR SWAP          35200020
         LR    RSWAP,RENTRYX            ONE BYTE SHY OF                 35300020
         SR    RSWAP,RLENGTH              ENTRY AND PREVIOUS ENTRY      35400020
ACTIVATE CLI   OPCZERO(RENTRYX),ACTEND  FIRST INACTIVE ENTRY?           35500020
         BE    MACTIVE                  YES, MAKE IT ACTIVE             35600020
         EX    RLTH1,SWAP1              SWAP                            35700020
         EX    RLTH1,SWAP2                 THIS ENTRY                   35800020
         EX    RLTH1,SWAP3                    AND PRECEDING ENTRY       35900020
         SR    RENTRYX,RLENGTH          BACK UP ONE ENTRY               36000020
         SR    RSWAP,RLENGTH            BACK PREVIOUS ENTRY, ONE ENTRY  36100020
         B     ACTIVATE                                                 36200020
MACTIVE  TM    OPCTHREE(RLIST),EOTENT    EOT ENTRY PRESENT              36300020
         BO    MACTIVE1                 YES, SPECIAL CARE               36400020
         EX    RLTH1,MOVACT             PLACE ENTRY ON ACTIVE SIDE      36500020
         LA    R14,OPCZERO(RLENGTH,RENTRYX) POINT TO NEW END OF ACTIVE  36600020
         BCTR  RENTRYX,OPCZERO         GET TO ONE SYY                   36700020
         BCTR  RSWAP,OPCZERO           GET TO ONE SHY                   36800020
         MVI   OPCZERO(R14),ACTEND      RESET ACTIVE POINTER            36900020
MACTIVE2 SR    R14,R14                  CLEAR REGISTER                  37000020
         IC    R14,OPCONE(RLIST)        GET NUMBER OF ACTIVE ENTRIES    37100020
         LA    R14,OPCONE(R14)          INCREMENT FOR BCT               37200020
ACTLOOP  BCT   R14,ACTPOS               IF NOT LAST POSITION COMPARE    37300020
RETURNA  IC    R14,OPCONE(RLIST)        GET                             37400020
         LA    R14,OPCONE(R14)          AND INCREMENT                   37500020
         STC   R14,OPCONE(RLIST)           NUMBER OF ACTIVE ENTRIES     37600020
         B     GTENTRY1                 RETURN FOR ANOTHER              37700020
ACTPOS   CLC   OPCZERO(OPCONE,RENTRYX),OPCDATA+3 ENTRY IN POSITION      37800020
         BL    RETURNA                  PREVIOUS ENTRY LOWER, DONE      37900020
         EX    RLTH1,SWAP1              SWAP THIS ENTRY                 38000020
         EX    RLTH1,SWAP2                 AND                          38100020
         EX    RLTH1,SWAP3                    PRECEDING ENTRY           38200020
         SPACE 2                                                        38300020
         SR    RENTRYX,RLENGTH          BACK UP                         38400020
         SR    RSWAP,RLENGTH               ONE ENTRY                    38500020
         B     ACTLOOP                                                  38600020
         EJECT                                                          38700020
         TITLE '''IEDQCT'' - STOP TERMINAL'                             38800020
*                                                                       38900020
CTSTART  EQU   *                                                        39000020
         SR    ROFF,ROFF                SET UP FIRST ENTRY              39100020
         STH   ROFF,OPCDATA+2           SAVE FOR INDEXING               39200020
         SR    RLENGTH,RLENGTH          HOUSEKEEP                       39300020
         SR    RLTH1,RLTH1              HOUSEKEEP                       39400020
         IC    RLENGTH,OPCTWO(RLIST)   LENGTH OF ENTRY                  39500020
         LR    RLTH1,RLENGTH            LENGTH OF ENTRY                 39600020
         BCTR  RLTH1,OPCZERO            DECREMENT FOR EXECUTE           39700020
GTENTRY  LH    ROFF,OPCDATA+2           GET NEXT ENTRY                  39800020
         CLI   OPCONE(RLIST),OPCZERO    ALLENTRIES INACTIVE             39900020
         BE    RTNCO                    YES                             40000020
*                                                                       40100020
         LA    ROFF,OPCONE(ROFF)        BUMP ONE                        40200020
         STH   ROFF,OPCDATA+2                                           40300020
         CLC   OPCDATA+3(OPCONE),OPCZERO(RLIST)  OUT OF ENTRIES         40400020
         BH    RTNCO                    YES                             40500020
*                                                                       40600020
         SLL   ROFF,OPCONE              MULTIPLY BY TWO FOR LENGTH      40700020
         LR    RENTRYX,RLIST               BEGINNING                    40800020
         SR    RENTRYX,ROFF                BACK TO ENTRY                40900020
         CLC   OPCZERO(OPCTWO,RENTRYX),OPCDATA TO BE DEACTI ATED        41000020
         BNE   GTENTRY                  NO GET NEXT                     41100020
ACTALL   LA    RENTRYX,OPCSEVEN(RLIST)  PTR TO FIRST ENTRY INDEX        41200020
         SR    R14,R14                  HOUSEKEEP                       41300020
         IC    R14,OPCONE(RLIST)        NUMBER OF ACTIVE ENTRIES        41400020
CKNEXT   AR    RENTRYX,RLENGTH             GO TO NEXT ENTRY'S INDEX     41500020
         CLC   OPCZERO(OPCONE,RENTRYX),OPCDATA+3  IS THIS AN ENTRY?     41600020
         BE    DACTIV                    YES, ITS ACTIVE, DEACTIVZTE    41700020
         BCT   R14,CKNEXT               IF NOT END OF ACTIVE, GO BACK   41800020
         B     GTENTRY                 GET THE NEXT --DONEWITH THIS     41900020
DACTIV   EQU   *                                                        42000020
         OI    OPCBITSW,OPCTEMPN        SET 'MOVED' INDICATOR           42100020
         LR    RSWAP,RENTRYX            HOUREKEEP                       42200020
         SR    RENTRYX,RLENGTH          SET TO ENTRY-LENGTH-1           42300020
         BCT   R14,SWAPLOOP                                             42400020
         B     LOOPOUT                                                  42500020
         SPACE 2                                                        42600020
SWAPLOOP EX    RLTH1,SWAP1              SWAP                            42700020
         EX    RLTH1,SWAP2                 THIS ENTRY                   42800020
         EX    RLTH1,SWAP3                AND NEXT ENTRY                42900020
         AR    RENTRYX,RLENGTH          GO TO NEXT ENTRY                43000020
         AR    RSWAP,RLENGTH              GET TO THIS ENTRY             43100020
         BCT   R14,SWAPLOOP             NOT DINE, RRTURN                43200020
         SPACE 2                                                        43300020
LOOPOUT  IC    R14,OPCTWO(RLIST)        DONE, GET ENTRY LENGTH          43400020
         LA    R15,OPCONE               GET'ONE'FOR USEAGE              43500020
         TM    OPCTHREE(RLIST),EOTENT   IS THIS EOT-FE  (BSC)           43600020
         BO    SFTEOT                     YES, SPECIAL TREATMENT        43700020
         SPACE 2                                                        43800020
SFTLOOP  MVC   OPCONE(OPCONE,RSWAP),OPCZERO(RSWAP)  MOVE ONE CHARACTER  43900020
         SR    RSWAP,R15                  AT A  TIME, STARTING          44000020
         BCT   R14,SFTLOOP                WITH THE LAST CHARACTER       44100020
         MVI   OPCONE(RSWAP),ACTEND     INSERT ACTIVE END CHACTER       44200020
RSETACT  IC    R14,OPCONE(RLIST)        COUNT OF ACTIVE ENTRIES         44300020
         SR    R14,R15                    ONE LESS                      44400020
         STC   R14,OPCONE(RLIST)        RESET                           44500020
         B     GTENTRY                  TRY NEXT                        44600020
         SPACE 2                                                        44700020
SFTEOT   MVC   OPCDATA+8(OPCTWO),OPCONE(RSWAP)  SAVE EOT-FE             44800020
SFTEOT1 MVC OPCTWO(OPCONE,RSWAP),OPCZERO(RSWAP)  MOVE  ONE CHARACTER    44900020
         SR    RSWAP,R15                   AT A TIME                    45000020
         BCT   R14,SFTEOT1                 STARTING WITH THE LASTP      45100020
         SPACE 2                                                        45200020
         MVC   OPCONE(OPCTWO,RSWAP),OPCDATA+8   RESET EOT-FE            45300020
         B     RSETACT                  SET ACTIVE COUNT                45400020
         SPACE 3                                                        45500020
MACTIVE1 LA    R14,OPCTWO               HOUSEKEEP                       45600020
         SR    RENTRYX,R14              BACK UP TWO FOR EOTFE           45700020
         SR    RSWAP,R14                  SAME                          45800020
         MVC   OPCDATA+8(OPCTWO),OPCONE(RENTRYX)  SAVE EOTFE            45900020
         EX    RLTH1,MOVEACT1           MOVE TO ACTIVE                  46000020
         LA    R14,OPCONE(RLENGTH,RENTRYX)  ADDRESSING FOR EOTFE        46100020
         MVC   OPCZERO(OPCTWO,R14),OPCDATA+8     RESET EOTFE            46200020
         B     MACTIVE2                 CARRY ON                        46300020
         EJECT                                                          46400020
HEX80    EQU   X'80'                                                    46500020
PROC     EQU   X'20'                                                    46600020
DIST     EQU   X'40'                                                    46650020
A        EQU   C'A'                                                     46700020
OFF      EQU   X'40'                                                    46800020
BITSOFF  EQU   X'E0'                                                    46900020
ACTEND   EQU   X'FE'                                                    47000020
EOTENT   EQU   X'80'     EOT(BSC)   IN STATUS BYTE                      47100020
HEX40    EQU   X'40'                                                    47200020
COMP     CLC   OPCTNME(OPCZERO),OPCZERO(RTNT)                           47300020
SWAP1    XC    OPCONE(OPCZERO,RSWAP),OPCONE(RENTRYX)                    47400020
SWAP2    XC    OPCONE(OPCZERO,RENTRYX),OPCONE(RSWAP)                    47500020
SWAP3    XC    OPCONE(OPCZERO,RSWAP),OPCONE(RENTRYX)                    47600020
MOVACT   MVC   OPCZERO(OPCZERO,RENTRYX),OPCONE(RENTRYX)                 47700020
MOVEACT1 MVC   OPCONE(OPCZERO,RENTRYX),OPCTHREE(RENTRYX)                47800020
ERMSG    DS    0H                                                       47830020
         DC    AL2(DESCR0-*),X'6000'     LENGTH,MCSFLGS-INREG0-IMMRS    47860020
         DC    C'IED089I LINE ACTIVE - VARY TERMINAL'                   47890020
         DC    C' COMMAND REJECTED'                                     47920020
DESCR0   DC    X'0800'                   DESCRIPTOR - IMMEDIATE RESP    47950020
         DC    X'0000'                   ROUTING - IN REG 0             47980020
BAD      DS    0H                                                       48010020
         DC    AL2(DESCR1-*),X'6000'     LENGTH,MCSFLGS-INREG0-IMMRS    48040020
         DC    C'IED016I STATION '                                      48070020
BADMSG   DC    8C' ',C' NOT FOUND'                                      48100020
DESCR1   DC    X'0800'                   DESCRIPTOR - IMMEDIATE RESP    48130020
         DC    X'0000'                   ROUTING - IN REG 0             48160020
ASMSG    DS    0H                                                       48190020
         DC    AL2(DESCR2-*),X'6000'     LENGTH,MCSFLGS-INREG0-IMMRS    48220020
         DC    C'IED019I '                                              48250020
AS       DC    8C' ',C' ALREADY STARTED'                                48280020
DESCR2   DC    X'0800'                   DESCRIPTOR - IMMEDIATE RESP    48310020
         DC    X'0000'                   ROUTING - IN REG 0             48340020
APMSG    DS    0H                                                       48370020
         DC    AL2(DESCR3-*),X'6000'     LENGTH,MCSFLGS-INREG0-IMMRS    48400020
         DC    C'IED025I '                                              48430020
AP       DC    8C' ',C' ALREADY STOPPED'                                48460020
DESCR3   DC    X'0800'                   DESCRIPTOR - IMMEDIATE RESP    48490020
         DC    X'0000'                   ROUTING - IN REG 0             48520020
SMSG     DS    0H                                                       48550020
         DC    AL2(DESCR4-*),X'6000'     LENGTH,MCSFLGS-INREG0-IMMRS    48580020
         DC    C'IED020I '                                              48610020
S        DC    8C' ',C' STARTED'                                        48640020
DESCR4   DC    X'0800'                   DESCRIPTOR - IMMEDIATE RESP    48670020
         DC    X'0000'                   ROUTING - IN REG 0             48700020
PMSG     DS    0H                                                       48730020
         DC    AL2(DESCR5-*),X'6000'     LENGTH,MCSFLGS-INREG0-IMMRS    48760020
         DC    C'IED026I '                                              48790020
P        DC    8C' ',C' STOPPED'                                        48820020
DESCR5   DC    X'0800'                   DESCRIPTOR - IMMEDIATE RESP    48850020
         DC    X'0000'                   ROUTING - IN REG 0             48880020
DMSG     DS    0H                                                       48910020
         DC    AL2(DESCR6-*),X'6000'     LENGTH,MCSFLGS-INREG0-IMMRS    48940020
         DC    C'IED088I '                                              48970020
D        DC    8C' ',C' ON DIAL LINE - CANNOT BE VARIED'                49000020
DESCR6   DC    X'0800'                   DESCRIPTOR - IMMEDIATE RESP    49030020
         DC    X'0000'                   ROUTING - IN REG 0             49060020
PEM      DS    0H                                                       49090020
         DC    AL2(DESCR7-*),X'6000'     LENGTH,MCSFLGS-INREG0-IMMRS    49120020
         DC    C'IED090I '                                              49150020
PE       DC    8C' ',C' IS NOT SINGLE ENTRY'                            49180020
DESCR7   DC    X'0800'                   DESCRIPTOR - IMMEDIATE RESP    49210020
         DC    X'0000'                   ROUTING - IN REG 0             49240020
NOP      DS    0H                                                       49270020
         DC    AL2(DESCR8-*),X'6000'     LENGTH,MCSFLGS-INREG0-IMMRS    49300020
         DC    C'IED091I LINE FOR '                                     49330020
NO       DC    8C' ',C' NOT OPEN'                                       49360020
DESCR8   DC    X'0800'                   DESCRIPTOR - IMMEDIATE RESP    49390020
         DC    X'0000'                   ROUTING - IN REG 0             49420020
OUTO     DS    0H                                                       49450020
         DC    AL2(DESCR9-*),X'6000'     LENGTH,MCSFLGS-INREG0-IMMRS    49480020
         DC    C'IED046I LINE FOR '                                     49510020
OU       DC    8C' ',C' IS OUTPUT ONLY STATION'                         49540020
DESCR9   DC    X'0800'                   DESCRIPTOR - IMMEDIATE RESP    49570020
         DC    X'0000'                   ROUTING - IN REG 0             49600020
*                                                                       49900020
         PRINT NOGEN                                                    50000020
         TTNTD                                                          50100020
         TOPCD                                                          50200020
         TAVTD                                                          50300020
         DCBD  DSORG=TX                                                 50400020
         TTRMD                                                          50500020
         TQCBD                                                          50600020
         TLCBD                                                          50700020
         TDEBD                                                          50800020
         END                                                            50900020
