         TITLE '''IEDQCQ'' - HOLD/RELEASE'                              00200020
IEDQCQ   CSECT                                                          00400020
*A655000,748000,810000                                           A42413 00460021
*A402600-403200,409000                                           S22026 00500022
*C300000-302000                                                  S22026 00510022
*C300000,655000                                                  A42413 00520021
*********************************************************************** 00600020
*                                                                     * 00800020
*TITLE 'IEDQCQ' PROCESSOR OF HOLD AND RELEASE OPERATOR CONTROL        * 01000020
*   COMMANDS                                                          * 01200020
*                                                                     * 01400020
*STATUS -- CHANGE LEVEL 0                                             * 01600020
*                                                                     * 01800020
*FUNCTION -- THE PURPOSE OF THIS ROUTINE IS TO PROCESS OPERATOR       * 02000020
*   CONTROL COMMANDS WHICH REQUEST THAT A SPECIFIED TERMINAL BE       * 02200020
*   INTERCEPTED (HOLD) OR RELEASED FROM ITS INTERCEPTED STATUS        * 02400020
*   (RELEASE).                                                        * 02600020
*                                                                     * 02800020
*   THE TERMNAME TABLE IS ACCESSED AND IS SERIALLY SEARCHED FOR AN    * 03000020
*   ENTRY MATCHING THAT IN THE COMMON INPUT BLOCK.  IF THE END OF     * 03200020
*   THE TABLE IS REACHED BEFORE A MATCH IS FOUND, AN ERROR MESSAGE    * 03400020
*   IS BUILT AND CONTROL RETURNS TO THE CONTROL MODULE.  WHEN THE     * 03600020
*   ENTRY IS FOUND ITS ADDRESS IS OBTAINED.  THE INPUT BLOCK IS       * 03800020
*   THEN TESTED TO SEE IF A HOLD OR RELEASE IS TO BE DONE.            * 04000020
*                                                                     * 04200020
*   IF IT IS HOLD, THE ENTRY IS TESTED TO SEE WHAT TYPE IT IS.  IF    * 04400020
*   IT IS NOT A SINGLE TERMINAL, AN ERROR MESSAGE IS BUILT AND THE    * 04600020
*   ROUTINE EXITS TO THE CONTROL MODULE.  IF IT IS ALREADY HELD       * 04800020
*   (TRMHELDN ON IN TRMSTATE), AN ALREADY INTERCEPTED MESSAGE IS      * 05000020
*   BUILT AND CONTROL RETURNS TO THE CONTROL MODULE.  IF HOLD CODE    * 05200020
*   IS NOT IN THE SYSTEM (AVTAS IS ZERO) THE TERMINAL CANNOT BE       * 05400020
*   HELD, AN ERROR MESSAGE IS BUILT AND CONTROL EXITS TO THE          * 05600020
*   CONTROL MODULE.                                                   * 05800020
*                                                                     * 06000020
*   THE QCB IS OBTAINED FROM TRMDESTQ AND TESTED FOR QUEUE TYPE.      * 06200020
*   IF IT IS MAIN-STORAGE ONLY (QCBDSFLG IS QCBCORE) THE TERMINAL     * 06400020
*   CANNOT BE HELD, SO AN ERROR MESSAGE IS BUILT AND CONTROL EXITS    * 06600020
*   TO THE CONTROL MODULE.  THE DCB IS ACCESSED FROM QCBDCBAD AND     * 06800020
*   TESTED FOR OPEN STATUS.  IF THE LINE IS NOT OPEN, AN ERROR        * 07000020
*   RESPONSE IS BUILT AND CONTROL RETURNS TO THE CONTROL MODULE.      * 07200020
*   IF THE LINE IS OPEN DD DUMMY (DEBUCBAD FROM DCBDEBAD IS ZERO)     * 07400020
*   AN ERROR MESSAGE IS BUILT AND THE ROUTINE RETURNS TO THE          * 07600020
*   CONTROL MODULE.                                                   * 07800020
*                                                                     * 08000020
*   IF QUEUEING BY TERMINAL (QCBTERMQ ON IN QCBFLAG), THE QCB HELD    * 08200020
*   FLAG IS TURNED ON (QCBTRMHO IN QCBSTAT).  THE INTERCEPT BIT IN    * 08400020
*   THE TERMINAL IS TURNED ON (TRMHELDN ON IN TRMSTATE) AND THE       * 08600020
*   CHECKPOINT BIT SET.  THE INPUT IS TESTED TO SEE IF THIS IS A      * 08800020
*   HOLD COMMAND ONLY OR AN ENTRY FOR VARY TERMINAL.  THE             * 09000020
*   APPROPRIATE RESPONSE MESSAGE IS BUILT AND THE ROUTINE RETURNS     * 09200020
*   TO THE CONTROL MODULE.                                            * 09400020
*                                                                     * 09600020
*   IF A RELEASE FUNCTION IS TO BE PERFORMED, THE INTERCEPT BIT IN    * 09800020
*   THE TERMINAL ENTRY IS TESTED.  IF IT IS OFF, AN ALREADY           * 10000020
*   RELEASED MESSAGE IS BUILT AND CONTROL EXITS TO THE CONTROL        * 10200020
*   MODULE.  OTHERWISE AN ERB IS BUILT TO REQUEST A BUFFER, AND THE   * 10400020
*   AQCTL MACRO (SVC 102) IS ISSUED TO OBTAIN THE BUFFER.  A WAIT     * 10600020
*   (SVC 1) IS ISSUED TO WAIT FOR THE BUFFER TO BE RECEIVED.  WHEN    * 10800020
*   THE WAIT IS SATISFIED, THE NEW BUFFER IS REMOVED FROM THE         * 11000020
*   OPERATOR CONTROL QUEUE, THE TERMINAL-TO-BE-RELEASED OFFSET IS     * 11200020
*   PLACED IN THE NEW BUFFER AND IT IS QUEUED TO IEDQAS01 (THE        * 11400020
*   RELEASE MODULE).  AQCTL (SVC 102) IS ISSUED TO GIVE THE NEW       * 11600020
*   BUFFER TO RELEASE.  A RESPONSE MESSAGE IS BUILT, ITS TEXT         * 11800020
*   DETERMINED BY WHETHER THIS IS A RELEASE OR A VARY TERMINAL        * 12000020
*   COMMAND, THE CHECKPOINT FLAG IS SET, AND THE ROUTINE RETURNS TO   * 12200020
*   THE CONTROL MODULE.                                               * 12400020
*                                                                     * 12600020
*ENTRY POINTS --                                                      * 12800020
*        'IEDQCQ' TO PROCESS HOLD AND RELEASE COMMANDS.  CALLING      * 13000020
*   SEQUENCE IS     LA   RLOAD,LOADPRFX                               * 13200020
*                   LOAD EPLOC=(RLOAD)                                * 13400020
*                   LR   R1,ROPC                                      * 13600020
*                   LR   R15,R0                                       * 13800020
*                   BALR R14,R15                                      * 14000020
*                                                                     * 14200020
*INPUT -- REGISTER 1 - ADDRESS OF OPERATOR CONTROL AVT.  AT THE TAG   * 14400020
*   OPCCKELE IS THE COMMON INPUT BLOCK.  FIELDS RELEVANT TO THIS      * 14600020
*   ROUTINE ARE                                                       * 14800020
*                   +8   OPCTNME   NAME OF THE TERMINAL               * 15000020
*                   +17  OPCVBCD2  IF NOT ZERO, ENTRY IS FOR A VARY   * 15200020
*                   +18  OPCFLG    X'80' IS A RELEASE, X'40' HOLD     * 15400020
*                                                                     * 15600020
*   REGISTER 15 - ENTRY POINT ADDRESS.                                * 15800020
*                                                                     * 16000020
*OUTPUT -- REGISTER 1 - ADDRESS OF APPROPRIATE RESPONSE MESSAGE.      * 16200020
*                                                                     * 16400020
*   REGISTER 15 - RETURN CODE.  VALUES ARE                            * 16600020
*                   0    IF HOLD OR RELEASE SUCCESSFUL OR ALREADY     * 16800020
*                        IN THE DESIRED CONDITION                     * 17000020
*                   4    IF STATION NOT FOUND OR CANNOT BE HELD       * 17200020
*                                                                     * 17400020
*EXTERNAL ROUTINES --                                                 * 17600020
*         'AQCTL' (SVC 102) TO POST AN ERB REQUESTING A BUFFER AND    * 17800020
*   TO POST THE BUFFER TO IEDQAS01.                                   * 18000020
*                                                                     * 18200020
*         'WAIT' (SVC 1) TO WAIT RETURN OF THE REQUESTED BUFFER.      * 18400020
*                                                                     * 18600020
*EXITS-NORMAL -- HOLD OR RELEASE DONE.  RESPONSE BUILT, X'00'         * 18800020
*   RETURN CODE SET.                                                  * 19000020
*                                                                     * 19200020
*   TERMINAL ALREADY HELD OR RELEASED.  RESPONSE BUILT, X'00'         * 19400020
*   RETURN CODE SET.                                                  * 19600020
*                                                                     * 19800020
*EXITS-ERROR -- TERMINAL NOT FOUND.  ERROR MESSAGE BUILT, X'04'       * 20000020
*   RETURN CODE SET.                                                  * 20200020
*                                                                     * 20400020
*   TERMINAL IS NOT A SINGLE ENTRY, QUEUEING IS MAIN-STORAGE ONLY,    * 20600020
*   HOLD CODE IS NOT IN SYSTEM, OR LINE IS NOT OPEN OR OPEN DD        * 20800020
*   DUMMY.  ERROR MESSAGE BUILT, X'04' RETURN CODE SET.               * 21000020
*                                                                     * 21200020
*TABLES/WORK AREAS -- MESSAGES, ERB, DEB, QCB, DCB, BUFFER, AVT,      * 21400020
*   OPERATOR CONTROL AVT, TERMNAME TABLE, TERMINAL ENTRY.             * 21600020
*                                                                     * 21800020
*ATTRIBUTES -- SERIALLY REUSABLE, REFRESHABLE, ENABLED, TRANSIENT,    * 22000020
*   PROBLEM PROGRAM MODE.                                             * 22200020
*                                                                     * 22400020
*NOTES -- THE OPERATION OF THIS MODULE DEPENDS UPON AN INTERNAL       * 22600020
*   REPRESENTATION OF THE EXTERNAL CHARACTER SET WHICH IS             * 22800020
*   EQUIVALENT TO THE ONE USED AT ASSEMBLY TIME.  THE CODING HAS      * 23000020
*   BEEN ARRANGED SO THAT REDEFINITION OF ''CHARACTER'' CONSTANTS,    * 23200020
*   BY REASSEMBLY, WILL RESULT IN A CORRECT MODULE FOR THE NEW        * 23400020
*   DEFINITIONS.                                                      * 23600020
*                                                                     * 23800020
*   MESSAGES ISSUED BY THIS MODULE ARE                                * 24000020
*              IED016I, IED019I, IED020I, IED025I, IED026I, IED051I   * 24200020
*              IED052I, IED053I, IED054I, IED084I                     * 24400020
*                                                                     * 24600020
*********************************************************************** 24800020
*                                                                       25000020
*                                                                       25200020
R0       EQU   0                        WORK                            25400020
R1       EQU   1                        PARAMETER                       25600020
ROPC     EQU   2                        OPERATOR CONTROL AVT BASE       25800020
RCIB     EQU   3                        INPUT BASE                      26000020
RAVT     EQU   4                        AVT BASE                        26200020
RTNT     EQU   5                        TERMNAME TABLE BASE             26400020
RTERM    EQU   6                        TERMINAL ENTRY BASE             26600020
RWORK    EQU   7                        WORK                            26800020
RWORK2   EQU   8                        WORK                            27000020
RWORK3   EQU   9                        WORK                            27200020
RQCB     EQU   10                       BASE FOR QCB                    27400020
RDCB     EQU   11                       BASE FOR DCB                    27600020
RBASE    EQU   12                       ROUTINE BASE                    27800020
R13      EQU   13                       SAVE AREA                       28000020
R14      EQU   14                       RETURN                          28200020
R15      EQU   15                       ENTRY POINT                     28400020
RERB     EQU   RCIB                                                     28600020
RPREFIX  EQU   RDCB                     BASE FOR PREFIX                 28800020
         USING IEDQCQ,RBASE             ADDRESSABILITY FOR ROUTINE      29000020
         USING IEDQOPC,ROPC             ADDRESSABILITY FOR OP CTL       29200020
         USING IEDQAVTD,RAVT            ADDRESSABILITY FOR AVT          29400020
         USING IEDQTNTD,RTNT            ADDRESSABILITY FOR TNT          29600020
         USING IEDQTRM,RTERM            ADDRESSABILITY FOR TERMINAL     29800020
         SAVE  (14,12)                  SAVE REGS                S22026 30000022
         LR    RBASE,R15                GET ROUTINE BASE                30100022
IEDQCQ   IEDHJN LCINSERT                MODULE ID AND DATE       S22026 30200022
         LR    ROPC,R1                  GET OP CTL AVT                  30400020
         L     RAVT,OPCAVTAD            GET AVT ADDRESS                 30600020
         L     RTNT,AVTRNMPT            GET TERMNAME TABLE              30800020
         LA    RWORK,OPCONE             SET COUNTER TO 1                31000020
         LH    RWORK2,TNTLEN            GET NUMBER OF ENTRIES           31200020
         SR    RTERM,RTERM              CLEAR                           31400020
         IC    RTERM,TNTENLEN           GET ENTRY LNEGTH                31600020
         BCTR  RTERM,R0                 DECREMENT BY ONE                31800022
         CH    RTERM,AVTHA7             EIGHT BYTE TERMNAME             31820022
         BE    HTRMOK                   YES, VALID LENGTH               31840020
         LA    R15,OPCTNME+1(RTERM)     PTR TO FIRST BLANK              31860020
        CLI   OPCZERO(R15),AVTEBLNK     IS IT A BLANK                   31880020
         BNE   ERR                      NO, ERROR                       31900020
HTRMOK   EQU   *                                                        31920020
         LA    RTNT,TNTFIRST            BUMP TO FIRST ENTRY             32000020
LOOP     EQU   *                                                        32200020
         CR    RWORK,RWORK2             END OF TABLE                    32400020
         BH    ERR                      YES - TAKE ERROR EXIT           32600020
*                                                                       32800020
         EX    RTERM,COMP               RIGHT ENTRY                     33000020
         BE    FOUND                    YES - GO PROCESS IT             33200020
*                                                                       33400020
         LA    RTNT,OPCFOUR(RTERM,RTNT) BUMP TO NEXT ENTRY              33600020
         LA    RWORK,OPCONE(,RWORK)     INCREMENT COUNTER               33800020
         B     LOOP                     LOOK AT NEXT ENTRY              34000020
*                                                                       34200020
ERR      EQU   *                                                        34400020
         MVC   BAD(OPCEIGHT),OPCTNME    PUT NAME IN MSG                 34600020
         LA    RWORK,BADMSG             PICK UP MSG ADDR                34800020
         LA    R15,HEX20                 ERR CODE - BAD TERM ENTRY      35100020
         B     EXIT                     GO TELL ABOUT ERROR             35400022
*                                                                       35600022
FOUND    EQU   *                        THIS IS THE RIGHT ENTRY         35800022
         AR    RTNT,RTERM               GET TO TERM ADDR                36000020
         MVC   OPCWORK+1(OPCTHREE),OPCONE(RTNT)                         36200020
         L     RTERM,OPCWORK                                            36400020
         STH   RWORK,OPCWORK             SAVE FOR AS                    36600020
         TM    OPCFLG,HEX80             HOLD OR RELEASE FUNCTION        36800020
         BO    CRCODE                   RELEASE - PROCESS               37000020
*                                                                       37200020
         EJECT                                                          37400022
CQCODE   EQU   *                                                        37800020
         USING IEDQQCB,RQCB             ADDRESSABILITY FOR QCB          38000020
         USING IHADCB,RDCB              ADDRESSABILITY FOR DCB          38200020
         TM    TRMSTATE,SNGL            SINGLE ENTRY                    38400020
         BNZ   NOHOLD                   NO - CANNOT HOLD                38600020
*                                                                       38800020
         TM    TRMSTATE,TRMHELDN        ALREADY HELD                    39000020
         BO    YES                      YES - REJECT COMMAND            39200020
*                                                                       39400020
         CLC   AVTAS(OPCFOUR),AVTFZERO  HOLD IN SYSTEM                  39600020
         BE    NOHOLD                   NO - NO WAY TO RELEASE          39800020
*                                                                       40000020
         L     RQCB,TRMDESTQ-1          GET QCB ADDRESS                 40200020
         TM    QCBDSFLG,QCBDRQQ         CONC                     S22026 40260022
         BO    CONCHOLD                 BRANCH IF YES            S22026 40320022
         CLI   QCBDSFLG,QCBCORE+QCBFQCB MO QUEUES                       40400020
         TM    QCBDSFLG,QCBNREUS+QCBREUS  DISK QUEUING                  40600020
         BZ    NOHOLD                    NO, CANNOT HOLD                40800020
CONCHOLD EQU   *                                                 S22026 40900022
         SR    RWORK,RWORK              CLEAR                           41000020
         IC    RWORK,QCBRELLN           GET RELATIVE LINE               41200020
         SLL   RWORK,OPCTWO             MULTIPLY BY 4                   41400020
         L     RDCB,QCBDCBAD-1          GET DCB ADDRESS                 41600020
         CLI   DCBTIOT,A                LINE OPEN                       41800020
         BNL   ERR01                     NO - CANNOT HOLD               42000020
*                                                                       42200020
         L     RWORK2,DCBDEBAD          GET DEB ADDRESS                 42400020
         CLC   QCBRELLN(OPCONE),DEBNMEXT-DEBNMSUB(RWORK2)  EXTENT HIGH  42460020
         BH    ERR01                   -YES, OPENED DD DUMMY            42520020
         L     RWORK2,DEBUCBAD-4-DEBNMSUB(RWORK,RWORK2) GET UCB ADDR    42600020
         LA    RWORK2,OPCZERO(RWORK2)   CLEAR HIGH BYTE                 42800020
         LTR   RWORK2,RWORK2            OPENED DD DUMMY                 43000020
         BZ    ERR01                     YES, CANNOT HOLD               43200020
*                                                                       43400020
         TM    QCBFLAG,QCBTERMQ         QUQUED BY TERMINAL              43600020
         BZ    PUTNM                    NO                              43800020
*                                                                       44000020
         OI    QCBSTAT,QCBTRMHO         TURN ON QCB HELD IND            44200020
PUTNM    EQU   *                                                        44400020
         MVC   GOOD(OPCEIGHT),OPCTNME   PUT NAME IN MSG                 44600020
         OI    TRMSTATE,TRMHELDN        TURN ON ITS HOLD BIT            44800020
         BAL   R14,CONVRTN              CONVERT SEQ FOR PRINTING        45000020
*                                                                       45200020
         MVC   GOODSO(OPCFOUR),OPCDOUBL+1   SAVE SEQ COUNT              45400020
         CLI   OPCVBCD2,AVTEZERO         ENTRY FOR STOP TERM            45600020
         BNE   STOP                     YES - PUT CORRECT MSG           45800020
*                                                                       46000020
         LA    RWORK,GOODMSG            PICK UP MSG ADDR                46200020
GOODEX   EQU   *                                                        46400020
         OI    OPCCKBIT,OPCCKPTN        TURN ON CHECKPOINT BIT          46600020
         NI    OPCCKBIT,OPCINVF         NO INVITATION                   46700020
         B     SETGOOD                  RETURN TO CALLER                46800022
*                                                                       47000022
STOP     EQU   *                                                        47200022
         MVC   SM(OPCEIGHT),OPCTNME     PUT NAME IN MSG                 47400022
         LA    RWORK,S                  GET ADDR OF MSG                 47600022
         B     GOODEX                   SET SWITCHES AND RETURN         47800022
*                                                                       48000022
CONVRTN  EQU   *                        CONVERT TO UNPACKED DECIMAL     48200022
         LH    RWORK,TRMOUTSQ           GET OUTPUT SEQUENCE             48400020
         CVD   RWORK,OPCDOUBL           CONVERT IT TO PACKED DEC        48600020
         UNPK  OPCDOUBL(OPCFIVE),OPCDOUBL+6(OPCTWO)                     48800020
         OI    OPCDOUBL+4,ZONE                                          49000020
         BR    R14                      RETURN TO CALLER                49200020
*                                                                       49400020
ERR01    EQU   *                                                        49450020
         LA    R15,OPCONE                UNOPENED  DCB                  49500020
         B     NOHOLD1                    GET MESSAGE                   49550020
NOHOLD   EQU   *                                                        49600020
         LA    R15,HEX18                 RTN CODE - CANNOT HOLD         49650020
NOHOLD1  EQU   *                                                        49700020
         MVC   NO(OPCEIGHT),OPCTNME     PUT NAME IN MSG                 49800020
         LA    RWORK,NOMSG                                              50000020
         B     EXIT                      RETURN                         50200020
*                                                                       50400020
YES      EQU   *                                                        50600020
         CLI   OPCVBCD2,AVTEZERO        STOP TERM COMMAND               50800020
         BNE   ALRS                     YES                             51000020
*                                                                       51200020
         MVC   SET(OPCEIGHT),OPCTNME    PUT NAME IN MSG                 51400020
         LA    RWORK,SETMSG             GET MSG ADDR                    51600020
SETGOOD  EQU   *                                                        51800020
         SR    R15,R15                                                  52000020
EXIT     EQU   *                                                        52200020
         NI    OPCBITSW,BITSOFF                                         52400020
         ST    RWORK,OPCREG1(,R13)      STORE IN SAVE AREA              52600020
         RETURN (14,12),T,RC=(15)                                       52800020
*                                                                       53000020
ALRS     EQU   *                                                        53200020
         TM    OPCBITSW,OPCTEMPN        ALREADY STOPPED                 53400020
         BO    STOP                     NO - SEND MSG                   53600020
*                                                                       53800020
         MVC   PB(OPCEIGHT),OPCTNME     PUT NNME IN MSG                 54000020
         LA    RWORK,PBM                GET MSG ADDR                    54200020
         B     SETGOOD                  SET GOOD RETURN CODE AND RETURN 54400022
*                                                                       54600022
         EJECT                                                          54800022
CRCODE   EQU   *                                                        55200020
         USING ERBD,RERB                ADDRESSABILIYT FOR ERB          55400020
         USING IEDQPRF,RPREFIX          ADDRESSABILITY FOR BFR          55600020
         TM    TRMSTATE,SNGL            OTHER THAN SINGLE ENTRY         55660020
         BNZ   CRCODE1                  YES, DON'T RELEASE              55720020
         TM    TRMSTATE,TRMHELDN        INTERCEPTED                     55800020
         BO    TURN                     YES - RELEASE IT                56000020
*                                                                       56200020
         CLI   OPCVBCD2,AVTEZERO        START TERM COMMAND              56400020
         BNE   ALRP                     YES                             56600020
*                                                                       56800020
CRCODE1  EQU   *                                                        57000020
         MVC   NOINT(OPCEIGHT),OPCTNME  PUT NAME IN MSG                 57200020
         LA    RWORK,NOINTMSG           GET MSG ADDR                    57400020
         LA    R15,OPCFOUR               TERM ALREADY RELEASED          57500020
         B     EXIT                      RETURN                         57600020
*                                                                       57800020
TURN     EQU   *                                                        58000020
         TM    OPCED,HEX80               IS THIS RESTART                58200020
         BZ    TURN1                      NO                            58400020
         NI    TRMSTATE,TRMHELDF         THRN OFF RESTART               58600020
         L     RQCB,TRMDESTQ-1           GET QCB ADDR                   58630020
         TM    QCBFLAG,QCBTERMQ          QUEUED BY TERMINAL             58660020
         BZ    CRCODE1                   NO - FINISHED                  58690020
        NI    QCBSTAT,ALL-QCBTRMHO      TURN OFF HOLD BIT               58720020
         MVC   CRMSO(OPCFOUR),OPCDOUBL+1        SAVE SEQ COUNT          58760020
         B     CRCODE1                   GET OUT                        58800020
TURN1    EQU   *                                                        59000020
         MVC   CRM(OPCEIGHT),OPCTNME    PUT NAME IN MSG                 59200020
         BAL   R14,CONVRTN              CONVERT SEQ FOR PRINTINT        59400020
*                                                                       59600020
         MVC   CRMSO(OPCFOUR),OPCDOUBL+1      SAVE SEQ COUNT            59800020
* BUILD DUMMY ERB TO GET A BUFFER                                       60000020
         LA    RERB,OPCSAVE2+20         GET DUMMY ERB ADDR              60200020
         LA    RWORK,AVTBFREB           AVAIL BFR Q                     60400020
         ST    RWORK,ERB                PUT IN ERB                      60600020
         MVI   ERBPY,PRIINTRQ           SET PRIORITY                    60800020
         XC    ERBLK(OPCTHREE),ERBLK    CLEAR LINK                      61000020
         MVI   ERBST,OPCTWO             SET STATUS                      61200020
         XC    ERBCH(OPCTHREE),ERBCH    CLEAR CHAIN                     61400020
         LH    RWORK,BFRUNIT            GET BFR/UNIT COUNT              61600020
         STH   RWORK,ERBCT              PUT IN ERB                      61800020
         LA    RWORK,AVTOPCOB           GET OP CTL Q ADDR               62000020
         ST    RWORK,OPCSAVE2           PUT IN RECB                     62200020
         ST    RERB,OPCPPL              BUILD PARAMETER LIST            62400020
         ST    RERB,OPCPPL+4              FOR AQCTL                     62600020
         MVI   OPCPPL,POST                                              62800020
         MVI   OPCPPL+4,TJID                                            63000020
         LA    R1,OPCPPL                                                63200020
         MVI   AVTOPCOB+4,AVTEZERO      CLEAR ECB HIGH BYTE             63400020
         AQCTL                                                          63600020
*                                                                       63800020
BUFDONE  EQU   *                                                        64000020
         WAIT  ECB=AVTOPCOB+4           WAIT FOR RETURNING ERB          64200020
         MVI   AVTOPCOB+4,AVTEZERO      CLEAR ECB HIGH BYTE             64400020
         L     RWORK,AVTOPCOB           GET FIRST ELEMENT               64600020
         CLI   OPCFOUR(RWORK),PRIINTRQ  IS IT ERB                       64800020
         BNE   BUFDONE                  NO - WAIT AGAIN                 65000020
*                                                                       65200020
*                                                                       65400020
         L     RWORK3,CVTPTR            LOAD CVT ADDR            A42413 65440021
         CLC   AVTCVTMP+1(3,RWORK3),AVTFZERO MP GEN'ED IN SYSTEM A42413 65480021
         BE    NOTS                     NO, CONTINUE             A42413 65520021
TSTMP65  CLI   CPUSTAT-IEAQFX00,AVTEZERO MP ACTIVE IN SYSTEM     A42413 65560021
         BNE   NOTS                      NO - PROCEED                   65600020
         TS    AVTOPCOB+8                ANY ONE QUEUI                  65700020
         BC    4,TSTMP65                 YES, WAIT UNTIL HE IS DONE     65800020
NOTS     EQU   *                                                        65900020
         MVC   AVTOPCOB+1(3),5(RWORK)    DEQUEUE THE ELEMENT            66000020
         MVI   AVTOPCOB+8,AVTEZERO       DONE, CLEAR TS SWITCH          66100020
*                                                                       66400020
* AQCTL BUFFER TO RELEASE QCB                                           66600020
SETAS    EQU   *                                                        66800020
         L     RPREFIX,ERBCH-1          GET BFR ADDR                    67000020
         LH    RWORK,OPCWORK            RECOVER TERM OFFSET             67200020
         STH   RWORK,PRFDEST            SET IN BFR                      67400020
         XC    PRFLINK-1(OPCFOUR),PRFLINK-1 CLEAR                       67600020
         OI    PRFPRI,PRIRELSE          SET PROPER PRIORITY             67800020
         L     RWORK,AVTAS              GET RELEASE QCB                 68000020
         ST    RWORK,PRFQCBA-1          SET IN BFR                      68200020
         ST    RPREFIX,OPCPPL                                           68400020
         ST    RPREFIX,OPCPPL+4                                         68600020
         MVI   OPCPPL,POST                                              68800020
         MVI   OPCPPL+4,TJID                                            69000020
         LA    R1,OPCPPL                                                69200020
         AQCTL                                                          69400020
*                                                                       69600020
         CLI   OPCVBCD2,AVTEZERO         ENTRY FOR START                69800020
         BNE   PMSG                     YES - SET RIGHT MSG             70000020
*                                                                       70200020
         LA    RWORK,CRMSG              GET MSG ADDR                    70400020
         B     GOODEX                   SET SWITCHES AND RETURN         70600022
*                                                                       70800022
PMSG     EQU   *                        SET RIGHT MSG                   71000022
         MVC   SR(OPCEIGHT),OPCTNME     PUT NAME IN MSG                 71200020
         LA    RWORK,SMSG               GET MSG ADDR                    71400020
         B     GOODEX                   SET SWITCHES AND RETURN         71600022
*                                                                       71800022
ALRP     EQU   *                        CHECK FOR PREVIOUS START        72000022
         TM    OPCBITSW,OPCTEMPN        ALREADY STARTED                 72200020
         BO    PMSG                     NO                              72400020
*                                                                       72600020
         MVC   SB(OPCEIGHT),OPCTNME     PUT NAME IN MSG                 72800020
         LA    RWORK,SBM                GET MG ADDR                     73000020
         B     SETGOOD                  RETURN TO CALLER                73200022
*                                                                       73300022
POST     EQU   X'0C'                    TO BUILD PARAMETER LIST         73400022
ALL      EQU   X'FF'                    TO REFERENCE ALL BITS IN A BYTE 73500022
ZONE     EQU   X'30'                    TO CONVERT TO UNPACKED DECIMAL  73600022
TJID     EQU   X'80'                    TO BUILD PARAMETER LIST         73700022
HEX80    EQU   X'80'                    TO CHECK FOR RESTART            73800022
HEX20    EQU   X'20'                    SWITCHES                        73900022
HEX18    EQU   X'18'                    SWITCHES                        74000022
SNGL     EQU   X'E0'                    TO CHECK FOR SINGLE ENTRY       74100022
BITSOFF  EQU   X'E0'                    TURN OFF SWITCHES               74200022
A        EQU   C'A'                     CHECK DCB FOR OPEN LINE         74300022
CVTPTR   EQU   16                       POINTER TO CVT           A42413 74400022
BFRUNIT  DC    X'0101'                  BUFFER UNIT COUNT               74500022
COMP     CLC   OPCZERO(OPCONE,RTNT),OPCTNME  EXECUTED INSTRUCTION       74600022
SETMSG   DS    0H                       SET UP MSG                      74700022
         DC    AL2(DESCR1-*),X'6000'     LENGTH,MCSFLGS-INREG0-IMMRS    75320020
         DC    C'IED052I '              MESSAGE ID                      75380022
SET      DC    8C' ',C' ALREADY SET FOR HOLD'  MESSAGE TEXT             75440022
DESCR1   DC    X'0800'                   DESCRIPTOR - IMMEDIATE RESP    75500020
         DC    X'0000'                   ROUTING - IN REG 0             75560020
BADMSG   DS    0H                                                       75620020
         DC    AL2(DESCR2-*),X'6000'     LENGTH,MCSFLGS-INREG0-IMMRSP   75680020
         DC    C'IED016I STATION '      MESSAGE ID                      75740022
BAD      DC    8C' ',C' NOT FOUND'      MESSAGE TEXT                    75800022
DESCR2   DC    X'0800'                   DESCRIPTOR - IMMEDIATE RESP    75860020
         DC    X'0000'                   ROUTING - IN REG 0             75920020
GOODMSG  DS    0H                                                       75980020
         DC    AL2(DESCR3-*),X'6000'     LENGTH,MCSFLGS-INREG0-IMMRSP   76040020
         DC    C'IED051I STATION '      MESSAGE ID                      76100022
GOOD     DC    8C' ',C' SET FOR HOLD, SEQ-OUT=' MESSAGE TEXT            76140022
GOODSO   DC    4C' '                    SEQ-OUT PARAMETER               76180022
DESCR3   DC    X'0800'                   DESCRIPTOR - IMMEDIATE RESP    76220020
         DC    X'0000'                   ROUTING - IN REG 0             76280020
NOMSG    DS    0H                                                       76340020
         DC    AL2(DESCR4-*),X'6000'     LENGTH,MCSFLGS-INREG0-IMMRSP   76400020
         DC    C'IED084I STATION '      MESSAGE ID                      76460022
NO       DC    8C' ',C' CANNOT BE HELD' MESSAGE TEXT                    76520022
DESCR4   DC    X'0800'                   DESCRIPTOR - IMMEDIATE RESP    76580020
         DC    X'0000'                   ROUTING - IN REG 0             76640020
S        DS    0H                                                       76700020
         DC    AL2(DESCR5-*),X'6000'     LENGTH,MCSFLGS-INREG0-IMMRSP   76760020
         DC    C'IED026I STATION '      MESSAGE ID                      76820022
SM       DC    8C' ',C' STOPPED'        MESSAGE TEXT                    76880022
DESCR5   DC    X'0800'                   DESCRIPTOR - IMMEDIATE RESP    76940020
         DC    X'0000'                   ROUTING - IN REG 0             77000020
NOINTMSG DS    0H                                                       77060020
         DC    AL2(DESCR6-*),X'6000'     LENGTH,MCSFLGS-INREG0-IMMRSP   77120020
         DC    C'IED053I '              MESSAGE ID                      77180022
NOINT    DC    8C' ',C' ALREADY RELEASED' MESSAGE TEXT                  77240022
DESCR6   DC    X'0800'                   DESCRIPTOR - IMMEDIATE RESP    77300020
         DC    X'0000'                   ROUTING - IN REG 0             77360020
CRMSG    DS    0H                                                       77420020
         DC    AL2(DESCR7-*),X'6000'     LENGTH,MCSFLGS-INREG0-IMMRSP   77480020
         DC    C'IED054I '              MESSAGE ID                      77540022
CRM      DC    8C' ',C' RELEASED, SEQ-OUT=' MESSAGE TEXT                77580022
CRMSO    DC    4C' '                    SEQ-OUT PARAMETER               77620022
DESCR7   DC    X'0800'                   DESCRIPTOR - IMMEDIATE RESP    77660020
         DC    X'0000'                   ROUTING - IN REG 0             77720020
SMSG     DS    0H                                                       77780020
         DC    AL2(DESCR8-*),X'6000'     LENGTH,MCSFLGS-INREG0-IMMRSP   77840020
         DC    C'IED020I STATION '      MESSAGE ID                      77900022
SR       DC    8C' ',C' STARTED'        MESSAGE TEXT                    77960022
DESCR8   DC    X'0800'                   DESCRIPTOR - IMMEDIATE RESP    78020020
         DC    X'0000'                   ROUTING - IN REG 0             78080020
SBM      DS    0H                                                       78140020
         DC    AL2(DESCR9-*),X'6000'     LENGTH,MCSFLGS-INREG0-IMMRSP   78200020
         DC    C'IED019I '              MESSAGE ID                      78260022
SB       DC    8C' ',C' ALREADY STARTED' MESSAGE TEXT                   78320022
DESCR9   DC    X'0800'                   DESCRIPTOR - IMMEDIATE RESP    78380020
         DC    X'0000'                   ROUTING - IN REG 0             78440020
PBM      DS    0H                                                       78500020
         DC    AL2(DESCR0-*),X'6000'     LENGTH,MCSFLGS-INREG0-IMMRSP   78560020
         DC    C'IED025I '              MESSAGE ID                      78620022
PB       DC    8C' ',C' ALREADY STOPPED' MESSAGE TEXT                   78680022
DESCR0   DC    X'0800'                   DESCRIPTOR - IMMEDIATE RESP    78740020
         DC    X'0000'                   ROUTING - IN REG 0             78800020
*                                                                       79400020
ERBD     DSECT                                                          79600020
ERB      DS    A                        ERB ADDRESS                     79800022
ERBPY    DS    X                        ERB PRIORITY                    80000022
ERBLK    DS    AL3                      ERB LINK                        80200022
ERBST    DS    X                        ERB STATUS                      80400022
ERBCH    DS    AL3                      ERB CHAIN                       80600022
ERBCT    DS    H                        ERB COUNT                       80800022
         IEAQFX 65,MCH,M65MP                                     A42413 81040022
         TDEBD                                                          81200020
         TQCBD                                                          81400020
         DCBD  DSORG=TX                                                 81600020
         TPRFD                                                          81800020
         TOPCD                                                          82000020
         TAVTD                                                          82200020
         TTNTD                                                          82400020
         TTRMD                                                          82600020
         TPRIOR                                                         82800020
         END                                                            83000020
