         TITLE '''IEDQCP'' - MODIFY TRACE'                              00200020
IEDQCP   CSECT                                                          00400020
*********************************************************************** 00600020
*                                                                     * 00800020
*TITLE 'IEDQCP' PROCESSOR OF MODIFY TRACE COMMANDS                    * 01000020
*                                                                     * 01200020
*STATUS -- CHANGE LEVEL 0                                             * 01400020
*                                                                     * 01600020
*FUNCTION -- THIS ROUTINE PROCESSES OPERATOR CONTROL COMMANDS WHICH   * 01800020
*   REQUEST A CHANGE OF THE TRACE STATUS FOR A SPECIFIED LINE.        * 02000020
*                                                                     * 02200020
*   THE ALTER TRACE STATUS ROUTINE TESTS THE COMMON INPUT BLOCK TO    * 02400020
*   DETERMINE IF THE DDNAME/RLN OR THE HARDWARE ADDRESS FORMAT WAS    * 02600020
*   SPECIFIED.  IF DDNAME, THE RLN IS TESTED FOR 'ALL'.  IF ALL,      * 02800020
*   THE COMMAND IS REJECTED, AS TRACE CAN ONLY BE ALTERED ON A        * 03000020
*   SINGLE LINE BASIS, AND CONTROL RETURNS TO THE CONTROL MODULE.     * 03200020
*   OTHERWISE, THE RLN IS CONVERTED TO HEXADECIMAL AND THE RESULT     * 03400020
*   TESTED FOR ZERO OR GREATER THAN 255.  EITHER CASE IS AN           * 03600020
*   INVALID RELATIVE LINE AND THE COMMAND IS REJECTED AND CONTROL     * 03800020
*   RETURNS TO THE CONTROL MODULE.  IF THE RLN IS VALID, THE TCB      * 04000020
*   IS OBTAINED FROM AVTTCB AND THE TIOT (AT TCB+12) IS SERIALLY      * 04200020
*   SEARCHED FOR THE DDNAME SPECIFIED.  IF NO MATCH IS FOUND, AN      * 04400020
*   ERROR MESSAGE IS BUILT AND THE ROUTINE EXITS TO THE CONTROL       * 04600020
*   MODULE.  WHEN A MATCHING ENTRY IS FOUND, ITS OFFSET INTO THE      * 04800020
*   TIOT IS SAVED.                                                    * 05000020
*                                                                     * 05200020
*   FOR BOTH INPUT FORMATS, THE DEB CHAIN IS ACCESSED FROM TCB+8,     * 05400020
*   AND EACH DCB IS EXAMINED TO SEE IF IT IS A TCAM LINE DCB          * 05600020
*   (DCB AT DEBDCBAD, DCBDSORG OF X'40').  IF NOT, AND THE END OF     * 05800020
*   THE DEB CHAIN IS REACHED, AN ERROR MESSAGE IS BUILT AND CONTROL   * 06000020
*   RETURNS TO THE CONTROL MODULE.                                    * 06200020
*                                                                     * 06400020
*   FOR DDNAME FORMAT, THE TCAM LINE DCB'S TIOT OFFSET IS COMPARED    * 06600020
*   TO THAT CALCULATED ABOVE.  IF THEY ARE NOT THE SAME, THE          * 06800020
*   ROUTINE RESUMES SEARCHING THE DEB CHAIN.  WHEN THE PROPER DCB     * 07000020
*   IS FOUND, THE RELATIVE LINE IS COMPARED TO THE NUMBER OF LINES    * 07200020
*   IN THE LINE GROUP (DEBNMEXT).  IF IT IS HIGHER, AN ERROR          * 07400020
*   MESSAGE IS BUILT AND CONTROL RETURNS TO THE CONTROL MODULE.       * 07600020
*   THE LINE IS THEN TESTED FOR OPEN DD DUMMY (DEBUCBAD OF ZERO).     * 07800020
*   IF SO, AN ERROR MESSAGE IS BUILT AND CONTROL EXITS TO THE         * 08000020
*   CONTROL MODULE.                                                   * 08200020
*                                                                     * 08400020
*   FOR LINE ADDRESS FORMAT, EACH UCB ASSOCIATED WITH A DEB IS        * 08600020
*   COMPARED TO THE ADDRESS SPECIFIED AND THE DEB CHAIN IS SEARCHED   * 08800020
*   UNTIL A MATCH IS FOUND.                                           * 09000020
*                                                                     * 09200020
*   ONCE THE PROPER DCB IS OBTAINED FOR BOTH COMMAND FORMATS, IT IS   * 09400020
*   TESTED FOR AN OPEN CONDITION.  IF IT IS NOT OPEN, AN ERROR        * 09600020
*   MESSAGE IS BUILT AND CONTROL RETURNS TO THE CONTROL MODULE.       * 09800020
*   OTHERWISE, THE LCB ADDRESS IS COMPUTED FROM DCBIOBAD+(DCBEIOBX    * 10000020
*   *RLN)-SIZE OF AN IOB.  THE AVT IS TESTED FOR THE PRESENCE OF A    * 10200020
*   TRACE TABLE (AVTRACE NOT ZERO) AND IF NOT, AN ERROR MESSAGE IS    * 10400020
*   BUILT AND CONTROL RETURNS TO THE CONTROL MODULE.                  * 10600020
*                                                                     * 10800020
*   IF TRACE IS TO BE STARTED, THE TRACE BIT IS TESTED.  IF ALREADY   * 11000020
*   ON, A RESPONSE IS BUILT AND CONTROL RETURNS TO THE CONTROL        * 11200020
*   MODULE.  OTHERWISE THE TRACE BIT IS TURNED ON (LCBTRACE IN        * 11400020
*   LCBSTAT2), A BIT IS TURNED ON TO INDICATE CHECKPOINTING IS        * 11600020
*   NEEDED, A RESPONSE IS BUILT AND CONTROL EXITS TO THE CONTROL      * 11800020
*   MODULE.                                                           * 12000020
*                                                                     * 12200020
*   IF TRACE IS TO BE STOPPED BUT THE LCB TRACE BIT IS NOT ON, AN     * 12400020
*   ALREADY STOPPED MESSAGE IS BUILT AND THE ROUTINE RETURNS TO THE   * 12600020
*   CONTROL MODULE.  OTHERWISE THE BIT IS TURNED OFF, THE CHECK-      * 12800020
*   POINT BIT IS TURNED ON, THE RESPONSE IS BUILT, AND THE ROUTINE    * 13000020
*   EXITS TO THE CONTROL MODULE.                                      * 13200020
*                                                                     * 13400020
*ENTRY POINTS --                                                      * 13600020
*        'IEDQCP' TO PROCESS MODIFY TRACE OPERATOR CONTROL COMMANDS   * 13800020
*   CALLING SEQUENCE IS                                               * 14000020
*                        LOAD EPLOC=LOADPRFX                          * 14200020
*                        LR   R1,ROPC                                 * 14400020
*                        LR   R15,R0                                  * 14600020
*                        BALR R14,R15                                 * 14800020
*                                                                     * 15000020
*INPUT -- REGISTER 1 - ADDRESS OF THE OPERATOR CONTROL AVT.  THE      * 15200020
*   COMMON INPUT BLOCK IS IN THIS AVT AT THE TAG OPCCKELE.  FIELDS    * 15400020
*   IN THE BLOCK USED BY THIS MODULE ARE                              * 15600020
*                   +4   OPCLEN    X'00' RLN ALL                      * 15800020
*                                  X'80' NO RLN (LINE ADDRESS)        * 16000020
*                                  1 - 3 LENGTH OF RLN                * 16200020
*                   +5   OPCRLN    RELATIVE LINE NUMBER               * 16400020
*                   +8   OPCTNME   DDNAME OR LINE ADDRESS             * 16600020
*                   +18  OPCFLG    X'80' IF MODIFY TRACE ON           * 16800020
*                                  X'40' IF MODIFY TRACE OFF          * 17000020
*                                                                     * 17200020
*   REGISTER 15 - ENTRY POINT ADDRESS.                                * 17400020
*                                                                     * 17600020
*OUTPUT -- REGISTER 1 - ADDRESS OF APPROPRIATE RESPONSE MESSAGE.      * 17800020
*                                                                     * 18000020
*   REGISTER 15 - RETURN CODE.  VALUES ARE                            * 18200020
*                   X'00' IF MODIFY SUCCESSFUL OR ALREADY IN          * 18400020
*                     EFFECT                                          * 18600020
*                   X'04' IF RLN INVALID, LINE NOT OPEN, OR TRACE     * 18800020
*                     NOT IN SYSTEM                                   * 19000020
*                                                                     * 19200020
*EXTERNAL ROUTINES -- N/A.                                            * 19400020
*                                                                     * 19600020
*EXITS-NORMAL -- TRACE IS MODIFIED AS REQUESTED.  RESPONSE BUILT,     * 19800020
*   X'00' RETURN CODE SET.                                            * 20000020
*                                                                     * 20200020
*   TRACE STATUS IS ALREADY AS REQUESTED.  RESPONSE BUILT, X'00'      * 20400020
*   RETURN CODE SET.                                                  * 20600020
*                                                                     * 20800020
*EXITS-ERROR -- RLN SPECIFIED IS INVALID.  COMMAND INVALID MESSAGE    * 21000020
*   BUILT, X'04' RETURN CODE SET.                                     * 21200020
*                                                                     * 21400020
*   NAME NOT FOUND SEARCHING TIOT OR DEB CHAIN, RLN NOT IN LINE       * 21600020
*   GROUP, LINE NOT OPEN OR OPEN DD DUMMY.  NOT OPEN MESSAGE BUILT,   * 21800020
*   X'04' RETURN CODE SET.                                            * 22000020
*                                                                     * 22200020
*   TRACE NOT DEFINED.  CANNOT MODIFY MESSAGE BUILT, X'04' RETURN     * 22400020
*   CODE SET.                                                         * 22600020
*                                                                     * 22800020
*TABLES/WORK AREAS -- MESSAGES, DEB, DCB, LCB, AVT, OPERATOR          * 23000020
*   CONTROL AVT.                                                      * 23200020
*                                                                     * 23400020
*ATTRIBUTES -- SERIALLY REUSABLE, REFRESHABLE, ENABLED, TRANSIENT,    * 23600020
*   PROBLEM PROGRAM MODE.                                             * 23800020
*                                                                     * 24000020
*NOTES -- THE OPERATION OF THIS MODULE DEPENDS UPON AN INTERNAL       * 24200020
*   REPRESENTATION OF THE EXTERNAL CHARACTER SET WHICH IS             * 24400020
*   EQUIVALENT TO THE ONE USED AT ASSEMBLY TIME.  THE CODING HAS      * 24600020
*   BEEN ARRANGED SO THAT REDEFINITION OF ''CHARACTER'' CONSTANTS,    * 24800020
*   BY REASSEMBLY, WILL RESULT IN A CORRECT MODULE FOR THE NEW        * 25000020
*   DEFINITIONS.                                                      * 25200020
*                                                                     * 25400020
*   MESSAGES ISSUED BY THIS MODULE ARE                                * 25600020
*              IED017I, IED018I, IED023I, IED024I, IED029I, IED030I   * 25800020
*              IED055I                                                * 26000020
*                                                                     * 26200020
*********************************************************************** 26400020
*                                                                       26600020
*                                                                       26800020
R0       EQU   0                        WORK                            27000020
R1       EQU   1                        PARAMETER                       27200020
ROPC     EQU   2                        OPERATOR CONTROL AVT BASE       27400020
RAVT     EQU   4                        AVT BASE                        27600020
RWORK    EQU   5                        WORK                            27800020
RTCB     EQU   6                        TCB BASE                        28000020
RDEB     EQU   6                        DEB BASE                        28200020
RDCB     EQU   7                        DCB BASE                        28400020
RWORK3   EQU   8                        WORK                            28600020
RLCB     EQU   9                        LCB BASE                        28800020
ROFF     EQU   10                       OFFSET TO DDNAME                29000020
RCTR     EQU   10                       COUNTER                         29200020
RDD      EQU   11                       DDNAME                          29400020
RUCB     EQU   11                       UCB BASE                        29600020
RBASE    EQU   12                       ROUTINE BASE                    29800020
R13      EQU   13                       SAVE AREA                       30000020
R14      EQU   14                       RETURN                          30200020
R15      EQU   15                       ENTRY POINT                     30400020
RWORK2   EQU   15                       WORK                            30600020
         USING IEDQCP,RBASE             ADDRESSABILITY FOR ROUTINE      30800020
         USING IEDQAVTD,RAVT            ADDRESSABILITY FOR AVT          31000020
         USING IEDQLCB,RLCB             ADDRESSABILITY FOR LCB          31200020
         USING IHADCB,RDCB              ADDRESSABILITY FOR DCB          31400020
         USING DEBNMSUB,RDEB            ADDRESSABILITY FOR DEB          31600020
         USING IEDQOPC,ROPC             ADDRESSABILITY FOR OP CTL       31800020
         SAVE  (14,12),,IEDQCP-12/14/70                                 32000020
         LR    RBASE,R15                SET UP BASE                     32200020
         LR    ROPC,R1                                                  32400020
         L     RAVT,OPCAVTAD            GET AVT ADDRESS                 32600020
         L     RTCB,AVTTCB              GET TCB ADDR                    32800020
         TM    OPCLEN,ADCODE             DDNAME OR ADDRESS              33000020
         BO    GETLCB                    ADDRESS SKIP RLN CODE          33200020
*                                                                       33400020
         CLI   OPCLEN,AVTEZERO          RLN 'ALL'                       33600020
         BE    COMINV                   YES - REJECT COMMAND            33800020
*                                                                       34000020
         MVC   OPCDOUBL(OPCTHREE),OPCRLN PUT RLN IN WORK AREA           34200020
         SR    R15,R15                  CLEAR                           34400020
         IC    R15,OPCLEN               GET LENGTH OF RLN               34600020
         BCTR  R15,R0                   DECREMENT FOR EXECUTE       620 34800020
         EX    R15,PACK                 CONVERT RLN TO PACKED       620 35000020
         XC    OPCDOUBL(OPCSIX),OPCDOUBL CLEAR FOR CVB              620 35200020
         CVB   RWORK,OPCDOUBL           CONVERT                         35400020
         LTR   RWORK,RWORK              RLN ZERO                        35600020
         BZ    COMINV                   YES - REJECT COMMAND            35800020
*                                                                       36000020
         CH    RWORK,MAXVAL             RLN > 255                       36200020
         BH    COMINV                   YES - REJECT COMAND             36400020
*                                                                       36600020
         STC   RWORK,OPCDOUBL           KEEP HEX RLN                    36800020
GETDATA  EQU   *                                                        37000020
         L     RDD,TIOT(RTCB)           GET TIOT ADDR                   37200020
         LA    ROFF,STARTOFF            OFFSET TO FIRST DD              37400020
         SR    RWORK2,RWORK2            CLEAR                           37600020
         LA    RDD,STARTOFF(RDD)        GET TO FRST DD                  37800020
LOOP     EQU   *                                                        38000020
         IC    RWORK2,OPCZERO(,RDD)     GET LENGTH BYTE                 38200020
         CLI   OPCZERO(RDD),OPCZERO     ANOTHER DD                      38400020
         BE    ERR                      NO - DDNAME NOT FOUND           38600020
*                                                                       38800020
         CLC   OPCFOUR(OPCEIGHT,RDD),OPCTNME SPECIFIED DD               39000020
         BE    GETLCB                   YES - WE HAVE FOUND DD          39200020
*                                                                       39400020
         AR    ROFF,RWORK2              BUMP OFFSET TO NEXT DD          39600020
         AR    RDD,RWORK2               BUMP TO NEXT ENTRY              39800020
         B     LOOP                     GET NEXT DD                     40000020
*                                                                       40200020
GETLCB   EQU   *                                                        40400020
         L     RDEB,DEB(,RTCB)          GET FIRST DEB                   40600020
GETDCB   EQU   *                                                        40800020
         L     RDCB,DEBDCBAD            GET DCB                         41000020
         TM    DCBDSORG+1,TX            TCAM LINE                       41200020
         BNO   NEXTDEB                  NO - WORNG DCB                  41400020
*                                                                       41600020
         TM    OPCLEN,ADCODE             DDNAME OR ADDRESS              41800020
         BO    UCB                       ADDRESS GO PROCESS UCBS        42000020
*                                                                       42200020
         LH    RWORK2,DCBTIOT           GET OFFSET INTO TIOT            42400020
         CR    RWORK2,ROFF              SAME AS FOR DD                  42600020
         BNE   NEXTDEB                  NO - WRONG DCB                  42800020
*                                                                       43000020
         CLC   OPCDOUBL(OPCONE),DEBNMEXT RLN GREATER THAN EXTENTS       43200020
         BH    ERR                      YES - SET ERROR MSG             43400020
*                                                                   622 43600020
         SR    R0,R0                    CLEAR                           43800020
         IC    R0,OPCDOUBL              GET RLN                         44000020
         LR    RWORK,R0                 RELOAD FOR TST                  44200020
         SLL   RWORK,OPCTWO             MULTIPLY BY FOUR                44400020
         L     RWORK,DEBUCBAD-4-DEBNMSUB(RWORK,RDEB) GET UCB ADDR       44600020
         LA    RWORK,OPCZERO(RWORK)     CLEAR HIGH BYTE                 44800020
         LTR   RWORK,RWORK              OPENED DD DUMMY                 45000020
         BZ    ERR                      YES - SET ERROR MSG             45200020
*                                                                   622 45400020
COUNTOK  EQU   *                                                        45600020
         CLI   DCBTIOT,A                LINE OPEN                       45800020
         BNL   ERR                      NO - REJECT COMMAND             46000020
*                                                                       46200020
         L     RLCB,DCBIOBAD            GET IOB                         46400020
         LA    RLCB,OPCZERO(RLCB)   CLEAR HI-ORDER BYTE             623 46600020
         SR    R1,R1                    CLEAR                           46800020
         IC    R1,DCBEIOBX              GET IOB LENGTH                  47000020
         MR    R0,R0                    MULTIPLY IOB BY RLN             47200020
         AR    RLCB,R1                  ADD RESULT TO IOB ADDR          47400020
         LA    RWORK3,LCBFLAG1-IEDQLCB  GET LENGTH OF IOB               47600020
         SR    RLCB,RWORK3              GET TO LCB START                47800020
         B     PROCESS1                 GO LOOK AT LCB                  48000020
*                                                                       48200020
COMINV   EQU   *                                                        48400020
         LA    RWORK,OPCERMSG           GET MSG ADDR                    48600020
         B     SETBAD                                                   48800020
*                                                                       49000020
UCB      EQU   *                                                        49200020
         SR    RWORK,RWORK              CLEAR                           49400020
         IC    RWORK,DEBNMEXT           GET NUMBER OF RLNS              49600020
         LA    RWORK3,DEBUCBAD          GET FIRST UCB ADDR              49800020
         LA    RCTR,OPCONE              SET COUNT TO ONE                50000020
UCBLOOP  EQU   *                                                    623 50200020
         LR    R0,RCTR                  SAVE COUNT                      50400020
         L     RUCB,OPCZERO(,RWORK3)    GET UCB ADDR                    50600020
         CLC   ADDR(OPCTHREE,RUCB),OPCTNME SPECIFIED ADDR               50800020
         BE    COUNTOK            YES - GET ITS LCB                 623 51000020
*                                                                       51200020
         LA    RCTR,OPCONE(,RCTR)       ADD 1 TO COUNT                  51400020
         LA    RWORK3,OPCFOUR(,RWORK3)  GET TO NEXT UCB ADDR            51600020
         CR    RCTR,RWORK               ANY MORE EXTENTS                51800020
         BNH   UCBLOOP            YES - CHECK IF OK                 623 52000020
*                                                                       52200020
NEXTDEB  EQU   *                                                        52400020
         L     RDEB,OPCFOUR(,RDEB)      PICK UP POINTER TO NEXT         52600020
         LA    RDEB,OPCZERO(RDEB)       CLEAR HIGH BYTE                 52800020
         LTR   RDEB,RDEB                ANOTHER DEB                     53000020
         BNZ   GETDCB                   YES - PROCESS IT                53200020
*                                                                       53400020
ERR      EQU   *                                                        53600020
         MVC   ERMGTXT(OPCEIGHT),OPCTNME PUT NAME IN MSG                53800020
         TM    OPCLEN,ADCODE             DDNAME OR ADDRESS              54000020
         BO    SETAD                     UCB- DO NOT MOVE RLN           54200020
*                                                                   623 54400020
         MVC   ERMGTXT+9(OPCTHREE),OPCRLN PUT RLN IN MSG                54600020
SETAD    EQU   *                                                        54800020
         LA    RWORK,ERMG               PICK UP ERROR MSG               55000020
SETBAD   EQU   *                                                        55200020
         LA    R15,OPCFOUR              SET BAD RETURN                  55400020
         B     EXIT                                                     55600020
*                                                                       55800020
NOWAY    EQU   *                                                        56000020
         LA    RWORK,NOMSG              GET MSG ADDR                    56200020
         B     SETBAD                                                   56400020
*                                                                       56600020
PROCESS1 EQU   *                                                        56800020
         L     RWORK,AVTRACE            TRACE TABLE ADDR                57000020
         LTR   RWORK,RWORK              TABLE SPECIFIED                 57200020
         BZ    NOWAY                    NO - CANNOT MODIFY TRACE        57400020
*                                                                       57600020
         CLI   OPCFLG,OFF               TRACE ON OR OFF                 57800020
         BE    OFFT                     OFF - GO PROCESS                58000020
*                                                                       58200020
         TM    LCBSTAT2,LCBTRACE        TRACE ALREADY ON                58400020
         BO    ALON                     YES - BUILD RESPONSE            58600020
*                                                                       58800020
         OI    LCBSTAT2,LCBTRACE        TURN ON TRACE BIT               59000020
         OI    OPCCKBIT,OPCCKPTN        TURN ON CKPT BLAG               59200020
         LA    RWORK,STARTMSG           GET MSG ADDRESS                 59400020
         LA    R1,SMSG                  GET VARIABLE ADDR               59600020
         B     SETGOOD                                                  59800020
*                                                                       60000020
OFFT     EQU   *                                                        60200020
         TM    LCBSTAT2,LCBTRACE        TRACE ALREADY OFF               60400020
         BNO   ALOF                     YES - BUILD MSG                 60600020
*                                                                       60800020
         NI    LCBSTAT2,TRACEOFF        TURN OFF TRACE BIT              61000020
         OI    OPCCKBIT,OPCCKPTN        TURN ON CKPT BLAG               61200020
         LA    RWORK,STOPMSG            GET MSG ADDRESS                 61400020
         LA    R1,PMSG                  GET VARIABLE ADDR               61600020
         B     SETGOOD                                                  61800020
*                                                                       62000020
EXIT     EQU   *                                                        62200020
         ST    RWORK,OPCREG1(,R13)      STORE IN SAVE AREA              62400020
         RETURN (14,12),T,RC=(15)                                       62600020
*                                                                       62800020
SETGOOD  EQU   *                                                        63000020
         MVC   OPCZERO(OPCEIGHT,R1),OPCTNME PUT NAME IN MSG             63200020
         TM    OPCLEN,ADCODE             DDNAME OR ADDRESS              63400020
         BO    CLRRTN                    ADDR - DO NOT MOVE RLN         63600020
*                                                                       63800020
         MVC   OPCNINE(OPCTHREE,R1),OPCRLN PUT RLN IN MSG               64000020
CLRRTN   EQU   *                                                    623 64200020
         SR    R15,R15                  SET GOOD RETURN                 64400020
         B     EXIT                                                     64600020
*                                                                       64800020
ALON     EQU   *                                                        65000020
         LA    RWORK,ASMSG              GET MSG ADDR                    65200020
         LA    R1,AS                    GET VARIABLE ADDR               65400020
         B     SETGOOD                                                  65600020
*                                                                       65800020
ALOF     EQU   *                                                        66000020
         LA    RWORK,APMSG              GET MSG ADDR                    66200020
         LA    R1,AP                    GET VARIABLE ADDR               66400020
         B     SETGOOD                                                  66600020
*                                                                       66800020
DEB      EQU   8                        OFFSET INTO TCB OF DEB          67000020
TIOT     EQU   12                       OFFSET INTO TCB OF TIOT         67200020
ADDR     EQU   13                                                       67400020
STARTOFF EQU   24                                                       67600020
OFF      EQU   X'40'                                                    67800020
TX       EQU   X'40'                                                    68000020
ADCODE   EQU   X'80'                                                    68200020
A        EQU   C'A'                                                     68400020
MAXVAL   DC    H'255'                                                   68600020
PACK     PACK  OPCDOUBL+6(OPCTWO),OPCDOUBL(OPCONE)                  620 68800020
ERMG     DS    0H                                                       68870020
         DC    AL2(DESCR1-*),X'6000'     LENGTH,MCSFLGS-INREG0-IMMRSP   68940020
         DC    C'IED017I LINE '                                         69010020
ERMGTXT  DC    12C' ',C' NOT OPEN'                                      69080020
DESCR1   DC    X'0800'                   DESCRIPTOR - IMMEDIATE RESP    69150020
         DC    X'0000'                   ROUTING - IN REG 0             69220020
STARTMSG DS    0H                                                       69290020
         DC    AL2(DESCR2-*),X'6000'     LENGTH,MCSFLGS-INREG0-IMMRSP   69360020
         DC    C'IED023I TRACE STARTED FOR LINE '                       69430020
SMSG     DC    12C' '                                                   69500020
DESCR2   DC    X'0800'                   DESCRIPTOR - IMMEDIATE RESP    69570020
         DC    X'0000'                   ROUTING - IN REG 0             69640020
STOPMSG  DS    0H                                                       69710020
         DC    AL2(DESCR3-*),X'6000'     LENGTH,MCSFLGS-INREG0-IMMRSP   69780020
         DC    C'IED029I TRACE STOPPED FOR LINE '                       69850020
PMSG     DC    12C' '                                                   69920020
DESCR3   DC    X'0800'                   DESCRIPTOR - IMMEDIATE RESP    69990020
         DC    X'0000'                   ROUTING - IN REG 0             70060020
ASMSG    DS    0H                                                       70130020
         DC    AL2(DESCR4-*),X'6000'     LENGTH,MCSFLGS-INREG0-IMMRSP   70200020
         DC    C'IED024I TRACE ALREADY'                                 70270020
         DC    C' STARTED FOR LINE '                                    70340020
AS       DC    12C' '                                                   70410020
DESCR4   DC    X'0800'                   DESCRIPTOR - IMMEDIATE RESP    70480020
         DC    X'0000'                   ROUTING - IN REG 0             70550020
APMSG    DS    0H                                                       70620020
         DC    AL2(DESCR5-*),X'6000'     LENGTH,MCSFLGS-INREG0-IMMRSP   70690020
         DC    C'IED030I TRACE ALREADY'                                 70760020
         DC    C' STOPPED FOR LINE '                                    70830020
AP       DC    12C' '                                                   70900020
DESCR5   DC    X'0800'                   DESCRIPTOR - IMMEDIATE RESP    70970020
         DC    X'0000'                   ROUTING - IN REG 0             71040020
NOMSG    DS    0H                                                       71110020
         DC    AL2(DESCR6-*),X'6000'     LENGTH,MCSFLGS-INREG0-IMMRSP   71180020
         DC    C'IED055I I/O TRACE CANNOT BE '                          71250020
         DC    C'STARTED'                                               71320020
DESCR6   DC    X'0800'                   DESCRIPTOR - IMMEDIATE RESP    71390020
         DC    X'0000'                   ROUTING - IN REG 0             71460020
*                                                                       71800020
         PRINT NOGEN                                                    72000020
         TOPCD                                                          72200020
         TDEBD                                                          72400020
         DCBD  DSORG=TX                                                 72600020
         TLCBD                                                          72800020
TRACEOFF EQU   X'FF'-LCBTRACE                                           73000020
         TAVTD                                                          73200020
         END                                                            73400020
