  TITLE  'IEDQCS DISPLAY OPITIONS'                                      00200020
IEDQCS   CSECT                                                          00400020
*********************************************************************** 00600020
*                                                                     * 00800020
*TITLE 'IEDQCS' PROCESSOR OF DISPLAY OPTION COMMANDS                  * 01000020
*                                                                     * 01200020
*STATUS -- CHANGE LEVEL 0                                             * 01400020
*                                                                     * 01600020
*FUNCTION -- THIS ROUTINE PROCESSES OPERATOR CONTROL COMMANDS WHICH   * 01800020
*   REQUEST DISPLAY OF TERMINAL OPTION FIELDS.                        * 02000020
*                                                                     * 02200020
*   THE DISPLAY OPTIONS ROUTINE LOADS ITS WORK AREA (IEDQC5) AND      * 02400020
*   SERIALLY SEARCHES THE TERMNAME TABLE FOR AN ENTRY MATCHING THAT   * 02600020
*   SPECIFIED IN THE COMMON INPUT BLOCK.  IF THE END OF THE TABLE     * 02800020
*   IS REACHED BEFORE A MATCH IS FOUND, AN ERROR MESSAGE IS BUILT     * 03000020
*   AND CONTROL RETURNS TO THE CONTROL MODULE.  WHEN THE ENTRY IS     * 03200020
*   FOUND, THE OPTION NAMES TABLE IS SERIALLY SEARCHED FOR THE        * 03400020
*   SPECIFIED OPTION FIELD.  IF NO ENTRY IS FOUND, AN ERROR MESSAGE   * 03600020
*   IS BUILT AND CONTROL EXITS TO THE CONTROL MODULE.  IF THERE ARE   * 03800020
*   NO OPTIONS FOR THE TERMINAL ENTRY (TRMOPTFN OFF IN TRMSTATE) AN   * 04000020
*   ERROR RESPONSE IS BUILT AND THE ROUTINE RETURNS TO THE CONTROL    * 04200020
*   MODULE.  IF THE SPECIFIED OPTION FIELD IS NOT DEFINED FOR THE     * 04400020
*   TERMINAL, AN ERROR MESSAGE IS BUILT AND CONTROL EXITS TO THE      * 04600020
*   CONTROL MODULE.  OTHERWISE THE ADDRESS OF THE OPTION FIELD IS     * 04800020
*   OBTAINED AND PROCESSING CONTINUES.                                * 05000020
*                                                                     * 05200020
*   FOR DISPLAY COMMANDS, THE OPTION FIELD IS MOVED INTO THE WORK     * 05400020
*   AREA.  IF THE DATA FORMAT IS CHARACTER AND THE FIELD IS ALL       * 05600020
*   BLANK, 'ALL BLANKS' IS MOVED INTO THE RESPONSE.  SINCE NO         * 05800020
*   CONVERSION IS NECESSARY FOR CHARACTER DATA, A RESPONSE MESSAGE    * 06000020
*   IS BUILT AND THE ROUTINE EXITS TO THE CONTROL MODULE.  ALL        * 06200020
*   OTHER TYPES OF FIELD ARE TESTED FOR ZERO CONTENT, AND A DATA IS   * 06400020
*   ZERO MESSAGE IS BUILT AND CONTROL RETURNS TO THE CONTROL          * 06600020
*   MODULE.  OTHERWISE THE DATA IS CONVERTED FROM ITS CURRENT         * 06800020
*   FORMAT INTO A PRINTABLE EQUIVALENT.  A RESPONSE IS BUILT AND      * 07000020
*   CONTROL RETURNS TO THE CONTROL MODULE.                            * 07200020
*                                                                     * 07400020
*ENTRY POINTS --                                                      * 07600020
*        'IEDQCS' TO PROCESS DISPLAY OPTION OPERATOR                  * 07800020
*   CONTROL COMMANDS.  CALLING SEQUENCE IS                            * 08000020
*                        LOAD EPLOC=LOADPRFX                          * 08200020
*                        LR   R1,ROPC                                 * 08400020
*                        LR   R15,R0                                  * 08600020
*                        BALR R14,R15                                 * 08800020
*                                                                     * 09000020
*INPUT -- REGISTER 1 - ADDRESS OF OPERATOR CONTROL AVT.  AT THE TAG   * 09200020
*   OPCCKELE IS THE COMMON INPUT BLOCK.  FIELDS RELEVANT TO THIS      * 09400020
*   ROUTINE ARE                                                       * 09600020
*                   +8   OPCTNME   NAME OF THE TERMINAL               * 09800020
*                   +24  OPCOPFLD  NAME OF THE OPTION FIELD           * 10000020
*                                                                     * 10200020
*   REGISTER 15 - ENTRY POINT ADDRESS.                                * 10400020
*                                                                     * 10600020
*OUTPUT -- REGISTER 1 - ADDRESS OF APPROPRIATE RESPONSE MESSAGE.      * 10800020
*                                                                     * 11000020
*   REGISTER 15 - RETURN CODE.  VALUES ARE                            * 11200020
*                   0    IF EXECUTION SUCCESSFUL                      * 11400020
*                   4    IF TERMINAL OR OPTION NOT FOUND, THE         * 11600020
*                        OPTION DOES NOT EXIST FOR THE TERMINAL,      * 11800020
*                                                                     * 12000020
*EXTERNAL ROUTINES --                                                 * 12200020
*       'IEDQCA02'  TO ACCESS THE MODIFY DATA                         * 12400020
*                                                                     * 12600020
*       'LOAD' (SVC 8) TO ACCESS THE WORK AREA                        * 12800020
*                                                                     * 13000020
*EXITS-NORMAL -- COMMAND IS PROCESSED.  A RESPONSE MESSAGE IS         * 13200020
*   CONSTRUCTED AND ITS ADDRESS IS RETURNED TO THE CALLER.            * 13400020
*                                                                     * 13600020
*EXITS-ERROR -- TERMINAL OR OPTION NOT FOUND, OR OPTION DOES NOT      * 13800020
*   EXIST FOR THE TERMINAL.  ERROR MESSAGE BUILT, X'04' RETURN CODE   * 14000020
*   SET.                                                              * 14200020
*                                                                     * 14400020
*TABLES/WORK AREAS -- MESSAGES, TRANSLATE TABLES, OPERATOR CONTROL    * 14600020
*   AVT, AVT, TERMNAME TABLE, TERMINAL ENTRY, BUFFER.                 * 14800020
*                                                                     * 15000020
*ATTRIBUTES -- SERIALLY REUSABLE, REFRESHABLE, ENABLED, TRANSIENT,    * 15200020
*   PROBLEM PROGRAM MODE.                                             * 15400020
*                                                                     * 15600020
*NOTES -- THE OPERATION OF THIS MODULE DEPENDS UPON AN INTERNAL       * 15800020
*   REPRESENTATION OF THE EXTERNAL CHARACTER SET WHICH IS             * 16000020
*   EQUIVALENT TO THE ONE USED AT ASSEMBLY TIME.  THE CODING HAS      * 16200020
*   BEEN ARRANGED SO THAT REDEFINITION OF ''CHARACTER'' CONSTANTS,    * 16400020
*   BY REASSEMBLY, WILL RESULT IN A CORRECT MODULE FOR THE NEW        * 16600020
*   DEFINITIONS.                                                      * 16800020
*                                                                     * 17000020
*   MESSAGES ISSUED BY THIS MODULE ARE                                * 17200020
*              IED016I, IED034I, IED035I, IED050I, IED056I, IED062I   * 17400020
*              IED077I                                                * 17600020
*                                                                     * 17800020
*********************************************************************** 18000020
*                                                                       18200020
*                                                                       18400020
R0       EQU   0                                                        18600020
R1       EQU   1                        PARAMETER                       18800020
ROPC     EQU   2                        OPERATOR CONTROL AVT BASE       19000020
RCIB     EQU   3                        BUFFER OR CIB BASE              19200020
RAVT     EQU   4                        AVT BASE                        19400020
ROPT     EQU   5                        OPTION CSECT BASE               19600020
RTNT     EQU   6                        TERMNAME TABLE BASE             19800020
RTERM    EQU   7                        TERMINAL ENTRY BASE             20000020
RWORK    EQU   8                        WORK                            20200020
RWORK2   EQU   9                        WORK                            20400020
RWORK3   EQU   10                       WORK                            20600020
RWORK4   EQU   11                                                       20800020
RBASE    EQU   12                       ROUTINE BASE                    21000020
R13      EQU   13                       SAVE AREA                       21200020
R14      EQU   14                       RETURN                          21400020
R15      EQU   15                        ENTRY POINT                    21600020
ZERO     EQU   0                                                        21800020
ONE      EQU   1                                                        22000020
TWO      EQU   2                                                        22200020
THREE    EQU   3                                                        22400020
FOUR     EQU   4                                                        22600020
FIVE     EQU   5                                                        22800020
SIX      EQU   6                                                        23000020
EIGHT    EQU   8                                                        23200020
TWELVE   EQU   12                                                       23400020
THIRTEEN EQU   13                                                       23600020
FOURTEEN EQU   14                                                       23800020
TWOONE   EQU   21                                                       24000020
TWOEIGHT EQU   28                                                       24200020
TWONINE  EQU   29                                                       24400020
THRSEVEN EQU   37                                                       24600020
THREIGHT EQU   38                                                       24800020
FOURTHR  EQU   43                                                       25000020
FOURFOUR EQU   44                                                       25200020
FOURFIVE EQU   45                                                       25400020
FOURSIX  EQU   46                                                       25600020
C255     EQU   255                                                      25800020
HEX0F    EQU   X'0F'                                                    25840020
HEXFLG   EQU   X'04'                                                    25880020
HEXF0    EQU   X'F0'                                                    25920020
CZERO    EQU   C'0'                                                     25960020
PACK     EQU   X'40'                                                    26000020
CHAR     EQU   X'00'                                                    26200020
COMONE   EQU   X'FE'                                                    26400020
C5BIT    EQU   X'10'                                                    26600020
COMC5BIT EQU   X'EF'                                                    26800020
ZONE     EQU   X'01'                                                    27000020
         USING IEDQCS,RBASE                                             27200020
         USING IEDQAVTD,RAVT            ADDRESSABILITY FOR AVT          27400020
         USING IEDQOPC,ROPC             ADDRESSABILITY FOR OP CTL       27600020
         USING IEDQTNTD,RTNT            ADDRESSABILITY FOR TNT          27800020
         USING IEDQTRM,RTERM            ADDRESSABILITY FOR TERM         28000020
         SAVE  (14,12),,IEDQCS-03/10/71                                 28200020
         LR    RBASE,R15                SET UP BASE                     28400020
         LR    ROPC,R1                  GET OP CTL AVT BASE             28600020
         L     RCIB,OPCINPUT            SET UP CIB                      28800020
         L     RAVT,OPCAVTAD            GET AVT BASE                    29000020
         L     RTNT,AVTRNMPT            GET TNT ADDRESS                 29200020
         LOAD  EPLOC=TAG                                                29400020
         ST    R0,OPCWORK               SAVE ADDRESS IF MODULE IEDQC5   29600020
         OI    OPCCKBIT,C5BIT           INDICATE MODULE C5 LOADED       29800020
         LA    RWORK3,OPCONE            SET COUNTER TO ONE              30000020
         LH    RWORK2,TNTLEN            GET NUMBER OF ENTRIES           30200020
         SR    RTERM,RTERM              CLEAR                           30400020
         IC    RTERM,TNTENLEN           GET ENTRY LENGTH                30600020
         BCTR  RTERM,R0                                                 30800020
         CH    RTERM,AVTHA7           EIGHT BYTE TERMNAME               30820020
         BE    HTRMOK                   YES, VALID LENGTH               30840020
         LA    R15,OPCTNME+1(RTERM)     PTR TO FIRST BLANK              30860020
        CLI   OPCZERO(R15),AVTEBLNK     IS IT A BLANK                   30880020
         BNE   ERROR                    NO, ERROR                       30900020
HTRMOK   EQU   *                                                        30920020
         LA    RTNT,TNTFIRST            GET TO FIRST ENTRY              31000020
TESTTRM  EQU   *                                                        31200020
         CR    RWORK3,RWORK2            END OF TABLE                    31400020
         BH    ERROR                    YES - ERROR EXIT                31600020
*                                                                       31800020
         EX    RTERM,COMP               TERM ENTRY FOUND                32000020
         BE    GETOP                                                    32200020
*                                                                       32400020
         LA    RWORK3,OPCONE(,RWORK3)   BUMP COUNTER                    32600020
         LA    RTNT,OPCFOUR(RTERM,RTNT) BUMP TNT ADDRESS                32800020
         B     TESTTRM                  GO TEST NEXT ENTRY              33000020
*                                                                       33200020
ERROR    EQU   *                                                        33400020
         MVC   ERMG(OPCEIGHT),OPCTNME   PUT NAME IN MSG                 33600020
         LA    RWORK,ERR                                                33800020
         B     ERROPRET                                                 34000020
*                                                                       34200020
GETOP    EQU   *                                                        34400020
         AR    RTNT,RTERM               BUMP TO ADDR                    34600020
         MVC   OPCSAVE2+1(THREE),ONE(RTNT) TERM ADR. TO FULL WORD       34800020
         L     RTERM,OPCSAVE2           ADDRESS OF TERMINAL ENTRY       35000020
         L     ROPT,AVTOPTPT            GET ADDR OPTION TBLS            35200020
         L     ROPT,OPCFOUR(,ROPT)      GET ADDR OPT NAMES              35400020
         LA    RWORK3,OPCONE            SET COUNTER FOR OPT OFFSET      35600020
         TM    TRMSTATE,TRMOPTFN        OPTION FIELDS PRESENT           35800020
         BNO   ERROP                    NO - ERROR EXIT                 36000020
*                                                                       36200020
COMPOP   EQU   *                                                        36400020
         CLI   OPCZERO(ROPT),AVTEFF     END OF OPTIONS                  36600020
         BE    ERROP                    YES- ERROREXIT                  36800020
*                                                                       37000020
         CLC   OPCTWO(OPCEIGHT,ROPT),OPCOPFLD OPTION FOUND              37200020
         BE    PROCESS                  YES - PROCESS IT                37400020
*                                                                       37600020
         LA    ROPT,OPCTEN(,ROPT)       BUMP TO NEXT ENTRY              37800020
         LA    RWORK3,OPCONE(,RWORK3)   BUMP COUNTER                    38000020
         B     COMPOP                   CHECK NEXT FIELD                38200020
*                                                                       38400020
PROCESS  EQU   *                                                        38600020
         SR    RWORK,RWORK                                              38800020
         IC    RWORK,TRMOPNO            PICK UP NUMBER OF OPTIONS       39000020
         CR    RWORK,RWORK3             OFFSET GREATER                  39200020
         BL    ERROP                    YES - ERROR EXIT                39400020
*                                                                       39600020
         AR    RWORK3,RTERM             ADD TERM BASE                   39800020
         CLI   TRMOPT-1-IEDQTRM(RWORK3),AVTEFF OFFSET THERE             40000020
         BE    ERROP                    NO - ERROR EXIT                 40200020
*                                                                       40400020
         SR    RWORK4,RWORK4                                            40600020
         IC    RWORK4,TRMOPT-1-IEDQTRM(RWORK3)                          40800020
         SR    RWORK3,RTERM                                             41000020
         L     RTNT,AVTOPTPT            GET OPTION DATA CSECT           41200020
         AH    RTNT,TRMOPTBL            ADD OFFSET TO THIS TERM         41400020
         AR    RTNT,RWORK4              ADD OFFSET TO THIS OPTION       41600020
         LA    R14,MSG35                DISPLAY MESSAGE ADDRESS         41800020
         L     RWORK4,OPCWORK           RESTORE IEDQC5 ADDRESS          42000020
         BCTR  RWORK4,R0                BACK UP ONE                     42200020
         MVC   ONE(TWO,RWORK4),ZERO(R14) MESSAGE LENGTH                 42400020
         MVC   THREE(FIVE,RWORK4),X1000IED IED PORTION OF MESSAGE       42600020
         MVC   EIGHT(FOUR,RWORK4),TWO(R14) MESSAGE NUMBER               42800020
         MVI   TWELVE(RWORK4),C' '      BLANK OUT NEXT BYTE             43000020
         MVC   THIRTEEN(EIGHT,RWORK4),OPCTNME TERMINAL NAME             43200020
         MVC   TWOONE(EIGHT,RWORK4),OPTION BLANK 'OPTION' BLANK         43400020
         MVC   TWONINE(EIGHT,RWORK4),OPCOPFLD OPTION FLD NAME           43600020
         MVI   THRSEVEN(RWORK4),C' '    BLANK OUT NEXT CHARACTER        43800020
         MVC   THREIGHT(TWOEIGHT,RWORK4),SIX(R14) MESSAGE TEXT          44000020
         LR    RWORK3,RWORK4            SAVE THE ADDRESS                44200020
         LR    R0,RWORK4                SAVE ADDRESS                    44400020
         SR    R1,R1                                                    44600020
         IC    R1,ZERO(ROPT)            LENGTH-1 OR THE OPTION FIELD    44800020
         CLI   OPCFLG,HEXFLG             TYPE DISPLAY REQUESTED         44900020
         BH    DFCK                     DEC EQUIVALENT OF HEX           45000020
         BE    HEXPACK                  HEXIDECIMAL                     45100020
         CLI   ONE(ROPT),ZERO           CHARACTER- IS PPT FIELD CHAR TY 45200020
         BNE   ERROPT                   NO, ERROR                       45300020
*                                       OR CHARACTER TYPE               45600020
*                                                                       45800020
*              DISPLAY CHARACTER FORMAT OPTION FIELDS                   46000020
*                                                                       46200020
CKNEXT   EQU   *                                                        46400020
         LA    RWORK,ZERO(RTNT,R1)      ADDRESS OF OPTION FIELD END     46600020
         CLI   ZERO(RWORK),C' '         TEST FOR BLANK CHARACTER        46800020
         BNE   NOTALL                   BRANCH NOT A BLANK CHARACTER    47000020
         LTR   R1,R1                    WAS THAT THE LAST CHARACTER     47200020
         BZ    ALLBLNK                  BRANCH IF YES                   47400020
         BCTR  R1,R0                    REDUCE CHARACTER COUNT          47600020
         B     CKNEXT                   GO TEST NEXT CHARACTER          47800020
ALLBLNK  EQU   *                                                        48000020
         MVC   FOURFOUR(FOURTEEN,RWORK3),ALLB PREPARE TO PRINT ALL      48200020
*                                       BLANK MESSAGE                   48400020
         LA    R1,THIRTEEN              SET MESSAGE LENGTH              48600020
         B     PREPEXIT                 GO FINISH MESSAGE               48800020
NOTALL   EQU   *                                                        49000020
         EX    R1,MOVEFROP              MOVE DATA TO DISPLAY MESSAGE    49200020
         B     PREPEXIT                 GO FINISH DISPLAY MESSAGE       49400020
*                                                                       49600020
*             DISPLAY ALL TYPES OF DATA IN HEXIDECIMAL FORMAT           50000020
*                                                                       50400020
HEXPACK  EQU   *                                                        50600020
         SR    R14,R14                                                  50800020
HEX1     EQU   *                                                        51600020
         IC    R14,ZERO(RTNT)           PICK UP BYTE FROM OPTION FLD.   51800020
         LTR   R14,R14                  STILL LEADING ZEROS             52000020
         BNZ   NONZERO                  BRANCH IF END OF LESDING ZEROS  52200020
         LTR   R1,R1                    LAST BYTE IN THE FIELD          52400020
         BZ    NONZERO                  BRANCH IF YES                   52600020
         BCTR  R1,R0                    SUB ONE FROM FIELD SIZE         52800020
         LA    RTNT,ONE(RTNT)           SKIP OVER LEADING ZERO          53000020
         B     HEX1                     GO CHECK THE NEXT BYTE          53200020
NONZERO  EQU   *                                                        53400020
         LR    R15,R1                   COPY COUNT OF NONZERO DIGITS    53600020
AGAIN    EQU   *                                                        53800020
         IC    R14,ZERO(RTNT)           PICK UP DATA BYTE               54000020
         STC   R14,FOURFIVE(RWORK4)     STORE RIGHT MOST DIGIT          54200020
         NI    FOURFIVE(RWORK4),X'0F'   CLEAR UNWANTED BITS             54400020
         SRL   R14,FOUR                 POSITION LEFT HALF BYTE         54600020
         STC   R14,FOURFOUR(RWORK4)     STORE LEFT HALF BYTE            54800020
         LTR   R15,R15                  MORE BYTES TO SPILT             55000020
         BZ    LAST                     BRANCH IF ALL SPILT             55200020
         LA    RTNT,ONE(RTNT)           INCREMENT OPTION FIELD PT.      55400020
         LA    RWORK4,TWO(RWORK4)       INCREMENT WORK AREA POINTER     55600020
         BCTR  R15,R0                   REDUCE CHARACTER COUNT          55800020
         B     AGAIN                    GO SPILT NEXT CHARACTER         56000020
LAST     EQU   *                                                        56200020
         SLL   R1,ONE                   CHARACTER COUNT TIMES TWO       56400020
         LA    R1,ONE(R1)               ADD ONE IN CASE OF HEX          56600020
         LR    R15,R1                   SAVE NEW CHARACTER COUNT        56800020
         LA    RWORK2,TRANSHEX          SET FOR HEX TRANSLATE           60200020
         LA    RTNT,FOURFOUR(RWORK3)    SET NEW OPTION FIELD POINTER    60400020
         B     TRANLATE                 GO TRANSLATE THE DATA           60600020
*                                                                       60690020
*                                                                       60780020
*                                                                       60870020
*              DISPLAY DECIMAL EQUIVALENT OF HEXIDECIMAL                60960020
*              EXCEPT FIELDS WHICH ARE DEFINED CHARACTER OR THOSE       61050020
*              WHOSE HEXIDECIMAN VLLUES ARE GREATER THAN 7FFFFF (31BIT) 61140020
*                                                                       61230020
*                                                                       61320020
*                                                                       61410020
DFCK     EQU   *                                                        61500020
         CLI   ONE(ROPT),CHAR           IS FIELD CHARACTER TYPE         61590020
         BE    ERROPT                   YES REJECT COMMAND              61680020
         XC    OPCDOUBL(EIGHT),OPCDOUBL CLEAR FOR USEAGE                61770020
         LR    R15,RTNT                 PTR TO OTP FIELD                61860020
         LA    R1,ONE(R1)               LENGTH OF OPT FIELD             61950020
         BAL   R14,ZLOOP                FIND FIRST NON ZERO CHAR        62040020
*                                                                       62130020
*                                       ON RETURN                       62220020
*                                            R1 = LENGTH                62310020
*                                            R15= PTR TO FIRST NONZERO  62400020
*                                            CHARACTER                  62490020
*                                                                       62580020
*                                                                       62670020
         CH    R1,H4                     IS LENGTH GREATER THAN 4       62760020
         BH    ERROPT                   YES, REJECT COMMAND             62850020
         LTR   R1,R1                    IS LENGTH ZERO                  62940020
         BZ    DFZEROF                  YES, SKIP MOVE CHAR             63030020
         LA    R14,OPCDOUBL+4       LENGTH PAST OPCDOUBL ADDR           63120020
         SR    R14,R1                   PTR TO FIRST CHARACTER          63210020
         BCTR  R1,R0                    DECREMENT LENGTH FOR MOVE       63300020
         EX    R1,MOV1DF                MOVE IT                         63390020
         L     R15,OPCDOUBL             FIELD IN REGISTER               63480020
         LTR   R15,R15                  FIELD GREATER THAN 31 BITS      63570020
         BM    ERROPT                   YES, GET OUT                    63660020
         CVD   R15,OPCDOUBL             CONVERT TO DECIMAL              63750020
         LA    R15,OPCDOUBL             PTER TO BEG OF FLD FOR ZLOOP    63840020
         LA    R1,EIGHT                 LENGTH                          63930020
         BAL   R14,ZLOOP                FIND FIRST OON ZERO CHAR        64020020
         OI    OPCDOUBL+7,HEX0F         CHANGE SIGN TO PRINTABLE        64110020
         BCTR  R1,R0                    LENGTH -1                       64200020
         SLL   R1,ONE                   2(N-1) UNPACK TO LENGTH         64290020
         TM    ZERO(R15),HEXF0           ODD NUMBER OF DIGETS           64380020
         BNZ   DFL1                     NO, IS LENGTH -1                64470020
         BCTR  R1,R0                    SUBTRACT 1 FOR EXECUTE          64560020
DFL1     EQU   *                                                        64650020
         LR    R14,R1                   USE R14, SAVE R1 FOR LATER      64740020
         SLL   R14,FOUR                 SET BITS TO 'OR' WITH 8-11      64830020
         EX    R14,UNPK1DF              UNPK INTO MSG AREA              64920020
         B     PREPEXIT                 FINISH MESSAGE                  65010020
*                                                                       65100020
*                                                                       65190020
ZLOOP    EQU   *                                                        65280020
         CLI   ZERO(R15),ZERO           IS CHAR ZERO                    65370020
         BCR   7,R14                    NO, DONE                        65460020
         LA    R15,ONE(R15)             PTR TO NEXT CHAR                65550020
         BCT   R1,ZLOOP                 DECREMENT LENGTH                65640020
         BR    R14                      ALL ZERO                        65730020
DFZEROF  EQU   *                                                        65820020
         MVI   FOURFOUR(RWORK4),CZERO    PLACE DUMMY ZERO IN MSG        65910020
         SR    R1,R1                    LENGTH - 1  TO ZERO             66000020
         B     PREPEXIT                 SEND OFT THE MESSAGE            66090020
*                                                                       66400020
*              TRANSLATE HEX AND PACKED EDCIMAL TYPE DATA               66600020
*                                                                       66800020
TRANLATE EQU   *                                                        67000020
         SR    RWORK,RWORK                                              67200020
         LR    R14,RTNT                 COPY OPTION FIELD ADDRESS       67400020
         LA    RWORK,C255               SET TO TRANSLATE MAX.           68000020
         EX    RWORK,TRAN               TRANSLATE FIRST 256 BYTES       68200020
ONETR    EQU   *                                                        68400020
         LA    R14,ONE(R14,RWORK)       COMPUTE ADDR REMAINING IF ANY   68800020
         EX    RWORK,TRAN               TRAN REST OR GARBAGE            69200020
PREPEXIT EQU   *                                                        69600020
         LR    RWORK4,R0                RESTORE WORK AREA ADDRESS       69800020
         LA    RWORK3,ONE(RWORK4)       REAL WORK AREA ADDRESS          70000020
         LA    R1,ONE(R1)               REAL DATA LENGTH                70200020
         AH    R1,ZERO(RWORK3)          ADD LENGTH OF FIXED MESSAGE     70400020
         STH   R1,ZERO(RWORK3)          STORE TOTAL MESSAGE LENGTH      70600020
         SR    R15,R15                  SET ZERO RETURN CODE            70800020
         LA    RWORK,ONE(RWORK4)        ADDRESS OF THE WORK AREA        71000020
         LH    R14,ZERO(RWORK)          LENGTH OF THE MESSAGE           71200020
         LA    R14,ONE(R14,RWORK4)      END OF MESSAGE PLUS ONE         71400020
         MVC   ZERO(FOUR,R14),ROUTE     ROUTING INFORMATION             71600020
         B     PUT                                                      71800020
ERROPT   EQU   *                                                        71850020
         LA    RWORK,OPCERMSG           INVALID COMMAND                 71900020
         B     ERROPRET                 SET RETURN CODE                 71950020
*                                                                       72000020
ERROP    EQU   *                                                        72200020
         MVC   EROM(OPCEIGHT),OPCTNME   TERMINAL NAME                   72400020
         MVC   EROOM(OPCEIGHT),OPCOPFLD                                 72600020
         LA    RWORK,ERO                                                72800020
ERROPRET EQU   *                                                        73000020
         LA    R15,OPCFOUR                                              73200020
PUT      EQU   *                                                        73400020
         ST    RWORK,OPCREG1(,R13)                                      73600020
         RETURN (14,12),T,RC=(15)                                       73800020
ERR      DC    H'38',X'6000',C'IED016I STATION '                        74000020
ERMG     DC    8C' ',C' NOT FOUND',X'08000000'                          74200020
*                                                                       74400020
*                                                                       74600020
*                                                                       74800020
*              IF THIS MESSAGE IS MOVED THE TWO DC'S FOLLOWING IT       75000020
*              MUST ALSO BE MOVED                                       75200020
*                                                                       75400020
ERO      DC    H'44',X'6000',C'IED034I '                                75600020
EROM     DC    CL8' ',C' HAS NO '                                       75800020
EROOM    DC    CL8' '                                                   76000020
*                                                                       76200020
*              THESE NEXT TWO DC'S CANNOT BE MOVED. THEY ARE PART       76400020
*              OF MESSAGE ERO AND ARE USED BY OTHER CODE                76600020
*                                                                       76800020
OPTION   DC    C' OPTION '                                              77000020
ROUTE    DC    X'08000000'                                              77200020
TRANSHEX DC    C'0123456789ABCDEF'                                      77400020
TRANSDEC DC    C'0123456789******'                                      77600020
MSG35    DC    H'43',C'035I',C'DATA= '                                  77800020
COMP     CLC   OPCZERO(OPCONE,RTNT),OPCTNME                             78000020
TAG      DC    CL8'IEDQC5'                                              78200020
X1000IED DC    X'6000',C'IED'                                           78400020
OI       OI    FOURFOUR(RWORK4),ZERO                                    78600020
MOVEFROP MVC   FOURFOUR(ONE,RWORK3),ZERO(RTNT)                          78800020
MOV1DF   MVC   ZERO(ONE,R14),ZERO(R15)                                  78850020
UNPK1DF  UNPK  FOURFOUR(ONE,RWORK4),OPCDOUBL(EIGHT)                     78900020
H4       DC    H'4'                                                     78950020
ALLB     DC    C'**ALL BLANKS**'                                        79000020
TRAN     TR    ZERO(ONE,R14),ZERO(RWORK2)                               79200020
         PRINT NOGEN                                                    79400020
         TOPCD                                                          79600020
OPCPPL1  EQU   OPCSCAN-8                                                79800020
OPCPPLA  EQU   OPCSCAN-7                                                80000020
OPCPPL2  EQU   OPCSCAN-4                                                80200020
         TAVTD                                                          80400020
         TTNTD                                                          80600020
         TTRMD                                                          80800020
         TPRFD                                                          81000020
         TPRIOR                                                         81200020
         END                                                            81400020
